author wenzelm
Mon Dec 28 01:28:28 2015 +0100 (2015-12-28)
changeset 61945 1135b8de26c3
parent 61585 a9599d3d7610
child 61955 e96292f32c3c
permissions -rw-r--r--
more symbols;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     5 section \<open>Pi and Function Sets\<close>
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    11 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    12   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    14 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    15   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    17 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    18   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    20 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "\<rightarrow>" 60)
    21   where "A \<rightarrow> B \<equiv> Pi A (\<lambda>_. B)"
    23 syntax
    24   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    25   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    26 syntax (xsymbols)
    27   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    28   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    29 translations
    30   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    31   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    33 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    34   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    37 subsection \<open>Basic Properties of @{term Pi}\<close>
    39 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    40   by (simp add: Pi_def)
    42 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    43   by (simp add:Pi_def)
    45 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    46   by (simp add: Pi_def)
    48 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    49   by (simp add: Pi_def)
    51 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    52   unfolding Pi_def by auto
    54 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    55   by (auto simp: Pi_def)
    57 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    58   by (auto simp: Pi_def)
    60 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    61   by auto
    63 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    64   by (simp add: Pi_def)
    66 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    67   by auto
    69 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    70   by auto
    72 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    73   apply (simp add: Pi_def)
    74   apply auto
    75   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    76   picking an element from each non-empty @{term "B x"}\<close>
    77   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    78   apply auto
    79   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    80   apply auto
    81   done
    83 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    84   by (simp add: Pi_def)
    86 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    87   by auto
    89 lemma Pi_UN:
    90   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    91   assumes "finite I"
    92     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    93   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
    94 proof (intro set_eqI iffI)
    95   fix f
    96   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
    97   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
    98     by auto
    99   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)"
   100     by auto
   101   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   102     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   103   have "f \<in> Pi I (A k)"
   104   proof (intro Pi_I)
   105     fix i
   106     assume "i \<in> I"
   107     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   108     show "f i \<in> A k i" by auto
   109   qed
   110   then show "f \<in> (\<Union>n. Pi I (A n))"
   111     by auto
   112 qed auto
   114 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   115   by (simp add: Pi_def)
   117 text \<open>Covariance of Pi-sets in their second argument\<close>
   118 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   119   by auto
   121 text \<open>Contravariance of Pi-sets in their first argument\<close>
   122 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   123   by auto
   125 lemma prod_final:
   126   assumes 1: "fst \<circ> f \<in> Pi A B"
   127     and 2: "snd \<circ> f \<in> Pi A C"
   128   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   129 proof (rule Pi_I)
   130   fix z
   131   assume z: "z \<in> A"
   132   have "f z = (fst (f z), snd (f z))"
   133     by simp
   134   also have "\<dots> \<in> B z \<times> C z"
   135     by (metis SigmaI PiE o_apply 1 2 z)
   136   finally show "f z \<in> B z \<times> C z" .
   137 qed
   139 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   140   by (auto simp: Pi_def)
   142 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   143   by (auto simp: Pi_def)
   145 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   146   by (auto simp: Pi_def)
   148 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   149   by (auto simp: Pi_def)
   151 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   152   apply auto
   153   apply (drule_tac x=x in Pi_mem)
   154   apply (simp_all split: split_if_asm)
   155   apply (drule_tac x=i in Pi_mem)
   156   apply (auto dest!: Pi_mem)
   157   done
   160 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   162 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   163   by (simp add: Pi_def compose_def restrict_def)
   165 lemma compose_assoc:
   166   assumes "f \<in> A \<rightarrow> B"
   167     and "g \<in> B \<rightarrow> C"
   168     and "h \<in> C \<rightarrow> D"
   169   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   170   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   172 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   173   by (simp add: compose_def restrict_def)
   175 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   176   by (auto simp add: image_def compose_eq)
   179 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   181 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
   182   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
   184 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   185   by (simp add: Pi_def restrict_def)
   187 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   188   by (simp add: Pi_def restrict_def)
   190 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   191   by (simp add: restrict_def)
   193 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   194   by simp
   196 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   197   by (simp add: fun_eq_iff Pi_def restrict_def)
   199 lemma restrict_UNIV: "restrict f UNIV = f"
   200   by (simp add: restrict_def)
   202 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   203   by (simp add: inj_on_def restrict_def)
   205 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   206   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   208 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   209   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   211 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   212   by (auto simp add: restrict_def)
   214 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   215   unfolding restrict_def by (simp add: fun_eq_iff)
   217 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   218   by (auto simp: restrict_def)
   220 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   221   by (auto simp: fun_eq_iff)
   223 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   224   by (auto simp: restrict_def Pi_def)
   227 subsection \<open>Bijections Between Sets\<close>
   229 text \<open>The definition of @{const bij_betw} is in \<open>Fun.thy\<close>, but most of
   230 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   232 lemma bij_betwI:
   233   assumes "f \<in> A \<rightarrow> B"
   234     and "g \<in> B \<rightarrow> A"
   235     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   236     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   237   shows "bij_betw f A B"
   238   unfolding bij_betw_def
   239 proof
   240   show "inj_on f A"
   241     by (metis g_f inj_on_def)
   242   have "f ` A \<subseteq> B"
   243     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   244   moreover
   245   have "B \<subseteq> f ` A"
   246     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   247   ultimately show "f ` A = B"
   248     by blast
   249 qed
   251 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   252   by (auto simp add: bij_betw_def)
   254 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   255   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   257 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   258   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   259   apply (auto simp add: compose_def image_def)
   260   done
   262 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   263   by (simp add: bij_betw_def)
   266 subsection \<open>Extensionality\<close>
   268 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   269   unfolding extensional_def by auto
   271 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   272   by (simp add: extensional_def)
   274 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   275   by (simp add: restrict_def extensional_def)
   277 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   278   by (simp add: compose_def)
   280 lemma extensionalityI:
   281   assumes "f \<in> extensional A"
   282     and "g \<in> extensional A"
   283     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   284   shows "f = g"
   285   using assms by (force simp add: fun_eq_iff extensional_def)
   287 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   288   by (rule extensionalityI[OF restrict_extensional]) auto
   290 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   291   unfolding extensional_def by auto
   293 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   294   by (unfold inv_into_def) (fast intro: someI2)
   296 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   297   apply (simp add: bij_betw_def compose_def)
   298   apply (rule restrict_ext, auto)
   299   done
   301 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   302   apply (simp add: compose_def)
   303   apply (rule restrict_ext)
   304   apply (simp add: f_inv_into_f)
   305   done
   307 lemma extensional_insert[intro, simp]:
   308   assumes "a \<in> extensional (insert i I)"
   309   shows "a(i := b) \<in> extensional (insert i I)"
   310   using assms unfolding extensional_def by auto
   312 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   313   unfolding extensional_def by auto
   315 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   316   by (auto simp: extensional_def)
   318 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   319   unfolding restrict_def extensional_def by auto
   321 lemma extensional_insert_undefined[intro, simp]:
   322   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   323   unfolding extensional_def by auto
   325 lemma extensional_insert_cancel[intro, simp]:
   326   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   327   unfolding extensional_def by auto
   330 subsection \<open>Cardinality\<close>
   332 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   333   by (rule card_inj_on_le) auto
   335 lemma card_bij:
   336   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   337     and "g \<in> B \<rightarrow> A" "inj_on g B"
   338     and "finite A" "finite B"
   339   shows "card A = card B"
   340   using assms by (blast intro: card_inj order_antisym)
   343 subsection \<open>Extensional Function Spaces\<close>
   345 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   346   where "PiE S T = Pi S T \<inter> extensional S"
   348 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   350 syntax
   351   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   352 syntax (xsymbols)
   353   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   354 translations "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   356 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "\<rightarrow>\<^sub>E" 60)
   357   where "A \<rightarrow>\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   359 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   360   by (simp add: PiE_def)
   362 lemma PiE_empty_domain[simp]: "PiE {} T = {\<lambda>x. undefined}"
   363   unfolding PiE_def by simp
   365 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   366   unfolding PiE_def by simp
   368 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   369   unfolding PiE_def by auto
   371 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   372 proof
   373   assume "Pi\<^sub>E I F = {}"
   374   show "\<exists>i\<in>I. F i = {}"
   375   proof (rule ccontr)
   376     assume "\<not> ?thesis"
   377     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   378       by auto
   379     from choice[OF this]
   380     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   381     then have "f \<in> Pi\<^sub>E I F"
   382       by (auto simp: extensional_def PiE_def)
   383     with \<open>Pi\<^sub>E I F = {}\<close> show False
   384       by auto
   385   qed
   386 qed (auto simp: PiE_def)
   388 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   389   unfolding PiE_def by auto (auto dest!: extensional_arb)
   391 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   392   unfolding PiE_def by auto
   394 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   395   unfolding PiE_def extensional_def by auto
   397 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   398   unfolding PiE_def extensional_def by auto
   400 lemma PiE_insert_eq: "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   401 proof -
   402   {
   403     fix f assume "f \<in> PiE (insert x S) T" "x \<notin> S"
   404     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   405       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   406   }
   407   moreover
   408   {
   409     fix f assume "f \<in> PiE (insert x S) T" "x \<in> S"
   410     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   411       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   412   }
   413   ultimately show ?thesis
   414     using assms by (auto intro: PiE_fun_upd)
   415 qed
   417 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   418   by (auto simp: PiE_def)
   420 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   421   unfolding PiE_def by (auto simp: Pi_cong)
   423 lemma PiE_E [elim]:
   424   assumes "f \<in> PiE A B"
   425   obtains "x \<in> A" and "f x \<in> B x"
   426     | "x \<notin> A" and "f x = undefined"
   427   using assms by (auto simp: Pi_def PiE_def extensional_def)
   429 lemma PiE_I[intro!]:
   430   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   431   by (simp add: PiE_def extensional_def)
   433 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   434   by auto
   436 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   437   by (simp add: PiE_def Pi_iff)
   439 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   440   by (simp add: extensional_restrict PiE_def)
   442 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   443   by (auto simp: PiE_iff)
   445 lemma PiE_eq_subset:
   446   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   447     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   448     and "i \<in> I"
   449   shows "F i \<subseteq> F' i"
   450 proof
   451   fix x
   452   assume "x \<in> F i"
   453   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   454     by auto
   455   from choice[OF this] obtain f
   456     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   457   then have "f \<in> Pi\<^sub>E I F"
   458     by (auto simp: extensional_def PiE_def)
   459   then have "f \<in> Pi\<^sub>E I F'"
   460     using assms by simp
   461   then show "x \<in> F' i"
   462     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   463 qed
   465 lemma PiE_eq_iff_not_empty:
   466   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   467   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   468 proof (intro iffI ballI)
   469   fix i
   470   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   471   assume i: "i \<in> I"
   472   show "F i = F' i"
   473     using PiE_eq_subset[of I F F', OF ne eq i]
   474     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   475     by auto
   476 qed (auto simp: PiE_def)
   478 lemma PiE_eq_iff:
   479   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   480 proof (intro iffI disjCI)
   481   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   482   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   483   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   484     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   485   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   486     by auto
   487 next
   488   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   489   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   490     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   491 qed
   493 lemma extensional_funcset_fun_upd_restricts_rangeI:
   494   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   495   unfolding extensional_funcset_def extensional_def
   496   apply auto
   497   apply (case_tac "x = xa")
   498   apply auto
   499   done
   501 lemma extensional_funcset_fun_upd_extends_rangeI:
   502   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   503   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   504   using assms unfolding extensional_funcset_def extensional_def by auto
   507 subsubsection \<open>Injective Extensional Function Spaces\<close>
   509 lemma extensional_funcset_fun_upd_inj_onI:
   510   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   511     and "inj_on f S"
   512   shows "inj_on (f(x := a)) S"
   513   using assms
   514   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   516 lemma extensional_funcset_extend_domain_inj_on_eq:
   517   assumes "x \<notin> S"
   518   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   519     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   520   using assms
   521   apply (auto del: PiE_I PiE_E)
   522   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   523     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   524   apply (auto simp add: image_iff inj_on_def)
   525   apply (rule_tac x="xa x" in exI)
   526   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   527   apply (rule_tac x="xa(x := undefined)" in exI)
   528   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   529   apply (auto dest!: PiE_mem split: split_if_asm)
   530   done
   532 lemma extensional_funcset_extend_domain_inj_onI:
   533   assumes "x \<notin> S"
   534   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   535   using assms
   536   apply (auto intro!: inj_onI)
   537   apply (metis fun_upd_same)
   538   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   539   done
   542 subsubsection \<open>Cardinality\<close>
   544 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   545   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   547 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   548 proof (safe intro!: inj_onI ext)
   549   fix f y g z
   550   assume "x \<notin> S"
   551   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   552   assume "f(x := y) = g(x := z)"
   553   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   554     unfolding fun_eq_iff by auto
   555   from this[of x] show "y = z" by simp
   556   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   557     by (auto split: split_if_asm simp: PiE_def extensional_def)
   558 qed
   560 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   561 proof (induct rule: finite_induct)
   562   case empty
   563   then show ?case by auto
   564 next
   565   case (insert x S)
   566   then show ?case
   567     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   568 qed
   570 end