src/HOL/Library/Multiset.thy
author wenzelm
Mon Dec 28 01:28:28 2015 +0100 (2015-12-28)
changeset 61945 1135b8de26c3
parent 61890 f6ded81f5690
child 61955 e96292f32c3c
permissions -rw-r--r--
more symbols;
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section \<open>(Finite) multisets\<close>
    10 
    11 theory Multiset
    12 imports Main
    13 begin
    14 
    15 subsection \<open>The type of multisets\<close>
    16 
    17 definition "multiset = {f :: 'a \<Rightarrow> nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a \<Rightarrow> nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 abbreviation Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"  ("(_/ :# _)" [50, 51] 50) where
    29   "a :# M == 0 < count M a"
    30 
    31 notation (xsymbols)
    32   Melem (infix "\<in>#" 50)
    33 
    34 lemma multiset_eq_iff: "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    35   by (simp only: count_inject [symmetric] fun_eq_iff)
    36 
    37 lemma multiset_eqI: "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    38   using multiset_eq_iff by auto
    39 
    40 text \<open>Preservation of the representing set @{term multiset}.\<close>
    41 
    42 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    43   by (simp add: multiset_def)
    44 
    45 lemma only1_in_multiset: "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    46   by (simp add: multiset_def)
    47 
    48 lemma union_preserves_multiset: "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma diff_preserves_multiset:
    52   assumes "M \<in> multiset"
    53   shows "(\<lambda>a. M a - N a) \<in> multiset"
    54 proof -
    55   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    56     by auto
    57   with assms show ?thesis
    58     by (auto simp add: multiset_def intro: finite_subset)
    59 qed
    60 
    61 lemma filter_preserves_multiset:
    62   assumes "M \<in> multiset"
    63   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    64 proof -
    65   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    66     by auto
    67   with assms show ?thesis
    68     by (auto simp add: multiset_def intro: finite_subset)
    69 qed
    70 
    71 lemmas in_multiset = const0_in_multiset only1_in_multiset
    72   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    73 
    74 
    75 subsection \<open>Representing multisets\<close>
    76 
    77 text \<open>Multiset enumeration\<close>
    78 
    79 instantiation multiset :: (type) cancel_comm_monoid_add
    80 begin
    81 
    82 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    83 by (rule const0_in_multiset)
    84 
    85 abbreviation Mempty :: "'a multiset" ("{#}") where
    86   "Mempty \<equiv> 0"
    87 
    88 lift_definition plus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    89 by (rule union_preserves_multiset)
    90 
    91 lift_definition minus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    92 by (rule diff_preserves_multiset)
    93 
    94 instance
    95   by (standard; transfer; simp add: fun_eq_iff)
    96 
    97 end
    98 
    99 lift_definition single :: "'a \<Rightarrow> 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   100 by (rule only1_in_multiset)
   101 
   102 syntax
   103   "_multiset" :: "args \<Rightarrow> 'a multiset"    ("{#(_)#}")
   104 translations
   105   "{#x, xs#}" == "{#x#} + {#xs#}"
   106   "{#x#}" == "CONST single x"
   107 
   108 lemma count_empty [simp]: "count {#} a = 0"
   109   by (simp add: zero_multiset.rep_eq)
   110 
   111 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   112   by (simp add: single.rep_eq)
   113 
   114 
   115 subsection \<open>Basic operations\<close>
   116 
   117 subsubsection \<open>Union\<close>
   118 
   119 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   120   by (simp add: plus_multiset.rep_eq)
   121 
   122 
   123 subsubsection \<open>Difference\<close>
   124 
   125 instantiation multiset :: (type) comm_monoid_diff
   126 begin
   127 
   128 instance
   129   by (standard; transfer; simp add: fun_eq_iff)
   130 
   131 end
   132 
   133 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   134   by (simp add: minus_multiset.rep_eq)
   135 
   136 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   137   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   138 
   139 lemma diff_cancel[simp]: "A - A = {#}"
   140   by (fact Groups.diff_cancel)
   141 
   142 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   143   by (fact add_diff_cancel_right')
   144 
   145 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   146   by (fact add_diff_cancel_left')
   147 
   148 lemma diff_right_commute:
   149   fixes M N Q :: "'a multiset"
   150   shows "M - N - Q = M - Q - N"
   151   by (fact diff_right_commute)
   152 
   153 lemma diff_add:
   154   fixes M N Q :: "'a multiset"
   155   shows "M - (N + Q) = M - N - Q"
   156   by (rule sym) (fact diff_diff_add)
   157 
   158 lemma insert_DiffM: "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   159   by (clarsimp simp: multiset_eq_iff)
   160 
   161 lemma insert_DiffM2 [simp]: "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma diff_union_swap: "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   165   by (auto simp add: multiset_eq_iff)
   166 
   167 lemma diff_union_single_conv: "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   168   by (simp add: multiset_eq_iff)
   169 
   170 
   171 subsubsection \<open>Equality of multisets\<close>
   172 
   173 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   174   by (simp add: multiset_eq_iff)
   175 
   176 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   177   by (auto simp add: multiset_eq_iff)
   178 
   179 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   180   by (auto simp add: multiset_eq_iff)
   181 
   182 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma diff_single_trivial: "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma diff_single_eq_union: "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   192   by auto
   193 
   194 lemma union_single_eq_diff: "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   195   by (auto dest: sym)
   196 
   197 lemma union_single_eq_member: "M + {#x#} = N \<Longrightarrow> x \<in># N"
   198   by auto
   199 
   200 lemma union_is_single: "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}"
   201   (is "?lhs = ?rhs")
   202 proof
   203   show ?lhs if ?rhs using that by auto
   204   show ?rhs if ?lhs
   205     using that by (simp add: multiset_eq_iff split: if_splits) (metis add_is_1)
   206 qed
   207 
   208 lemma single_is_union: "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   209   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   210 
   211 lemma add_eq_conv_diff:
   212   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"
   213   (is "?lhs \<longleftrightarrow> ?rhs")
   214 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   215 proof
   216   show ?lhs if ?rhs
   217     using that
   218     by (auto simp add: add.assoc add.commute [of "{#b#}"])
   219       (drule sym, simp add: add.assoc [symmetric])
   220   show ?rhs if ?lhs
   221   proof (cases "a = b")
   222     case True with \<open>?lhs\<close> show ?thesis by simp
   223   next
   224     case False
   225     from \<open>?lhs\<close> have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   226     with False have "a \<in># N" by auto
   227     moreover from \<open>?lhs\<close> have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   228     moreover note False
   229     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   230   qed
   231 qed
   232 
   233 lemma insert_noteq_member:
   234   assumes BC: "B + {#b#} = C + {#c#}"
   235    and bnotc: "b \<noteq> c"
   236   shows "c \<in># B"
   237 proof -
   238   have "c \<in># C + {#c#}" by simp
   239   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   240   then have "c \<in># B + {#b#}" using BC by simp
   241   then show "c \<in># B" using nc by simp
   242 qed
   243 
   244 lemma add_eq_conv_ex:
   245   "(M + {#a#} = N + {#b#}) =
   246     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   247   by (auto simp add: add_eq_conv_diff)
   248 
   249 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   250   by (rule exI [where x = "M - {#x#}"]) simp
   251 
   252 lemma multiset_add_sub_el_shuffle:
   253   assumes "c \<in># B"
   254     and "b \<noteq> c"
   255   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   256 proof -
   257   from \<open>c \<in># B\<close> obtain A where B: "B = A + {#c#}"
   258     by (blast dest: multi_member_split)
   259   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   260   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
   261     by (simp add: ac_simps)
   262   then show ?thesis using B by simp
   263 qed
   264 
   265 
   266 subsubsection \<open>Pointwise ordering induced by count\<close>
   267 
   268 definition subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
   269 "subseteq_mset A B = (\<forall>a. count A a \<le> count B a)"
   270 
   271 definition subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
   272 "subset_mset A B = (A <=# B \<and> A \<noteq> B)"
   273 
   274 notation subseteq_mset (infix "\<le>#" 50)
   275 notation (xsymbols) subseteq_mset (infix "\<subseteq>#" 50)
   276 
   277 notation (xsymbols) subset_mset (infix "\<subset>#" 50)
   278 
   279 interpretation subset_mset: ordered_ab_semigroup_add_imp_le "op +" "op -" "op \<subseteq>#" "op \<subset>#"
   280   by standard (auto simp add: subset_mset_def subseteq_mset_def multiset_eq_iff intro: order_trans antisym)
   281 
   282 lemma mset_less_eqI: "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le># B"
   283   by (simp add: subseteq_mset_def)
   284 
   285 lemma mset_le_exists_conv: "(A::'a multiset) \<le># B \<longleftrightarrow> (\<exists>C. B = A + C)"
   286   unfolding subseteq_mset_def
   287   apply (rule iffI)
   288    apply (rule exI [where x = "B - A"])
   289    apply (auto intro: multiset_eq_iff [THEN iffD2])
   290   done
   291 
   292 interpretation subset_mset: ordered_cancel_comm_monoid_diff  "op +" "op -" 0 "op \<le>#" "op <#"
   293   by standard (simp, fact mset_le_exists_conv)
   294 
   295 lemma mset_le_mono_add_right_cancel [simp]: "(A::'a multiset) + C \<le># B + C \<longleftrightarrow> A \<le># B"
   296   by (fact subset_mset.add_le_cancel_right)
   297 
   298 lemma mset_le_mono_add_left_cancel [simp]: "C + (A::'a multiset) \<le># C + B \<longleftrightarrow> A \<le># B"
   299   by (fact subset_mset.add_le_cancel_left)
   300 
   301 lemma mset_le_mono_add: "(A::'a multiset) \<le># B \<Longrightarrow> C \<le># D \<Longrightarrow> A + C \<le># B + D"
   302   by (fact subset_mset.add_mono)
   303 
   304 lemma mset_le_add_left [simp]: "(A::'a multiset) \<le># A + B"
   305   unfolding subseteq_mset_def by auto
   306 
   307 lemma mset_le_add_right [simp]: "B \<le># (A::'a multiset) + B"
   308   unfolding subseteq_mset_def by auto
   309 
   310 lemma mset_le_single: "a \<in># B \<Longrightarrow> {#a#} \<le># B"
   311   by (simp add: subseteq_mset_def)
   312 
   313 lemma multiset_diff_union_assoc:
   314   fixes A B C D :: "'a multiset"
   315   shows "C \<le># B \<Longrightarrow> A + B - C = A + (B - C)"
   316   by (simp add: subset_mset.diff_add_assoc)
   317 
   318 lemma mset_le_multiset_union_diff_commute:
   319   fixes A B C D :: "'a multiset"
   320   shows "B \<le># A \<Longrightarrow> A - B + C = A + C - B"
   321 by (simp add: subset_mset.add_diff_assoc2)
   322 
   323 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le># M"
   324 by(simp add: subseteq_mset_def)
   325 
   326 lemma mset_lessD: "A <# B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   327 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   328 apply (erule allE [where x = x])
   329 apply auto
   330 done
   331 
   332 lemma mset_leD: "A \<le># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   333 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   334 apply (erule allE [where x = x])
   335 apply auto
   336 done
   337 
   338 lemma mset_less_insertD: "(A + {#x#} <# B) \<Longrightarrow> (x \<in># B \<and> A <# B)"
   339 apply (rule conjI)
   340  apply (simp add: mset_lessD)
   341 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   342 apply safe
   343  apply (erule_tac x = a in allE)
   344  apply (auto split: split_if_asm)
   345 done
   346 
   347 lemma mset_le_insertD: "(A + {#x#} \<le># B) \<Longrightarrow> (x \<in># B \<and> A \<le># B)"
   348 apply (rule conjI)
   349  apply (simp add: mset_leD)
   350 apply (force simp: subset_mset_def subseteq_mset_def split: split_if_asm)
   351 done
   352 
   353 lemma mset_less_of_empty[simp]: "A <# {#} \<longleftrightarrow> False"
   354   by (auto simp add: subseteq_mset_def subset_mset_def multiset_eq_iff)
   355 
   356 lemma empty_le[simp]: "{#} \<le># A"
   357   unfolding mset_le_exists_conv by auto
   358 
   359 lemma le_empty[simp]: "(M \<le># {#}) = (M = {#})"
   360   unfolding mset_le_exists_conv by auto
   361 
   362 lemma multi_psub_of_add_self[simp]: "A <# A + {#x#}"
   363   by (auto simp: subset_mset_def subseteq_mset_def)
   364 
   365 lemma multi_psub_self[simp]: "(A::'a multiset) <# A = False"
   366   by simp
   367 
   368 lemma mset_less_add_bothsides: "N + {#x#} <# M + {#x#} \<Longrightarrow> N <# M"
   369   by (fact subset_mset.add_less_imp_less_right)
   370 
   371 lemma mset_less_empty_nonempty: "{#} <# S \<longleftrightarrow> S \<noteq> {#}"
   372   by (auto simp: subset_mset_def subseteq_mset_def)
   373 
   374 lemma mset_less_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} <# B"
   375   by (auto simp: subset_mset_def subseteq_mset_def multiset_eq_iff)
   376 
   377 
   378 subsubsection \<open>Intersection\<close>
   379 
   380 definition inf_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   381   multiset_inter_def: "inf_subset_mset A B = A - (A - B)"
   382 
   383 interpretation subset_mset: semilattice_inf inf_subset_mset "op \<le>#" "op <#"
   384 proof -
   385   have [simp]: "m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" for m n q :: nat
   386     by arith
   387   show "class.semilattice_inf op #\<inter> op \<le># op <#"
   388     by standard (auto simp add: multiset_inter_def subseteq_mset_def)
   389 qed
   390 
   391 
   392 lemma multiset_inter_count [simp]:
   393   fixes A B :: "'a multiset"
   394   shows "count (A #\<inter> B) x = min (count A x) (count B x)"
   395   by (simp add: multiset_inter_def)
   396 
   397 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   398   by (rule multiset_eqI) auto
   399 
   400 lemma multiset_union_diff_commute:
   401   assumes "B #\<inter> C = {#}"
   402   shows "A + B - C = A - C + B"
   403 proof (rule multiset_eqI)
   404   fix x
   405   from assms have "min (count B x) (count C x) = 0"
   406     by (auto simp add: multiset_eq_iff)
   407   then have "count B x = 0 \<or> count C x = 0"
   408     by auto
   409   then show "count (A + B - C) x = count (A - C + B) x"
   410     by auto
   411 qed
   412 
   413 lemma empty_inter [simp]: "{#} #\<inter> M = {#}"
   414   by (simp add: multiset_eq_iff)
   415 
   416 lemma inter_empty [simp]: "M #\<inter> {#} = {#}"
   417   by (simp add: multiset_eq_iff)
   418 
   419 lemma inter_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   420   by (simp add: multiset_eq_iff)
   421 
   422 lemma inter_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   423   by (simp add: multiset_eq_iff)
   424 
   425 lemma inter_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   426   by (simp add: multiset_eq_iff)
   427 
   428 lemma inter_add_right2: "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   429   by (simp add: multiset_eq_iff)
   430 
   431 
   432 subsubsection \<open>Bounded union\<close>
   433 
   434 definition sup_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"(infixl "#\<union>" 70)
   435   where "sup_subset_mset A B = A + (B - A)"
   436 
   437 interpretation subset_mset: semilattice_sup sup_subset_mset "op \<le>#" "op <#"
   438 proof -
   439   have [simp]: "m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" for m n q :: nat
   440     by arith
   441   show "class.semilattice_sup op #\<union> op \<le># op <#"
   442     by standard (auto simp add: sup_subset_mset_def subseteq_mset_def)
   443 qed
   444 
   445 lemma sup_subset_mset_count [simp]: "count (A #\<union> B) x = max (count A x) (count B x)"
   446   by (simp add: sup_subset_mset_def)
   447 
   448 lemma empty_sup [simp]: "{#} #\<union> M = M"
   449   by (simp add: multiset_eq_iff)
   450 
   451 lemma sup_empty [simp]: "M #\<union> {#} = M"
   452   by (simp add: multiset_eq_iff)
   453 
   454 lemma sup_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   455   by (simp add: multiset_eq_iff)
   456 
   457 lemma sup_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   458   by (simp add: multiset_eq_iff)
   459 
   460 lemma sup_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   461   by (simp add: multiset_eq_iff)
   462 
   463 lemma sup_add_right2: "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   464   by (simp add: multiset_eq_iff)
   465 
   466 subsubsection \<open>Subset is an order\<close>
   467 interpretation subset_mset: order "op \<le>#" "op <#" by unfold_locales auto
   468 
   469 subsubsection \<open>Filter (with comprehension syntax)\<close>
   470 
   471 text \<open>Multiset comprehension\<close>
   472 
   473 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
   474 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   475 by (rule filter_preserves_multiset)
   476 
   477 lemma count_filter_mset [simp]: "count (filter_mset P M) a = (if P a then count M a else 0)"
   478   by (simp add: filter_mset.rep_eq)
   479 
   480 lemma filter_empty_mset [simp]: "filter_mset P {#} = {#}"
   481   by (rule multiset_eqI) simp
   482 
   483 lemma filter_single_mset [simp]: "filter_mset P {#x#} = (if P x then {#x#} else {#})"
   484   by (rule multiset_eqI) simp
   485 
   486 lemma filter_union_mset [simp]: "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
   487   by (rule multiset_eqI) simp
   488 
   489 lemma filter_diff_mset [simp]: "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
   490   by (rule multiset_eqI) simp
   491 
   492 lemma filter_inter_mset [simp]: "filter_mset P (M #\<inter> N) = filter_mset P M #\<inter> filter_mset P N"
   493   by (rule multiset_eqI) simp
   494 
   495 lemma multiset_filter_subset[simp]: "filter_mset f M \<le># M"
   496   by (simp add: mset_less_eqI)
   497 
   498 lemma multiset_filter_mono:
   499   assumes "A \<le># B"
   500   shows "filter_mset f A \<le># filter_mset f B"
   501 proof -
   502   from assms[unfolded mset_le_exists_conv]
   503   obtain C where B: "B = A + C" by auto
   504   show ?thesis unfolding B by auto
   505 qed
   506 
   507 syntax
   508   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   509 syntax (xsymbol)
   510   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   511 translations
   512   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
   513 
   514 
   515 subsubsection \<open>Set of elements\<close>
   516 
   517 definition set_mset :: "'a multiset \<Rightarrow> 'a set"
   518   where "set_mset M = {x. x \<in># M}"
   519 
   520 lemma set_mset_empty [simp]: "set_mset {#} = {}"
   521 by (simp add: set_mset_def)
   522 
   523 lemma set_mset_single [simp]: "set_mset {#b#} = {b}"
   524 by (simp add: set_mset_def)
   525 
   526 lemma set_mset_union [simp]: "set_mset (M + N) = set_mset M \<union> set_mset N"
   527 by (auto simp add: set_mset_def)
   528 
   529 lemma set_mset_eq_empty_iff [simp]: "(set_mset M = {}) = (M = {#})"
   530 by (auto simp add: set_mset_def multiset_eq_iff)
   531 
   532 lemma mem_set_mset_iff [simp]: "(x \<in> set_mset M) = (x \<in># M)"
   533 by (auto simp add: set_mset_def)
   534 
   535 lemma set_mset_filter [simp]: "set_mset {# x\<in>#M. P x #} = set_mset M \<inter> {x. P x}"
   536 by (auto simp add: set_mset_def)
   537 
   538 lemma finite_set_mset [iff]: "finite (set_mset M)"
   539   using count [of M] by (simp add: multiset_def set_mset_def)
   540 
   541 lemma finite_Collect_mem [iff]: "finite {x. x \<in># M}"
   542   unfolding set_mset_def[symmetric] by simp
   543 
   544 lemma set_mset_mono: "A \<le># B \<Longrightarrow> set_mset A \<subseteq> set_mset B"
   545   by (metis mset_leD subsetI mem_set_mset_iff)
   546 
   547 lemma ball_set_mset_iff: "(\<forall>x \<in> set_mset M. P x) \<longleftrightarrow> (\<forall>x. x \<in># M \<longrightarrow> P x)"
   548   by auto
   549 
   550 
   551 subsubsection \<open>Size\<close>
   552 
   553 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
   554 
   555 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
   556   by (auto simp: wcount_def add_mult_distrib)
   557 
   558 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
   559   "size_multiset f M = setsum (wcount f M) (set_mset M)"
   560 
   561 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
   562 
   563 instantiation multiset :: (type) size
   564 begin
   565 
   566 definition size_multiset where
   567   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
   568 instance ..
   569 
   570 end
   571 
   572 lemmas size_multiset_overloaded_eq =
   573   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
   574 
   575 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
   576 by (simp add: size_multiset_def)
   577 
   578 lemma size_empty [simp]: "size {#} = 0"
   579 by (simp add: size_multiset_overloaded_def)
   580 
   581 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
   582 by (simp add: size_multiset_eq)
   583 
   584 lemma size_single [simp]: "size {#b#} = 1"
   585 by (simp add: size_multiset_overloaded_def)
   586 
   587 lemma setsum_wcount_Int:
   588   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_mset N) = setsum (wcount f N) A"
   589 apply (induct rule: finite_induct)
   590  apply simp
   591 apply (simp add: Int_insert_left set_mset_def wcount_def)
   592 done
   593 
   594 lemma size_multiset_union [simp]:
   595   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
   596 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
   597 apply (subst Int_commute)
   598 apply (simp add: setsum_wcount_Int)
   599 done
   600 
   601 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   602 by (auto simp add: size_multiset_overloaded_def)
   603 
   604 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
   605 by (auto simp add: size_multiset_eq multiset_eq_iff)
   606 
   607 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   608 by (auto simp add: size_multiset_overloaded_def)
   609 
   610 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   611 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   612 
   613 lemma size_eq_Suc_imp_elem: "size M = Suc n \<Longrightarrow> \<exists>a. a \<in># M"
   614 apply (unfold size_multiset_overloaded_eq)
   615 apply (drule setsum_SucD)
   616 apply auto
   617 done
   618 
   619 lemma size_eq_Suc_imp_eq_union:
   620   assumes "size M = Suc n"
   621   shows "\<exists>a N. M = N + {#a#}"
   622 proof -
   623   from assms obtain a where "a \<in># M"
   624     by (erule size_eq_Suc_imp_elem [THEN exE])
   625   then have "M = M - {#a#} + {#a#}" by simp
   626   then show ?thesis by blast
   627 qed
   628 
   629 lemma size_mset_mono:
   630   fixes A B :: "'a multiset"
   631   assumes "A \<le># B"
   632   shows "size A \<le> size B"
   633 proof -
   634   from assms[unfolded mset_le_exists_conv]
   635   obtain C where B: "B = A + C" by auto
   636   show ?thesis unfolding B by (induct C) auto
   637 qed
   638 
   639 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
   640 by (rule size_mset_mono[OF multiset_filter_subset])
   641 
   642 lemma size_Diff_submset:
   643   "M \<le># M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
   644 by (metis add_diff_cancel_left' size_union mset_le_exists_conv)
   645 
   646 subsection \<open>Induction and case splits\<close>
   647 
   648 theorem multiset_induct [case_names empty add, induct type: multiset]:
   649   assumes empty: "P {#}"
   650   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   651   shows "P M"
   652 proof (induct n \<equiv> "size M" arbitrary: M)
   653   case 0 thus "P M" by (simp add: empty)
   654 next
   655   case (Suc k)
   656   obtain N x where "M = N + {#x#}"
   657     using \<open>Suc k = size M\<close> [symmetric]
   658     using size_eq_Suc_imp_eq_union by fast
   659   with Suc add show "P M" by simp
   660 qed
   661 
   662 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   663 by (induct M) auto
   664 
   665 lemma multiset_cases [cases type]:
   666   obtains (empty) "M = {#}"
   667     | (add) N x where "M = N + {#x#}"
   668   using assms by (induct M) simp_all
   669 
   670 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   671 by (cases "B = {#}") (auto dest: multi_member_split)
   672 
   673 lemma multiset_partition: "M = {# x\<in>#M. P x #} + {# x\<in>#M. \<not> P x #}"
   674 apply (subst multiset_eq_iff)
   675 apply auto
   676 done
   677 
   678 lemma mset_less_size: "(A::'a multiset) <# B \<Longrightarrow> size A < size B"
   679 proof (induct A arbitrary: B)
   680   case (empty M)
   681   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   682   then obtain M' x where "M = M' + {#x#}"
   683     by (blast dest: multi_nonempty_split)
   684   then show ?case by simp
   685 next
   686   case (add S x T)
   687   have IH: "\<And>B. S <# B \<Longrightarrow> size S < size B" by fact
   688   have SxsubT: "S + {#x#} <# T" by fact
   689   then have "x \<in># T" and "S <# T" by (auto dest: mset_less_insertD)
   690   then obtain T' where T: "T = T' + {#x#}"
   691     by (blast dest: multi_member_split)
   692   then have "S <# T'" using SxsubT
   693     by (blast intro: mset_less_add_bothsides)
   694   then have "size S < size T'" using IH by simp
   695   then show ?case using T by simp
   696 qed
   697 
   698 
   699 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
   700 by (cases M) auto
   701 
   702 subsubsection \<open>Strong induction and subset induction for multisets\<close>
   703 
   704 text \<open>Well-foundedness of strict subset relation\<close>
   705 
   706 lemma wf_less_mset_rel: "wf {(M, N :: 'a multiset). M <# N}"
   707 apply (rule wf_measure [THEN wf_subset, where f1=size])
   708 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   709 done
   710 
   711 lemma full_multiset_induct [case_names less]:
   712 assumes ih: "\<And>B. \<forall>(A::'a multiset). A <# B \<longrightarrow> P A \<Longrightarrow> P B"
   713 shows "P B"
   714 apply (rule wf_less_mset_rel [THEN wf_induct])
   715 apply (rule ih, auto)
   716 done
   717 
   718 lemma multi_subset_induct [consumes 2, case_names empty add]:
   719   assumes "F \<le># A"
   720     and empty: "P {#}"
   721     and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   722   shows "P F"
   723 proof -
   724   from \<open>F \<le># A\<close>
   725   show ?thesis
   726   proof (induct F)
   727     show "P {#}" by fact
   728   next
   729     fix x F
   730     assume P: "F \<le># A \<Longrightarrow> P F" and i: "F + {#x#} \<le># A"
   731     show "P (F + {#x#})"
   732     proof (rule insert)
   733       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   734       from i have "F \<le># A" by (auto dest: mset_le_insertD)
   735       with P show "P F" .
   736     qed
   737   qed
   738 qed
   739 
   740 
   741 subsection \<open>The fold combinator\<close>
   742 
   743 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   744 where
   745   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_mset M)"
   746 
   747 lemma fold_mset_empty [simp]: "fold_mset f s {#} = s"
   748   by (simp add: fold_mset_def)
   749 
   750 context comp_fun_commute
   751 begin
   752 
   753 lemma fold_mset_insert: "fold_mset f s (M + {#x#}) = f x (fold_mset f s M)"
   754 proof -
   755   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   756     by (fact comp_fun_commute_funpow)
   757   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   758     by (fact comp_fun_commute_funpow)
   759   show ?thesis
   760   proof (cases "x \<in> set_mset M")
   761     case False
   762     then have *: "count (M + {#x#}) x = 1" by simp
   763     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_mset M) =
   764       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_mset M)"
   765       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   766     with False * show ?thesis
   767       by (simp add: fold_mset_def del: count_union)
   768   next
   769     case True
   770     def N \<equiv> "set_mset M - {x}"
   771     from N_def True have *: "set_mset M = insert x N" "x \<notin> N" "finite N" by auto
   772     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   773       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   774       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   775     with * show ?thesis by (simp add: fold_mset_def del: count_union) simp
   776   qed
   777 qed
   778 
   779 corollary fold_mset_single [simp]: "fold_mset f s {#x#} = f x s"
   780 proof -
   781   have "fold_mset f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   782   then show ?thesis by simp
   783 qed
   784 
   785 lemma fold_mset_fun_left_comm: "f x (fold_mset f s M) = fold_mset f (f x s) M"
   786   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   787 
   788 lemma fold_mset_union [simp]: "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
   789 proof (induct M)
   790   case empty then show ?case by simp
   791 next
   792   case (add M x)
   793   have "M + {#x#} + N = (M + N) + {#x#}"
   794     by (simp add: ac_simps)
   795   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   796 qed
   797 
   798 lemma fold_mset_fusion:
   799   assumes "comp_fun_commute g"
   800     and *: "\<And>x y. h (g x y) = f x (h y)"
   801   shows "h (fold_mset g w A) = fold_mset f (h w) A"
   802 proof -
   803   interpret comp_fun_commute g by (fact assms)
   804   from * show ?thesis by (induct A) auto
   805 qed
   806 
   807 end
   808 
   809 text \<open>
   810   A note on code generation: When defining some function containing a
   811   subterm @{term "fold_mset F"}, code generation is not automatic. When
   812   interpreting locale \<open>left_commutative\<close> with \<open>F\<close>, the
   813   would be code thms for @{const fold_mset} become thms like
   814   @{term "fold_mset F z {#} = z"} where \<open>F\<close> is not a pattern but
   815   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   816   constant with its own code thms needs to be introduced for \<open>F\<close>. See the image operator below.
   817 \<close>
   818 
   819 
   820 subsection \<open>Image\<close>
   821 
   822 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   823   "image_mset f = fold_mset (plus \<circ> single \<circ> f) {#}"
   824 
   825 lemma comp_fun_commute_mset_image: "comp_fun_commute (plus \<circ> single \<circ> f)"
   826 proof
   827 qed (simp add: ac_simps fun_eq_iff)
   828 
   829 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   830   by (simp add: image_mset_def)
   831 
   832 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   833 proof -
   834   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   835     by (fact comp_fun_commute_mset_image)
   836   show ?thesis by (simp add: image_mset_def)
   837 qed
   838 
   839 lemma image_mset_union [simp]: "image_mset f (M + N) = image_mset f M + image_mset f N"
   840 proof -
   841   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   842     by (fact comp_fun_commute_mset_image)
   843   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
   844 qed
   845 
   846 corollary image_mset_insert: "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   847   by simp
   848 
   849 lemma set_image_mset [simp]: "set_mset (image_mset f M) = image f (set_mset M)"
   850   by (induct M) simp_all
   851 
   852 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
   853   by (induct M) simp_all
   854 
   855 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   856   by (cases M) auto
   857 
   858 syntax
   859   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   860       ("({#_/. _ :# _#})")
   861 translations
   862   "{#e. x:#M#}" == "CONST image_mset (\<lambda>x. e) M"
   863 
   864 syntax (xsymbols)
   865   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   866       ("({#_/. _ \<in># _#})")
   867 translations
   868   "{#e. x \<in># M#}" == "CONST image_mset (\<lambda>x. e) M"
   869 
   870 syntax
   871   "_comprehension3_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   872       ("({#_/ | _ :# _./ _#})")
   873 translations
   874   "{#e | x:#M. P#}" \<rightharpoonup> "{#e. x :# {# x:#M. P#}#}"
   875 
   876 syntax
   877   "_comprehension4_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   878       ("({#_/ | _ \<in># _./ _#})")
   879 translations
   880   "{#e | x\<in>#M. P#}" \<rightharpoonup> "{#e. x \<in># {# x\<in>#M. P#}#}"
   881 
   882 text \<open>
   883   This allows to write not just filters like @{term "{#x\<in>#M. x<c#}"}
   884   but also images like @{term "{#x+x. x\<in>#M #}"} and @{term [source]
   885   "{#x+x|x\<in>#M. x<c#}"}, where the latter is currently displayed as
   886   @{term "{#x+x|x\<in>#M. x<c#}"}.
   887 \<close>
   888 
   889 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_mset M"
   890 by (metis mem_set_mset_iff set_image_mset)
   891 
   892 functor image_mset: image_mset
   893 proof -
   894   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   895   proof
   896     fix A
   897     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   898       by (induct A) simp_all
   899   qed
   900   show "image_mset id = id"
   901   proof
   902     fix A
   903     show "image_mset id A = id A"
   904       by (induct A) simp_all
   905   qed
   906 qed
   907 
   908 declare
   909   image_mset.id [simp]
   910   image_mset.identity [simp]
   911 
   912 lemma image_mset_id[simp]: "image_mset id x = x"
   913   unfolding id_def by auto
   914 
   915 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
   916   by (induct M) auto
   917 
   918 lemma image_mset_cong_pair:
   919   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
   920   by (metis image_mset_cong split_cong)
   921 
   922 
   923 subsection \<open>Further conversions\<close>
   924 
   925 primrec mset :: "'a list \<Rightarrow> 'a multiset" where
   926   "mset [] = {#}" |
   927   "mset (a # x) = mset x + {# a #}"
   928 
   929 lemma in_multiset_in_set:
   930   "x \<in># mset xs \<longleftrightarrow> x \<in> set xs"
   931   by (induct xs) simp_all
   932 
   933 lemma count_mset:
   934   "count (mset xs) x = length (filter (\<lambda>y. x = y) xs)"
   935   by (induct xs) simp_all
   936 
   937 lemma mset_zero_iff[simp]: "(mset x = {#}) = (x = [])"
   938   by (induct x) auto
   939 
   940 lemma mset_zero_iff_right[simp]: "({#} = mset x) = (x = [])"
   941 by (induct x) auto
   942 
   943 lemma set_mset_mset[simp]: "set_mset (mset x) = set x"
   944 by (induct x) auto
   945 
   946 lemma mem_set_multiset_eq: "x \<in> set xs = (x \<in># mset xs)"
   947 by (induct xs) auto
   948 
   949 lemma size_mset [simp]: "size (mset xs) = length xs"
   950   by (induct xs) simp_all
   951 
   952 lemma mset_append [simp]: "mset (xs @ ys) = mset xs + mset ys"
   953   by (induct xs arbitrary: ys) (auto simp: ac_simps)
   954 
   955 lemma mset_filter: "mset (filter P xs) = {#x \<in># mset xs. P x #}"
   956   by (induct xs) simp_all
   957 
   958 lemma mset_rev [simp]:
   959   "mset (rev xs) = mset xs"
   960   by (induct xs) simp_all
   961 
   962 lemma surj_mset: "surj mset"
   963 apply (unfold surj_def)
   964 apply (rule allI)
   965 apply (rule_tac M = y in multiset_induct)
   966  apply auto
   967 apply (rule_tac x = "x # xa" in exI)
   968 apply auto
   969 done
   970 
   971 lemma set_count_greater_0: "set x = {a. count (mset x) a > 0}"
   972 by (induct x) auto
   973 
   974 lemma distinct_count_atmost_1:
   975   "distinct x = (\<forall>a. count (mset x) a = (if a \<in> set x then 1 else 0))"
   976   apply (induct x, simp, rule iffI, simp_all)
   977   subgoal for a b
   978     apply (rule conjI)
   979     apply (simp_all add: set_mset_mset [symmetric] del: set_mset_mset)
   980     apply (erule_tac x = a in allE, simp)
   981     apply clarify
   982     apply (erule_tac x = aa in allE, simp)
   983     done
   984   done
   985 
   986 lemma mset_eq_setD: "mset xs = mset ys \<Longrightarrow> set xs = set ys"
   987 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   988 
   989 lemma set_eq_iff_mset_eq_distinct:
   990   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   991     (set x = set y) = (mset x = mset y)"
   992 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   993 
   994 lemma set_eq_iff_mset_remdups_eq:
   995    "(set x = set y) = (mset (remdups x) = mset (remdups y))"
   996 apply (rule iffI)
   997 apply (simp add: set_eq_iff_mset_eq_distinct[THEN iffD1])
   998 apply (drule distinct_remdups [THEN distinct_remdups
   999       [THEN set_eq_iff_mset_eq_distinct [THEN iffD2]]])
  1000 apply simp
  1001 done
  1002 
  1003 lemma mset_compl_union [simp]: "mset [x\<leftarrow>xs. P x] + mset [x\<leftarrow>xs. \<not>P x] = mset xs"
  1004   by (induct xs) (auto simp: ac_simps)
  1005 
  1006 lemma nth_mem_mset: "i < length ls \<Longrightarrow> (ls ! i) \<in># mset ls"
  1007 proof (induct ls arbitrary: i)
  1008   case Nil
  1009   then show ?case by simp
  1010 next
  1011   case Cons
  1012   then show ?case by (cases i) auto
  1013 qed
  1014 
  1015 lemma mset_remove1[simp]: "mset (remove1 a xs) = mset xs - {#a#}"
  1016   by (induct xs) (auto simp add: multiset_eq_iff)
  1017 
  1018 lemma mset_eq_length:
  1019   assumes "mset xs = mset ys"
  1020   shows "length xs = length ys"
  1021   using assms by (metis size_mset)
  1022 
  1023 lemma mset_eq_length_filter:
  1024   assumes "mset xs = mset ys"
  1025   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1026   using assms by (metis count_mset)
  1027 
  1028 lemma fold_multiset_equiv:
  1029   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1030     and equiv: "mset xs = mset ys"
  1031   shows "List.fold f xs = List.fold f ys"
  1032   using f equiv [symmetric]
  1033 proof (induct xs arbitrary: ys)
  1034   case Nil
  1035   then show ?case by simp
  1036 next
  1037   case (Cons x xs)
  1038   then have *: "set ys = set (x # xs)"
  1039     by (blast dest: mset_eq_setD)
  1040   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1041     by (rule Cons.prems(1)) (simp_all add: *)
  1042   moreover from * have "x \<in> set ys"
  1043     by simp
  1044   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x"
  1045     by (fact fold_remove1_split)
  1046   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)"
  1047     by (auto intro: Cons.hyps)
  1048   ultimately show ?case by simp
  1049 qed
  1050 
  1051 lemma mset_insort [simp]: "mset (insort x xs) = mset xs + {#x#}"
  1052   by (induct xs) (simp_all add: ac_simps)
  1053 
  1054 lemma mset_map: "mset (map f xs) = image_mset f (mset xs)"
  1055   by (induct xs) simp_all
  1056 
  1057 global_interpretation mset_set: folding "\<lambda>x M. {#x#} + M" "{#}"
  1058   defines mset_set = "folding.F (\<lambda>x M. {#x#} + M) {#}"
  1059   by standard (simp add: fun_eq_iff ac_simps)
  1060 
  1061 lemma count_mset_set [simp]:
  1062   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (mset_set A) x = 1" (is "PROP ?P")
  1063   "\<not> finite A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?Q")
  1064   "x \<notin> A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?R")
  1065 proof -
  1066   have *: "count (mset_set A) x = 0" if "x \<notin> A" for A
  1067   proof (cases "finite A")
  1068     case False then show ?thesis by simp
  1069   next
  1070     case True from True \<open>x \<notin> A\<close> show ?thesis by (induct A) auto
  1071   qed
  1072   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1073   by (auto elim!: Set.set_insert)
  1074 qed \<comment> \<open>TODO: maybe define @{const mset_set} also in terms of @{const Abs_multiset}\<close>
  1075 
  1076 lemma elem_mset_set[simp, intro]: "finite A \<Longrightarrow> x \<in># mset_set A \<longleftrightarrow> x \<in> A"
  1077   by (induct A rule: finite_induct) simp_all
  1078 
  1079 context linorder
  1080 begin
  1081 
  1082 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1083 where
  1084   "sorted_list_of_multiset M = fold_mset insort [] M"
  1085 
  1086 lemma sorted_list_of_multiset_empty [simp]:
  1087   "sorted_list_of_multiset {#} = []"
  1088   by (simp add: sorted_list_of_multiset_def)
  1089 
  1090 lemma sorted_list_of_multiset_singleton [simp]:
  1091   "sorted_list_of_multiset {#x#} = [x]"
  1092 proof -
  1093   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1094   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1095 qed
  1096 
  1097 lemma sorted_list_of_multiset_insert [simp]:
  1098   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1099 proof -
  1100   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1101   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1102 qed
  1103 
  1104 end
  1105 
  1106 lemma mset_sorted_list_of_multiset [simp]:
  1107   "mset (sorted_list_of_multiset M) = M"
  1108 by (induct M) simp_all
  1109 
  1110 lemma sorted_list_of_multiset_mset [simp]:
  1111   "sorted_list_of_multiset (mset xs) = sort xs"
  1112 by (induct xs) simp_all
  1113 
  1114 lemma finite_set_mset_mset_set[simp]:
  1115   "finite A \<Longrightarrow> set_mset (mset_set A) = A"
  1116 by (induct A rule: finite_induct) simp_all
  1117 
  1118 lemma infinite_set_mset_mset_set:
  1119   "\<not> finite A \<Longrightarrow> set_mset (mset_set A) = {}"
  1120 by simp
  1121 
  1122 lemma set_sorted_list_of_multiset [simp]:
  1123   "set (sorted_list_of_multiset M) = set_mset M"
  1124 by (induct M) (simp_all add: set_insort)
  1125 
  1126 lemma sorted_list_of_mset_set [simp]:
  1127   "sorted_list_of_multiset (mset_set A) = sorted_list_of_set A"
  1128 by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1129 
  1130 
  1131 subsection \<open>Replicate operation\<close>
  1132 
  1133 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
  1134   "replicate_mset n x = ((op + {#x#}) ^^ n) {#}"
  1135 
  1136 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
  1137   unfolding replicate_mset_def by simp
  1138 
  1139 lemma replicate_mset_Suc[simp]: "replicate_mset (Suc n) x = replicate_mset n x + {#x#}"
  1140   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
  1141 
  1142 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  1143   unfolding replicate_mset_def by (induct n) simp_all
  1144 
  1145 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
  1146   unfolding replicate_mset_def by (induct n) simp_all
  1147 
  1148 lemma set_mset_replicate_mset_subset[simp]: "set_mset (replicate_mset n x) = (if n = 0 then {} else {x})"
  1149   by (auto split: if_splits)
  1150 
  1151 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  1152   by (induct n, simp_all)
  1153 
  1154 lemma count_le_replicate_mset_le: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<le># M"
  1155   by (auto simp add: assms mset_less_eqI) (metis count_replicate_mset subseteq_mset_def)
  1156 
  1157 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  1158   by (induct D) simp_all
  1159 
  1160 lemma replicate_count_mset_eq_filter_eq:
  1161   "replicate (count (mset xs) k) k = filter (HOL.eq k) xs"
  1162   by (induct xs) auto
  1163 
  1164 
  1165 subsection \<open>Big operators\<close>
  1166 
  1167 no_notation times (infixl "*" 70)
  1168 no_notation Groups.one ("1")
  1169 
  1170 locale comm_monoid_mset = comm_monoid
  1171 begin
  1172 
  1173 definition F :: "'a multiset \<Rightarrow> 'a"
  1174   where eq_fold: "F M = fold_mset f 1 M"
  1175 
  1176 lemma empty [simp]: "F {#} = 1"
  1177   by (simp add: eq_fold)
  1178 
  1179 lemma singleton [simp]: "F {#x#} = x"
  1180 proof -
  1181   interpret comp_fun_commute
  1182     by standard (simp add: fun_eq_iff left_commute)
  1183   show ?thesis by (simp add: eq_fold)
  1184 qed
  1185 
  1186 lemma union [simp]: "F (M + N) = F M * F N"
  1187 proof -
  1188   interpret comp_fun_commute f
  1189     by standard (simp add: fun_eq_iff left_commute)
  1190   show ?thesis
  1191     by (induct N) (simp_all add: left_commute eq_fold)
  1192 qed
  1193 
  1194 end
  1195 
  1196 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + :: 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  1197   by standard (simp add: add_ac comp_def)
  1198 
  1199 declare comp_fun_commute.fold_mset_insert[OF comp_fun_commute_plus_mset, simp]
  1200 
  1201 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  1202   by (induct NN) auto
  1203 
  1204 notation times (infixl "*" 70)
  1205 notation Groups.one ("1")
  1206 
  1207 context comm_monoid_add
  1208 begin
  1209 
  1210 sublocale msetsum: comm_monoid_mset plus 0
  1211   defines msetsum = msetsum.F ..
  1212 
  1213 lemma (in semiring_1) msetsum_replicate_mset [simp]:
  1214   "msetsum (replicate_mset n a) = of_nat n * a"
  1215   by (induct n) (simp_all add: algebra_simps)
  1216 
  1217 lemma setsum_unfold_msetsum:
  1218   "setsum f A = msetsum (image_mset f (mset_set A))"
  1219   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1220 
  1221 end
  1222 
  1223 lemma msetsum_diff:
  1224   fixes M N :: "('a :: ordered_cancel_comm_monoid_diff) multiset"
  1225   shows "N \<le># M \<Longrightarrow> msetsum (M - N) = msetsum M - msetsum N"
  1226   by (metis add_diff_cancel_right' msetsum.union subset_mset.diff_add)
  1227 
  1228 lemma size_eq_msetsum: "size M = msetsum (image_mset (\<lambda>_. 1) M)"
  1229 proof (induct M)
  1230   case empty then show ?case by simp
  1231 next
  1232   case (add M x) then show ?case
  1233     by (cases "x \<in> set_mset M")
  1234       (simp_all del: mem_set_mset_iff add: size_multiset_overloaded_eq setsum.distrib setsum.delta' insert_absorb, simp)
  1235 qed
  1236 
  1237 
  1238 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset" where
  1239   "Union_mset MM \<equiv> msetsum MM"
  1240 
  1241 notation (xsymbols) Union_mset ("\<Union>#_" [900] 900)
  1242 
  1243 lemma set_mset_Union_mset[simp]: "set_mset (\<Union># MM) = (\<Union>M \<in> set_mset MM. set_mset M)"
  1244   by (induct MM) auto
  1245 
  1246 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  1247   by (induct MM) auto
  1248 
  1249 syntax
  1250   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1251       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1252 syntax (xsymbols)
  1253   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1254       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1255 translations
  1256   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
  1257 
  1258 context comm_monoid_mult
  1259 begin
  1260 
  1261 sublocale msetprod: comm_monoid_mset times 1
  1262   defines msetprod = msetprod.F ..
  1263 
  1264 lemma msetprod_empty:
  1265   "msetprod {#} = 1"
  1266   by (fact msetprod.empty)
  1267 
  1268 lemma msetprod_singleton:
  1269   "msetprod {#x#} = x"
  1270   by (fact msetprod.singleton)
  1271 
  1272 lemma msetprod_Un:
  1273   "msetprod (A + B) = msetprod A * msetprod B"
  1274   by (fact msetprod.union)
  1275 
  1276 lemma msetprod_replicate_mset [simp]:
  1277   "msetprod (replicate_mset n a) = a ^ n"
  1278   by (induct n) (simp_all add: ac_simps)
  1279 
  1280 lemma setprod_unfold_msetprod:
  1281   "setprod f A = msetprod (image_mset f (mset_set A))"
  1282   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1283 
  1284 lemma msetprod_multiplicity:
  1285   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_mset M)"
  1286   by (simp add: fold_mset_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1287 
  1288 end
  1289 
  1290 syntax
  1291   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1292       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1293 syntax (xsymbols)
  1294   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1295       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1296 translations
  1297   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
  1298 
  1299 lemma (in comm_semiring_1) dvd_msetprod:
  1300   assumes "x \<in># A"
  1301   shows "x dvd msetprod A"
  1302 proof -
  1303   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1304   then obtain B where "A = B + {#x#}" ..
  1305   then show ?thesis by simp
  1306 qed
  1307 
  1308 
  1309 subsection \<open>Alternative representations\<close>
  1310 
  1311 subsubsection \<open>Lists\<close>
  1312 
  1313 context linorder
  1314 begin
  1315 
  1316 lemma mset_insort [simp]:
  1317   "mset (insort_key k x xs) = {#x#} + mset xs"
  1318   by (induct xs) (simp_all add: ac_simps)
  1319 
  1320 lemma mset_sort [simp]:
  1321   "mset (sort_key k xs) = mset xs"
  1322   by (induct xs) (simp_all add: ac_simps)
  1323 
  1324 text \<open>
  1325   This lemma shows which properties suffice to show that a function
  1326   \<open>f\<close> with \<open>f xs = ys\<close> behaves like sort.
  1327 \<close>
  1328 
  1329 lemma properties_for_sort_key:
  1330   assumes "mset ys = mset xs"
  1331     and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1332     and "sorted (map f ys)"
  1333   shows "sort_key f xs = ys"
  1334   using assms
  1335 proof (induct xs arbitrary: ys)
  1336   case Nil then show ?case by simp
  1337 next
  1338   case (Cons x xs)
  1339   from Cons.prems(2) have
  1340     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1341     by (simp add: filter_remove1)
  1342   with Cons.prems have "sort_key f xs = remove1 x ys"
  1343     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1344   moreover from Cons.prems have "x \<in> set ys"
  1345     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1346   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1347 qed
  1348 
  1349 lemma properties_for_sort:
  1350   assumes multiset: "mset ys = mset xs"
  1351     and "sorted ys"
  1352   shows "sort xs = ys"
  1353 proof (rule properties_for_sort_key)
  1354   from multiset show "mset ys = mset xs" .
  1355   from \<open>sorted ys\<close> show "sorted (map (\<lambda>x. x) ys)" by simp
  1356   from multiset have "length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)" for k
  1357     by (rule mset_eq_length_filter)
  1358   then have "replicate (length (filter (\<lambda>y. k = y) ys)) k =
  1359     replicate (length (filter (\<lambda>x. k = x) xs)) k" for k
  1360     by simp
  1361   then show "k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs" for k
  1362     by (simp add: replicate_length_filter)
  1363 qed
  1364 
  1365 lemma sort_key_inj_key_eq:
  1366   assumes mset_equal: "mset xs = mset ys"
  1367     and "inj_on f (set xs)"
  1368     and "sorted (map f ys)"
  1369   shows "sort_key f xs = ys"
  1370 proof (rule properties_for_sort_key)
  1371   from mset_equal
  1372   show "mset ys = mset xs" by simp
  1373   from \<open>sorted (map f ys)\<close>
  1374   show "sorted (map f ys)" .
  1375   show "[x\<leftarrow>ys . f k = f x] = [x\<leftarrow>xs . f k = f x]" if "k \<in> set ys" for k
  1376   proof -
  1377     from mset_equal
  1378     have set_equal: "set xs = set ys" by (rule mset_eq_setD)
  1379     with that have "insert k (set ys) = set ys" by auto
  1380     with \<open>inj_on f (set xs)\<close> have inj: "inj_on f (insert k (set ys))"
  1381       by (simp add: set_equal)
  1382     from inj have "[x\<leftarrow>ys . f k = f x] = filter (HOL.eq k) ys"
  1383       by (auto intro!: inj_on_filter_key_eq)
  1384     also have "\<dots> = replicate (count (mset ys) k) k"
  1385       by (simp add: replicate_count_mset_eq_filter_eq)
  1386     also have "\<dots> = replicate (count (mset xs) k) k"
  1387       using mset_equal by simp
  1388     also have "\<dots> = filter (HOL.eq k) xs"
  1389       by (simp add: replicate_count_mset_eq_filter_eq)
  1390     also have "\<dots> = [x\<leftarrow>xs . f k = f x]"
  1391       using inj by (auto intro!: inj_on_filter_key_eq [symmetric] simp add: set_equal)
  1392     finally show ?thesis .
  1393   qed
  1394 qed
  1395 
  1396 lemma sort_key_eq_sort_key:
  1397   assumes "mset xs = mset ys"
  1398     and "inj_on f (set xs)"
  1399   shows "sort_key f xs = sort_key f ys"
  1400   by (rule sort_key_inj_key_eq) (simp_all add: assms)
  1401 
  1402 lemma sort_key_by_quicksort:
  1403   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1404     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1405     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1406 proof (rule properties_for_sort_key)
  1407   show "mset ?rhs = mset ?lhs"
  1408     by (rule multiset_eqI) (auto simp add: mset_filter)
  1409   show "sorted (map f ?rhs)"
  1410     by (auto simp add: sorted_append intro: sorted_map_same)
  1411 next
  1412   fix l
  1413   assume "l \<in> set ?rhs"
  1414   let ?pivot = "f (xs ! (length xs div 2))"
  1415   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1416   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1417     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1418   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1419   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1420   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1421     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1422   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1423   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1424   proof (cases "f l" ?pivot rule: linorder_cases)
  1425     case less
  1426     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1427     with less show ?thesis
  1428       by (simp add: filter_sort [symmetric] ** ***)
  1429   next
  1430     case equal then show ?thesis
  1431       by (simp add: * less_le)
  1432   next
  1433     case greater
  1434     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1435     with greater show ?thesis
  1436       by (simp add: filter_sort [symmetric] ** ***)
  1437   qed
  1438 qed
  1439 
  1440 lemma sort_by_quicksort:
  1441   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1442     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1443     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1444   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1445 
  1446 text \<open>A stable parametrized quicksort\<close>
  1447 
  1448 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1449   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1450 
  1451 lemma part_code [code]:
  1452   "part f pivot [] = ([], [], [])"
  1453   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1454      if x' < pivot then (x # lts, eqs, gts)
  1455      else if x' > pivot then (lts, eqs, x # gts)
  1456      else (lts, x # eqs, gts))"
  1457   by (auto simp add: part_def Let_def split_def)
  1458 
  1459 lemma sort_key_by_quicksort_code [code]:
  1460   "sort_key f xs =
  1461     (case xs of
  1462       [] \<Rightarrow> []
  1463     | [x] \<Rightarrow> xs
  1464     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1465     | _ \<Rightarrow>
  1466         let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1467         in sort_key f lts @ eqs @ sort_key f gts)"
  1468 proof (cases xs)
  1469   case Nil then show ?thesis by simp
  1470 next
  1471   case (Cons _ ys) note hyps = Cons show ?thesis
  1472   proof (cases ys)
  1473     case Nil with hyps show ?thesis by simp
  1474   next
  1475     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1476     proof (cases zs)
  1477       case Nil with hyps show ?thesis by auto
  1478     next
  1479       case Cons
  1480       from sort_key_by_quicksort [of f xs]
  1481       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1482         in sort_key f lts @ eqs @ sort_key f gts)"
  1483       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1484       with hyps Cons show ?thesis by (simp only: list.cases)
  1485     qed
  1486   qed
  1487 qed
  1488 
  1489 end
  1490 
  1491 hide_const (open) part
  1492 
  1493 lemma mset_remdups_le: "mset (remdups xs) \<le># mset xs"
  1494   by (induct xs) (auto intro: subset_mset.order_trans)
  1495 
  1496 lemma mset_update:
  1497   "i < length ls \<Longrightarrow> mset (ls[i := v]) = mset ls - {#ls ! i#} + {#v#}"
  1498 proof (induct ls arbitrary: i)
  1499   case Nil then show ?case by simp
  1500 next
  1501   case (Cons x xs)
  1502   show ?case
  1503   proof (cases i)
  1504     case 0 then show ?thesis by simp
  1505   next
  1506     case (Suc i')
  1507     with Cons show ?thesis
  1508       apply simp
  1509       apply (subst add.assoc)
  1510       apply (subst add.commute [of "{#v#}" "{#x#}"])
  1511       apply (subst add.assoc [symmetric])
  1512       apply simp
  1513       apply (rule mset_le_multiset_union_diff_commute)
  1514       apply (simp add: mset_le_single nth_mem_mset)
  1515       done
  1516   qed
  1517 qed
  1518 
  1519 lemma mset_swap:
  1520   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1521     mset (ls[j := ls ! i, i := ls ! j]) = mset ls"
  1522   by (cases "i = j") (simp_all add: mset_update nth_mem_mset)
  1523 
  1524 
  1525 subsection \<open>The multiset order\<close>
  1526 
  1527 subsubsection \<open>Well-foundedness\<close>
  1528 
  1529 definition mult1 :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1530   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1531       (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r)}"
  1532 
  1533 definition mult :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1534   "mult r = (mult1 r)\<^sup>+"
  1535 
  1536 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1537 by (simp add: mult1_def)
  1538 
  1539 lemma less_add:
  1540   assumes mult1: "(N, M0 + {#a#}) \<in> mult1 r"
  1541   shows
  1542     "(\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1543      (\<exists>K. (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r) \<and> N = M0 + K)"
  1544 proof -
  1545   let ?r = "\<lambda>K a. \<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r"
  1546   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1547   obtain a' M0' K where M0: "M0 + {#a#} = M0' + {#a'#}"
  1548     and N: "N = M0' + K"
  1549     and r: "?r K a'"
  1550     using mult1 unfolding mult1_def by auto
  1551   show ?thesis (is "?case1 \<or> ?case2")
  1552   proof -
  1553     from M0 consider "M0 = M0'" "a = a'"
  1554       | K' where "M0 = K' + {#a'#}" "M0' = K' + {#a#}"
  1555       by atomize_elim (simp only: add_eq_conv_ex)
  1556     then show ?thesis
  1557     proof cases
  1558       case 1
  1559       with N r have "?r K a \<and> N = M0 + K" by simp
  1560       then have ?case2 ..
  1561       then show ?thesis ..
  1562     next
  1563       case 2
  1564       from N 2(2) have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
  1565       with r 2(1) have "?R (K' + K) M0" by blast
  1566       with n have ?case1 by (simp add: mult1_def)
  1567       then show ?thesis ..
  1568     qed
  1569   qed
  1570 qed
  1571 
  1572 lemma all_accessible:
  1573   assumes "wf r"
  1574   shows "\<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1575 proof
  1576   let ?R = "mult1 r"
  1577   let ?W = "Wellfounded.acc ?R"
  1578   {
  1579     fix M M0 a
  1580     assume M0: "M0 \<in> ?W"
  1581       and wf_hyp: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1582       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W"
  1583     have "M0 + {#a#} \<in> ?W"
  1584     proof (rule accI [of "M0 + {#a#}"])
  1585       fix N
  1586       assume "(N, M0 + {#a#}) \<in> ?R"
  1587       then consider M where "(M, M0) \<in> ?R" "N = M + {#a#}"
  1588         | K where "\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r" "N = M0 + K"
  1589         by atomize_elim (rule less_add)
  1590       then show "N \<in> ?W"
  1591       proof cases
  1592         case 1
  1593         from acc_hyp have "(M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W" ..
  1594         from this and \<open>(M, M0) \<in> ?R\<close> have "M + {#a#} \<in> ?W" ..
  1595         then show "N \<in> ?W" by (simp only: \<open>N = M + {#a#}\<close>)
  1596       next
  1597         case 2
  1598         from this(1) have "M0 + K \<in> ?W"
  1599         proof (induct K)
  1600           case empty
  1601           from M0 show "M0 + {#} \<in> ?W" by simp
  1602         next
  1603           case (add K x)
  1604           from add.prems have "(x, a) \<in> r" by simp
  1605           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1606           moreover from add have "M0 + K \<in> ?W" by simp
  1607           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1608           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
  1609         qed
  1610         then show "N \<in> ?W" by (simp only: 2(2))
  1611       qed
  1612     qed
  1613   } note tedious_reasoning = this
  1614 
  1615   show "M \<in> ?W" for M
  1616   proof (induct M)
  1617     show "{#} \<in> ?W"
  1618     proof (rule accI)
  1619       fix b assume "(b, {#}) \<in> ?R"
  1620       with not_less_empty show "b \<in> ?W" by contradiction
  1621     qed
  1622 
  1623     fix M a assume "M \<in> ?W"
  1624     from \<open>wf r\<close> have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1625     proof induct
  1626       fix a
  1627       assume r: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1628       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1629       proof
  1630         fix M assume "M \<in> ?W"
  1631         then show "M + {#a#} \<in> ?W"
  1632           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1633       qed
  1634     qed
  1635     from this and \<open>M \<in> ?W\<close> show "M + {#a#} \<in> ?W" ..
  1636   qed
  1637 qed
  1638 
  1639 theorem wf_mult1: "wf r \<Longrightarrow> wf (mult1 r)"
  1640 by (rule acc_wfI) (rule all_accessible)
  1641 
  1642 theorem wf_mult: "wf r \<Longrightarrow> wf (mult r)"
  1643 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1644 
  1645 
  1646 subsubsection \<open>Closure-free presentation\<close>
  1647 
  1648 text \<open>One direction.\<close>
  1649 
  1650 lemma mult_implies_one_step:
  1651   "trans r \<Longrightarrow> (M, N) \<in> mult r \<Longrightarrow>
  1652     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1653     (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)"
  1654 apply (unfold mult_def mult1_def set_mset_def)
  1655 apply (erule converse_trancl_induct, clarify)
  1656  apply (rule_tac x = M0 in exI, simp, clarify)
  1657 apply (case_tac "a \<in># K")
  1658  apply (rule_tac x = I in exI)
  1659  apply (simp (no_asm))
  1660  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1661  apply (simp (no_asm_simp) add: add.assoc [symmetric])
  1662  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong)
  1663  apply (simp add: diff_union_single_conv)
  1664  apply (simp (no_asm_use) add: trans_def)
  1665  apply blast
  1666 apply (subgoal_tac "a \<in># I")
  1667  apply (rule_tac x = "I - {#a#}" in exI)
  1668  apply (rule_tac x = "J + {#a#}" in exI)
  1669  apply (rule_tac x = "K + Ka" in exI)
  1670  apply (rule conjI)
  1671   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1672  apply (rule conjI)
  1673   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong, simp)
  1674   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1675  apply (simp (no_asm_use) add: trans_def)
  1676  apply blast
  1677 apply (subgoal_tac "a \<in># (M0 + {#a#})")
  1678  apply simp
  1679 apply (simp (no_asm))
  1680 done
  1681 
  1682 lemma one_step_implies_mult_aux:
  1683   "\<forall>I J K. size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)
  1684     \<longrightarrow> (I + K, I + J) \<in> mult r"
  1685 apply (induct n)
  1686  apply auto
  1687 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1688 apply (rename_tac "J'", simp)
  1689 apply (erule notE, auto)
  1690 apply (case_tac "J' = {#}")
  1691  apply (simp add: mult_def)
  1692  apply (rule r_into_trancl)
  1693  apply (simp add: mult1_def set_mset_def, blast)
  1694 txt \<open>Now we know @{term "J' \<noteq> {#}"}.\<close>
  1695 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1696 apply (erule_tac P = "\<forall>k \<in> set_mset K. P k" for P in rev_mp)
  1697 apply (erule ssubst)
  1698 apply (simp add: Ball_def, auto)
  1699 apply (subgoal_tac
  1700   "((I + {# x \<in># K. (x, a) \<in> r #}) + {# x \<in># K. (x, a) \<notin> r #},
  1701     (I + {# x \<in># K. (x, a) \<in> r #}) + J') \<in> mult r")
  1702  prefer 2
  1703  apply force
  1704 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
  1705 apply (erule trancl_trans)
  1706 apply (rule r_into_trancl)
  1707 apply (simp add: mult1_def set_mset_def)
  1708 apply (rule_tac x = a in exI)
  1709 apply (rule_tac x = "I + J'" in exI)
  1710 apply (simp add: ac_simps)
  1711 done
  1712 
  1713 lemma one_step_implies_mult:
  1714   "trans r \<Longrightarrow> J \<noteq> {#} \<Longrightarrow> \<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r
  1715     \<Longrightarrow> (I + K, I + J) \<in> mult r"
  1716 using one_step_implies_mult_aux by blast
  1717 
  1718 
  1719 subsubsection \<open>Partial-order properties\<close>
  1720 
  1721 definition less_multiset :: "'a::order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<#" 50) where
  1722   "M' #<# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1723 
  1724 definition le_multiset :: "'a::order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<=#" 50) where
  1725   "M' #<=# M \<longleftrightarrow> M' #<# M \<or> M' = M"
  1726 
  1727 notation (xsymbols) less_multiset (infix "#\<subset>#" 50)
  1728 notation (xsymbols) le_multiset (infix "#\<subseteq>#" 50)
  1729 
  1730 interpretation multiset_order: order le_multiset less_multiset
  1731 proof -
  1732   have irrefl: "\<not> M #\<subset># M" for M :: "'a multiset"
  1733   proof
  1734     assume "M #\<subset># M"
  1735     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1736     have "trans {(x'::'a, x). x' < x}"
  1737       by (rule transI) simp
  1738     moreover note MM
  1739     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1740       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
  1741       by (rule mult_implies_one_step)
  1742     then obtain I J K where "M = I + J" and "M = I + K"
  1743       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
  1744     then have *: "K \<noteq> {#}" and **: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
  1745     have "finite (set_mset K)" by simp
  1746     moreover note **
  1747     ultimately have "set_mset K = {}"
  1748       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1749     with * show False by simp
  1750   qed
  1751   have trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># N" for K M N :: "'a multiset"
  1752     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1753   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1754     by standard (auto simp add: le_multiset_def irrefl dest: trans)
  1755 qed
  1756 
  1757 lemma mult_less_irrefl [elim!]:
  1758   fixes M :: "'a::order multiset"
  1759   shows "M #\<subset># M \<Longrightarrow> R"
  1760   by simp
  1761 
  1762 
  1763 subsubsection \<open>Monotonicity of multiset union\<close>
  1764 
  1765 lemma mult1_union: "(B, D) \<in> mult1 r \<Longrightarrow> (C + B, C + D) \<in> mult1 r"
  1766 apply (unfold mult1_def)
  1767 apply auto
  1768 apply (rule_tac x = a in exI)
  1769 apply (rule_tac x = "C + M0" in exI)
  1770 apply (simp add: add.assoc)
  1771 done
  1772 
  1773 lemma union_less_mono2: "B #\<subset># D \<Longrightarrow> C + B #\<subset># C + (D::'a::order multiset)"
  1774 apply (unfold less_multiset_def mult_def)
  1775 apply (erule trancl_induct)
  1776  apply (blast intro: mult1_union)
  1777 apply (blast intro: mult1_union trancl_trans)
  1778 done
  1779 
  1780 lemma union_less_mono1: "B #\<subset># D \<Longrightarrow> B + C #\<subset># D + (C::'a::order multiset)"
  1781 apply (subst add.commute [of B C])
  1782 apply (subst add.commute [of D C])
  1783 apply (erule union_less_mono2)
  1784 done
  1785 
  1786 lemma union_less_mono:
  1787   fixes A B C D :: "'a::order multiset"
  1788   shows "A #\<subset># C \<Longrightarrow> B #\<subset># D \<Longrightarrow> A + B #\<subset># C + D"
  1789   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1790 
  1791 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1792   by standard (auto simp add: le_multiset_def intro: union_less_mono2)
  1793 
  1794 
  1795 subsubsection \<open>Termination proofs with multiset orders\<close>
  1796 
  1797 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1798   and multi_member_this: "x \<in># {# x #} + XS"
  1799   and multi_member_last: "x \<in># {# x #}"
  1800   by auto
  1801 
  1802 definition "ms_strict = mult pair_less"
  1803 definition "ms_weak = ms_strict \<union> Id"
  1804 
  1805 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1806 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1807 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1808 
  1809 lemma smsI:
  1810   "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1811   unfolding ms_strict_def
  1812 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1813 
  1814 lemma wmsI:
  1815   "(set_mset A, set_mset B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1816   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1817 unfolding ms_weak_def ms_strict_def
  1818 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1819 
  1820 inductive pw_leq
  1821 where
  1822   pw_leq_empty: "pw_leq {#} {#}"
  1823 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1824 
  1825 lemma pw_leq_lstep:
  1826   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1827 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1828 
  1829 lemma pw_leq_split:
  1830   assumes "pw_leq X Y"
  1831   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1832   using assms
  1833 proof induct
  1834   case pw_leq_empty thus ?case by auto
  1835 next
  1836   case (pw_leq_step x y X Y)
  1837   then obtain A B Z where
  1838     [simp]: "X = A + Z" "Y = B + Z"
  1839       and 1[simp]: "(set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  1840     by auto
  1841   from pw_leq_step consider "x = y" | "(x, y) \<in> pair_less"
  1842     unfolding pair_leq_def by auto
  1843   thus ?case
  1844   proof cases
  1845     case [simp]: 1
  1846     have "{#x#} + X = A + ({#y#}+Z) \<and> {#y#} + Y = B + ({#y#}+Z) \<and>
  1847       ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1848       by (auto simp: ac_simps)
  1849     thus ?thesis by blast
  1850   next
  1851     case 2
  1852     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1853     have "{#x#} + X = ?A' + Z"
  1854       "{#y#} + Y = ?B' + Z"
  1855       by (auto simp add: ac_simps)
  1856     moreover have
  1857       "(set_mset ?A', set_mset ?B') \<in> max_strict"
  1858       using 1 2 unfolding max_strict_def
  1859       by (auto elim!: max_ext.cases)
  1860     ultimately show ?thesis by blast
  1861   qed
  1862 qed
  1863 
  1864 lemma
  1865   assumes pwleq: "pw_leq Z Z'"
  1866   shows ms_strictI: "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1867     and ms_weakI1:  "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1868     and ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1869 proof -
  1870   from pw_leq_split[OF pwleq]
  1871   obtain A' B' Z''
  1872     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1873     and mx_or_empty: "(set_mset A', set_mset B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1874     by blast
  1875   {
  1876     assume max: "(set_mset A, set_mset B) \<in> max_strict"
  1877     from mx_or_empty
  1878     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1879     proof
  1880       assume max': "(set_mset A', set_mset B') \<in> max_strict"
  1881       with max have "(set_mset (A + A'), set_mset (B + B')) \<in> max_strict"
  1882         by (auto simp: max_strict_def intro: max_ext_additive)
  1883       thus ?thesis by (rule smsI)
  1884     next
  1885       assume [simp]: "A' = {#} \<and> B' = {#}"
  1886       show ?thesis by (rule smsI) (auto intro: max)
  1887     qed
  1888     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add: ac_simps)
  1889     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1890   }
  1891   from mx_or_empty
  1892   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1893   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
  1894 qed
  1895 
  1896 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1897 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1898 and nonempty_single: "{# x #} \<noteq> {#}"
  1899 by auto
  1900 
  1901 setup \<open>
  1902   let
  1903     fun msetT T = Type (@{type_name multiset}, [T]);
  1904 
  1905     fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1906       | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1907       | mk_mset T (x :: xs) =
  1908             Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1909                   mk_mset T [x] $ mk_mset T xs
  1910 
  1911     fun mset_member_tac ctxt m i =
  1912       if m <= 0 then
  1913         resolve_tac ctxt @{thms multi_member_this} i ORELSE
  1914         resolve_tac ctxt @{thms multi_member_last} i
  1915       else
  1916         resolve_tac ctxt @{thms multi_member_skip} i THEN mset_member_tac ctxt (m - 1) i
  1917 
  1918     fun mset_nonempty_tac ctxt =
  1919       resolve_tac ctxt @{thms nonempty_plus} ORELSE'
  1920       resolve_tac ctxt @{thms nonempty_single}
  1921 
  1922     fun regroup_munion_conv ctxt =
  1923       Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  1924         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  1925 
  1926     fun unfold_pwleq_tac ctxt i =
  1927       (resolve_tac ctxt @{thms pw_leq_step} i THEN (fn st => unfold_pwleq_tac ctxt (i + 1) st))
  1928         ORELSE (resolve_tac ctxt @{thms pw_leq_lstep} i)
  1929         ORELSE (resolve_tac ctxt @{thms pw_leq_empty} i)
  1930 
  1931     val set_mset_simps = [@{thm set_mset_empty}, @{thm set_mset_single}, @{thm set_mset_union},
  1932                         @{thm Un_insert_left}, @{thm Un_empty_left}]
  1933   in
  1934     ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  1935     {
  1936       msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1937       mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1938       mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_mset_simps,
  1939       smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1940       reduction_pair = @{thm ms_reduction_pair}
  1941     })
  1942   end
  1943 \<close>
  1944 
  1945 
  1946 subsection \<open>Legacy theorem bindings\<close>
  1947 
  1948 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1949 
  1950 lemma union_commute: "M + N = N + (M::'a multiset)"
  1951   by (fact add.commute)
  1952 
  1953 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1954   by (fact add.assoc)
  1955 
  1956 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1957   by (fact add.left_commute)
  1958 
  1959 lemmas union_ac = union_assoc union_commute union_lcomm
  1960 
  1961 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1962   by (fact add_right_cancel)
  1963 
  1964 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1965   by (fact add_left_cancel)
  1966 
  1967 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1968   by (fact add_left_imp_eq)
  1969 
  1970 lemma mset_less_trans: "(M::'a multiset) <# K \<Longrightarrow> K <# N \<Longrightarrow> M <# N"
  1971   by (fact subset_mset.less_trans)
  1972 
  1973 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1974   by (fact subset_mset.inf.commute)
  1975 
  1976 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1977   by (fact subset_mset.inf.assoc [symmetric])
  1978 
  1979 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1980   by (fact subset_mset.inf.left_commute)
  1981 
  1982 lemmas multiset_inter_ac =
  1983   multiset_inter_commute
  1984   multiset_inter_assoc
  1985   multiset_inter_left_commute
  1986 
  1987 lemma mult_less_not_refl: "\<not> M #\<subset># (M::'a::order multiset)"
  1988   by (fact multiset_order.less_irrefl)
  1989 
  1990 lemma mult_less_trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># (N::'a::order multiset)"
  1991   by (fact multiset_order.less_trans)
  1992 
  1993 lemma mult_less_not_sym: "M #\<subset># N \<Longrightarrow> \<not> N #\<subset># (M::'a::order multiset)"
  1994   by (fact multiset_order.less_not_sym)
  1995 
  1996 lemma mult_less_asym: "M #\<subset># N \<Longrightarrow> (\<not> P \<Longrightarrow> N #\<subset># (M::'a::order multiset)) \<Longrightarrow> P"
  1997   by (fact multiset_order.less_asym)
  1998 
  1999 declaration \<open>
  2000   let
  2001     fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T])) (Const _ $ t') =
  2002           let
  2003             val (maybe_opt, ps) =
  2004               Nitpick_Model.dest_plain_fun t'
  2005               ||> op ~~
  2006               ||> map (apsnd (snd o HOLogic.dest_number))
  2007             fun elems_for t =
  2008               (case AList.lookup (op =) ps t of
  2009                 SOME n => replicate n t
  2010               | NONE => [Const (maybe_name, elem_T --> elem_T) $ t])
  2011           in
  2012             (case maps elems_for (all_values elem_T) @
  2013                  (if maybe_opt then [Const (Nitpick_Model.unrep_mixfix (), elem_T)] else []) of
  2014               [] => Const (@{const_name zero_class.zero}, T)
  2015             | ts =>
  2016                 foldl1 (fn (t1, t2) =>
  2017                     Const (@{const_name plus_class.plus}, T --> T --> T) $ t1 $ t2)
  2018                   (map (curry (op $) (Const (@{const_name single}, elem_T --> T))) ts))
  2019           end
  2020       | multiset_postproc _ _ _ _ t = t
  2021   in Nitpick_Model.register_term_postprocessor @{typ "'a multiset"} multiset_postproc end
  2022 \<close>
  2023 
  2024 
  2025 subsection \<open>Naive implementation using lists\<close>
  2026 
  2027 code_datatype mset
  2028 
  2029 lemma [code]: "{#} = mset []"
  2030   by simp
  2031 
  2032 lemma [code]: "{#x#} = mset [x]"
  2033   by simp
  2034 
  2035 lemma union_code [code]: "mset xs + mset ys = mset (xs @ ys)"
  2036   by simp
  2037 
  2038 lemma [code]: "image_mset f (mset xs) = mset (map f xs)"
  2039   by (simp add: mset_map)
  2040 
  2041 lemma [code]: "filter_mset f (mset xs) = mset (filter f xs)"
  2042   by (simp add: mset_filter)
  2043 
  2044 lemma [code]: "mset xs - mset ys = mset (fold remove1 ys xs)"
  2045   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2046 
  2047 lemma [code]:
  2048   "mset xs #\<inter> mset ys =
  2049     mset (snd (fold (\<lambda>x (ys, zs).
  2050       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2051 proof -
  2052   have "\<And>zs. mset (snd (fold (\<lambda>x (ys, zs).
  2053     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2054       (mset xs #\<inter> mset ys) + mset zs"
  2055     by (induct xs arbitrary: ys)
  2056       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2057   then show ?thesis by simp
  2058 qed
  2059 
  2060 lemma [code]:
  2061   "mset xs #\<union> mset ys =
  2062     mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2063 proof -
  2064   have "\<And>zs. mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2065       (mset xs #\<union> mset ys) + mset zs"
  2066     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2067   then show ?thesis by simp
  2068 qed
  2069 
  2070 declare in_multiset_in_set [code_unfold]
  2071 
  2072 lemma [code]: "count (mset xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2073 proof -
  2074   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (mset xs) x + n"
  2075     by (induct xs) simp_all
  2076   then show ?thesis by simp
  2077 qed
  2078 
  2079 declare set_mset_mset [code]
  2080 
  2081 declare sorted_list_of_multiset_mset [code]
  2082 
  2083 lemma [code]: \<comment> \<open>not very efficient, but representation-ignorant!\<close>
  2084   "mset_set A = mset (sorted_list_of_set A)"
  2085   apply (cases "finite A")
  2086   apply simp_all
  2087   apply (induct A rule: finite_induct)
  2088   apply (simp_all add: add.commute)
  2089   done
  2090 
  2091 declare size_mset [code]
  2092 
  2093 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  2094   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2095 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  2096      None \<Rightarrow> None
  2097    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2098 
  2099 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> mset xs \<le># mset ys) \<and>
  2100   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> mset xs <# mset ys) \<and>
  2101   (ms_lesseq_impl xs ys = Some False \<longrightarrow> mset xs = mset ys)"
  2102 proof (induct xs arbitrary: ys)
  2103   case (Nil ys)
  2104   show ?case by (auto simp: mset_less_empty_nonempty)
  2105 next
  2106   case (Cons x xs ys)
  2107   show ?case
  2108   proof (cases "List.extract (op = x) ys")
  2109     case None
  2110     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2111     {
  2112       assume "mset (x # xs) \<le># mset ys"
  2113       from set_mset_mono[OF this] x have False by simp
  2114     } note nle = this
  2115     moreover
  2116     {
  2117       assume "mset (x # xs) <# mset ys"
  2118       hence "mset (x # xs) \<le># mset ys" by auto
  2119       from nle[OF this] have False .
  2120     }
  2121     ultimately show ?thesis using None by auto
  2122   next
  2123     case (Some res)
  2124     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2125     note Some = Some[unfolded res]
  2126     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2127     hence id: "mset ys = mset (ys1 @ ys2) + {#x#}"
  2128       by (auto simp: ac_simps)
  2129     show ?thesis unfolding ms_lesseq_impl.simps
  2130       unfolding Some option.simps split
  2131       unfolding id
  2132       using Cons[of "ys1 @ ys2"]
  2133       unfolding subset_mset_def subseteq_mset_def by auto
  2134   qed
  2135 qed
  2136 
  2137 lemma [code]: "mset xs \<le># mset ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2138   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2139 
  2140 lemma [code]: "mset xs <# mset ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2141   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2142 
  2143 instantiation multiset :: (equal) equal
  2144 begin
  2145 
  2146 definition
  2147   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2148 lemma [code]: "HOL.equal (mset xs) (mset ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2149   unfolding equal_multiset_def
  2150   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2151 
  2152 instance
  2153   by standard (simp add: equal_multiset_def)
  2154 
  2155 end
  2156 
  2157 lemma [code]: "msetsum (mset xs) = listsum xs"
  2158   by (induct xs) (simp_all add: add.commute)
  2159 
  2160 lemma [code]: "msetprod (mset xs) = fold times xs 1"
  2161 proof -
  2162   have "\<And>x. fold times xs x = msetprod (mset xs) * x"
  2163     by (induct xs) (simp_all add: mult.assoc)
  2164   then show ?thesis by simp
  2165 qed
  2166 
  2167 text \<open>
  2168   Exercise for the casual reader: add implementations for @{const le_multiset}
  2169   and @{const less_multiset} (multiset order).
  2170 \<close>
  2171 
  2172 text \<open>Quickcheck generators\<close>
  2173 
  2174 definition (in term_syntax)
  2175   msetify :: "'a::typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2176     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2177   [code_unfold]: "msetify xs = Code_Evaluation.valtermify mset {\<cdot>} xs"
  2178 
  2179 notation fcomp (infixl "\<circ>>" 60)
  2180 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2181 
  2182 instantiation multiset :: (random) random
  2183 begin
  2184 
  2185 definition
  2186   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2187 
  2188 instance ..
  2189 
  2190 end
  2191 
  2192 no_notation fcomp (infixl "\<circ>>" 60)
  2193 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2194 
  2195 instantiation multiset :: (full_exhaustive) full_exhaustive
  2196 begin
  2197 
  2198 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2199 where
  2200   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2201 
  2202 instance ..
  2203 
  2204 end
  2205 
  2206 hide_const (open) msetify
  2207 
  2208 
  2209 subsection \<open>BNF setup\<close>
  2210 
  2211 definition rel_mset where
  2212   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. mset xs = X \<and> mset ys = Y \<and> list_all2 R xs ys)"
  2213 
  2214 lemma mset_zip_take_Cons_drop_twice:
  2215   assumes "length xs = length ys" "j \<le> length xs"
  2216   shows "mset (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  2217     mset (zip xs ys) + {#(x, y)#}"
  2218   using assms
  2219 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  2220   case Nil
  2221   thus ?case
  2222     by simp
  2223 next
  2224   case (Cons x xs y ys)
  2225   thus ?case
  2226   proof (cases "j = 0")
  2227     case True
  2228     thus ?thesis
  2229       by simp
  2230   next
  2231     case False
  2232     then obtain k where k: "j = Suc k"
  2233       by (cases j) simp
  2234     hence "k \<le> length xs"
  2235       using Cons.prems by auto
  2236     hence "mset (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  2237       mset (zip xs ys) + {#(x, y)#}"
  2238       by (rule Cons.hyps(2))
  2239     thus ?thesis
  2240       unfolding k by (auto simp: add.commute union_lcomm)
  2241   qed
  2242 qed
  2243 
  2244 lemma ex_mset_zip_left:
  2245   assumes "length xs = length ys" "mset xs' = mset xs"
  2246   shows "\<exists>ys'. length ys' = length xs' \<and> mset (zip xs' ys') = mset (zip xs ys)"
  2247 using assms
  2248 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  2249   case Nil
  2250   thus ?case
  2251     by auto
  2252 next
  2253   case (Cons x xs y ys xs')
  2254   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  2255     by (metis Cons.prems in_set_conv_nth list.set_intros(1) mset_eq_setD)
  2256 
  2257   def xsa \<equiv> "take j xs' @ drop (Suc j) xs'"
  2258   have "mset xs' = {#x#} + mset xsa"
  2259     unfolding xsa_def using j_len nth_j
  2260     by (metis (no_types) ab_semigroup_add_class.add_ac(1) append_take_drop_id Cons_nth_drop_Suc
  2261       mset.simps(2) union_code add.commute)
  2262   hence ms_x: "mset xsa = mset xs"
  2263     by (metis Cons.prems add.commute add_right_imp_eq mset.simps(2))
  2264   then obtain ysa where
  2265     len_a: "length ysa = length xsa" and ms_a: "mset (zip xsa ysa) = mset (zip xs ys)"
  2266     using Cons.hyps(2) by blast
  2267 
  2268   def ys' \<equiv> "take j ysa @ y # drop j ysa"
  2269   have xs': "xs' = take j xsa @ x # drop j xsa"
  2270     using ms_x j_len nth_j Cons.prems xsa_def
  2271     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  2272       length_drop size_mset)
  2273   have j_len': "j \<le> length xsa"
  2274     using j_len xs' xsa_def
  2275     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  2276   have "length ys' = length xs'"
  2277     unfolding ys'_def using Cons.prems len_a ms_x
  2278     by (metis add_Suc_right append_take_drop_id length_Cons length_append mset_eq_length)
  2279   moreover have "mset (zip xs' ys') = mset (zip (x # xs) (y # ys))"
  2280     unfolding xs' ys'_def
  2281     by (rule trans[OF mset_zip_take_Cons_drop_twice])
  2282       (auto simp: len_a ms_a j_len' add.commute)
  2283   ultimately show ?case
  2284     by blast
  2285 qed
  2286 
  2287 lemma list_all2_reorder_left_invariance:
  2288   assumes rel: "list_all2 R xs ys" and ms_x: "mset xs' = mset xs"
  2289   shows "\<exists>ys'. list_all2 R xs' ys' \<and> mset ys' = mset ys"
  2290 proof -
  2291   have len: "length xs = length ys"
  2292     using rel list_all2_conv_all_nth by auto
  2293   obtain ys' where
  2294     len': "length xs' = length ys'" and ms_xy: "mset (zip xs' ys') = mset (zip xs ys)"
  2295     using len ms_x by (metis ex_mset_zip_left)
  2296   have "list_all2 R xs' ys'"
  2297     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: mset_eq_setD)
  2298   moreover have "mset ys' = mset ys"
  2299     using len len' ms_xy map_snd_zip mset_map by metis
  2300   ultimately show ?thesis
  2301     by blast
  2302 qed
  2303 
  2304 lemma ex_mset: "\<exists>xs. mset xs = X"
  2305   by (induct X) (simp, metis mset.simps(2))
  2306 
  2307 bnf "'a multiset"
  2308   map: image_mset
  2309   sets: set_mset
  2310   bd: natLeq
  2311   wits: "{#}"
  2312   rel: rel_mset
  2313 proof -
  2314   show "image_mset id = id"
  2315     by (rule image_mset.id)
  2316   show "image_mset (g \<circ> f) = image_mset g \<circ> image_mset f" for f g
  2317     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  2318   show "(\<And>z. z \<in> set_mset X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X" for f g X
  2319     by (induct X) (simp_all (no_asm),
  2320       metis One_nat_def Un_iff count_single mem_set_mset_iff set_mset_union zero_less_Suc)
  2321   show "set_mset \<circ> image_mset f = op ` f \<circ> set_mset" for f
  2322     by auto
  2323   show "card_order natLeq"
  2324     by (rule natLeq_card_order)
  2325   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  2326     by (rule natLeq_cinfinite)
  2327   show "ordLeq3 (card_of (set_mset X)) natLeq" for X
  2328     by transfer
  2329       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2330   show "rel_mset R OO rel_mset S \<le> rel_mset (R OO S)" for R S
  2331     unfolding rel_mset_def[abs_def] OO_def
  2332     apply clarify
  2333     subgoal for X Z Y xs ys' ys zs
  2334       apply (drule list_all2_reorder_left_invariance [where xs = ys' and ys = zs and xs' = ys])
  2335       apply (auto intro: list_all2_trans)
  2336       done
  2337     done
  2338   show "rel_mset R =
  2339     (BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset fst))\<inverse>\<inverse> OO
  2340     BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset snd)" for R
  2341     unfolding rel_mset_def[abs_def] BNF_Def.Grp_def OO_def
  2342     apply (rule ext)+
  2343     apply auto
  2344      apply (rule_tac x = "mset (zip xs ys)" in exI; auto)
  2345         apply (metis list_all2_lengthD map_fst_zip mset_map)
  2346        apply (auto simp: list_all2_iff)[1]
  2347       apply (metis list_all2_lengthD map_snd_zip mset_map)
  2348      apply (auto simp: list_all2_iff)[1]
  2349     apply (rename_tac XY)
  2350     apply (cut_tac X = XY in ex_mset)
  2351     apply (erule exE)
  2352     apply (rename_tac xys)
  2353     apply (rule_tac x = "map fst xys" in exI)
  2354     apply (auto simp: mset_map)
  2355     apply (rule_tac x = "map snd xys" in exI)
  2356     apply (auto simp: mset_map list_all2I subset_eq zip_map_fst_snd)
  2357     done
  2358   show "z \<in> set_mset {#} \<Longrightarrow> False" for z
  2359     by auto
  2360 qed
  2361 
  2362 inductive rel_mset'
  2363 where
  2364   Zero[intro]: "rel_mset' R {#} {#}"
  2365 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (M + {#a#}) (N + {#b#})"
  2366 
  2367 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  2368 unfolding rel_mset_def Grp_def by auto
  2369 
  2370 declare multiset.count[simp]
  2371 declare Abs_multiset_inverse[simp]
  2372 declare multiset.count_inverse[simp]
  2373 declare union_preserves_multiset[simp]
  2374 
  2375 lemma rel_mset_Plus:
  2376   assumes ab: "R a b"
  2377     and MN: "rel_mset R M N"
  2378   shows "rel_mset R (M + {#a#}) (N + {#b#})"
  2379 proof -
  2380   have "\<exists>ya. image_mset fst y + {#a#} = image_mset fst ya \<and>
  2381     image_mset snd y + {#b#} = image_mset snd ya \<and>
  2382     set_mset ya \<subseteq> {(x, y). R x y}"
  2383     if "R a b" and "set_mset y \<subseteq> {(x, y). R x y}" for y
  2384     using that by (intro exI[of _ "y + {#(a,b)#}"]) auto
  2385   thus ?thesis
  2386   using assms
  2387   unfolding multiset.rel_compp_Grp Grp_def by blast
  2388 qed
  2389 
  2390 lemma rel_mset'_imp_rel_mset: "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  2391   by (induct rule: rel_mset'.induct) (auto simp: rel_mset_Zero rel_mset_Plus)
  2392 
  2393 lemma rel_mset_size: "rel_mset R M N \<Longrightarrow> size M = size N"
  2394   unfolding multiset.rel_compp_Grp Grp_def by auto
  2395 
  2396 lemma multiset_induct2[case_names empty addL addR]:
  2397   assumes empty: "P {#} {#}"
  2398     and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2399     and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2400   shows "P M N"
  2401 apply(induct N rule: multiset_induct)
  2402   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2403   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2404 done
  2405 
  2406 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  2407   assumes c: "size M = size N"
  2408     and empty: "P {#} {#}"
  2409     and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2410   shows "P M N"
  2411   using c
  2412 proof (induct M arbitrary: N rule: measure_induct_rule[of size])
  2413   case (less M)
  2414   show ?case
  2415   proof(cases "M = {#}")
  2416     case True hence "N = {#}" using less.prems by auto
  2417     thus ?thesis using True empty by auto
  2418   next
  2419     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2420     have "N \<noteq> {#}" using False less.prems by auto
  2421     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2422     have "size M1 = size N1" using less.prems unfolding M N by auto
  2423     thus ?thesis using M N less.hyps add by auto
  2424   qed
  2425 qed
  2426 
  2427 lemma msed_map_invL:
  2428   assumes "image_mset f (M + {#a#}) = N"
  2429   shows "\<exists>N1. N = N1 + {#f a#} \<and> image_mset f M = N1"
  2430 proof -
  2431   have "f a \<in># N"
  2432     using assms multiset.set_map[of f "M + {#a#}"] by auto
  2433   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2434   have "image_mset f M = N1" using assms unfolding N by simp
  2435   thus ?thesis using N by blast
  2436 qed
  2437 
  2438 lemma msed_map_invR:
  2439   assumes "image_mset f M = N + {#b#}"
  2440   shows "\<exists>M1 a. M = M1 + {#a#} \<and> f a = b \<and> image_mset f M1 = N"
  2441 proof -
  2442   obtain a where a: "a \<in># M" and fa: "f a = b"
  2443     using multiset.set_map[of f M] unfolding assms
  2444     by (metis image_iff mem_set_mset_iff union_single_eq_member)
  2445   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2446   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  2447   thus ?thesis using M fa by blast
  2448 qed
  2449 
  2450 lemma msed_rel_invL:
  2451   assumes "rel_mset R (M + {#a#}) N"
  2452   shows "\<exists>N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_mset R M N1"
  2453 proof -
  2454   obtain K where KM: "image_mset fst K = M + {#a#}"
  2455     and KN: "image_mset snd K = N" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2456     using assms
  2457     unfolding multiset.rel_compp_Grp Grp_def by auto
  2458   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2459     and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  2460   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "image_mset snd K1 = N1"
  2461     using msed_map_invL[OF KN[unfolded K]] by auto
  2462   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2463   have "rel_mset R M N1" using sK K1M K1N1
  2464     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2465   thus ?thesis using N Rab by auto
  2466 qed
  2467 
  2468 lemma msed_rel_invR:
  2469   assumes "rel_mset R M (N + {#b#})"
  2470   shows "\<exists>M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_mset R M1 N"
  2471 proof -
  2472   obtain K where KN: "image_mset snd K = N + {#b#}"
  2473     and KM: "image_mset fst K = M" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2474     using assms
  2475     unfolding multiset.rel_compp_Grp Grp_def by auto
  2476   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2477     and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  2478   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "image_mset fst K1 = M1"
  2479     using msed_map_invL[OF KM[unfolded K]] by auto
  2480   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2481   have "rel_mset R M1 N" using sK K1N K1M1
  2482     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2483   thus ?thesis using M Rab by auto
  2484 qed
  2485 
  2486 lemma rel_mset_imp_rel_mset':
  2487   assumes "rel_mset R M N"
  2488   shows "rel_mset' R M N"
  2489 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  2490   case (less M)
  2491   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  2492   show ?case
  2493   proof(cases "M = {#}")
  2494     case True hence "N = {#}" using c by simp
  2495     thus ?thesis using True rel_mset'.Zero by auto
  2496   next
  2497     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2498     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_mset R M1 N1"
  2499       using msed_rel_invL[OF less.prems[unfolded M]] by auto
  2500     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  2501     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  2502   qed
  2503 qed
  2504 
  2505 lemma rel_mset_rel_mset': "rel_mset R M N = rel_mset' R M N"
  2506   using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  2507 
  2508 text \<open>The main end product for @{const rel_mset}: inductive characterization:\<close>
  2509 lemmas rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  2510   rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  2511 
  2512 
  2513 subsection \<open>Size setup\<close>
  2514 
  2515 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  2516   apply (rule ext)
  2517   subgoal for x by (induct x) auto
  2518   done
  2519 
  2520 setup \<open>
  2521   BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  2522     @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  2523       size_union}
  2524     @{thms multiset_size_o_map}
  2525 \<close>
  2526 
  2527 hide_const (open) wcount
  2528 
  2529 end