src/HOL/Library/Stream.thy
author wenzelm
Mon Dec 28 01:28:28 2015 +0100 (2015-12-28)
changeset 61945 1135b8de26c3
parent 61681 ca53150406c9
child 62093 bd73a2279fcd
permissions -rw-r--r--
more symbols;
     1 (*  Title:      HOL/Library/Stream.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   2012, 2013
     5 
     6 Infinite streams.
     7 *)
     8 
     9 section \<open>Infinite Streams\<close>
    10 
    11 theory Stream
    12 imports "~~/src/HOL/Library/Nat_Bijection"
    13 begin
    14 
    15 codatatype (sset: 'a) stream =
    16   SCons (shd: 'a) (stl: "'a stream") (infixr "##" 65)
    17 for
    18   map: smap
    19   rel: stream_all2
    20 
    21 context
    22 begin
    23 
    24 (*for code generation only*)
    25 qualified definition smember :: "'a \<Rightarrow> 'a stream \<Rightarrow> bool" where
    26   [code_abbrev]: "smember x s \<longleftrightarrow> x \<in> sset s"
    27 
    28 lemma smember_code[code, simp]: "smember x (y ## s) = (if x = y then True else smember x s)"
    29   unfolding smember_def by auto
    30 
    31 end
    32 
    33 lemmas smap_simps[simp] = stream.map_sel
    34 lemmas shd_sset = stream.set_sel(1)
    35 lemmas stl_sset = stream.set_sel(2)
    36 
    37 theorem sset_induct[consumes 1, case_names shd stl, induct set: sset]:
    38   assumes "y \<in> sset s" and "\<And>s. P (shd s) s" and "\<And>s y. \<lbrakk>y \<in> sset (stl s); P y (stl s)\<rbrakk> \<Longrightarrow> P y s"
    39   shows "P y s"
    40 using assms by induct (metis stream.sel(1), auto)
    41 
    42 lemma smap_ctr: "smap f s = x ## s' \<longleftrightarrow> f (shd s) = x \<and> smap f (stl s) = s'"
    43   by (cases s) simp
    44 
    45 subsection \<open>prepend list to stream\<close>
    46 
    47 primrec shift :: "'a list \<Rightarrow> 'a stream \<Rightarrow> 'a stream" (infixr "@-" 65) where
    48   "shift [] s = s"
    49 | "shift (x # xs) s = x ## shift xs s"
    50 
    51 lemma smap_shift[simp]: "smap f (xs @- s) = map f xs @- smap f s"
    52   by (induct xs) auto
    53 
    54 lemma shift_append[simp]: "(xs @ ys) @- s = xs @- ys @- s"
    55   by (induct xs) auto
    56 
    57 lemma shift_simps[simp]:
    58    "shd (xs @- s) = (if xs = [] then shd s else hd xs)"
    59    "stl (xs @- s) = (if xs = [] then stl s else tl xs @- s)"
    60   by (induct xs) auto
    61 
    62 lemma sset_shift[simp]: "sset (xs @- s) = set xs \<union> sset s"
    63   by (induct xs) auto
    64 
    65 lemma shift_left_inj[simp]: "xs @- s1 = xs @- s2 \<longleftrightarrow> s1 = s2"
    66   by (induct xs) auto
    67 
    68 
    69 subsection \<open>set of streams with elements in some fixed set\<close>
    70 
    71 context
    72   notes [[inductive_defs]]
    73 begin
    74 
    75 coinductive_set
    76   streams :: "'a set \<Rightarrow> 'a stream set"
    77   for A :: "'a set"
    78 where
    79   Stream[intro!, simp, no_atp]: "\<lbrakk>a \<in> A; s \<in> streams A\<rbrakk> \<Longrightarrow> a ## s \<in> streams A"
    80 
    81 end
    82 
    83 lemma in_streams: "stl s \<in> streams S \<Longrightarrow> shd s \<in> S \<Longrightarrow> s \<in> streams S"
    84   by (cases s) auto
    85 
    86 lemma streamsE: "s \<in> streams A \<Longrightarrow> (shd s \<in> A \<Longrightarrow> stl s \<in> streams A \<Longrightarrow> P) \<Longrightarrow> P"
    87   by (erule streams.cases) simp_all
    88 
    89 lemma Stream_image: "x ## y \<in> (op ## x') ` Y \<longleftrightarrow> x = x' \<and> y \<in> Y"
    90   by auto
    91 
    92 lemma shift_streams: "\<lbrakk>w \<in> lists A; s \<in> streams A\<rbrakk> \<Longrightarrow> w @- s \<in> streams A"
    93   by (induct w) auto
    94 
    95 lemma streams_Stream: "x ## s \<in> streams A \<longleftrightarrow> x \<in> A \<and> s \<in> streams A"
    96   by (auto elim: streams.cases)
    97 
    98 lemma streams_stl: "s \<in> streams A \<Longrightarrow> stl s \<in> streams A"
    99   by (cases s) (auto simp: streams_Stream)
   100 
   101 lemma streams_shd: "s \<in> streams A \<Longrightarrow> shd s \<in> A"
   102   by (cases s) (auto simp: streams_Stream)
   103 
   104 lemma sset_streams:
   105   assumes "sset s \<subseteq> A"
   106   shows "s \<in> streams A"
   107 using assms proof (coinduction arbitrary: s)
   108   case streams then show ?case by (cases s) simp
   109 qed
   110 
   111 lemma streams_sset:
   112   assumes "s \<in> streams A"
   113   shows "sset s \<subseteq> A"
   114 proof
   115   fix x assume "x \<in> sset s" from this \<open>s \<in> streams A\<close> show "x \<in> A"
   116     by (induct s) (auto intro: streams_shd streams_stl)
   117 qed
   118 
   119 lemma streams_iff_sset: "s \<in> streams A \<longleftrightarrow> sset s \<subseteq> A"
   120   by (metis sset_streams streams_sset)
   121 
   122 lemma streams_mono:  "s \<in> streams A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> s \<in> streams B"
   123   unfolding streams_iff_sset by auto
   124 
   125 lemma streams_mono2: "S \<subseteq> T \<Longrightarrow> streams S \<subseteq> streams T"
   126   by (auto intro: streams_mono)
   127 
   128 lemma smap_streams: "s \<in> streams A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> smap f s \<in> streams B"
   129   unfolding streams_iff_sset stream.set_map by auto
   130 
   131 lemma streams_empty: "streams {} = {}"
   132   by (auto elim: streams.cases)
   133 
   134 lemma streams_UNIV[simp]: "streams UNIV = UNIV"
   135   by (auto simp: streams_iff_sset)
   136 
   137 subsection \<open>nth, take, drop for streams\<close>
   138 
   139 primrec snth :: "'a stream \<Rightarrow> nat \<Rightarrow> 'a" (infixl "!!" 100) where
   140   "s !! 0 = shd s"
   141 | "s !! Suc n = stl s !! n"
   142 
   143 lemma snth_Stream: "(x ## s) !! Suc i = s !! i"
   144   by simp
   145 
   146 lemma snth_smap[simp]: "smap f s !! n = f (s !! n)"
   147   by (induct n arbitrary: s) auto
   148 
   149 lemma shift_snth_less[simp]: "p < length xs \<Longrightarrow> (xs @- s) !! p = xs ! p"
   150   by (induct p arbitrary: xs) (auto simp: hd_conv_nth nth_tl)
   151 
   152 lemma shift_snth_ge[simp]: "p \<ge> length xs \<Longrightarrow> (xs @- s) !! p = s !! (p - length xs)"
   153   by (induct p arbitrary: xs) (auto simp: Suc_diff_eq_diff_pred)
   154 
   155 lemma shift_snth: "(xs @- s) !! n = (if n < length xs then xs ! n else s !! (n - length xs))"
   156   by auto
   157 
   158 lemma snth_sset[simp]: "s !! n \<in> sset s"
   159   by (induct n arbitrary: s) (auto intro: shd_sset stl_sset)
   160 
   161 lemma sset_range: "sset s = range (snth s)"
   162 proof (intro equalityI subsetI)
   163   fix x assume "x \<in> sset s"
   164   thus "x \<in> range (snth s)"
   165   proof (induct s)
   166     case (stl s x)
   167     then obtain n where "x = stl s !! n" by auto
   168     thus ?case by (auto intro: range_eqI[of _ _ "Suc n"])
   169   qed (auto intro: range_eqI[of _ _ 0])
   170 qed auto
   171 
   172 lemma streams_iff_snth: "s \<in> streams X \<longleftrightarrow> (\<forall>n. s !! n \<in> X)"
   173   by (force simp: streams_iff_sset sset_range)
   174 
   175 lemma snth_in: "s \<in> streams X \<Longrightarrow> s !! n \<in> X"
   176   by (simp add: streams_iff_snth)
   177 
   178 primrec stake :: "nat \<Rightarrow> 'a stream \<Rightarrow> 'a list" where
   179   "stake 0 s = []"
   180 | "stake (Suc n) s = shd s # stake n (stl s)"
   181 
   182 lemma length_stake[simp]: "length (stake n s) = n"
   183   by (induct n arbitrary: s) auto
   184 
   185 lemma stake_smap[simp]: "stake n (smap f s) = map f (stake n s)"
   186   by (induct n arbitrary: s) auto
   187 
   188 lemma take_stake: "take n (stake m s) = stake (min n m) s"
   189 proof (induct m arbitrary: s n)
   190   case (Suc m) thus ?case by (cases n) auto
   191 qed simp
   192 
   193 primrec sdrop :: "nat \<Rightarrow> 'a stream \<Rightarrow> 'a stream" where
   194   "sdrop 0 s = s"
   195 | "sdrop (Suc n) s = sdrop n (stl s)"
   196 
   197 lemma sdrop_simps[simp]:
   198   "shd (sdrop n s) = s !! n" "stl (sdrop n s) = sdrop (Suc n) s"
   199   by (induct n arbitrary: s)  auto
   200 
   201 lemma sdrop_smap[simp]: "sdrop n (smap f s) = smap f (sdrop n s)"
   202   by (induct n arbitrary: s) auto
   203 
   204 lemma sdrop_stl: "sdrop n (stl s) = stl (sdrop n s)"
   205   by (induct n) auto
   206 
   207 lemma drop_stake: "drop n (stake m s) = stake (m - n) (sdrop n s)"
   208 proof (induct m arbitrary: s n)
   209   case (Suc m) thus ?case by (cases n) auto
   210 qed simp
   211 
   212 lemma stake_sdrop: "stake n s @- sdrop n s = s"
   213   by (induct n arbitrary: s) auto
   214 
   215 lemma id_stake_snth_sdrop:
   216   "s = stake i s @- s !! i ## sdrop (Suc i) s"
   217   by (subst stake_sdrop[symmetric, of _ i]) (metis sdrop_simps stream.collapse)
   218 
   219 lemma smap_alt: "smap f s = s' \<longleftrightarrow> (\<forall>n. f (s !! n) = s' !! n)" (is "?L = ?R")
   220 proof
   221   assume ?R
   222   then have "\<And>n. smap f (sdrop n s) = sdrop n s'"
   223     by coinduction (auto intro: exI[of _ 0] simp del: sdrop.simps(2))
   224   then show ?L using sdrop.simps(1) by metis
   225 qed auto
   226 
   227 lemma stake_invert_Nil[iff]: "stake n s = [] \<longleftrightarrow> n = 0"
   228   by (induct n) auto
   229 
   230 lemma sdrop_shift: "sdrop i (w @- s) = drop i w @- sdrop (i - length w) s"
   231   by (induct i arbitrary: w s) (auto simp: drop_tl drop_Suc neq_Nil_conv)
   232 
   233 lemma stake_shift: "stake i (w @- s) = take i w @ stake (i - length w) s"
   234   by (induct i arbitrary: w s) (auto simp: neq_Nil_conv)
   235 
   236 lemma stake_add[simp]: "stake m s @ stake n (sdrop m s) = stake (m + n) s"
   237   by (induct m arbitrary: s) auto
   238 
   239 lemma sdrop_add[simp]: "sdrop n (sdrop m s) = sdrop (m + n) s"
   240   by (induct m arbitrary: s) auto
   241 
   242 lemma sdrop_snth: "sdrop n s !! m = s !! (n + m)"
   243   by (induct n arbitrary: m s) auto
   244 
   245 partial_function (tailrec) sdrop_while :: "('a \<Rightarrow> bool) \<Rightarrow> 'a stream \<Rightarrow> 'a stream" where 
   246   "sdrop_while P s = (if P (shd s) then sdrop_while P (stl s) else s)"
   247 
   248 lemma sdrop_while_SCons[code]:
   249   "sdrop_while P (a ## s) = (if P a then sdrop_while P s else a ## s)"
   250   by (subst sdrop_while.simps) simp
   251 
   252 lemma sdrop_while_sdrop_LEAST:
   253   assumes "\<exists>n. P (s !! n)"
   254   shows "sdrop_while (Not o P) s = sdrop (LEAST n. P (s !! n)) s"
   255 proof -
   256   from assms obtain m where "P (s !! m)" "\<And>n. P (s !! n) \<Longrightarrow> m \<le> n"
   257     and *: "(LEAST n. P (s !! n)) = m" by atomize_elim (auto intro: LeastI Least_le)
   258   thus ?thesis unfolding *
   259   proof (induct m arbitrary: s)
   260     case (Suc m)
   261     hence "sdrop_while (Not \<circ> P) (stl s) = sdrop m (stl s)"
   262       by (metis (full_types) not_less_eq_eq snth.simps(2))
   263     moreover from Suc(3) have "\<not> (P (s !! 0))" by blast
   264     ultimately show ?case by (subst sdrop_while.simps) simp
   265   qed (metis comp_apply sdrop.simps(1) sdrop_while.simps snth.simps(1))
   266 qed
   267 
   268 primcorec sfilter where
   269   "shd (sfilter P s) = shd (sdrop_while (Not o P) s)"
   270 | "stl (sfilter P s) = sfilter P (stl (sdrop_while (Not o P) s))"
   271 
   272 lemma sfilter_Stream: "sfilter P (x ## s) = (if P x then x ## sfilter P s else sfilter P s)"
   273 proof (cases "P x")
   274   case True thus ?thesis by (subst sfilter.ctr) (simp add: sdrop_while_SCons)
   275 next
   276   case False thus ?thesis by (subst (1 2) sfilter.ctr) (simp add: sdrop_while_SCons)
   277 qed
   278 
   279 
   280 subsection \<open>unary predicates lifted to streams\<close>
   281 
   282 definition "stream_all P s = (\<forall>p. P (s !! p))"
   283 
   284 lemma stream_all_iff[iff]: "stream_all P s \<longleftrightarrow> Ball (sset s) P"
   285   unfolding stream_all_def sset_range by auto
   286 
   287 lemma stream_all_shift[simp]: "stream_all P (xs @- s) = (list_all P xs \<and> stream_all P s)"
   288   unfolding stream_all_iff list_all_iff by auto
   289 
   290 lemma stream_all_Stream: "stream_all P (x ## X) \<longleftrightarrow> P x \<and> stream_all P X"
   291   by simp
   292 
   293 
   294 subsection \<open>recurring stream out of a list\<close>
   295 
   296 primcorec cycle :: "'a list \<Rightarrow> 'a stream" where
   297   "shd (cycle xs) = hd xs"
   298 | "stl (cycle xs) = cycle (tl xs @ [hd xs])"
   299 
   300 lemma cycle_decomp: "u \<noteq> [] \<Longrightarrow> cycle u = u @- cycle u"
   301 proof (coinduction arbitrary: u)
   302   case Eq_stream then show ?case using stream.collapse[of "cycle u"]
   303     by (auto intro!: exI[of _ "tl u @ [hd u]"])
   304 qed
   305 
   306 lemma cycle_Cons[code]: "cycle (x # xs) = x ## cycle (xs @ [x])"
   307   by (subst cycle.ctr) simp
   308 
   309 lemma cycle_rotated: "\<lbrakk>v \<noteq> []; cycle u = v @- s\<rbrakk> \<Longrightarrow> cycle (tl u @ [hd u]) = tl v @- s"
   310   by (auto dest: arg_cong[of _ _ stl])
   311 
   312 lemma stake_append: "stake n (u @- s) = take (min (length u) n) u @ stake (n - length u) s"
   313 proof (induct n arbitrary: u)
   314   case (Suc n) thus ?case by (cases u) auto
   315 qed auto
   316 
   317 lemma stake_cycle_le[simp]:
   318   assumes "u \<noteq> []" "n < length u"
   319   shows "stake n (cycle u) = take n u"
   320 using min_absorb2[OF less_imp_le_nat[OF assms(2)]]
   321   by (subst cycle_decomp[OF assms(1)], subst stake_append) auto
   322 
   323 lemma stake_cycle_eq[simp]: "u \<noteq> [] \<Longrightarrow> stake (length u) (cycle u) = u"
   324   by (subst cycle_decomp) (auto simp: stake_shift)
   325 
   326 lemma sdrop_cycle_eq[simp]: "u \<noteq> [] \<Longrightarrow> sdrop (length u) (cycle u) = cycle u"
   327   by (subst cycle_decomp) (auto simp: sdrop_shift)
   328 
   329 lemma stake_cycle_eq_mod_0[simp]: "\<lbrakk>u \<noteq> []; n mod length u = 0\<rbrakk> \<Longrightarrow>
   330    stake n (cycle u) = concat (replicate (n div length u) u)"
   331   by (induct "n div length u" arbitrary: n u) (auto simp: stake_add[symmetric])
   332 
   333 lemma sdrop_cycle_eq_mod_0[simp]: "\<lbrakk>u \<noteq> []; n mod length u = 0\<rbrakk> \<Longrightarrow>
   334    sdrop n (cycle u) = cycle u"
   335   by (induct "n div length u" arbitrary: n u) (auto simp: sdrop_add[symmetric])
   336 
   337 lemma stake_cycle: "u \<noteq> [] \<Longrightarrow>
   338    stake n (cycle u) = concat (replicate (n div length u) u) @ take (n mod length u) u"
   339   by (subst mod_div_equality[of n "length u", symmetric], unfold stake_add[symmetric]) auto
   340 
   341 lemma sdrop_cycle: "u \<noteq> [] \<Longrightarrow> sdrop n (cycle u) = cycle (rotate (n mod length u) u)"
   342   by (induct n arbitrary: u) (auto simp: rotate1_rotate_swap rotate1_hd_tl rotate_conv_mod[symmetric])
   343 
   344 
   345 subsection \<open>iterated application of a function\<close>
   346 
   347 primcorec siterate where
   348   "shd (siterate f x) = x"
   349 | "stl (siterate f x) = siterate f (f x)"
   350 
   351 lemma stake_Suc: "stake (Suc n) s = stake n s @ [s !! n]"
   352   by (induct n arbitrary: s) auto
   353 
   354 lemma snth_siterate[simp]: "siterate f x !! n = (f^^n) x"
   355   by (induct n arbitrary: x) (auto simp: funpow_swap1)
   356 
   357 lemma sdrop_siterate[simp]: "sdrop n (siterate f x) = siterate f ((f^^n) x)"
   358   by (induct n arbitrary: x) (auto simp: funpow_swap1)
   359 
   360 lemma stake_siterate[simp]: "stake n (siterate f x) = map (\<lambda>n. (f^^n) x) [0 ..< n]"
   361   by (induct n arbitrary: x) (auto simp del: stake.simps(2) simp: stake_Suc)
   362 
   363 lemma sset_siterate: "sset (siterate f x) = {(f^^n) x | n. True}"
   364   by (auto simp: sset_range)
   365 
   366 lemma smap_siterate: "smap f (siterate f x) = siterate f (f x)"
   367   by (coinduction arbitrary: x) auto
   368 
   369 
   370 subsection \<open>stream repeating a single element\<close>
   371 
   372 abbreviation "sconst \<equiv> siterate id"
   373 
   374 lemma shift_replicate_sconst[simp]: "replicate n x @- sconst x = sconst x"
   375   by (subst (3) stake_sdrop[symmetric]) (simp add: map_replicate_trivial)
   376 
   377 lemma sset_sconst[simp]: "sset (sconst x) = {x}"
   378   by (simp add: sset_siterate)
   379 
   380 lemma sconst_alt: "s = sconst x \<longleftrightarrow> sset s = {x}"
   381 proof
   382   assume "sset s = {x}"
   383   then show "s = sconst x"
   384   proof (coinduction arbitrary: s)
   385     case Eq_stream
   386     then have "shd s = x" "sset (stl s) \<subseteq> {x}" by (case_tac [!] s) auto
   387     then have "sset (stl s) = {x}" by (cases "stl s") auto
   388     with \<open>shd s = x\<close> show ?case by auto
   389   qed
   390 qed simp
   391 
   392 lemma sconst_cycle: "sconst x = cycle [x]"
   393   by coinduction auto
   394 
   395 lemma smap_sconst: "smap f (sconst x) = sconst (f x)"
   396   by coinduction auto
   397 
   398 lemma sconst_streams: "x \<in> A \<Longrightarrow> sconst x \<in> streams A"
   399   by (simp add: streams_iff_sset)
   400 
   401 
   402 subsection \<open>stream of natural numbers\<close>
   403 
   404 abbreviation "fromN \<equiv> siterate Suc"
   405 
   406 abbreviation "nats \<equiv> fromN 0"
   407 
   408 lemma sset_fromN[simp]: "sset (fromN n) = {n ..}"
   409   by (auto simp add: sset_siterate le_iff_add)
   410 
   411 lemma stream_smap_fromN: "s = smap (\<lambda>j. let i = j - n in s !! i) (fromN n)"
   412   by (coinduction arbitrary: s n)
   413     (force simp: neq_Nil_conv Let_def snth.simps(2)[symmetric] Suc_diff_Suc
   414       intro: stream.map_cong split: if_splits simp del: snth.simps(2))
   415 
   416 lemma stream_smap_nats: "s = smap (snth s) nats"
   417   using stream_smap_fromN[where n = 0] by simp
   418 
   419 
   420 subsection \<open>flatten a stream of lists\<close>
   421 
   422 primcorec flat where
   423   "shd (flat ws) = hd (shd ws)"
   424 | "stl (flat ws) = flat (if tl (shd ws) = [] then stl ws else tl (shd ws) ## stl ws)"
   425 
   426 lemma flat_Cons[simp, code]: "flat ((x # xs) ## ws) = x ## flat (if xs = [] then ws else xs ## ws)"
   427   by (subst flat.ctr) simp
   428 
   429 lemma flat_Stream[simp]: "xs \<noteq> [] \<Longrightarrow> flat (xs ## ws) = xs @- flat ws"
   430   by (induct xs) auto
   431 
   432 lemma flat_unfold: "shd ws \<noteq> [] \<Longrightarrow> flat ws = shd ws @- flat (stl ws)"
   433   by (cases ws) auto
   434 
   435 lemma flat_snth: "\<forall>xs \<in> sset s. xs \<noteq> [] \<Longrightarrow> flat s !! n = (if n < length (shd s) then 
   436   shd s ! n else flat (stl s) !! (n - length (shd s)))"
   437   by (metis flat_unfold not_less shd_sset shift_snth_ge shift_snth_less)
   438 
   439 lemma sset_flat[simp]: "\<forall>xs \<in> sset s. xs \<noteq> [] \<Longrightarrow> 
   440   sset (flat s) = (\<Union>xs \<in> sset s. set xs)" (is "?P \<Longrightarrow> ?L = ?R")
   441 proof safe
   442   fix x assume ?P "x : ?L"
   443   then obtain m where "x = flat s !! m" by (metis image_iff sset_range)
   444   with \<open>?P\<close> obtain n m' where "x = s !! n ! m'" "m' < length (s !! n)"
   445   proof (atomize_elim, induct m arbitrary: s rule: less_induct)
   446     case (less y)
   447     thus ?case
   448     proof (cases "y < length (shd s)")
   449       case True thus ?thesis by (metis flat_snth less(2,3) snth.simps(1))
   450     next
   451       case False
   452       hence "x = flat (stl s) !! (y - length (shd s))" by (metis less(2,3) flat_snth)
   453       moreover
   454       { from less(2) have *: "length (shd s) > 0" by (cases s) simp_all
   455         with False have "y > 0" by (cases y) simp_all
   456         with * have "y - length (shd s) < y" by simp
   457       }
   458       moreover have "\<forall>xs \<in> sset (stl s). xs \<noteq> []" using less(2) by (cases s) auto
   459       ultimately have "\<exists>n m'. x = stl s !! n ! m' \<and> m' < length (stl s !! n)" by (intro less(1)) auto
   460       thus ?thesis by (metis snth.simps(2))
   461     qed
   462   qed
   463   thus "x \<in> ?R" by (auto simp: sset_range dest!: nth_mem)
   464 next
   465   fix x xs assume "xs \<in> sset s" ?P "x \<in> set xs" thus "x \<in> ?L"
   466     by (induct rule: sset_induct)
   467       (metis UnI1 flat_unfold shift.simps(1) sset_shift,
   468        metis UnI2 flat_unfold shd_sset stl_sset sset_shift)
   469 qed
   470 
   471 
   472 subsection \<open>merge a stream of streams\<close>
   473 
   474 definition smerge :: "'a stream stream \<Rightarrow> 'a stream" where
   475   "smerge ss = flat (smap (\<lambda>n. map (\<lambda>s. s !! n) (stake (Suc n) ss) @ stake n (ss !! n)) nats)"
   476 
   477 lemma stake_nth[simp]: "m < n \<Longrightarrow> stake n s ! m = s !! m"
   478   by (induct n arbitrary: s m) (auto simp: nth_Cons', metis Suc_pred snth.simps(2))
   479 
   480 lemma snth_sset_smerge: "ss !! n !! m \<in> sset (smerge ss)"
   481 proof (cases "n \<le> m")
   482   case False thus ?thesis unfolding smerge_def
   483     by (subst sset_flat)
   484       (auto simp: stream.set_map in_set_conv_nth simp del: stake.simps
   485         intro!: exI[of _ n, OF disjI2] exI[of _ m, OF mp])
   486 next
   487   case True thus ?thesis unfolding smerge_def
   488     by (subst sset_flat)
   489       (auto simp: stream.set_map in_set_conv_nth image_iff simp del: stake.simps snth.simps
   490         intro!: exI[of _ m, OF disjI1] bexI[of _ "ss !! n"] exI[of _ n, OF mp])
   491 qed
   492 
   493 lemma sset_smerge: "sset (smerge ss) = UNION (sset ss) sset"
   494 proof safe
   495   fix x assume "x \<in> sset (smerge ss)"
   496   thus "x \<in> UNION (sset ss) sset"
   497     unfolding smerge_def by (subst (asm) sset_flat)
   498       (auto simp: stream.set_map in_set_conv_nth sset_range simp del: stake.simps, fast+)
   499 next
   500   fix s x assume "s \<in> sset ss" "x \<in> sset s"
   501   thus "x \<in> sset (smerge ss)" using snth_sset_smerge by (auto simp: sset_range)
   502 qed
   503 
   504 
   505 subsection \<open>product of two streams\<close>
   506 
   507 definition sproduct :: "'a stream \<Rightarrow> 'b stream \<Rightarrow> ('a \<times> 'b) stream" where
   508   "sproduct s1 s2 = smerge (smap (\<lambda>x. smap (Pair x) s2) s1)"
   509 
   510 lemma sset_sproduct: "sset (sproduct s1 s2) = sset s1 \<times> sset s2"
   511   unfolding sproduct_def sset_smerge by (auto simp: stream.set_map)
   512 
   513 
   514 subsection \<open>interleave two streams\<close>
   515 
   516 primcorec sinterleave where
   517   "shd (sinterleave s1 s2) = shd s1"
   518 | "stl (sinterleave s1 s2) = sinterleave s2 (stl s1)"
   519 
   520 lemma sinterleave_code[code]:
   521   "sinterleave (x ## s1) s2 = x ## sinterleave s2 s1"
   522   by (subst sinterleave.ctr) simp
   523 
   524 lemma sinterleave_snth[simp]:
   525   "even n \<Longrightarrow> sinterleave s1 s2 !! n = s1 !! (n div 2)"
   526   "odd n \<Longrightarrow> sinterleave s1 s2 !! n = s2 !! (n div 2)"
   527   by (induct n arbitrary: s1 s2) simp_all
   528 
   529 lemma sset_sinterleave: "sset (sinterleave s1 s2) = sset s1 \<union> sset s2"
   530 proof (intro equalityI subsetI)
   531   fix x assume "x \<in> sset (sinterleave s1 s2)"
   532   then obtain n where "x = sinterleave s1 s2 !! n" unfolding sset_range by blast
   533   thus "x \<in> sset s1 \<union> sset s2" by (cases "even n") auto
   534 next
   535   fix x assume "x \<in> sset s1 \<union> sset s2"
   536   thus "x \<in> sset (sinterleave s1 s2)"
   537   proof
   538     assume "x \<in> sset s1"
   539     then obtain n where "x = s1 !! n" unfolding sset_range by blast
   540     hence "sinterleave s1 s2 !! (2 * n) = x" by simp
   541     thus ?thesis unfolding sset_range by blast
   542   next
   543     assume "x \<in> sset s2"
   544     then obtain n where "x = s2 !! n" unfolding sset_range by blast
   545     hence "sinterleave s1 s2 !! (2 * n + 1) = x" by simp
   546     thus ?thesis unfolding sset_range by blast
   547   qed
   548 qed
   549 
   550 
   551 subsection \<open>zip\<close>
   552 
   553 primcorec szip where
   554   "shd (szip s1 s2) = (shd s1, shd s2)"
   555 | "stl (szip s1 s2) = szip (stl s1) (stl s2)"
   556 
   557 lemma szip_unfold[code]: "szip (a ## s1) (b ## s2) = (a, b) ## (szip s1 s2)"
   558   by (subst szip.ctr) simp
   559 
   560 lemma snth_szip[simp]: "szip s1 s2 !! n = (s1 !! n, s2 !! n)"
   561   by (induct n arbitrary: s1 s2) auto
   562 
   563 lemma stake_szip[simp]:
   564   "stake n (szip s1 s2) = zip (stake n s1) (stake n s2)"
   565   by (induct n arbitrary: s1 s2) auto
   566 
   567 lemma sdrop_szip[simp]: "sdrop n (szip s1 s2) = szip (sdrop n s1) (sdrop n s2)"
   568   by (induct n arbitrary: s1 s2) auto
   569 
   570 lemma smap_szip_fst:
   571   "smap (\<lambda>x. f (fst x)) (szip s1 s2) = smap f s1"
   572   by (coinduction arbitrary: s1 s2) auto
   573 
   574 lemma smap_szip_snd:
   575   "smap (\<lambda>x. g (snd x)) (szip s1 s2) = smap g s2"
   576   by (coinduction arbitrary: s1 s2) auto
   577 
   578 
   579 subsection \<open>zip via function\<close>
   580 
   581 primcorec smap2 where
   582   "shd (smap2 f s1 s2) = f (shd s1) (shd s2)"
   583 | "stl (smap2 f s1 s2) = smap2 f (stl s1) (stl s2)"
   584 
   585 lemma smap2_unfold[code]:
   586   "smap2 f (a ## s1) (b ## s2) = f a b ## (smap2 f s1 s2)"
   587   by (subst smap2.ctr) simp
   588 
   589 lemma smap2_szip:
   590   "smap2 f s1 s2 = smap (case_prod f) (szip s1 s2)"
   591   by (coinduction arbitrary: s1 s2) auto
   592 
   593 lemma smap_smap2[simp]:
   594   "smap f (smap2 g s1 s2) = smap2 (\<lambda>x y. f (g x y)) s1 s2"
   595   unfolding smap2_szip stream.map_comp o_def split_def ..
   596 
   597 lemma smap2_alt:
   598   "(smap2 f s1 s2 = s) = (\<forall>n. f (s1 !! n) (s2 !! n) = s !! n)"
   599   unfolding smap2_szip smap_alt by auto
   600 
   601 lemma snth_smap2[simp]:
   602   "smap2 f s1 s2 !! n = f (s1 !! n) (s2 !! n)"
   603   by (induct n arbitrary: s1 s2) auto
   604 
   605 lemma stake_smap2[simp]:
   606   "stake n (smap2 f s1 s2) = map (case_prod f) (zip (stake n s1) (stake n s2))"
   607   by (induct n arbitrary: s1 s2) auto
   608 
   609 lemma sdrop_smap2[simp]:
   610   "sdrop n (smap2 f s1 s2) = smap2 f (sdrop n s1) (sdrop n s2)"
   611   by (induct n arbitrary: s1 s2) auto
   612 
   613 end