src/HOL/List.thy
author wenzelm
Tue Jul 16 18:26:36 2002 +0200 (2002-07-16)
changeset 13366 114b7c14084a
parent 13187 e5434b822a96
child 13462 56610e2ba220
permissions -rw-r--r--
moved stuff from Main.thy;
tuned;
     1 (* Title:HOL/List.thy
     2    ID: $Id$
     3    Author: Tobias Nipkow
     4    Copyright 1994 TU Muenchen
     5 *)
     6 
     7 header {* The datatype of finite lists *}
     8 
     9 theory List = PreList:
    10 
    11 datatype 'a list =
    12     Nil    ("[]")
    13   | Cons 'a  "'a list"    (infixr "#" 65)
    14 
    15 consts
    16   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    17   filter:: "('a => bool) => 'a list => 'a list"
    18   concat:: "'a list list => 'a list"
    19   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    20   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    21   hd:: "'a list => 'a"
    22   tl:: "'a list => 'a list"
    23   last:: "'a list => 'a"
    24   butlast :: "'a list => 'a list"
    25   set :: "'a list => 'a set"
    26   list_all:: "('a => bool) => ('a list => bool)"
    27   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    28   map :: "('a=>'b) => ('a list => 'b list)"
    29   mem :: "'a => 'a list => bool"    (infixl 55)
    30   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    31   list_update :: "'a list => nat => 'a => 'a list"
    32   take:: "nat => 'a list => 'a list"
    33   drop:: "nat => 'a list => 'a list"
    34   takeWhile :: "('a => bool) => 'a list => 'a list"
    35   dropWhile :: "('a => bool) => 'a list => 'a list"
    36   rev :: "'a list => 'a list"
    37   zip :: "'a list => 'b list => ('a * 'b) list"
    38   upt :: "nat => nat => nat list" ("(1[_../_'(])")
    39   remdups :: "'a list => 'a list"
    40   null:: "'a list => bool"
    41   "distinct":: "'a list => bool"
    42   replicate :: "nat => 'a => 'a list"
    43 
    44 nonterminals lupdbinds lupdbind
    45 
    46 syntax
    47   -- {* list Enumeration *}
    48   "@list" :: "args => 'a list"    ("[(_)]")
    49 
    50   -- {* Special syntax for filter *}
    51   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    52 
    53   -- {* list update *}
    54   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    55   "" :: "lupdbind => lupdbinds"    ("_")
    56   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    57   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    58 
    59   upto:: "nat => nat => nat list"    ("(1[_../_])")
    60 
    61 translations
    62   "[x, xs]" == "x#[xs]"
    63   "[x]" == "x#[]"
    64   "[x:xs . P]"== "filter (%x. P) xs"
    65 
    66   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    67   "xs[i:=x]" == "list_update xs i x"
    68 
    69   "[i..j]" == "[i..(Suc j)(]"
    70 
    71 
    72 syntax (xsymbols)
    73   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    74 
    75 
    76 text {*
    77   Function @{text size} is overloaded for all datatypes.Users may
    78   refer to the list version as @{text length}. *}
    79 
    80 syntax length :: "'a list => nat"
    81 translations "length" => "size :: _ list => nat"
    82 
    83 typed_print_translation {*
    84   let
    85     fun size_tr' _ (Type ("fun", (Type ("list", _) :: _))) [t] =
    86           Syntax.const "length" $ t
    87       | size_tr' _ _ _ = raise Match;
    88   in [("size", size_tr')] end
    89 *}
    90 
    91 primrec
    92 "hd(x#xs) = x"
    93 primrec
    94 "tl([]) = []"
    95 "tl(x#xs) = xs"
    96 primrec
    97 "null([]) = True"
    98 "null(x#xs) = False"
    99 primrec
   100 "last(x#xs) = (if xs=[] then x else last xs)"
   101 primrec
   102 "butlast []= []"
   103 "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   104 primrec
   105 "x mem [] = False"
   106 "x mem (y#ys) = (if y=x then True else x mem ys)"
   107 primrec
   108 "set [] = {}"
   109 "set (x#xs) = insert x (set xs)"
   110 primrec
   111 list_all_Nil:"list_all P [] = True"
   112 list_all_Cons: "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   113 primrec
   114 "map f [] = []"
   115 "map f (x#xs) = f(x)#map f xs"
   116 primrec
   117 append_Nil:"[]@ys = ys"
   118 append_Cons: "(x#xs)@ys = x#(xs@ys)"
   119 primrec
   120 "rev([]) = []"
   121 "rev(x#xs) = rev(xs) @ [x]"
   122 primrec
   123 "filter P [] = []"
   124 "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   125 primrec
   126 foldl_Nil:"foldl f a [] = a"
   127 foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   128 primrec
   129 "foldr f [] a = a"
   130 "foldr f (x#xs) a = f x (foldr f xs a)"
   131 primrec
   132 "concat([]) = []"
   133 "concat(x#xs) = x @ concat(xs)"
   134 primrec
   135 drop_Nil:"drop n [] = []"
   136 drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   137 -- {* Warning: simpset does not contain this definition *}
   138 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   139 primrec
   140 take_Nil:"take n [] = []"
   141 take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   142 -- {* Warning: simpset does not contain this definition *}
   143 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   144 primrec
   145 nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   146 -- {* Warning: simpset does not contain this definition *}
   147 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   148 primrec
   149 "[][i:=v] = []"
   150 "(x#xs)[i:=v] =
   151 (case i of 0 => v # xs
   152 | Suc j => x # xs[j:=v])"
   153 primrec
   154 "takeWhile P [] = []"
   155 "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   156 primrec
   157 "dropWhile P [] = []"
   158 "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   159 primrec
   160 "zip xs [] = []"
   161 zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   162 -- {* Warning: simpset does not contain this definition *}
   163 -- {* but separate theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   164 primrec
   165 upt_0: "[i..0(] = []"
   166 upt_Suc: "[i..(Suc j)(] = (if i <= j then [i..j(] @ [j] else [])"
   167 primrec
   168 "distinct [] = True"
   169 "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   170 primrec
   171 "remdups [] = []"
   172 "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   173 primrec
   174 replicate_0: "replicate 0 x = []"
   175 replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   176 defs
   177  list_all2_def:
   178  "list_all2 P xs ys == length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   179 
   180 
   181 subsection {* Lexicographic orderings on lists *}
   182 
   183 consts
   184 lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
   185 primrec
   186 "lexn r 0 = {}"
   187 "lexn r (Suc n) =
   188 (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
   189 {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
   190 
   191 constdefs
   192 lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   193 "lex r == \<Union>n. lexn r n"
   194 
   195 lexico :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   196 "lexico r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
   197 
   198 sublist :: "'a list => nat set => 'a list"
   199 "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..size xs(]))"
   200 
   201 
   202 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   203 by (induct xs) auto
   204 
   205 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   206 
   207 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   208 by (induct xs) auto
   209 
   210 lemma length_induct:
   211 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   212 by (rule measure_induct [of length]) rules
   213 
   214 
   215 subsection {* @{text lists}: the list-forming operator over sets *}
   216 
   217 consts lists :: "'a set => 'a list set"
   218 inductive "lists A"
   219 intros
   220 Nil [intro!]: "[]: lists A"
   221 Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
   222 
   223 inductive_cases listsE [elim!]: "x#l : lists A"
   224 
   225 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
   226 by (unfold lists.defs) (blast intro!: lfp_mono)
   227 
   228 lemma lists_IntI [rule_format]:
   229 "l: lists A ==> l: lists B --> l: lists (A Int B)"
   230 apply (erule lists.induct)
   231 apply blast+
   232 done
   233 
   234 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
   235 apply (rule mono_Int [THEN equalityI])
   236 apply (simp add: mono_def lists_mono)
   237 apply (blast intro!: lists_IntI)
   238 done
   239 
   240 lemma append_in_lists_conv [iff]:
   241 "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
   242 by (induct xs) auto
   243 
   244 
   245 subsection {* @{text length} *}
   246 
   247 text {*
   248 Needs to come before @{text "@"} because of theorem @{text
   249 append_eq_append_conv}.
   250 *}
   251 
   252 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   253 by (induct xs) auto
   254 
   255 lemma length_map [simp]: "length (map f xs) = length xs"
   256 by (induct xs) auto
   257 
   258 lemma length_rev [simp]: "length (rev xs) = length xs"
   259 by (induct xs) auto
   260 
   261 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   262 by (cases xs) auto
   263 
   264 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   265 by (induct xs) auto
   266 
   267 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   268 by (induct xs) auto
   269 
   270 lemma length_Suc_conv:
   271 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   272 by (induct xs) auto
   273 
   274 
   275 subsection {* @{text "@"} -- append *}
   276 
   277 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   278 by (induct xs) auto
   279 
   280 lemma append_Nil2 [simp]: "xs @ [] = xs"
   281 by (induct xs) auto
   282 
   283 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   284 by (induct xs) auto
   285 
   286 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   287 by (induct xs) auto
   288 
   289 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   290 by (induct xs) auto
   291 
   292 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   293 by (induct xs) auto
   294 
   295 lemma append_eq_append_conv [rule_format, simp]:
   296  "\<forall>ys. length xs = length ys \<or> length us = length vs
   297  --> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   298 apply (induct_tac xs)
   299  apply(rule allI)
   300  apply (case_tac ys)
   301 apply simp
   302  apply force
   303 apply (rule allI)
   304 apply (case_tac ys)
   305  apply force
   306 apply simp
   307 done
   308 
   309 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   310 by simp
   311 
   312 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   313 by simp
   314 
   315 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   316 by simp
   317 
   318 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   319 using append_same_eq [of _ _ "[]"] by auto
   320 
   321 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   322 using append_same_eq [of "[]"] by auto
   323 
   324 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   325 by (induct xs) auto
   326 
   327 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   328 by (induct xs) auto
   329 
   330 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   331 by (simp add: hd_append split: list.split)
   332 
   333 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   334 by (simp split: list.split)
   335 
   336 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   337 by (simp add: tl_append split: list.split)
   338 
   339 
   340 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   341 
   342 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   343 by simp
   344 
   345 lemma Cons_eq_appendI:
   346 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   347 by (drule sym) simp
   348 
   349 lemma append_eq_appendI:
   350 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   351 by (drule sym) simp
   352 
   353 
   354 text {*
   355 Simplification procedure for all list equalities.
   356 Currently only tries to rearrange @{text "@"} to see if
   357 - both lists end in a singleton list,
   358 - or both lists end in the same list.
   359 *}
   360 
   361 ML_setup {*
   362 local
   363 
   364 val append_assoc = thm "append_assoc";
   365 val append_Nil = thm "append_Nil";
   366 val append_Cons = thm "append_Cons";
   367 val append1_eq_conv = thm "append1_eq_conv";
   368 val append_same_eq = thm "append_same_eq";
   369 
   370 val list_eq_pattern =
   371 Thm.read_cterm (Theory.sign_of (the_context ())) ("(xs::'a list) = ys",HOLogic.boolT)
   372 
   373 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   374 (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   375 | last (Const("List.op @",_) $ _ $ ys) = last ys
   376 | last t = t
   377 
   378 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   379 | list1 _ = false
   380 
   381 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   382 (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   383 | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   384 | butlast xs = Const("List.list.Nil",fastype_of xs)
   385 
   386 val rearr_tac =
   387 simp_tac (HOL_basic_ss addsimps [append_assoc,append_Nil,append_Cons])
   388 
   389 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   390 let
   391 val lastl = last lhs and lastr = last rhs
   392 fun rearr conv =
   393 let val lhs1 = butlast lhs and rhs1 = butlast rhs
   394 val Type(_,listT::_) = eqT
   395 val appT = [listT,listT] ---> listT
   396 val app = Const("List.op @",appT)
   397 val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   398 val ct = cterm_of sg (HOLogic.mk_Trueprop(HOLogic.mk_eq(F,F2)))
   399 val thm = prove_goalw_cterm [] ct (K [rearr_tac 1])
   400 handle ERROR =>
   401 error("The error(s) above occurred while trying to prove " ^
   402 string_of_cterm ct)
   403 in Some((conv RS (thm RS trans)) RS eq_reflection) end
   404 
   405 in if list1 lastl andalso list1 lastr
   406  then rearr append1_eq_conv
   407  else
   408  if lastl aconv lastr
   409  then rearr append_same_eq
   410  else None
   411 end
   412 in
   413 val list_eq_simproc = mk_simproc "list_eq" [list_eq_pattern] list_eq
   414 end;
   415 
   416 Addsimprocs [list_eq_simproc];
   417 *}
   418 
   419 
   420 subsection {* @{text map} *}
   421 
   422 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   423 by (induct xs) simp_all
   424 
   425 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   426 by (rule ext, induct_tac xs) auto
   427 
   428 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   429 by (induct xs) auto
   430 
   431 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   432 by (induct xs) (auto simp add: o_def)
   433 
   434 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   435 by (induct xs) auto
   436 
   437 lemma map_cong [recdef_cong]:
   438 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   439 -- {* a congruence rule for @{text map} *}
   440 by (clarify, induct ys) auto
   441 
   442 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   443 by (cases xs) auto
   444 
   445 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   446 by (cases xs) auto
   447 
   448 lemma map_eq_Cons:
   449 "(map f xs = y # ys) = (\<exists>x xs'. xs = x # xs' \<and> f x = y \<and> map f xs' = ys)"
   450 by (cases xs) auto
   451 
   452 lemma map_injective:
   453 "!!xs. map f xs = map f ys ==> (\<forall>x y. f x = f y --> x = y) ==> xs = ys"
   454 by (induct ys) (auto simp add: map_eq_Cons)
   455 
   456 lemma inj_mapI: "inj f ==> inj (map f)"
   457 by (rules dest: map_injective injD intro: injI)
   458 
   459 lemma inj_mapD: "inj (map f) ==> inj f"
   460 apply (unfold inj_on_def)
   461 apply clarify
   462 apply (erule_tac x = "[x]" in ballE)
   463  apply (erule_tac x = "[y]" in ballE)
   464 apply simp
   465  apply blast
   466 apply blast
   467 done
   468 
   469 lemma inj_map: "inj (map f) = inj f"
   470 by (blast dest: inj_mapD intro: inj_mapI)
   471 
   472 
   473 subsection {* @{text rev} *}
   474 
   475 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   476 by (induct xs) auto
   477 
   478 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   479 by (induct xs) auto
   480 
   481 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   482 by (induct xs) auto
   483 
   484 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   485 by (induct xs) auto
   486 
   487 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   488 apply (induct xs)
   489  apply force
   490 apply (case_tac ys)
   491  apply simp
   492 apply force
   493 done
   494 
   495 lemma rev_induct [case_names Nil snoc]:
   496   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   497 apply(subst rev_rev_ident[symmetric])
   498 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   499 done
   500 
   501 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   502 
   503 lemma rev_exhaust [case_names Nil snoc]:
   504   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   505 by (induct xs rule: rev_induct) auto
   506 
   507 lemmas rev_cases = rev_exhaust
   508 
   509 
   510 subsection {* @{text set} *}
   511 
   512 lemma finite_set [iff]: "finite (set xs)"
   513 by (induct xs) auto
   514 
   515 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   516 by (induct xs) auto
   517 
   518 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   519 by auto
   520 
   521 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   522 by (induct xs) auto
   523 
   524 lemma set_rev [simp]: "set (rev xs) = set xs"
   525 by (induct xs) auto
   526 
   527 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   528 by (induct xs) auto
   529 
   530 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   531 by (induct xs) auto
   532 
   533 lemma set_upt [simp]: "set[i..j(] = {k. i \<le> k \<and> k < j}"
   534 apply (induct j)
   535  apply simp_all
   536 apply(erule ssubst)
   537 apply auto
   538 done
   539 
   540 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   541 apply (induct xs)
   542  apply simp
   543 apply simp
   544 apply (rule iffI)
   545  apply (blast intro: eq_Nil_appendI Cons_eq_appendI)
   546 apply (erule exE)+
   547 apply (case_tac ys)
   548 apply auto
   549 done
   550 
   551 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
   552 -- {* eliminate @{text lists} in favour of @{text set} *}
   553 by (induct xs) auto
   554 
   555 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
   556 by (rule in_lists_conv_set [THEN iffD1])
   557 
   558 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
   559 by (rule in_lists_conv_set [THEN iffD2])
   560 
   561 
   562 subsection {* @{text mem} *}
   563 
   564 lemma set_mem_eq: "(x mem xs) = (x : set xs)"
   565 by (induct xs) auto
   566 
   567 
   568 subsection {* @{text list_all} *}
   569 
   570 lemma list_all_conv: "list_all P xs = (\<forall>x \<in> set xs. P x)"
   571 by (induct xs) auto
   572 
   573 lemma list_all_append [simp]:
   574 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
   575 by (induct xs) auto
   576 
   577 
   578 subsection {* @{text filter} *}
   579 
   580 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   581 by (induct xs) auto
   582 
   583 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   584 by (induct xs) auto
   585 
   586 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   587 by (induct xs) auto
   588 
   589 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   590 by (induct xs) auto
   591 
   592 lemma length_filter [simp]: "length (filter P xs) \<le> length xs"
   593 by (induct xs) (auto simp add: le_SucI)
   594 
   595 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   596 by auto
   597 
   598 
   599 subsection {* @{text concat} *}
   600 
   601 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   602 by (induct xs) auto
   603 
   604 lemma concat_eq_Nil_conv [iff]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   605 by (induct xss) auto
   606 
   607 lemma Nil_eq_concat_conv [iff]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   608 by (induct xss) auto
   609 
   610 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   611 by (induct xs) auto
   612 
   613 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   614 by (induct xs) auto
   615 
   616 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   617 by (induct xs) auto
   618 
   619 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   620 by (induct xs) auto
   621 
   622 
   623 subsection {* @{text nth} *}
   624 
   625 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   626 by auto
   627 
   628 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   629 by auto
   630 
   631 declare nth.simps [simp del]
   632 
   633 lemma nth_append:
   634 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   635 apply(induct "xs")
   636  apply simp
   637 apply (case_tac n)
   638  apply auto
   639 done
   640 
   641 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   642 apply(induct xs)
   643  apply simp
   644 apply (case_tac n)
   645  apply auto
   646 done
   647 
   648 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   649 apply (induct_tac xs)
   650  apply simp
   651 apply simp
   652 apply safe
   653 apply (rule_tac x = 0 in exI)
   654 apply simp
   655  apply (rule_tac x = "Suc i" in exI)
   656  apply simp
   657 apply (case_tac i)
   658  apply simp
   659 apply (rename_tac j)
   660 apply (rule_tac x = j in exI)
   661 apply simp
   662 done
   663 
   664 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   665 by (auto simp add: set_conv_nth)
   666 
   667 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   668 by (auto simp add: set_conv_nth)
   669 
   670 lemma all_nth_imp_all_set:
   671 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   672 by (auto simp add: set_conv_nth)
   673 
   674 lemma all_set_conv_all_nth:
   675 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   676 by (auto simp add: set_conv_nth)
   677 
   678 
   679 subsection {* @{text list_update} *}
   680 
   681 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   682 by (induct xs) (auto split: nat.split)
   683 
   684 lemma nth_list_update:
   685 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   686 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   687 
   688 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   689 by (simp add: nth_list_update)
   690 
   691 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   692 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   693 
   694 lemma list_update_overwrite [simp]:
   695 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   696 by (induct xs) (auto split: nat.split)
   697 
   698 lemma list_update_same_conv:
   699 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   700 by (induct xs) (auto split: nat.split)
   701 
   702 lemma update_zip:
   703 "!!i xy xs. length xs = length ys ==>
   704 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   705 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   706 
   707 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   708 by (induct xs) (auto split: nat.split)
   709 
   710 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   711 by (blast dest!: set_update_subset_insert [THEN subsetD])
   712 
   713 
   714 subsection {* @{text last} and @{text butlast} *}
   715 
   716 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   717 by (induct xs) auto
   718 
   719 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   720 by (induct xs) auto
   721 
   722 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
   723 by (induct xs rule: rev_induct) auto
   724 
   725 lemma butlast_append:
   726 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
   727 by (induct xs) auto
   728 
   729 lemma append_butlast_last_id [simp]:
   730 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
   731 by (induct xs) auto
   732 
   733 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
   734 by (induct xs) (auto split: split_if_asm)
   735 
   736 lemma in_set_butlast_appendI:
   737 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
   738 by (auto dest: in_set_butlastD simp add: butlast_append)
   739 
   740 
   741 subsection {* @{text take} and @{text drop} *}
   742 
   743 lemma take_0 [simp]: "take 0 xs = []"
   744 by (induct xs) auto
   745 
   746 lemma drop_0 [simp]: "drop 0 xs = xs"
   747 by (induct xs) auto
   748 
   749 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
   750 by simp
   751 
   752 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
   753 by simp
   754 
   755 declare take_Cons [simp del] and drop_Cons [simp del]
   756 
   757 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
   758 by (induct n) (auto, case_tac xs, auto)
   759 
   760 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
   761 by (induct n) (auto, case_tac xs, auto)
   762 
   763 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
   764 by (induct n) (auto, case_tac xs, auto)
   765 
   766 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
   767 by (induct n) (auto, case_tac xs, auto)
   768 
   769 lemma take_append [simp]:
   770 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
   771 by (induct n) (auto, case_tac xs, auto)
   772 
   773 lemma drop_append [simp]:
   774 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
   775 by (induct n) (auto, case_tac xs, auto)
   776 
   777 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
   778 apply (induct m)
   779  apply auto
   780 apply (case_tac xs)
   781  apply auto
   782 apply (case_tac na)
   783  apply auto
   784 done
   785 
   786 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
   787 apply (induct m)
   788  apply auto
   789 apply (case_tac xs)
   790  apply auto
   791 done
   792 
   793 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
   794 apply (induct m)
   795  apply auto
   796 apply (case_tac xs)
   797  apply auto
   798 done
   799 
   800 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
   801 apply (induct n)
   802  apply auto
   803 apply (case_tac xs)
   804  apply auto
   805 done
   806 
   807 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
   808 apply (induct n)
   809  apply auto
   810 apply (case_tac xs)
   811  apply auto
   812 done
   813 
   814 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
   815 apply (induct n)
   816  apply auto
   817 apply (case_tac xs)
   818  apply auto
   819 done
   820 
   821 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
   822 apply (induct xs)
   823  apply auto
   824 apply (case_tac i)
   825  apply auto
   826 done
   827 
   828 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
   829 apply (induct xs)
   830  apply auto
   831 apply (case_tac i)
   832  apply auto
   833 done
   834 
   835 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
   836 apply (induct xs)
   837  apply auto
   838 apply (case_tac n)
   839  apply(blast )
   840 apply (case_tac i)
   841  apply auto
   842 done
   843 
   844 lemma nth_drop [simp]:
   845 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
   846 apply (induct n)
   847  apply auto
   848 apply (case_tac xs)
   849  apply auto
   850 done
   851 
   852 lemma append_eq_conv_conj:
   853 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
   854 apply(induct xs)
   855  apply simp
   856 apply clarsimp
   857 apply (case_tac zs)
   858 apply auto
   859 done
   860 
   861 
   862 subsection {* @{text takeWhile} and @{text dropWhile} *}
   863 
   864 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
   865 by (induct xs) auto
   866 
   867 lemma takeWhile_append1 [simp]:
   868 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
   869 by (induct xs) auto
   870 
   871 lemma takeWhile_append2 [simp]:
   872 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
   873 by (induct xs) auto
   874 
   875 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
   876 by (induct xs) auto
   877 
   878 lemma dropWhile_append1 [simp]:
   879 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
   880 by (induct xs) auto
   881 
   882 lemma dropWhile_append2 [simp]:
   883 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
   884 by (induct xs) auto
   885 
   886 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
   887 by (induct xs) (auto split: split_if_asm)
   888 
   889 
   890 subsection {* @{text zip} *}
   891 
   892 lemma zip_Nil [simp]: "zip [] ys = []"
   893 by (induct ys) auto
   894 
   895 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
   896 by simp
   897 
   898 declare zip_Cons [simp del]
   899 
   900 lemma length_zip [simp]:
   901 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
   902 apply(induct ys)
   903  apply simp
   904 apply (case_tac xs)
   905  apply auto
   906 done
   907 
   908 lemma zip_append1:
   909 "!!xs. zip (xs @ ys) zs =
   910 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
   911 apply (induct zs)
   912  apply simp
   913 apply (case_tac xs)
   914  apply simp_all
   915 done
   916 
   917 lemma zip_append2:
   918 "!!ys. zip xs (ys @ zs) =
   919 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
   920 apply (induct xs)
   921  apply simp
   922 apply (case_tac ys)
   923  apply simp_all
   924 done
   925 
   926 lemma zip_append [simp]:
   927  "[| length xs = length us; length ys = length vs |] ==>
   928 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
   929 by (simp add: zip_append1)
   930 
   931 lemma zip_rev:
   932 "!!xs. length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
   933 apply(induct ys)
   934  apply simp
   935 apply (case_tac xs)
   936  apply simp_all
   937 done
   938 
   939 lemma nth_zip [simp]:
   940 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
   941 apply (induct ys)
   942  apply simp
   943 apply (case_tac xs)
   944  apply (simp_all add: nth.simps split: nat.split)
   945 done
   946 
   947 lemma set_zip:
   948 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
   949 by (simp add: set_conv_nth cong: rev_conj_cong)
   950 
   951 lemma zip_update:
   952 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
   953 by (rule sym, simp add: update_zip)
   954 
   955 lemma zip_replicate [simp]:
   956 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
   957 apply (induct i)
   958  apply auto
   959 apply (case_tac j)
   960  apply auto
   961 done
   962 
   963 
   964 subsection {* @{text list_all2} *}
   965 
   966 lemma list_all2_lengthD: "list_all2 P xs ys ==> length xs = length ys"
   967 by (simp add: list_all2_def)
   968 
   969 lemma list_all2_Nil [iff]: "list_all2 P [] ys = (ys = [])"
   970 by (simp add: list_all2_def)
   971 
   972 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
   973 by (simp add: list_all2_def)
   974 
   975 lemma list_all2_Cons [iff]:
   976 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
   977 by (auto simp add: list_all2_def)
   978 
   979 lemma list_all2_Cons1:
   980 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
   981 by (cases ys) auto
   982 
   983 lemma list_all2_Cons2:
   984 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
   985 by (cases xs) auto
   986 
   987 lemma list_all2_rev [iff]:
   988 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
   989 by (simp add: list_all2_def zip_rev cong: conj_cong)
   990 
   991 lemma list_all2_append1:
   992 "list_all2 P (xs @ ys) zs =
   993 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
   994 list_all2 P xs us \<and> list_all2 P ys vs)"
   995 apply (simp add: list_all2_def zip_append1)
   996 apply (rule iffI)
   997  apply (rule_tac x = "take (length xs) zs" in exI)
   998  apply (rule_tac x = "drop (length xs) zs" in exI)
   999  apply (force split: nat_diff_split simp add: min_def)
  1000 apply clarify
  1001 apply (simp add: ball_Un)
  1002 done
  1003 
  1004 lemma list_all2_append2:
  1005 "list_all2 P xs (ys @ zs) =
  1006 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1007 list_all2 P us ys \<and> list_all2 P vs zs)"
  1008 apply (simp add: list_all2_def zip_append2)
  1009 apply (rule iffI)
  1010  apply (rule_tac x = "take (length ys) xs" in exI)
  1011  apply (rule_tac x = "drop (length ys) xs" in exI)
  1012  apply (force split: nat_diff_split simp add: min_def)
  1013 apply clarify
  1014 apply (simp add: ball_Un)
  1015 done
  1016 
  1017 lemma list_all2_conv_all_nth:
  1018 "list_all2 P xs ys =
  1019 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1020 by (force simp add: list_all2_def set_zip)
  1021 
  1022 lemma list_all2_trans[rule_format]:
  1023 "\<forall>a b c. P1 a b --> P2 b c --> P3 a c ==>
  1024 \<forall>bs cs. list_all2 P1 as bs --> list_all2 P2 bs cs --> list_all2 P3 as cs"
  1025 apply(induct_tac as)
  1026  apply simp
  1027 apply(rule allI)
  1028 apply(induct_tac bs)
  1029  apply simp
  1030 apply(rule allI)
  1031 apply(induct_tac cs)
  1032  apply auto
  1033 done
  1034 
  1035 
  1036 subsection {* @{text foldl} *}
  1037 
  1038 lemma foldl_append [simp]:
  1039 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1040 by (induct xs) auto
  1041 
  1042 text {*
  1043 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1044 difficult to use because it requires an additional transitivity step.
  1045 *}
  1046 
  1047 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1048 by (induct ns) auto
  1049 
  1050 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1051 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1052 
  1053 lemma sum_eq_0_conv [iff]:
  1054 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1055 by (induct ns) auto
  1056 
  1057 
  1058 subsection {* @{text upto} *}
  1059 
  1060 lemma upt_rec: "[i..j(] = (if i<j then i#[Suc i..j(] else [])"
  1061 -- {* Does not terminate! *}
  1062 by (induct j) auto
  1063 
  1064 lemma upt_conv_Nil [simp]: "j <= i ==> [i..j(] = []"
  1065 by (subst upt_rec) simp
  1066 
  1067 lemma upt_Suc_append: "i <= j ==> [i..(Suc j)(] = [i..j(]@[j]"
  1068 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1069 by simp
  1070 
  1071 lemma upt_conv_Cons: "i < j ==> [i..j(] = i # [Suc i..j(]"
  1072 apply(rule trans)
  1073 apply(subst upt_rec)
  1074  prefer 2 apply(rule refl)
  1075 apply simp
  1076 done
  1077 
  1078 lemma upt_add_eq_append: "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]"
  1079 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1080 by (induct k) auto
  1081 
  1082 lemma length_upt [simp]: "length [i..j(] = j - i"
  1083 by (induct j) (auto simp add: Suc_diff_le)
  1084 
  1085 lemma nth_upt [simp]: "i + k < j ==> [i..j(] ! k = i + k"
  1086 apply (induct j)
  1087 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1088 done
  1089 
  1090 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..n(] = [i..i+m(]"
  1091 apply (induct m)
  1092  apply simp
  1093 apply (subst upt_rec)
  1094 apply (rule sym)
  1095 apply (subst upt_rec)
  1096 apply (simp del: upt.simps)
  1097 done
  1098 
  1099 lemma map_Suc_upt: "map Suc [m..n(] = [Suc m..n]"
  1100 by (induct n) auto
  1101 
  1102 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..n(]) ! i = f(m+i)"
  1103 apply (induct n m rule: diff_induct)
  1104 prefer 3 apply (subst map_Suc_upt[symmetric])
  1105 apply (auto simp add: less_diff_conv nth_upt)
  1106 done
  1107 
  1108 lemma nth_take_lemma [rule_format]:
  1109 "ALL xs ys. k <= length xs --> k <= length ys
  1110 --> (ALL i. i < k --> xs!i = ys!i)
  1111 --> take k xs = take k ys"
  1112 apply (induct k)
  1113 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib)
  1114 apply clarify
  1115 txt {* Both lists must be non-empty *}
  1116 apply (case_tac xs)
  1117  apply simp
  1118 apply (case_tac ys)
  1119  apply clarify
  1120  apply (simp (no_asm_use))
  1121 apply clarify
  1122 txt {* prenexing's needed, not miniscoping *}
  1123 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1124 apply blast
  1125 done
  1126 
  1127 lemma nth_equalityI:
  1128  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1129 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1130 apply (simp_all add: take_all)
  1131 done
  1132 
  1133 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1134 -- {* The famous take-lemma. *}
  1135 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1136 apply (simp add: le_max_iff_disj take_all)
  1137 done
  1138 
  1139 
  1140 subsection {* @{text "distinct"} and @{text remdups} *}
  1141 
  1142 lemma distinct_append [simp]:
  1143 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1144 by (induct xs) auto
  1145 
  1146 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1147 by (induct xs) (auto simp add: insert_absorb)
  1148 
  1149 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1150 by (induct xs) auto
  1151 
  1152 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1153 by (induct xs) auto
  1154 
  1155 text {*
  1156 It is best to avoid this indexed version of distinct, but sometimes
  1157 it is useful. *}
  1158 lemma distinct_conv_nth:
  1159 "distinct xs = (\<forall>i j. i < size xs \<and> j < size xs \<and> i \<noteq> j --> xs!i \<noteq> xs!j)"
  1160 apply (induct_tac xs)
  1161  apply simp
  1162 apply simp
  1163 apply (rule iffI)
  1164  apply clarsimp
  1165  apply (case_tac i)
  1166 apply (case_tac j)
  1167  apply simp
  1168 apply (simp add: set_conv_nth)
  1169  apply (case_tac j)
  1170 apply (clarsimp simp add: set_conv_nth)
  1171  apply simp
  1172 apply (rule conjI)
  1173  apply (clarsimp simp add: set_conv_nth)
  1174  apply (erule_tac x = 0 in allE)
  1175  apply (erule_tac x = "Suc i" in allE)
  1176  apply simp
  1177 apply clarsimp
  1178 apply (erule_tac x = "Suc i" in allE)
  1179 apply (erule_tac x = "Suc j" in allE)
  1180 apply simp
  1181 done
  1182 
  1183 
  1184 subsection {* @{text replicate} *}
  1185 
  1186 lemma length_replicate [simp]: "length (replicate n x) = n"
  1187 by (induct n) auto
  1188 
  1189 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1190 by (induct n) auto
  1191 
  1192 lemma replicate_app_Cons_same:
  1193 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1194 by (induct n) auto
  1195 
  1196 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1197 apply(induct n)
  1198  apply simp
  1199 apply (simp add: replicate_app_Cons_same)
  1200 done
  1201 
  1202 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1203 by (induct n) auto
  1204 
  1205 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1206 by (induct n) auto
  1207 
  1208 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1209 by (induct n) auto
  1210 
  1211 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1212 by (atomize (full), induct n) auto
  1213 
  1214 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1215 apply(induct n)
  1216  apply simp
  1217 apply (simp add: nth_Cons split: nat.split)
  1218 done
  1219 
  1220 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1221 by (induct n) auto
  1222 
  1223 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1224 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1225 
  1226 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1227 by auto
  1228 
  1229 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1230 by (simp add: set_replicate_conv_if split: split_if_asm)
  1231 
  1232 
  1233 subsection {* Lexcicographic orderings on lists *}
  1234 
  1235 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  1236 apply (induct_tac n)
  1237  apply simp
  1238 apply simp
  1239 apply(rule wf_subset)
  1240  prefer 2 apply (rule Int_lower1)
  1241 apply(rule wf_prod_fun_image)
  1242  prefer 2 apply (rule injI)
  1243 apply auto
  1244 done
  1245 
  1246 lemma lexn_length:
  1247 "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  1248 by (induct n) auto
  1249 
  1250 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  1251 apply (unfold lex_def)
  1252 apply (rule wf_UN)
  1253 apply (blast intro: wf_lexn)
  1254 apply clarify
  1255 apply (rename_tac m n)
  1256 apply (subgoal_tac "m \<noteq> n")
  1257  prefer 2 apply blast
  1258 apply (blast dest: lexn_length not_sym)
  1259 done
  1260 
  1261 lemma lexn_conv:
  1262 "lexn r n =
  1263 {(xs,ys). length xs = n \<and> length ys = n \<and>
  1264 (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  1265 apply (induct_tac n)
  1266  apply simp
  1267  apply blast
  1268 apply (simp add: image_Collect lex_prod_def)
  1269 apply auto
  1270 apply blast
  1271  apply (rename_tac a xys x xs' y ys')
  1272  apply (rule_tac x = "a # xys" in exI)
  1273  apply simp
  1274 apply (case_tac xys)
  1275  apply simp_all
  1276 apply blast
  1277 done
  1278 
  1279 lemma lex_conv:
  1280 "lex r =
  1281 {(xs,ys). length xs = length ys \<and>
  1282 (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  1283 by (force simp add: lex_def lexn_conv)
  1284 
  1285 lemma wf_lexico [intro!]: "wf r ==> wf (lexico r)"
  1286 by (unfold lexico_def) blast
  1287 
  1288 lemma lexico_conv:
  1289 "lexico r = {(xs,ys). length xs < length ys |
  1290 length xs = length ys \<and> (xs, ys) : lex r}"
  1291 by (simp add: lexico_def diag_def lex_prod_def measure_def inv_image_def)
  1292 
  1293 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  1294 by (simp add: lex_conv)
  1295 
  1296 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  1297 by (simp add:lex_conv)
  1298 
  1299 lemma Cons_in_lex [iff]:
  1300 "((x # xs, y # ys) : lex r) =
  1301 ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  1302 apply (simp add: lex_conv)
  1303 apply (rule iffI)
  1304  prefer 2 apply (blast intro: Cons_eq_appendI)
  1305 apply clarify
  1306 apply (case_tac xys)
  1307  apply simp
  1308 apply simp
  1309 apply blast
  1310 done
  1311 
  1312 
  1313 subsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  1314 
  1315 lemma sublist_empty [simp]: "sublist xs {} = []"
  1316 by (auto simp add: sublist_def)
  1317 
  1318 lemma sublist_nil [simp]: "sublist [] A = []"
  1319 by (auto simp add: sublist_def)
  1320 
  1321 lemma sublist_shift_lemma:
  1322 "map fst [p:zip xs [i..i + length xs(] . snd p : A] =
  1323 map fst [p:zip xs [0..length xs(] . snd p + i : A]"
  1324 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  1325 
  1326 lemma sublist_append:
  1327 "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  1328 apply (unfold sublist_def)
  1329 apply (induct l' rule: rev_induct)
  1330  apply simp
  1331 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  1332 apply (simp add: add_commute)
  1333 done
  1334 
  1335 lemma sublist_Cons:
  1336 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  1337 apply (induct l rule: rev_induct)
  1338  apply (simp add: sublist_def)
  1339 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  1340 done
  1341 
  1342 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  1343 by (simp add: sublist_Cons)
  1344 
  1345 lemma sublist_upt_eq_take [simp]: "sublist l {..n(} = take n l"
  1346 apply (induct l rule: rev_induct)
  1347  apply simp
  1348 apply (simp split: nat_diff_split add: sublist_append)
  1349 done
  1350 
  1351 
  1352 lemma take_Cons':
  1353 "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1354 by (cases n) simp_all
  1355 
  1356 lemma drop_Cons':
  1357 "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1358 by (cases n) simp_all
  1359 
  1360 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1361 by (cases n) simp_all
  1362 
  1363 lemmas [simp] = take_Cons'[of "number_of v",standard]
  1364                 drop_Cons'[of "number_of v",standard]
  1365                 nth_Cons'[of _ _ "number_of v",standard]
  1366 
  1367 subsection {* Characters and strings *}
  1368 
  1369 datatype nibble =
  1370     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  1371   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  1372 
  1373 datatype char = Char nibble nibble
  1374   -- "Note: canonical order of character encoding coincides with standard term ordering"
  1375 
  1376 types string = "char list"
  1377 
  1378 syntax
  1379   "_Char" :: "xstr => char"    ("CHR _")
  1380   "_String" :: "xstr => string"    ("_")
  1381 
  1382 parse_ast_translation {*
  1383   let
  1384     val constants = Syntax.Appl o map Syntax.Constant;
  1385 
  1386     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  1387     fun mk_char c =
  1388       if Symbol.is_ascii c andalso Symbol.is_printable c then
  1389         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  1390       else error ("Printable ASCII character expected: " ^ quote c);
  1391 
  1392     fun mk_string [] = Syntax.Constant "Nil"
  1393       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  1394 
  1395     fun char_ast_tr [Syntax.Variable xstr] =
  1396         (case Syntax.explode_xstr xstr of
  1397           [c] => mk_char c
  1398         | _ => error ("Single character expected: " ^ xstr))
  1399       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  1400 
  1401     fun string_ast_tr [Syntax.Variable xstr] =
  1402         (case Syntax.explode_xstr xstr of
  1403           [] => constants [Syntax.constrainC, "Nil", "string"]
  1404         | cs => mk_string cs)
  1405       | string_ast_tr asts = raise AST ("string_tr", asts);
  1406   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  1407 *}
  1408 
  1409 print_ast_translation {*
  1410   let
  1411     fun dest_nib (Syntax.Constant c) =
  1412         (case explode c of
  1413           ["N", "i", "b", "b", "l", "e", h] =>
  1414             if "0" <= h andalso h <= "9" then ord h - ord "0"
  1415             else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  1416             else raise Match
  1417         | _ => raise Match)
  1418       | dest_nib _ = raise Match;
  1419 
  1420     fun dest_chr c1 c2 =
  1421       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  1422       in if Symbol.is_printable c then c else raise Match end;
  1423 
  1424     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  1425       | dest_char _ = raise Match;
  1426 
  1427     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  1428 
  1429     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  1430       | char_ast_tr' _ = raise Match;
  1431 
  1432     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  1433             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  1434       | list_ast_tr' ts = raise Match;
  1435   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  1436 *}
  1437 
  1438 end