src/HOL/Set_Interval.thy
author blanchet
Thu Sep 11 18:54:36 2014 +0200 (2014-09-11)
changeset 58306 117ba6cbe414
parent 57514 bdc2c6b40bf2
child 58889 5b7a9633cfa8
permissions -rw-r--r--
renamed 'rep_datatype' to 'old_rep_datatype' (HOL)
     1 (*  Title:      HOL/Set_Interval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 
     8 Modern convention: Ixy stands for an interval where x and y
     9 describe the lower and upper bound and x,y : {c,o,i}
    10 where c = closed, o = open, i = infinite.
    11 Examples: Ico = {_ ..< _} and Ici = {_ ..}
    12 *)
    13 
    14 header {* Set intervals *}
    15 
    16 theory Set_Interval
    17 imports Lattices_Big Nat_Transfer
    18 begin
    19 
    20 context ord
    21 begin
    22 
    23 definition
    24   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    25   "{..<u} == {x. x < u}"
    26 
    27 definition
    28   atMost      :: "'a => 'a set" ("(1{.._})") where
    29   "{..u} == {x. x \<le> u}"
    30 
    31 definition
    32   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    33   "{l<..} == {x. l<x}"
    34 
    35 definition
    36   atLeast     :: "'a => 'a set" ("(1{_..})") where
    37   "{l..} == {x. l\<le>x}"
    38 
    39 definition
    40   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    41   "{l<..<u} == {l<..} Int {..<u}"
    42 
    43 definition
    44   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    45   "{l..<u} == {l..} Int {..<u}"
    46 
    47 definition
    48   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    49   "{l<..u} == {l<..} Int {..u}"
    50 
    51 definition
    52   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    53   "{l..u} == {l..} Int {..u}"
    54 
    55 end
    56 
    57 
    58 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    59 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    60 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    61 
    62 syntax
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" [0, 0, 10] 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" [0, 0, 10] 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" [0, 0, 10] 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (xsymbols)
    69   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" [0, 0, 10] 10)
    70   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" [0, 0, 10] 10)
    71   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" [0, 0, 10] 10)
    72   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" [0, 0, 10] 10)
    73 
    74 syntax (latex output)
    75   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    76   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" [0, 0, 10] 10)
    77   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    78   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" [0, 0, 10] 10)
    79 
    80 translations
    81   "UN i<=n. A"  == "UN i:{..n}. A"
    82   "UN i<n. A"   == "UN i:{..<n}. A"
    83   "INT i<=n. A" == "INT i:{..n}. A"
    84   "INT i<n. A"  == "INT i:{..<n}. A"
    85 
    86 
    87 subsection {* Various equivalences *}
    88 
    89 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    90 by (simp add: lessThan_def)
    91 
    92 lemma Compl_lessThan [simp]:
    93     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    94 apply (auto simp add: lessThan_def atLeast_def)
    95 done
    96 
    97 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    98 by auto
    99 
   100 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
   101 by (simp add: greaterThan_def)
   102 
   103 lemma Compl_greaterThan [simp]:
   104     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   105   by (auto simp add: greaterThan_def atMost_def)
   106 
   107 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   108 apply (subst Compl_greaterThan [symmetric])
   109 apply (rule double_complement)
   110 done
   111 
   112 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   113 by (simp add: atLeast_def)
   114 
   115 lemma Compl_atLeast [simp]:
   116     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   117   by (auto simp add: lessThan_def atLeast_def)
   118 
   119 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   120 by (simp add: atMost_def)
   121 
   122 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   123 by (blast intro: order_antisym)
   124 
   125 lemma (in linorder) lessThan_Int_lessThan: "{ a <..} \<inter> { b <..} = { max a b <..}"
   126   by auto
   127 
   128 lemma (in linorder) greaterThan_Int_greaterThan: "{..< a} \<inter> {..< b} = {..< min a b}"
   129   by auto
   130 
   131 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   132 
   133 lemma atLeast_subset_iff [iff]:
   134      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   135 by (blast intro: order_trans)
   136 
   137 lemma atLeast_eq_iff [iff]:
   138      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   139 by (blast intro: order_antisym order_trans)
   140 
   141 lemma greaterThan_subset_iff [iff]:
   142      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   143 apply (auto simp add: greaterThan_def)
   144  apply (subst linorder_not_less [symmetric], blast)
   145 done
   146 
   147 lemma greaterThan_eq_iff [iff]:
   148      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   149 apply (rule iffI)
   150  apply (erule equalityE)
   151  apply simp_all
   152 done
   153 
   154 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   155 by (blast intro: order_trans)
   156 
   157 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   158 by (blast intro: order_antisym order_trans)
   159 
   160 lemma lessThan_subset_iff [iff]:
   161      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   162 apply (auto simp add: lessThan_def)
   163  apply (subst linorder_not_less [symmetric], blast)
   164 done
   165 
   166 lemma lessThan_eq_iff [iff]:
   167      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   168 apply (rule iffI)
   169  apply (erule equalityE)
   170  apply simp_all
   171 done
   172 
   173 lemma lessThan_strict_subset_iff:
   174   fixes m n :: "'a::linorder"
   175   shows "{..<m} < {..<n} \<longleftrightarrow> m < n"
   176   by (metis leD lessThan_subset_iff linorder_linear not_less_iff_gr_or_eq psubset_eq)
   177 
   178 lemma (in linorder) Ici_subset_Ioi_iff: "{a ..} \<subseteq> {b <..} \<longleftrightarrow> b < a"
   179   by auto
   180 
   181 lemma (in linorder) Iic_subset_Iio_iff: "{.. a} \<subseteq> {..< b} \<longleftrightarrow> a < b"
   182   by auto
   183 
   184 subsection {*Two-sided intervals*}
   185 
   186 context ord
   187 begin
   188 
   189 lemma greaterThanLessThan_iff [simp]:
   190   "(i : {l<..<u}) = (l < i & i < u)"
   191 by (simp add: greaterThanLessThan_def)
   192 
   193 lemma atLeastLessThan_iff [simp]:
   194   "(i : {l..<u}) = (l <= i & i < u)"
   195 by (simp add: atLeastLessThan_def)
   196 
   197 lemma greaterThanAtMost_iff [simp]:
   198   "(i : {l<..u}) = (l < i & i <= u)"
   199 by (simp add: greaterThanAtMost_def)
   200 
   201 lemma atLeastAtMost_iff [simp]:
   202   "(i : {l..u}) = (l <= i & i <= u)"
   203 by (simp add: atLeastAtMost_def)
   204 
   205 text {* The above four lemmas could be declared as iffs. Unfortunately this
   206 breaks many proofs. Since it only helps blast, it is better to leave them
   207 alone. *}
   208 
   209 lemma greaterThanLessThan_eq: "{ a <..< b} = { a <..} \<inter> {..< b }"
   210   by auto
   211 
   212 end
   213 
   214 subsubsection{* Emptyness, singletons, subset *}
   215 
   216 context order
   217 begin
   218 
   219 lemma atLeastatMost_empty[simp]:
   220   "b < a \<Longrightarrow> {a..b} = {}"
   221 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   222 
   223 lemma atLeastatMost_empty_iff[simp]:
   224   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   225 by auto (blast intro: order_trans)
   226 
   227 lemma atLeastatMost_empty_iff2[simp]:
   228   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   229 by auto (blast intro: order_trans)
   230 
   231 lemma atLeastLessThan_empty[simp]:
   232   "b <= a \<Longrightarrow> {a..<b} = {}"
   233 by(auto simp: atLeastLessThan_def)
   234 
   235 lemma atLeastLessThan_empty_iff[simp]:
   236   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   237 by auto (blast intro: le_less_trans)
   238 
   239 lemma atLeastLessThan_empty_iff2[simp]:
   240   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   241 by auto (blast intro: le_less_trans)
   242 
   243 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   244 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   245 
   246 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   247 by auto (blast intro: less_le_trans)
   248 
   249 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   250 by auto (blast intro: less_le_trans)
   251 
   252 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   253 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   254 
   255 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   256 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   257 
   258 lemma atLeastAtMost_singleton': "a = b \<Longrightarrow> {a .. b} = {a}" by simp
   259 
   260 lemma atLeastatMost_subset_iff[simp]:
   261   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   262 unfolding atLeastAtMost_def atLeast_def atMost_def
   263 by (blast intro: order_trans)
   264 
   265 lemma atLeastatMost_psubset_iff:
   266   "{a..b} < {c..d} \<longleftrightarrow>
   267    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   268 by(simp add: psubset_eq set_eq_iff less_le_not_le)(blast intro: order_trans)
   269 
   270 lemma Icc_eq_Icc[simp]:
   271   "{l..h} = {l'..h'} = (l=l' \<and> h=h' \<or> \<not> l\<le>h \<and> \<not> l'\<le>h')"
   272 by(simp add: order_class.eq_iff)(auto intro: order_trans)
   273 
   274 lemma atLeastAtMost_singleton_iff[simp]:
   275   "{a .. b} = {c} \<longleftrightarrow> a = b \<and> b = c"
   276 proof
   277   assume "{a..b} = {c}"
   278   hence *: "\<not> (\<not> a \<le> b)" unfolding atLeastatMost_empty_iff[symmetric] by simp
   279   with `{a..b} = {c}` have "c \<le> a \<and> b \<le> c" by auto
   280   with * show "a = b \<and> b = c" by auto
   281 qed simp
   282 
   283 lemma Icc_subset_Ici_iff[simp]:
   284   "{l..h} \<subseteq> {l'..} = (~ l\<le>h \<or> l\<ge>l')"
   285 by(auto simp: subset_eq intro: order_trans)
   286 
   287 lemma Icc_subset_Iic_iff[simp]:
   288   "{l..h} \<subseteq> {..h'} = (~ l\<le>h \<or> h\<le>h')"
   289 by(auto simp: subset_eq intro: order_trans)
   290 
   291 lemma not_Ici_eq_empty[simp]: "{l..} \<noteq> {}"
   292 by(auto simp: set_eq_iff)
   293 
   294 lemma not_Iic_eq_empty[simp]: "{..h} \<noteq> {}"
   295 by(auto simp: set_eq_iff)
   296 
   297 lemmas not_empty_eq_Ici_eq_empty[simp] = not_Ici_eq_empty[symmetric]
   298 lemmas not_empty_eq_Iic_eq_empty[simp] = not_Iic_eq_empty[symmetric]
   299 
   300 end
   301 
   302 context no_top
   303 begin
   304 
   305 (* also holds for no_bot but no_top should suffice *)
   306 lemma not_UNIV_le_Icc[simp]: "\<not> UNIV \<subseteq> {l..h}"
   307 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   308 
   309 lemma not_UNIV_le_Iic[simp]: "\<not> UNIV \<subseteq> {..h}"
   310 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   311 
   312 lemma not_Ici_le_Icc[simp]: "\<not> {l..} \<subseteq> {l'..h'}"
   313 using gt_ex[of h']
   314 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   315 
   316 lemma not_Ici_le_Iic[simp]: "\<not> {l..} \<subseteq> {..h'}"
   317 using gt_ex[of h']
   318 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   319 
   320 end
   321 
   322 context no_bot
   323 begin
   324 
   325 lemma not_UNIV_le_Ici[simp]: "\<not> UNIV \<subseteq> {l..}"
   326 using lt_ex[of l] by(auto simp: subset_eq less_le_not_le)
   327 
   328 lemma not_Iic_le_Icc[simp]: "\<not> {..h} \<subseteq> {l'..h'}"
   329 using lt_ex[of l']
   330 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   331 
   332 lemma not_Iic_le_Ici[simp]: "\<not> {..h} \<subseteq> {l'..}"
   333 using lt_ex[of l']
   334 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   335 
   336 end
   337 
   338 
   339 context no_top
   340 begin
   341 
   342 (* also holds for no_bot but no_top should suffice *)
   343 lemma not_UNIV_eq_Icc[simp]: "\<not> UNIV = {l'..h'}"
   344 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   345 
   346 lemmas not_Icc_eq_UNIV[simp] = not_UNIV_eq_Icc[symmetric]
   347 
   348 lemma not_UNIV_eq_Iic[simp]: "\<not> UNIV = {..h'}"
   349 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   350 
   351 lemmas not_Iic_eq_UNIV[simp] = not_UNIV_eq_Iic[symmetric]
   352 
   353 lemma not_Icc_eq_Ici[simp]: "\<not> {l..h} = {l'..}"
   354 unfolding atLeastAtMost_def using not_Ici_le_Iic[of l'] by blast
   355 
   356 lemmas not_Ici_eq_Icc[simp] = not_Icc_eq_Ici[symmetric]
   357 
   358 (* also holds for no_bot but no_top should suffice *)
   359 lemma not_Iic_eq_Ici[simp]: "\<not> {..h} = {l'..}"
   360 using not_Ici_le_Iic[of l' h] by blast
   361 
   362 lemmas not_Ici_eq_Iic[simp] = not_Iic_eq_Ici[symmetric]
   363 
   364 end
   365 
   366 context no_bot
   367 begin
   368 
   369 lemma not_UNIV_eq_Ici[simp]: "\<not> UNIV = {l'..}"
   370 using lt_ex[of l'] by(auto simp: set_eq_iff  less_le_not_le)
   371 
   372 lemmas not_Ici_eq_UNIV[simp] = not_UNIV_eq_Ici[symmetric]
   373 
   374 lemma not_Icc_eq_Iic[simp]: "\<not> {l..h} = {..h'}"
   375 unfolding atLeastAtMost_def using not_Iic_le_Ici[of h'] by blast
   376 
   377 lemmas not_Iic_eq_Icc[simp] = not_Icc_eq_Iic[symmetric]
   378 
   379 end
   380 
   381 
   382 context dense_linorder
   383 begin
   384 
   385 lemma greaterThanLessThan_empty_iff[simp]:
   386   "{ a <..< b } = {} \<longleftrightarrow> b \<le> a"
   387   using dense[of a b] by (cases "a < b") auto
   388 
   389 lemma greaterThanLessThan_empty_iff2[simp]:
   390   "{} = { a <..< b } \<longleftrightarrow> b \<le> a"
   391   using dense[of a b] by (cases "a < b") auto
   392 
   393 lemma atLeastLessThan_subseteq_atLeastAtMost_iff:
   394   "{a ..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   395   using dense[of "max a d" "b"]
   396   by (force simp: subset_eq Ball_def not_less[symmetric])
   397 
   398 lemma greaterThanAtMost_subseteq_atLeastAtMost_iff:
   399   "{a <.. b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   400   using dense[of "a" "min c b"]
   401   by (force simp: subset_eq Ball_def not_less[symmetric])
   402 
   403 lemma greaterThanLessThan_subseteq_atLeastAtMost_iff:
   404   "{a <..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   405   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   406   by (force simp: subset_eq Ball_def not_less[symmetric])
   407 
   408 lemma atLeastAtMost_subseteq_atLeastLessThan_iff:
   409   "{a .. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a \<le> b \<longrightarrow> c \<le> a \<and> b < d)"
   410   using dense[of "max a d" "b"]
   411   by (force simp: subset_eq Ball_def not_less[symmetric])
   412 
   413 lemma greaterThanAtMost_subseteq_atLeastLessThan_iff:
   414   "{a <.. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b < d)"
   415   using dense[of "a" "min c b"]
   416   by (force simp: subset_eq Ball_def not_less[symmetric])
   417 
   418 lemma greaterThanLessThan_subseteq_atLeastLessThan_iff:
   419   "{a <..< b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   420   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   421   by (force simp: subset_eq Ball_def not_less[symmetric])
   422 
   423 lemma greaterThanLessThan_subseteq_greaterThanAtMost_iff:
   424   "{a <..< b} \<subseteq> { c <.. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   425   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   426   by (force simp: subset_eq Ball_def not_less[symmetric])
   427 
   428 end
   429 
   430 context no_top
   431 begin
   432 
   433 lemma greaterThan_non_empty[simp]: "{x <..} \<noteq> {}"
   434   using gt_ex[of x] by auto
   435 
   436 end
   437 
   438 context no_bot
   439 begin
   440 
   441 lemma lessThan_non_empty[simp]: "{..< x} \<noteq> {}"
   442   using lt_ex[of x] by auto
   443 
   444 end
   445 
   446 lemma (in linorder) atLeastLessThan_subset_iff:
   447   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   448 apply (auto simp:subset_eq Ball_def)
   449 apply(frule_tac x=a in spec)
   450 apply(erule_tac x=d in allE)
   451 apply (simp add: less_imp_le)
   452 done
   453 
   454 lemma atLeastLessThan_inj:
   455   fixes a b c d :: "'a::linorder"
   456   assumes eq: "{a ..< b} = {c ..< d}" and "a < b" "c < d"
   457   shows "a = c" "b = d"
   458 using assms by (metis atLeastLessThan_subset_iff eq less_le_not_le linorder_antisym_conv2 subset_refl)+
   459 
   460 lemma atLeastLessThan_eq_iff:
   461   fixes a b c d :: "'a::linorder"
   462   assumes "a < b" "c < d"
   463   shows "{a ..< b} = {c ..< d} \<longleftrightarrow> a = c \<and> b = d"
   464   using atLeastLessThan_inj assms by auto
   465 
   466 lemma (in linorder) Ioc_inj: "{a <.. b} = {c <.. d} \<longleftrightarrow> (b \<le> a \<and> d \<le> c) \<or> a = c \<and> b = d"
   467   by (metis eq_iff greaterThanAtMost_empty_iff2 greaterThanAtMost_iff le_cases not_le)
   468 
   469 lemma (in order) Iio_Int_singleton: "{..<k} \<inter> {x} = (if x < k then {x} else {})"
   470   by auto
   471 
   472 lemma (in linorder) Ioc_subset_iff: "{a<..b} \<subseteq> {c<..d} \<longleftrightarrow> (b \<le> a \<or> c \<le> a \<and> b \<le> d)"
   473   by (auto simp: subset_eq Ball_def) (metis less_le not_less)
   474 
   475 lemma (in order_bot) atLeast_eq_UNIV_iff: "{x..} = UNIV \<longleftrightarrow> x = bot"
   476 by (auto simp: set_eq_iff intro: le_bot)
   477 
   478 lemma (in order_top) atMost_eq_UNIV_iff: "{..x} = UNIV \<longleftrightarrow> x = top"
   479 by (auto simp: set_eq_iff intro: top_le)
   480 
   481 lemma (in bounded_lattice) atLeastAtMost_eq_UNIV_iff:
   482   "{x..y} = UNIV \<longleftrightarrow> (x = bot \<and> y = top)"
   483 by (auto simp: set_eq_iff intro: top_le le_bot)
   484 
   485 lemma Iio_eq_empty_iff: "{..< n::'a::{linorder, order_bot}} = {} \<longleftrightarrow> n = bot"
   486   by (auto simp: set_eq_iff not_less le_bot)
   487 
   488 lemma Iio_eq_empty_iff_nat: "{..< n::nat} = {} \<longleftrightarrow> n = 0"
   489   by (simp add: Iio_eq_empty_iff bot_nat_def)
   490 
   491 
   492 subsection {* Infinite intervals *}
   493 
   494 context dense_linorder
   495 begin
   496 
   497 lemma infinite_Ioo:
   498   assumes "a < b"
   499   shows "\<not> finite {a<..<b}"
   500 proof
   501   assume fin: "finite {a<..<b}"
   502   moreover have ne: "{a<..<b} \<noteq> {}"
   503     using `a < b` by auto
   504   ultimately have "a < Max {a <..< b}" "Max {a <..< b} < b"
   505     using Max_in[of "{a <..< b}"] by auto
   506   then obtain x where "Max {a <..< b} < x" "x < b"
   507     using dense[of "Max {a<..<b}" b] by auto
   508   then have "x \<in> {a <..< b}"
   509     using `a < Max {a <..< b}` by auto
   510   then have "x \<le> Max {a <..< b}"
   511     using fin by auto
   512   with `Max {a <..< b} < x` show False by auto
   513 qed
   514 
   515 lemma infinite_Icc: "a < b \<Longrightarrow> \<not> finite {a .. b}"
   516   using greaterThanLessThan_subseteq_atLeastAtMost_iff[of a b a b] infinite_Ioo[of a b]
   517   by (auto dest: finite_subset)
   518 
   519 lemma infinite_Ico: "a < b \<Longrightarrow> \<not> finite {a ..< b}"
   520   using greaterThanLessThan_subseteq_atLeastLessThan_iff[of a b a b] infinite_Ioo[of a b]
   521   by (auto dest: finite_subset)
   522 
   523 lemma infinite_Ioc: "a < b \<Longrightarrow> \<not> finite {a <.. b}"
   524   using greaterThanLessThan_subseteq_greaterThanAtMost_iff[of a b a b] infinite_Ioo[of a b]
   525   by (auto dest: finite_subset)
   526 
   527 end
   528 
   529 lemma infinite_Iio: "\<not> finite {..< a :: 'a :: {no_bot, linorder}}"
   530 proof
   531   assume "finite {..< a}"
   532   then have *: "\<And>x. x < a \<Longrightarrow> Min {..< a} \<le> x"
   533     by auto
   534   obtain x where "x < a"
   535     using lt_ex by auto
   536 
   537   obtain y where "y < Min {..< a}"
   538     using lt_ex by auto
   539   also have "Min {..< a} \<le> x"
   540     using `x < a` by fact
   541   also note `x < a`
   542   finally have "Min {..< a} \<le> y"
   543     by fact
   544   with `y < Min {..< a}` show False by auto
   545 qed
   546 
   547 lemma infinite_Iic: "\<not> finite {.. a :: 'a :: {no_bot, linorder}}"
   548   using infinite_Iio[of a] finite_subset[of "{..< a}" "{.. a}"]
   549   by (auto simp: subset_eq less_imp_le)
   550 
   551 lemma infinite_Ioi: "\<not> finite {a :: 'a :: {no_top, linorder} <..}"
   552 proof
   553   assume "finite {a <..}"
   554   then have *: "\<And>x. a < x \<Longrightarrow> x \<le> Max {a <..}"
   555     by auto
   556 
   557   obtain y where "Max {a <..} < y"
   558     using gt_ex by auto
   559 
   560   obtain x where "a < x"
   561     using gt_ex by auto
   562   also then have "x \<le> Max {a <..}"
   563     by fact
   564   also note `Max {a <..} < y`
   565   finally have "y \<le> Max { a <..}"
   566     by fact
   567   with `Max {a <..} < y` show False by auto
   568 qed
   569 
   570 lemma infinite_Ici: "\<not> finite {a :: 'a :: {no_top, linorder} ..}"
   571   using infinite_Ioi[of a] finite_subset[of "{a <..}" "{a ..}"]
   572   by (auto simp: subset_eq less_imp_le)
   573 
   574 subsubsection {* Intersection *}
   575 
   576 context linorder
   577 begin
   578 
   579 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   580 by auto
   581 
   582 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   583 by auto
   584 
   585 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   586 by auto
   587 
   588 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   589 by auto
   590 
   591 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   592 by auto
   593 
   594 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   595 by auto
   596 
   597 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   598 by auto
   599 
   600 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   601 by auto
   602 
   603 lemma Int_atMost[simp]: "{..a} \<inter> {..b} = {.. min a b}"
   604   by (auto simp: min_def)
   605 
   606 lemma Ioc_disjoint: "{a<..b} \<inter> {c<..d} = {} \<longleftrightarrow> b \<le> a \<or> d \<le> c \<or> b \<le> c \<or> d \<le> a"
   607   using assms by auto
   608 
   609 end
   610 
   611 context complete_lattice
   612 begin
   613 
   614 lemma
   615   shows Sup_atLeast[simp]: "Sup {x ..} = top"
   616     and Sup_greaterThanAtLeast[simp]: "x < top \<Longrightarrow> Sup {x <..} = top"
   617     and Sup_atMost[simp]: "Sup {.. y} = y"
   618     and Sup_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Sup { x .. y} = y"
   619     and Sup_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Sup { x <.. y} = y"
   620   by (auto intro!: Sup_eqI)
   621 
   622 lemma
   623   shows Inf_atMost[simp]: "Inf {.. x} = bot"
   624     and Inf_atMostLessThan[simp]: "top < x \<Longrightarrow> Inf {..< x} = bot"
   625     and Inf_atLeast[simp]: "Inf {x ..} = x"
   626     and Inf_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Inf { x .. y} = x"
   627     and Inf_atLeastLessThan[simp]: "x < y \<Longrightarrow> Inf { x ..< y} = x"
   628   by (auto intro!: Inf_eqI)
   629 
   630 end
   631 
   632 lemma
   633   fixes x y :: "'a :: {complete_lattice, dense_linorder}"
   634   shows Sup_lessThan[simp]: "Sup {..< y} = y"
   635     and Sup_atLeastLessThan[simp]: "x < y \<Longrightarrow> Sup { x ..< y} = y"
   636     and Sup_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Sup { x <..< y} = y"
   637     and Inf_greaterThan[simp]: "Inf {x <..} = x"
   638     and Inf_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Inf { x <.. y} = x"
   639     and Inf_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Inf { x <..< y} = x"
   640   by (auto intro!: Inf_eqI Sup_eqI intro: dense_le dense_le_bounded dense_ge dense_ge_bounded)
   641 
   642 subsection {* Intervals of natural numbers *}
   643 
   644 subsubsection {* The Constant @{term lessThan} *}
   645 
   646 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   647 by (simp add: lessThan_def)
   648 
   649 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   650 by (simp add: lessThan_def less_Suc_eq, blast)
   651 
   652 text {* The following proof is convenient in induction proofs where
   653 new elements get indices at the beginning. So it is used to transform
   654 @{term "{..<Suc n}"} to @{term "0::nat"} and @{term "{..< n}"}. *}
   655 
   656 lemma lessThan_Suc_eq_insert_0: "{..<Suc n} = insert 0 (Suc ` {..<n})"
   657 proof safe
   658   fix x assume "x < Suc n" "x \<notin> Suc ` {..<n}"
   659   then have "x \<noteq> Suc (x - 1)" by auto
   660   with `x < Suc n` show "x = 0" by auto
   661 qed
   662 
   663 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   664 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   665 
   666 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   667 by blast
   668 
   669 subsubsection {* The Constant @{term greaterThan} *}
   670 
   671 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   672 apply (simp add: greaterThan_def)
   673 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   674 done
   675 
   676 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   677 apply (simp add: greaterThan_def)
   678 apply (auto elim: linorder_neqE)
   679 done
   680 
   681 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   682 by blast
   683 
   684 subsubsection {* The Constant @{term atLeast} *}
   685 
   686 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   687 by (unfold atLeast_def UNIV_def, simp)
   688 
   689 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   690 apply (simp add: atLeast_def)
   691 apply (simp add: Suc_le_eq)
   692 apply (simp add: order_le_less, blast)
   693 done
   694 
   695 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   696   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   697 
   698 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   699 by blast
   700 
   701 subsubsection {* The Constant @{term atMost} *}
   702 
   703 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   704 by (simp add: atMost_def)
   705 
   706 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   707 apply (simp add: atMost_def)
   708 apply (simp add: less_Suc_eq order_le_less, blast)
   709 done
   710 
   711 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   712 by blast
   713 
   714 subsubsection {* The Constant @{term atLeastLessThan} *}
   715 
   716 text{*The orientation of the following 2 rules is tricky. The lhs is
   717 defined in terms of the rhs.  Hence the chosen orientation makes sense
   718 in this theory --- the reverse orientation complicates proofs (eg
   719 nontermination). But outside, when the definition of the lhs is rarely
   720 used, the opposite orientation seems preferable because it reduces a
   721 specific concept to a more general one. *}
   722 
   723 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   724 by(simp add:lessThan_def atLeastLessThan_def)
   725 
   726 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   727 by(simp add:atMost_def atLeastAtMost_def)
   728 
   729 declare atLeast0LessThan[symmetric, code_unfold]
   730         atLeast0AtMost[symmetric, code_unfold]
   731 
   732 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   733 by (simp add: atLeastLessThan_def)
   734 
   735 subsubsection {* Intervals of nats with @{term Suc} *}
   736 
   737 text{*Not a simprule because the RHS is too messy.*}
   738 lemma atLeastLessThanSuc:
   739     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   740 by (auto simp add: atLeastLessThan_def)
   741 
   742 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   743 by (auto simp add: atLeastLessThan_def)
   744 (*
   745 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   746 by (induct k, simp_all add: atLeastLessThanSuc)
   747 
   748 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   749 by (auto simp add: atLeastLessThan_def)
   750 *)
   751 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   752   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   753 
   754 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   755   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   756     greaterThanAtMost_def)
   757 
   758 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   759   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   760     greaterThanLessThan_def)
   761 
   762 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   763 by (auto simp add: atLeastAtMost_def)
   764 
   765 lemma atLeastAtMost_insertL: "m \<le> n \<Longrightarrow> insert m {Suc m..n} = {m ..n}"
   766 by auto
   767 
   768 text {* The analogous result is useful on @{typ int}: *}
   769 (* here, because we don't have an own int section *)
   770 lemma atLeastAtMostPlus1_int_conv:
   771   "m <= 1+n \<Longrightarrow> {m..1+n} = insert (1+n) {m..n::int}"
   772   by (auto intro: set_eqI)
   773 
   774 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   775   apply (induct k) 
   776   apply (simp_all add: atLeastLessThanSuc)   
   777   done
   778 
   779 subsubsection {* Intervals and numerals *}
   780 
   781 lemma lessThan_nat_numeral:  --{*Evaluation for specific numerals*}
   782   "lessThan (numeral k :: nat) = insert (pred_numeral k) (lessThan (pred_numeral k))"
   783   by (simp add: numeral_eq_Suc lessThan_Suc)
   784 
   785 lemma atMost_nat_numeral:  --{*Evaluation for specific numerals*}
   786   "atMost (numeral k :: nat) = insert (numeral k) (atMost (pred_numeral k))"
   787   by (simp add: numeral_eq_Suc atMost_Suc)
   788 
   789 lemma atLeastLessThan_nat_numeral:  --{*Evaluation for specific numerals*}
   790   "atLeastLessThan m (numeral k :: nat) = 
   791      (if m \<le> (pred_numeral k) then insert (pred_numeral k) (atLeastLessThan m (pred_numeral k))
   792                  else {})"
   793   by (simp add: numeral_eq_Suc atLeastLessThanSuc)
   794 
   795 subsubsection {* Image *}
   796 
   797 lemma image_add_atLeastAtMost:
   798   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   799 proof
   800   show "?A \<subseteq> ?B" by auto
   801 next
   802   show "?B \<subseteq> ?A"
   803   proof
   804     fix n assume a: "n : ?B"
   805     hence "n - k : {i..j}" by auto
   806     moreover have "n = (n - k) + k" using a by auto
   807     ultimately show "n : ?A" by blast
   808   qed
   809 qed
   810 
   811 lemma image_add_atLeastLessThan:
   812   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   813 proof
   814   show "?A \<subseteq> ?B" by auto
   815 next
   816   show "?B \<subseteq> ?A"
   817   proof
   818     fix n assume a: "n : ?B"
   819     hence "n - k : {i..<j}" by auto
   820     moreover have "n = (n - k) + k" using a by auto
   821     ultimately show "n : ?A" by blast
   822   qed
   823 qed
   824 
   825 corollary image_Suc_atLeastAtMost[simp]:
   826   "Suc ` {i..j} = {Suc i..Suc j}"
   827 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   828 
   829 corollary image_Suc_atLeastLessThan[simp]:
   830   "Suc ` {i..<j} = {Suc i..<Suc j}"
   831 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   832 
   833 lemma image_add_int_atLeastLessThan:
   834     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   835   apply (auto simp add: image_def)
   836   apply (rule_tac x = "x - l" in bexI)
   837   apply auto
   838   done
   839 
   840 lemma image_minus_const_atLeastLessThan_nat:
   841   fixes c :: nat
   842   shows "(\<lambda>i. i - c) ` {x ..< y} =
   843       (if c < y then {x - c ..< y - c} else if x < y then {0} else {})"
   844     (is "_ = ?right")
   845 proof safe
   846   fix a assume a: "a \<in> ?right"
   847   show "a \<in> (\<lambda>i. i - c) ` {x ..< y}"
   848   proof cases
   849     assume "c < y" with a show ?thesis
   850       by (auto intro!: image_eqI[of _ _ "a + c"])
   851   next
   852     assume "\<not> c < y" with a show ?thesis
   853       by (auto intro!: image_eqI[of _ _ x] split: split_if_asm)
   854   qed
   855 qed auto
   856 
   857 lemma image_int_atLeastLessThan: "int ` {a..<b} = {int a..<int b}"
   858   by (auto intro!: image_eqI [where x = "nat x" for x])
   859 
   860 context ordered_ab_group_add
   861 begin
   862 
   863 lemma
   864   fixes x :: 'a
   865   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   866   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   867 proof safe
   868   fix y assume "y < -x"
   869   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   870   have "- (-y) \<in> uminus ` {x<..}"
   871     by (rule imageI) (simp add: *)
   872   thus "y \<in> uminus ` {x<..}" by simp
   873 next
   874   fix y assume "y \<le> -x"
   875   have "- (-y) \<in> uminus ` {x..}"
   876     by (rule imageI) (insert `y \<le> -x`[THEN le_imp_neg_le], simp)
   877   thus "y \<in> uminus ` {x..}" by simp
   878 qed simp_all
   879 
   880 lemma
   881   fixes x :: 'a
   882   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   883   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   884 proof -
   885   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   886     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   887   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   888     by (simp_all add: image_image
   889         del: image_uminus_greaterThan image_uminus_atLeast)
   890 qed
   891 
   892 lemma
   893   fixes x :: 'a
   894   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   895   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   896   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   897   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   898   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   899       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   900 end
   901 
   902 subsubsection {* Finiteness *}
   903 
   904 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   905   by (induct k) (simp_all add: lessThan_Suc)
   906 
   907 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   908   by (induct k) (simp_all add: atMost_Suc)
   909 
   910 lemma finite_greaterThanLessThan [iff]:
   911   fixes l :: nat shows "finite {l<..<u}"
   912 by (simp add: greaterThanLessThan_def)
   913 
   914 lemma finite_atLeastLessThan [iff]:
   915   fixes l :: nat shows "finite {l..<u}"
   916 by (simp add: atLeastLessThan_def)
   917 
   918 lemma finite_greaterThanAtMost [iff]:
   919   fixes l :: nat shows "finite {l<..u}"
   920 by (simp add: greaterThanAtMost_def)
   921 
   922 lemma finite_atLeastAtMost [iff]:
   923   fixes l :: nat shows "finite {l..u}"
   924 by (simp add: atLeastAtMost_def)
   925 
   926 text {* A bounded set of natural numbers is finite. *}
   927 lemma bounded_nat_set_is_finite:
   928   "(ALL i:N. i < (n::nat)) ==> finite N"
   929 apply (rule finite_subset)
   930  apply (rule_tac [2] finite_lessThan, auto)
   931 done
   932 
   933 text {* A set of natural numbers is finite iff it is bounded. *}
   934 lemma finite_nat_set_iff_bounded:
   935   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   936 proof
   937   assume f:?F  show ?B
   938     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   939 next
   940   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   941 qed
   942 
   943 lemma finite_nat_set_iff_bounded_le:
   944   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   945 apply(simp add:finite_nat_set_iff_bounded)
   946 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   947 done
   948 
   949 lemma finite_less_ub:
   950      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   951 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   952 
   953 
   954 text{* Any subset of an interval of natural numbers the size of the
   955 subset is exactly that interval. *}
   956 
   957 lemma subset_card_intvl_is_intvl:
   958   assumes "A \<subseteq> {k..<k + card A}"
   959   shows "A = {k..<k + card A}"
   960 proof (cases "finite A")
   961   case True
   962   from this and assms show ?thesis
   963   proof (induct A rule: finite_linorder_max_induct)
   964     case empty thus ?case by auto
   965   next
   966     case (insert b A)
   967     hence *: "b \<notin> A" by auto
   968     with insert have "A <= {k..<k + card A}" and "b = k + card A"
   969       by fastforce+
   970     with insert * show ?case by auto
   971   qed
   972 next
   973   case False
   974   with assms show ?thesis by simp
   975 qed
   976 
   977 
   978 subsubsection {* Proving Inclusions and Equalities between Unions *}
   979 
   980 lemma UN_le_eq_Un0:
   981   "(\<Union>i\<le>n::nat. M i) = (\<Union>i\<in>{1..n}. M i) \<union> M 0" (is "?A = ?B")
   982 proof
   983   show "?A <= ?B"
   984   proof
   985     fix x assume "x : ?A"
   986     then obtain i where i: "i\<le>n" "x : M i" by auto
   987     show "x : ?B"
   988     proof(cases i)
   989       case 0 with i show ?thesis by simp
   990     next
   991       case (Suc j) with i show ?thesis by auto
   992     qed
   993   qed
   994 next
   995   show "?B <= ?A" by auto
   996 qed
   997 
   998 lemma UN_le_add_shift:
   999   "(\<Union>i\<le>n::nat. M(i+k)) = (\<Union>i\<in>{k..n+k}. M i)" (is "?A = ?B")
  1000 proof
  1001   show "?A <= ?B" by fastforce
  1002 next
  1003   show "?B <= ?A"
  1004   proof
  1005     fix x assume "x : ?B"
  1006     then obtain i where i: "i : {k..n+k}" "x : M(i)" by auto
  1007     hence "i-k\<le>n & x : M((i-k)+k)" by auto
  1008     thus "x : ?A" by blast
  1009   qed
  1010 qed
  1011 
  1012 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
  1013   by (auto simp add: atLeast0LessThan) 
  1014 
  1015 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
  1016   by (subst UN_UN_finite_eq [symmetric]) blast
  1017 
  1018 lemma UN_finite2_subset: 
  1019      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
  1020   apply (rule UN_finite_subset)
  1021   apply (subst UN_UN_finite_eq [symmetric, of B]) 
  1022   apply blast
  1023   done
  1024 
  1025 lemma UN_finite2_eq:
  1026   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
  1027   apply (rule subset_antisym)
  1028    apply (rule UN_finite2_subset, blast)
  1029  apply (rule UN_finite2_subset [where k=k])
  1030  apply (force simp add: atLeastLessThan_add_Un [of 0])
  1031  done
  1032 
  1033 
  1034 subsubsection {* Cardinality *}
  1035 
  1036 lemma card_lessThan [simp]: "card {..<u} = u"
  1037   by (induct u, simp_all add: lessThan_Suc)
  1038 
  1039 lemma card_atMost [simp]: "card {..u} = Suc u"
  1040   by (simp add: lessThan_Suc_atMost [THEN sym])
  1041 
  1042 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
  1043 proof -
  1044   have "{l..<u} = (%x. x + l) ` {..<u-l}"
  1045     apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
  1046     apply (rule_tac x = "x - l" in exI)
  1047     apply arith
  1048     done
  1049   then have "card {l..<u} = card {..<u-l}"
  1050     by (simp add: card_image inj_on_def)
  1051   then show ?thesis
  1052     by simp
  1053 qed
  1054 
  1055 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
  1056   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
  1057 
  1058 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
  1059   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
  1060 
  1061 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
  1062   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
  1063 
  1064 lemma ex_bij_betw_nat_finite:
  1065   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
  1066 apply(drule finite_imp_nat_seg_image_inj_on)
  1067 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
  1068 done
  1069 
  1070 lemma ex_bij_betw_finite_nat:
  1071   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
  1072 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
  1073 
  1074 lemma finite_same_card_bij:
  1075   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
  1076 apply(drule ex_bij_betw_finite_nat)
  1077 apply(drule ex_bij_betw_nat_finite)
  1078 apply(auto intro!:bij_betw_trans)
  1079 done
  1080 
  1081 lemma ex_bij_betw_nat_finite_1:
  1082   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
  1083 by (rule finite_same_card_bij) auto
  1084 
  1085 lemma bij_betw_iff_card:
  1086   assumes FIN: "finite A" and FIN': "finite B"
  1087   shows BIJ: "(\<exists>f. bij_betw f A B) \<longleftrightarrow> (card A = card B)"
  1088 using assms
  1089 proof(auto simp add: bij_betw_same_card)
  1090   assume *: "card A = card B"
  1091   obtain f where "bij_betw f A {0 ..< card A}"
  1092   using FIN ex_bij_betw_finite_nat by blast
  1093   moreover obtain g where "bij_betw g {0 ..< card B} B"
  1094   using FIN' ex_bij_betw_nat_finite by blast
  1095   ultimately have "bij_betw (g o f) A B"
  1096   using * by (auto simp add: bij_betw_trans)
  1097   thus "(\<exists>f. bij_betw f A B)" by blast
  1098 qed
  1099 
  1100 lemma inj_on_iff_card_le:
  1101   assumes FIN: "finite A" and FIN': "finite B"
  1102   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> B) = (card A \<le> card B)"
  1103 proof (safe intro!: card_inj_on_le)
  1104   assume *: "card A \<le> card B"
  1105   obtain f where 1: "inj_on f A" and 2: "f ` A = {0 ..< card A}"
  1106   using FIN ex_bij_betw_finite_nat unfolding bij_betw_def by force
  1107   moreover obtain g where "inj_on g {0 ..< card B}" and 3: "g ` {0 ..< card B} = B"
  1108   using FIN' ex_bij_betw_nat_finite unfolding bij_betw_def by force
  1109   ultimately have "inj_on g (f ` A)" using subset_inj_on[of g _ "f ` A"] * by force
  1110   hence "inj_on (g o f) A" using 1 comp_inj_on by blast
  1111   moreover
  1112   {have "{0 ..< card A} \<le> {0 ..< card B}" using * by force
  1113    with 2 have "f ` A  \<le> {0 ..< card B}" by blast
  1114    hence "(g o f) ` A \<le> B" unfolding comp_def using 3 by force
  1115   }
  1116   ultimately show "(\<exists>f. inj_on f A \<and> f ` A \<le> B)" by blast
  1117 qed (insert assms, auto)
  1118 
  1119 subsection {* Intervals of integers *}
  1120 
  1121 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
  1122   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
  1123 
  1124 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
  1125   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
  1126 
  1127 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
  1128     "{l+1..<u} = {l<..<u::int}"
  1129   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
  1130 
  1131 subsubsection {* Finiteness *}
  1132 
  1133 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
  1134     {(0::int)..<u} = int ` {..<nat u}"
  1135   apply (unfold image_def lessThan_def)
  1136   apply auto
  1137   apply (rule_tac x = "nat x" in exI)
  1138   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
  1139   done
  1140 
  1141 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
  1142   apply (cases "0 \<le> u")
  1143   apply (subst image_atLeastZeroLessThan_int, assumption)
  1144   apply (rule finite_imageI)
  1145   apply auto
  1146   done
  1147 
  1148 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
  1149   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1150   apply (erule subst)
  1151   apply (rule finite_imageI)
  1152   apply (rule finite_atLeastZeroLessThan_int)
  1153   apply (rule image_add_int_atLeastLessThan)
  1154   done
  1155 
  1156 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
  1157   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
  1158 
  1159 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
  1160   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1161 
  1162 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
  1163   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1164 
  1165 
  1166 subsubsection {* Cardinality *}
  1167 
  1168 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
  1169   apply (cases "0 \<le> u")
  1170   apply (subst image_atLeastZeroLessThan_int, assumption)
  1171   apply (subst card_image)
  1172   apply (auto simp add: inj_on_def)
  1173   done
  1174 
  1175 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
  1176   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
  1177   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
  1178   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1179   apply (erule subst)
  1180   apply (rule card_image)
  1181   apply (simp add: inj_on_def)
  1182   apply (rule image_add_int_atLeastLessThan)
  1183   done
  1184 
  1185 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
  1186 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
  1187 apply (auto simp add: algebra_simps)
  1188 done
  1189 
  1190 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
  1191 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1192 
  1193 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
  1194 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1195 
  1196 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
  1197 proof -
  1198   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
  1199   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
  1200 qed
  1201 
  1202 lemma card_less:
  1203 assumes zero_in_M: "0 \<in> M"
  1204 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
  1205 proof -
  1206   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
  1207   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
  1208 qed
  1209 
  1210 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
  1211 apply (rule card_bij_eq [of Suc _ _ "\<lambda>x. x - Suc 0"])
  1212 apply auto
  1213 apply (rule inj_on_diff_nat)
  1214 apply auto
  1215 apply (case_tac x)
  1216 apply auto
  1217 apply (case_tac xa)
  1218 apply auto
  1219 apply (case_tac xa)
  1220 apply auto
  1221 done
  1222 
  1223 lemma card_less_Suc:
  1224   assumes zero_in_M: "0 \<in> M"
  1225     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
  1226 proof -
  1227   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
  1228   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
  1229     by (auto simp only: insert_Diff)
  1230   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
  1231   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] 
  1232   have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
  1233     apply (subst card_insert)
  1234     apply simp_all
  1235     apply (subst b)
  1236     apply (subst card_less_Suc2[symmetric])
  1237     apply simp_all
  1238     done
  1239   with c show ?thesis by simp
  1240 qed
  1241 
  1242 
  1243 subsection {*Lemmas useful with the summation operator setsum*}
  1244 
  1245 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
  1246 
  1247 subsubsection {* Disjoint Unions *}
  1248 
  1249 text {* Singletons and open intervals *}
  1250 
  1251 lemma ivl_disj_un_singleton:
  1252   "{l::'a::linorder} Un {l<..} = {l..}"
  1253   "{..<u} Un {u::'a::linorder} = {..u}"
  1254   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
  1255   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
  1256   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
  1257   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
  1258 by auto
  1259 
  1260 text {* One- and two-sided intervals *}
  1261 
  1262 lemma ivl_disj_un_one:
  1263   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
  1264   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
  1265   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
  1266   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
  1267   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
  1268   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
  1269   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
  1270   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
  1271 by auto
  1272 
  1273 text {* Two- and two-sided intervals *}
  1274 
  1275 lemma ivl_disj_un_two:
  1276   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
  1277   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
  1278   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
  1279   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
  1280   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
  1281   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
  1282   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
  1283   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
  1284 by auto
  1285 
  1286 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
  1287 
  1288 subsubsection {* Disjoint Intersections *}
  1289 
  1290 text {* One- and two-sided intervals *}
  1291 
  1292 lemma ivl_disj_int_one:
  1293   "{..l::'a::order} Int {l<..<u} = {}"
  1294   "{..<l} Int {l..<u} = {}"
  1295   "{..l} Int {l<..u} = {}"
  1296   "{..<l} Int {l..u} = {}"
  1297   "{l<..u} Int {u<..} = {}"
  1298   "{l<..<u} Int {u..} = {}"
  1299   "{l..u} Int {u<..} = {}"
  1300   "{l..<u} Int {u..} = {}"
  1301   by auto
  1302 
  1303 text {* Two- and two-sided intervals *}
  1304 
  1305 lemma ivl_disj_int_two:
  1306   "{l::'a::order<..<m} Int {m..<u} = {}"
  1307   "{l<..m} Int {m<..<u} = {}"
  1308   "{l..<m} Int {m..<u} = {}"
  1309   "{l..m} Int {m<..<u} = {}"
  1310   "{l<..<m} Int {m..u} = {}"
  1311   "{l<..m} Int {m<..u} = {}"
  1312   "{l..<m} Int {m..u} = {}"
  1313   "{l..m} Int {m<..u} = {}"
  1314   by auto
  1315 
  1316 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
  1317 
  1318 subsubsection {* Some Differences *}
  1319 
  1320 lemma ivl_diff[simp]:
  1321  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
  1322 by(auto)
  1323 
  1324 lemma (in linorder) lessThan_minus_lessThan [simp]:
  1325   "{..< n} - {..< m} = {m ..< n}"
  1326   by auto
  1327 
  1328 
  1329 subsubsection {* Some Subset Conditions *}
  1330 
  1331 lemma ivl_subset [simp]:
  1332  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
  1333 apply(auto simp:linorder_not_le)
  1334 apply(rule ccontr)
  1335 apply(insert linorder_le_less_linear[of i n])
  1336 apply(clarsimp simp:linorder_not_le)
  1337 apply(fastforce)
  1338 done
  1339 
  1340 
  1341 subsection {* Summation indexed over intervals *}
  1342 
  1343 syntax
  1344   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
  1345   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
  1346   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
  1347   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
  1348 syntax (xsymbols)
  1349   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1350   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1351   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1352   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1353 syntax (HTML output)
  1354   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1355   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1356   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1357   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1358 syntax (latex_sum output)
  1359   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1360  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1361   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1362  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1363   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1364  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1365   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1366  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1367 
  1368 translations
  1369   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
  1370   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
  1371   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
  1372   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
  1373 
  1374 text{* The above introduces some pretty alternative syntaxes for
  1375 summation over intervals:
  1376 \begin{center}
  1377 \begin{tabular}{lll}
  1378 Old & New & \LaTeX\\
  1379 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
  1380 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
  1381 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
  1382 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
  1383 \end{tabular}
  1384 \end{center}
  1385 The left column shows the term before introduction of the new syntax,
  1386 the middle column shows the new (default) syntax, and the right column
  1387 shows a special syntax. The latter is only meaningful for latex output
  1388 and has to be activated explicitly by setting the print mode to
  1389 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
  1390 antiquotations). It is not the default \LaTeX\ output because it only
  1391 works well with italic-style formulae, not tt-style.
  1392 
  1393 Note that for uniformity on @{typ nat} it is better to use
  1394 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
  1395 not provide all lemmas available for @{term"{m..<n}"} also in the
  1396 special form for @{term"{..<n}"}. *}
  1397 
  1398 text{* This congruence rule should be used for sums over intervals as
  1399 the standard theorem @{text[source]setsum.cong} does not work well
  1400 with the simplifier who adds the unsimplified premise @{term"x:B"} to
  1401 the context. *}
  1402 
  1403 lemma setsum_ivl_cong:
  1404  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
  1405  setsum f {a..<b} = setsum g {c..<d}"
  1406 by(rule setsum.cong, simp_all)
  1407 
  1408 (* FIXME why are the following simp rules but the corresponding eqns
  1409 on intervals are not? *)
  1410 
  1411 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
  1412 by (simp add:atMost_Suc ac_simps)
  1413 
  1414 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
  1415 by (simp add:lessThan_Suc ac_simps)
  1416 
  1417 lemma setsum_cl_ivl_Suc[simp]:
  1418   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
  1419 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1420 
  1421 lemma setsum_op_ivl_Suc[simp]:
  1422   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
  1423 by (auto simp:ac_simps atLeastLessThanSuc)
  1424 (*
  1425 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
  1426     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
  1427 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1428 *)
  1429 
  1430 lemma setsum_head:
  1431   fixes n :: nat
  1432   assumes mn: "m <= n" 
  1433   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
  1434 proof -
  1435   from mn
  1436   have "{m..n} = {m} \<union> {m<..n}"
  1437     by (auto intro: ivl_disj_un_singleton)
  1438   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
  1439     by (simp add: atLeast0LessThan)
  1440   also have "\<dots> = ?rhs" by simp
  1441   finally show ?thesis .
  1442 qed
  1443 
  1444 lemma setsum_head_Suc:
  1445   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
  1446 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
  1447 
  1448 lemma setsum_head_upt_Suc:
  1449   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
  1450 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
  1451 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
  1452 done
  1453 
  1454 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
  1455   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1456 proof-
  1457   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
  1458   thus ?thesis by (auto simp: ivl_disj_int setsum.union_disjoint
  1459     atLeastSucAtMost_greaterThanAtMost)
  1460 qed
  1461 
  1462 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1463   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
  1464 by (simp add:setsum.union_disjoint[symmetric] ivl_disj_int ivl_disj_un)
  1465 
  1466 lemma setsum_diff_nat_ivl:
  1467 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1468 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1469   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
  1470 using setsum_add_nat_ivl [of m n p f,symmetric]
  1471 apply (simp add: ac_simps)
  1472 done
  1473 
  1474 lemma setsum_natinterval_difff:
  1475   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1476   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1477           (if m <= n then f m - f(n + 1) else 0)"
  1478 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
  1479 
  1480 lemma setsum_nat_group: "(\<Sum>m<n::nat. setsum f {m * k ..< m*k + k}) = setsum f {..< n * k}"
  1481   apply (subgoal_tac "k = 0 | 0 < k", auto)
  1482   apply (induct "n")
  1483   apply (simp_all add: setsum_add_nat_ivl add.commute atLeast0LessThan[symmetric])
  1484   done
  1485 
  1486 subsection{* Shifting bounds *}
  1487 
  1488 lemma setsum_shift_bounds_nat_ivl:
  1489   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1490 by (induct "n", auto simp:atLeastLessThanSuc)
  1491 
  1492 lemma setsum_shift_bounds_cl_nat_ivl:
  1493   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1494   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. i + k" and j="\<lambda>i. i - k"]) auto
  1495 
  1496 corollary setsum_shift_bounds_cl_Suc_ivl:
  1497   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1498 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1499 
  1500 corollary setsum_shift_bounds_Suc_ivl:
  1501   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1502 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1503 
  1504 lemma setsum_shift_lb_Suc0_0:
  1505   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1506 by(simp add:setsum_head_Suc)
  1507 
  1508 lemma setsum_shift_lb_Suc0_0_upt:
  1509   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1510 apply(cases k)apply simp
  1511 apply(simp add:setsum_head_upt_Suc)
  1512 done
  1513 
  1514 lemma setsum_atMost_Suc_shift:
  1515   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
  1516   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1517 proof (induct n)
  1518   case 0 show ?case by simp
  1519 next
  1520   case (Suc n) note IH = this
  1521   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
  1522     by (rule setsum_atMost_Suc)
  1523   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1524     by (rule IH)
  1525   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
  1526              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
  1527     by (rule add.assoc)
  1528   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
  1529     by (rule setsum_atMost_Suc [symmetric])
  1530   finally show ?case .
  1531 qed
  1532 
  1533 lemma setsum_last_plus: fixes n::nat shows "m <= n \<Longrightarrow> (\<Sum>i = m..n. f i) = f n + (\<Sum>i = m..<n. f i)"
  1534   by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost add.commute)
  1535 
  1536 lemma setsum_Suc_diff:
  1537   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1538   assumes "m \<le> Suc n"
  1539   shows "(\<Sum>i = m..n. f(Suc i) - f i) = f (Suc n) - f m"
  1540 using assms by (induct n) (auto simp: le_Suc_eq)
  1541 
  1542 lemma nested_setsum_swap:
  1543      "(\<Sum>i = 0..n. (\<Sum>j = 0..<i. a i j)) = (\<Sum>j = 0..<n. \<Sum>i = Suc j..n. a i j)"
  1544   by (induction n) (auto simp: setsum.distrib)
  1545 
  1546 lemma nested_setsum_swap':
  1547      "(\<Sum>i\<le>n. (\<Sum>j<i. a i j)) = (\<Sum>j<n. \<Sum>i = Suc j..n. a i j)"
  1548   by (induction n) (auto simp: setsum.distrib)
  1549 
  1550 lemma setsum_zero_power [simp]:
  1551   fixes c :: "nat \<Rightarrow> 'a::division_ring"
  1552   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
  1553 apply (cases "finite A")
  1554   by (induction A rule: finite_induct) auto
  1555 
  1556 lemma setsum_zero_power' [simp]:
  1557   fixes c :: "nat \<Rightarrow> 'a::field"
  1558   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
  1559   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
  1560   by auto
  1561 
  1562 
  1563 subsection {* The formula for geometric sums *}
  1564 
  1565 lemma geometric_sum:
  1566   assumes "x \<noteq> 1"
  1567   shows "(\<Sum>i<n. x ^ i) = (x ^ n - 1) / (x - 1::'a::field)"
  1568 proof -
  1569   from assms obtain y where "y = x - 1" and "y \<noteq> 0" by simp_all
  1570   moreover have "(\<Sum>i<n. (y + 1) ^ i) = ((y + 1) ^ n - 1) / y"
  1571     by (induct n) (simp_all add: field_simps `y \<noteq> 0`)
  1572   ultimately show ?thesis by simp
  1573 qed
  1574 
  1575 
  1576 subsection {* The formula for arithmetic sums *}
  1577 
  1578 lemma gauss_sum:
  1579   "(2::'a::comm_semiring_1)*(\<Sum>i\<in>{1..n}. of_nat i) = of_nat n*((of_nat n)+1)"
  1580 proof (induct n)
  1581   case 0
  1582   show ?case by simp
  1583 next
  1584   case (Suc n)
  1585   then show ?case
  1586     by (simp add: algebra_simps add: one_add_one [symmetric] del: one_add_one)
  1587       (* FIXME: make numeral cancellation simprocs work for semirings *)
  1588 qed
  1589 
  1590 theorem arith_series_general:
  1591   "(2::'a::comm_semiring_1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1592   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1593 proof cases
  1594   assume ngt1: "n > 1"
  1595   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1596   have
  1597     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1598      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1599     by (rule setsum.distrib)
  1600   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1601   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1602     unfolding One_nat_def
  1603     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt ac_simps)
  1604   also have "2*\<dots> = 2*?n*a + d*2*(\<Sum>i\<in>{1..<n}. ?I i)"
  1605     by (simp add: algebra_simps)
  1606   also from ngt1 have "{1..<n} = {1..n - 1}"
  1607     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1608   also from ngt1
  1609   have "2*?n*a + d*2*(\<Sum>i\<in>{1..n - 1}. ?I i) = (2*?n*a + d*?I (n - 1)*?I n)"
  1610     by (simp only: mult.assoc gauss_sum [of "n - 1"], unfold One_nat_def)
  1611       (simp add:  mult.commute trans [OF add.commute of_nat_Suc [symmetric]])
  1612   finally show ?thesis
  1613     unfolding mult_2 by (simp add: algebra_simps)
  1614 next
  1615   assume "\<not>(n > 1)"
  1616   hence "n = 1 \<or> n = 0" by auto
  1617   thus ?thesis by (auto simp: mult_2)
  1618 qed
  1619 
  1620 lemma arith_series_nat:
  1621   "(2::nat) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1622 proof -
  1623   have
  1624     "2 * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1625     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1626     by (rule arith_series_general)
  1627   thus ?thesis
  1628     unfolding One_nat_def by auto
  1629 qed
  1630 
  1631 lemma arith_series_int:
  1632   "2 * (\<Sum>i\<in>{..<n}. a + int i * d) = int n * (a + (a + int(n - 1)*d))"
  1633   by (fact arith_series_general) (* FIXME: duplicate *)
  1634 
  1635 lemma sum_diff_distrib:
  1636   fixes P::"nat\<Rightarrow>nat"
  1637   shows
  1638   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1639   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1640 proof (induct n)
  1641   case 0 show ?case by simp
  1642 next
  1643   case (Suc n)
  1644 
  1645   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1646   let ?rhs = "\<Sum>x<n. P x - Q x"
  1647 
  1648   from Suc have "?lhs = ?rhs" by simp
  1649   moreover
  1650   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1651   moreover
  1652   from Suc have
  1653     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1654     by (subst diff_diff_left[symmetric],
  1655         subst diff_add_assoc2)
  1656        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1657   ultimately
  1658   show ?case by simp
  1659 qed
  1660 
  1661 lemma nat_diff_setsum_reindex: "(\<Sum>i<n. f (n - Suc i)) = (\<Sum>i<n. f i)"
  1662   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. n - Suc i" and j="\<lambda>i. n - Suc i"]) auto
  1663 
  1664 subsection {* Products indexed over intervals *}
  1665 
  1666 syntax
  1667   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1668   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1669   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1670   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1671 syntax (xsymbols)
  1672   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1673   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1674   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1675   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1676 syntax (HTML output)
  1677   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1678   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1679   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1680   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1681 syntax (latex_prod output)
  1682   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1683  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1684   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1685  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1686   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1687  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1688   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1689  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1690 
  1691 translations
  1692   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1693   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1694   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1695   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1696 
  1697 subsection {* Transfer setup *}
  1698 
  1699 lemma transfer_nat_int_set_functions:
  1700     "{..n} = nat ` {0..int n}"
  1701     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1702   apply (auto simp add: image_def)
  1703   apply (rule_tac x = "int x" in bexI)
  1704   apply auto
  1705   apply (rule_tac x = "int x" in bexI)
  1706   apply auto
  1707   done
  1708 
  1709 lemma transfer_nat_int_set_function_closures:
  1710     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1711   by (simp add: nat_set_def)
  1712 
  1713 declare transfer_morphism_nat_int[transfer add
  1714   return: transfer_nat_int_set_functions
  1715     transfer_nat_int_set_function_closures
  1716 ]
  1717 
  1718 lemma transfer_int_nat_set_functions:
  1719     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1720   by (simp only: is_nat_def transfer_nat_int_set_functions
  1721     transfer_nat_int_set_function_closures
  1722     transfer_nat_int_set_return_embed nat_0_le
  1723     cong: transfer_nat_int_set_cong)
  1724 
  1725 lemma transfer_int_nat_set_function_closures:
  1726     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1727   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1728 
  1729 declare transfer_morphism_int_nat[transfer add
  1730   return: transfer_int_nat_set_functions
  1731     transfer_int_nat_set_function_closures
  1732 ]
  1733 
  1734 lemma setprod_int_plus_eq: "setprod int {i..i+j} =  \<Prod>{int i..int (i+j)}"
  1735   by (induct j) (auto simp add: atLeastAtMostSuc_conv atLeastAtMostPlus1_int_conv)
  1736 
  1737 lemma setprod_int_eq: "setprod int {i..j} =  \<Prod>{int i..int j}"
  1738 proof (cases "i \<le> j")
  1739   case True
  1740   then show ?thesis
  1741     by (metis Nat.le_iff_add setprod_int_plus_eq)
  1742 next
  1743   case False
  1744   then show ?thesis
  1745     by auto
  1746 qed
  1747 
  1748 end