src/Pure/sign.ML
author wenzelm
Thu Oct 11 16:05:23 2007 +0200 (2007-10-11)
changeset 24959 119793c84647
parent 24949 5f00e3532418
child 24973 dc67846b00c0
permissions -rw-r--r--
replaced Sign.add_consts_authentic by Sign.declare_const;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> output * int)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> output * int)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    57     theory -> theory
    58   val restore_naming: theory -> theory -> theory
    59 end
    60 
    61 signature SIGN =
    62 sig
    63   val rep_sg: theory ->
    64    {naming: NameSpace.naming,
    65     syn: Syntax.syntax,
    66     tsig: Type.tsig,
    67     consts: Consts.T}
    68   val naming_of: theory -> NameSpace.naming
    69   val base_name: string -> bstring
    70   val full_name: theory -> bstring -> string
    71   val full_name_path: theory -> string -> bstring -> string
    72   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    73   val syn_of: theory -> Syntax.syntax
    74   val tsig_of: theory -> Type.tsig
    75   val classes_of: theory -> Sorts.algebra
    76   val all_classes: theory -> class list
    77   val super_classes: theory -> class -> class list
    78   val minimize_sort: theory -> sort -> sort
    79   val complete_sort: theory -> sort -> sort
    80   val defaultS: theory -> sort
    81   val subsort: theory -> sort * sort -> bool
    82   val of_sort: theory -> typ * sort -> bool
    83   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    84   val universal_witness: theory -> (typ * sort) option
    85   val all_sorts_nonempty: theory -> bool
    86   val is_logtype: theory -> string -> bool
    87   val typ_instance: theory -> typ * typ -> bool
    88   val typ_equiv: theory -> typ * typ -> bool
    89   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    90   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    91   val consts_of: theory -> Consts.T
    92   val the_const_constraint: theory -> string -> typ
    93   val const_type: theory -> string -> typ option
    94   val the_const_type: theory -> string -> typ
    95   val declared_tyname: theory -> string -> bool
    96   val declared_const: theory -> string -> bool
    97   val const_monomorphic: theory -> string -> bool
    98   val const_syntax_name: theory -> string -> string
    99   val const_typargs: theory -> string * typ -> typ list
   100   val const_instance: theory -> string * typ list -> typ
   101   val class_space: theory -> NameSpace.T
   102   val type_space: theory -> NameSpace.T
   103   val const_space: theory -> NameSpace.T
   104   val intern_class: theory -> xstring -> string
   105   val extern_class: theory -> string -> xstring
   106   val intern_type: theory -> xstring -> string
   107   val extern_type: theory -> string -> xstring
   108   val intern_const: theory -> xstring -> string
   109   val extern_const: theory -> string -> xstring
   110   val intern_sort: theory -> sort -> sort
   111   val extern_sort: theory -> sort -> sort
   112   val intern_typ: theory -> typ -> typ
   113   val extern_typ: theory -> typ -> typ
   114   val intern_term: theory -> term -> term
   115   val extern_term: (string -> xstring) -> theory -> term -> term
   116   val intern_tycons: theory -> typ -> typ
   117   val pretty_term: theory -> term -> Pretty.T
   118   val pretty_typ: theory -> typ -> Pretty.T
   119   val pretty_sort: theory -> sort -> Pretty.T
   120   val string_of_term: theory -> term -> string
   121   val string_of_typ: theory -> typ -> string
   122   val string_of_sort: theory -> sort -> string
   123   val pp: theory -> Pretty.pp
   124   val arity_number: theory -> string -> int
   125   val arity_sorts: theory -> string -> sort -> sort list
   126   val certify_class: theory -> class -> class
   127   val certify_sort: theory -> sort -> sort
   128   val certify_typ: theory -> typ -> typ
   129   val certify_typ_mode: Type.mode -> theory -> typ -> typ
   130   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
   131   val certify_term: theory -> term -> term * typ * int
   132   val certify_prop: theory -> term -> term * typ * int
   133   val cert_term: theory -> term -> term
   134   val cert_prop: theory -> term -> term
   135   val no_frees: Pretty.pp -> term -> term
   136   val no_vars: Pretty.pp -> term -> term
   137   val cert_def: Pretty.pp -> term -> (string * typ) * term
   138   val read_class: theory -> xstring -> class
   139   val read_arity: theory -> xstring * string list * string -> arity
   140   val cert_arity: theory -> arity -> arity
   141   val get_sort: theory ->
   142     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   143   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   144   val read_typ: theory -> string -> typ
   145   val read_typ_syntax: theory -> string -> typ
   146   val read_typ_abbrev: theory -> string -> typ
   147   val read_tyname: theory -> string -> typ
   148   val read_const: theory -> string -> term
   149   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   150     (string -> string option) -> Proof.context ->
   151     (indexname -> typ option) * (indexname -> sort option) ->
   152     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   153   val read_def_terms:
   154     theory * (indexname -> typ option) * (indexname -> sort option) ->
   155     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   156   val simple_read_term: theory -> typ -> string -> term
   157   val read_term: theory -> string -> term
   158   val read_prop: theory -> string -> term
   159   val declare_const: Markup.property list -> (bstring * typ * mixfix) -> theory -> term * theory
   160   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
   161   val add_abbrev: string -> Markup.property list ->
   162     bstring * term -> theory -> (term * term) * theory
   163   include SIGN_THEORY
   164   val add_const_constraint: string * typ option -> theory -> theory
   165   val primitive_class: string * class list -> theory -> theory
   166   val primitive_classrel: class * class -> theory -> theory
   167   val primitive_arity: arity -> theory -> theory
   168   val hide_classes: bool -> xstring list -> theory -> theory
   169   val hide_classes_i: bool -> string list -> theory -> theory
   170   val hide_types: bool -> xstring list -> theory -> theory
   171   val hide_types_i: bool -> string list -> theory -> theory
   172   val hide_consts: bool -> xstring list -> theory -> theory
   173   val hide_consts_i: bool -> string list -> theory -> theory
   174   val hide_names: bool -> string * xstring list -> theory -> theory
   175   val hide_names_i: bool -> string * string list -> theory -> theory
   176 end
   177 
   178 structure Sign: SIGN =
   179 struct
   180 
   181 (** datatype sign **)
   182 
   183 datatype sign = Sign of
   184  {naming: NameSpace.naming,     (*common naming conventions*)
   185   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   186   tsig: Type.tsig,              (*order-sorted signature of types*)
   187   consts: Consts.T};            (*polymorphic constants*)
   188 
   189 fun make_sign (naming, syn, tsig, consts) =
   190   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   191 
   192 structure SignData = TheoryDataFun
   193 (
   194   type T = sign;
   195   val copy = I;
   196   fun extend (Sign {syn, tsig, consts, ...}) =
   197     make_sign (NameSpace.default_naming, syn, tsig, consts);
   198 
   199   val empty =
   200     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   201 
   202   fun merge pp (sign1, sign2) =
   203     let
   204       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   205       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   206 
   207       val naming = NameSpace.default_naming;
   208       val syn = Syntax.merge_syntaxes syn1 syn2;
   209       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   210       val consts = Consts.merge (consts1, consts2);
   211     in make_sign (naming, syn, tsig, consts) end;
   212 );
   213 
   214 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   215 
   216 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   217   make_sign (f (naming, syn, tsig, consts)));
   218 
   219 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   220 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   221 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   222 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   223 
   224 
   225 (* naming *)
   226 
   227 val naming_of = #naming o rep_sg;
   228 val base_name = NameSpace.base;
   229 val full_name = NameSpace.full o naming_of;
   230 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   231 val declare_name = NameSpace.declare o naming_of;
   232 
   233 
   234 (* syntax *)
   235 
   236 val syn_of = #syn o rep_sg;
   237 
   238 
   239 (* type signature *)
   240 
   241 val tsig_of = #tsig o rep_sg;
   242 
   243 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   244 val all_classes = Sorts.all_classes o classes_of;
   245 val minimal_classes = Sorts.minimal_classes o classes_of;
   246 val super_classes = Sorts.super_classes o classes_of;
   247 val minimize_sort = Sorts.minimize_sort o classes_of;
   248 val complete_sort = Sorts.complete_sort o classes_of;
   249 
   250 val defaultS = Type.defaultS o tsig_of;
   251 val subsort = Type.subsort o tsig_of;
   252 val of_sort = Type.of_sort o tsig_of;
   253 val witness_sorts = Type.witness_sorts o tsig_of;
   254 val universal_witness = Type.universal_witness o tsig_of;
   255 val all_sorts_nonempty = is_some o universal_witness;
   256 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   257 
   258 val typ_instance = Type.typ_instance o tsig_of;
   259 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   260 val typ_match = Type.typ_match o tsig_of;
   261 val typ_unify = Type.unify o tsig_of;
   262 
   263 
   264 (* polymorphic constants *)
   265 
   266 val consts_of = #consts o rep_sg;
   267 val the_const_constraint = Consts.the_constraint o consts_of;
   268 val the_const_type = Consts.the_declaration o consts_of;
   269 val const_type = try o the_const_type;
   270 val const_monomorphic = Consts.is_monomorphic o consts_of;
   271 val const_syntax_name = Consts.syntax_name o consts_of;
   272 val const_typargs = Consts.typargs o consts_of;
   273 val const_instance = Consts.instance o consts_of;
   274 
   275 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   276 val declared_const = can o the_const_constraint;
   277 
   278 
   279 
   280 (** intern / extern names **)
   281 
   282 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   283 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   284 val const_space = Consts.space_of o consts_of;
   285 
   286 val intern_class = NameSpace.intern o class_space;
   287 val extern_class = NameSpace.extern o class_space;
   288 val intern_type = NameSpace.intern o type_space;
   289 val extern_type = NameSpace.extern o type_space;
   290 val intern_const = NameSpace.intern o const_space;
   291 val extern_const = NameSpace.extern o const_space;
   292 
   293 val intern_sort = map o intern_class;
   294 val extern_sort = map o extern_class;
   295 
   296 local
   297 
   298 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   299   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   300   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   301 
   302 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   303   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   304   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   305   | map_term _ _ _ (t as Bound _) = t
   306   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   307   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   308 
   309 val add_classesT = Term.fold_atyps
   310   (fn TFree (_, S) => fold (insert (op =)) S
   311     | TVar (_, S) => fold (insert (op =)) S
   312     | _ => I);
   313 
   314 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   315   | add_tyconsT _ = I;
   316 
   317 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   318 
   319 fun mapping add_names f t =
   320   let
   321     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   322     val tab = map_filter f' (add_names t []);
   323     fun get x = the_default x (AList.lookup (op =) tab x);
   324   in get end;
   325 
   326 fun typ_mapping f g thy T =
   327   T |> map_typ
   328     (mapping add_classesT (f thy) T)
   329     (mapping add_tyconsT (g thy) T);
   330 
   331 fun term_mapping f g h thy t =
   332   t |> map_term
   333     (mapping (Term.fold_types add_classesT) (f thy) t)
   334     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   335     (mapping add_consts (h thy) t);
   336 
   337 in
   338 
   339 val intern_typ = typ_mapping intern_class intern_type;
   340 val extern_typ = typ_mapping extern_class extern_type;
   341 val intern_term = term_mapping intern_class intern_type intern_const;
   342 fun extern_term h = term_mapping extern_class extern_type (K h);
   343 val intern_tycons = typ_mapping (K I) intern_type;
   344 
   345 end;
   346 
   347 
   348 
   349 (** pretty printing of terms, types etc. **)
   350 
   351 val pretty_term = Syntax.pretty_term o ProofContext.init;
   352 val pretty_typ = Syntax.pretty_typ o ProofContext.init;
   353 val pretty_sort = Syntax.pretty_sort o ProofContext.init;
   354 
   355 val string_of_term = Syntax.string_of_term o ProofContext.init;
   356 val string_of_typ = Syntax.string_of_typ o ProofContext.init;
   357 val string_of_sort = Syntax.string_of_sort o ProofContext.init;
   358 
   359 (*pp operations -- deferred evaluation*)
   360 fun pp thy = Pretty.pp
   361  (fn x => pretty_term thy x,
   362   fn x => pretty_typ thy x,
   363   fn x => pretty_sort thy x,
   364   fn x => Syntax.pretty_classrel (ProofContext.init thy) x,
   365   fn x => Syntax.pretty_arity (ProofContext.init thy) x);
   366 
   367 
   368 
   369 (** certify entities **)    (*exception TYPE*)
   370 
   371 (* certify wrt. type signature *)
   372 
   373 val arity_number = Type.arity_number o tsig_of;
   374 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   375 
   376 val certify_class         = Type.cert_class o tsig_of;
   377 val certify_sort          = Type.cert_sort o tsig_of;
   378 val certify_typ           = Type.cert_typ o tsig_of;
   379 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   380 
   381 
   382 (* certify term/prop *)
   383 
   384 local
   385 
   386 fun type_check pp tm =
   387   let
   388     fun err_appl why bs t T u U =
   389       let
   390         val xs = map Free bs;           (*we do not rename here*)
   391         val t' = subst_bounds (xs, t);
   392         val u' = subst_bounds (xs, u);
   393         val msg = cat_lines
   394           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   395       in raise TYPE (msg, [T, U], [t', u']) end;
   396 
   397     fun typ_of (_, Const (_, T)) = T
   398       | typ_of (_, Free  (_, T)) = T
   399       | typ_of (_, Var (_, T)) = T
   400       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   401           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   402       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   403       | typ_of (bs, t $ u) =
   404           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   405             (case T of
   406               Type ("fun", [T1, T2]) =>
   407                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   408             | _ => err_appl "Operator not of function type" bs t T u U)
   409           end;
   410   in typ_of ([], tm) end;
   411 
   412 fun err msg = raise TYPE (msg, [], []);
   413 
   414 fun check_vars (t $ u) = (check_vars t; check_vars u)
   415   | check_vars (Abs (_, _, t)) = check_vars t
   416   | check_vars (Var (xi as (_, i), _)) =
   417       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   418   | check_vars _ = ();
   419 
   420 in
   421 
   422 fun certify' prop pp do_expand consts thy tm =
   423   let
   424     val _ = check_vars tm;
   425     val tm' = Term.map_types (certify_typ thy) tm;
   426     val T = type_check pp tm';
   427     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   428     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   429   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   430 
   431 fun certify_term thy = certify' false (pp thy) true (consts_of thy) thy;
   432 fun certify_prop thy = certify' true (pp thy) true (consts_of thy) thy;
   433 
   434 fun cert_term_abbrev thy = #1 o certify' false (pp thy) false (consts_of thy) thy;
   435 val cert_term = #1 oo certify_term;
   436 val cert_prop = #1 oo certify_prop;
   437 
   438 end;
   439 
   440 
   441 (* specifications *)
   442 
   443 fun no_variables kind add addT mk mkT pp tm =
   444   (case (add tm [], addT tm []) of
   445     ([], []) => tm
   446   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   447       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   448        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   449 
   450 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   451 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   452 
   453 fun cert_def pp tm =
   454   let val ((lhs, rhs), _) = tm
   455     |> no_vars pp
   456     |> Logic.strip_imp_concl
   457     |> PrimitiveDefs.dest_def pp Term.is_Const (K false) (K false)
   458   in (Term.dest_Const (Term.head_of lhs), rhs) end
   459   handle TERM (msg, _) => error msg;
   460 
   461 
   462 
   463 (** read and certify entities **)    (*exception ERROR*)
   464 
   465 (* classes *)
   466 
   467 fun read_class thy c = certify_class thy (intern_class thy c)
   468   handle TYPE (msg, _, _) => error msg;
   469 
   470 
   471 (* type arities *)
   472 
   473 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   474   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   475   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   476 
   477 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   478 val cert_arity = prep_arity (K I) certify_sort;
   479 
   480 
   481 (* types *)
   482 
   483 fun get_sort thy def_sort raw_env =
   484   let
   485     val tsig = tsig_of thy;
   486 
   487     fun eq ((xi, S), (xi', S')) =
   488       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   489     val env = distinct eq raw_env;
   490     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   491       | dups => error ("Inconsistent sort constraints for type variable(s) "
   492           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   493 
   494     fun get xi =
   495       (case (AList.lookup (op =) env xi, def_sort xi) of
   496         (NONE, NONE) => Type.defaultS tsig
   497       | (NONE, SOME S) => S
   498       | (SOME S, NONE) => S
   499       | (SOME S, SOME S') =>
   500           if Type.eq_sort tsig (S, S') then S'
   501           else error ("Sort constraint inconsistent with default for type variable " ^
   502             quote (Term.string_of_vname' xi)));
   503   in get end;
   504 
   505 local
   506 
   507 fun gen_read_typ mode (thy, def_sort) str =
   508   let
   509     val ctxt = ProofContext.init thy;
   510     val syn = syn_of thy;
   511     val T = intern_tycons thy
   512       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   513   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   514   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   515 
   516 in
   517 
   518 fun no_def_sort thy = (thy: theory, K NONE);
   519 
   520 val read_def_typ     = gen_read_typ Type.mode_default;
   521 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   522 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   523 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   524 
   525 end;
   526 
   527 
   528 (* type and constant names *)
   529 
   530 fun read_tyname thy raw_c =
   531   let val c = intern_type thy raw_c
   532   in Type (c, replicate (arity_number thy c) dummyT) end;
   533 
   534 val read_const = Consts.read_const o consts_of;
   535 
   536 
   537 
   538 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   539 
   540 (*
   541   def_type: partial map from indexnames to types (constrains Frees and Vars)
   542   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   543   used: context of already used type variables
   544   freeze: if true then generated parameters are turned into TFrees, else TVars
   545 *)
   546 
   547 fun read_def_terms'
   548     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   549   let
   550     val thy = ProofContext.theory_of ctxt;
   551     fun check_typs Ts = map (certify_typ thy) Ts
   552       handle TYPE (msg, _, _) => error msg;
   553 
   554     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   555         (try (Consts.the_constraint consts)) def_type used ~1 (SOME freeze) args |>> map fst
   556       handle TYPE (msg, _, _) => error msg;
   557 
   558     fun check T t = Exn.Result (singleton (fst o infer) (t, T))
   559       handle ERROR msg => Exn.Exn (ERROR msg);
   560     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   561     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   562         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   563   in
   564     raw_args
   565     |> map (fn (s, raw_T) =>
   566       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   567       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   568     |> infer
   569   end;
   570 
   571 fun read_def_terms (thy, types, sorts) used freeze sTs =
   572   let
   573     val pp = pp thy;
   574     val consts = consts_of thy;
   575     val cert_consts = Consts.certify pp (tsig_of thy) true consts;
   576     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   577     val (ts, inst) =
   578       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   579         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   580   in (map cert_consts ts, inst) end;
   581 
   582 fun simple_read_term thy T s =
   583   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   584   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   585 
   586 fun read_term thy = simple_read_term thy dummyT;
   587 fun read_prop thy = simple_read_term thy propT;
   588 
   589 
   590 
   591 (** signature extension functions **)  (*exception ERROR/TYPE*)
   592 
   593 (* add default sort *)
   594 
   595 fun gen_add_defsort prep_sort s thy =
   596   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   597 
   598 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   599 val add_defsort_i = gen_add_defsort certify_sort;
   600 
   601 
   602 (* add type constructors *)
   603 
   604 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   605   let
   606     val syn' = Syntax.extend_type_gram types syn;
   607     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   608     val tsig' = Type.add_types naming decls tsig;
   609   in (naming, syn', tsig', consts) end);
   610 
   611 fun add_typedecls decls thy =
   612   let
   613     fun type_of (a, vs: string list, mx) =
   614       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   615       else error ("Duplicate parameters in type declaration: " ^ quote a);
   616   in add_types (map type_of decls) thy end;
   617 
   618 
   619 (* add nonterminals *)
   620 
   621 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   622   let
   623     val syn' = Syntax.extend_consts ns syn;
   624     val tsig' = Type.add_nonterminals naming ns tsig;
   625   in (naming, syn', tsig', consts) end);
   626 
   627 
   628 (* add type abbreviations *)
   629 
   630 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   631   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   632     let
   633       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   634       val a' = Syntax.type_name a mx;
   635       val abbr = (a', vs,
   636           certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) rhs))
   637         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   638       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   639     in (naming, syn', tsig', consts) end);
   640 
   641 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   642 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   643 
   644 
   645 (* modify syntax *)
   646 
   647 fun gen_syntax change_gram prep_typ mode args thy =
   648   let
   649     fun prep (c, T, mx) = (c,
   650         certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) T), mx)
   651       handle ERROR msg =>
   652         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   653   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   654 
   655 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   656 
   657 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   658 val add_modesyntax_i = gen_add_syntax (K I);
   659 val add_syntax = add_modesyntax Syntax.mode_default;
   660 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   661 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   662 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   663 
   664 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   665   | const_syntax _ _ = NONE;
   666 
   667 fun notation add mode args thy = thy
   668   |> (if add then add_modesyntax_i else del_modesyntax_i) mode (map_filter (const_syntax thy) args);
   669 
   670 
   671 (* add constants *)
   672 
   673 local
   674 
   675 fun gen_add_consts prep_typ authentic tags raw_args thy =
   676   let
   677     val prepT = Type.no_tvars o Term.no_dummyT o prep_typ thy;
   678     fun prep (raw_c, raw_T, raw_mx) =
   679       let
   680         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   681         val full_c = full_name thy c;
   682         val c' = if authentic then Syntax.constN ^ full_c else c;
   683         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   684           cat_error msg ("in declaration of constant " ^ quote c);
   685         val T' = Compress.typ thy (Logic.varifyT T);
   686       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   687     val args = map prep raw_args;
   688   in
   689     thy
   690     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags o #1) args)
   691     |> add_syntax_i (map #2 args)
   692     |> pair (map #3 args)
   693   end;
   694 
   695 in
   696 
   697 val add_consts = snd oo gen_add_consts read_typ false [];
   698 val add_consts_i = snd oo gen_add_consts certify_typ false [];
   699 
   700 fun declare_const tags arg = gen_add_consts certify_typ true tags [arg] #>> the_single;
   701 
   702 end;
   703 
   704 
   705 (* add abbreviations *)
   706 
   707 fun add_abbrev mode tags (c, raw_t) thy =
   708   let
   709     val pp = pp thy;
   710     val prep_tm = Compress.term thy o no_frees pp o
   711       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   712       Term.no_dummy_patterns o cert_term_abbrev thy;
   713     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   714       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   715     val (res, consts') = consts_of thy
   716       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   717   in (res, thy |> map_consts (K consts')) end;
   718 
   719 
   720 (* add constraints *)
   721 
   722 fun add_const_constraint (c, opt_T) thy =
   723   let
   724     fun prepT raw_T =
   725       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   726       in cert_term thy (Const (c, T)); T end
   727       handle TYPE (msg, _, _) => error msg;
   728   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   729 
   730 
   731 (* primitive classes and arities *)
   732 
   733 fun primitive_class (bclass, classes) thy =
   734   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   735     let
   736       val syn' = Syntax.extend_consts [bclass] syn;
   737       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   738     in (naming, syn', tsig', consts) end)
   739   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   740 
   741 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   742 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   743 
   744 
   745 (* add translation functions *)
   746 
   747 local
   748 
   749 fun mk trs = map Syntax.mk_trfun trs;
   750 
   751 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   752   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   753 
   754 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   755 
   756 in
   757 
   758 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   759 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   760 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   761 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   762 
   763 end;
   764 
   765 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   766 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   767 
   768 
   769 (* translation rules *)
   770 
   771 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   772   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   773   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   774 
   775 val add_trrules = gen_trrules Syntax.extend_trrules;
   776 val del_trrules = gen_trrules Syntax.remove_trrules;
   777 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   778 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   779 
   780 
   781 (* modify naming *)
   782 
   783 val add_path        = map_naming o NameSpace.add_path;
   784 val no_base_names   = map_naming NameSpace.no_base_names;
   785 val qualified_names = map_naming NameSpace.qualified_names;
   786 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   787 val set_policy      = map_naming o NameSpace.set_policy;
   788 val restore_naming  = map_naming o K o naming_of;
   789 
   790 val parent_path   = add_path "..";
   791 val root_path     = add_path "/";
   792 val absolute_path = add_path "//";
   793 
   794 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   795 
   796 
   797 (* hide names *)
   798 
   799 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   800 val hide_classes_i = map_tsig oo Type.hide_classes;
   801 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   802 val hide_types_i = map_tsig oo Type.hide_types;
   803 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   804 val hide_consts_i = map_consts oo (fold o Consts.hide);
   805 
   806 local
   807 
   808 val kinds =
   809  [("class", (intern_class, can o certify_class, hide_classes_i)),
   810   ("type", (intern_type, declared_tyname, hide_types_i)),
   811   ("const", (intern_const, declared_const, hide_consts_i))];
   812 
   813 fun gen_hide int b (kind, xnames) thy =
   814   (case AList.lookup (op =) kinds kind of
   815     SOME (intern, check, hide) =>
   816       let
   817         val names = if int then map (intern thy) xnames else xnames;
   818         val bads = filter_out (check thy) names;
   819       in
   820         if null bads then hide b names thy
   821         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   822       end
   823   | NONE => error ("Bad name space specification: " ^ quote kind));
   824 
   825 in
   826 
   827 val hide_names = gen_hide true;
   828 val hide_names_i = gen_hide false;
   829 
   830 end;
   831 
   832 end;