src/HOL/BNF_FP_Base.thy
author desharna
Tue Jul 01 17:01:28 2014 +0200 (2014-07-01)
changeset 57471 11cd462e31ec
parent 57303 498a62e65f5f
child 57489 8f0ba9f2d10f
permissions -rw-r--r--
generate 'rel_induct' theorem for datatypes
     1 (*  Title:      HOL/BNF_FP_Base.thy
     2     Author:     Lorenz Panny, TU Muenchen
     3     Author:     Dmitriy Traytel, TU Muenchen
     4     Author:     Jasmin Blanchette, TU Muenchen
     5     Copyright   2012, 2013
     6 
     7 Shared fixed point operations on bounded natural functors.
     8 *)
     9 
    10 header {* Shared Fixed Point Operations on Bounded Natural Functors *}
    11 
    12 theory BNF_FP_Base
    13 imports BNF_Comp Basic_BNFs
    14 begin
    15 
    16 lemma mp_conj: "(P \<longrightarrow> Q) \<and> R \<Longrightarrow> P \<Longrightarrow> R \<and> Q"
    17 by auto
    18 
    19 lemma predicate2D_conj: "P \<le> Q \<and> R \<Longrightarrow> P x y \<Longrightarrow> R \<and> Q x y"
    20   by auto
    21 
    22 lemma eq_sym_Unity_conv: "(x = (() = ())) = x"
    23 by blast
    24 
    25 lemma case_unit_Unity: "(case u of () \<Rightarrow> f) = f"
    26 by (cases u) (hypsubst, rule unit.case)
    27 
    28 lemma case_prod_Pair_iden: "(case p of (x, y) \<Rightarrow> (x, y)) = p"
    29 by simp
    30 
    31 lemma unit_all_impI: "(P () \<Longrightarrow> Q ()) \<Longrightarrow> \<forall>x. P x \<longrightarrow> Q x"
    32 by simp
    33 
    34 lemma pointfree_idE: "f \<circ> g = id \<Longrightarrow> f (g x) = x"
    35 unfolding comp_def fun_eq_iff by simp
    36 
    37 lemma o_bij:
    38   assumes gf: "g \<circ> f = id" and fg: "f \<circ> g = id"
    39   shows "bij f"
    40 unfolding bij_def inj_on_def surj_def proof safe
    41   fix a1 a2 assume "f a1 = f a2"
    42   hence "g ( f a1) = g (f a2)" by simp
    43   thus "a1 = a2" using gf unfolding fun_eq_iff by simp
    44 next
    45   fix b
    46   have "b = f (g b)"
    47   using fg unfolding fun_eq_iff by simp
    48   thus "EX a. b = f a" by blast
    49 qed
    50 
    51 lemma ssubst_mem: "\<lbrakk>t = s; s \<in> X\<rbrakk> \<Longrightarrow> t \<in> X" by simp
    52 
    53 lemma case_sum_step:
    54 "case_sum (case_sum f' g') g (Inl p) = case_sum f' g' p"
    55 "case_sum f (case_sum f' g') (Inr p) = case_sum f' g' p"
    56 by auto
    57 
    58 lemma obj_one_pointE: "\<forall>x. s = x \<longrightarrow> P \<Longrightarrow> P"
    59 by blast
    60 
    61 lemma type_copy_obj_one_point_absE:
    62   assumes "type_definition Rep Abs UNIV" "\<forall>x. s = Abs x \<longrightarrow> P" shows P
    63   using type_definition.Rep_inverse[OF assms(1)]
    64   by (intro mp[OF spec[OF assms(2), of "Rep s"]]) simp
    65 
    66 lemma obj_sumE_f:
    67   assumes "\<forall>x. s = f (Inl x) \<longrightarrow> P" "\<forall>x. s = f (Inr x) \<longrightarrow> P"
    68   shows "\<forall>x. s = f x \<longrightarrow> P"
    69 proof
    70   fix x from assms show "s = f x \<longrightarrow> P" by (cases x) auto
    71 qed
    72 
    73 lemma case_sum_if:
    74 "case_sum f g (if p then Inl x else Inr y) = (if p then f x else g y)"
    75 by simp
    76 
    77 lemma prod_set_simps:
    78 "fsts (x, y) = {x}"
    79 "snds (x, y) = {y}"
    80 unfolding fsts_def snds_def by simp+
    81 
    82 lemma sum_set_simps:
    83 "setl (Inl x) = {x}"
    84 "setl (Inr x) = {}"
    85 "setr (Inl x) = {}"
    86 "setr (Inr x) = {x}"
    87 unfolding sum_set_defs by simp+
    88 
    89 lemma Inl_Inr_False: "(Inl x = Inr y) = False"
    90   by simp
    91 
    92 lemma Inr_Inl_False: "(Inr x = Inl y) = False"
    93   by simp
    94 
    95 lemma spec2: "\<forall>x y. P x y \<Longrightarrow> P x y"
    96 by blast
    97 
    98 lemma rewriteR_comp_comp: "\<lbrakk>g \<circ> h = r\<rbrakk> \<Longrightarrow> f \<circ> g \<circ> h = f \<circ> r"
    99   unfolding comp_def fun_eq_iff by auto
   100 
   101 lemma rewriteR_comp_comp2: "\<lbrakk>g \<circ> h = r1 \<circ> r2; f \<circ> r1 = l\<rbrakk> \<Longrightarrow> f \<circ> g \<circ> h = l \<circ> r2"
   102   unfolding comp_def fun_eq_iff by auto
   103 
   104 lemma rewriteL_comp_comp: "\<lbrakk>f \<circ> g = l\<rbrakk> \<Longrightarrow> f \<circ> (g \<circ> h) = l \<circ> h"
   105   unfolding comp_def fun_eq_iff by auto
   106 
   107 lemma rewriteL_comp_comp2: "\<lbrakk>f \<circ> g = l1 \<circ> l2; l2 \<circ> h = r\<rbrakk> \<Longrightarrow> f \<circ> (g \<circ> h) = l1 \<circ> r"
   108   unfolding comp_def fun_eq_iff by auto
   109 
   110 lemma convol_o: "<f, g> \<circ> h = <f \<circ> h, g \<circ> h>"
   111   unfolding convol_def by auto
   112 
   113 lemma map_prod_o_convol: "map_prod h1 h2 \<circ> <f, g> = <h1 \<circ> f, h2 \<circ> g>"
   114   unfolding convol_def by auto
   115 
   116 lemma map_prod_o_convol_id: "(map_prod f id \<circ> <id , g>) x = <id \<circ> f , g> x"
   117   unfolding map_prod_o_convol id_comp comp_id ..
   118 
   119 lemma o_case_sum: "h \<circ> case_sum f g = case_sum (h \<circ> f) (h \<circ> g)"
   120   unfolding comp_def by (auto split: sum.splits)
   121 
   122 lemma case_sum_o_map_sum: "case_sum f g \<circ> map_sum h1 h2 = case_sum (f \<circ> h1) (g \<circ> h2)"
   123   unfolding comp_def by (auto split: sum.splits)
   124 
   125 lemma case_sum_o_map_sum_id: "(case_sum id g \<circ> map_sum f id) x = case_sum (f \<circ> id) g x"
   126   unfolding case_sum_o_map_sum id_comp comp_id ..
   127 
   128 lemma rel_fun_def_butlast:
   129   "rel_fun R (rel_fun S T) f g = (\<forall>x y. R x y \<longrightarrow> (rel_fun S T) (f x) (g y))"
   130   unfolding rel_fun_def ..
   131 
   132 lemma subst_eq_imp: "(\<forall>a b. a = b \<longrightarrow> P a b) \<equiv> (\<forall>a. P a a)"
   133   by auto
   134 
   135 lemma eq_subset: "op = \<le> (\<lambda>a b. P a b \<or> a = b)"
   136   by auto
   137 
   138 lemma eq_le_Grp_id_iff: "(op = \<le> Grp (Collect R) id) = (All R)"
   139   unfolding Grp_def id_apply by blast
   140 
   141 lemma Grp_id_mono_subst: "(\<And>x y. Grp P id x y \<Longrightarrow> Grp Q id (f x) (f y)) \<equiv>
   142    (\<And>x. x \<in> P \<Longrightarrow> f x \<in> Q)"
   143   unfolding Grp_def by rule auto
   144 
   145 lemma vimage2p_mono: "vimage2p f g R x y \<Longrightarrow> R \<le> S \<Longrightarrow> vimage2p f g S x y"
   146   unfolding vimage2p_def by blast
   147 
   148 lemma vimage2p_refl: "(\<And>x. R x x) \<Longrightarrow> vimage2p f f R x x"
   149   unfolding vimage2p_def by auto
   150 
   151 lemma
   152   assumes "type_definition Rep Abs UNIV"
   153   shows type_copy_Rep_o_Abs: "Rep \<circ> Abs = id" and type_copy_Abs_o_Rep: "Abs \<circ> Rep = id"
   154   unfolding fun_eq_iff comp_apply id_apply
   155     type_definition.Abs_inverse[OF assms UNIV_I] type_definition.Rep_inverse[OF assms] by simp_all
   156 
   157 lemma type_copy_map_comp0_undo:
   158   assumes "type_definition Rep Abs UNIV"
   159           "type_definition Rep' Abs' UNIV"
   160           "type_definition Rep'' Abs'' UNIV"
   161   shows "Abs' \<circ> M \<circ> Rep'' = (Abs' \<circ> M1 \<circ> Rep) \<circ> (Abs \<circ> M2 \<circ> Rep'') \<Longrightarrow> M1 \<circ> M2 = M"
   162   by (rule sym) (auto simp: fun_eq_iff type_definition.Abs_inject[OF assms(2) UNIV_I UNIV_I]
   163     type_definition.Abs_inverse[OF assms(1) UNIV_I]
   164     type_definition.Abs_inverse[OF assms(3) UNIV_I] dest: spec[of _ "Abs'' x" for x])
   165 
   166 lemma vimage2p_id: "vimage2p id id R = R"
   167   unfolding vimage2p_def by auto
   168 
   169 lemma vimage2p_comp: "vimage2p (f1 \<circ> f2) (g1 \<circ> g2) = vimage2p f2 g2 \<circ> vimage2p f1 g1"
   170   unfolding fun_eq_iff vimage2p_def o_apply by simp
   171 
   172 lemma fun_cong_unused_0: "f = (\<lambda>x. g) \<Longrightarrow> f (\<lambda>x. 0) = g"
   173   by (erule arg_cong)
   174 
   175 lemma inj_on_convol_ident: "inj_on (\<lambda>x. (x, f x)) X"
   176   unfolding inj_on_def by simp
   177 
   178 lemma case_prod_app: "case_prod f x y = case_prod (\<lambda>l r. f l r y) x"
   179   by (case_tac x) simp
   180 
   181 lemma case_sum_map_sum: "case_sum l r (map_sum f g x) = case_sum (l \<circ> f) (r \<circ> g) x"
   182   by (case_tac x) simp+
   183 
   184 lemma case_prod_map_prod: "case_prod h (map_prod f g x) = case_prod (\<lambda>l r. h (f l) (g r)) x"
   185   by (case_tac x) simp+
   186 
   187 lemma prod_inj_map: "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (map_prod f g)"
   188   by (simp add: inj_on_def)
   189 
   190 ML_file "Tools/BNF/bnf_fp_util.ML"
   191 ML_file "Tools/BNF/bnf_fp_def_sugar_tactics.ML"
   192 ML_file "Tools/BNF/bnf_lfp_size.ML"
   193 ML_file "Tools/BNF/bnf_fp_def_sugar.ML"
   194 ML_file "Tools/BNF/bnf_fp_n2m_tactics.ML"
   195 ML_file "Tools/BNF/bnf_fp_n2m.ML"
   196 ML_file "Tools/BNF/bnf_fp_n2m_sugar.ML"
   197 
   198 ML_file "Tools/Function/size.ML"
   199 setup Size.setup
   200 
   201 lemma size_bool[code]: "size (b\<Colon>bool) = 0"
   202   by (cases b) auto
   203 
   204 lemma size_nat[simp, code]: "size (n\<Colon>nat) = n"
   205   by (induct n) simp_all
   206 
   207 declare prod.size[no_atp]
   208 
   209 lemma size_sum_o_map: "size_sum g1 g2 \<circ> map_sum f1 f2 = size_sum (g1 \<circ> f1) (g2 \<circ> f2)"
   210   by (rule ext) (case_tac x, auto)
   211 
   212 lemma size_prod_o_map: "size_prod g1 g2 \<circ> map_prod f1 f2 = size_prod (g1 \<circ> f1) (g2 \<circ> f2)"
   213   by (rule ext) auto
   214 
   215 setup {*
   216 BNF_LFP_Size.register_size_global @{type_name sum} @{const_name size_sum} @{thms sum.size}
   217   @{thms size_sum_o_map}
   218 #> BNF_LFP_Size.register_size_global @{type_name prod} @{const_name size_prod} @{thms prod.size}
   219   @{thms size_prod_o_map}
   220 *}
   221 
   222 end