src/HOL/NatDef.ML
author paulson
Fri May 30 15:30:52 1997 +0200 (1997-05-30)
changeset 3378 11f4884a071a
parent 3355 0d955bcf8e0a
child 3457 a8ab7c64817c
permissions -rw-r--r--
Moved "less_eq" to NatDef from Arith
     1 (*  Title:      HOL/NatDef.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 *)
     6 
     7 goal thy "mono(%X. {Zero_Rep} Un (Suc_Rep``X))";
     8 by (REPEAT (ares_tac [monoI, subset_refl, image_mono, Un_mono] 1));
     9 qed "Nat_fun_mono";
    10 
    11 val Nat_unfold = Nat_fun_mono RS (Nat_def RS def_lfp_Tarski);
    12 
    13 (* Zero is a natural number -- this also justifies the type definition*)
    14 goal thy "Zero_Rep: Nat";
    15 by (stac Nat_unfold 1);
    16 by (rtac (singletonI RS UnI1) 1);
    17 qed "Zero_RepI";
    18 
    19 val prems = goal thy "i: Nat ==> Suc_Rep(i) : Nat";
    20 by (stac Nat_unfold 1);
    21 by (rtac (imageI RS UnI2) 1);
    22 by (resolve_tac prems 1);
    23 qed "Suc_RepI";
    24 
    25 (*** Induction ***)
    26 
    27 val major::prems = goal thy
    28     "[| i: Nat;  P(Zero_Rep);   \
    29 \       !!j. [| j: Nat; P(j) |] ==> P(Suc_Rep(j)) |]  ==> P(i)";
    30 by (rtac ([Nat_def, Nat_fun_mono, major] MRS def_induct) 1);
    31 by (blast_tac (!claset addIs prems) 1);
    32 qed "Nat_induct";
    33 
    34 val prems = goalw thy [Zero_def,Suc_def]
    35     "[| P(0);   \
    36 \       !!n. P(n) ==> P(Suc(n)) |]  ==> P(n)";
    37 by (rtac (Rep_Nat_inverse RS subst) 1);   (*types force good instantiation*)
    38 by (rtac (Rep_Nat RS Nat_induct) 1);
    39 by (REPEAT (ares_tac prems 1
    40      ORELSE eresolve_tac [Abs_Nat_inverse RS subst] 1));
    41 qed "nat_induct";
    42 
    43 (*Perform induction on n. *)
    44 fun nat_ind_tac a i = 
    45     EVERY[res_inst_tac [("n",a)] nat_induct i,
    46           COND (Datatype.occs_in_prems a (i+1)) all_tac
    47                (rename_last_tac a [""] (i+1))];
    48 
    49 (*A special form of induction for reasoning about m<n and m-n*)
    50 val prems = goal thy
    51     "[| !!x. P x 0;  \
    52 \       !!y. P 0 (Suc y);  \
    53 \       !!x y. [| P x y |] ==> P (Suc x) (Suc y)  \
    54 \    |] ==> P m n";
    55 by (res_inst_tac [("x","m")] spec 1);
    56 by (nat_ind_tac "n" 1);
    57 by (rtac allI 2);
    58 by (nat_ind_tac "x" 2);
    59 by (REPEAT (ares_tac (prems@[allI]) 1 ORELSE etac spec 1));
    60 qed "diff_induct";
    61 
    62 (*Case analysis on the natural numbers*)
    63 val prems = goal thy 
    64     "[| n=0 ==> P;  !!x. n = Suc(x) ==> P |] ==> P";
    65 by (subgoal_tac "n=0 | (EX x. n = Suc(x))" 1);
    66 by (fast_tac (!claset addSEs prems) 1);
    67 by (nat_ind_tac "n" 1);
    68 by (rtac (refl RS disjI1) 1);
    69 by (Blast_tac 1);
    70 qed "natE";
    71 
    72 (*Install 'automatic' induction tactic, pretending nat is a datatype *)
    73 (*except for induct_tac and exhaust_tac, everything is dummy*)
    74 datatypes := [("nat",{case_const = Bound 0, case_rewrites = [],
    75   constructors = [], induct_tac = nat_ind_tac,
    76   exhaustion = natE,
    77   exhaust_tac = fn v => ALLNEWSUBGOALS (res_inst_tac [("n",v)] natE)
    78                                        (rotate_tac ~1),
    79   nchotomy = flexpair_def, case_cong = flexpair_def})];
    80 
    81 
    82 (*** Isomorphisms: Abs_Nat and Rep_Nat ***)
    83 
    84 (*We can't take these properties as axioms, or take Abs_Nat==Inv(Rep_Nat),
    85   since we assume the isomorphism equations will one day be given by Isabelle*)
    86 
    87 goal thy "inj(Rep_Nat)";
    88 by (rtac inj_inverseI 1);
    89 by (rtac Rep_Nat_inverse 1);
    90 qed "inj_Rep_Nat";
    91 
    92 goal thy "inj_onto Abs_Nat Nat";
    93 by (rtac inj_onto_inverseI 1);
    94 by (etac Abs_Nat_inverse 1);
    95 qed "inj_onto_Abs_Nat";
    96 
    97 (*** Distinctness of constructors ***)
    98 
    99 goalw thy [Zero_def,Suc_def] "Suc(m) ~= 0";
   100 by (rtac (inj_onto_Abs_Nat RS inj_onto_contraD) 1);
   101 by (rtac Suc_Rep_not_Zero_Rep 1);
   102 by (REPEAT (resolve_tac [Rep_Nat, Suc_RepI, Zero_RepI] 1));
   103 qed "Suc_not_Zero";
   104 
   105 bind_thm ("Zero_not_Suc", Suc_not_Zero RS not_sym);
   106 
   107 AddIffs [Suc_not_Zero,Zero_not_Suc];
   108 
   109 bind_thm ("Suc_neq_Zero", (Suc_not_Zero RS notE));
   110 val Zero_neq_Suc = sym RS Suc_neq_Zero;
   111 
   112 (** Injectiveness of Suc **)
   113 
   114 goalw thy [Suc_def] "inj(Suc)";
   115 by (rtac injI 1);
   116 by (dtac (inj_onto_Abs_Nat RS inj_ontoD) 1);
   117 by (REPEAT (resolve_tac [Rep_Nat, Suc_RepI] 1));
   118 by (dtac (inj_Suc_Rep RS injD) 1);
   119 by (etac (inj_Rep_Nat RS injD) 1);
   120 qed "inj_Suc";
   121 
   122 val Suc_inject = inj_Suc RS injD;
   123 
   124 goal thy "(Suc(m)=Suc(n)) = (m=n)";
   125 by (EVERY1 [rtac iffI, etac Suc_inject, etac arg_cong]); 
   126 qed "Suc_Suc_eq";
   127 
   128 AddIffs [Suc_Suc_eq];
   129 
   130 goal thy "n ~= Suc(n)";
   131 by (nat_ind_tac "n" 1);
   132 by (ALLGOALS Asm_simp_tac);
   133 qed "n_not_Suc_n";
   134 
   135 bind_thm ("Suc_n_not_n", n_not_Suc_n RS not_sym);
   136 
   137 goal thy "!!n. n ~= 0 ==> EX m. n = Suc m";
   138 br natE 1;
   139 by (REPEAT (Blast_tac 1));
   140 qed "not0_implies_Suc";
   141 
   142 
   143 (*** nat_case -- the selection operator for nat ***)
   144 
   145 goalw thy [nat_case_def] "nat_case a f 0 = a";
   146 by (blast_tac (!claset addIs [select_equality]) 1);
   147 qed "nat_case_0";
   148 
   149 goalw thy [nat_case_def] "nat_case a f (Suc k) = f(k)";
   150 by (blast_tac (!claset addIs [select_equality]) 1);
   151 qed "nat_case_Suc";
   152 
   153 goalw thy [wf_def, pred_nat_def] "wf(pred_nat)";
   154 by (strip_tac 1);
   155 by (nat_ind_tac "x" 1);
   156 by (ALLGOALS Blast_tac);
   157 qed "wf_pred_nat";
   158 
   159 
   160 (*** nat_rec -- by wf recursion on pred_nat ***)
   161 
   162 (* The unrolling rule for nat_rec *)
   163 goal thy
   164    "(%n. nat_rec c d n) = wfrec pred_nat (%f. nat_case ?c (%m. ?d m (f m)))";
   165   by (simp_tac (HOL_ss addsimps [nat_rec_def]) 1);
   166 bind_thm("nat_rec_unfold", wf_pred_nat RS 
   167                             ((result() RS eq_reflection) RS def_wfrec));
   168 
   169 (*---------------------------------------------------------------------------
   170  * Old:
   171  * bind_thm ("nat_rec_unfold", (wf_pred_nat RS (nat_rec_def RS def_wfrec))); 
   172  *---------------------------------------------------------------------------*)
   173 
   174 (** conversion rules **)
   175 
   176 goal thy "nat_rec c h 0 = c";
   177 by (rtac (nat_rec_unfold RS trans) 1);
   178 by (simp_tac (!simpset addsimps [nat_case_0]) 1);
   179 qed "nat_rec_0";
   180 
   181 goal thy "nat_rec c h (Suc n) = h n (nat_rec c h n)";
   182 by (rtac (nat_rec_unfold RS trans) 1);
   183 by (simp_tac (!simpset addsimps [nat_case_Suc, pred_nat_def, cut_apply]) 1);
   184 qed "nat_rec_Suc";
   185 
   186 (*These 2 rules ease the use of primitive recursion.  NOTE USE OF == *)
   187 val [rew] = goal thy
   188     "[| !!n. f(n) == nat_rec c h n |] ==> f(0) = c";
   189 by (rewtac rew);
   190 by (rtac nat_rec_0 1);
   191 qed "def_nat_rec_0";
   192 
   193 val [rew] = goal thy
   194     "[| !!n. f(n) == nat_rec c h n |] ==> f(Suc(n)) = h n (f n)";
   195 by (rewtac rew);
   196 by (rtac nat_rec_Suc 1);
   197 qed "def_nat_rec_Suc";
   198 
   199 fun nat_recs def =
   200       [standard (def RS def_nat_rec_0),
   201        standard (def RS def_nat_rec_Suc)];
   202 
   203 
   204 (*** Basic properties of "less than" ***)
   205 
   206 (*Used in TFL/post.sml*)
   207 goalw thy [less_def] "(m,n) : pred_nat^+ = (m<n)";
   208 by (rtac refl 1);
   209 qed "less_eq";
   210 
   211 (** Introduction properties **)
   212 
   213 val prems = goalw thy [less_def] "[| i<j;  j<k |] ==> i<(k::nat)";
   214 by (rtac (trans_trancl RS transD) 1);
   215 by (resolve_tac prems 1);
   216 by (resolve_tac prems 1);
   217 qed "less_trans";
   218 
   219 goalw thy [less_def, pred_nat_def] "n < Suc(n)";
   220 by (simp_tac (!simpset addsimps [r_into_trancl]) 1);
   221 qed "lessI";
   222 AddIffs [lessI];
   223 
   224 (* i<j ==> i<Suc(j) *)
   225 bind_thm("less_SucI", lessI RSN (2, less_trans));
   226 Addsimps [less_SucI];
   227 
   228 goal thy "0 < Suc(n)";
   229 by (nat_ind_tac "n" 1);
   230 by (rtac lessI 1);
   231 by (etac less_trans 1);
   232 by (rtac lessI 1);
   233 qed "zero_less_Suc";
   234 AddIffs [zero_less_Suc];
   235 
   236 (** Elimination properties **)
   237 
   238 val prems = goalw thy [less_def] "n<m ==> ~ m<(n::nat)";
   239 by (blast_tac (!claset addIs ([wf_pred_nat, wf_trancl RS wf_asym]@prems))1);
   240 qed "less_not_sym";
   241 
   242 (* [| n<m; m<n |] ==> R *)
   243 bind_thm ("less_asym", (less_not_sym RS notE));
   244 
   245 goalw thy [less_def] "~ n<(n::nat)";
   246 by (rtac notI 1);
   247 by (etac (wf_pred_nat RS wf_trancl RS wf_irrefl) 1);
   248 qed "less_not_refl";
   249 
   250 (* n<n ==> R *)
   251 bind_thm ("less_irrefl", (less_not_refl RS notE));
   252 
   253 goal thy "!!m. n<m ==> m ~= (n::nat)";
   254 by (blast_tac (!claset addSEs [less_irrefl]) 1);
   255 qed "less_not_refl2";
   256 
   257 
   258 val major::prems = goalw thy [less_def, pred_nat_def]
   259     "[| i<k;  k=Suc(i) ==> P;  !!j. [| i<j;  k=Suc(j) |] ==> P \
   260 \    |] ==> P";
   261 by (rtac (major RS tranclE) 1);
   262 by (ALLGOALS Full_simp_tac); 
   263 by (REPEAT_FIRST (bound_hyp_subst_tac ORELSE'
   264                   eresolve_tac (prems@[asm_rl, Pair_inject])));
   265 qed "lessE";
   266 
   267 goal thy "~ n<0";
   268 by (rtac notI 1);
   269 by (etac lessE 1);
   270 by (etac Zero_neq_Suc 1);
   271 by (etac Zero_neq_Suc 1);
   272 qed "not_less0";
   273 
   274 AddIffs [not_less0];
   275 
   276 (* n<0 ==> R *)
   277 bind_thm ("less_zeroE", not_less0 RS notE);
   278 
   279 val [major,less,eq] = goal thy
   280     "[| m < Suc(n);  m<n ==> P;  m=n ==> P |] ==> P";
   281 by (rtac (major RS lessE) 1);
   282 by (rtac eq 1);
   283 by (Blast_tac 1);
   284 by (rtac less 1);
   285 by (Blast_tac 1);
   286 qed "less_SucE";
   287 
   288 goal thy "(m < Suc(n)) = (m < n | m = n)";
   289 by (blast_tac (!claset addSEs [less_SucE] addIs [less_trans]) 1);
   290 qed "less_Suc_eq";
   291 
   292 val prems = goal thy "m<n ==> n ~= 0";
   293 by (res_inst_tac [("n","n")] natE 1);
   294 by (cut_facts_tac prems 1);
   295 by (ALLGOALS Asm_full_simp_tac);
   296 qed "gr_implies_not0";
   297 Addsimps [gr_implies_not0];
   298 
   299 qed_goal "zero_less_eq" thy "0 < n = (n ~= 0)" (fn _ => [
   300         rtac iffI 1,
   301         etac gr_implies_not0 1,
   302         rtac natE 1,
   303         contr_tac 1,
   304         etac ssubst 1,
   305         rtac zero_less_Suc 1]);
   306 
   307 (** Inductive (?) properties **)
   308 
   309 val [prem] = goal thy "Suc(m) < n ==> m<n";
   310 by (rtac (prem RS rev_mp) 1);
   311 by (nat_ind_tac "n" 1);
   312 by (ALLGOALS (fast_tac (!claset addSIs [lessI RS less_SucI]
   313                                 addEs  [less_trans, lessE])));
   314 qed "Suc_lessD";
   315 
   316 val [major,minor] = goal thy 
   317     "[| Suc(i)<k;  !!j. [| i<j;  k=Suc(j) |] ==> P \
   318 \    |] ==> P";
   319 by (rtac (major RS lessE) 1);
   320 by (etac (lessI RS minor) 1);
   321 by (etac (Suc_lessD RS minor) 1);
   322 by (assume_tac 1);
   323 qed "Suc_lessE";
   324 
   325 goal thy "!!m n. Suc(m) < Suc(n) ==> m<n";
   326 by (blast_tac (!claset addEs [lessE, make_elim Suc_lessD]) 1);
   327 qed "Suc_less_SucD";
   328 
   329 goal thy "!!m n. m<n ==> Suc(m) < Suc(n)";
   330 by (etac rev_mp 1);
   331 by (nat_ind_tac "n" 1);
   332 by (ALLGOALS (fast_tac (!claset addEs  [less_trans, lessE])));
   333 qed "Suc_mono";
   334 
   335 
   336 goal thy "(Suc(m) < Suc(n)) = (m<n)";
   337 by (EVERY1 [rtac iffI, etac Suc_less_SucD, etac Suc_mono]);
   338 qed "Suc_less_eq";
   339 Addsimps [Suc_less_eq];
   340 
   341 goal thy "~(Suc(n) < n)";
   342 by (blast_tac (!claset addEs [Suc_lessD RS less_irrefl]) 1);
   343 qed "not_Suc_n_less_n";
   344 Addsimps [not_Suc_n_less_n];
   345 
   346 goal thy "!!i. i<j ==> j<k --> Suc i < k";
   347 by (nat_ind_tac "k" 1);
   348 by (ALLGOALS (asm_simp_tac (!simpset)));
   349 by (asm_simp_tac (!simpset addsimps [less_Suc_eq]) 1);
   350 by (blast_tac (!claset addDs [Suc_lessD]) 1);
   351 qed_spec_mp "less_trans_Suc";
   352 
   353 (*"Less than" is a linear ordering*)
   354 goal thy "m<n | m=n | n<(m::nat)";
   355 by (nat_ind_tac "m" 1);
   356 by (nat_ind_tac "n" 1);
   357 by (rtac (refl RS disjI1 RS disjI2) 1);
   358 by (rtac (zero_less_Suc RS disjI1) 1);
   359 by (blast_tac (!claset addIs [Suc_mono, less_SucI] addEs [lessE]) 1);
   360 qed "less_linear";
   361 
   362 qed_goal "nat_less_cases" thy 
   363    "[| (m::nat)<n ==> P n m; m=n ==> P n m; n<m ==> P n m |] ==> P n m"
   364 ( fn [major,eqCase,lessCase] =>
   365         [
   366         (rtac (less_linear RS disjE) 1),
   367         (etac disjE 2),
   368         (etac lessCase 1),
   369         (etac (sym RS eqCase) 1),
   370         (etac major 1)
   371         ]);
   372 
   373 (*Can be used with less_Suc_eq to get n=m | n<m *)
   374 goal thy "(~ m < n) = (n < Suc(m))";
   375 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   376 by (ALLGOALS Asm_simp_tac);
   377 qed "not_less_eq";
   378 
   379 (*Complete induction, aka course-of-values induction*)
   380 val prems = goalw thy [less_def]
   381     "[| !!n. [| ! m::nat. m<n --> P(m) |] ==> P(n) |]  ==>  P(n)";
   382 by (wf_ind_tac "n" [wf_pred_nat RS wf_trancl] 1);
   383 by (eresolve_tac prems 1);
   384 qed "less_induct";
   385 
   386 qed_goal "nat_induct2" thy 
   387 "[| P 0; P 1; !!k. P k ==> P (Suc (Suc k)) |] ==> P n" (fn prems => [
   388         cut_facts_tac prems 1,
   389         rtac less_induct 1,
   390         res_inst_tac [("n","n")] natE 1,
   391          hyp_subst_tac 1,
   392          atac 1,
   393         hyp_subst_tac 1,
   394         res_inst_tac [("n","x")] natE 1,
   395          hyp_subst_tac 1,
   396          atac 1,
   397         hyp_subst_tac 1,
   398         resolve_tac prems 1,
   399         dtac spec 1,
   400         etac mp 1,
   401         rtac (lessI RS less_trans) 1,
   402         rtac (lessI RS Suc_mono) 1]);
   403 
   404 (*** Properties of <= ***)
   405 
   406 goalw thy [le_def] "(m <= n) = (m < Suc n)";
   407 by (rtac not_less_eq 1);
   408 qed "le_eq_less_Suc";
   409 
   410 (*  m<=n ==> m < Suc n  *)
   411 bind_thm ("le_imp_less_Suc", le_eq_less_Suc RS iffD1);
   412 
   413 goalw thy [le_def] "0 <= n";
   414 by (rtac not_less0 1);
   415 qed "le0";
   416 
   417 goalw thy [le_def] "~ Suc n <= n";
   418 by (Simp_tac 1);
   419 qed "Suc_n_not_le_n";
   420 
   421 goalw thy [le_def] "(i <= 0) = (i = 0)";
   422 by (nat_ind_tac "i" 1);
   423 by (ALLGOALS Asm_simp_tac);
   424 qed "le_0_eq";
   425 
   426 Addsimps [(*less_Suc_eq, makes simpset non-confluent*) le0, le_0_eq,
   427           Suc_n_not_le_n,
   428           n_not_Suc_n, Suc_n_not_n,
   429           nat_case_0, nat_case_Suc, nat_rec_0, nat_rec_Suc];
   430 
   431 goal thy "!!m. (m <= Suc(n)) = (m<=n | m = Suc n)";
   432 by (simp_tac (!simpset addsimps [le_eq_less_Suc]) 1);
   433 by (blast_tac (!claset addSEs [less_SucE] addIs [less_SucI]) 1);
   434 qed "le_Suc_eq";
   435 
   436 (*
   437 goal thy "(Suc m < n | Suc m = n) = (m < n)";
   438 by (stac (less_Suc_eq RS sym) 1);
   439 by (rtac Suc_less_eq 1);
   440 qed "Suc_le_eq";
   441 
   442 this could make the simpset (with less_Suc_eq added again) more confluent,
   443 but less_Suc_eq makes additional problems with terms of the form 0 < Suc (...)
   444 *)
   445 
   446 (*Prevents simplification of f and g: much faster*)
   447 qed_goal "nat_case_weak_cong" thy
   448   "m=n ==> nat_case a f m = nat_case a f n"
   449   (fn [prem] => [rtac (prem RS arg_cong) 1]);
   450 
   451 qed_goal "nat_rec_weak_cong" thy
   452   "m=n ==> nat_rec a f m = nat_rec a f n"
   453   (fn [prem] => [rtac (prem RS arg_cong) 1]);
   454 
   455 qed_goal "expand_nat_case" thy
   456   "P(nat_case z s n) = ((n=0 --> P z) & (!m. n = Suc m --> P(s m)))"
   457   (fn _ => [nat_ind_tac "n" 1, ALLGOALS Asm_simp_tac]);
   458 
   459 val prems = goalw thy [le_def] "~n<m ==> m<=(n::nat)";
   460 by (resolve_tac prems 1);
   461 qed "leI";
   462 
   463 val prems = goalw thy [le_def] "m<=n ==> ~ n < (m::nat)";
   464 by (resolve_tac prems 1);
   465 qed "leD";
   466 
   467 val leE = make_elim leD;
   468 
   469 goal thy "(~n<m) = (m<=(n::nat))";
   470 by (blast_tac (!claset addIs [leI] addEs [leE]) 1);
   471 qed "not_less_iff_le";
   472 
   473 goalw thy [le_def] "!!m. ~ m <= n ==> n<(m::nat)";
   474 by (Blast_tac 1);
   475 qed "not_leE";
   476 
   477 goalw thy [le_def] "!!m. m < n ==> Suc(m) <= n";
   478 by (simp_tac (!simpset addsimps [less_Suc_eq]) 1);
   479 by (blast_tac (!claset addSEs [less_irrefl,less_asym]) 1);
   480 qed "Suc_leI";  (*formerly called lessD*)
   481 
   482 goalw thy [le_def] "!!m. Suc(m) <= n ==> m <= n";
   483 by (asm_full_simp_tac (!simpset addsimps [less_Suc_eq]) 1);
   484 qed "Suc_leD";
   485 
   486 (* stronger version of Suc_leD *)
   487 goalw thy [le_def] 
   488         "!!m. Suc m <= n ==> m < n";
   489 by (asm_full_simp_tac (!simpset addsimps [less_Suc_eq]) 1);
   490 by (cut_facts_tac [less_linear] 1);
   491 by (Blast_tac 1);
   492 qed "Suc_le_lessD";
   493 
   494 goal thy "(Suc m <= n) = (m < n)";
   495 by (blast_tac (!claset addIs [Suc_leI, Suc_le_lessD]) 1);
   496 qed "Suc_le_eq";
   497 
   498 goalw thy [le_def] "!!m. m <= n ==> m <= Suc n";
   499 by (blast_tac (!claset addDs [Suc_lessD]) 1);
   500 qed "le_SucI";
   501 Addsimps[le_SucI];
   502 
   503 bind_thm ("le_Suc", not_Suc_n_less_n RS leI);
   504 
   505 goalw thy [le_def] "!!m. m < n ==> m <= (n::nat)";
   506 by (blast_tac (!claset addEs [less_asym]) 1);
   507 qed "less_imp_le";
   508 
   509 (** Equivalence of m<=n and  m<n | m=n **)
   510 
   511 goalw thy [le_def] "!!m. m <= n ==> m < n | m=(n::nat)";
   512 by (cut_facts_tac [less_linear] 1);
   513 by (blast_tac (!claset addEs [less_irrefl,less_asym]) 1);
   514 qed "le_imp_less_or_eq";
   515 
   516 goalw thy [le_def] "!!m. m<n | m=n ==> m <=(n::nat)";
   517 by (cut_facts_tac [less_linear] 1);
   518 by (blast_tac (!claset addSEs [less_irrefl] addEs [less_asym]) 1);
   519 qed "less_or_eq_imp_le";
   520 
   521 goal thy "(m <= (n::nat)) = (m < n | m=n)";
   522 by (REPEAT(ares_tac [iffI,less_or_eq_imp_le,le_imp_less_or_eq] 1));
   523 qed "le_eq_less_or_eq";
   524 
   525 goal thy "n <= (n::nat)";
   526 by (simp_tac (!simpset addsimps [le_eq_less_or_eq]) 1);
   527 qed "le_refl";
   528 
   529 val prems = goal thy "!!i. [| i <= j; j < k |] ==> i < (k::nat)";
   530 by (dtac le_imp_less_or_eq 1);
   531 by (blast_tac (!claset addIs [less_trans]) 1);
   532 qed "le_less_trans";
   533 
   534 goal thy "!!i. [| i < j; j <= k |] ==> i < (k::nat)";
   535 by (dtac le_imp_less_or_eq 1);
   536 by (blast_tac (!claset addIs [less_trans]) 1);
   537 qed "less_le_trans";
   538 
   539 goal thy "!!i. [| i <= j; j <= k |] ==> i <= (k::nat)";
   540 by (EVERY1[dtac le_imp_less_or_eq, 
   541            dtac le_imp_less_or_eq,
   542            rtac less_or_eq_imp_le, 
   543            blast_tac (!claset addIs [less_trans])]);
   544 qed "le_trans";
   545 
   546 goal thy "!!m. [| m <= n; n <= m |] ==> m = (n::nat)";
   547 by (EVERY1[dtac le_imp_less_or_eq, 
   548            dtac le_imp_less_or_eq,
   549            blast_tac (!claset addEs [less_irrefl,less_asym])]);
   550 qed "le_anti_sym";
   551 
   552 goal thy "(Suc(n) <= Suc(m)) = (n <= m)";
   553 by (simp_tac (!simpset addsimps [le_eq_less_or_eq]) 1);
   554 qed "Suc_le_mono";
   555 
   556 AddIffs [Suc_le_mono];
   557 
   558 (* Axiom 'order_le_less' of class 'order': *)
   559 goal thy "(m::nat) < n = (m <= n & m ~= n)";
   560 by (rtac iffI 1);
   561  by (rtac conjI 1);
   562   by (etac less_imp_le 1);
   563  by (etac (less_not_refl2 RS not_sym) 1);
   564 by (blast_tac (!claset addSDs [le_imp_less_or_eq]) 1);
   565 qed "nat_less_le";
   566 
   567 (** LEAST -- the least number operator **)
   568 
   569 goal thy "(! m::nat. P m --> n <= m) = (! m. m < n --> ~ P m)";
   570 by(blast_tac (!claset addIs [leI] addEs [leE]) 1);
   571 val lemma = result();
   572 
   573 (* This is an old def of Least for nat, which is derived for compatibility *)
   574 goalw thy [Least_def]
   575   "(LEAST n::nat. P n) == (@n. P(n) & (ALL m. m < n --> ~P(m)))";
   576 by(simp_tac (!simpset addsimps [lemma]) 1);
   577 br eq_reflection 1;
   578 br refl 1;
   579 qed "Least_nat_def";
   580 
   581 val [prem1,prem2] = goalw thy [Least_nat_def]
   582     "[| P(k::nat);  !!x. x<k ==> ~P(x) |] ==> (LEAST x.P(x)) = k";
   583 by (rtac select_equality 1);
   584 by (blast_tac (!claset addSIs [prem1,prem2]) 1);
   585 by (cut_facts_tac [less_linear] 1);
   586 by (blast_tac (!claset addSIs [prem1] addSDs [prem2]) 1);
   587 qed "Least_equality";
   588 
   589 val [prem] = goal thy "P(k::nat) ==> P(LEAST x.P(x))";
   590 by (rtac (prem RS rev_mp) 1);
   591 by (res_inst_tac [("n","k")] less_induct 1);
   592 by (rtac impI 1);
   593 by (rtac classical 1);
   594 by (res_inst_tac [("s","n")] (Least_equality RS ssubst) 1);
   595 by (assume_tac 1);
   596 by (assume_tac 2);
   597 by (Blast_tac 1);
   598 qed "LeastI";
   599 
   600 (*Proof is almost identical to the one above!*)
   601 val [prem] = goal thy "P(k::nat) ==> (LEAST x.P(x)) <= k";
   602 by (rtac (prem RS rev_mp) 1);
   603 by (res_inst_tac [("n","k")] less_induct 1);
   604 by (rtac impI 1);
   605 by (rtac classical 1);
   606 by (res_inst_tac [("s","n")] (Least_equality RS ssubst) 1);
   607 by (assume_tac 1);
   608 by (rtac le_refl 2);
   609 by (blast_tac (!claset addIs [less_imp_le,le_trans]) 1);
   610 qed "Least_le";
   611 
   612 val [prem] = goal thy "k < (LEAST x.P(x)) ==> ~P(k::nat)";
   613 by (rtac notI 1);
   614 by (etac (rewrite_rule [le_def] Least_le RS notE) 1);
   615 by (rtac prem 1);
   616 qed "not_less_Least";
   617 
   618 qed_goalw "Least_Suc" thy [Least_nat_def]
   619  "!!P. [| ? n. P(Suc n); ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   620  (fn _ => [
   621         rtac select_equality 1,
   622         fold_goals_tac [Least_nat_def],
   623         safe_tac (!claset addSEs [LeastI]),
   624         rename_tac "j" 1,
   625         res_inst_tac [("n","j")] natE 1,
   626         Blast_tac 1,
   627         blast_tac (!claset addDs [Suc_less_SucD, not_less_Least]) 1,
   628         rename_tac "k n" 1,
   629         res_inst_tac [("n","k")] natE 1,
   630         Blast_tac 1,
   631         hyp_subst_tac 1,
   632         rewtac Least_nat_def,
   633         rtac (select_equality RS arg_cong RS sym) 1,
   634         safe_tac (!claset),
   635         dtac Suc_mono 1,
   636         Blast_tac 1,
   637         cut_facts_tac [less_linear] 1,
   638         safe_tac (!claset),
   639         atac 2,
   640         Blast_tac 2,
   641         dtac Suc_mono 1,
   642         Blast_tac 1]);
   643 
   644 
   645 (*** Instantiation of transitivity prover ***)
   646 
   647 structure Less_Arith =
   648 struct
   649 val nat_leI = leI;
   650 val nat_leD = leD;
   651 val lessI = lessI;
   652 val zero_less_Suc = zero_less_Suc;
   653 val less_reflE = less_irrefl;
   654 val less_zeroE = less_zeroE;
   655 val less_incr = Suc_mono;
   656 val less_decr = Suc_less_SucD;
   657 val less_incr_rhs = Suc_mono RS Suc_lessD;
   658 val less_decr_lhs = Suc_lessD;
   659 val less_trans_Suc = less_trans_Suc;
   660 val leI = Suc_leI RS (Suc_le_mono RS iffD1);
   661 val not_lessI = leI RS leD
   662 val not_leI = prove_goal thy "!!m::nat. n < m ==> ~ m <= n"
   663   (fn _ => [etac swap2 1, etac leD 1]);
   664 val eqI = prove_goal thy "!!m. [| m < Suc n; n < Suc m |] ==> m=n"
   665   (fn _ => [etac less_SucE 1,
   666             blast_tac (!claset addSDs [Suc_less_SucD] addSEs [less_irrefl]
   667                               addDs [less_trans_Suc]) 1,
   668             assume_tac 1]);
   669 val leD = le_eq_less_Suc RS iffD1;
   670 val not_lessD = nat_leI RS leD;
   671 val not_leD = not_leE
   672 val eqD1 = prove_goal thy  "!!n. m = n ==> m < Suc n"
   673  (fn _ => [etac subst 1, rtac lessI 1]);
   674 val eqD2 = sym RS eqD1;
   675 
   676 fun is_zero(t) =  t = Const("0",Type("nat",[]));
   677 
   678 fun nnb T = T = Type("fun",[Type("nat",[]),
   679                             Type("fun",[Type("nat",[]),
   680                                         Type("bool",[])])])
   681 
   682 fun decomp_Suc(Const("Suc",_)$t) = let val (a,i) = decomp_Suc t in (a,i+1) end
   683   | decomp_Suc t = (t,0);
   684 
   685 fun decomp2(rel,T,lhs,rhs) =
   686   if not(nnb T) then None else
   687   let val (x,i) = decomp_Suc lhs
   688       val (y,j) = decomp_Suc rhs
   689   in case rel of
   690        "op <"  => Some(x,i,"<",y,j)
   691      | "op <=" => Some(x,i,"<=",y,j)
   692      | "op ="  => Some(x,i,"=",y,j)
   693      | _       => None
   694   end;
   695 
   696 fun negate(Some(x,i,rel,y,j)) = Some(x,i,"~"^rel,y,j)
   697   | negate None = None;
   698 
   699 fun decomp(_$(Const(rel,T)$lhs$rhs)) = decomp2(rel,T,lhs,rhs)
   700   | decomp(_$(Const("Not",_)$(Const(rel,T)$lhs$rhs))) =
   701       negate(decomp2(rel,T,lhs,rhs))
   702   | decomp _ = None
   703 
   704 end;
   705 
   706 structure Trans_Tac = Trans_Tac_Fun(Less_Arith);
   707 
   708 open Trans_Tac;
   709 
   710 (*** eliminates ~= in premises, which trans_tac cannot deal with ***)
   711 qed_goal "nat_neqE" thy
   712   "[| (m::nat) ~= n; m < n ==> P; n < m ==> P |] ==> P"
   713   (fn major::prems => [cut_facts_tac [less_linear] 1,
   714                        REPEAT(eresolve_tac ([disjE,major RS notE]@prems) 1)]);
   715 
   716 
   717 
   718 (* add function nat_add_primrec *) 
   719 val (_, nat_add_primrec, _) = Datatype.add_datatype
   720 ([], "nat", [("0", [], Mixfix ("0", [], max_pri)), ("Suc", [dtTyp ([],
   721 "nat")], NoSyn)]) (add_thyname "Arith" HOL.thy);
   722 (* pretend Arith is part of the basic theory to fool package *)
   723