src/Pure/tactic.ML
author wenzelm
Wed Nov 21 00:36:51 2001 +0100 (2001-11-21)
changeset 12262 11ff5f47df6e
parent 12212 657ad5edeab6
child 12320 6e70d870ddf0
permissions -rw-r--r--
use tracing function for trace output;
     1 (*  Title:      Pure/tactic.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Tactics.
     7 *)
     8 
     9 signature BASIC_TACTIC =
    10 sig
    11   val ares_tac          : thm list -> int -> tactic
    12   val asm_rewrite_goal_tac: bool*bool*bool ->
    13     (MetaSimplifier.meta_simpset -> tactic) -> MetaSimplifier.meta_simpset -> int -> tactic
    14   val assume_tac        : int -> tactic
    15   val atac      : int ->tactic
    16   val bimatch_from_nets_tac:
    17       (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net -> int -> tactic
    18   val bimatch_tac       : (bool*thm)list -> int -> tactic
    19   val biresolution_from_nets_tac:
    20         ('a list -> (bool * thm) list) ->
    21         bool -> 'a Net.net * 'a Net.net -> int -> tactic
    22   val biresolve_from_nets_tac:
    23       (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net -> int -> tactic
    24   val biresolve_tac     : (bool*thm)list -> int -> tactic
    25   val build_net : thm list -> (int*thm) Net.net
    26   val build_netpair:    (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net ->
    27       (bool*thm)list -> (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net
    28   val compose_inst_tac  : (string*string)list -> (bool*thm*int) ->
    29                           int -> tactic
    30   val compose_tac       : (bool * thm * int) -> int -> tactic
    31   val cut_facts_tac     : thm list -> int -> tactic
    32   val cut_inst_tac      : (string*string)list -> thm -> int -> tactic
    33   val datac             : thm -> int -> int -> tactic
    34   val defer_tac         : int -> tactic
    35   val distinct_subgoals_tac     : tactic
    36   val dmatch_tac        : thm list -> int -> tactic
    37   val dresolve_tac      : thm list -> int -> tactic
    38   val dres_inst_tac     : (string*string)list -> thm -> int -> tactic
    39   val dtac              : thm -> int ->tactic
    40   val eatac             : thm -> int -> int -> tactic
    41   val etac              : thm -> int ->tactic
    42   val eq_assume_tac     : int -> tactic
    43   val ematch_tac        : thm list -> int -> tactic
    44   val eresolve_tac      : thm list -> int -> tactic
    45   val eres_inst_tac     : (string*string)list -> thm -> int -> tactic
    46   val fatac             : thm -> int -> int -> tactic
    47   val filter_prems_tac  : (term -> bool) -> int -> tactic
    48   val filter_thms       : (term*term->bool) -> int*term*thm list -> thm list
    49   val filt_resolve_tac  : thm list -> int -> int -> tactic
    50   val flexflex_tac      : tactic
    51   val fold_goals_tac    : thm list -> tactic
    52   val fold_rule         : thm list -> thm -> thm
    53   val fold_tac          : thm list -> tactic
    54   val forward_tac       : thm list -> int -> tactic
    55   val forw_inst_tac     : (string*string)list -> thm -> int -> tactic
    56   val ftac              : thm -> int ->tactic
    57   val insert_tagged_brl : ('a*(bool*thm)) *
    58                           (('a*(bool*thm))Net.net * ('a*(bool*thm))Net.net) ->
    59                           ('a*(bool*thm))Net.net * ('a*(bool*thm))Net.net
    60   val delete_tagged_brl : (bool*thm) *
    61                          ((int*(bool*thm))Net.net * (int*(bool*thm))Net.net) ->
    62                     (int*(bool*thm))Net.net * (int*(bool*thm))Net.net
    63   val is_fact           : thm -> bool
    64   val lessb             : (bool * thm) * (bool * thm) -> bool
    65   val lift_inst_rule    : thm * int * (string*string)list * thm -> thm
    66   val make_elim         : thm -> thm
    67   val match_from_net_tac        : (int*thm) Net.net -> int -> tactic
    68   val match_tac : thm list -> int -> tactic
    69   val metacut_tac       : thm -> int -> tactic
    70   val net_bimatch_tac   : (bool*thm) list -> int -> tactic
    71   val net_biresolve_tac : (bool*thm) list -> int -> tactic
    72   val net_match_tac     : thm list -> int -> tactic
    73   val net_resolve_tac   : thm list -> int -> tactic
    74   val norm_hhf          : thm -> thm
    75   val norm_hhf_tac      : int -> tactic
    76   val PRIMITIVE         : (thm -> thm) -> tactic
    77   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    78   val prune_params_tac  : tactic
    79   val rename_params_tac : string list -> int -> tactic
    80   val rename_tac        : string -> int -> tactic
    81   val rename_last_tac   : string -> string list -> int -> tactic
    82   val resolve_from_net_tac      : (int*thm) Net.net -> int -> tactic
    83   val resolve_tac       : thm list -> int -> tactic
    84   val res_inst_tac      : (string*string)list -> thm -> int -> tactic
    85   val rewrite_goal_tac  : thm list -> int -> tactic
    86   val rewrite_goals_rule: thm list -> thm -> thm
    87   val rewrite_rule      : thm list -> thm -> thm
    88   val rewrite_goals_tac : thm list -> tactic
    89   val rewrite_tac       : thm list -> tactic
    90   val rewtac            : thm -> tactic
    91   val rotate_tac        : int -> int -> tactic
    92   val rtac              : thm -> int -> tactic
    93   val rule_by_tactic    : tactic -> thm -> thm
    94   val solve_tac         : thm list -> int -> tactic
    95   val subgoal_tac       : string -> int -> tactic
    96   val subgoals_tac      : string list -> int -> tactic
    97   val subgoals_of_brl   : bool * thm -> int
    98   val term_lift_inst_rule       :
    99       thm * int * (indexname*typ)list * ((indexname*typ)*term)list  * thm
   100       -> thm
   101   val instantiate_tac   : (string * string) list -> tactic
   102   val thin_tac          : string -> int -> tactic
   103   val trace_goalno_tac  : (int -> tactic) -> int -> tactic
   104 end;
   105 
   106 signature TACTIC =
   107 sig
   108   include BASIC_TACTIC
   109   val innermost_params: int -> thm -> (string * typ) list
   110   val untaglist: (int * 'a) list -> 'a list
   111   val orderlist: (int * 'a) list -> 'a list
   112   val rewrite: bool -> thm list -> cterm -> thm
   113   val rewrite_cterm: bool -> thm list -> cterm -> cterm
   114   val simplify: bool -> thm list -> thm -> thm
   115   val conjunction_tac: tactic
   116   val prove: Sign.sg -> string list -> term list -> term -> (thm list -> tactic) -> thm
   117   val prove_standard: Sign.sg -> string list -> term list -> term -> (thm list -> tactic) -> thm
   118 end;
   119 
   120 structure Tactic: TACTIC =
   121 struct
   122 
   123 (*Discover which goal is chosen:  SOMEGOAL(trace_goalno_tac tac) *)
   124 fun trace_goalno_tac tac i st =
   125     case Seq.pull(tac i st) of
   126         None    => Seq.empty
   127       | seqcell => (tracing ("Subgoal " ^ string_of_int i ^ " selected");
   128                          Seq.make(fn()=> seqcell));
   129 
   130 (*Makes a rule by applying a tactic to an existing rule*)
   131 fun rule_by_tactic tac rl =
   132   let val (st, thaw) = freeze_thaw (zero_var_indexes rl)
   133   in case Seq.pull (tac st)  of
   134         None        => raise THM("rule_by_tactic", 0, [rl])
   135       | Some(st',_) => Thm.varifyT (thaw st')
   136   end;
   137 
   138 (*** Basic tactics ***)
   139 
   140 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   141 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   142 
   143 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   144 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   145 
   146 (*** The following fail if the goal number is out of range:
   147      thus (REPEAT (resolve_tac rules i)) stops once subgoal i disappears. *)
   148 
   149 (*Solve subgoal i by assumption*)
   150 fun assume_tac i = PRIMSEQ (assumption i);
   151 
   152 (*Solve subgoal i by assumption, using no unification*)
   153 fun eq_assume_tac i = PRIMITIVE (eq_assumption i);
   154 
   155 (** Resolution/matching tactics **)
   156 
   157 (*The composition rule/state: no lifting or var renaming.
   158   The arg = (bires_flg, orule, m) ;  see bicompose for explanation.*)
   159 fun compose_tac arg i = PRIMSEQ (bicompose false arg i);
   160 
   161 (*Converts a "destruct" rule like P&Q==>P to an "elimination" rule
   162   like [| P&Q; P==>R |] ==> R *)
   163 fun make_elim rl = zero_var_indexes (rl RS revcut_rl);
   164 
   165 (*Attack subgoal i by resolution, using flags to indicate elimination rules*)
   166 fun biresolve_tac brules i = PRIMSEQ (biresolution false brules i);
   167 
   168 (*Resolution: the simple case, works for introduction rules*)
   169 fun resolve_tac rules = biresolve_tac (map (pair false) rules);
   170 
   171 (*Resolution with elimination rules only*)
   172 fun eresolve_tac rules = biresolve_tac (map (pair true) rules);
   173 
   174 (*Forward reasoning using destruction rules.*)
   175 fun forward_tac rls = resolve_tac (map make_elim rls) THEN' assume_tac;
   176 
   177 (*Like forward_tac, but deletes the assumption after use.*)
   178 fun dresolve_tac rls = eresolve_tac (map make_elim rls);
   179 
   180 (*Shorthand versions: for resolution with a single theorem*)
   181 val atac    =   assume_tac;
   182 fun rtac rl =  resolve_tac [rl];
   183 fun dtac rl = dresolve_tac [rl];
   184 fun etac rl = eresolve_tac [rl];
   185 fun ftac rl =  forward_tac [rl];
   186 fun datac thm j = EVERY' (dtac thm::replicate j atac);
   187 fun eatac thm j = EVERY' (etac thm::replicate j atac);
   188 fun fatac thm j = EVERY' (ftac thm::replicate j atac);
   189 
   190 (*Use an assumption or some rules ... A popular combination!*)
   191 fun ares_tac rules = assume_tac  ORELSE'  resolve_tac rules;
   192 
   193 fun solve_tac rules = resolve_tac rules THEN_ALL_NEW assume_tac;
   194 
   195 (*Matching tactics -- as above, but forbid updating of state*)
   196 fun bimatch_tac brules i = PRIMSEQ (biresolution true brules i);
   197 fun match_tac rules  = bimatch_tac (map (pair false) rules);
   198 fun ematch_tac rules = bimatch_tac (map (pair true) rules);
   199 fun dmatch_tac rls   = ematch_tac (map make_elim rls);
   200 
   201 (*Smash all flex-flex disagreement pairs in the proof state.*)
   202 val flexflex_tac = PRIMSEQ flexflex_rule;
   203 
   204 
   205 (*Remove duplicate subgoals.  By Mark Staples*)
   206 local
   207 fun cterm_aconv (a,b) = #t (rep_cterm a) aconv #t (rep_cterm b);
   208 in
   209 fun distinct_subgoals_tac state =
   210     let val (frozth,thawfn) = freeze_thaw state
   211         val froz_prems = cprems_of frozth
   212         val assumed = implies_elim_list frozth (map assume froz_prems)
   213         val implied = implies_intr_list (gen_distinct cterm_aconv froz_prems)
   214                                         assumed;
   215     in  Seq.single (thawfn implied)  end
   216 end;
   217 
   218 
   219 (*Determine print names of goal parameters (reversed)*)
   220 fun innermost_params i st =
   221   let val (_, _, Bi, _) = dest_state (st, i)
   222   in rename_wrt_term Bi (Logic.strip_params Bi) end;
   223 
   224 (*Lift and instantiate a rule wrt the given state and subgoal number *)
   225 fun lift_inst_rule (st, i, sinsts, rule) =
   226 let val {maxidx,sign,...} = rep_thm st
   227     val (_, _, Bi, _) = dest_state(st,i)
   228     val params = Logic.strip_params Bi          (*params of subgoal i*)
   229     val params = rev(rename_wrt_term Bi params) (*as they are printed*)
   230     val paramTs = map #2 params
   231     and inc = maxidx+1
   232     fun liftvar (Var ((a,j), T)) = Var((a, j+inc), paramTs---> incr_tvar inc T)
   233       | liftvar t = raise TERM("Variable expected", [t]);
   234     fun liftterm t = list_abs_free (params,
   235                                     Logic.incr_indexes(paramTs,inc) t)
   236     (*Lifts instantiation pair over params*)
   237     fun liftpair (cv,ct) = (cterm_fun liftvar cv, cterm_fun liftterm ct)
   238     fun lifttvar((a,i),ctyp) =
   239         let val {T,sign} = rep_ctyp ctyp
   240         in  ((a,i+inc), ctyp_of sign (incr_tvar inc T)) end
   241     val rts = types_sorts rule and (types,sorts) = types_sorts st
   242     fun types'(a,~1) = (case assoc(params,a) of None => types(a,~1) | sm => sm)
   243       | types'(ixn) = types ixn;
   244     val used = add_term_tvarnames
   245                   (#prop(rep_thm st) $ #prop(rep_thm rule),[])
   246     val (Tinsts,insts) = read_insts sign rts (types',sorts) used sinsts
   247 in Drule.instantiate (map lifttvar Tinsts, map liftpair insts)
   248                      (lift_rule (st,i) rule)
   249 end;
   250 
   251 (*
   252 Like lift_inst_rule but takes terms, not strings, where the terms may contain
   253 Bounds referring to parameters of the subgoal.
   254 
   255 insts: [...,(vj,tj),...]
   256 
   257 The tj may contain references to parameters of subgoal i of the state st
   258 in the form of Bound k, i.e. the tj may be subterms of the subgoal.
   259 To saturate the lose bound vars, the tj are enclosed in abstractions
   260 corresponding to the parameters of subgoal i, thus turning them into
   261 functions. At the same time, the types of the vj are lifted.
   262 
   263 NB: the types in insts must be correctly instantiated already,
   264     i.e. Tinsts is not applied to insts.
   265 *)
   266 fun term_lift_inst_rule (st, i, Tinsts, insts, rule) =
   267 let val {maxidx,sign,...} = rep_thm st
   268     val (_, _, Bi, _) = dest_state(st,i)
   269     val params = Logic.strip_params Bi          (*params of subgoal i*)
   270     val paramTs = map #2 params
   271     and inc = maxidx+1
   272     fun liftvar ((a,j), T) = Var((a, j+inc), paramTs---> incr_tvar inc T)
   273     (*lift only Var, not term, which must be lifted already*)
   274     fun liftpair (v,t) = (cterm_of sign (liftvar v), cterm_of sign t)
   275     fun liftTpair((a,i),T) = ((a,i+inc), ctyp_of sign (incr_tvar inc T))
   276 in Drule.instantiate (map liftTpair Tinsts, map liftpair insts)
   277                      (lift_rule (st,i) rule)
   278 end;
   279 
   280 (*** Resolve after lifting and instantation; may refer to parameters of the
   281      subgoal.  Fails if "i" is out of range.  ***)
   282 
   283 (*compose version: arguments are as for bicompose.*)
   284 fun compose_inst_tac sinsts (bires_flg, rule, nsubgoal) i st =
   285   if i > nprems_of st then no_tac st
   286   else st |>
   287     (compose_tac (bires_flg, lift_inst_rule (st, i, sinsts, rule), nsubgoal) i
   288      handle TERM (msg,_)   => (warning msg;  no_tac)
   289           | THM  (msg,_,_) => (warning msg;  no_tac));
   290 
   291 (*"Resolve" version.  Note: res_inst_tac cannot behave sensibly if the
   292   terms that are substituted contain (term or type) unknowns from the
   293   goal, because it is unable to instantiate goal unknowns at the same time.
   294 
   295   The type checker is instructed not to freeze flexible type vars that
   296   were introduced during type inference and still remain in the term at the
   297   end.  This increases flexibility but can introduce schematic type vars in
   298   goals.
   299 *)
   300 fun res_inst_tac sinsts rule i =
   301     compose_inst_tac sinsts (false, rule, nprems_of rule) i;
   302 
   303 (*eresolve elimination version*)
   304 fun eres_inst_tac sinsts rule i =
   305     compose_inst_tac sinsts (true, rule, nprems_of rule) i;
   306 
   307 (*For forw_inst_tac and dres_inst_tac.  Preserve Var indexes of rl;
   308   increment revcut_rl instead.*)
   309 fun make_elim_preserve rl =
   310   let val {maxidx,...} = rep_thm rl
   311       fun cvar ixn = cterm_of (Theory.sign_of ProtoPure.thy) (Var(ixn,propT));
   312       val revcut_rl' =
   313           instantiate ([],  [(cvar("V",0), cvar("V",maxidx+1)),
   314                              (cvar("W",0), cvar("W",maxidx+1))]) revcut_rl
   315       val arg = (false, rl, nprems_of rl)
   316       val [th] = Seq.list_of (bicompose false arg 1 revcut_rl')
   317   in  th  end
   318   handle Bind => raise THM("make_elim_preserve", 1, [rl]);
   319 
   320 (*instantiate and cut -- for a FACT, anyway...*)
   321 fun cut_inst_tac sinsts rule = res_inst_tac sinsts (make_elim_preserve rule);
   322 
   323 (*forward tactic applies a RULE to an assumption without deleting it*)
   324 fun forw_inst_tac sinsts rule = cut_inst_tac sinsts rule THEN' assume_tac;
   325 
   326 (*dresolve tactic applies a RULE to replace an assumption*)
   327 fun dres_inst_tac sinsts rule = eres_inst_tac sinsts (make_elim_preserve rule);
   328 
   329 (*instantiate variables in the whole state*)
   330 val instantiate_tac = PRIMITIVE o read_instantiate;
   331 
   332 (*Deletion of an assumption*)
   333 fun thin_tac s = eres_inst_tac [("V",s)] thin_rl;
   334 
   335 (*** Applications of cut_rl ***)
   336 
   337 (*Used by metacut_tac*)
   338 fun bires_cut_tac arg i =
   339     resolve_tac [cut_rl] i  THEN  biresolve_tac arg (i+1) ;
   340 
   341 (*The conclusion of the rule gets assumed in subgoal i,
   342   while subgoal i+1,... are the premises of the rule.*)
   343 fun metacut_tac rule = bires_cut_tac [(false,rule)];
   344 
   345 (*Recognizes theorems that are not rules, but simple propositions*)
   346 fun is_fact rl =
   347     case prems_of rl of
   348         [] => true  |  _::_ => false;
   349 
   350 (*"Cut" all facts from theorem list into the goal as assumptions. *)
   351 fun cut_facts_tac ths i =
   352     EVERY (map (fn th => metacut_tac th i) (filter is_fact ths));
   353 
   354 (*Introduce the given proposition as a lemma and subgoal*)
   355 fun subgoal_tac sprop i st =
   356   let val st'    = Seq.hd (res_inst_tac [("psi", sprop)] cut_rl i st)
   357       val concl' = Logic.strip_assums_concl (List.nth(prems_of st', i))
   358   in
   359       if null (term_tvars concl') then ()
   360       else warning"Type variables in new subgoal: add a type constraint?";
   361       Seq.single st'
   362   end;
   363 
   364 (*Introduce a list of lemmas and subgoals*)
   365 fun subgoals_tac sprops = EVERY' (map subgoal_tac sprops);
   366 
   367 
   368 (**** Indexing and filtering of theorems ****)
   369 
   370 (*Returns the list of potentially resolvable theorems for the goal "prem",
   371         using the predicate  could(subgoal,concl).
   372   Resulting list is no longer than "limit"*)
   373 fun filter_thms could (limit, prem, ths) =
   374   let val pb = Logic.strip_assums_concl prem;   (*delete assumptions*)
   375       fun filtr (limit, []) = []
   376         | filtr (limit, th::ths) =
   377             if limit=0 then  []
   378             else if could(pb, concl_of th)  then th :: filtr(limit-1, ths)
   379             else filtr(limit,ths)
   380   in  filtr(limit,ths)  end;
   381 
   382 
   383 (*** biresolution and resolution using nets ***)
   384 
   385 (** To preserve the order of the rules, tag them with increasing integers **)
   386 
   387 (*insert tags*)
   388 fun taglist k [] = []
   389   | taglist k (x::xs) = (k,x) :: taglist (k+1) xs;
   390 
   391 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   392 fun untaglist [] = []
   393   | untaglist [(k:int,x)] = [x]
   394   | untaglist ((k,x) :: (rest as (k',x')::_)) =
   395       if k=k' then untaglist rest
   396       else    x :: untaglist rest;
   397 
   398 (*return list elements in original order*)
   399 fun orderlist kbrls = untaglist (sort (int_ord o pairself fst) kbrls);
   400 
   401 (*insert one tagged brl into the pair of nets*)
   402 fun insert_tagged_brl (kbrl as (k,(eres,th)), (inet,enet)) =
   403     if eres then
   404         case prems_of th of
   405             prem::_ => (inet, Net.insert_term ((prem,kbrl), enet, K false))
   406           | [] => error"insert_tagged_brl: elimination rule with no premises"
   407     else (Net.insert_term ((concl_of th, kbrl), inet, K false), enet);
   408 
   409 (*build a pair of nets for biresolution*)
   410 fun build_netpair netpair brls =
   411     foldr insert_tagged_brl (taglist 1 brls, netpair);
   412 
   413 (*delete one kbrl from the pair of nets;
   414   we don't know the value of k, so we use 0 and ignore it in the comparison*)
   415 local
   416   fun eq_kbrl ((k,(eres,th)), (k',(eres',th'))) = eq_thm (th,th')
   417 in
   418 fun delete_tagged_brl (brl as (eres,th), (inet,enet)) =
   419     if eres then
   420         case prems_of th of
   421             prem::_ => (inet, Net.delete_term ((prem, (0,brl)), enet, eq_kbrl))
   422           | []      => (inet,enet)     (*no major premise: ignore*)
   423     else (Net.delete_term ((concl_of th, (0,brl)), inet, eq_kbrl), enet);
   424 end;
   425 
   426 
   427 (*biresolution using a pair of nets rather than rules.
   428     function "order" must sort and possibly filter the list of brls.
   429     boolean "match" indicates matching or unification.*)
   430 fun biresolution_from_nets_tac order match (inet,enet) =
   431   SUBGOAL
   432     (fn (prem,i) =>
   433       let val hyps = Logic.strip_assums_hyp prem
   434           and concl = Logic.strip_assums_concl prem
   435           val kbrls = Net.unify_term inet concl @
   436                       List.concat (map (Net.unify_term enet) hyps)
   437       in PRIMSEQ (biresolution match (order kbrls) i) end);
   438 
   439 (*versions taking pre-built nets.  No filtering of brls*)
   440 val biresolve_from_nets_tac = biresolution_from_nets_tac orderlist false;
   441 val bimatch_from_nets_tac   = biresolution_from_nets_tac orderlist true;
   442 
   443 (*fast versions using nets internally*)
   444 val net_biresolve_tac =
   445     biresolve_from_nets_tac o build_netpair(Net.empty,Net.empty);
   446 
   447 val net_bimatch_tac =
   448     bimatch_from_nets_tac o build_netpair(Net.empty,Net.empty);
   449 
   450 (*** Simpler version for resolve_tac -- only one net, and no hyps ***)
   451 
   452 (*insert one tagged rl into the net*)
   453 fun insert_krl (krl as (k,th), net) =
   454     Net.insert_term ((concl_of th, krl), net, K false);
   455 
   456 (*build a net of rules for resolution*)
   457 fun build_net rls =
   458     foldr insert_krl (taglist 1 rls, Net.empty);
   459 
   460 (*resolution using a net rather than rules; pred supports filt_resolve_tac*)
   461 fun filt_resolution_from_net_tac match pred net =
   462   SUBGOAL
   463     (fn (prem,i) =>
   464       let val krls = Net.unify_term net (Logic.strip_assums_concl prem)
   465       in
   466          if pred krls
   467          then PRIMSEQ
   468                 (biresolution match (map (pair false) (orderlist krls)) i)
   469          else no_tac
   470       end);
   471 
   472 (*Resolve the subgoal using the rules (making a net) unless too flexible,
   473    which means more than maxr rules are unifiable.      *)
   474 fun filt_resolve_tac rules maxr =
   475     let fun pred krls = length krls <= maxr
   476     in  filt_resolution_from_net_tac false pred (build_net rules)  end;
   477 
   478 (*versions taking pre-built nets*)
   479 val resolve_from_net_tac = filt_resolution_from_net_tac false (K true);
   480 val match_from_net_tac = filt_resolution_from_net_tac true (K true);
   481 
   482 (*fast versions using nets internally*)
   483 val net_resolve_tac = resolve_from_net_tac o build_net;
   484 val net_match_tac = match_from_net_tac o build_net;
   485 
   486 
   487 (*** For Natural Deduction using (bires_flg, rule) pairs ***)
   488 
   489 (*The number of new subgoals produced by the brule*)
   490 fun subgoals_of_brl (true,rule)  = nprems_of rule - 1
   491   | subgoals_of_brl (false,rule) = nprems_of rule;
   492 
   493 (*Less-than test: for sorting to minimize number of new subgoals*)
   494 fun lessb (brl1,brl2) = subgoals_of_brl brl1 < subgoals_of_brl brl2;
   495 
   496 
   497 (*** Meta-Rewriting Tactics ***)
   498 
   499 fun result1 tacf mss thm =
   500   apsome fst (Seq.pull (tacf mss thm));
   501 
   502 val simple_prover =
   503   result1 (fn mss => ALLGOALS (resolve_tac (MetaSimplifier.prems_of_mss mss)));
   504 
   505 val rewrite = MetaSimplifier.rewrite_aux simple_prover;
   506 val rewrite_cterm = (#2 o Thm.dest_comb o #prop o Thm.crep_thm) ooo rewrite;
   507 val simplify = MetaSimplifier.simplify_aux simple_prover;
   508 val rewrite_rule = simplify true;
   509 val rewrite_goals_rule = MetaSimplifier.rewrite_goals_rule_aux simple_prover;
   510 
   511 (*Rewrite subgoal i only.  SELECT_GOAL avoids inefficiencies in goals_conv.*)
   512 fun asm_rewrite_goal_tac mode prover_tac mss =
   513   SELECT_GOAL
   514     (PRIMITIVE (MetaSimplifier.rewrite_goal_rule mode (result1 prover_tac) mss 1));
   515 
   516 fun rewrite_goal_tac rews =
   517   asm_rewrite_goal_tac (true, false, false) (K no_tac) (MetaSimplifier.mss_of rews);
   518 
   519 (*Rewrite throughout proof state. *)
   520 fun rewrite_tac defs = PRIMITIVE(rewrite_rule defs);
   521 
   522 (*Rewrite subgoals only, not main goal. *)
   523 fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
   524 fun rewtac def = rewrite_goals_tac [def];
   525 
   526 fun norm_hhf th =
   527   (if Logic.is_norm_hhf (#prop (Thm.rep_thm th)) then th else rewrite_rule [Drule.norm_hhf_eq] th)
   528   |> Drule.forall_elim_vars_safe;
   529 
   530 val norm_hhf_tac = SUBGOAL (fn (t, i) =>
   531   if Logic.is_norm_hhf t then all_tac
   532   else rewrite_goal_tac [Drule.norm_hhf_eq] i);
   533 
   534 
   535 (*** for folding definitions, handling critical pairs ***)
   536 
   537 (*The depth of nesting in a term*)
   538 fun term_depth (Abs(a,T,t)) = 1 + term_depth t
   539   | term_depth (f$t) = 1 + Int.max(term_depth f, term_depth t)
   540   | term_depth _ = 0;
   541 
   542 val lhs_of_thm = #1 o Logic.dest_equals o #prop o rep_thm;
   543 
   544 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
   545   Returns longest lhs first to avoid folding its subexpressions.*)
   546 fun sort_lhs_depths defs =
   547   let val keylist = make_keylist (term_depth o lhs_of_thm) defs
   548       val keys = distinct (sort (rev_order o int_ord) (map #2 keylist))
   549   in  map (keyfilter keylist) keys  end;
   550 
   551 val rev_defs = sort_lhs_depths o map symmetric;
   552 
   553 fun fold_rule defs thm = foldl (fn (th, ds) => rewrite_rule ds th) (thm, rev_defs defs);
   554 fun fold_tac defs = EVERY (map rewrite_tac (rev_defs defs));
   555 fun fold_goals_tac defs = EVERY (map rewrite_goals_tac (rev_defs defs));
   556 
   557 
   558 (*** Renaming of parameters in a subgoal
   559      Names may contain letters, digits or primes and must be
   560      separated by blanks ***)
   561 
   562 (*Calling this will generate the warning "Same as previous level" since
   563   it affects nothing but the names of bound variables!*)
   564 fun rename_params_tac xs i =
   565   (if !Logic.auto_rename
   566     then (warning "Resetting Logic.auto_rename";
   567         Logic.auto_rename := false)
   568    else (); PRIMITIVE (rename_params_rule (xs, i)));
   569 
   570 fun rename_tac str i =
   571   let val cs = Symbol.explode str in
   572   case #2 (take_prefix (Symbol.is_letdig orf Symbol.is_blank) cs) of
   573       [] => rename_params_tac (scanwords Symbol.is_letdig cs) i
   574     | c::_ => error ("Illegal character: " ^ c)
   575   end;
   576 
   577 (*Rename recent parameters using names generated from a and the suffixes,
   578   provided the string a, which represents a term, is an identifier. *)
   579 fun rename_last_tac a sufs i =
   580   let val names = map (curry op^ a) sufs
   581   in  if Syntax.is_identifier a
   582       then PRIMITIVE (rename_params_rule (names,i))
   583       else all_tac
   584   end;
   585 
   586 (*Prunes all redundant parameters from the proof state by rewriting.
   587   DOES NOT rewrite main goal, where quantification over an unused bound
   588     variable is sometimes done to avoid the need for cut_facts_tac.*)
   589 val prune_params_tac = rewrite_goals_tac [triv_forall_equality];
   590 
   591 (*rotate_tac n i: rotate the assumptions of subgoal i by n positions, from
   592   right to left if n is positive, and from left to right if n is negative.*)
   593 fun rotate_tac 0 i = all_tac
   594   | rotate_tac k i = PRIMITIVE (rotate_rule k i);
   595 
   596 (*Rotates the given subgoal to be the last.*)
   597 fun defer_tac i = PRIMITIVE (permute_prems (i-1) 1);
   598 
   599 (* remove premises that do not satisfy p; fails if all prems satisfy p *)
   600 fun filter_prems_tac p =
   601   let fun Then None tac = Some tac
   602         | Then (Some tac) tac' = Some(tac THEN' tac');
   603       fun thins ((tac,n),H) =
   604         if p H then (tac,n+1)
   605         else (Then tac (rotate_tac n THEN' etac thin_rl),0);
   606   in SUBGOAL(fn (subg,n) =>
   607        let val Hs = Logic.strip_assums_hyp subg
   608        in case fst(foldl thins ((None,0),Hs)) of
   609             None => no_tac | Some tac => tac n
   610        end)
   611   end;
   612 
   613 
   614 (*meta-level conjunction*)
   615 val conj_tac = SUBGOAL (fn (Const ("all", _) $ Abs (_, _, Const ("==>", _) $
   616       (Const ("==>", _) $ _ $ (Const ("==>", _) $ _ $ Bound 0)) $ Bound 0), i) =>
   617     (fn st =>
   618       compose_tac (false, Drule.incr_indexes_wrt [] [] [] [st] Drule.conj_intr_thm, 2) i st)
   619   | _ => no_tac);
   620   
   621 val conjunction_tac = ALLGOALS (REPEAT_ALL_NEW conj_tac);
   622 
   623 
   624 
   625 (** minimal goal interface for internal use *)
   626 
   627 fun prove sign xs asms prop tac =
   628   let
   629     val statement = Logic.list_implies (asms, prop);
   630     val frees = map Term.dest_Free (Term.term_frees statement);
   631     val fixed_frees = filter_out (fn (x, _) => x mem_string xs) frees;
   632     val fixed_tfrees = foldr Term.add_typ_tfree_names (map #2 fixed_frees, []);
   633     val params = mapfilter (fn x => apsome (pair x) (assoc_string (frees, x))) xs;
   634 
   635     fun err msg = raise ERROR_MESSAGE
   636       (msg ^ "\nThe error(s) above occurred for the goal statement:\n" ^
   637         Sign.string_of_term sign (Term.list_all_free (params, statement)));
   638 
   639     fun cert_safe t = Thm.cterm_of sign (Envir.beta_norm t)
   640       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   641 
   642     val _ = cert_safe statement;
   643     val _ = Term.no_dummy_patterns statement handle TERM (msg, _) => err msg;
   644 
   645     val cparams = map (cert_safe o Free) params;
   646     val casms = map cert_safe asms;
   647     val prems = map (norm_hhf o Thm.assume) casms;
   648     val goal = Drule.mk_triv_goal (cert_safe prop);
   649 
   650     val goal' =
   651       (case Seq.pull (tac prems goal) of Some (goal', _) => goal' | _ => err "Tactic failed.");
   652     val ngoals = Thm.nprems_of goal';
   653     val raw_result = goal' RS Drule.rev_triv_goal;
   654     val prop' = #prop (Thm.rep_thm raw_result);
   655   in
   656     if ngoals <> 0 then
   657       err ("Proof failed.\n" ^ Pretty.string_of (Pretty.chunks (Display.pretty_goals ngoals goal'))
   658         ^ ("\n" ^ string_of_int ngoals ^ " unsolved goal(s)!"))
   659     else if not (Pattern.matches (Sign.tsig_of sign) (prop, prop')) then
   660       err ("Proved a different theorem: " ^ Sign.string_of_term sign prop')
   661     else
   662       raw_result
   663       |> Drule.implies_intr_list casms
   664       |> Drule.forall_intr_list cparams
   665       |> norm_hhf
   666       |> Thm.varifyT' fixed_tfrees
   667       |> Drule.zero_var_indexes
   668   end;
   669 
   670 fun prove_standard sign xs asms prop tac = Drule.standard (prove sign xs asms prop tac);
   671 
   672 end;
   673 
   674 structure BasicTactic: BASIC_TACTIC = Tactic;
   675 open BasicTactic;