src/HOL/Nat.thy
author haftmann
Thu Aug 18 13:55:26 2011 +0200 (2011-08-18)
changeset 44278 1220ecb81e8f
parent 43595 7ae4a23b5be6
child 44325 84696670feb1
permissions -rw-r--r--
observe distinction between sets and predicates more properly
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 subsection {* Type nat *}
    34 
    35 text {* Type definition *}
    36 
    37 inductive Nat :: "ind \<Rightarrow> bool"
    38 where
    39     Zero_RepI: "Nat Zero_Rep"
    40   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    41 
    42 typedef (open Nat) nat = "{n. Nat n}"
    43   using Nat.Zero_RepI by auto
    44 
    45 lemma Nat_Rep_Nat:
    46   "Nat (Rep_Nat n)"
    47   using Rep_Nat by simp
    48 
    49 lemma Nat_Abs_Nat_inverse:
    50   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    51   using Abs_Nat_inverse by simp
    52 
    53 lemma Nat_Abs_Nat_inject:
    54   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    55   using Abs_Nat_inject by simp
    56 
    57 instantiation nat :: zero
    58 begin
    59 
    60 definition Zero_nat_def:
    61   "0 = Abs_Nat Zero_Rep"
    62 
    63 instance ..
    64 
    65 end
    66 
    67 definition Suc :: "nat \<Rightarrow> nat" where
    68   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    69 
    70 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    71   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    72 
    73 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    74   by (rule not_sym, rule Suc_not_Zero not_sym)
    75 
    76 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    77   by (rule iffI, rule Suc_Rep_inject) simp_all
    78 
    79 rep_datatype "0 \<Colon> nat" Suc
    80   apply (unfold Zero_nat_def Suc_def)
    81   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    82    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    83    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    84     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    85       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    86       Suc_Rep_not_Zero_Rep [symmetric]
    87       Suc_Rep_inject' Rep_Nat_inject)
    88   done
    89 
    90 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    91   -- {* for backward compatibility -- names of variables differ *}
    92   fixes n
    93   assumes "P 0"
    94     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    95   shows "P n"
    96   using assms by (rule nat.induct)
    97 
    98 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    99 
   100 lemmas nat_rec_0 = nat.recs(1)
   101   and nat_rec_Suc = nat.recs(2)
   102 
   103 lemmas nat_case_0 = nat.cases(1)
   104   and nat_case_Suc = nat.cases(2)
   105    
   106 
   107 text {* Injectiveness and distinctness lemmas *}
   108 
   109 lemma inj_Suc[simp]: "inj_on Suc N"
   110   by (simp add: inj_on_def)
   111 
   112 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   113 by (rule notE, rule Suc_not_Zero)
   114 
   115 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   116 by (rule Suc_neq_Zero, erule sym)
   117 
   118 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   119 by (rule inj_Suc [THEN injD])
   120 
   121 lemma n_not_Suc_n: "n \<noteq> Suc n"
   122 by (induct n) simp_all
   123 
   124 lemma Suc_n_not_n: "Suc n \<noteq> n"
   125 by (rule not_sym, rule n_not_Suc_n)
   126 
   127 text {* A special form of induction for reasoning
   128   about @{term "m < n"} and @{term "m - n"} *}
   129 
   130 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   131     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   132   apply (rule_tac x = m in spec)
   133   apply (induct n)
   134   prefer 2
   135   apply (rule allI)
   136   apply (induct_tac x, iprover+)
   137   done
   138 
   139 
   140 subsection {* Arithmetic operators *}
   141 
   142 instantiation nat :: "{minus, comm_monoid_add}"
   143 begin
   144 
   145 primrec plus_nat
   146 where
   147   add_0:      "0 + n = (n\<Colon>nat)"
   148   | add_Suc:  "Suc m + n = Suc (m + n)"
   149 
   150 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   151   by (induct m) simp_all
   152 
   153 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   154   by (induct m) simp_all
   155 
   156 declare add_0 [code]
   157 
   158 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   159   by simp
   160 
   161 primrec minus_nat
   162 where
   163   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   164 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   165 
   166 declare diff_Suc [simp del]
   167 
   168 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   169   by (induct n) (simp_all add: diff_Suc)
   170 
   171 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   172   by (induct n) (simp_all add: diff_Suc)
   173 
   174 instance proof
   175   fix n m q :: nat
   176   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   177   show "n + m = m + n" by (induct n) simp_all
   178   show "0 + n = n" by simp
   179 qed
   180 
   181 end
   182 
   183 hide_fact (open) add_0 add_0_right diff_0
   184 
   185 instantiation nat :: comm_semiring_1_cancel
   186 begin
   187 
   188 definition
   189   One_nat_def [simp]: "1 = Suc 0"
   190 
   191 primrec times_nat
   192 where
   193   mult_0:     "0 * n = (0\<Colon>nat)"
   194   | mult_Suc: "Suc m * n = n + (m * n)"
   195 
   196 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   197   by (induct m) simp_all
   198 
   199 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   200   by (induct m) (simp_all add: add_left_commute)
   201 
   202 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   203   by (induct m) (simp_all add: add_assoc)
   204 
   205 instance proof
   206   fix n m q :: nat
   207   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   208   show "1 * n = n" unfolding One_nat_def by simp
   209   show "n * m = m * n" by (induct n) simp_all
   210   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   211   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   212   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   213 qed
   214 
   215 end
   216 
   217 subsubsection {* Addition *}
   218 
   219 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   220   by (rule add_assoc)
   221 
   222 lemma nat_add_commute: "m + n = n + (m::nat)"
   223   by (rule add_commute)
   224 
   225 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   226   by (rule add_left_commute)
   227 
   228 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   229   by (rule add_left_cancel)
   230 
   231 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   232   by (rule add_right_cancel)
   233 
   234 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   235 
   236 lemma add_is_0 [iff]:
   237   fixes m n :: nat
   238   shows "(m + n = 0) = (m = 0 & n = 0)"
   239   by (cases m) simp_all
   240 
   241 lemma add_is_1:
   242   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   243   by (cases m) simp_all
   244 
   245 lemma one_is_add:
   246   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   247   by (rule trans, rule eq_commute, rule add_is_1)
   248 
   249 lemma add_eq_self_zero:
   250   fixes m n :: nat
   251   shows "m + n = m \<Longrightarrow> n = 0"
   252   by (induct m) simp_all
   253 
   254 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   255   apply (induct k)
   256    apply simp
   257   apply(drule comp_inj_on[OF _ inj_Suc])
   258   apply (simp add:o_def)
   259   done
   260 
   261 
   262 subsubsection {* Difference *}
   263 
   264 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   265   by (induct m) simp_all
   266 
   267 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   268   by (induct i j rule: diff_induct) simp_all
   269 
   270 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   271   by (simp add: diff_diff_left)
   272 
   273 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   274   by (simp add: diff_diff_left add_commute)
   275 
   276 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   277   by (induct n) simp_all
   278 
   279 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   280   by (simp add: diff_add_inverse add_commute [of m n])
   281 
   282 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   283   by (induct k) simp_all
   284 
   285 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   286   by (simp add: diff_cancel add_commute)
   287 
   288 lemma diff_add_0: "n - (n + m) = (0::nat)"
   289   by (induct n) simp_all
   290 
   291 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   292   unfolding One_nat_def by simp
   293 
   294 text {* Difference distributes over multiplication *}
   295 
   296 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   297 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   298 
   299 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   300 by (simp add: diff_mult_distrib mult_commute [of k])
   301   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   302 
   303 
   304 subsubsection {* Multiplication *}
   305 
   306 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   307   by (rule mult_assoc)
   308 
   309 lemma nat_mult_commute: "m * n = n * (m::nat)"
   310   by (rule mult_commute)
   311 
   312 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   313   by (rule right_distrib)
   314 
   315 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   316   by (induct m) auto
   317 
   318 lemmas nat_distrib =
   319   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   320 
   321 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   322   apply (induct m)
   323    apply simp
   324   apply (induct n)
   325    apply auto
   326   done
   327 
   328 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   329   apply (rule trans)
   330   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   331   done
   332 
   333 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   334   unfolding One_nat_def by (rule mult_eq_1_iff)
   335 
   336 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   337   unfolding One_nat_def by (rule one_eq_mult_iff)
   338 
   339 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   340 proof -
   341   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   342   proof (induct n arbitrary: m)
   343     case 0 then show "m = 0" by simp
   344   next
   345     case (Suc n) then show "m = Suc n"
   346       by (cases m) (simp_all add: eq_commute [of "0"])
   347   qed
   348   then show ?thesis by auto
   349 qed
   350 
   351 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   352   by (simp add: mult_commute)
   353 
   354 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   355   by (subst mult_cancel1) simp
   356 
   357 
   358 subsection {* Orders on @{typ nat} *}
   359 
   360 subsubsection {* Operation definition *}
   361 
   362 instantiation nat :: linorder
   363 begin
   364 
   365 primrec less_eq_nat where
   366   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   367   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   368 
   369 declare less_eq_nat.simps [simp del]
   370 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   371 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   372 
   373 definition less_nat where
   374   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   375 
   376 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   377   by (simp add: less_eq_nat.simps(2))
   378 
   379 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   380   unfolding less_eq_Suc_le ..
   381 
   382 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   383   by (induct n) (simp_all add: less_eq_nat.simps(2))
   384 
   385 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   386   by (simp add: less_eq_Suc_le)
   387 
   388 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   389   by simp
   390 
   391 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   392   by (simp add: less_eq_Suc_le)
   393 
   394 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   395   by (simp add: less_eq_Suc_le)
   396 
   397 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   398   by (induct m arbitrary: n)
   399     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   400 
   401 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   402   by (cases n) (auto intro: le_SucI)
   403 
   404 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   405   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   406 
   407 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   408   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   409 
   410 instance
   411 proof
   412   fix n m :: nat
   413   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   414   proof (induct n arbitrary: m)
   415     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   416   next
   417     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   418   qed
   419 next
   420   fix n :: nat show "n \<le> n" by (induct n) simp_all
   421 next
   422   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   423   then show "n = m"
   424     by (induct n arbitrary: m)
   425       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   426 next
   427   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   428   then show "n \<le> q"
   429   proof (induct n arbitrary: m q)
   430     case 0 show ?case by simp
   431   next
   432     case (Suc n) then show ?case
   433       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   434         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   435         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   436   qed
   437 next
   438   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   439     by (induct n arbitrary: m)
   440       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   441 qed
   442 
   443 end
   444 
   445 instantiation nat :: bot
   446 begin
   447 
   448 definition bot_nat :: nat where
   449   "bot_nat = 0"
   450 
   451 instance proof
   452 qed (simp add: bot_nat_def)
   453 
   454 end
   455 
   456 subsubsection {* Introduction properties *}
   457 
   458 lemma lessI [iff]: "n < Suc n"
   459   by (simp add: less_Suc_eq_le)
   460 
   461 lemma zero_less_Suc [iff]: "0 < Suc n"
   462   by (simp add: less_Suc_eq_le)
   463 
   464 
   465 subsubsection {* Elimination properties *}
   466 
   467 lemma less_not_refl: "~ n < (n::nat)"
   468   by (rule order_less_irrefl)
   469 
   470 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   471   by (rule not_sym) (rule less_imp_neq) 
   472 
   473 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   474   by (rule less_imp_neq)
   475 
   476 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   477   by (rule notE, rule less_not_refl)
   478 
   479 lemma less_zeroE: "(n::nat) < 0 ==> R"
   480   by (rule notE) (rule not_less0)
   481 
   482 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   483   unfolding less_Suc_eq_le le_less ..
   484 
   485 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   486   by (simp add: less_Suc_eq)
   487 
   488 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   489   unfolding One_nat_def by (rule less_Suc0)
   490 
   491 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   492   by simp
   493 
   494 text {* "Less than" is antisymmetric, sort of *}
   495 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   496   unfolding not_less less_Suc_eq_le by (rule antisym)
   497 
   498 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   499   by (rule linorder_neq_iff)
   500 
   501 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   502   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   503   shows "P n m"
   504   apply (rule less_linear [THEN disjE])
   505   apply (erule_tac [2] disjE)
   506   apply (erule lessCase)
   507   apply (erule sym [THEN eqCase])
   508   apply (erule major)
   509   done
   510 
   511 
   512 subsubsection {* Inductive (?) properties *}
   513 
   514 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   515   unfolding less_eq_Suc_le [of m] le_less by simp 
   516 
   517 lemma lessE:
   518   assumes major: "i < k"
   519   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   520   shows P
   521 proof -
   522   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   523     unfolding less_eq_Suc_le by (induct k) simp_all
   524   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   525     by (clarsimp simp add: less_le)
   526   with p1 p2 show P by auto
   527 qed
   528 
   529 lemma less_SucE: assumes major: "m < Suc n"
   530   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   531   apply (rule major [THEN lessE])
   532   apply (rule eq, blast)
   533   apply (rule less, blast)
   534   done
   535 
   536 lemma Suc_lessE: assumes major: "Suc i < k"
   537   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   538   apply (rule major [THEN lessE])
   539   apply (erule lessI [THEN minor])
   540   apply (erule Suc_lessD [THEN minor], assumption)
   541   done
   542 
   543 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   544   by simp
   545 
   546 lemma less_trans_Suc:
   547   assumes le: "i < j" shows "j < k ==> Suc i < k"
   548   apply (induct k, simp_all)
   549   apply (insert le)
   550   apply (simp add: less_Suc_eq)
   551   apply (blast dest: Suc_lessD)
   552   done
   553 
   554 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   555 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   556   unfolding not_less less_Suc_eq_le ..
   557 
   558 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   559   unfolding not_le Suc_le_eq ..
   560 
   561 text {* Properties of "less than or equal" *}
   562 
   563 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   564   unfolding less_Suc_eq_le .
   565 
   566 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   567   unfolding not_le less_Suc_eq_le ..
   568 
   569 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   570   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   571 
   572 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   573   by (drule le_Suc_eq [THEN iffD1], iprover+)
   574 
   575 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   576   unfolding Suc_le_eq .
   577 
   578 text {* Stronger version of @{text Suc_leD} *}
   579 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   580   unfolding Suc_le_eq .
   581 
   582 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   583   unfolding less_eq_Suc_le by (rule Suc_leD)
   584 
   585 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   586 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   587 
   588 
   589 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   590 
   591 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   592   unfolding le_less .
   593 
   594 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   595   by (rule le_less)
   596 
   597 text {* Useful with @{text blast}. *}
   598 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   599   by auto
   600 
   601 lemma le_refl: "n \<le> (n::nat)"
   602   by simp
   603 
   604 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   605   by (rule order_trans)
   606 
   607 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   608   by (rule antisym)
   609 
   610 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   611   by (rule less_le)
   612 
   613 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   614   unfolding less_le ..
   615 
   616 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   617   by (rule linear)
   618 
   619 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   620 
   621 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   622   unfolding less_Suc_eq_le by auto
   623 
   624 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   625   unfolding not_less by (rule le_less_Suc_eq)
   626 
   627 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   628 
   629 text {* These two rules ease the use of primitive recursion.
   630 NOTE USE OF @{text "=="} *}
   631 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   632 by simp
   633 
   634 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   635 by simp
   636 
   637 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   638 by (cases n) simp_all
   639 
   640 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   641 by (cases n) simp_all
   642 
   643 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   644 by (cases n) simp_all
   645 
   646 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   647 by (cases n) simp_all
   648 
   649 text {* This theorem is useful with @{text blast} *}
   650 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   651 by (rule neq0_conv[THEN iffD1], iprover)
   652 
   653 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   654 by (fast intro: not0_implies_Suc)
   655 
   656 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   657 using neq0_conv by blast
   658 
   659 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   660 by (induct m') simp_all
   661 
   662 text {* Useful in certain inductive arguments *}
   663 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   664 by (cases m) simp_all
   665 
   666 
   667 subsubsection {* @{term min} and @{term max} *}
   668 
   669 lemma mono_Suc: "mono Suc"
   670 by (rule monoI) simp
   671 
   672 lemma min_0L [simp]: "min 0 n = (0::nat)"
   673 by (rule min_leastL) simp
   674 
   675 lemma min_0R [simp]: "min n 0 = (0::nat)"
   676 by (rule min_leastR) simp
   677 
   678 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   679 by (simp add: mono_Suc min_of_mono)
   680 
   681 lemma min_Suc1:
   682    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   683 by (simp split: nat.split)
   684 
   685 lemma min_Suc2:
   686    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   687 by (simp split: nat.split)
   688 
   689 lemma max_0L [simp]: "max 0 n = (n::nat)"
   690 by (rule max_leastL) simp
   691 
   692 lemma max_0R [simp]: "max n 0 = (n::nat)"
   693 by (rule max_leastR) simp
   694 
   695 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   696 by (simp add: mono_Suc max_of_mono)
   697 
   698 lemma max_Suc1:
   699    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   700 by (simp split: nat.split)
   701 
   702 lemma max_Suc2:
   703    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   704 by (simp split: nat.split)
   705 
   706 
   707 subsubsection {* Monotonicity of Addition *}
   708 
   709 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   710 by (simp add: diff_Suc split: nat.split)
   711 
   712 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   713 unfolding One_nat_def by (rule Suc_pred)
   714 
   715 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   716 by (induct k) simp_all
   717 
   718 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   719 by (induct k) simp_all
   720 
   721 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   722 by(auto dest:gr0_implies_Suc)
   723 
   724 text {* strict, in 1st argument *}
   725 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   726 by (induct k) simp_all
   727 
   728 text {* strict, in both arguments *}
   729 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   730   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   731   apply (induct j, simp_all)
   732   done
   733 
   734 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   735 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   736   apply (induct n)
   737   apply (simp_all add: order_le_less)
   738   apply (blast elim!: less_SucE
   739                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   740   done
   741 
   742 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   743 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   744 apply(auto simp: gr0_conv_Suc)
   745 apply (induct_tac m)
   746 apply (simp_all add: add_less_mono)
   747 done
   748 
   749 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   750 instance nat :: linordered_semidom
   751 proof
   752   fix i j k :: nat
   753   show "0 < (1::nat)" by simp
   754   show "i \<le> j ==> k + i \<le> k + j" by simp
   755   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   756 qed
   757 
   758 instance nat :: no_zero_divisors
   759 proof
   760   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   761 qed
   762 
   763 lemma nat_mult_1: "(1::nat) * n = n"
   764 by simp
   765 
   766 lemma nat_mult_1_right: "n * (1::nat) = n"
   767 by simp
   768 
   769 
   770 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   771 
   772 text {* Complete induction, aka course-of-values induction *}
   773 
   774 instance nat :: wellorder proof
   775   fix P and n :: nat
   776   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   777   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   778   proof (induct n)
   779     case (0 n)
   780     have "P 0" by (rule step) auto
   781     thus ?case using 0 by auto
   782   next
   783     case (Suc m n)
   784     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   785     thus ?case
   786     proof
   787       assume "n \<le> m" thus "P n" by (rule Suc(1))
   788     next
   789       assume n: "n = Suc m"
   790       show "P n"
   791         by (rule step) (rule Suc(1), simp add: n le_simps)
   792     qed
   793   qed
   794   then show "P n" by auto
   795 qed
   796 
   797 lemma Least_Suc:
   798      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   799   apply (case_tac "n", auto)
   800   apply (frule LeastI)
   801   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   802   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   803   apply (erule_tac [2] Least_le)
   804   apply (case_tac "LEAST x. P x", auto)
   805   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   806   apply (blast intro: order_antisym)
   807   done
   808 
   809 lemma Least_Suc2:
   810    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   811   apply (erule (1) Least_Suc [THEN ssubst])
   812   apply simp
   813   done
   814 
   815 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   816   apply (cases n)
   817    apply blast
   818   apply (rule_tac x="LEAST k. P(k)" in exI)
   819   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   820   done
   821 
   822 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   823   unfolding One_nat_def
   824   apply (cases n)
   825    apply blast
   826   apply (frule (1) ex_least_nat_le)
   827   apply (erule exE)
   828   apply (case_tac k)
   829    apply simp
   830   apply (rename_tac k1)
   831   apply (rule_tac x=k1 in exI)
   832   apply (auto simp add: less_eq_Suc_le)
   833   done
   834 
   835 lemma nat_less_induct:
   836   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   837   using assms less_induct by blast
   838 
   839 lemma measure_induct_rule [case_names less]:
   840   fixes f :: "'a \<Rightarrow> nat"
   841   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   842   shows "P a"
   843 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   844 
   845 text {* old style induction rules: *}
   846 lemma measure_induct:
   847   fixes f :: "'a \<Rightarrow> nat"
   848   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   849   by (rule measure_induct_rule [of f P a]) iprover
   850 
   851 lemma full_nat_induct:
   852   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   853   shows "P n"
   854   by (rule less_induct) (auto intro: step simp:le_simps)
   855 
   856 text{*An induction rule for estabilishing binary relations*}
   857 lemma less_Suc_induct:
   858   assumes less:  "i < j"
   859      and  step:  "!!i. P i (Suc i)"
   860      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   861   shows "P i j"
   862 proof -
   863   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   864   have "P i (Suc (i + k))"
   865   proof (induct k)
   866     case 0
   867     show ?case by (simp add: step)
   868   next
   869     case (Suc k)
   870     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   871     hence "i < Suc (i + k)" by (simp add: add_commute)
   872     from trans[OF this lessI Suc step]
   873     show ?case by simp
   874   qed
   875   thus "P i j" by (simp add: j)
   876 qed
   877 
   878 text {* The method of infinite descent, frequently used in number theory.
   879 Provided by Roelof Oosterhuis.
   880 $P(n)$ is true for all $n\in\mathbb{N}$ if
   881 \begin{itemize}
   882   \item case ``0'': given $n=0$ prove $P(n)$,
   883   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   884         a smaller integer $m$ such that $\neg P(m)$.
   885 \end{itemize} *}
   886 
   887 text{* A compact version without explicit base case: *}
   888 lemma infinite_descent:
   889   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   890 by (induct n rule: less_induct, auto)
   891 
   892 lemma infinite_descent0[case_names 0 smaller]: 
   893   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   894 by (rule infinite_descent) (case_tac "n>0", auto)
   895 
   896 text {*
   897 Infinite descent using a mapping to $\mathbb{N}$:
   898 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   899 \begin{itemize}
   900 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   901 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   902 \end{itemize}
   903 NB: the proof also shows how to use the previous lemma. *}
   904 
   905 corollary infinite_descent0_measure [case_names 0 smaller]:
   906   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   907     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   908   shows "P x"
   909 proof -
   910   obtain n where "n = V x" by auto
   911   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   912   proof (induct n rule: infinite_descent0)
   913     case 0 -- "i.e. $V(x) = 0$"
   914     with A0 show "P x" by auto
   915   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   916     case (smaller n)
   917     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   918     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   919     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   920     then show ?case by auto
   921   qed
   922   ultimately show "P x" by auto
   923 qed
   924 
   925 text{* Again, without explicit base case: *}
   926 lemma infinite_descent_measure:
   927 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   928 proof -
   929   from assms obtain n where "n = V x" by auto
   930   moreover have "!!x. V x = n \<Longrightarrow> P x"
   931   proof (induct n rule: infinite_descent, auto)
   932     fix x assume "\<not> P x"
   933     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   934   qed
   935   ultimately show "P x" by auto
   936 qed
   937 
   938 text {* A [clumsy] way of lifting @{text "<"}
   939   monotonicity to @{text "\<le>"} monotonicity *}
   940 lemma less_mono_imp_le_mono:
   941   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   942 by (simp add: order_le_less) (blast)
   943 
   944 
   945 text {* non-strict, in 1st argument *}
   946 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   947 by (rule add_right_mono)
   948 
   949 text {* non-strict, in both arguments *}
   950 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   951 by (rule add_mono)
   952 
   953 lemma le_add2: "n \<le> ((m + n)::nat)"
   954 by (insert add_right_mono [of 0 m n], simp)
   955 
   956 lemma le_add1: "n \<le> ((n + m)::nat)"
   957 by (simp add: add_commute, rule le_add2)
   958 
   959 lemma less_add_Suc1: "i < Suc (i + m)"
   960 by (rule le_less_trans, rule le_add1, rule lessI)
   961 
   962 lemma less_add_Suc2: "i < Suc (m + i)"
   963 by (rule le_less_trans, rule le_add2, rule lessI)
   964 
   965 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   966 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   967 
   968 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   969 by (rule le_trans, assumption, rule le_add1)
   970 
   971 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   972 by (rule le_trans, assumption, rule le_add2)
   973 
   974 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   975 by (rule less_le_trans, assumption, rule le_add1)
   976 
   977 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   978 by (rule less_le_trans, assumption, rule le_add2)
   979 
   980 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   981 apply (rule le_less_trans [of _ "i+j"])
   982 apply (simp_all add: le_add1)
   983 done
   984 
   985 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   986 apply (rule notI)
   987 apply (drule add_lessD1)
   988 apply (erule less_irrefl [THEN notE])
   989 done
   990 
   991 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   992 by (simp add: add_commute)
   993 
   994 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   995 apply (rule order_trans [of _ "m+k"])
   996 apply (simp_all add: le_add1)
   997 done
   998 
   999 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1000 apply (simp add: add_commute)
  1001 apply (erule add_leD1)
  1002 done
  1003 
  1004 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1005 by (blast dest: add_leD1 add_leD2)
  1006 
  1007 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1008 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1009 by (force simp del: add_Suc_right
  1010     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1011 
  1012 
  1013 subsubsection {* More results about difference *}
  1014 
  1015 text {* Addition is the inverse of subtraction:
  1016   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1017 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1018 by (induct m n rule: diff_induct) simp_all
  1019 
  1020 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1021 by (simp add: add_diff_inverse linorder_not_less)
  1022 
  1023 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1024 by (simp add: add_commute)
  1025 
  1026 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1027 by (induct m n rule: diff_induct) simp_all
  1028 
  1029 lemma diff_less_Suc: "m - n < Suc m"
  1030 apply (induct m n rule: diff_induct)
  1031 apply (erule_tac [3] less_SucE)
  1032 apply (simp_all add: less_Suc_eq)
  1033 done
  1034 
  1035 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1036 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1037 
  1038 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1039   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1040 
  1041 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1042 by (rule le_less_trans, rule diff_le_self)
  1043 
  1044 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1045 by (cases n) (auto simp add: le_simps)
  1046 
  1047 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1048 by (induct j k rule: diff_induct) simp_all
  1049 
  1050 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1051 by (simp add: add_commute diff_add_assoc)
  1052 
  1053 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1054 by (auto simp add: diff_add_inverse2)
  1055 
  1056 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1057 by (induct m n rule: diff_induct) simp_all
  1058 
  1059 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1060 by (rule iffD2, rule diff_is_0_eq)
  1061 
  1062 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1063 by (induct m n rule: diff_induct) simp_all
  1064 
  1065 lemma less_imp_add_positive:
  1066   assumes "i < j"
  1067   shows "\<exists>k::nat. 0 < k & i + k = j"
  1068 proof
  1069   from assms show "0 < j - i & i + (j - i) = j"
  1070     by (simp add: order_less_imp_le)
  1071 qed
  1072 
  1073 text {* a nice rewrite for bounded subtraction *}
  1074 lemma nat_minus_add_max:
  1075   fixes n m :: nat
  1076   shows "n - m + m = max n m"
  1077     by (simp add: max_def not_le order_less_imp_le)
  1078 
  1079 lemma nat_diff_split:
  1080   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1081     -- {* elimination of @{text -} on @{text nat} *}
  1082 by (cases "a < b")
  1083   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1084     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1085 
  1086 lemma nat_diff_split_asm:
  1087   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1088     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1089 by (auto split: nat_diff_split)
  1090 
  1091 
  1092 subsubsection {* Monotonicity of Multiplication *}
  1093 
  1094 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1095 by (simp add: mult_right_mono)
  1096 
  1097 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1098 by (simp add: mult_left_mono)
  1099 
  1100 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1101 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1102 by (simp add: mult_mono)
  1103 
  1104 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1105 by (simp add: mult_strict_right_mono)
  1106 
  1107 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1108       there are no negative numbers.*}
  1109 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1110   apply (induct m)
  1111    apply simp
  1112   apply (case_tac n)
  1113    apply simp_all
  1114   done
  1115 
  1116 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1117   apply (induct m)
  1118    apply simp
  1119   apply (case_tac n)
  1120    apply simp_all
  1121   done
  1122 
  1123 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1124   apply (safe intro!: mult_less_mono1)
  1125   apply (case_tac k, auto)
  1126   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1127   apply (blast intro: mult_le_mono1)
  1128   done
  1129 
  1130 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1131 by (simp add: mult_commute [of k])
  1132 
  1133 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1134 by (simp add: linorder_not_less [symmetric], auto)
  1135 
  1136 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1137 by (simp add: linorder_not_less [symmetric], auto)
  1138 
  1139 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1140 by (subst mult_less_cancel1) simp
  1141 
  1142 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1143 by (subst mult_le_cancel1) simp
  1144 
  1145 lemma le_square: "m \<le> m * (m::nat)"
  1146   by (cases m) (auto intro: le_add1)
  1147 
  1148 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1149   by (cases m) (auto intro: le_add1)
  1150 
  1151 text {* Lemma for @{text gcd} *}
  1152 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1153   apply (drule sym)
  1154   apply (rule disjCI)
  1155   apply (rule nat_less_cases, erule_tac [2] _)
  1156    apply (drule_tac [2] mult_less_mono2)
  1157     apply (auto)
  1158   done
  1159 
  1160 text {* the lattice order on @{typ nat} *}
  1161 
  1162 instantiation nat :: distrib_lattice
  1163 begin
  1164 
  1165 definition
  1166   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1167 
  1168 definition
  1169   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1170 
  1171 instance by intro_classes
  1172   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1173     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1174 
  1175 end
  1176 
  1177 
  1178 subsection {* Natural operation of natural numbers on functions *}
  1179 
  1180 text {*
  1181   We use the same logical constant for the power operations on
  1182   functions and relations, in order to share the same syntax.
  1183 *}
  1184 
  1185 consts compow :: "nat \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
  1186 
  1187 abbreviation compower :: "('a \<Rightarrow> 'b) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'b" (infixr "^^" 80) where
  1188   "f ^^ n \<equiv> compow n f"
  1189 
  1190 notation (latex output)
  1191   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1192 
  1193 notation (HTML output)
  1194   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1195 
  1196 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1197 
  1198 overloading
  1199   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1200 begin
  1201 
  1202 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1203     "funpow 0 f = id"
  1204   | "funpow (Suc n) f = f o funpow n f"
  1205 
  1206 end
  1207 
  1208 text {* for code generation *}
  1209 
  1210 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1211   funpow_code_def [code_post]: "funpow = compow"
  1212 
  1213 lemmas [code_unfold] = funpow_code_def [symmetric]
  1214 
  1215 lemma [code]:
  1216   "funpow (Suc n) f = f o funpow n f"
  1217   "funpow 0 f = id"
  1218   by (simp_all add: funpow_code_def)
  1219 
  1220 hide_const (open) funpow
  1221 
  1222 lemma funpow_add:
  1223   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1224   by (induct m) simp_all
  1225 
  1226 lemma funpow_mult:
  1227   fixes f :: "'a \<Rightarrow> 'a"
  1228   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1229   by (induct n) (simp_all add: funpow_add)
  1230 
  1231 lemma funpow_swap1:
  1232   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1233 proof -
  1234   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1235   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1236   also have "\<dots> = (f ^^ n) (f x)" by simp
  1237   finally show ?thesis .
  1238 qed
  1239 
  1240 lemma comp_funpow:
  1241   fixes f :: "'a \<Rightarrow> 'a"
  1242   shows "comp f ^^ n = comp (f ^^ n)"
  1243   by (induct n) simp_all
  1244 
  1245 
  1246 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1247 
  1248 context semiring_1
  1249 begin
  1250 
  1251 definition of_nat :: "nat \<Rightarrow> 'a" where
  1252   "of_nat n = (plus 1 ^^ n) 0"
  1253 
  1254 lemma of_nat_simps [simp]:
  1255   shows of_nat_0: "of_nat 0 = 0"
  1256     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1257   by (simp_all add: of_nat_def)
  1258 
  1259 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1260   by (simp add: of_nat_def)
  1261 
  1262 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1263   by (induct m) (simp_all add: add_ac)
  1264 
  1265 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1266   by (induct m) (simp_all add: add_ac left_distrib)
  1267 
  1268 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1269   "of_nat_aux inc 0 i = i"
  1270   | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1271 
  1272 lemma of_nat_code:
  1273   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1274 proof (induct n)
  1275   case 0 then show ?case by simp
  1276 next
  1277   case (Suc n)
  1278   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1279     by (induct n) simp_all
  1280   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1281     by simp
  1282   with Suc show ?case by (simp add: add_commute)
  1283 qed
  1284 
  1285 end
  1286 
  1287 declare of_nat_code [code, code_unfold, code_inline del]
  1288 
  1289 text{*Class for unital semirings with characteristic zero.
  1290  Includes non-ordered rings like the complex numbers.*}
  1291 
  1292 class semiring_char_0 = semiring_1 +
  1293   assumes inj_of_nat: "inj of_nat"
  1294 begin
  1295 
  1296 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1297   by (auto intro: inj_of_nat injD)
  1298 
  1299 text{*Special cases where either operand is zero*}
  1300 
  1301 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1302   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1303 
  1304 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1305   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1306 
  1307 end
  1308 
  1309 context linordered_semidom
  1310 begin
  1311 
  1312 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1313   by (induct m) simp_all
  1314 
  1315 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1316   apply (induct m n rule: diff_induct, simp_all)
  1317   apply (rule add_pos_nonneg [OF zero_less_one zero_le_imp_of_nat])
  1318   done
  1319 
  1320 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1321   apply (induct m n rule: diff_induct, simp_all)
  1322   apply (insert zero_le_imp_of_nat)
  1323   apply (force simp add: not_less [symmetric])
  1324   done
  1325 
  1326 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1327   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1328 
  1329 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1330   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1331 
  1332 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1333 
  1334 subclass semiring_char_0 proof
  1335 qed (auto intro!: injI simp add: eq_iff)
  1336 
  1337 text{*Special cases where either operand is zero*}
  1338 
  1339 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1340   by (rule of_nat_le_iff [of 0, simplified])
  1341 
  1342 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1343   by (rule of_nat_le_iff [of _ 0, simplified])
  1344 
  1345 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1346   by (rule of_nat_less_iff [of 0, simplified])
  1347 
  1348 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1349   by (rule of_nat_less_iff [of _ 0, simplified])
  1350 
  1351 end
  1352 
  1353 context ring_1
  1354 begin
  1355 
  1356 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1357 by (simp add: algebra_simps of_nat_add [symmetric])
  1358 
  1359 end
  1360 
  1361 context linordered_idom
  1362 begin
  1363 
  1364 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1365   unfolding abs_if by auto
  1366 
  1367 end
  1368 
  1369 lemma of_nat_id [simp]: "of_nat n = n"
  1370   by (induct n) simp_all
  1371 
  1372 lemma of_nat_eq_id [simp]: "of_nat = id"
  1373   by (auto simp add: fun_eq_iff)
  1374 
  1375 
  1376 subsection {* The Set of Natural Numbers *}
  1377 
  1378 context semiring_1
  1379 begin
  1380 
  1381 definition Nats  :: "'a set" where
  1382   "Nats = range of_nat"
  1383 
  1384 notation (xsymbols)
  1385   Nats  ("\<nat>")
  1386 
  1387 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1388   by (simp add: Nats_def)
  1389 
  1390 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1391 apply (simp add: Nats_def)
  1392 apply (rule range_eqI)
  1393 apply (rule of_nat_0 [symmetric])
  1394 done
  1395 
  1396 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1397 apply (simp add: Nats_def)
  1398 apply (rule range_eqI)
  1399 apply (rule of_nat_1 [symmetric])
  1400 done
  1401 
  1402 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1403 apply (auto simp add: Nats_def)
  1404 apply (rule range_eqI)
  1405 apply (rule of_nat_add [symmetric])
  1406 done
  1407 
  1408 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1409 apply (auto simp add: Nats_def)
  1410 apply (rule range_eqI)
  1411 apply (rule of_nat_mult [symmetric])
  1412 done
  1413 
  1414 lemma Nats_cases [cases set: Nats]:
  1415   assumes "x \<in> \<nat>"
  1416   obtains (of_nat) n where "x = of_nat n"
  1417   unfolding Nats_def
  1418 proof -
  1419   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1420   then obtain n where "x = of_nat n" ..
  1421   then show thesis ..
  1422 qed
  1423 
  1424 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1425   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1426   by (rule Nats_cases) auto
  1427 
  1428 end
  1429 
  1430 
  1431 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1432 
  1433 lemma subst_equals:
  1434   assumes 1: "t = s" and 2: "u = t"
  1435   shows "u = s"
  1436   using 2 1 by (rule trans)
  1437 
  1438 setup Arith_Data.setup
  1439 
  1440 use "Tools/nat_arith.ML"
  1441 declaration {* K Nat_Arith.setup *}
  1442 
  1443 use "Tools/lin_arith.ML"
  1444 setup {* Lin_Arith.global_setup *}
  1445 declaration {* K Lin_Arith.setup *}
  1446 
  1447 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1448   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1449 (* Because of this simproc, the arithmetic solver is really only
  1450 useful to detect inconsistencies among the premises for subgoals which are
  1451 *not* themselves (in)equalities, because the latter activate
  1452 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1453 solver all the time rather than add the additional check. *)
  1454 
  1455 
  1456 lemmas [arith_split] = nat_diff_split split_min split_max
  1457 
  1458 context order
  1459 begin
  1460 
  1461 lemma lift_Suc_mono_le:
  1462   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1463   shows "f n \<le> f n'"
  1464 proof (cases "n < n'")
  1465   case True
  1466   thus ?thesis
  1467     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1468 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1469 
  1470 lemma lift_Suc_mono_less:
  1471   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1472   shows "f n < f n'"
  1473 using `n < n'`
  1474 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1475 
  1476 lemma lift_Suc_mono_less_iff:
  1477   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1478 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1479          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1480 
  1481 end
  1482 
  1483 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1484   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1485 
  1486 lemma mono_nat_linear_lb:
  1487   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1488 apply(induct_tac k)
  1489  apply simp
  1490 apply(erule_tac x="m+n" in meta_allE)
  1491 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1492 apply simp
  1493 done
  1494 
  1495 
  1496 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1497 
  1498 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1499 by arith
  1500 
  1501 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1502 by arith
  1503 
  1504 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1505 by arith
  1506 
  1507 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1508 by arith
  1509 
  1510 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1511 by arith
  1512 
  1513 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1514 by arith
  1515 
  1516 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1517   second premise n\<le>m*)
  1518 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1519 by arith
  1520 
  1521 text {* Simplification of relational expressions involving subtraction *}
  1522 
  1523 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1524 by (simp split add: nat_diff_split)
  1525 
  1526 hide_fact (open) diff_diff_eq
  1527 
  1528 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1529 by (auto split add: nat_diff_split)
  1530 
  1531 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1532 by (auto split add: nat_diff_split)
  1533 
  1534 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1535 by (auto split add: nat_diff_split)
  1536 
  1537 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1538 
  1539 (* Monotonicity of subtraction in first argument *)
  1540 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1541 by (simp split add: nat_diff_split)
  1542 
  1543 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1544 by (simp split add: nat_diff_split)
  1545 
  1546 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1547 by (simp split add: nat_diff_split)
  1548 
  1549 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1550 by (simp split add: nat_diff_split)
  1551 
  1552 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1553 by auto
  1554 
  1555 lemma inj_on_diff_nat: 
  1556   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1557   shows "inj_on (\<lambda>n. n - k) N"
  1558 proof (rule inj_onI)
  1559   fix x y
  1560   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1561   with k_le_n have "x - k + k = y - k + k" by auto
  1562   with a k_le_n show "x = y" by auto
  1563 qed
  1564 
  1565 text{*Rewriting to pull differences out*}
  1566 
  1567 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1568 by arith
  1569 
  1570 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1571 by arith
  1572 
  1573 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1574 by arith
  1575 
  1576 text{*Lemmas for ex/Factorization*}
  1577 
  1578 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1579 by (cases m) auto
  1580 
  1581 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1582 by (cases m) auto
  1583 
  1584 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1585 by (cases m) auto
  1586 
  1587 text {* Specialized induction principles that work "backwards": *}
  1588 
  1589 lemma inc_induct[consumes 1, case_names base step]:
  1590   assumes less: "i <= j"
  1591   assumes base: "P j"
  1592   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1593   shows "P i"
  1594   using less
  1595 proof (induct d=="j - i" arbitrary: i)
  1596   case (0 i)
  1597   hence "i = j" by simp
  1598   with base show ?case by simp
  1599 next
  1600   case (Suc d i)
  1601   hence "i < j" "P (Suc i)"
  1602     by simp_all
  1603   thus "P i" by (rule step)
  1604 qed
  1605 
  1606 lemma strict_inc_induct[consumes 1, case_names base step]:
  1607   assumes less: "i < j"
  1608   assumes base: "!!i. j = Suc i ==> P i"
  1609   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1610   shows "P i"
  1611   using less
  1612 proof (induct d=="j - i - 1" arbitrary: i)
  1613   case (0 i)
  1614   with `i < j` have "j = Suc i" by simp
  1615   with base show ?case by simp
  1616 next
  1617   case (Suc d i)
  1618   hence "i < j" "P (Suc i)"
  1619     by simp_all
  1620   thus "P i" by (rule step)
  1621 qed
  1622 
  1623 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1624   using inc_induct[of "k - i" k P, simplified] by blast
  1625 
  1626 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1627   using inc_induct[of 0 k P] by blast
  1628 
  1629 (*The others are
  1630       i - j - k = i - (j + k),
  1631       k \<le> j ==> j - k + i = j + i - k,
  1632       k \<le> j ==> i + (j - k) = i + j - k *)
  1633 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1634 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1635 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1636 
  1637 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1638 Least_Suc}, since there appears to be no need.*}
  1639 
  1640 
  1641 subsection {* The divides relation on @{typ nat} *}
  1642 
  1643 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1644 unfolding dvd_def by simp
  1645 
  1646 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1647 by (simp add: dvd_def)
  1648 
  1649 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1650 by (simp add: dvd_def)
  1651 
  1652 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1653   unfolding dvd_def
  1654   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1655 
  1656 text {* @{term "op dvd"} is a partial order *}
  1657 
  1658 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1659   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1660 
  1661 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1662 unfolding dvd_def
  1663 by (blast intro: diff_mult_distrib2 [symmetric])
  1664 
  1665 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1666   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1667   apply (blast intro: dvd_add)
  1668   done
  1669 
  1670 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1671 by (drule_tac m = m in dvd_diff_nat, auto)
  1672 
  1673 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1674   apply (rule iffI)
  1675    apply (erule_tac [2] dvd_add)
  1676    apply (rule_tac [2] dvd_refl)
  1677   apply (subgoal_tac "n = (n+k) -k")
  1678    prefer 2 apply simp
  1679   apply (erule ssubst)
  1680   apply (erule dvd_diff_nat)
  1681   apply (rule dvd_refl)
  1682   done
  1683 
  1684 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1685   unfolding dvd_def
  1686   apply (erule exE)
  1687   apply (simp add: mult_ac)
  1688   done
  1689 
  1690 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1691   apply auto
  1692    apply (subgoal_tac "m*n dvd m*1")
  1693    apply (drule dvd_mult_cancel, auto)
  1694   done
  1695 
  1696 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1697   apply (subst mult_commute)
  1698   apply (erule dvd_mult_cancel1)
  1699   done
  1700 
  1701 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1702 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1703 
  1704 lemma nat_dvd_not_less:
  1705   fixes m n :: nat
  1706   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1707 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1708 
  1709 
  1710 subsection {* size of a datatype value *}
  1711 
  1712 class size =
  1713   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1714 
  1715 
  1716 subsection {* code module namespace *}
  1717 
  1718 code_modulename SML
  1719   Nat Arith
  1720 
  1721 code_modulename OCaml
  1722   Nat Arith
  1723 
  1724 code_modulename Haskell
  1725   Nat Arith
  1726 
  1727 end