src/Pure/library.ML
author paulson
Mon Oct 10 15:35:29 2005 +0200 (2005-10-10)
changeset 17819 1241e5d31d5b
parent 17756 d4a35f82fbb4
child 17822 3830b0a41d51
permissions -rw-r--r--
small tidy-up of utility functions
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    12 infix 2 ?;
    13 infix 3 o oo ooo oooo;
    14 
    15 infix 4 ~~ upto downto;
    16 infix orf andf prefix \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string;
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |> : 'a * ('a -> 'b) -> 'b
    27   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    28   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    29   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    30   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    31   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    32   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    33   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    34   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    35   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    36   val tap: ('b -> 'a) -> 'b -> 'b
    37   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    38   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    39   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    40   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    41 
    42   (*old options -- invalidated*)
    43   datatype invalid = None of invalid
    44   exception OPTION of invalid
    45 
    46   (*options*)
    47   val the: 'a option -> 'a
    48   val these: 'a list option -> 'a list
    49   val the_default: 'a -> 'a option -> 'a
    50   val the_list: 'a option -> 'a list
    51   val if_none: 'a option -> 'a -> 'a
    52   val is_some: 'a option -> bool
    53   val is_none: 'a option -> bool
    54 
    55   exception EXCEPTION of exn * string
    56   exception ERROR
    57   val try: ('a -> 'b) -> 'a -> 'b option
    58   val can: ('a -> 'b) -> 'a -> bool
    59   datatype 'a result = Result of 'a | Exn of exn
    60   val capture: ('a -> 'b) -> 'a -> 'b result
    61   val release: 'a result -> 'a
    62   val get_result: 'a result -> 'a option
    63   val get_exn: 'a result -> exn option
    64 
    65   (*pairs*)
    66   val pair: 'a -> 'b -> 'a * 'b
    67   val rpair: 'a -> 'b -> 'b * 'a
    68   val fst: 'a * 'b -> 'a
    69   val snd: 'a * 'b -> 'b
    70   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    71   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    72   val swap: 'a * 'b -> 'b * 'a
    73   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    74   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    75   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    76 
    77   (*booleans*)
    78   val equal: ''a -> ''a -> bool
    79   val not_equal: ''a -> ''a -> bool
    80   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    81   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    82   val exists: ('a -> bool) -> 'a list -> bool
    83   val forall: ('a -> bool) -> 'a list -> bool
    84   val set: bool ref -> bool
    85   val reset: bool ref -> bool
    86   val toggle: bool ref -> bool
    87   val change: 'a ref -> ('a -> 'a) -> unit
    88   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    89   val conditional: bool -> (unit -> unit) -> unit
    90 
    91   (*lists*)
    92   exception UnequalLengths
    93   val cons: 'a -> 'a list -> 'a list
    94   val single: 'a -> 'a list
    95   val append: 'a list -> 'a list -> 'a list
    96   val apply: ('a -> 'a) list -> 'a -> 'a
    97   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   100   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   101   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   102   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
   103   val unflat: 'a list list -> 'b list -> 'b list list
   104   val splitAt: int * 'a list -> 'a list * 'a list
   105   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   106   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
   107   val split_last: 'a list -> 'a list * 'a
   108   val nth_update: 'a -> int * 'a list -> 'a list
   109   val find_index: ('a -> bool) -> 'a list -> int
   110   val find_index_eq: ''a -> ''a list -> int
   111   val find_first: ('a -> bool) -> 'a list -> 'a option
   112   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   113   val separate: 'a -> 'a list -> 'a list
   114   val replicate: int -> 'a -> 'a list
   115   val multiply: 'a list * 'a list list -> 'a list list
   116   val product: 'a list -> 'b list -> ('a * 'b) list
   117   val filter: ('a -> bool) -> 'a list -> 'a list
   118   val filter_out: ('a -> bool) -> 'a list -> 'a list
   119   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   120   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   121   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   122   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   123   val ~~ : 'a list * 'b list -> ('a * 'b) list
   124   val split_list: ('a * 'b) list -> 'a list * 'b list
   125   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   126   val prefix: ''a list * ''a list -> bool
   127   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   128   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   129   val prefixes1: 'a list -> 'a list list
   130   val suffixes1: 'a list -> 'a list list
   131 
   132   (*integers*)
   133   val gcd: IntInf.int * IntInf.int -> IntInf.int
   134   val lcm: IntInf.int * IntInf.int -> IntInf.int
   135   val inc: int ref -> int
   136   val dec: int ref -> int
   137   val upto: int * int -> int list
   138   val downto: int * int -> int list
   139   val downto0: int list * int -> bool
   140   val radixpand: int * int -> int list
   141   val radixstring: int * string * int -> string
   142   val string_of_int: int -> string
   143   val string_of_indexname: string * int -> string
   144   val read_radixint: int * string list -> int * string list
   145   val read_int: string list -> int * string list
   146   val oct_char: string -> string
   147 
   148   (*rational numbers*)
   149   type rat
   150   exception RAT of string
   151   val rep_rat: rat -> IntInf.int * IntInf.int
   152   val ratge0: rat -> bool
   153   val ratgt0: rat -> bool
   154   val ratle: rat * rat -> bool
   155   val ratlt: rat * rat -> bool
   156   val ratadd: rat * rat -> rat
   157   val ratmul: rat * rat -> rat
   158   val ratinv: rat -> rat
   159   val int_ratdiv: IntInf.int * IntInf.int -> rat
   160   val ratneg: rat -> rat
   161   val rat_of_int: int -> rat
   162   val rat_of_intinf: IntInf.int -> rat
   163   val rat0: rat
   164 
   165   (*strings*)
   166   val nth_elem_string: int * string -> string
   167   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   168   val exists_string: (string -> bool) -> string -> bool
   169   val forall_string: (string -> bool) -> string -> bool
   170   val enclose: string -> string -> string -> string
   171   val unenclose: string -> string
   172   val quote: string -> string
   173   val space_implode: string -> string list -> string
   174   val commas: string list -> string
   175   val commas_quote: string list -> string
   176   val cat_lines: string list -> string
   177   val space_explode: string -> string -> string list
   178   val split_lines: string -> string list
   179   val prefix_lines: string -> string -> string
   180   val untabify: string list -> string list
   181   val suffix: string -> string -> string
   182   val unsuffix: string -> string -> string
   183   val unprefix: string -> string -> string
   184   val replicate_string: int -> string -> string
   185   val translate_string: (string -> string) -> string -> string
   186 
   187   (*lists as sets -- see also Pure/General/ord_list.ML*)
   188   val mem: ''a * ''a list -> bool
   189   val mem_int: int * int list -> bool
   190   val mem_string: string * string list -> bool
   191   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   192   val ins: ''a * ''a list -> ''a list
   193   val ins_int: int * int list -> int list
   194   val ins_string: string * string list -> string list
   195   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   196   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   197   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   198   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   199   val union: ''a list * ''a list -> ''a list
   200   val union_int: int list * int list -> int list
   201   val union_string: string list * string list -> string list
   202   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   203   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   204   val inter: ''a list * ''a list -> ''a list
   205   val inter_int: int list * int list -> int list
   206   val inter_string: string list * string list -> string list
   207   val subset: ''a list * ''a list -> bool
   208   val subset_int: int list * int list -> bool
   209   val subset_string: string list * string list -> bool
   210   val eq_set: ''a list * ''a list -> bool
   211   val eq_set_string: string list * string list -> bool
   212   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   213   val \ : ''a list * ''a -> ''a list
   214   val \\ : ''a list * ''a list -> ''a list
   215   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   216   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   217   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   218   val distinct: ''a list -> ''a list
   219   val findrep: ''a list -> ''a list
   220   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   221   val duplicates: ''a list -> ''a list
   222   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   223 
   224   (*lists as tables -- see also Pure/General/alist.ML*)
   225   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   226   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   227   val merge_lists: ''a list -> ''a list -> ''a list
   228   val merge_lists': ''a list -> ''a list -> ''a list
   229   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   230   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   231 
   232   (*balanced trees*)
   233   exception Balance
   234   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   235   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   236   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   237 
   238   (*orders*)
   239   val rev_order: order -> order
   240   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   241   val int_ord: int * int -> order
   242   val string_ord: string * string -> order
   243   val fast_string_ord: string * string -> order
   244   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   245   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   246   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   247   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   248   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   249   val sort_strings: string list -> string list
   250   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   251   val unique_strings: string list -> string list
   252 
   253   (*random numbers*)
   254   exception RANDOM
   255   val random: unit -> real
   256   val random_range: int -> int -> int
   257   val one_of: 'a list -> 'a
   258   val frequency: (int * 'a) list -> 'a
   259 
   260   (*current directory*)
   261   val cd: string -> unit
   262   val pwd: unit -> string
   263 
   264   (*misc*)
   265   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   266   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   267   val gensym: string -> string
   268   val scanwords: (string -> bool) -> string list -> string list
   269   val string_of_pid: Posix.Process.pid -> string
   270   type stamp
   271   val stamp: unit -> stamp
   272   type serial
   273   val serial: unit -> serial
   274   structure Object: sig type T end
   275 end;
   276 
   277 signature LIBRARY =
   278 sig
   279   include BASIC_LIBRARY
   280   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   281   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   282   val take: int * 'a list -> 'a list
   283   val drop: int * 'a list -> 'a list
   284   val nth_elem: int * 'a list -> 'a
   285   val last_elem: 'a list -> 'a
   286   val flat: 'a list list -> 'a list
   287   val seq: ('a -> unit) -> 'a list -> unit
   288   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   289   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   290 end;
   291 
   292 structure Library: LIBRARY =
   293 struct
   294 
   295 
   296 (** functions **)
   297 
   298 fun I x = x;
   299 fun K x = fn _ => x;
   300 fun curry f x y = f (x, y);
   301 fun uncurry f (x, y) = f x y;
   302 
   303 (*reverse application and structured results*)
   304 fun x |> f = f x;
   305 fun (x, y) |-> f = f x y;
   306 fun (x, y) |>> f = (f x, y);
   307 fun (x, y) ||> f = (x, f y);
   308 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   309 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   310 
   311 (*reverse composition*)
   312 fun f #> g = g o f;
   313 fun f #-> g = uncurry g o f;
   314 
   315 (*conditional application*)
   316 fun b ? f = fn x => if b x then f x else x;
   317 
   318 (*view results*)
   319 fun `f = fn x => (f x, x);
   320 fun tap f = fn x => (f x; x);
   321 
   322 (*composition with multiple args*)
   323 fun (f oo g) x y = f (g x y);
   324 fun (f ooo g) x y z = f (g x y z);
   325 fun (f oooo g) x y z w = f (g x y z w);
   326 
   327 (*function exponentiation: f(...(f x)...) with n applications of f*)
   328 fun funpow n f x =
   329   let fun rep (0, x) = x
   330         | rep (n, x) = rep (n - 1, f x)
   331   in rep (n, x) end;
   332 
   333 
   334 (** options **)
   335 
   336 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   337 datatype invalid = None of invalid;
   338 exception OPTION of invalid;
   339 
   340 val the = Option.valOf;
   341 
   342 fun these (SOME x) = x
   343   | these _ = [];
   344 
   345 fun the_default x (SOME y) = y
   346   | the_default x _ = x;
   347 
   348 fun the_list (SOME x) = [x]
   349   | the_list _ = []
   350 
   351 (*strict!*)
   352 fun if_none NONE y = y
   353   | if_none (SOME x) _ = x;
   354 
   355 fun is_some (SOME _) = true
   356   | is_some NONE = false;
   357 
   358 fun is_none (SOME _) = false
   359   | is_none NONE = true;
   360 
   361 
   362 (* exceptions *)
   363 
   364 exception EXCEPTION of exn * string;
   365 
   366 exception ERROR;
   367 
   368 fun try f x = SOME (f x)
   369   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   370 
   371 fun can f x = is_some (try f x);
   372 
   373 
   374 datatype 'a result =
   375   Result of 'a |
   376   Exn of exn;
   377 
   378 fun capture f x = Result (f x) handle e => Exn e;
   379 
   380 fun release (Result y) = y
   381   | release (Exn e) = raise e;
   382 
   383 fun get_result (Result x) = SOME x
   384   | get_result _ = NONE;
   385 
   386 fun get_exn (Exn exn) = SOME exn
   387   | get_exn _ = NONE;
   388 
   389 
   390 
   391 (** pairs **)
   392 
   393 fun pair x y = (x, y);
   394 fun rpair x y = (y, x);
   395 
   396 fun fst (x, y) = x;
   397 fun snd (x, y) = y;
   398 
   399 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   400 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   401 
   402 fun swap (x, y) = (y, x);
   403 
   404 (*apply function to components*)
   405 fun apfst f (x, y) = (f x, y);
   406 fun apsnd f (x, y) = (x, f y);
   407 fun pairself f (x, y) = (f x, f y);
   408 
   409 
   410 
   411 (** booleans **)
   412 
   413 (* equality *)
   414 
   415 fun equal x y = x = y;
   416 fun not_equal x y = x <> y;
   417 
   418 
   419 (* operators for combining predicates *)
   420 
   421 fun p orf q = fn x => p x orelse q x;
   422 fun p andf q = fn x => p x andalso q x;
   423 
   424 
   425 (* predicates on lists *)
   426 
   427 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   428 fun exists (pred: 'a -> bool) : 'a list -> bool =
   429   let fun boolf [] = false
   430         | boolf (x :: xs) = pred x orelse boolf xs
   431   in boolf end;
   432 
   433 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   434 fun forall (pred: 'a -> bool) : 'a list -> bool =
   435   let fun boolf [] = true
   436         | boolf (x :: xs) = pred x andalso boolf xs
   437   in boolf end;
   438 
   439 
   440 (* flags *)
   441 
   442 fun set flag = (flag := true; true);
   443 fun reset flag = (flag := false; false);
   444 fun toggle flag = (flag := not (! flag); ! flag);
   445 
   446 fun change r f = r := f (! r);
   447 
   448 (*temporarily set flag, handling exceptions*)
   449 fun setmp flag value f x =
   450   let
   451     val orig_value = ! flag;
   452     fun return y = (flag := orig_value; y);
   453   in
   454     flag := value;
   455     return (f x handle exn => (return (); raise exn))
   456   end;
   457 
   458 
   459 (* conditional execution *)
   460 
   461 fun conditional b f = if b then f () else ();
   462 
   463 
   464 
   465 (** lists **)
   466 
   467 exception UnequalLengths;
   468 
   469 fun cons x xs = x :: xs;
   470 fun single x = [x];
   471 
   472 fun append xs ys = xs @ ys;
   473 
   474 fun apply [] x = x
   475   | apply (f :: fs) x = apply fs (f x);
   476 
   477 
   478 (* fold *)
   479 
   480 fun fold f =
   481   let
   482     fun fold_aux [] y = y
   483       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   484   in fold_aux end;
   485 
   486 fun fold_rev f =
   487   let
   488     fun fold_aux [] y = y
   489       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   490   in fold_aux end;
   491 
   492 fun fold_map f =
   493   let
   494     fun fold_aux [] y = ([], y)
   495       | fold_aux (x :: xs) y =
   496           let
   497             val (x', y') = f x y;
   498             val (xs', y'') = fold_aux xs y';
   499           in (x' :: xs', y'') end;
   500   in fold_aux end;
   501 
   502 (*the following versions of fold are designed to fit nicely with infixes*)
   503 
   504 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   505     for operators that associate to the left (TAIL RECURSIVE)*)
   506 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   507   let fun itl (e, [])  = e
   508         | itl (e, a::l) = itl (f(e, a), l)
   509   in  itl end;
   510 
   511 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   512     for operators that associate to the right (not tail recursive)*)
   513 fun foldr f (l, e) =
   514   let fun itr [] = e
   515         | itr (a::l) = f(a, itr l)
   516   in  itr l  end;
   517 
   518 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   519     for n > 0, operators that associate to the right (not tail recursive)*)
   520 fun foldr1 f l =
   521   let fun itr [x] = x
   522         | itr (x::l) = f(x, itr l)
   523   in  itr l  end;
   524 
   525 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   526 
   527 fun foldl_map f =
   528   let
   529     fun fold_aux (x, []) = (x, [])
   530       | fold_aux (x, y :: ys) =
   531           let
   532             val (x', y') = f (x, y);
   533             val (x'', ys') = fold_aux (x', ys);
   534           in (x'', y' :: ys') end;
   535   in fold_aux end;
   536 
   537 
   538 (* basic list functions *)
   539 
   540 (*take the first n elements from a list*)
   541 fun take (n, []) = []
   542   | take (n, x :: xs) =
   543       if n > 0 then x :: take (n - 1, xs) else [];
   544 
   545 (*drop the first n elements from a list*)
   546 fun drop (n, []) = []
   547   | drop (n, x :: xs) =
   548       if n > 0 then drop (n - 1, xs) else x :: xs;
   549 
   550 fun splitAt(n,[]) = ([],[])
   551   | splitAt(n,xs as x::ys) =
   552       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   553       else ([],xs)
   554 
   555 fun dropwhile P [] = []
   556   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   557 
   558 (*return nth element of a list, where 0 designates the first element;
   559   raise EXCEPTION if list too short*)
   560 fun nth_elem (i,xs) = List.nth(xs,i);
   561 
   562 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   563   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   564   | map_nth_elem _ _ [] = raise Subscript;
   565 
   566 (*last element of a list*)
   567 val last_elem = List.last;
   568 
   569 (*rear decomposition*)
   570 fun split_last [] = raise Empty
   571   | split_last [x] = ([], x)
   572   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   573 
   574 (*update nth element*)
   575 fun nth_update x n_xs =
   576     (case splitAt n_xs of
   577       (_,[]) => raise Subscript
   578     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   579 
   580 (*find the position of an element in a list*)
   581 fun find_index pred =
   582   let fun find _ [] = ~1
   583         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   584   in find 0 end;
   585 
   586 fun find_index_eq x = find_index (equal x);
   587 
   588 (*find first element satisfying predicate*)
   589 fun find_first _ [] = NONE
   590   | find_first pred (x :: xs) =
   591       if pred x then SOME x else find_first pred xs;
   592 
   593 (*get first element by lookup function*)
   594 fun get_first _ [] = NONE
   595   | get_first f (x :: xs) =
   596       (case f x of
   597         NONE => get_first f xs
   598       | some => some);
   599 
   600 (*flatten a list of lists to a list*)
   601 val flat = List.concat;
   602 
   603 fun unflat (xs :: xss) ys =
   604       let val (ps,qs) = splitAt(length xs,ys)
   605       in ps :: unflat xss qs end
   606   | unflat [] [] = []
   607   | unflat _ _ = raise UnequalLengths;
   608 
   609 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   610   (proc x1; ...; proc xn) for side effects*)
   611 val seq = List.app;
   612 
   613 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   614 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   615   | separate _ xs = xs;
   616 
   617 (*make the list [x, x, ..., x] of length n*)
   618 fun replicate n (x: 'a) : 'a list =
   619   let fun rep (0, xs) = xs
   620         | rep (n, xs) = rep (n - 1, x :: xs)
   621   in
   622     if n < 0 then raise Subscript
   623     else rep (n, [])
   624   end;
   625 
   626 fun translate_string f = String.translate (f o String.str);
   627 
   628 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   629 fun multiply ([], _) = []
   630   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   631 
   632 (*direct product*)
   633 fun product _ [] = []
   634   | product [] _ = []
   635   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   636 
   637 
   638 (* filter *)
   639 
   640 (*copy the list preserving elements that satisfy the predicate*)
   641 val filter = List.filter;
   642 fun filter_out f = filter (not o f);
   643 val mapfilter = List.mapPartial;
   644 
   645 
   646 (* lists of pairs *)
   647 
   648 exception UnequalLengths;
   649 
   650 fun map2 _ ([], []) = []
   651   | map2 f (x :: xs, y :: ys) = f (x, y) :: map2 f (xs, ys)
   652   | map2 _ _ = raise UnequalLengths;
   653 
   654 fun exists2 _ ([], []) = false
   655   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   656   | exists2 _ _ = raise UnequalLengths;
   657 
   658 fun forall2 _ ([], []) = true
   659   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   660   | forall2 _ _ = raise UnequalLengths;
   661 
   662 fun seq2 _ ([], []) = ()
   663   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   664   | seq2 _ _ = raise UnequalLengths;
   665 
   666 (*combine two lists forming a list of pairs:
   667   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   668 fun [] ~~ [] = []
   669   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   670   | _ ~~ _ = raise UnequalLengths;
   671 
   672 (*inverse of ~~; the old 'split':
   673   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   674 val split_list = ListPair.unzip;
   675 
   676 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   677 
   678 
   679 (* prefixes, suffixes *)
   680 
   681 fun [] prefix _ = true
   682   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   683   | _ prefix _ = false;
   684 
   685 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   686    where xi is the first element that does not satisfy the predicate*)
   687 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   688   let fun take (rxs, []) = (rev rxs, [])
   689         | take (rxs, x :: xs) =
   690             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   691   in  take([], xs)  end;
   692 
   693 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   694    where xi is the last element that does not satisfy the predicate*)
   695 fun take_suffix _ [] = ([], [])
   696   | take_suffix pred (x :: xs) =
   697       (case take_suffix pred xs of
   698         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   699       | (prfx, sffx) => (x :: prfx, sffx));
   700 
   701 fun prefixes1 [] = []
   702   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   703 
   704 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   705 
   706 
   707 
   708 (** integers **)
   709 
   710 fun gcd (x, y) =
   711   let fun gxd x y : IntInf.int =
   712     if y = 0 then x else gxd y (x mod y)
   713   in if x < y then gxd y x else gxd x y end;
   714 
   715 fun lcm (x, y) = (x * y) div gcd (x, y);
   716 
   717 fun inc i = (i := ! i + 1; ! i);
   718 fun dec i = (i := ! i - 1; ! i);
   719 
   720 
   721 (* lists of integers *)
   722 
   723 (*make the list [from, from + 1, ..., to]*)
   724 fun (from upto to) =
   725   if from > to then [] else from :: ((from + 1) upto to);
   726 
   727 (*make the list [from, from - 1, ..., to]*)
   728 fun (from downto to) =
   729   if from < to then [] else from :: ((from - 1) downto to);
   730 
   731 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   732 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   733   | downto0 ([], n) = n = ~1;
   734 
   735 
   736 (* convert integers to strings *)
   737 
   738 (*expand the number in the given base;
   739   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   740 fun radixpand (base, num) : int list =
   741   let
   742     fun radix (n, tail) =
   743       if n < base then n :: tail
   744       else radix (n div base, (n mod base) :: tail)
   745   in radix (num, []) end;
   746 
   747 (*expands a number into a string of characters starting from "zerochar";
   748   example: radixstring (2, "0", 8) gives "1000"*)
   749 fun radixstring (base, zerochar, num) =
   750   let val offset = ord zerochar;
   751       fun chrof n = chr (offset + n)
   752   in implode (map chrof (radixpand (base, num))) end;
   753 
   754 
   755 val string_of_int = Int.toString;
   756 
   757 fun string_of_indexname (a,0) = a
   758   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   759 
   760 
   761 (* read integers *)
   762 
   763 fun read_radixint (radix: int, cs) : int * string list =
   764   let val zero = ord"0"
   765       val limit = zero+radix
   766       fun scan (num,[]) = (num,[])
   767         | scan (num, c::cs) =
   768               if  zero <= ord c  andalso  ord c < limit
   769               then scan(radix*num + ord c - zero, cs)
   770               else (num, c::cs)
   771   in  scan(0,cs)  end;
   772 
   773 fun read_int cs = read_radixint (10, cs);
   774 
   775 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   776 
   777 
   778 
   779 (** strings **)
   780 
   781 (* functions tuned for strings, avoiding explode *)
   782 
   783 fun nth_elem_string (i, str) =
   784   (case try String.substring (str, i, 1) of
   785     SOME s => s
   786   | NONE => raise Subscript);
   787 
   788 fun fold_string f str x0 =
   789   let
   790     val n = size str;
   791     fun iter (x, i) =
   792       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   793   in iter (x0, 0) end;
   794 
   795 fun exists_string pred str =
   796   let
   797     val n = size str;
   798     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   799   in ex 0 end;
   800 
   801 fun forall_string pred = not o exists_string (not o pred);
   802 
   803 (*enclose in brackets*)
   804 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   805 fun unenclose str = String.substring (str, 1, size str - 2);
   806 
   807 (*simple quoting (does not escape special chars)*)
   808 val quote = enclose "\"" "\"";
   809 
   810 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   811 fun space_implode a bs = implode (separate a bs);
   812 
   813 val commas = space_implode ", ";
   814 val commas_quote = commas o map quote;
   815 
   816 (*concatenate messages, one per line, into a string*)
   817 val cat_lines = space_implode "\n";
   818 
   819 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   820 fun space_explode _ "" = []
   821   | space_explode sep str =
   822       let
   823         fun expl chs =
   824           (case take_prefix (not_equal sep) chs of
   825             (cs, []) => [implode cs]
   826           | (cs, _ :: cs') => implode cs :: expl cs');
   827       in expl (explode str) end;
   828 
   829 val split_lines = space_explode "\n";
   830 
   831 fun prefix_lines "" txt = txt
   832   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   833 
   834 fun untabify chs =
   835   let
   836     val tab_width = 8;
   837 
   838     fun untab (_, "\n") = (0, ["\n"])
   839       | untab (pos, "\t") =
   840           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   841       | untab (pos, c) = (pos + 1, [c]);
   842   in
   843     if not (exists (equal "\t") chs) then chs
   844     else flat (#2 (foldl_map untab (0, chs)))
   845   end;
   846 
   847 fun suffix sffx s = s ^ sffx;
   848 
   849 fun unsuffix sffx s =
   850   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   851   else raise Fail "unsuffix";
   852 
   853 fun unprefix prfx s =
   854   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   855   else raise Fail "unprefix";
   856 
   857 fun replicate_string 0 _ = ""
   858   | replicate_string 1 a = a
   859   | replicate_string k a =
   860       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   861       else replicate_string (k div 2) (a ^ a) ^ a;
   862 
   863 
   864 
   865 (** lists as sets -- see also Pure/General/ord_list.ML **)
   866 
   867 (*membership in a list*)
   868 fun x mem [] = false
   869   | x mem (y :: ys) = x = y orelse x mem ys;
   870 
   871 (*membership in a list, optimized version for ints*)
   872 fun (x:int) mem_int [] = false
   873   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   874 
   875 (*membership in a list, optimized version for strings*)
   876 fun (x:string) mem_string [] = false
   877   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   878 
   879 (*generalized membership test*)
   880 fun gen_mem eq (x, []) = false
   881   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   882 
   883 (*member, insert, and remove -- with canonical argument order*)
   884 fun member eq xs x = gen_mem eq (x, xs);
   885 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   886 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   887 
   888 (*insertion into list if not already there*)
   889 fun (x ins xs) = if x mem xs then xs else x :: xs;
   890 
   891 (*insertion into list, optimized version for ints*)
   892 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   893 
   894 (*insertion into list, optimized version for strings*)
   895 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   896 
   897 (*generalized insertion*)
   898 fun gen_ins eq (x, xs) = insert eq x xs;
   899 
   900 (*union of sets represented as lists: no repetitions*)
   901 fun xs union [] = xs
   902   | [] union ys = ys
   903   | (x :: xs) union ys = xs union (x ins ys);
   904 
   905 (*union of sets, optimized version for ints*)
   906 fun (xs:int list) union_int [] = xs
   907   | [] union_int ys = ys
   908   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   909 
   910 (*union of sets, optimized version for strings*)
   911 fun (xs:string list) union_string [] = xs
   912   | [] union_string ys = ys
   913   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   914 
   915 (*generalized union*)
   916 fun gen_union eq (xs, []) = xs
   917   | gen_union eq ([], ys) = ys
   918   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   919 
   920 
   921 (*intersection*)
   922 fun [] inter ys = []
   923   | (x :: xs) inter ys =
   924       if x mem ys then x :: (xs inter ys) else xs inter ys;
   925 
   926 (*intersection, optimized version for ints*)
   927 fun ([]:int list) inter_int ys = []
   928   | (x :: xs) inter_int ys =
   929       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   930 
   931 (*intersection, optimized version for strings *)
   932 fun ([]:string list) inter_string ys = []
   933   | (x :: xs) inter_string ys =
   934       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   935 
   936 (*generalized intersection*)
   937 fun gen_inter eq ([], ys) = []
   938   | gen_inter eq (x::xs, ys) =
   939       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   940                            else      gen_inter eq (xs, ys);
   941 
   942 
   943 (*subset*)
   944 fun [] subset ys = true
   945   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   946 
   947 (*subset, optimized version for ints*)
   948 fun ([]: int list) subset_int ys = true
   949   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   950 
   951 (*subset, optimized version for strings*)
   952 fun ([]: string list) subset_string ys = true
   953   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   954 
   955 (*set equality*)
   956 fun eq_set (xs, ys) =
   957   xs = ys orelse (xs subset ys andalso ys subset xs);
   958 
   959 (*set equality for strings*)
   960 fun eq_set_string ((xs: string list), ys) =
   961   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   962 
   963 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   964 
   965 
   966 (*removing an element from a list WITHOUT duplicates*)
   967 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   968   | [] \ x = [];
   969 
   970 fun ys \\ xs = foldl (op \) (ys,xs);
   971 
   972 (*removing an element from a list -- possibly WITH duplicates*)
   973 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   974 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   975 
   976 (*makes a list of the distinct members of the input; preserves order, takes
   977   first of equal elements*)
   978 fun gen_distinct eq lst =
   979   let
   980     val memb = gen_mem eq;
   981 
   982     fun dist (rev_seen, []) = rev rev_seen
   983       | dist (rev_seen, x :: xs) =
   984           if memb (x, rev_seen) then dist (rev_seen, xs)
   985           else dist (x :: rev_seen, xs);
   986   in
   987     dist ([], lst)
   988   end;
   989 
   990 fun distinct l = gen_distinct (op =) l;
   991 
   992 (*returns the tail beginning with the first repeated element, or []*)
   993 fun findrep [] = []
   994   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   995 
   996 
   997 (*returns a list containing all repeated elements exactly once; preserves
   998   order, takes first of equal elements*)
   999 fun gen_duplicates eq lst =
  1000   let
  1001     val memb = gen_mem eq;
  1002 
  1003     fun dups (rev_dups, []) = rev rev_dups
  1004       | dups (rev_dups, x :: xs) =
  1005           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1006             dups (rev_dups, xs)
  1007           else dups (x :: rev_dups, xs);
  1008   in
  1009     dups ([], lst)
  1010   end;
  1011 
  1012 fun duplicates l = gen_duplicates (op =) l;
  1013 
  1014 fun has_duplicates eq =
  1015   let
  1016     fun dups [] = false
  1017       | dups (x :: xs) = member eq xs x orelse dups xs;
  1018   in dups end;
  1019 
  1020 
  1021 
  1022 (** association lists **)
  1023 
  1024 (* lists as tables *)
  1025 
  1026 fun gen_merge_lists _ xs [] = xs
  1027   | gen_merge_lists _ [] ys = ys
  1028   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1029 
  1030 fun gen_merge_lists' _ xs [] = xs
  1031   | gen_merge_lists' _ [] ys = ys
  1032   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1033 
  1034 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1035 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1036 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1037 fun merge_alists' al = gen_merge_lists' (eq_fst (op =)) al;
  1038 
  1039 
  1040 
  1041 (** balanced trees **)
  1042 
  1043 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1044 
  1045 (*balanced folding; avoids deep nesting*)
  1046 fun fold_bal f [x] = x
  1047   | fold_bal f [] = raise Balance
  1048   | fold_bal f xs =
  1049       let val (ps,qs) = splitAt(length xs div 2, xs)
  1050       in  f (fold_bal f ps, fold_bal f qs)  end;
  1051 
  1052 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1053 fun access_bal (f, g, x) n i =
  1054   let fun acc n i =     (*1<=i<=n*)
  1055           if n=1 then x else
  1056           let val n2 = n div 2
  1057           in  if i<=n2 then f (acc n2 i)
  1058                        else g (acc (n-n2) (i-n2))
  1059           end
  1060   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1061 
  1062 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1063 fun accesses_bal (f, g, x) n =
  1064   let fun acc n =
  1065           if n=1 then [x] else
  1066           let val n2 = n div 2
  1067               val acc2 = acc n2
  1068           in  if n-n2=n2 then map f acc2 @ map g acc2
  1069                          else map f acc2 @ map g (acc (n-n2)) end
  1070   in  if 1<=n then acc n else raise Balance  end;
  1071 
  1072 
  1073 
  1074 (** orders **)
  1075 
  1076 fun rev_order LESS = GREATER
  1077   | rev_order EQUAL = EQUAL
  1078   | rev_order GREATER = LESS;
  1079 
  1080 (*assume rel is a linear strict order*)
  1081 fun make_ord rel (x, y) =
  1082   if rel (x, y) then LESS
  1083   else if rel (y, x) then GREATER
  1084   else EQUAL;
  1085 
  1086 val int_ord = Int.compare;
  1087 val string_ord = String.compare;
  1088 
  1089 fun fast_string_ord (s1, s2) =
  1090   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1091 
  1092 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1093   | option_ord _ (NONE, NONE) = EQUAL
  1094   | option_ord _ (NONE, SOME _) = LESS
  1095   | option_ord _ (SOME _, NONE) = GREATER;
  1096 
  1097 (*lexicographic product*)
  1098 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1099   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1100 
  1101 (*dictionary order -- in general NOT well-founded!*)
  1102 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1103       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1104   | dict_ord _ ([], []) = EQUAL
  1105   | dict_ord _ ([], _ :: _) = LESS
  1106   | dict_ord _ (_ :: _, []) = GREATER;
  1107 
  1108 (*lexicographic product of lists*)
  1109 fun list_ord elem_ord (xs, ys) =
  1110   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1111 
  1112 
  1113 (* sorting *)
  1114 
  1115 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1116 fun sort ord =
  1117   let
  1118     fun qsort [] = []
  1119       | qsort (xs as [_]) = xs
  1120       | qsort (xs as [x, y]) = if ord (x, y) = GREATER then [y, x] else xs
  1121       | qsort xs =
  1122           let val (lts, eqs, gts) = part (nth_elem (length xs div 2, xs)) xs
  1123           in qsort lts @ eqs @ qsort gts end
  1124     and part _ [] = ([], [], [])
  1125       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1126     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1127       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1128       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1129   in qsort end;
  1130 
  1131 (*sort strings*)
  1132 val sort_strings = sort string_ord;
  1133 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1134 
  1135 fun unique_strings ([]: string list) = []
  1136   | unique_strings [x] = [x]
  1137   | unique_strings (x :: y :: ys) =
  1138       if x = y then unique_strings (y :: ys)
  1139       else x :: unique_strings (y :: ys);
  1140 
  1141 
  1142 (** random numbers **)
  1143 
  1144 exception RANDOM;
  1145 
  1146 fun rmod x y = x - y * Real.realFloor (x / y);
  1147 
  1148 local
  1149   val a = 16807.0;
  1150   val m = 2147483647.0;
  1151   val random_seed = ref 1.0;
  1152 in
  1153 
  1154 fun random () =
  1155   let val r = rmod (a * !random_seed) m
  1156   in (random_seed := r; r) end;
  1157 
  1158 end;
  1159 
  1160 fun random_range l h =
  1161   if h < l orelse l < 0 then raise RANDOM
  1162   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1163 
  1164 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1165 
  1166 fun frequency xs =
  1167   let
  1168     val sum = foldl op + (0, map fst xs);
  1169     fun pick n ((k: int, x) :: xs) =
  1170       if n <= k then x else pick (n - k) xs
  1171   in pick (random_range 1 sum) xs end;
  1172 
  1173 
  1174 (** current directory **)
  1175 
  1176 val cd = OS.FileSys.chDir;
  1177 val pwd = OS.FileSys.getDir;
  1178 
  1179 
  1180 
  1181 (** rational numbers **)
  1182 (* Keep them normalized! *)
  1183 
  1184 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1185 
  1186 exception RAT of string;
  1187 
  1188 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1189 
  1190 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1191   let val absp = abs p
  1192       val m = gcd(absp,q)
  1193   in Rat(a = (0 <= p), absp div m, q div m) end;
  1194 
  1195 fun ratcommon(p,q,r,s) =
  1196   let val den = lcm(q,s)
  1197   in (p*(den div q), r*(den div s), den) end
  1198 
  1199 fun ratge0(Rat(a,p,q)) = a;
  1200 fun ratgt0(Rat(a,p,q)) = a andalso p > 0;
  1201 
  1202 fun ratle(Rat(a,p,q),Rat(b,r,s)) =
  1203   not a andalso b orelse
  1204   a = b andalso
  1205     let val (p,r,_) = ratcommon(p,q,r,s)
  1206     in if a then p <= r else r <= p end
  1207 
  1208 fun ratlt(Rat(a,p,q),Rat(b,r,s)) =
  1209   not a andalso b orelse
  1210   a = b andalso
  1211     let val (p,r,_) = ratcommon(p,q,r,s)
  1212     in if a then p < r else r < p end
  1213 
  1214 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1215   let val (p,r,den) = ratcommon(p,q,r,s)
  1216       val num = (if a then p else ~p) + (if b then r else ~r)
  1217   in ratnorm(true,num,den) end;
  1218 
  1219 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1220 
  1221 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1222 
  1223 fun int_ratdiv(p,q) =
  1224   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1225 
  1226 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1227 
  1228 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1229 
  1230 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1231 
  1232 val rat0 = rat_of_int 0;
  1233 
  1234 
  1235 (** misc **)
  1236 
  1237 (*Partition list into elements that satisfy predicate and those that don't.
  1238   Preserves order of elements in both lists.*)
  1239 val partition = List.partition;
  1240 
  1241 fun partition_eq (eq:'a * 'a -> bool) =
  1242   let
  1243     fun part [] = []
  1244       | part (x :: ys) =
  1245           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1246           in (x::xs)::(part xs') end
  1247   in part end;
  1248 
  1249 
  1250 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1251    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1252 fun partition_list p i j =
  1253   let fun part k xs =
  1254             if k>j then
  1255               (case xs of [] => []
  1256                          | _ => raise Fail "partition_list")
  1257             else
  1258             let val (ns, rest) = partition (p k) xs;
  1259             in  ns :: part(k+1)rest  end
  1260   in  part i end;
  1261 
  1262 
  1263 (* generating identifiers *)
  1264 
  1265 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1266 local
  1267 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1268 fun char i =      if i<26 then chr (ord "A" + i)
  1269              else if i<52 then chr (ord "a" + i - 26)
  1270              else if i<62 then chr (ord"0" + i - 52)
  1271              else if i=62 then "_"
  1272              else  (*i=63*)    "'";
  1273 
  1274 val charVec = Vector.tabulate (64, char);
  1275 
  1276 fun newid n =
  1277   let
  1278   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1279 
  1280 val seedr = ref 0;
  1281 
  1282 in
  1283 
  1284 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1285 
  1286 end;
  1287 
  1288 (*Convert a process ID to a decimal string (chiefly for tracing)*)
  1289 fun string_of_pid pid = 
  1290     Word.fmt StringCvt.DEC (Word.fromLargeWord (Posix.Process.pidToWord pid));
  1291 
  1292 
  1293 (* lexical scanning *)
  1294 
  1295 (*scan a list of characters into "words" composed of "letters" (recognized by
  1296   is_let) and separated by any number of non-"letters"*)
  1297 fun scanwords is_let cs =
  1298   let fun scan1 [] = []
  1299         | scan1 cs =
  1300             let val (lets, rest) = take_prefix is_let cs
  1301             in implode lets :: scanwords is_let rest end;
  1302   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1303 
  1304 
  1305 (* stamps and serial numbers *)
  1306 
  1307 type stamp = unit ref;
  1308 val stamp: unit -> stamp = ref;
  1309 
  1310 type serial = int;
  1311 local val count = ref 0
  1312 in fun serial () = inc count end;
  1313 
  1314 
  1315 (* generic objects *)
  1316 
  1317 (*note that the builtin exception datatype may be extended by new
  1318   constructors at any time*)
  1319 structure Object = struct type T = exn end;
  1320 
  1321 end;
  1322 
  1323 structure BasicLibrary: BASIC_LIBRARY = Library;
  1324 open BasicLibrary;