src/HOL/Library/Float.thy
author bulwahn
Fri Apr 08 16:31:14 2011 +0200 (2011-04-08)
changeset 42316 12635bb655fd
parent 41528 276078f01ada
child 42676 8724f20bf69c
permissions -rw-r--r--
deactivating other compilations in quickcheck_exhaustive momentarily that only interesting for my benchmarks and experiments
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Steven Obua 2008
     3     Author:     Johannes Hoelzl, TU Muenchen <hoelzl@in.tum.de> 2008 / 2009
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main Lattice_Algebras
    10 begin
    11 
    12 definition
    13   pow2 :: "int \<Rightarrow> real" where
    14   [simp]: "pow2 a = (if (0 <= a) then (2^(nat a)) else (inverse (2^(nat (-a)))))"
    15 
    16 datatype float = Float int int
    17 
    18 primrec of_float :: "float \<Rightarrow> real" where
    19   "of_float (Float a b) = real a * pow2 b"
    20 
    21 defs (overloaded)
    22   real_of_float_def [code_unfold]: "real == of_float"
    23 
    24 declare [[coercion "% x . Float x 0"]]
    25 declare [[coercion "real::float\<Rightarrow>real"]]
    26 
    27 primrec mantissa :: "float \<Rightarrow> int" where
    28   "mantissa (Float a b) = a"
    29 
    30 primrec scale :: "float \<Rightarrow> int" where
    31   "scale (Float a b) = b"
    32 
    33 instantiation float :: zero begin
    34 definition zero_float where "0 = Float 0 0"
    35 instance ..
    36 end
    37 
    38 instantiation float :: one begin
    39 definition one_float where "1 = Float 1 0"
    40 instance ..
    41 end
    42 
    43 instantiation float :: number begin
    44 definition number_of_float where "number_of n = Float n 0"
    45 instance ..
    46 end
    47 
    48 lemma number_of_float_Float [code_unfold_post]:
    49   "number_of k = Float (number_of k) 0"
    50   by (simp add: number_of_float_def number_of_is_id)
    51 
    52 lemma real_of_float_simp[simp]: "real (Float a b) = real a * pow2 b"
    53   unfolding real_of_float_def using of_float.simps .
    54 
    55 lemma real_of_float_neg_exp: "e < 0 \<Longrightarrow> real (Float m e) = real m * inverse (2^nat (-e))" by auto
    56 lemma real_of_float_nge0_exp: "\<not> 0 \<le> e \<Longrightarrow> real (Float m e) = real m * inverse (2^nat (-e))" by auto
    57 lemma real_of_float_ge0_exp: "0 \<le> e \<Longrightarrow> real (Float m e) = real m * (2^nat e)" by auto
    58 
    59 lemma Float_num[simp]: shows
    60    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
    61    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
    62    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
    63   by auto
    64 
    65 lemma float_number_of[simp]: "real (number_of x :: float) = number_of x"
    66   by (simp only:number_of_float_def Float_num[unfolded number_of_is_id])
    67 
    68 lemma float_number_of_int[simp]: "real (Float n 0) = real n"
    69   by simp
    70 
    71 lemma pow2_0[simp]: "pow2 0 = 1" by simp
    72 lemma pow2_1[simp]: "pow2 1 = 2" by simp
    73 lemma pow2_neg: "pow2 x = inverse (pow2 (-x))" by simp
    74 
    75 declare pow2_def[simp del]
    76 
    77 lemma pow2_add1: "pow2 (1 + a) = 2 * (pow2 a)"
    78 proof -
    79   have h: "! n. nat (2 + int n) - Suc 0 = nat (1 + int n)" by arith
    80   have g: "! a b. a - -1 = a + (1::int)" by arith
    81   have pos: "! n. pow2 (int n + 1) = 2 * pow2 (int n)"
    82     apply (auto, induct_tac n)
    83     apply (simp_all add: pow2_def)
    84     apply (rule_tac m1="2" and n1="nat (2 + int na)" in ssubst[OF realpow_num_eq_if])
    85     by (auto simp add: h)
    86   show ?thesis
    87   proof (induct a)
    88     case (1 n)
    89     from pos show ?case by (simp add: algebra_simps)
    90   next
    91     case (2 n)
    92     show ?case
    93       apply (auto)
    94       apply (subst pow2_neg[of "- int n"])
    95       apply (subst pow2_neg[of "-1 - int n"])
    96       apply (auto simp add: g pos)
    97       done
    98   qed
    99 qed
   100 
   101 lemma pow2_add: "pow2 (a+b) = (pow2 a) * (pow2 b)"
   102 proof (induct b)
   103   case (1 n)
   104   show ?case
   105   proof (induct n)
   106     case 0
   107     show ?case by simp
   108   next
   109     case (Suc m)
   110     then show ?case by (auto simp add: algebra_simps pow2_add1)
   111   qed
   112 next
   113   case (2 n)
   114   show ?case
   115   proof (induct n)
   116     case 0
   117     show ?case
   118       apply (auto)
   119       apply (subst pow2_neg[of "a + -1"])
   120       apply (subst pow2_neg[of "-1"])
   121       apply (simp)
   122       apply (insert pow2_add1[of "-a"])
   123       apply (simp add: algebra_simps)
   124       apply (subst pow2_neg[of "-a"])
   125       apply (simp)
   126       done
   127   next
   128     case (Suc m)
   129     have a: "int m - (a + -2) =  1 + (int m - a + 1)" by arith
   130     have b: "int m - -2 = 1 + (int m + 1)" by arith
   131     show ?case
   132       apply (auto)
   133       apply (subst pow2_neg[of "a + (-2 - int m)"])
   134       apply (subst pow2_neg[of "-2 - int m"])
   135       apply (auto simp add: algebra_simps)
   136       apply (subst a)
   137       apply (subst b)
   138       apply (simp only: pow2_add1)
   139       apply (subst pow2_neg[of "int m - a + 1"])
   140       apply (subst pow2_neg[of "int m + 1"])
   141       apply auto
   142       apply (insert Suc)
   143       apply (auto simp add: algebra_simps)
   144       done
   145   qed
   146 qed
   147 
   148 lemma float_components[simp]: "Float (mantissa f) (scale f) = f" by (cases f) auto
   149 
   150 lemma float_split: "\<exists> a b. x = Float a b" by (cases x) auto
   151 
   152 lemma float_split2: "(\<forall> a b. x \<noteq> Float a b) = False" by (auto simp add: float_split)
   153 
   154 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
   155 
   156 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
   157 by arith
   158 
   159 function normfloat :: "float \<Rightarrow> float" where
   160   "normfloat (Float a b) =
   161     (if a \<noteq> 0 \<and> even a then normfloat (Float (a div 2) (b+1))
   162      else if a=0 then Float 0 0 else Float a b)"
   163 by pat_completeness auto
   164 termination by (relation "measure (nat o abs o mantissa)") (auto intro: abs_div_2_less)
   165 declare normfloat.simps[simp del]
   166 
   167 theorem normfloat[symmetric, simp]: "real f = real (normfloat f)"
   168 proof (induct f rule: normfloat.induct)
   169   case (1 a b)
   170   have real2: "2 = real (2::int)"
   171     by auto
   172   show ?case
   173     apply (subst normfloat.simps)
   174     apply auto
   175     apply (subst 1[symmetric])
   176     apply (auto simp add: pow2_add even_def)
   177     done
   178 qed
   179 
   180 lemma pow2_neq_zero[simp]: "pow2 x \<noteq> 0"
   181   by (auto simp add: pow2_def)
   182 
   183 lemma pow2_int: "pow2 (int c) = 2^c"
   184 by (simp add: pow2_def)
   185 
   186 lemma zero_less_pow2[simp]:
   187   "0 < pow2 x"
   188 proof -
   189   {
   190     fix y
   191     have "0 <= y \<Longrightarrow> 0 < pow2 y"
   192       apply (induct y)
   193       apply (induct_tac n)
   194       apply (simp_all add: pow2_add)
   195       done
   196   }
   197   note helper=this
   198   show ?thesis
   199     apply (case_tac "0 <= x")
   200     apply (simp add: helper)
   201     apply (subst pow2_neg)
   202     apply (simp add: helper)
   203     done
   204 qed
   205 
   206 lemma normfloat_imp_odd_or_zero: "normfloat f = Float a b \<Longrightarrow> odd a \<or> (a = 0 \<and> b = 0)"
   207 proof (induct f rule: normfloat.induct)
   208   case (1 u v)
   209   from 1 have ab: "normfloat (Float u v) = Float a b" by auto
   210   {
   211     assume eu: "even u"
   212     assume z: "u \<noteq> 0"
   213     have "normfloat (Float u v) = normfloat (Float (u div 2) (v + 1))"
   214       apply (subst normfloat.simps)
   215       by (simp add: eu z)
   216     with ab have "normfloat (Float (u div 2) (v + 1)) = Float a b" by simp
   217     with 1 eu z have ?case by auto
   218   }
   219   note case1 = this
   220   {
   221     assume "odd u \<or> u = 0"
   222     then have ou: "\<not> (u \<noteq> 0 \<and> even u)" by auto
   223     have "normfloat (Float u v) = (if u = 0 then Float 0 0 else Float u v)"
   224       apply (subst normfloat.simps)
   225       apply (simp add: ou)
   226       done
   227     with ab have "Float a b = (if u = 0 then Float 0 0 else Float u v)" by auto
   228     then have ?case
   229       apply (case_tac "u=0")
   230       apply (auto)
   231       by (insert ou, auto)
   232   }
   233   note case2 = this
   234   show ?case
   235     apply (case_tac "odd u \<or> u = 0")
   236     apply (rule case2)
   237     apply simp
   238     apply (rule case1)
   239     apply auto
   240     done
   241 qed
   242 
   243 lemma float_eq_odd_helper: 
   244   assumes odd: "odd a'"
   245   and floateq: "real (Float a b) = real (Float a' b')"
   246   shows "b \<le> b'"
   247 proof - 
   248   {
   249     assume bcmp: "b > b'"
   250     from floateq have eq: "real a * pow2 b = real a' * pow2 b'" by simp
   251     {
   252       fix x y z :: real
   253       assume "y \<noteq> 0"
   254       then have "(x * inverse y = z) = (x = z * y)"
   255         by auto
   256     }
   257     note inverse = this
   258     have eq': "real a * (pow2 (b - b')) = real a'"
   259       apply (subst diff_int_def)
   260       apply (subst pow2_add)
   261       apply (subst pow2_neg[where x = "-b'"])
   262       apply simp
   263       apply (subst mult_assoc[symmetric])
   264       apply (subst inverse)
   265       apply (simp_all add: eq)
   266       done
   267     have "\<exists> z > 0. pow2 (b-b') = 2^z"
   268       apply (rule exI[where x="nat (b - b')"])
   269       apply (auto)
   270       apply (insert bcmp)
   271       apply simp
   272       apply (subst pow2_int[symmetric])
   273       apply auto
   274       done
   275     then obtain z where z: "z > 0 \<and> pow2 (b-b') = 2^z" by auto
   276     with eq' have "real a * 2^z = real a'"
   277       by auto
   278     then have "real a * real ((2::int)^z) = real a'"
   279       by auto
   280     then have "real (a * 2^z) = real a'"
   281       apply (subst real_of_int_mult)
   282       apply simp
   283       done
   284     then have a'_rep: "a * 2^z = a'" by arith
   285     then have "a' = a*2^z" by simp
   286     with z have "even a'" by simp
   287     with odd have False by auto
   288   }
   289   then show ?thesis by arith
   290 qed
   291 
   292 lemma float_eq_odd: 
   293   assumes odd1: "odd a"
   294   and odd2: "odd a'"
   295   and floateq: "real (Float a b) = real (Float a' b')"
   296   shows "a = a' \<and> b = b'"
   297 proof -
   298   from 
   299      float_eq_odd_helper[OF odd2 floateq] 
   300      float_eq_odd_helper[OF odd1 floateq[symmetric]]
   301   have beq: "b = b'" by arith
   302   with floateq show ?thesis by auto
   303 qed
   304 
   305 theorem normfloat_unique:
   306   assumes real_of_float_eq: "real f = real g"
   307   shows "normfloat f = normfloat g"
   308 proof - 
   309   from float_split[of "normfloat f"] obtain a b where normf:"normfloat f = Float a b" by auto
   310   from float_split[of "normfloat g"] obtain a' b' where normg:"normfloat g = Float a' b'" by auto
   311   have "real (normfloat f) = real (normfloat g)"
   312     by (simp add: real_of_float_eq)
   313   then have float_eq: "real (Float a b) = real (Float a' b')"
   314     by (simp add: normf normg)
   315   have ab: "odd a \<or> (a = 0 \<and> b = 0)" by (rule normfloat_imp_odd_or_zero[OF normf])
   316   have ab': "odd a' \<or> (a' = 0 \<and> b' = 0)" by (rule normfloat_imp_odd_or_zero[OF normg])
   317   {
   318     assume odd: "odd a"
   319     then have "a \<noteq> 0" by (simp add: even_def, arith)
   320     with float_eq have "a' \<noteq> 0" by auto
   321     with ab' have "odd a'" by simp
   322     from odd this float_eq have "a = a' \<and> b = b'" by (rule float_eq_odd)
   323   }
   324   note odd_case = this
   325   {
   326     assume even: "even a"
   327     with ab have a0: "a = 0" by simp
   328     with float_eq have a0': "a' = 0" by auto 
   329     from a0 a0' ab ab' have "a = a' \<and> b = b'" by auto
   330   }
   331   note even_case = this
   332   from odd_case even_case show ?thesis
   333     apply (simp add: normf normg)
   334     apply (case_tac "even a")
   335     apply auto
   336     done
   337 qed
   338 
   339 instantiation float :: plus begin
   340 fun plus_float where
   341 [simp del]: "(Float a_m a_e) + (Float b_m b_e) = 
   342      (if a_e \<le> b_e then Float (a_m + b_m * 2^(nat(b_e - a_e))) a_e 
   343                    else Float (a_m * 2^(nat (a_e - b_e)) + b_m) b_e)"
   344 instance ..
   345 end
   346 
   347 instantiation float :: uminus begin
   348 primrec uminus_float where [simp del]: "uminus_float (Float m e) = Float (-m) e"
   349 instance ..
   350 end
   351 
   352 instantiation float :: minus begin
   353 definition minus_float where [simp del]: "(z::float) - w = z + (- w)"
   354 instance ..
   355 end
   356 
   357 instantiation float :: times begin
   358 fun times_float where [simp del]: "(Float a_m a_e) * (Float b_m b_e) = Float (a_m * b_m) (a_e + b_e)"
   359 instance ..
   360 end
   361 
   362 primrec float_pprt :: "float \<Rightarrow> float" where
   363   "float_pprt (Float a e) = (if 0 <= a then (Float a e) else 0)"
   364 
   365 primrec float_nprt :: "float \<Rightarrow> float" where
   366   "float_nprt (Float a e) = (if 0 <= a then 0 else (Float a e))" 
   367 
   368 instantiation float :: ord begin
   369 definition le_float_def: "z \<le> (w :: float) \<equiv> real z \<le> real w"
   370 definition less_float_def: "z < (w :: float) \<equiv> real z < real w"
   371 instance ..
   372 end
   373 
   374 lemma real_of_float_add[simp]: "real (a + b) = real a + real (b :: float)"
   375   by (cases a, cases b) (simp add: algebra_simps plus_float.simps, 
   376       auto simp add: pow2_int[symmetric] pow2_add[symmetric])
   377 
   378 lemma real_of_float_minus[simp]: "real (- a) = - real (a :: float)"
   379   by (cases a) (simp add: uminus_float.simps)
   380 
   381 lemma real_of_float_sub[simp]: "real (a - b) = real a - real (b :: float)"
   382   by (cases a, cases b) (simp add: minus_float_def)
   383 
   384 lemma real_of_float_mult[simp]: "real (a*b) = real a * real (b :: float)"
   385   by (cases a, cases b) (simp add: times_float.simps pow2_add)
   386 
   387 lemma real_of_float_0[simp]: "real (0 :: float) = 0"
   388   by (auto simp add: zero_float_def float_zero)
   389 
   390 lemma real_of_float_1[simp]: "real (1 :: float) = 1"
   391   by (auto simp add: one_float_def)
   392 
   393 lemma zero_le_float:
   394   "(0 <= real (Float a b)) = (0 <= a)"
   395   apply auto
   396   apply (auto simp add: zero_le_mult_iff)
   397   apply (insert zero_less_pow2[of b])
   398   apply (simp_all)
   399   done
   400 
   401 lemma float_le_zero:
   402   "(real (Float a b) <= 0) = (a <= 0)"
   403   apply auto
   404   apply (auto simp add: mult_le_0_iff)
   405   apply (insert zero_less_pow2[of b])
   406   apply auto
   407   done
   408 
   409 lemma zero_less_float:
   410   "(0 < real (Float a b)) = (0 < a)"
   411   apply auto
   412   apply (auto simp add: zero_less_mult_iff)
   413   apply (insert zero_less_pow2[of b])
   414   apply (simp_all)
   415   done
   416 
   417 lemma float_less_zero:
   418   "(real (Float a b) < 0) = (a < 0)"
   419   apply auto
   420   apply (auto simp add: mult_less_0_iff)
   421   apply (insert zero_less_pow2[of b])
   422   apply (simp_all)
   423   done
   424 
   425 declare real_of_float_simp[simp del]
   426 
   427 lemma real_of_float_pprt[simp]: "real (float_pprt a) = pprt (real a)"
   428   by (cases a) (auto simp add: zero_le_float float_le_zero)
   429 
   430 lemma real_of_float_nprt[simp]: "real (float_nprt a) = nprt (real a)"
   431   by (cases a) (auto simp add: zero_le_float float_le_zero)
   432 
   433 instance float :: ab_semigroup_add
   434 proof (intro_classes)
   435   fix a b c :: float
   436   show "a + b + c = a + (b + c)"
   437     by (cases a, cases b, cases c)
   438       (auto simp add: algebra_simps power_add[symmetric] plus_float.simps)
   439 next
   440   fix a b :: float
   441   show "a + b = b + a"
   442     by (cases a, cases b) (simp add: plus_float.simps)
   443 qed
   444 
   445 instance float :: comm_monoid_mult
   446 proof (intro_classes)
   447   fix a b c :: float
   448   show "a * b * c = a * (b * c)"
   449     by (cases a, cases b, cases c) (simp add: times_float.simps)
   450 next
   451   fix a b :: float
   452   show "a * b = b * a"
   453     by (cases a, cases b) (simp add: times_float.simps)
   454 next
   455   fix a :: float
   456   show "1 * a = a"
   457     by (cases a) (simp add: times_float.simps one_float_def)
   458 qed
   459 
   460 (* Floats do NOT form a cancel_semigroup_add: *)
   461 lemma "0 + Float 0 1 = 0 + Float 0 2"
   462   by (simp add: plus_float.simps zero_float_def)
   463 
   464 instance float :: comm_semiring
   465 proof (intro_classes)
   466   fix a b c :: float
   467   show "(a + b) * c = a * c + b * c"
   468     by (cases a, cases b, cases c) (simp add: plus_float.simps times_float.simps algebra_simps)
   469 qed
   470 
   471 (* Floats do NOT form an order, because "(x < y) = (x <= y & x <> y)" does NOT hold *)
   472 
   473 instance float :: zero_neq_one
   474 proof (intro_classes)
   475   show "(0::float) \<noteq> 1"
   476     by (simp add: zero_float_def one_float_def)
   477 qed
   478 
   479 lemma float_le_simp: "((x::float) \<le> y) = (0 \<le> y - x)"
   480   by (auto simp add: le_float_def)
   481 
   482 lemma float_less_simp: "((x::float) < y) = (0 < y - x)"
   483   by (auto simp add: less_float_def)
   484 
   485 lemma real_of_float_min: "real (min x y :: float) = min (real x) (real y)" unfolding min_def le_float_def by auto
   486 lemma real_of_float_max: "real (max a b :: float) = max (real a) (real b)" unfolding max_def le_float_def by auto
   487 
   488 lemma float_power: "real (x ^ n :: float) = real x ^ n"
   489   by (induct n) simp_all
   490 
   491 lemma zero_le_pow2[simp]: "0 \<le> pow2 s"
   492   apply (subgoal_tac "0 < pow2 s")
   493   apply (auto simp only:)
   494   apply auto
   495   done
   496 
   497 lemma pow2_less_0_eq_False[simp]: "(pow2 s < 0) = False"
   498   apply auto
   499   apply (subgoal_tac "0 \<le> pow2 s")
   500   apply simp
   501   apply simp
   502   done
   503 
   504 lemma pow2_le_0_eq_False[simp]: "(pow2 s \<le> 0) = False"
   505   apply auto
   506   apply (subgoal_tac "0 < pow2 s")
   507   apply simp
   508   apply simp
   509   done
   510 
   511 lemma float_pos_m_pos: "0 < Float m e \<Longrightarrow> 0 < m"
   512   unfolding less_float_def real_of_float_simp real_of_float_0 zero_less_mult_iff
   513   by auto
   514 
   515 lemma float_pos_less1_e_neg: assumes "0 < Float m e" and "Float m e < 1" shows "e < 0"
   516 proof -
   517   have "0 < m" using float_pos_m_pos `0 < Float m e` by auto
   518   hence "0 \<le> real m" and "1 \<le> real m" by auto
   519   
   520   show "e < 0"
   521   proof (rule ccontr)
   522     assume "\<not> e < 0" hence "0 \<le> e" by auto
   523     hence "1 \<le> pow2 e" unfolding pow2_def by auto
   524     from mult_mono[OF `1 \<le> real m` this `0 \<le> real m`]
   525     have "1 \<le> Float m e" by (simp add: le_float_def real_of_float_simp)
   526     thus False using `Float m e < 1` unfolding less_float_def le_float_def by auto
   527   qed
   528 qed
   529 
   530 lemma float_less1_mantissa_bound: assumes "0 < Float m e" "Float m e < 1" shows "m < 2^(nat (-e))"
   531 proof -
   532   have "e < 0" using float_pos_less1_e_neg assms by auto
   533   have "\<And>x. (0::real) < 2^x" by auto
   534   have "real m < 2^(nat (-e))" using `Float m e < 1`
   535     unfolding less_float_def real_of_float_neg_exp[OF `e < 0`] real_of_float_1
   536           real_mult_less_iff1[of _ _ 1, OF `0 < 2^(nat (-e))`, symmetric] 
   537           mult_assoc by auto
   538   thus ?thesis unfolding real_of_int_less_iff[symmetric] by auto
   539 qed
   540 
   541 function bitlen :: "int \<Rightarrow> int" where
   542 "bitlen 0 = 0" | 
   543 "bitlen -1 = 1" | 
   544 "0 < x \<Longrightarrow> bitlen x = 1 + (bitlen (x div 2))" | 
   545 "x < -1 \<Longrightarrow> bitlen x = 1 + (bitlen (x div 2))"
   546   apply (case_tac "x = 0 \<or> x = -1 \<or> x < -1 \<or> x > 0")
   547   apply auto
   548   done
   549 termination by (relation "measure (nat o abs)", auto)
   550 
   551 lemma bitlen_ge0: "0 \<le> bitlen x" by (induct x rule: bitlen.induct, auto)
   552 lemma bitlen_ge1: "x \<noteq> 0 \<Longrightarrow> 1 \<le> bitlen x" by (induct x rule: bitlen.induct, auto simp add: bitlen_ge0)
   553 
   554 lemma bitlen_bounds': assumes "0 < x" shows "2^nat (bitlen x - 1) \<le> x \<and> x + 1 \<le> 2^nat (bitlen x)" (is "?P x")
   555   using `0 < x`
   556 proof (induct x rule: bitlen.induct)
   557   fix x
   558   assume "0 < x" and hyp: "0 < x div 2 \<Longrightarrow> ?P (x div 2)" hence "0 \<le> x" and "x \<noteq> 0" by auto
   559   { fix x have "0 \<le> 1 + bitlen x" using bitlen_ge0[of x] by auto } note gt0_pls1 = this
   560 
   561   have "0 < (2::int)" by auto
   562 
   563   show "?P x"
   564   proof (cases "x = 1")
   565     case True show "?P x" unfolding True by auto
   566   next
   567     case False hence "2 \<le> x" using `0 < x` `x \<noteq> 1` by auto
   568     hence "2 div 2 \<le> x div 2" by (rule zdiv_mono1, auto)
   569     hence "0 < x div 2" and "x div 2 \<noteq> 0" by auto
   570     hence bitlen_s1_ge0: "0 \<le> bitlen (x div 2) - 1" using bitlen_ge1[OF `x div 2 \<noteq> 0`] by auto
   571 
   572     { from hyp[OF `0 < x div 2`]
   573       have "2 ^ nat (bitlen (x div 2) - 1) \<le> x div 2" by auto
   574       hence "2 ^ nat (bitlen (x div 2) - 1) * 2 \<le> x div 2 * 2" by (rule mult_right_mono, auto)
   575       also have "\<dots> \<le> x" using `0 < x` by auto
   576       finally have "2^nat (1 + bitlen (x div 2) - 1) \<le> x" unfolding power_Suc2[symmetric] Suc_nat_eq_nat_zadd1[OF bitlen_s1_ge0] by auto
   577     } moreover
   578     { have "x + 1 \<le> x - x mod 2 + 2"
   579       proof -
   580         have "x mod 2 < 2" using `0 < x` by auto
   581         hence "x < x - x mod 2 +  2" unfolding algebra_simps by auto
   582         thus ?thesis by auto
   583       qed
   584       also have "x - x mod 2 + 2 = (x div 2 + 1) * 2" unfolding algebra_simps using `0 < x` zdiv_zmod_equality2[of x 2 0] by auto
   585       also have "\<dots> \<le> 2^nat (bitlen (x div 2)) * 2" using hyp[OF `0 < x div 2`, THEN conjunct2] by (rule mult_right_mono, auto)
   586       also have "\<dots> = 2^(1 + nat (bitlen (x div 2)))" unfolding power_Suc2[symmetric] by auto
   587       finally have "x + 1 \<le> 2^(1 + nat (bitlen (x div 2)))" .
   588     }
   589     ultimately show ?thesis
   590       unfolding bitlen.simps(3)[OF `0 < x`] nat_add_distrib[OF zero_le_one bitlen_ge0]
   591       unfolding add_commute nat_add_distrib[OF zero_le_one gt0_pls1]
   592       by auto
   593   qed
   594 next
   595   fix x :: int assume "x < -1" and "0 < x" hence False by auto
   596   thus "?P x" by auto
   597 qed auto
   598 
   599 lemma bitlen_bounds: assumes "0 < x" shows "2^nat (bitlen x - 1) \<le> x \<and> x < 2^nat (bitlen x)"
   600   using bitlen_bounds'[OF `0<x`] by auto
   601 
   602 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   603 proof -
   604   let ?B = "2^nat(bitlen m - 1)"
   605 
   606   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   607   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   608   thus "1 \<le> real m / ?B" by auto
   609 
   610   have "m \<noteq> 0" using assms by auto
   611   have "0 \<le> bitlen m - 1" using bitlen_ge1[OF `m \<noteq> 0`] by auto
   612 
   613   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   614   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using bitlen_ge1[OF `m \<noteq> 0`] by auto
   615   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   616   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   617   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   618   thus "real m / ?B < 2" by auto
   619 qed
   620 
   621 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   622   shows "0 \<le> e + (bitlen m - 1)"
   623 proof (cases "0 \<le> e")
   624   have "0 < Float m e" using assms unfolding less_float_def le_float_def by auto
   625   hence "0 < m" using float_pos_m_pos by auto
   626   hence "m \<noteq> 0" by auto
   627   case True with bitlen_ge1[OF `m \<noteq> 0`] show ?thesis by auto
   628 next
   629   have "0 < Float m e" using assms unfolding less_float_def le_float_def by auto
   630   hence "0 < m" using float_pos_m_pos by auto
   631   hence "m \<noteq> 0" and "1 < (2::int)" by auto
   632   case False let ?S = "2^(nat (-e))"
   633   have "1 \<le> real m * inverse ?S" using assms unfolding le_float_def real_of_float_nge0_exp[OF False] by auto
   634   hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   635   hence "?S \<le> real m" unfolding mult_assoc by auto
   636   hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   637   from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   638   have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   639   hence "-e < bitlen m" using False bitlen_ge0 by auto
   640   thus ?thesis by auto
   641 qed
   642 
   643 lemma normalized_float: assumes "m \<noteq> 0" shows "real (Float m (- (bitlen m - 1))) = real m / 2^nat (bitlen m - 1)"
   644 proof (cases "- (bitlen m - 1) = 0")
   645   case True show ?thesis unfolding real_of_float_simp pow2_def using True by auto
   646 next
   647   case False hence P: "\<not> 0 \<le> - (bitlen m - 1)" using bitlen_ge1[OF `m \<noteq> 0`] by auto
   648   show ?thesis unfolding real_of_float_nge0_exp[OF P] divide_inverse by auto
   649 qed
   650 
   651 lemma bitlen_Pls: "bitlen (Int.Pls) = Int.Pls" by (subst Pls_def, subst Pls_def, simp)
   652 
   653 lemma bitlen_Min: "bitlen (Int.Min) = Int.Bit1 Int.Pls" by (subst Min_def, simp add: Bit1_def) 
   654 
   655 lemma bitlen_B0: "bitlen (Int.Bit0 b) = (if iszero b then Int.Pls else Int.succ (bitlen b))"
   656   apply (auto simp add: iszero_def succ_def)
   657   apply (simp add: Bit0_def Pls_def)
   658   apply (subst Bit0_def)
   659   apply simp
   660   apply (subgoal_tac "0 < 2 * b \<or> 2 * b < -1")
   661   apply auto
   662   done
   663 
   664 lemma bitlen_B1: "bitlen (Int.Bit1 b) = (if iszero (Int.succ b) then Int.Bit1 Int.Pls else Int.succ (bitlen b))"
   665 proof -
   666   have h: "! x. (2*x + 1) div 2 = (x::int)"
   667     by arith    
   668   show ?thesis
   669     apply (auto simp add: iszero_def succ_def)
   670     apply (subst Bit1_def)+
   671     apply simp
   672     apply (subgoal_tac "2 * b + 1 = -1")
   673     apply (simp only:)
   674     apply simp_all
   675     apply (subst Bit1_def)
   676     apply simp
   677     apply (subgoal_tac "0 < 2 * b + 1 \<or> 2 * b + 1 < -1")
   678     apply (auto simp add: h)
   679     done
   680 qed
   681 
   682 lemma bitlen_number_of: "bitlen (number_of w) = number_of (bitlen w)"
   683   by (simp add: number_of_is_id)
   684 
   685 lemma [code]: "bitlen x = 
   686      (if x = 0  then 0 
   687  else if x = -1 then 1 
   688                 else (1 + (bitlen (x div 2))))"
   689   by (cases "x = 0 \<or> x = -1 \<or> 0 < x") auto
   690 
   691 definition lapprox_posrat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float"
   692 where
   693   "lapprox_posrat prec x y = 
   694    (let 
   695        l = nat (int prec + bitlen y - bitlen x) ;
   696        d = (x * 2^l) div y
   697     in normfloat (Float d (- (int l))))"
   698 
   699 lemma pow2_minus: "pow2 (-x) = inverse (pow2 x)"
   700   unfolding pow2_neg[of "-x"] by auto
   701 
   702 lemma lapprox_posrat: 
   703   assumes x: "0 \<le> x"
   704   and y: "0 < y"
   705   shows "real (lapprox_posrat prec x y) \<le> real x / real y"
   706 proof -
   707   let ?l = "nat (int prec + bitlen y - bitlen x)"
   708   
   709   have "real (x * 2^?l div y) * inverse (2^?l) \<le> (real (x * 2^?l) / real y) * inverse (2^?l)" 
   710     by (rule mult_right_mono, fact real_of_int_div4, simp)
   711   also have "\<dots> \<le> (real x / real y) * 2^?l * inverse (2^?l)" by auto
   712   finally have "real (x * 2^?l div y) * inverse (2^?l) \<le> real x / real y" unfolding mult_assoc by auto
   713   thus ?thesis unfolding lapprox_posrat_def Let_def normfloat real_of_float_simp
   714     unfolding pow2_minus pow2_int minus_minus .
   715 qed
   716 
   717 lemma real_of_int_div_mult: 
   718   fixes x y c :: int assumes "0 < y" and "0 < c"
   719   shows "real (x div y) \<le> real (x * c div y) * inverse (real c)"
   720 proof -
   721   have "c * (x div y) + 0 \<le> c * x div y" unfolding zdiv_zmult1_eq[of c x y]
   722     by (rule zadd_left_mono, 
   723         auto intro!: mult_nonneg_nonneg 
   724              simp add: pos_imp_zdiv_nonneg_iff[OF `0 < y`] `0 < c`[THEN less_imp_le] pos_mod_sign[OF `0 < y`])
   725   hence "real (x div y) * real c \<le> real (x * c div y)" 
   726     unfolding real_of_int_mult[symmetric] real_of_int_le_iff zmult_commute by auto
   727   hence "real (x div y) * real c * inverse (real c) \<le> real (x * c div y) * inverse (real c)"
   728     using `0 < c` by auto
   729   thus ?thesis unfolding mult_assoc using `0 < c` by auto
   730 qed
   731 
   732 lemma lapprox_posrat_bottom: assumes "0 < y"
   733   shows "real (x div y) \<le> real (lapprox_posrat n x y)" 
   734 proof -
   735   have pow: "\<And>x. (0::int) < 2^x" by auto
   736   show ?thesis
   737     unfolding lapprox_posrat_def Let_def real_of_float_add normfloat real_of_float_simp pow2_minus pow2_int
   738     using real_of_int_div_mult[OF `0 < y` pow] by auto
   739 qed
   740 
   741 lemma lapprox_posrat_nonneg: assumes "0 \<le> x" and "0 < y"
   742   shows "0 \<le> real (lapprox_posrat n x y)" 
   743 proof -
   744   show ?thesis
   745     unfolding lapprox_posrat_def Let_def real_of_float_add normfloat real_of_float_simp pow2_minus pow2_int
   746     using pos_imp_zdiv_nonneg_iff[OF `0 < y`] assms by (auto intro!: mult_nonneg_nonneg)
   747 qed
   748 
   749 definition rapprox_posrat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float"
   750 where
   751   "rapprox_posrat prec x y = (let
   752      l = nat (int prec + bitlen y - bitlen x) ;
   753      X = x * 2^l ;
   754      d = X div y ;
   755      m = X mod y
   756    in normfloat (Float (d + (if m = 0 then 0 else 1)) (- (int l))))"
   757 
   758 lemma rapprox_posrat:
   759   assumes x: "0 \<le> x"
   760   and y: "0 < y"
   761   shows "real x / real y \<le> real (rapprox_posrat prec x y)"
   762 proof -
   763   let ?l = "nat (int prec + bitlen y - bitlen x)" let ?X = "x * 2^?l"
   764   show ?thesis 
   765   proof (cases "?X mod y = 0")
   766     case True hence "y \<noteq> 0" and "y dvd ?X" using `0 < y` by auto
   767     from real_of_int_div[OF this]
   768     have "real (?X div y) * inverse (2 ^ ?l) = real ?X / real y * inverse (2 ^ ?l)" by auto
   769     also have "\<dots> = real x / real y * (2^?l * inverse (2^?l))" by auto
   770     finally have "real (?X div y) * inverse (2^?l) = real x / real y" by auto
   771     thus ?thesis unfolding rapprox_posrat_def Let_def normfloat if_P[OF True] 
   772       unfolding real_of_float_simp pow2_minus pow2_int minus_minus by auto
   773   next
   774     case False
   775     have "0 \<le> real y" and "real y \<noteq> 0" using `0 < y` by auto
   776     have "0 \<le> real y * 2^?l" by (rule mult_nonneg_nonneg, rule `0 \<le> real y`, auto)
   777 
   778     have "?X = y * (?X div y) + ?X mod y" by auto
   779     also have "\<dots> \<le> y * (?X div y) + y" by (rule add_mono, auto simp add: pos_mod_bound[OF `0 < y`, THEN less_imp_le])
   780     also have "\<dots> = y * (?X div y + 1)" unfolding zadd_zmult_distrib2 by auto
   781     finally have "real ?X \<le> real y * real (?X div y + 1)" unfolding real_of_int_le_iff real_of_int_mult[symmetric] .
   782     hence "real ?X / (real y * 2^?l) \<le> real y * real (?X div y + 1) / (real y * 2^?l)" 
   783       by (rule divide_right_mono, simp only: `0 \<le> real y * 2^?l`)
   784     also have "\<dots> = real y * real (?X div y + 1) / real y / 2^?l" by auto
   785     also have "\<dots> = real (?X div y + 1) * inverse (2^?l)" unfolding nonzero_mult_divide_cancel_left[OF `real y \<noteq> 0`] 
   786       unfolding divide_inverse ..
   787     finally show ?thesis unfolding rapprox_posrat_def Let_def normfloat real_of_float_simp if_not_P[OF False]
   788       unfolding pow2_minus pow2_int minus_minus by auto
   789   qed
   790 qed
   791 
   792 lemma rapprox_posrat_le1: assumes "0 \<le> x" and "0 < y" and "x \<le> y"
   793   shows "real (rapprox_posrat n x y) \<le> 1"
   794 proof -
   795   let ?l = "nat (int n + bitlen y - bitlen x)" let ?X = "x * 2^?l"
   796   show ?thesis
   797   proof (cases "?X mod y = 0")
   798     case True hence "y \<noteq> 0" and "y dvd ?X" using `0 < y` by auto
   799     from real_of_int_div[OF this]
   800     have "real (?X div y) * inverse (2 ^ ?l) = real ?X / real y * inverse (2 ^ ?l)" by auto
   801     also have "\<dots> = real x / real y * (2^?l * inverse (2^?l))" by auto
   802     finally have "real (?X div y) * inverse (2^?l) = real x / real y" by auto
   803     also have "real x / real y \<le> 1" using `0 \<le> x` and `0 < y` and `x \<le> y` by auto
   804     finally show ?thesis unfolding rapprox_posrat_def Let_def normfloat if_P[OF True]
   805       unfolding real_of_float_simp pow2_minus pow2_int minus_minus by auto
   806   next
   807     case False
   808     have "x \<noteq> y"
   809     proof (rule ccontr)
   810       assume "\<not> x \<noteq> y" hence "x = y" by auto
   811       have "?X mod y = 0" unfolding `x = y` using mod_mult_self1_is_0 by auto
   812       thus False using False by auto
   813     qed
   814     hence "x < y" using `x \<le> y` by auto
   815     hence "real x / real y < 1" using `0 < y` and `0 \<le> x` by auto
   816 
   817     from real_of_int_div4[of "?X" y]
   818     have "real (?X div y) \<le> (real x / real y) * 2^?l" unfolding real_of_int_mult times_divide_eq_left real_of_int_power real_number_of .
   819     also have "\<dots> < 1 * 2^?l" using `real x / real y < 1` by (rule mult_strict_right_mono, auto)
   820     finally have "?X div y < 2^?l" unfolding real_of_int_less_iff[of _ "2^?l", symmetric] by auto
   821     hence "?X div y + 1 \<le> 2^?l" by auto
   822     hence "real (?X div y + 1) * inverse (2^?l) \<le> 2^?l * inverse (2^?l)"
   823       unfolding real_of_int_le_iff[of _ "2^?l", symmetric] real_of_int_power real_number_of
   824       by (rule mult_right_mono, auto)
   825     hence "real (?X div y + 1) * inverse (2^?l) \<le> 1" by auto
   826     thus ?thesis unfolding rapprox_posrat_def Let_def normfloat real_of_float_simp if_not_P[OF False]
   827       unfolding pow2_minus pow2_int minus_minus by auto
   828   qed
   829 qed
   830 
   831 lemma zdiv_greater_zero: fixes a b :: int assumes "0 < a" and "a \<le> b"
   832   shows "0 < b div a"
   833 proof (rule ccontr)
   834   have "0 \<le> b" using assms by auto
   835   assume "\<not> 0 < b div a" hence "b div a = 0" using `0 \<le> b`[unfolded pos_imp_zdiv_nonneg_iff[OF `0<a`, of b, symmetric]] by auto
   836   have "b = a * (b div a) + b mod a" by auto
   837   hence "b = b mod a" unfolding `b div a = 0` by auto
   838   hence "b < a" using `0 < a`[THEN pos_mod_bound, of b] by auto
   839   thus False using `a \<le> b` by auto
   840 qed
   841 
   842 lemma rapprox_posrat_less1: assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   843   shows "real (rapprox_posrat n x y) < 1"
   844 proof (cases "x = 0")
   845   case True thus ?thesis unfolding rapprox_posrat_def True Let_def normfloat real_of_float_simp by auto
   846 next
   847   case False hence "0 < x" using `0 \<le> x` by auto
   848   hence "x < y" using assms by auto
   849   
   850   let ?l = "nat (int n + bitlen y - bitlen x)" let ?X = "x * 2^?l"
   851   show ?thesis
   852   proof (cases "?X mod y = 0")
   853     case True hence "y \<noteq> 0" and "y dvd ?X" using `0 < y` by auto
   854     from real_of_int_div[OF this]
   855     have "real (?X div y) * inverse (2 ^ ?l) = real ?X / real y * inverse (2 ^ ?l)" by auto
   856     also have "\<dots> = real x / real y * (2^?l * inverse (2^?l))" by auto
   857     finally have "real (?X div y) * inverse (2^?l) = real x / real y" by auto
   858     also have "real x / real y < 1" using `0 \<le> x` and `0 < y` and `x < y` by auto
   859     finally show ?thesis unfolding rapprox_posrat_def Let_def normfloat real_of_float_simp if_P[OF True]
   860       unfolding pow2_minus pow2_int minus_minus by auto
   861   next
   862     case False
   863     hence "(real x / real y) < 1 / 2" using `0 < y` and `0 \<le> x` `2 * x < y` by auto
   864 
   865     have "0 < ?X div y"
   866     proof -
   867       have "2^nat (bitlen x - 1) \<le> y" and "y < 2^nat (bitlen y)"
   868         using bitlen_bounds[OF `0 < x`, THEN conjunct1] bitlen_bounds[OF `0 < y`, THEN conjunct2] `x < y` by auto
   869       hence "(2::int)^nat (bitlen x - 1) < 2^nat (bitlen y)" by (rule order_le_less_trans)
   870       hence "bitlen x \<le> bitlen y" by auto
   871       hence len_less: "nat (bitlen x - 1) \<le> nat (int (n - 1) + bitlen y)" by auto
   872 
   873       have "x \<noteq> 0" and "y \<noteq> 0" using `0 < x` `0 < y` by auto
   874 
   875       have exp_eq: "nat (int (n - 1) + bitlen y) - nat (bitlen x - 1) = ?l"
   876         using `bitlen x \<le> bitlen y` bitlen_ge1[OF `x \<noteq> 0`] bitlen_ge1[OF `y \<noteq> 0`] `0 < n` by auto
   877 
   878       have "y * 2^nat (bitlen x - 1) \<le> y * x" 
   879         using bitlen_bounds[OF `0 < x`, THEN conjunct1] `0 < y`[THEN less_imp_le] by (rule mult_left_mono)
   880       also have "\<dots> \<le> 2^nat (bitlen y) * x" using bitlen_bounds[OF `0 < y`, THEN conjunct2, THEN less_imp_le] `0 \<le> x` by (rule mult_right_mono)
   881       also have "\<dots> \<le> x * 2^nat (int (n - 1) + bitlen y)" unfolding mult_commute[of x] by (rule mult_right_mono, auto simp add: `0 \<le> x`)
   882       finally have "real y * 2^nat (bitlen x - 1) * inverse (2^nat (bitlen x - 1)) \<le> real x * 2^nat (int (n - 1) + bitlen y) * inverse (2^nat (bitlen x - 1))"
   883         unfolding real_of_int_le_iff[symmetric] by auto
   884       hence "real y \<le> real x * (2^nat (int (n - 1) + bitlen y) / (2^nat (bitlen x - 1)))" 
   885         unfolding mult_assoc divide_inverse by auto
   886       also have "\<dots> = real x * (2^(nat (int (n - 1) + bitlen y) - nat (bitlen x - 1)))" using power_diff[of "2::real", OF _ len_less] by auto
   887       finally have "y \<le> x * 2^?l" unfolding exp_eq unfolding real_of_int_le_iff[symmetric] by auto
   888       thus ?thesis using zdiv_greater_zero[OF `0 < y`] by auto
   889     qed
   890 
   891     from real_of_int_div4[of "?X" y]
   892     have "real (?X div y) \<le> (real x / real y) * 2^?l" unfolding real_of_int_mult times_divide_eq_left real_of_int_power real_number_of .
   893     also have "\<dots> < 1/2 * 2^?l" using `real x / real y < 1/2` by (rule mult_strict_right_mono, auto)
   894     finally have "?X div y * 2 < 2^?l" unfolding real_of_int_less_iff[of _ "2^?l", symmetric] by auto
   895     hence "?X div y + 1 < 2^?l" using `0 < ?X div y` by auto
   896     hence "real (?X div y + 1) * inverse (2^?l) < 2^?l * inverse (2^?l)"
   897       unfolding real_of_int_less_iff[of _ "2^?l", symmetric] real_of_int_power real_number_of
   898       by (rule mult_strict_right_mono, auto)
   899     hence "real (?X div y + 1) * inverse (2^?l) < 1" by auto
   900     thus ?thesis unfolding rapprox_posrat_def Let_def normfloat real_of_float_simp if_not_P[OF False]
   901       unfolding pow2_minus pow2_int minus_minus by auto
   902   qed
   903 qed
   904 
   905 lemma approx_rat_pattern: fixes P and ps :: "nat * int * int"
   906   assumes Y: "\<And>y prec x. \<lbrakk>y = 0; ps = (prec, x, 0)\<rbrakk> \<Longrightarrow> P" 
   907   and A: "\<And>x y prec. \<lbrakk>0 \<le> x; 0 < y; ps = (prec, x, y)\<rbrakk> \<Longrightarrow> P"
   908   and B: "\<And>x y prec. \<lbrakk>x < 0; 0 < y; ps = (prec, x, y)\<rbrakk> \<Longrightarrow> P"
   909   and C: "\<And>x y prec. \<lbrakk>x < 0; y < 0; ps = (prec, x, y)\<rbrakk> \<Longrightarrow> P"
   910   and D: "\<And>x y prec. \<lbrakk>0 \<le> x; y < 0; ps = (prec, x, y)\<rbrakk> \<Longrightarrow> P"
   911   shows P
   912 proof -
   913   obtain prec x y where [simp]: "ps = (prec, x, y)" by (cases ps) auto
   914   from Y have "y = 0 \<Longrightarrow> P" by auto
   915   moreover {
   916     assume "0 < y"
   917     have P
   918     proof (cases "0 \<le> x")
   919       case True
   920       with A and `0 < y` show P by auto
   921     next
   922       case False
   923       with B and `0 < y` show P by auto
   924     qed
   925   } 
   926   moreover {
   927     assume "y < 0"
   928     have P
   929     proof (cases "0 \<le> x")
   930       case True
   931       with D and `y < 0` show P by auto
   932     next
   933       case False
   934       with C and `y < 0` show P by auto
   935     qed
   936   }
   937   ultimately show P by (cases "y = 0 \<or> 0 < y \<or> y < 0") auto
   938 qed
   939 
   940 function lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float"
   941 where
   942   "y = 0 \<Longrightarrow> lapprox_rat prec x y = 0"
   943 | "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> lapprox_rat prec x y = lapprox_posrat prec x y"
   944 | "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> lapprox_rat prec x y = - (rapprox_posrat prec (-x) y)"
   945 | "x < 0 \<Longrightarrow> y < 0 \<Longrightarrow> lapprox_rat prec x y = lapprox_posrat prec (-x) (-y)"
   946 | "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> lapprox_rat prec x y = - (rapprox_posrat prec x (-y))"
   947 apply simp_all by (rule approx_rat_pattern)
   948 termination by lexicographic_order
   949 
   950 lemma compute_lapprox_rat[code]:
   951       "lapprox_rat prec x y = (if y = 0 then 0 else if 0 \<le> x then (if 0 < y then lapprox_posrat prec x y else - (rapprox_posrat prec x (-y))) 
   952                                                              else (if 0 < y then - (rapprox_posrat prec (-x) y) else lapprox_posrat prec (-x) (-y)))"
   953   by auto
   954             
   955 lemma lapprox_rat: "real (lapprox_rat prec x y) \<le> real x / real y"
   956 proof -      
   957   have h[rule_format]: "! a b b'. b' \<le> b \<longrightarrow> a \<le> b' \<longrightarrow> a \<le> (b::real)" by auto
   958   show ?thesis
   959     apply (case_tac "y = 0")
   960     apply simp
   961     apply (case_tac "0 \<le> x \<and> 0 < y")
   962     apply (simp add: lapprox_posrat)
   963     apply (case_tac "x < 0 \<and> 0 < y")
   964     apply simp
   965     apply (subst minus_le_iff)   
   966     apply (rule h[OF rapprox_posrat])
   967     apply (simp_all)
   968     apply (case_tac "x < 0 \<and> y < 0")
   969     apply simp
   970     apply (rule h[OF _ lapprox_posrat])
   971     apply (simp_all)
   972     apply (case_tac "0 \<le> x \<and> y < 0")
   973     apply (simp)
   974     apply (subst minus_le_iff)   
   975     apply (rule h[OF rapprox_posrat])
   976     apply simp_all
   977     apply arith
   978     done
   979 qed
   980 
   981 lemma lapprox_rat_bottom: assumes "0 \<le> x" and "0 < y"
   982   shows "real (x div y) \<le> real (lapprox_rat n x y)" 
   983   unfolding lapprox_rat.simps(2)[OF assms]  using lapprox_posrat_bottom[OF `0<y`] .
   984 
   985 function rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float"
   986 where
   987   "y = 0 \<Longrightarrow> rapprox_rat prec x y = 0"
   988 | "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> rapprox_rat prec x y = rapprox_posrat prec x y"
   989 | "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> rapprox_rat prec x y = - (lapprox_posrat prec (-x) y)"
   990 | "x < 0 \<Longrightarrow> y < 0 \<Longrightarrow> rapprox_rat prec x y = rapprox_posrat prec (-x) (-y)"
   991 | "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> rapprox_rat prec x y = - (lapprox_posrat prec x (-y))"
   992 apply simp_all by (rule approx_rat_pattern)
   993 termination by lexicographic_order
   994 
   995 lemma compute_rapprox_rat[code]:
   996       "rapprox_rat prec x y = (if y = 0 then 0 else if 0 \<le> x then (if 0 < y then rapprox_posrat prec x y else - (lapprox_posrat prec x (-y))) else 
   997                                                                   (if 0 < y then - (lapprox_posrat prec (-x) y) else rapprox_posrat prec (-x) (-y)))"
   998   by auto
   999 
  1000 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1001 proof -      
  1002   have h[rule_format]: "! a b b'. b' \<le> b \<longrightarrow> a \<le> b' \<longrightarrow> a \<le> (b::real)" by auto
  1003   show ?thesis
  1004     apply (case_tac "y = 0")
  1005     apply simp
  1006     apply (case_tac "0 \<le> x \<and> 0 < y")
  1007     apply (simp add: rapprox_posrat)
  1008     apply (case_tac "x < 0 \<and> 0 < y")
  1009     apply simp
  1010     apply (subst le_minus_iff)   
  1011     apply (rule h[OF _ lapprox_posrat])
  1012     apply (simp_all)
  1013     apply (case_tac "x < 0 \<and> y < 0")
  1014     apply simp
  1015     apply (rule h[OF rapprox_posrat])
  1016     apply (simp_all)
  1017     apply (case_tac "0 \<le> x \<and> y < 0")
  1018     apply (simp)
  1019     apply (subst le_minus_iff)   
  1020     apply (rule h[OF _ lapprox_posrat])
  1021     apply simp_all
  1022     apply arith
  1023     done
  1024 qed
  1025 
  1026 lemma rapprox_rat_le1: assumes "0 \<le> x" and "0 < y" and "x \<le> y"
  1027   shows "real (rapprox_rat n x y) \<le> 1"
  1028   unfolding rapprox_rat.simps(2)[OF `0 \<le> x` `0 < y`] using rapprox_posrat_le1[OF assms] .
  1029 
  1030 lemma rapprox_rat_neg: assumes "x < 0" and "0 < y"
  1031   shows "real (rapprox_rat n x y) \<le> 0"
  1032   unfolding rapprox_rat.simps(3)[OF assms] using lapprox_posrat_nonneg[of "-x" y n] assms by auto
  1033 
  1034 lemma rapprox_rat_nonneg_neg: assumes "0 \<le> x" and "y < 0"
  1035   shows "real (rapprox_rat n x y) \<le> 0"
  1036   unfolding rapprox_rat.simps(5)[OF assms] using lapprox_posrat_nonneg[of x "-y" n] assms by auto
  1037 
  1038 lemma rapprox_rat_nonpos_pos: assumes "x \<le> 0" and "0 < y"
  1039   shows "real (rapprox_rat n x y) \<le> 0"
  1040 proof (cases "x = 0") 
  1041   case True
  1042   hence "0 \<le> x" by auto show ?thesis
  1043     unfolding rapprox_rat.simps(2)[OF `0 \<le> x` `0 < y`]
  1044     unfolding True rapprox_posrat_def Let_def
  1045     by auto
  1046 next
  1047   case False
  1048   hence "x < 0" using assms by auto
  1049   show ?thesis using rapprox_rat_neg[OF `x < 0` `0 < y`] .
  1050 qed
  1051 
  1052 fun float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float"
  1053 where
  1054   "float_divl prec (Float m1 s1) (Float m2 s2) = 
  1055     (let
  1056        l = lapprox_rat prec m1 m2;
  1057        f = Float 1 (s1 - s2)
  1058      in
  1059        f * l)"     
  1060 
  1061 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1062 proof - 
  1063   from float_split[of x] obtain mx sx where x: "x = Float mx sx" by auto
  1064   from float_split[of y] obtain my sy where y: "y = Float my sy" by auto
  1065   have "real mx / real my \<le> (real mx * pow2 sx / (real my * pow2 sy)) / (pow2 (sx - sy))"
  1066     apply (case_tac "my = 0")
  1067     apply simp
  1068     apply (case_tac "my > 0")       
  1069     apply (subst pos_le_divide_eq)
  1070     apply simp
  1071     apply (subst pos_le_divide_eq)
  1072     apply (simp add: mult_pos_pos)
  1073     apply simp
  1074     apply (subst pow2_add[symmetric])
  1075     apply simp
  1076     apply (subgoal_tac "my < 0")
  1077     apply auto
  1078     apply (simp add: field_simps)
  1079     apply (subst pow2_add[symmetric])
  1080     apply (simp add: field_simps)
  1081     done
  1082   then have "real (lapprox_rat prec mx my) \<le> (real mx * pow2 sx / (real my * pow2 sy)) / (pow2 (sx - sy))"
  1083     by (rule order_trans[OF lapprox_rat])
  1084   then have "real (lapprox_rat prec mx my) * pow2 (sx - sy) \<le> real mx * pow2 sx / (real my * pow2 sy)"
  1085     apply (subst pos_le_divide_eq[symmetric])
  1086     apply simp_all
  1087     done
  1088   then have "pow2 (sx - sy) * real (lapprox_rat prec mx my) \<le> real mx * pow2 sx / (real my * pow2 sy)"
  1089     by (simp add: algebra_simps)
  1090   then show ?thesis
  1091     by (simp add: x y Let_def real_of_float_simp)
  1092 qed
  1093 
  1094 lemma float_divl_lower_bound: assumes "0 \<le> x" and "0 < y" shows "0 \<le> float_divl prec x y"
  1095 proof (cases x, cases y)
  1096   fix xm xe ym ye :: int
  1097   assume x_eq: "x = Float xm xe" and y_eq: "y = Float ym ye"
  1098   have "0 \<le> xm"
  1099     using `0 \<le> x`[unfolded x_eq le_float_def real_of_float_simp real_of_float_0 zero_le_mult_iff]
  1100     by auto
  1101   have "0 < ym"
  1102     using `0 < y`[unfolded y_eq less_float_def real_of_float_simp real_of_float_0 zero_less_mult_iff]
  1103     by auto
  1104 
  1105   have "\<And>n. 0 \<le> real (Float 1 n)"
  1106     unfolding real_of_float_simp using zero_le_pow2 by auto
  1107   moreover have "0 \<le> real (lapprox_rat prec xm ym)"
  1108     apply (rule order_trans[OF _ lapprox_rat_bottom[OF `0 \<le> xm` `0 < ym`]])
  1109     apply (auto simp add: `0 \<le> xm` pos_imp_zdiv_nonneg_iff[OF `0 < ym`])
  1110     done
  1111   ultimately show "0 \<le> float_divl prec x y"
  1112     unfolding x_eq y_eq float_divl.simps Let_def le_float_def real_of_float_0
  1113     by (auto intro!: mult_nonneg_nonneg)
  1114 qed
  1115 
  1116 lemma float_divl_pos_less1_bound:
  1117   assumes "0 < x" and "x < 1" and "0 < prec"
  1118   shows "1 \<le> float_divl prec 1 x"
  1119 proof (cases x)
  1120   case (Float m e)
  1121   from `0 < x` `x < 1` have "0 < m" "e < 0"
  1122     using float_pos_m_pos float_pos_less1_e_neg unfolding Float by auto
  1123   let ?b = "nat (bitlen m)" and ?e = "nat (-e)"
  1124   have "1 \<le> m" and "m \<noteq> 0" using `0 < m` by auto
  1125   with bitlen_bounds[OF `0 < m`] have "m < 2^?b" and "(2::int) \<le> 2^?b" by auto
  1126   hence "1 \<le> bitlen m" using power_le_imp_le_exp[of "2::int" 1 ?b] by auto
  1127   hence pow_split: "nat (int prec + bitlen m - 1) = (prec - 1) + ?b" using `0 < prec` by auto
  1128   
  1129   have pow_not0: "\<And>x. (2::real)^x \<noteq> 0" by auto
  1130 
  1131   from float_less1_mantissa_bound `0 < x` `x < 1` Float 
  1132   have "m < 2^?e" by auto
  1133   with bitlen_bounds[OF `0 < m`, THEN conjunct1] have "(2::int)^nat (bitlen m - 1) < 2^?e"
  1134     by (rule order_le_less_trans)
  1135   from power_less_imp_less_exp[OF _ this]
  1136   have "bitlen m \<le> - e" by auto
  1137   hence "(2::real)^?b \<le> 2^?e" by auto
  1138   hence "(2::real)^?b * inverse (2^?b) \<le> 2^?e * inverse (2^?b)"
  1139     by (rule mult_right_mono) auto
  1140   hence "(1::real) \<le> 2^?e * inverse (2^?b)" by auto
  1141   also
  1142   let ?d = "real (2 ^ nat (int prec + bitlen m - 1) div m) * inverse (2 ^ nat (int prec + bitlen m - 1))"
  1143   {
  1144     have "2^(prec - 1) * m \<le> 2^(prec - 1) * 2^?b"
  1145       using `m < 2^?b`[THEN less_imp_le] by (rule mult_left_mono) auto
  1146     also have "\<dots> = 2 ^ nat (int prec + bitlen m - 1)"
  1147       unfolding pow_split zpower_zadd_distrib by auto
  1148     finally have "2^(prec - 1) * m div m \<le> 2 ^ nat (int prec + bitlen m - 1) div m"
  1149       using `0 < m` by (rule zdiv_mono1)
  1150     hence "2^(prec - 1) \<le> 2 ^ nat (int prec + bitlen m - 1) div m"
  1151       unfolding div_mult_self2_is_id[OF `m \<noteq> 0`] .
  1152     hence "2^(prec - 1) * inverse (2 ^ nat (int prec + bitlen m - 1)) \<le> ?d"
  1153       unfolding real_of_int_le_iff[of "2^(prec - 1)", symmetric] by auto
  1154   }
  1155   from mult_left_mono[OF this [unfolded pow_split power_add inverse_mult_distrib mult_assoc[symmetric] right_inverse[OF pow_not0] mult_1_left], of "2^?e"]
  1156   have "2^?e * inverse (2^?b) \<le> 2^?e * ?d" unfolding pow_split power_add by auto
  1157   finally have "1 \<le> 2^?e * ?d" .
  1158   
  1159   have e_nat: "0 - e = int (nat (-e))" using `e < 0` by auto
  1160   have "bitlen 1 = 1" using bitlen.simps by auto
  1161   
  1162   show ?thesis 
  1163     unfolding one_float_def Float float_divl.simps Let_def
  1164       lapprox_rat.simps(2)[OF zero_le_one `0 < m`]
  1165       lapprox_posrat_def `bitlen 1 = 1`
  1166     unfolding le_float_def real_of_float_mult normfloat real_of_float_simp
  1167       pow2_minus pow2_int e_nat
  1168     using `1 \<le> 2^?e * ?d` by (auto simp add: pow2_def)
  1169 qed
  1170 
  1171 fun float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float"
  1172 where
  1173   "float_divr prec (Float m1 s1) (Float m2 s2) = 
  1174     (let
  1175        r = rapprox_rat prec m1 m2;
  1176        f = Float 1 (s1 - s2)
  1177      in
  1178        f * r)"  
  1179 
  1180 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1181 proof - 
  1182   from float_split[of x] obtain mx sx where x: "x = Float mx sx" by auto
  1183   from float_split[of y] obtain my sy where y: "y = Float my sy" by auto
  1184   have "real mx / real my \<ge> (real mx * pow2 sx / (real my * pow2 sy)) / (pow2 (sx - sy))"
  1185     apply (case_tac "my = 0")
  1186     apply simp
  1187     apply (case_tac "my > 0")
  1188     apply auto
  1189     apply (subst pos_divide_le_eq)
  1190     apply (rule mult_pos_pos)+
  1191     apply simp_all
  1192     apply (subst pow2_add[symmetric])
  1193     apply simp
  1194     apply (subgoal_tac "my < 0")
  1195     apply auto
  1196     apply (simp add: field_simps)
  1197     apply (subst pow2_add[symmetric])
  1198     apply (simp add: field_simps)
  1199     done
  1200   then have "real (rapprox_rat prec mx my) \<ge> (real mx * pow2 sx / (real my * pow2 sy)) / (pow2 (sx - sy))"
  1201     by (rule order_trans[OF _ rapprox_rat])
  1202   then have "real (rapprox_rat prec mx my) * pow2 (sx - sy) \<ge> real mx * pow2 sx / (real my * pow2 sy)"
  1203     apply (subst pos_divide_le_eq[symmetric])
  1204     apply simp_all
  1205     done
  1206   then show ?thesis
  1207     by (simp add: x y Let_def algebra_simps real_of_float_simp)
  1208 qed
  1209 
  1210 lemma float_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> float_divr prec 1 x"
  1211 proof -
  1212   have "1 \<le> 1 / real x" using `0 < x` and `x < 1` unfolding less_float_def by auto
  1213   also have "\<dots> \<le> real (float_divr prec 1 x)" using float_divr[where x=1 and y=x] by auto
  1214   finally show ?thesis unfolding le_float_def by auto
  1215 qed
  1216 
  1217 lemma float_divr_nonpos_pos_upper_bound: assumes "x \<le> 0" and "0 < y" shows "float_divr prec x y \<le> 0"
  1218 proof (cases x, cases y)
  1219   fix xm xe ym ye :: int
  1220   assume x_eq: "x = Float xm xe" and y_eq: "y = Float ym ye"
  1221   have "xm \<le> 0" using `x \<le> 0`[unfolded x_eq le_float_def real_of_float_simp real_of_float_0 mult_le_0_iff] by auto
  1222   have "0 < ym" using `0 < y`[unfolded y_eq less_float_def real_of_float_simp real_of_float_0 zero_less_mult_iff] by auto
  1223 
  1224   have "\<And>n. 0 \<le> real (Float 1 n)" unfolding real_of_float_simp using zero_le_pow2 by auto
  1225   moreover have "real (rapprox_rat prec xm ym) \<le> 0" using rapprox_rat_nonpos_pos[OF `xm \<le> 0` `0 < ym`] .
  1226   ultimately show "float_divr prec x y \<le> 0"
  1227     unfolding x_eq y_eq float_divr.simps Let_def le_float_def real_of_float_0 real_of_float_mult by (auto intro!: mult_nonneg_nonpos)
  1228 qed
  1229 
  1230 lemma float_divr_nonneg_neg_upper_bound: assumes "0 \<le> x" and "y < 0" shows "float_divr prec x y \<le> 0"
  1231 proof (cases x, cases y)
  1232   fix xm xe ym ye :: int
  1233   assume x_eq: "x = Float xm xe" and y_eq: "y = Float ym ye"
  1234   have "0 \<le> xm" using `0 \<le> x`[unfolded x_eq le_float_def real_of_float_simp real_of_float_0 zero_le_mult_iff] by auto
  1235   have "ym < 0" using `y < 0`[unfolded y_eq less_float_def real_of_float_simp real_of_float_0 mult_less_0_iff] by auto
  1236   hence "0 < - ym" by auto
  1237 
  1238   have "\<And>n. 0 \<le> real (Float 1 n)" unfolding real_of_float_simp using zero_le_pow2 by auto
  1239   moreover have "real (rapprox_rat prec xm ym) \<le> 0" using rapprox_rat_nonneg_neg[OF `0 \<le> xm` `ym < 0`] .
  1240   ultimately show "float_divr prec x y \<le> 0"
  1241     unfolding x_eq y_eq float_divr.simps Let_def le_float_def real_of_float_0 real_of_float_mult by (auto intro!: mult_nonneg_nonpos)
  1242 qed
  1243 
  1244 primrec round_down :: "nat \<Rightarrow> float \<Rightarrow> float" where
  1245 "round_down prec (Float m e) = (let d = bitlen m - int prec in
  1246      if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1247               else Float m e)"
  1248 
  1249 primrec round_up :: "nat \<Rightarrow> float \<Rightarrow> float" where
  1250 "round_up prec (Float m e) = (let d = bitlen m - int prec in
  1251   if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P in Float (n + (if r = 0 then 0 else 1)) (e + d) 
  1252            else Float m e)"
  1253 
  1254 lemma round_up: "real x \<le> real (round_up prec x)"
  1255 proof (cases x)
  1256   case (Float m e)
  1257   let ?d = "bitlen m - int prec"
  1258   let ?p = "(2::int)^nat ?d"
  1259   have "0 < ?p" by auto
  1260   show "?thesis"
  1261   proof (cases "0 < ?d")
  1262     case True
  1263     hence pow_d: "pow2 ?d = real ?p" using pow2_int[symmetric] by simp
  1264     show ?thesis
  1265     proof (cases "m mod ?p = 0")
  1266       case True
  1267       have m: "m = m div ?p * ?p + 0" unfolding True[symmetric] using zdiv_zmod_equality2[where k=0, unfolded monoid_add_class.add_0_right, symmetric] .
  1268       have "real (Float m e) = real (Float (m div ?p) (e + ?d))" unfolding real_of_float_simp arg_cong[OF m, of real]
  1269         by (auto simp add: pow2_add `0 < ?d` pow_d)
  1270       thus ?thesis
  1271         unfolding Float round_up.simps Let_def if_P[OF `m mod ?p = 0`] if_P[OF `0 < ?d`]
  1272         by auto
  1273     next
  1274       case False
  1275       have "m = m div ?p * ?p + m mod ?p" unfolding zdiv_zmod_equality2[where k=0, unfolded monoid_add_class.add_0_right] ..
  1276       also have "\<dots> \<le> (m div ?p + 1) * ?p" unfolding left_distrib zmult_1 by (rule add_left_mono, rule pos_mod_bound[OF `0 < ?p`, THEN less_imp_le])
  1277       finally have "real (Float m e) \<le> real (Float (m div ?p + 1) (e + ?d))" unfolding real_of_float_simp add_commute[of e]
  1278         unfolding pow2_add mult_assoc[symmetric] real_of_int_le_iff[of m, symmetric]
  1279         by (auto intro!: mult_mono simp add: pow2_add `0 < ?d` pow_d)
  1280       thus ?thesis
  1281         unfolding Float round_up.simps Let_def if_not_P[OF `\<not> m mod ?p = 0`] if_P[OF `0 < ?d`] .
  1282     qed
  1283   next
  1284     case False
  1285     show ?thesis
  1286       unfolding Float round_up.simps Let_def if_not_P[OF False] .. 
  1287   qed
  1288 qed
  1289 
  1290 lemma round_down: "real (round_down prec x) \<le> real x"
  1291 proof (cases x)
  1292   case (Float m e)
  1293   let ?d = "bitlen m - int prec"
  1294   let ?p = "(2::int)^nat ?d"
  1295   have "0 < ?p" by auto
  1296   show "?thesis"
  1297   proof (cases "0 < ?d")
  1298     case True
  1299     hence pow_d: "pow2 ?d = real ?p" using pow2_int[symmetric] by simp
  1300     have "m div ?p * ?p \<le> m div ?p * ?p + m mod ?p" by (auto simp add: pos_mod_bound[OF `0 < ?p`, THEN less_imp_le])
  1301     also have "\<dots> \<le> m" unfolding zdiv_zmod_equality2[where k=0, unfolded monoid_add_class.add_0_right] ..
  1302     finally have "real (Float (m div ?p) (e + ?d)) \<le> real (Float m e)" unfolding real_of_float_simp add_commute[of e]
  1303       unfolding pow2_add mult_assoc[symmetric] real_of_int_le_iff[of _ m, symmetric]
  1304       by (auto intro!: mult_mono simp add: pow2_add `0 < ?d` pow_d)
  1305     thus ?thesis
  1306       unfolding Float round_down.simps Let_def if_P[OF `0 < ?d`] .
  1307   next
  1308     case False
  1309     show ?thesis
  1310       unfolding Float round_down.simps Let_def if_not_P[OF False] .. 
  1311   qed
  1312 qed
  1313 
  1314 definition lb_mult :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" where
  1315 "lb_mult prec x y = (case normfloat (x * y) of Float m e \<Rightarrow> let
  1316     l = bitlen m - int prec
  1317   in if l > 0 then Float (m div (2^nat l)) (e + l)
  1318               else Float m e)"
  1319 
  1320 definition ub_mult :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" where
  1321 "ub_mult prec x y = (case normfloat (x * y) of Float m e \<Rightarrow> let
  1322     l = bitlen m - int prec
  1323   in if l > 0 then Float (m div (2^nat l) + 1) (e + l)
  1324               else Float m e)"
  1325 
  1326 lemma lb_mult: "real (lb_mult prec x y) \<le> real (x * y)"
  1327 proof (cases "normfloat (x * y)")
  1328   case (Float m e)
  1329   hence "odd m \<or> (m = 0 \<and> e = 0)" by (rule normfloat_imp_odd_or_zero)
  1330   let ?l = "bitlen m - int prec"
  1331   have "real (lb_mult prec x y) \<le> real (normfloat (x * y))"
  1332   proof (cases "?l > 0")
  1333     case False thus ?thesis unfolding lb_mult_def Float Let_def float.cases by auto
  1334   next
  1335     case True
  1336     have "real (m div 2^(nat ?l)) * pow2 ?l \<le> real m"
  1337     proof -
  1338       have "real (m div 2^(nat ?l)) * pow2 ?l = real (2^(nat ?l) * (m div 2^(nat ?l)))" unfolding real_of_int_mult real_of_int_power real_number_of unfolding pow2_int[symmetric] 
  1339         using `?l > 0` by auto
  1340       also have "\<dots> \<le> real (2^(nat ?l) * (m div 2^(nat ?l)) + m mod 2^(nat ?l))" unfolding real_of_int_add by auto
  1341       also have "\<dots> = real m" unfolding zmod_zdiv_equality[symmetric] ..
  1342       finally show ?thesis by auto
  1343     qed
  1344     thus ?thesis unfolding lb_mult_def Float Let_def float.cases if_P[OF True] real_of_float_simp pow2_add mult_commute mult_assoc by auto
  1345   qed
  1346   also have "\<dots> = real (x * y)" unfolding normfloat ..
  1347   finally show ?thesis .
  1348 qed
  1349 
  1350 lemma ub_mult: "real (x * y) \<le> real (ub_mult prec x y)"
  1351 proof (cases "normfloat (x * y)")
  1352   case (Float m e)
  1353   hence "odd m \<or> (m = 0 \<and> e = 0)" by (rule normfloat_imp_odd_or_zero)
  1354   let ?l = "bitlen m - int prec"
  1355   have "real (x * y) = real (normfloat (x * y))" unfolding normfloat ..
  1356   also have "\<dots> \<le> real (ub_mult prec x y)"
  1357   proof (cases "?l > 0")
  1358     case False thus ?thesis unfolding ub_mult_def Float Let_def float.cases by auto
  1359   next
  1360     case True
  1361     have "real m \<le> real (m div 2^(nat ?l) + 1) * pow2 ?l"
  1362     proof -
  1363       have "m mod 2^(nat ?l) < 2^(nat ?l)" by (rule pos_mod_bound) auto
  1364       hence mod_uneq: "real (m mod 2^(nat ?l)) \<le> 1 * 2^(nat ?l)" unfolding zmult_1 real_of_int_less_iff[symmetric] by auto
  1365       
  1366       have "real m = real (2^(nat ?l) * (m div 2^(nat ?l)) + m mod 2^(nat ?l))" unfolding zmod_zdiv_equality[symmetric] ..
  1367       also have "\<dots> = real (m div 2^(nat ?l)) * 2^(nat ?l) + real (m mod 2^(nat ?l))" unfolding real_of_int_add by auto
  1368       also have "\<dots> \<le> (real (m div 2^(nat ?l)) + 1) * 2^(nat ?l)" unfolding left_distrib using mod_uneq by auto
  1369       finally show ?thesis unfolding pow2_int[symmetric] using True by auto
  1370     qed
  1371     thus ?thesis unfolding ub_mult_def Float Let_def float.cases if_P[OF True] real_of_float_simp pow2_add mult_commute mult_assoc by auto
  1372   qed
  1373   finally show ?thesis .
  1374 qed
  1375 
  1376 primrec float_abs :: "float \<Rightarrow> float" where
  1377   "float_abs (Float m e) = Float \<bar>m\<bar> e"
  1378 
  1379 instantiation float :: abs begin
  1380 definition abs_float_def: "\<bar>x\<bar> = float_abs x"
  1381 instance ..
  1382 end
  1383 
  1384 lemma real_of_float_abs: "real \<bar>x :: float\<bar> = \<bar>real x\<bar>" 
  1385 proof (cases x)
  1386   case (Float m e)
  1387   have "\<bar>real m\<bar> * pow2 e = \<bar>real m * pow2 e\<bar>" unfolding abs_mult by auto
  1388   thus ?thesis unfolding Float abs_float_def float_abs.simps real_of_float_simp by auto
  1389 qed
  1390 
  1391 primrec floor_fl :: "float \<Rightarrow> float" where
  1392   "floor_fl (Float m e) = (if 0 \<le> e then Float m e
  1393                                   else Float (m div (2 ^ (nat (-e)))) 0)"
  1394 
  1395 lemma floor_fl: "real (floor_fl x) \<le> real x"
  1396 proof (cases x)
  1397   case (Float m e)
  1398   show ?thesis
  1399   proof (cases "0 \<le> e")
  1400     case False
  1401     hence me_eq: "pow2 (-e) = pow2 (int (nat (-e)))" by auto
  1402     have "real (Float (m div (2 ^ (nat (-e)))) 0) = real (m div 2 ^ (nat (-e)))" unfolding real_of_float_simp by auto
  1403     also have "\<dots> \<le> real m / real ((2::int) ^ (nat (-e)))" using real_of_int_div4 .
  1404     also have "\<dots> = real m * inverse (2 ^ (nat (-e)))" unfolding real_of_int_power real_number_of divide_inverse ..
  1405     also have "\<dots> = real (Float m e)" unfolding real_of_float_simp me_eq pow2_int pow2_neg[of e] ..
  1406     finally show ?thesis unfolding Float floor_fl.simps if_not_P[OF `\<not> 0 \<le> e`] .
  1407   next
  1408     case True thus ?thesis unfolding Float by auto
  1409   qed
  1410 qed
  1411 
  1412 lemma floor_pos_exp: assumes floor: "Float m e = floor_fl x" shows "0 \<le> e"
  1413 proof (cases x)
  1414   case (Float mx me)
  1415   from floor[unfolded Float floor_fl.simps] show ?thesis by (cases "0 \<le> me", auto)
  1416 qed
  1417 
  1418 declare floor_fl.simps[simp del]
  1419 
  1420 primrec ceiling_fl :: "float \<Rightarrow> float" where
  1421   "ceiling_fl (Float m e) = (if 0 \<le> e then Float m e
  1422                                     else Float (m div (2 ^ (nat (-e))) + 1) 0)"
  1423 
  1424 lemma ceiling_fl: "real x \<le> real (ceiling_fl x)"
  1425 proof (cases x)
  1426   case (Float m e)
  1427   show ?thesis
  1428   proof (cases "0 \<le> e")
  1429     case False
  1430     hence me_eq: "pow2 (-e) = pow2 (int (nat (-e)))" by auto
  1431     have "real (Float m e) = real m * inverse (2 ^ (nat (-e)))" unfolding real_of_float_simp me_eq pow2_int pow2_neg[of e] ..
  1432     also have "\<dots> = real m / real ((2::int) ^ (nat (-e)))" unfolding real_of_int_power real_number_of divide_inverse ..
  1433     also have "\<dots> \<le> 1 + real (m div 2 ^ (nat (-e)))" using real_of_int_div3[unfolded diff_le_eq] .
  1434     also have "\<dots> = real (Float (m div (2 ^ (nat (-e))) + 1) 0)" unfolding real_of_float_simp by auto
  1435     finally show ?thesis unfolding Float ceiling_fl.simps if_not_P[OF `\<not> 0 \<le> e`] .
  1436   next
  1437     case True thus ?thesis unfolding Float by auto
  1438   qed
  1439 qed
  1440 
  1441 declare ceiling_fl.simps[simp del]
  1442 
  1443 definition lb_mod :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" where
  1444 "lb_mod prec x ub lb = x - ceiling_fl (float_divr prec x lb) * ub"
  1445 
  1446 definition ub_mod :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" where
  1447 "ub_mod prec x ub lb = x - floor_fl (float_divl prec x ub) * lb"
  1448 
  1449 lemma lb_mod: fixes k :: int assumes "0 \<le> real x" and "real k * y \<le> real x" (is "?k * y \<le> ?x")
  1450   assumes "0 < real lb" "real lb \<le> y" (is "?lb \<le> y") "y \<le> real ub" (is "y \<le> ?ub")
  1451   shows "real (lb_mod prec x ub lb) \<le> ?x - ?k * y"
  1452 proof -
  1453   have "?lb \<le> ?ub" using assms by auto
  1454   have "0 \<le> ?lb" and "?lb \<noteq> 0" using assms by auto
  1455   have "?k * y \<le> ?x" using assms by auto
  1456   also have "\<dots> \<le> ?x / ?lb * ?ub" by (metis mult_left_mono[OF `?lb \<le> ?ub` `0 \<le> ?x`] divide_right_mono[OF _ `0 \<le> ?lb` ] times_divide_eq_left nonzero_mult_divide_cancel_right[OF `?lb \<noteq> 0`])
  1457   also have "\<dots> \<le> real (ceiling_fl (float_divr prec x lb)) * ?ub" by (metis mult_right_mono order_trans `0 \<le> ?lb` `?lb \<le> ?ub` float_divr ceiling_fl)
  1458   finally show ?thesis unfolding lb_mod_def real_of_float_sub real_of_float_mult by auto
  1459 qed
  1460 
  1461 lemma ub_mod: fixes k :: int and x :: float assumes "0 \<le> real x" and "real x \<le> real k * y" (is "?x \<le> ?k * y")
  1462   assumes "0 < real lb" "real lb \<le> y" (is "?lb \<le> y") "y \<le> real ub" (is "y \<le> ?ub")
  1463   shows "?x - ?k * y \<le> real (ub_mod prec x ub lb)"
  1464 proof -
  1465   have "?lb \<le> ?ub" using assms by auto
  1466   hence "0 \<le> ?lb" and "0 \<le> ?ub" and "?ub \<noteq> 0" using assms by auto
  1467   have "real (floor_fl (float_divl prec x ub)) * ?lb \<le> ?x / ?ub * ?lb" by (metis mult_right_mono order_trans `0 \<le> ?lb` `?lb \<le> ?ub` float_divl floor_fl)
  1468   also have "\<dots> \<le> ?x" by (metis mult_left_mono[OF `?lb \<le> ?ub` `0 \<le> ?x`] divide_right_mono[OF _ `0 \<le> ?ub` ] times_divide_eq_left nonzero_mult_divide_cancel_right[OF `?ub \<noteq> 0`])
  1469   also have "\<dots> \<le> ?k * y" using assms by auto
  1470   finally show ?thesis unfolding ub_mod_def real_of_float_sub real_of_float_mult by auto
  1471 qed
  1472 
  1473 lemma le_float_def'[code]: "f \<le> g = (case f - g of Float a b \<Rightarrow> a \<le> 0)"
  1474 proof -
  1475   have le_transfer: "(f \<le> g) = (real (f - g) \<le> 0)" by (auto simp add: le_float_def)
  1476   from float_split[of "f - g"] obtain a b where f_diff_g: "f - g = Float a b" by auto
  1477   with le_transfer have le_transfer': "f \<le> g = (real (Float a b) \<le> 0)" by simp
  1478   show ?thesis by (simp add: le_transfer' f_diff_g float_le_zero)
  1479 qed
  1480 
  1481 lemma less_float_def'[code]: "f < g = (case f - g of Float a b \<Rightarrow> a < 0)"
  1482 proof -
  1483   have less_transfer: "(f < g) = (real (f - g) < 0)" by (auto simp add: less_float_def)
  1484   from float_split[of "f - g"] obtain a b where f_diff_g: "f - g = Float a b" by auto
  1485   with less_transfer have less_transfer': "f < g = (real (Float a b) < 0)" by simp
  1486   show ?thesis by (simp add: less_transfer' f_diff_g float_less_zero)
  1487 qed
  1488 
  1489 end