src/Pure/drule.ML
author wenzelm
Sun Oct 28 19:44:58 2001 +0100 (2001-10-28)
changeset 11975 129c6679e8c4
parent 11960 58ffa8bec4da
child 11997 402ae1a172ae
permissions -rw-r--r--
rules for meta-level conjunction;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val forall_elim_vars_safe  : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val standard'         : thm -> thm
    43   val rotate_prems      : int -> thm -> thm
    44   val rearrange_prems   : int list -> thm -> thm
    45   val assume_ax         : theory -> string -> thm
    46   val RSN               : thm * (int * thm) -> thm
    47   val RS                : thm * thm -> thm
    48   val RLN               : thm list * (int * thm list) -> thm list
    49   val RL                : thm list * thm list -> thm list
    50   val MRS               : thm list * thm -> thm
    51   val MRL               : thm list list * thm list -> thm list
    52   val OF                : thm * thm list -> thm
    53   val compose           : thm * int * thm -> thm list
    54   val COMP              : thm * thm -> thm
    55   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    56   val read_instantiate  : (string*string)list -> thm -> thm
    57   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    58   val weak_eq_thm       : thm * thm -> bool
    59   val eq_thm_sg         : thm * thm -> bool
    60   val size_of_thm       : thm -> int
    61   val reflexive_thm     : thm
    62   val symmetric_thm     : thm
    63   val transitive_thm    : thm
    64   val refl_implies      : thm
    65   val symmetric_fun     : thm -> thm
    66   val extensional       : thm -> thm
    67   val imp_cong          : thm
    68   val swap_prems_eq     : thm
    69   val equal_abs_elim    : cterm  -> thm -> thm
    70   val equal_abs_elim_list: cterm list -> thm -> thm
    71   val flexpair_abs_elim_list: cterm list -> thm -> thm
    72   val asm_rl            : thm
    73   val cut_rl            : thm
    74   val revcut_rl         : thm
    75   val thin_rl           : thm
    76   val triv_forall_equality: thm
    77   val swap_prems_rl     : thm
    78   val equal_intr_rule   : thm
    79   val inst              : string -> string -> thm -> thm
    80   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    81   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    82 end;
    83 
    84 signature DRULE =
    85 sig
    86   include BASIC_DRULE
    87   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    88   val tag_rule: tag -> thm -> thm
    89   val untag_rule: string -> thm -> thm
    90   val tag: tag -> 'a attribute
    91   val untag: string -> 'a attribute
    92   val get_kind: thm -> string
    93   val kind: string -> 'a attribute
    94   val theoremK: string
    95   val lemmaK: string
    96   val corollaryK: string
    97   val internalK: string
    98   val kind_internal: 'a attribute
    99   val has_internal: tag list -> bool
   100   val impose_hyps: cterm list -> thm -> thm
   101   val close_derivation: thm -> thm
   102   val compose_single: thm * int * thm -> thm
   103   val add_rules: thm list -> thm list -> thm list
   104   val del_rules: thm list -> thm list -> thm list
   105   val merge_rules: thm list * thm list -> thm list
   106   val norm_hhf_eq: thm
   107   val triv_goal: thm
   108   val rev_triv_goal: thm
   109   val implies_intr_goals: cterm list -> thm -> thm
   110   val freeze_all: thm -> thm
   111   val mk_triv_goal: cterm -> thm
   112   val tvars_of_terms: term list -> (indexname * sort) list
   113   val vars_of_terms: term list -> (indexname * typ) list
   114   val tvars_of: thm -> (indexname * sort) list
   115   val vars_of: thm -> (indexname * typ) list
   116   val unvarifyT: thm -> thm
   117   val unvarify: thm -> thm
   118   val tvars_intr_list: string list -> thm -> thm
   119   val conj_intr: thm -> thm -> thm
   120   val conj_intr_list: thm list -> thm
   121   val conj_elim: thm -> thm * thm
   122   val conj_elim_list: thm -> thm list
   123 end;
   124 
   125 structure Drule: DRULE =
   126 struct
   127 
   128 
   129 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   130 
   131 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   132 
   133 (*dest_implies for cterms. Note T=prop below*)
   134 fun dest_implies ct =
   135     case term_of ct of
   136         (Const("==>", _) $ _ $ _) =>
   137             let val (ct1,ct2) = Thm.dest_comb ct
   138             in  (#2 (Thm.dest_comb ct1), ct2)  end
   139       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   140 
   141 fun dest_equals ct =
   142     case term_of ct of
   143         (Const("==", _) $ _ $ _) =>
   144             let val (ct1,ct2) = Thm.dest_comb ct
   145             in  (#2 (Thm.dest_comb ct1), ct2)  end
   146       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   147 
   148 
   149 (*Discard flexflex pairs; return a cterm*)
   150 fun skip_flexpairs ct =
   151     case term_of ct of
   152         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   153             skip_flexpairs (#2 (dest_implies ct))
   154       | _ => ct;
   155 
   156 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   157 fun strip_imp_prems ct =
   158     let val (cA,cB) = dest_implies ct
   159     in  cA :: strip_imp_prems cB  end
   160     handle TERM _ => [];
   161 
   162 (* A1==>...An==>B  goes to B, where B is not an implication *)
   163 fun strip_imp_concl ct =
   164     case term_of ct of (Const("==>", _) $ _ $ _) =>
   165         strip_imp_concl (#2 (Thm.dest_comb ct))
   166   | _ => ct;
   167 
   168 (*The premises of a theorem, as a cterm list*)
   169 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   170 
   171 val proto_sign = Theory.sign_of ProtoPure.thy;
   172 
   173 val implies = cterm_of proto_sign Term.implies;
   174 
   175 (*cterm version of mk_implies*)
   176 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   177 
   178 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   179 fun list_implies([], B) = B
   180   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   181 
   182 
   183 (** reading of instantiations **)
   184 
   185 fun absent ixn =
   186   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   187 
   188 fun inst_failure ixn =
   189   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   190 
   191 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   192 let
   193     fun split([],tvs,vs) = (tvs,vs)
   194       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   195                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   196                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   197     val (tvs,vs) = split(insts,[],[]);
   198     fun readT((a,i),st) =
   199         let val ixn = ("'" ^ a,i);
   200             val S = case rsorts ixn of Some S => S | None => absent ixn;
   201             val T = Sign.read_typ (sign,sorts) st;
   202         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   203            else inst_failure ixn
   204         end
   205     val tye = map readT tvs;
   206     fun mkty(ixn,st) = (case rtypes ixn of
   207                           Some T => (ixn,(st,typ_subst_TVars tye T))
   208                         | None => absent ixn);
   209     val ixnsTs = map mkty vs;
   210     val ixns = map fst ixnsTs
   211     and sTs  = map snd ixnsTs
   212     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   213     fun mkcVar(ixn,T) =
   214         let val U = typ_subst_TVars tye2 T
   215         in cterm_of sign (Var(ixn,U)) end
   216     val ixnTs = ListPair.zip(ixns, map snd sTs)
   217 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   218     ListPair.zip(map mkcVar ixnTs,cts))
   219 end;
   220 
   221 
   222 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   223      Used for establishing default types (of variables) and sorts (of
   224      type variables) when reading another term.
   225      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   226 ***)
   227 
   228 fun types_sorts thm =
   229     let val {prop,hyps,...} = rep_thm thm;
   230         val big = list_comb(prop,hyps); (* bogus term! *)
   231         val vars = map dest_Var (term_vars big);
   232         val frees = map dest_Free (term_frees big);
   233         val tvars = term_tvars big;
   234         val tfrees = term_tfrees big;
   235         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   236         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   237     in (typ,sort) end;
   238 
   239 
   240 
   241 (** basic attributes **)
   242 
   243 (* dependent rules *)
   244 
   245 fun rule_attribute f (x, thm) = (x, (f x thm));
   246 
   247 
   248 (* add / delete tags *)
   249 
   250 fun map_tags f thm =
   251   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   252 
   253 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   254 fun untag_rule s = map_tags (filter_out (equal s o #1));
   255 
   256 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   257 fun untag s x = rule_attribute (K (untag_rule s)) x;
   258 
   259 fun simple_tag name x = tag (name, []) x;
   260 
   261 
   262 (* theorem kinds *)
   263 
   264 val theoremK = "theorem";
   265 val lemmaK = "lemma";
   266 val corollaryK = "corollary";
   267 val internalK = "internal";
   268 
   269 fun get_kind thm =
   270   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   271     Some (k :: _) => k
   272   | _ => "unknown");
   273 
   274 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   275 fun kind k x = rule_attribute (K (kind_rule k)) x;
   276 fun kind_internal x = kind internalK x;
   277 fun has_internal tags = exists (equal internalK o fst) tags;
   278 
   279 
   280 
   281 (** Standardization of rules **)
   282 
   283 (*Strip extraneous shyps as far as possible*)
   284 fun strip_shyps_warning thm =
   285   let
   286     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   287     val thm' = Thm.strip_shyps thm;
   288     val xshyps = Thm.extra_shyps thm';
   289   in
   290     if null xshyps then ()
   291     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   292     thm'
   293   end;
   294 
   295 (*Generalization over a list of variables, IGNORING bad ones*)
   296 fun forall_intr_list [] th = th
   297   | forall_intr_list (y::ys) th =
   298         let val gth = forall_intr_list ys th
   299         in  forall_intr y gth   handle THM _ =>  gth  end;
   300 
   301 (*Generalization over all suitable Free variables*)
   302 fun forall_intr_frees th =
   303     let val {prop,sign,...} = rep_thm th
   304     in  forall_intr_list
   305          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   306          th
   307     end;
   308 
   309 val forall_elim_var = PureThy.forall_elim_var;
   310 val forall_elim_vars = PureThy.forall_elim_vars;
   311 
   312 fun forall_elim_vars_safe th =
   313   forall_elim_vars_safe (forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th)
   314     handle THM _ => th;
   315 
   316 
   317 (*Specialization over a list of cterms*)
   318 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   319 
   320 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   321 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   322 
   323 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   324 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   325 
   326 (* maps |- B to A1,...,An |- B *)
   327 fun impose_hyps chyps th =
   328   implies_elim_list (implies_intr_list chyps th) (map Thm.assume chyps);
   329 
   330 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   331 fun zero_var_indexes th =
   332     let val {prop,sign,...} = rep_thm th;
   333         val vars = term_vars prop
   334         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   335         val inrs = add_term_tvars(prop,[]);
   336         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   337         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   338                      (inrs, nms')
   339         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   340         fun varpairs([],[]) = []
   341           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   342                 let val T' = typ_subst_TVars tye T
   343                 in (cterm_of sign (Var(v,T')),
   344                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   345                 end
   346           | varpairs _ = raise TERM("varpairs", []);
   347     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   348 
   349 
   350 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   351     all generality expressed by Vars having index 0.*)
   352 
   353 fun close_derivation thm =
   354   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   355   else thm;
   356 
   357 fun standard' th =
   358   let val {maxidx,...} = rep_thm th in
   359     th
   360     |> implies_intr_hyps
   361     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   362     |> strip_shyps_warning
   363     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   364   end;
   365 
   366 val standard = close_derivation o standard';
   367 
   368 
   369 (*Convert all Vars in a theorem to Frees.  Also return a function for
   370   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   371   Similar code in type/freeze_thaw*)
   372 fun freeze_thaw th =
   373  let val fth = freezeT th
   374      val {prop,sign,...} = rep_thm fth
   375  in
   376    case term_vars prop of
   377        [] => (fth, fn x => x)
   378      | vars =>
   379          let fun newName (Var(ix,_), (pairs,used)) =
   380                    let val v = variant used (string_of_indexname ix)
   381                    in  ((ix,v)::pairs, v::used)  end;
   382              val (alist, _) = foldr newName
   383                                 (vars, ([], add_term_names (prop, [])))
   384              fun mk_inst (Var(v,T)) =
   385                  (cterm_of sign (Var(v,T)),
   386                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   387              val insts = map mk_inst vars
   388              fun thaw th' =
   389                  th' |> forall_intr_list (map #2 insts)
   390                      |> forall_elim_list (map #1 insts)
   391          in  (Thm.instantiate ([],insts) fth, thaw)  end
   392  end;
   393 
   394 
   395 (*Rotates a rule's premises to the left by k*)
   396 val rotate_prems = permute_prems 0;
   397 
   398 (* permute prems, where the i-th position in the argument list (counting from 0)
   399    gives the position within the original thm to be transferred to position i.
   400    Any remaining trailing positions are left unchanged. *)
   401 val rearrange_prems = let
   402   fun rearr new []      thm = thm
   403   |   rearr new (p::ps) thm = rearr (new+1)
   404      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   405      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   406   in rearr 0 end;
   407 
   408 (*Assume a new formula, read following the same conventions as axioms.
   409   Generalizes over Free variables,
   410   creates the assumption, and then strips quantifiers.
   411   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   412              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   413 fun assume_ax thy sP =
   414     let val sign = Theory.sign_of thy
   415         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   416     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   417 
   418 (*Resolution: exactly one resolvent must be produced.*)
   419 fun tha RSN (i,thb) =
   420   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   421       ([th],_) => th
   422     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   423     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   424 
   425 (*resolution: P==>Q, Q==>R gives P==>R. *)
   426 fun tha RS thb = tha RSN (1,thb);
   427 
   428 (*For joining lists of rules*)
   429 fun thas RLN (i,thbs) =
   430   let val resolve = biresolution false (map (pair false) thas) i
   431       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   432   in  List.concat (map resb thbs)  end;
   433 
   434 fun thas RL thbs = thas RLN (1,thbs);
   435 
   436 (*Resolve a list of rules against bottom_rl from right to left;
   437   makes proof trees*)
   438 fun rls MRS bottom_rl =
   439   let fun rs_aux i [] = bottom_rl
   440         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   441   in  rs_aux 1 rls  end;
   442 
   443 (*As above, but for rule lists*)
   444 fun rlss MRL bottom_rls =
   445   let fun rs_aux i [] = bottom_rls
   446         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   447   in  rs_aux 1 rlss  end;
   448 
   449 (*A version of MRS with more appropriate argument order*)
   450 fun bottom_rl OF rls = rls MRS bottom_rl;
   451 
   452 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   453   with no lifting or renaming!  Q may contain ==> or meta-quants
   454   ALWAYS deletes premise i *)
   455 fun compose(tha,i,thb) =
   456     Seq.list_of (bicompose false (false,tha,0) i thb);
   457 
   458 fun compose_single (tha,i,thb) =
   459   (case compose (tha,i,thb) of
   460     [th] => th
   461   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   462 
   463 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   464 fun tha COMP thb =
   465     case compose(tha,1,thb) of
   466         [th] => th
   467       | _ =>   raise THM("COMP", 1, [tha,thb]);
   468 
   469 (** theorem equality **)
   470 
   471 (*Do the two theorems have the same signature?*)
   472 fun eq_thm_sg (th1,th2) = Sign.eq_sg(#sign(rep_thm th1), #sign(rep_thm th2));
   473 
   474 (*Useful "distance" function for BEST_FIRST*)
   475 val size_of_thm = size_of_term o #prop o rep_thm;
   476 
   477 (*maintain lists of theorems --- preserving canonical order*)
   478 fun del_rules rs rules = Library.gen_rems Thm.eq_thm (rules, rs);
   479 fun add_rules rs rules = rs @ del_rules rs rules;
   480 fun merge_rules (rules1, rules2) = Library.generic_merge Thm.eq_thm I I rules1 rules2;
   481 
   482 
   483 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   484     (some) type variable renaming **)
   485 
   486  (* Can't use term_vars, because it sorts the resulting list of variable names.
   487     We instead need the unique list noramlised by the order of appearance
   488     in the term. *)
   489 fun term_vars' (t as Var(v,T)) = [t]
   490   | term_vars' (Abs(_,_,b)) = term_vars' b
   491   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   492   | term_vars' _ = [];
   493 
   494 fun forall_intr_vars th =
   495   let val {prop,sign,...} = rep_thm th;
   496       val vars = distinct (term_vars' prop);
   497   in forall_intr_list (map (cterm_of sign) vars) th end;
   498 
   499 fun weak_eq_thm (tha,thb) =
   500     eq_thm(forall_intr_vars (freezeT tha), forall_intr_vars (freezeT thb));
   501 
   502 
   503 
   504 (*** Meta-Rewriting Rules ***)
   505 
   506 fun read_prop s = read_cterm proto_sign (s, propT);
   507 
   508 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   509 fun store_standard_thm name thm = store_thm name (standard thm);
   510 fun open_store_thm name thm = hd (PureThy.open_smart_store_thms (name, [thm]));
   511 fun open_store_standard_thm name thm = open_store_thm name (standard' thm);
   512 
   513 val reflexive_thm =
   514   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   515   in store_standard_thm "reflexive" (Thm.reflexive cx) end;
   516 
   517 val symmetric_thm =
   518   let val xy = read_prop "x::'a::logic == y"
   519   in store_standard_thm "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   520 
   521 val transitive_thm =
   522   let val xy = read_prop "x::'a::logic == y"
   523       val yz = read_prop "y::'a::logic == z"
   524       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   525   in store_standard_thm "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   526 
   527 fun symmetric_fun thm = thm RS symmetric_thm;
   528 
   529 fun extensional eq =
   530   let val eq' =
   531     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   532   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   533 
   534 val imp_cong =
   535   let
   536     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   537     val AB = read_prop "PROP A ==> PROP B"
   538     val AC = read_prop "PROP A ==> PROP C"
   539     val A = read_prop "PROP A"
   540   in
   541     open_store_standard_thm "imp_cong" (implies_intr ABC (equal_intr
   542       (implies_intr AB (implies_intr A
   543         (equal_elim (implies_elim (assume ABC) (assume A))
   544           (implies_elim (assume AB) (assume A)))))
   545       (implies_intr AC (implies_intr A
   546         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   547           (implies_elim (assume AC) (assume A)))))))
   548   end;
   549 
   550 val swap_prems_eq =
   551   let
   552     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   553     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   554     val A = read_prop "PROP A"
   555     val B = read_prop "PROP B"
   556   in
   557     open_store_standard_thm "swap_prems_eq" (equal_intr
   558       (implies_intr ABC (implies_intr B (implies_intr A
   559         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   560       (implies_intr BAC (implies_intr A (implies_intr B
   561         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   562   end;
   563 
   564 val refl_implies = reflexive implies;
   565 
   566 
   567 (*** Some useful meta-theorems ***)
   568 
   569 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   570 val asm_rl = open_store_standard_thm "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   571 val _ = store_thm "_" asm_rl;
   572 
   573 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   574 val cut_rl =
   575   open_store_standard_thm "cut_rl"
   576     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   577 
   578 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   579      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   580 val revcut_rl =
   581   let val V = read_prop "PROP V"
   582       and VW = read_prop "PROP V ==> PROP W";
   583   in
   584     open_store_standard_thm "revcut_rl"
   585       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   586   end;
   587 
   588 (*for deleting an unwanted assumption*)
   589 val thin_rl =
   590   let val V = read_prop "PROP V"
   591       and W = read_prop "PROP W";
   592   in  open_store_standard_thm "thin_rl" (implies_intr V (implies_intr W (assume W)))
   593   end;
   594 
   595 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   596 val triv_forall_equality =
   597   let val V  = read_prop "PROP V"
   598       and QV = read_prop "!!x::'a. PROP V"
   599       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   600   in
   601     open_store_standard_thm "triv_forall_equality"
   602       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   603         (implies_intr V  (forall_intr x (assume V))))
   604   end;
   605 
   606 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   607    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   608    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   609 *)
   610 val swap_prems_rl =
   611   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   612       val major = assume cmajor;
   613       val cminor1 = read_prop "PROP PhiA";
   614       val minor1 = assume cminor1;
   615       val cminor2 = read_prop "PROP PhiB";
   616       val minor2 = assume cminor2;
   617   in open_store_standard_thm "swap_prems_rl"
   618        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   619          (implies_elim (implies_elim major minor1) minor2))))
   620   end;
   621 
   622 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   623    ==> PROP ?phi == PROP ?psi
   624    Introduction rule for == as a meta-theorem.
   625 *)
   626 val equal_intr_rule =
   627   let val PQ = read_prop "PROP phi ==> PROP psi"
   628       and QP = read_prop "PROP psi ==> PROP phi"
   629   in
   630     open_store_standard_thm "equal_intr_rule"
   631       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   632   end;
   633 
   634 
   635 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   636   Rewrite rule for HHF normalization.
   637 *)
   638 
   639 val norm_hhf_eq =
   640   let
   641     val cert = Thm.cterm_of proto_sign;
   642     val aT = TFree ("'a", Term.logicS);
   643     val all = Term.all aT;
   644     val x = Free ("x", aT);
   645     val phi = Free ("phi", propT);
   646     val psi = Free ("psi", aT --> propT);
   647 
   648     val cx = cert x;
   649     val cphi = cert phi;
   650     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   651     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   652   in
   653     Thm.equal_intr
   654       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   655         |> Thm.forall_elim cx
   656         |> Thm.implies_intr cphi
   657         |> Thm.forall_intr cx
   658         |> Thm.implies_intr lhs)
   659       (Thm.implies_elim
   660           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   661         |> Thm.forall_intr cx
   662         |> Thm.implies_intr cphi
   663         |> Thm.implies_intr rhs)
   664     |> store_standard_thm "norm_hhf_eq"
   665   end;
   666 
   667 
   668 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   669 
   670 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   671 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   672 
   673 fun read_instantiate_sg sg sinsts th =
   674     let val ts = types_sorts th;
   675         val used = add_term_tvarnames(#prop(rep_thm th),[]);
   676     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   677 
   678 (*Instantiate theorem th, reading instantiations under theory of th*)
   679 fun read_instantiate sinsts th =
   680     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   681 
   682 
   683 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   684   Instantiates distinct Vars by terms, inferring type instantiations. *)
   685 local
   686   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   687     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   688         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   689         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   690         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   691         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) maxi tye (T,U)
   692           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   693     in  (sign', tye', maxi')  end;
   694 in
   695 fun cterm_instantiate ctpairs0 th =
   696   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   697       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   698                          in (cterm_fun inst ct, cterm_fun inst cu) end
   699       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   700   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   701   handle TERM _ =>
   702            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   703        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   704 end;
   705 
   706 
   707 (** Derived rules mainly for METAHYPS **)
   708 
   709 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   710 fun equal_abs_elim ca eqth =
   711   let val {sign=signa, t=a, ...} = rep_cterm ca
   712       and combth = combination eqth (reflexive ca)
   713       val {sign,prop,...} = rep_thm eqth
   714       val (abst,absu) = Logic.dest_equals prop
   715       val cterm = cterm_of (Sign.merge (sign,signa))
   716   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   717            (transitive combth (beta_conversion false (cterm (absu$a))))
   718   end
   719   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   720 
   721 (*Calling equal_abs_elim with multiple terms*)
   722 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   723 
   724 local
   725   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   726   fun err th = raise THM("flexpair_inst: ", 0, [th])
   727   fun flexpair_inst def th =
   728     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   729         val cterm = cterm_of sign
   730         fun cvar a = cterm(Var((a,0),alpha))
   731         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   732                    def
   733     in  equal_elim def' th
   734     end
   735     handle THM _ => err th | Bind => err th
   736 in
   737 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   738 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   739 end;
   740 
   741 (*Version for flexflex pairs -- this supports lifting.*)
   742 fun flexpair_abs_elim_list cts =
   743     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   744 
   745 
   746 (*** Goal (PROP A) <==> PROP A ***)
   747 
   748 local
   749   val cert = Thm.cterm_of proto_sign;
   750   val A = Free ("A", propT);
   751   val G = Logic.mk_goal A;
   752   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   753 in
   754   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   755       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   756   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   757       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   758 end;
   759 
   760 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   761 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   762 
   763 fun implies_intr_goals cprops thm =
   764   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   765   |> implies_intr_list (map mk_cgoal cprops);
   766 
   767 
   768 
   769 (** variations on instantiate **)
   770 
   771 (*shorthand for instantiating just one variable in the current theory*)
   772 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   773 
   774 
   775 (* collect vars *)
   776 
   777 val add_tvarsT = foldl_atyps (fn (vs, TVar v) => v ins vs | (vs, _) => vs);
   778 val add_tvars = foldl_types add_tvarsT;
   779 val add_vars = foldl_aterms (fn (vs, Var v) => v ins vs | (vs, _) => vs);
   780 
   781 fun tvars_of_terms ts = rev (foldl add_tvars ([], ts));
   782 fun vars_of_terms ts = rev (foldl add_vars ([], ts));
   783 
   784 fun tvars_of thm = tvars_of_terms [#prop (Thm.rep_thm thm)];
   785 fun vars_of thm = vars_of_terms [#prop (Thm.rep_thm thm)];
   786 
   787 
   788 (* instantiate by left-to-right occurrence of variables *)
   789 
   790 fun instantiate' cTs cts thm =
   791   let
   792     fun err msg =
   793       raise TYPE ("instantiate': " ^ msg,
   794         mapfilter (apsome Thm.typ_of) cTs,
   795         mapfilter (apsome Thm.term_of) cts);
   796 
   797     fun inst_of (v, ct) =
   798       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   799         handle TYPE (msg, _, _) => err msg;
   800 
   801     fun zip_vars _ [] = []
   802       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   803       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   804       | zip_vars [] _ = err "more instantiations than variables in thm";
   805 
   806     (*instantiate types first!*)
   807     val thm' =
   808       if forall is_none cTs then thm
   809       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   810     in
   811       if forall is_none cts then thm'
   812       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   813     end;
   814 
   815 
   816 (* unvarify(T) *)
   817 
   818 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   819 
   820 fun unvarifyT thm =
   821   let
   822     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   823     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   824   in instantiate' tfrees [] thm end;
   825 
   826 fun unvarify raw_thm =
   827   let
   828     val thm = unvarifyT raw_thm;
   829     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   830     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   831   in instantiate' [] frees thm end;
   832 
   833 
   834 (* tvars_intr_list *)
   835 
   836 fun tfrees_of thm =
   837   let val {hyps, prop, ...} = Thm.rep_thm thm
   838   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   839 
   840 fun tvars_intr_list tfrees thm =
   841   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   842 
   843 
   844 (* increment var indexes *)
   845 
   846 fun incr_indexes_wrt is cTs cts thms =
   847   let
   848     val maxidx =
   849       foldl Int.max (~1, is @
   850         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   851         map (#maxidx o Thm.rep_cterm) cts @
   852         map (#maxidx o Thm.rep_thm) thms);
   853   in Thm.incr_indexes (maxidx + 1) end;
   854 
   855 
   856 (* freeze_all *)
   857 
   858 (*freeze all (T)Vars; assumes thm in standard form*)
   859 
   860 fun freeze_all_TVars thm =
   861   (case tvars_of thm of
   862     [] => thm
   863   | tvars =>
   864       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   865       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   866 
   867 fun freeze_all_Vars thm =
   868   (case vars_of thm of
   869     [] => thm
   870   | vars =>
   871       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   872       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   873 
   874 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   875 
   876 
   877 (* mk_triv_goal *)
   878 
   879 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   880 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   881 
   882 
   883 
   884 (** meta-level conjunction **)
   885 
   886 local
   887   val A = read_prop "PROP A";
   888   val B = read_prop "PROP B";
   889   val C = read_prop "PROP C";
   890   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   891 
   892   val proj1 =
   893     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   894     |> forall_elim_vars 0;
   895 
   896   val proj2 =
   897     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   898     |> forall_elim_vars 0;
   899 
   900   val conj_intr_rule =
   901     forall_intr_list [A, B] (implies_intr_list [A, B]
   902       (Thm.forall_intr C (Thm.implies_intr ABC
   903         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   904     |> forall_elim_vars 0;
   905 
   906   val incr = incr_indexes_wrt [] [] [];
   907 in
   908 
   909 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   910 val conj_intr_list = foldr1 (uncurry conj_intr);
   911 
   912 fun conj_elim th =
   913   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   914   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   915 
   916 fun conj_elim_list th =
   917   let val (th1, th2) = conj_elim th
   918   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   919 
   920 end;
   921 
   922 end;
   923 
   924 structure BasicDrule: BASIC_DRULE = Drule;
   925 open BasicDrule;