src/Pure/Isar/class_declaration.ML
author wenzelm
Wed Nov 09 22:43:14 2011 +0100 (2011-11-09)
changeset 45432 12cc89f1eb0c
parent 45431 924c2f6dcd05
child 45433 4283f3a57cf5
permissions -rw-r--r--
clarified singleton_fixate: intersection with supersort is identity, only replace actual type inference parameters;
tuned reject_other, after_infer_fixate;
     1 (*  Title:      Pure/Isar/class_declaration.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Declaring classes and subclass relations.
     5 *)
     6 
     7 signature CLASS_DECLARATION =
     8 sig
     9   val class: (local_theory -> local_theory) -> binding -> class list ->
    10     Element.context_i list -> theory -> string * local_theory
    11   val class_cmd: (local_theory -> local_theory) -> binding -> xstring list ->
    12     Element.context list -> theory -> string * local_theory
    13   val prove_subclass: (local_theory -> local_theory) -> tactic -> class ->
    14     local_theory -> local_theory
    15   val subclass: (local_theory -> local_theory) -> class -> local_theory -> Proof.state
    16   val subclass_cmd: (local_theory -> local_theory) -> xstring -> local_theory -> Proof.state
    17 end;
    18 
    19 structure Class_Declaration: CLASS_DECLARATION =
    20 struct
    21 
    22 (** class definitions **)
    23 
    24 local
    25 
    26 (* calculating class-related rules including canonical interpretation *)
    27 
    28 fun calculate thy class sups base_sort param_map assm_axiom =
    29   let
    30     val empty_ctxt = Proof_Context.init_global thy;
    31 
    32     (* instantiation of canonical interpretation *)
    33     val aT = TFree (Name.aT, base_sort);
    34     val param_map_const = (map o apsnd) Const param_map;
    35     val param_map_inst = (map o apsnd)
    36       (Const o apsnd (map_atyps (K aT))) param_map;
    37     val const_morph = Element.inst_morphism thy
    38       (Symtab.empty, Symtab.make param_map_inst);
    39     val typ_morph = Element.inst_morphism thy
    40       (Symtab.empty |> Symtab.update (Name.aT, TFree (Name.aT, [class])), Symtab.empty);
    41     val (([raw_props], [(_, raw_inst_morph)], export_morph), _) = empty_ctxt
    42       |> Expression.cert_goal_expression ([(class, (("", false),
    43            Expression.Named param_map_const))], []);
    44     val (props, inst_morph) =
    45       if null param_map
    46       then (raw_props |> map (Morphism.term typ_morph),
    47         raw_inst_morph $> typ_morph)
    48       else (raw_props, raw_inst_morph); (*FIXME proper handling in
    49         locale.ML / expression.ML would be desirable*)
    50 
    51     (* witness for canonical interpretation *)
    52     val prop = try the_single props;
    53     val wit = Option.map (fn prop =>
    54       let
    55         val sup_axioms = map_filter (fst o Class.rules thy) sups;
    56         val loc_intro_tac =
    57           (case Locale.intros_of thy class of
    58             (_, NONE) => all_tac
    59           | (_, SOME intro) => ALLGOALS (Tactic.rtac intro));
    60         val tac = loc_intro_tac
    61           THEN ALLGOALS (Proof_Context.fact_tac (sup_axioms @ the_list assm_axiom));
    62       in Element.prove_witness empty_ctxt prop tac end) prop;
    63     val axiom = Option.map Element.conclude_witness wit;
    64 
    65     (* canonical interpretation *)
    66     val base_morph = inst_morph
    67       $> Morphism.binding_morphism (Binding.prefix false (Class.class_prefix class))
    68       $> Element.satisfy_morphism (the_list wit);
    69     val eq_morph = Element.eq_morphism thy (Class.these_defs thy sups);
    70 
    71     (* assm_intro *)
    72     fun prove_assm_intro thm =
    73       let
    74         val ((_, [thm']), _) = Variable.import true [thm] empty_ctxt;
    75         val const_eq_morph =
    76           (case eq_morph of
    77              SOME eq_morph => const_morph $> eq_morph
    78           | NONE => const_morph);
    79         val thm'' = Morphism.thm const_eq_morph thm';
    80         val tac = ALLGOALS (Proof_Context.fact_tac [thm'']);
    81       in Skip_Proof.prove_global thy [] [] (Thm.prop_of thm'') (K tac) end;
    82     val assm_intro = Option.map prove_assm_intro
    83       (fst (Locale.intros_of thy class));
    84 
    85     (* of_class *)
    86     val of_class_prop_concl = Logic.mk_of_class (aT, class);
    87     val of_class_prop =
    88       (case prop of
    89         NONE => of_class_prop_concl
    90       | SOME prop => Logic.mk_implies (Morphism.term const_morph
    91           ((map_types o map_atyps) (K aT) prop), of_class_prop_concl));
    92     val sup_of_classes = map (snd o Class.rules thy) sups;
    93     val loc_axiom_intros = map Drule.export_without_context_open (Locale.axioms_of thy class);
    94     val axclass_intro = #intro (AxClass.get_info thy class);
    95     val base_sort_trivs = Thm.of_sort (Thm.ctyp_of thy aT, base_sort);
    96     val tac =
    97       REPEAT (SOMEGOAL
    98         (Tactic.match_tac (axclass_intro :: sup_of_classes @ loc_axiom_intros @ base_sort_trivs)
    99           ORELSE' Tactic.assume_tac));
   100     val of_class = Skip_Proof.prove_global thy [] [] of_class_prop (K tac);
   101 
   102   in (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) end;
   103 
   104 
   105 (* reading and processing class specifications *)
   106 
   107 fun prep_class_elems prep_decl thy sups raw_elems =
   108   let
   109 
   110     (* user space type system: only permits 'a type variable, improves towards 'a *)
   111     val algebra = Sign.classes_of thy;
   112     val inter_sort = curry (Sorts.inter_sort algebra);
   113     val proto_base_sort =
   114       if null sups then Sign.defaultS thy
   115       else fold inter_sort (map (Class.base_sort thy) sups) [];
   116     val base_constraints = (map o apsnd)
   117       (map_type_tfree (K (TVar ((Name.aT, 0), proto_base_sort))) o fst o snd)
   118         (Class.these_operations thy sups);
   119     val reject_other =
   120       (tap o exists o Term.exists_subtype)
   121         (fn TFree (a, _) =>
   122           a <> Name.aT andalso
   123             error ("No type variable other than " ^ Name.aT ^ " allowed in class specification")
   124         | _ => false);
   125     fun singleton_fixate Ts =
   126       let
   127         val tfrees = fold Term.add_tfreesT Ts [];
   128         val inferred_sort = (fold o Term.fold_atyps) (fn TVar (_, S) => inter_sort S | _ => I) Ts [];
   129         val fixate_sort =
   130           (case tfrees of
   131             [] => inferred_sort
   132           | [(_, S)] =>
   133               if Sorts.sort_le algebra (S, inferred_sort) then S
   134               else
   135                 error ("Type inference imposes additional sort constraint " ^
   136                   Syntax.string_of_sort_global thy inferred_sort ^
   137                   " of type parameter " ^ Name.aT ^ " of sort " ^
   138                   Syntax.string_of_sort_global thy S)
   139           | _ => error "Multiple type variables in class specification");
   140         val fixateT = TFree (Name.aT, fixate_sort);
   141       in
   142         (map o map_atyps)
   143           (fn T as TVar (xi, _) => if Type_Infer.is_param xi then fixateT else T | T => T) Ts
   144       end;
   145     fun after_infer_fixate Ts =
   146       let
   147         val fixate_sort =
   148           (fold o fold_atyps)
   149             (fn TVar (xi, S) => if Type_Infer.is_param xi then inter_sort S else I | _ => I) Ts [];
   150       in
   151         (map o map_atyps)
   152           (fn T as TVar (xi, _) =>
   153               if Type_Infer.is_param xi then Type_Infer.param 0 (Name.aT, fixate_sort) else T
   154             | T => T) Ts
   155       end;
   156 
   157     (* preprocessing elements, retrieving base sort from type-checked elements *)
   158     val raw_supexpr =
   159       (map (fn sup => (sup, (("", false), Expression.Positional []))) sups, []);
   160     val init_class_body =
   161       fold (Proof_Context.add_const_constraint o apsnd SOME) base_constraints
   162       #> Class.redeclare_operations thy sups
   163       #> Context.proof_map (Syntax_Phases.typ_check 10 "reject_other" (K reject_other))
   164       #> Context.proof_map (Syntax_Phases.typ_check ~10 "singleton_fixate" (K singleton_fixate));
   165     val ((raw_supparams, _, raw_inferred_elems), _) =
   166       Proof_Context.init_global thy
   167       |> Context.proof_map (Syntax_Phases.typ_check 5 "after_infer_fixate" (K after_infer_fixate))
   168       |> prep_decl raw_supexpr init_class_body raw_elems;
   169     fun filter_element (Element.Fixes []) = NONE
   170       | filter_element (e as Element.Fixes _) = SOME e
   171       | filter_element (Element.Constrains []) = NONE
   172       | filter_element (e as Element.Constrains _) = SOME e
   173       | filter_element (Element.Assumes []) = NONE
   174       | filter_element (e as Element.Assumes _) = SOME e
   175       | filter_element (Element.Defines _) =
   176           error ("\"defines\" element not allowed in class specification.")
   177       | filter_element (Element.Notes _) =
   178           error ("\"notes\" element not allowed in class specification.");
   179     val inferred_elems = map_filter filter_element raw_inferred_elems;
   180     fun fold_element_types f (Element.Fixes fxs) = fold (fn (_, SOME T, _) => f T) fxs
   181       | fold_element_types f (Element.Constrains cnstrs) = fold (f o snd) cnstrs
   182       | fold_element_types f (Element.Assumes assms) = fold (fold (fn (t, ts) =>
   183           fold_types f t #> (fold o fold_types) f ts) o snd) assms;
   184     val base_sort =
   185       if null inferred_elems then proto_base_sort
   186       else
   187         (case (fold o fold_element_types) Term.add_tfreesT inferred_elems [] of
   188           [] => error "No type variable in class specification"
   189         | [(_, sort)] => sort
   190         | _ => error "Multiple type variables in class specification");
   191     val supparams = map (fn ((c, T), _) =>
   192       (c, map_atyps (K (TFree (Name.aT, base_sort))) T)) raw_supparams;
   193     val supparam_names = map fst supparams;
   194     fun mk_param ((c, _), _) = Free (c, (the o AList.lookup (op =) supparams) c);
   195     val supexpr = (map (fn sup => (sup, (("", false),
   196       Expression.Positional (map (SOME o mk_param) (Locale.params_of thy sup))))) sups,
   197         map (fn (c, T) => (Binding.name c, SOME T, NoSyn)) supparams);
   198 
   199   in (base_sort, supparam_names, supexpr, inferred_elems) end;
   200 
   201 val cert_class_elems = prep_class_elems Expression.cert_declaration;
   202 val read_class_elems = prep_class_elems Expression.cert_read_declaration;
   203 
   204 fun prep_class_spec prep_class prep_class_elems thy raw_supclasses raw_elems =
   205   let
   206 
   207     (* prepare import *)
   208     val inter_sort = curry (Sorts.inter_sort (Sign.classes_of thy));
   209     val sups = Sign.minimize_sort thy (map (prep_class thy) raw_supclasses);
   210     val _ =
   211       (case filter_out (Class.is_class thy) sups of
   212         [] => ()
   213       | no_classes => error ("No (proper) classes: " ^ commas_quote no_classes));
   214     val raw_supparams = (map o apsnd) (snd o snd) (Class.these_params thy sups);
   215     val raw_supparam_names = map fst raw_supparams;
   216     val _ =
   217       if has_duplicates (op =) raw_supparam_names then
   218         error ("Duplicate parameter(s) in superclasses: " ^
   219           (commas_quote (duplicates (op =) raw_supparam_names)))
   220       else ();
   221 
   222     (* infer types and base sort *)
   223     val (base_sort, supparam_names, supexpr, inferred_elems) = prep_class_elems thy sups raw_elems;
   224     val sup_sort = inter_sort base_sort sups;
   225 
   226     (* process elements as class specification *)
   227     val class_ctxt = Class.begin sups base_sort (Proof_Context.init_global thy);
   228     val ((_, _, syntax_elems), _) = class_ctxt
   229       |> Expression.cert_declaration supexpr I inferred_elems;
   230     fun check_vars e vs =
   231       if null vs then
   232         error ("No type variable in part of specification element " ^
   233           Pretty.string_of (Pretty.chunks (Element.pretty_ctxt class_ctxt e)))
   234       else ();
   235     fun check_element (e as Element.Fixes fxs) =
   236           List.app (fn (_, SOME T, _) => check_vars e (Term.add_tfreesT T [])) fxs
   237       | check_element (e as Element.Assumes assms) =
   238           List.app (fn (_, ts_pss) =>
   239             List.app (fn (t, _) => check_vars e (Term.add_tfrees t [])) ts_pss) assms
   240       | check_element _ = ();
   241     val _ = List.app check_element syntax_elems;
   242     fun fork_syn (Element.Fixes xs) =
   243           fold_map (fn (c, ty, syn) => cons (c, syn) #> pair (c, ty, NoSyn)) xs
   244           #>> Element.Fixes
   245       | fork_syn x = pair x;
   246     val (elems, global_syntax) = fold_map fork_syn syntax_elems [];
   247 
   248   in (((sups, supparam_names), (sup_sort, base_sort, supexpr)), (elems, global_syntax)) end;
   249 
   250 val cert_class_spec = prep_class_spec (K I) cert_class_elems;
   251 val read_class_spec = prep_class_spec Sign.intern_class read_class_elems;
   252 
   253 
   254 (* class establishment *)
   255 
   256 fun add_consts class base_sort sups supparam_names global_syntax thy =
   257   let
   258     (*FIXME simplify*)
   259     val supconsts = supparam_names
   260       |> AList.make (snd o the o AList.lookup (op =) (Class.these_params thy sups))
   261       |> (map o apsnd o apsnd o map_atyps o K o TFree) (Name.aT, [class]);
   262     val all_params = Locale.params_of thy class;
   263     val raw_params = (snd o chop (length supparam_names)) all_params;
   264     fun add_const ((raw_c, raw_ty), _) thy =
   265       let
   266         val b = Binding.name raw_c;
   267         val c = Sign.full_name thy b;
   268         val ty = map_atyps (K (TFree (Name.aT, base_sort))) raw_ty;
   269         val ty0 = Type.strip_sorts ty;
   270         val ty' = map_atyps (K (TFree (Name.aT, [class]))) ty0;
   271         val syn = (the_default NoSyn o AList.lookup Binding.eq_name global_syntax) b;
   272       in
   273         thy
   274         |> Sign.declare_const_global ((b, ty0), syn)
   275         |> snd
   276         |> pair ((Variable.check_name b, ty), (c, ty'))
   277       end;
   278   in
   279     thy
   280     |> Sign.add_path (Class.class_prefix class)
   281     |> fold_map add_const raw_params
   282     ||> Sign.restore_naming thy
   283     |-> (fn params => pair (supconsts @ (map o apfst) fst params, params))
   284   end;
   285 
   286 fun adjungate_axclass bname class base_sort sups supsort supparam_names global_syntax thy =
   287   let
   288     (*FIXME simplify*)
   289     fun globalize param_map = map_aterms
   290       (fn Free (v, ty) => Const ((fst o the o AList.lookup (op =) param_map) v, ty)
   291         | t => t);
   292     val raw_pred = Locale.intros_of thy class
   293       |> fst
   294       |> Option.map (Logic.unvarify_global o Logic.strip_imp_concl o Thm.prop_of);
   295     fun get_axiom thy =
   296       (case #axioms (AxClass.get_info thy class) of
   297          [] => NONE
   298       | [thm] => SOME thm);
   299   in
   300     thy
   301     |> add_consts class base_sort sups supparam_names global_syntax
   302     |-> (fn (param_map, params) => AxClass.define_class (bname, supsort)
   303           (map (fst o snd) params)
   304           [(Thm.empty_binding, Option.map (globalize param_map) raw_pred |> the_list)]
   305     #> snd
   306     #> `get_axiom
   307     #-> (fn assm_axiom => fold (Sign.add_const_constraint o apsnd SOME o snd) params
   308     #> pair (param_map, params, assm_axiom)))
   309   end;
   310 
   311 fun gen_class prep_class_spec before_exit b raw_supclasses raw_elems thy =
   312   let
   313     val class = Sign.full_name thy b;
   314     val (((sups, supparam_names), (supsort, base_sort, supexpr)), (elems, global_syntax)) =
   315       prep_class_spec thy raw_supclasses raw_elems;
   316   in
   317     thy
   318     |> Expression.add_locale I b (Binding.qualify true "class" b) supexpr elems
   319     |> snd |> Local_Theory.exit_global
   320     |> adjungate_axclass b class base_sort sups supsort supparam_names global_syntax
   321     ||> Theory.checkpoint
   322     |-> (fn (param_map, params, assm_axiom) =>
   323        `(fn thy => calculate thy class sups base_sort param_map assm_axiom)
   324     #-> (fn (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) =>
   325        Context.theory_map (Locale.add_registration (class, base_morph)
   326          (Option.map (rpair true) eq_morph) export_morph)
   327     #> Class.register class sups params base_sort base_morph export_morph axiom assm_intro of_class))
   328     |> Named_Target.init before_exit class
   329     |> pair class
   330   end;
   331 
   332 in
   333 
   334 val class = gen_class cert_class_spec;
   335 val class_cmd = gen_class read_class_spec;
   336 
   337 end; (*local*)
   338 
   339 
   340 
   341 (** subclass relations **)
   342 
   343 local
   344 
   345 fun gen_subclass prep_class do_proof before_exit raw_sup lthy =
   346   let
   347     val thy = Proof_Context.theory_of lthy;
   348     val proto_sup = prep_class thy raw_sup;
   349     val proto_sub =
   350       (case Named_Target.peek lthy of
   351          SOME {target, is_class = true, ...} => target
   352       | _ => error "Not in a class target");
   353     val (sub, sup) = AxClass.cert_classrel thy (proto_sub, proto_sup);
   354 
   355     val expr = ([(sup, (("", false), Expression.Positional []))], []);
   356     val (([props], deps, export), goal_ctxt) =
   357       Expression.cert_goal_expression expr lthy;
   358     val some_prop = try the_single props;
   359     val some_dep_morph = try the_single (map snd deps);
   360     fun after_qed some_wit =
   361       Proof_Context.background_theory (Class.register_subclass (sub, sup)
   362         some_dep_morph some_wit export)
   363       #> Proof_Context.theory_of #> Named_Target.init before_exit sub;
   364   in do_proof after_qed some_prop goal_ctxt end;
   365 
   366 fun user_proof after_qed some_prop =
   367   Element.witness_proof (after_qed o try the_single o the_single)
   368     [the_list some_prop];
   369 
   370 fun tactic_proof tac after_qed some_prop ctxt =
   371   after_qed (Option.map
   372     (fn prop => Element.prove_witness ctxt prop tac) some_prop) ctxt;
   373 
   374 in
   375 
   376 val subclass = gen_subclass (K I) user_proof;
   377 fun prove_subclass before_exit tac = gen_subclass (K I) (tactic_proof tac) before_exit;
   378 val subclass_cmd = gen_subclass (Proof_Context.read_class o Proof_Context.init_global) user_proof;
   379 
   380 end; (*local*)
   381 
   382 end;