src/Pure/sign.ML
author wenzelm
Wed Apr 06 13:33:46 2011 +0200 (2011-04-06)
changeset 42247 12fe41a92cd5
parent 42224 578a51fae383
child 42268 01401287c3f7
permissions -rw-r--r--
typed_print_translation: discontinued show_sorts argument;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val inter_sort: theory -> sort * sort -> sort
    33   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    34   val is_logtype: theory -> string -> bool
    35   val typ_instance: theory -> typ * typ -> bool
    36   val typ_equiv: theory -> typ * typ -> bool
    37   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    38   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    39   val consts_of: theory -> Consts.T
    40   val the_const_constraint: theory -> string -> typ
    41   val const_type: theory -> string -> typ option
    42   val the_const_type: theory -> string -> typ
    43   val declared_tyname: theory -> string -> bool
    44   val declared_const: theory -> string -> bool
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val class_alias: binding -> class -> theory -> theory
    53   val type_alias: binding -> string -> theory -> theory
    54   val const_alias: binding -> string -> theory -> theory
    55   val intern_class: theory -> xstring -> string
    56   val extern_class: theory -> string -> xstring
    57   val intern_type: theory -> xstring -> string
    58   val extern_type: theory -> string -> xstring
    59   val intern_const: theory -> xstring -> string
    60   val extern_const: theory -> string -> xstring
    61   val arity_number: theory -> string -> int
    62   val arity_sorts: theory -> string -> sort -> sort list
    63   val certify_class: theory -> class -> class
    64   val certify_sort: theory -> sort -> sort
    65   val certify_typ: theory -> typ -> typ
    66   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    67   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    68   val certify_term: theory -> term -> term * typ * int
    69   val cert_term: theory -> term -> term
    70   val cert_prop: theory -> term -> term
    71   val no_frees: Proof.context -> term -> term
    72   val no_vars: Proof.context -> term -> term
    73   val add_types: (binding * int * mixfix) list -> theory -> theory
    74   val add_nonterminals: binding list -> theory -> theory
    75   val add_type_abbrev: binding * string list * typ -> theory -> theory
    76   val add_syntax: (string * string * mixfix) list -> theory -> theory
    77   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    78   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    79   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    80   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    81   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    82   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    83   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    84   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    85   val add_consts: (binding * string * mixfix) list -> theory -> theory
    86   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    87   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    88   val revert_abbrev: string -> string -> theory -> theory
    89   val add_const_constraint: string * typ option -> theory -> theory
    90   val primitive_class: binding * class list -> theory -> theory
    91   val primitive_classrel: class * class -> theory -> theory
    92   val primitive_arity: arity -> theory -> theory
    93   val add_trfuns:
    94     (string * (Ast.ast list -> Ast.ast)) list *
    95     (string * (term list -> term)) list *
    96     (string * (term list -> term)) list *
    97     (string * (Ast.ast list -> Ast.ast)) list -> theory -> theory
    98   val add_trfunsT: (string * (typ -> term list -> term)) list -> theory -> theory
    99   val add_advanced_trfuns:
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list *
   101     (string * (Proof.context -> term list -> term)) list *
   102     (string * (Proof.context -> term list -> term)) list *
   103     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   104   val add_advanced_trfunsT:
   105     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   106   val add_tokentrfuns:
   107     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   108   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   109     -> theory -> theory
   110   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   111   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   112   val new_group: theory -> theory
   113   val reset_group: theory -> theory
   114   val add_path: string -> theory -> theory
   115   val root_path: theory -> theory
   116   val parent_path: theory -> theory
   117   val mandatory_path: string -> theory -> theory
   118   val qualified_path: bool -> binding -> theory -> theory
   119   val local_path: theory -> theory
   120   val restore_naming: theory -> theory -> theory
   121   val hide_class: bool -> string -> theory -> theory
   122   val hide_type: bool -> string -> theory -> theory
   123   val hide_const: bool -> string -> theory -> theory
   124 end
   125 
   126 structure Sign: SIGN =
   127 struct
   128 
   129 (** datatype sign **)
   130 
   131 datatype sign = Sign of
   132  {naming: Name_Space.naming,    (*common naming conventions*)
   133   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   134   tsig: Type.tsig,              (*order-sorted signature of types*)
   135   consts: Consts.T};            (*polymorphic constants*)
   136 
   137 fun make_sign (naming, syn, tsig, consts) =
   138   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   139 
   140 structure Data = Theory_Data_PP
   141 (
   142   type T = sign;
   143   fun extend (Sign {syn, tsig, consts, ...}) =
   144     make_sign (Name_Space.default_naming, syn, tsig, consts);
   145 
   146   val empty =
   147     make_sign (Name_Space.default_naming, Syntax.basic_syntax, Type.empty_tsig, Consts.empty);
   148 
   149   fun merge pp (sign1, sign2) =
   150     let
   151       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   152       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   153 
   154       val naming = Name_Space.default_naming;
   155       val syn = Syntax.merge_syntaxes syn1 syn2;
   156       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   157       val consts = Consts.merge (consts1, consts2);
   158     in make_sign (naming, syn, tsig, consts) end;
   159 );
   160 
   161 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   162 
   163 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   164   make_sign (f (naming, syn, tsig, consts)));
   165 
   166 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   167 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   168 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   169 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   170 
   171 
   172 (* naming *)
   173 
   174 val naming_of = #naming o rep_sg;
   175 
   176 val full_name = Name_Space.full_name o naming_of;
   177 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   178 
   179 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   180 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   181 
   182 
   183 (* syntax *)
   184 
   185 val syn_of = #syn o rep_sg;
   186 
   187 
   188 (* type signature *)
   189 
   190 val tsig_of = #tsig o rep_sg;
   191 
   192 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   193 val all_classes = Sorts.all_classes o classes_of;
   194 val super_classes = Sorts.super_classes o classes_of;
   195 val minimize_sort = Sorts.minimize_sort o classes_of;
   196 val complete_sort = Sorts.complete_sort o classes_of;
   197 
   198 val set_defsort = map_tsig o Type.set_defsort;
   199 val defaultS = Type.defaultS o tsig_of;
   200 val subsort = Type.subsort o tsig_of;
   201 val of_sort = Type.of_sort o tsig_of;
   202 val inter_sort = Type.inter_sort o tsig_of;
   203 val witness_sorts = Type.witness_sorts o tsig_of;
   204 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   205 
   206 val typ_instance = Type.typ_instance o tsig_of;
   207 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   208 val typ_match = Type.typ_match o tsig_of;
   209 val typ_unify = Type.unify o tsig_of;
   210 
   211 
   212 (* polymorphic constants *)
   213 
   214 val consts_of = #consts o rep_sg;
   215 val the_const_constraint = Consts.the_constraint o consts_of;
   216 val the_const_type = Consts.the_type o consts_of;
   217 val const_type = try o the_const_type;
   218 val const_monomorphic = Consts.is_monomorphic o consts_of;
   219 val const_typargs = Consts.typargs o consts_of;
   220 val const_instance = Consts.instance o consts_of;
   221 
   222 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   223 
   224 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   225 val declared_const = can o the_const_constraint;
   226 
   227 
   228 
   229 (** intern / extern names **)
   230 
   231 val class_space = Type.class_space o tsig_of;
   232 val type_space = Type.type_space o tsig_of;
   233 val const_space = Consts.space_of o consts_of;
   234 
   235 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   236 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   237 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   238 
   239 val intern_class = Name_Space.intern o class_space;
   240 val extern_class = Name_Space.extern o class_space;
   241 val intern_type = Name_Space.intern o type_space;
   242 val extern_type = Name_Space.extern o type_space;
   243 val intern_const = Name_Space.intern o const_space;
   244 val extern_const = Name_Space.extern o const_space;
   245 
   246 
   247 
   248 (** certify entities **)    (*exception TYPE*)
   249 
   250 (* certify wrt. type signature *)
   251 
   252 val arity_number = Type.arity_number o tsig_of;
   253 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   254 
   255 val certify_class         = Type.cert_class o tsig_of;
   256 val certify_sort          = Type.cert_sort o tsig_of;
   257 val certify_typ           = Type.cert_typ o tsig_of;
   258 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   259 
   260 
   261 (* certify term/prop *)
   262 
   263 local
   264 
   265 fun type_check pp tm =
   266   let
   267     fun err_appl bs t T u U =
   268       let
   269         val xs = map Free bs;           (*we do not rename here*)
   270         val t' = subst_bounds (xs, t);
   271         val u' = subst_bounds (xs, u);
   272         val msg = Type.appl_error pp t' T u' U;
   273       in raise TYPE (msg, [T, U], [t', u']) end;
   274 
   275     fun typ_of (_, Const (_, T)) = T
   276       | typ_of (_, Free  (_, T)) = T
   277       | typ_of (_, Var (_, T)) = T
   278       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   279           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   280       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   281       | typ_of (bs, t $ u) =
   282           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   283             (case T of
   284               Type ("fun", [T1, T2]) =>
   285                 if T1 = U then T2 else err_appl bs t T u U
   286             | _ => err_appl bs t T u U)
   287           end;
   288   in typ_of ([], tm) end;
   289 
   290 fun err msg = raise TYPE (msg, [], []);
   291 
   292 fun check_vars (t $ u) = (check_vars t; check_vars u)
   293   | check_vars (Abs (_, _, t)) = check_vars t
   294   | check_vars (Free (x, _)) =
   295       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   296   | check_vars (Var (xi as (_, i), _)) =
   297       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   298   | check_vars _ = ();
   299 
   300 in
   301 
   302 fun certify' prop pp do_expand consts thy tm =
   303   let
   304     val _ = check_vars tm;
   305     val tm' = Term.map_types (certify_typ thy) tm;
   306     val T = type_check pp tm';
   307     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   308     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   309   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   310 
   311 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   312 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   313 val cert_term = #1 oo certify_term;
   314 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   315 
   316 end;
   317 
   318 
   319 (* specifications *)
   320 
   321 fun no_variables kind add addT mk mkT ctxt tm =
   322   (case (add tm [], addT tm []) of
   323     ([], []) => tm
   324   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   325       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   326        Pretty.commas
   327         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   328 
   329 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   330 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   331 
   332 
   333 
   334 (** signature extension functions **)  (*exception ERROR/TYPE*)
   335 
   336 (* add type constructors *)
   337 
   338 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   339   let
   340     fun type_syntax (b, n, mx) =
   341       (Syntax.mark_type (Name_Space.full_name naming b), Syntax.make_type n, mx);
   342     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   343     val tsig' = fold (fn (a, n, _) => Type.add_type naming (a, n)) types tsig;
   344   in (naming, syn', tsig', consts) end);
   345 
   346 
   347 (* add nonterminals *)
   348 
   349 fun add_nonterminals ns = map_sign (fn (naming, syn, tsig, consts) =>
   350   (naming, syn, fold (Type.add_nonterminal naming) ns tsig, consts));
   351 
   352 
   353 (* add type abbreviations *)
   354 
   355 fun add_type_abbrev abbr = map_sign (fn (naming, syn, tsig, consts) =>
   356   (naming, syn, Type.add_abbrev naming abbr tsig, consts));
   357 
   358 
   359 (* modify syntax *)
   360 
   361 fun gen_syntax change_gram parse_typ mode args thy =
   362   let
   363     val ctxt = ProofContext.init_global thy;
   364     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   365       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   366   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   367 
   368 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   369 
   370 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   371 val add_modesyntax_i = gen_add_syntax (K I);
   372 val add_syntax = add_modesyntax Syntax.mode_default;
   373 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   374 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   375 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   376 
   377 fun type_notation add mode args =
   378   let
   379     fun type_syntax (Type (c, args), mx) =
   380           SOME (Syntax.mark_type c, Syntax.make_type (length args), mx)
   381       | type_syntax _ = NONE;
   382   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   383 
   384 fun notation add mode args thy =
   385   let
   386     fun const_syntax (Const (c, _), mx) =
   387           (case try (Consts.type_scheme (consts_of thy)) c of
   388             SOME T => SOME (Syntax.mark_const c, T, mx)
   389           | NONE => NONE)
   390       | const_syntax _ = NONE;
   391   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   392 
   393 
   394 (* add constants *)
   395 
   396 local
   397 
   398 fun gen_add_consts parse_typ raw_args thy =
   399   let
   400     val ctxt = ProofContext.init_global thy;
   401     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   402     fun prep (b, raw_T, mx) =
   403       let
   404         val c = full_name thy b;
   405         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   406           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   407         val T' = Logic.varifyT_global T;
   408       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   409     val args = map prep raw_args;
   410   in
   411     thy
   412     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   413     |> add_syntax_i (map #2 args)
   414     |> pair (map #3 args)
   415   end;
   416 
   417 in
   418 
   419 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   420 fun add_consts_i args = snd o gen_add_consts (K I) args;
   421 
   422 fun declare_const ((b, T), mx) thy =
   423   let
   424     val pos = Binding.pos_of b;
   425     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   426     val _ = Position.report pos (Markup.const_decl c);
   427   in (const, thy') end;
   428 
   429 end;
   430 
   431 
   432 (* abbreviations *)
   433 
   434 fun add_abbrev mode (b, raw_t) thy =
   435   let
   436     val ctxt = Syntax.init_pretty_global thy;
   437     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   438     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   439       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   440     val (res, consts') = consts_of thy
   441       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of thy) (naming_of thy) mode (b, t);
   442   in (res, thy |> map_consts (K consts')) end;
   443 
   444 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   445 
   446 
   447 (* add constraints *)
   448 
   449 fun add_const_constraint (c, opt_T) thy =
   450   let
   451     fun prepT raw_T =
   452       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   453       in cert_term thy (Const (c, T)); T end
   454       handle TYPE (msg, _, _) => error msg;
   455   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   456 
   457 
   458 (* primitive classes and arities *)
   459 
   460 fun primitive_class (bclass, classes) thy =
   461   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   462     let
   463       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   464     in (naming, syn, tsig', consts) end)
   465   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   466 
   467 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   468 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   469 
   470 
   471 (* add translation functions *)
   472 
   473 local
   474 
   475 fun mk trs = map Syntax.mk_trfun trs;
   476 
   477 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   478   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   479 
   480 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   481 
   482 in
   483 
   484 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   485 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   486 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   487 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   488 
   489 end;
   490 
   491 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   492 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   493 
   494 
   495 (* translation rules *)
   496 
   497 val add_trrules = map_syn o Syntax.update_trrules;
   498 val del_trrules = map_syn o Syntax.remove_trrules;
   499 
   500 
   501 (* naming *)
   502 
   503 val new_group = map_naming Name_Space.new_group;
   504 val reset_group = map_naming Name_Space.reset_group;
   505 
   506 val add_path = map_naming o Name_Space.add_path;
   507 val root_path = map_naming Name_Space.root_path;
   508 val parent_path = map_naming Name_Space.parent_path;
   509 val mandatory_path = map_naming o Name_Space.mandatory_path;
   510 val qualified_path = map_naming oo Name_Space.qualified_path;
   511 
   512 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   513 
   514 val restore_naming = map_naming o K o naming_of;
   515 
   516 
   517 (* hide names *)
   518 
   519 val hide_class = map_tsig oo Type.hide_class;
   520 val hide_type = map_tsig oo Type.hide_type;
   521 val hide_const = map_consts oo Consts.hide;
   522 
   523 end;