src/Pure/drule.ML
author wenzelm
Thu Apr 22 10:52:32 2004 +0200 (2004-04-22)
changeset 14643 130076a81b84
parent 14394 51b24127eef2
child 14824 336ade035a34
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val strip_imp_prems   : cterm -> cterm list
    18   val strip_imp_concl   : cterm -> cterm
    19   val cprems_of         : thm -> cterm list
    20   val read_insts        :
    21           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    22                   -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> string list -> (string*string)list
    24                   -> (indexname*ctyp)list * (cterm*cterm)list
    25   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    26   val strip_shyps_warning : thm -> thm
    27   val forall_intr_list  : cterm list -> thm -> thm
    28   val forall_intr_frees : thm -> thm
    29   val forall_intr_vars  : thm -> thm
    30   val forall_elim_list  : cterm list -> thm -> thm
    31   val forall_elim_var   : int -> thm -> thm
    32   val forall_elim_vars  : int -> thm -> thm
    33   val gen_all           : thm -> thm
    34   val freeze_thaw       : thm -> thm * (thm -> thm)
    35   val implies_elim_list : thm -> thm list -> thm
    36   val implies_intr_list : cterm list -> thm -> thm
    37   val instantiate       :
    38     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    39   val zero_var_indexes  : thm -> thm
    40   val standard          : thm -> thm
    41   val standard'         : thm -> thm
    42   val rotate_prems      : int -> thm -> thm
    43   val rearrange_prems   : int list -> thm -> thm
    44   val assume_ax         : theory -> string -> thm
    45   val RSN               : thm * (int * thm) -> thm
    46   val RS                : thm * thm -> thm
    47   val RLN               : thm list * (int * thm list) -> thm list
    48   val RL                : thm list * thm list -> thm list
    49   val MRS               : thm list * thm -> thm
    50   val MRL               : thm list list * thm list -> thm list
    51   val OF                : thm * thm list -> thm
    52   val compose           : thm * int * thm -> thm list
    53   val COMP              : thm * thm -> thm
    54   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    55   val read_instantiate  : (string*string)list -> thm -> thm
    56   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    57   val eq_thm_sg         : thm * thm -> bool
    58   val eq_thm_prop	: thm * thm -> bool
    59   val weak_eq_thm       : thm * thm -> bool
    60   val size_of_thm       : thm -> int
    61   val reflexive_thm     : thm
    62   val symmetric_thm     : thm
    63   val transitive_thm    : thm
    64   val refl_implies      : thm
    65   val symmetric_fun     : thm -> thm
    66   val extensional       : thm -> thm
    67   val imp_cong          : thm
    68   val swap_prems_eq     : thm
    69   val equal_abs_elim    : cterm  -> thm -> thm
    70   val equal_abs_elim_list: cterm list -> thm -> thm
    71   val asm_rl            : thm
    72   val cut_rl            : thm
    73   val revcut_rl         : thm
    74   val thin_rl           : thm
    75   val triv_forall_equality: thm
    76   val swap_prems_rl     : thm
    77   val equal_intr_rule   : thm
    78   val equal_elim_rule1  : thm
    79   val inst              : string -> string -> thm -> thm
    80   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    81   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    82 end;
    83 
    84 signature DRULE =
    85 sig
    86   include BASIC_DRULE
    87   val strip_comb: cterm -> cterm * cterm list
    88   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    89   val tag_rule: tag -> thm -> thm
    90   val untag_rule: string -> thm -> thm
    91   val tag: tag -> 'a attribute
    92   val untag: string -> 'a attribute
    93   val get_kind: thm -> string
    94   val kind: string -> 'a attribute
    95   val theoremK: string
    96   val lemmaK: string
    97   val corollaryK: string
    98   val internalK: string
    99   val kind_internal: 'a attribute
   100   val has_internal: tag list -> bool
   101   val impose_hyps: cterm list -> thm -> thm
   102   val satisfy_hyps: thm list -> thm -> thm
   103   val close_derivation: thm -> thm
   104   val local_standard: thm -> thm
   105   val compose_single: thm * int * thm -> thm
   106   val add_rule: thm -> thm list -> thm list
   107   val del_rule: thm -> thm list -> thm list
   108   val add_rules: thm list -> thm list -> thm list
   109   val del_rules: thm list -> thm list -> thm list
   110   val merge_rules: thm list * thm list -> thm list
   111   val norm_hhf_eq: thm
   112   val is_norm_hhf: term -> bool
   113   val norm_hhf: Sign.sg -> term -> term
   114   val triv_goal: thm
   115   val rev_triv_goal: thm
   116   val implies_intr_goals: cterm list -> thm -> thm
   117   val freeze_all: thm -> thm
   118   val mk_triv_goal: cterm -> thm
   119   val tvars_of_terms: term list -> (indexname * sort) list
   120   val vars_of_terms: term list -> (indexname * typ) list
   121   val tvars_of: thm -> (indexname * sort) list
   122   val vars_of: thm -> (indexname * typ) list
   123   val rename_bvars: (string * string) list -> thm -> thm
   124   val rename_bvars': string option list -> thm -> thm
   125   val unvarifyT: thm -> thm
   126   val unvarify: thm -> thm
   127   val tvars_intr_list: string list -> thm -> thm * (string * indexname) list
   128   val remdups_rl: thm
   129   val conj_intr: thm -> thm -> thm
   130   val conj_intr_list: thm list -> thm
   131   val conj_elim: thm -> thm * thm
   132   val conj_elim_list: thm -> thm list
   133   val conj_elim_precise: int -> thm -> thm list
   134   val conj_intr_thm: thm
   135   val abs_def: thm -> thm
   136 end;
   137 
   138 structure Drule: DRULE =
   139 struct
   140 
   141 
   142 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   143 
   144 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   145 
   146 (*dest_implies for cterms. Note T=prop below*)
   147 fun dest_implies ct =
   148     case term_of ct of
   149         (Const("==>", _) $ _ $ _) =>
   150             let val (ct1,ct2) = Thm.dest_comb ct
   151             in  (#2 (Thm.dest_comb ct1), ct2)  end
   152       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   153 
   154 fun dest_equals ct =
   155     case term_of ct of
   156         (Const("==", _) $ _ $ _) =>
   157             let val (ct1,ct2) = Thm.dest_comb ct
   158             in  (#2 (Thm.dest_comb ct1), ct2)  end
   159       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   160 
   161 
   162 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   163 fun strip_imp_prems ct =
   164     let val (cA,cB) = dest_implies ct
   165     in  cA :: strip_imp_prems cB  end
   166     handle TERM _ => [];
   167 
   168 (* A1==>...An==>B  goes to B, where B is not an implication *)
   169 fun strip_imp_concl ct =
   170     case term_of ct of (Const("==>", _) $ _ $ _) =>
   171         strip_imp_concl (#2 (Thm.dest_comb ct))
   172   | _ => ct;
   173 
   174 (*The premises of a theorem, as a cterm list*)
   175 val cprems_of = strip_imp_prems o cprop_of;
   176 
   177 val proto_sign = Theory.sign_of ProtoPure.thy;
   178 
   179 val implies = cterm_of proto_sign Term.implies;
   180 
   181 (*cterm version of mk_implies*)
   182 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   183 
   184 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   185 fun list_implies([], B) = B
   186   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   187 
   188 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   189 fun strip_comb ct = 
   190   let
   191     fun stripc (p as (ct, cts)) =
   192       let val (ct1, ct2) = Thm.dest_comb ct
   193       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   194   in stripc (ct, []) end;
   195 
   196 
   197 (** reading of instantiations **)
   198 
   199 fun absent ixn =
   200   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   201 
   202 fun inst_failure ixn =
   203   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   204 
   205 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   206 let
   207     fun split([],tvs,vs) = (tvs,vs)
   208       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   209                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   210                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   211     val (tvs,vs) = split(insts,[],[]);
   212     fun readT((a,i),st) =
   213         let val ixn = ("'" ^ a,i);
   214             val S = case rsorts ixn of Some S => S | None => absent ixn;
   215             val T = Sign.read_typ (sign,sorts) st;
   216         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   217            else inst_failure ixn
   218         end
   219     val tye = map readT tvs;
   220     fun mkty(ixn,st) = (case rtypes ixn of
   221                           Some T => (ixn,(st,typ_subst_TVars tye T))
   222                         | None => absent ixn);
   223     val ixnsTs = map mkty vs;
   224     val ixns = map fst ixnsTs
   225     and sTs  = map snd ixnsTs
   226     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   227     fun mkcVar(ixn,T) =
   228         let val U = typ_subst_TVars tye2 T
   229         in cterm_of sign (Var(ixn,U)) end
   230     val ixnTs = ListPair.zip(ixns, map snd sTs)
   231 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   232     ListPair.zip(map mkcVar ixnTs,cts))
   233 end;
   234 
   235 
   236 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   237      Used for establishing default types (of variables) and sorts (of
   238      type variables) when reading another term.
   239      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   240 ***)
   241 
   242 fun types_sorts thm =
   243     let val {prop,hyps,...} = rep_thm thm;
   244         val big = list_comb(prop,hyps); (* bogus term! *)
   245         val vars = map dest_Var (term_vars big);
   246         val frees = map dest_Free (term_frees big);
   247         val tvars = term_tvars big;
   248         val tfrees = term_tfrees big;
   249         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   250         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   251     in (typ,sort) end;
   252 
   253 
   254 
   255 (** basic attributes **)
   256 
   257 (* dependent rules *)
   258 
   259 fun rule_attribute f (x, thm) = (x, (f x thm));
   260 
   261 
   262 (* add / delete tags *)
   263 
   264 fun map_tags f thm =
   265   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   266 
   267 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   268 fun untag_rule s = map_tags (filter_out (equal s o #1));
   269 
   270 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   271 fun untag s x = rule_attribute (K (untag_rule s)) x;
   272 
   273 fun simple_tag name x = tag (name, []) x;
   274 
   275 
   276 (* theorem kinds *)
   277 
   278 val theoremK = "theorem";
   279 val lemmaK = "lemma";
   280 val corollaryK = "corollary";
   281 val internalK = "internal";
   282 
   283 fun get_kind thm =
   284   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   285     Some (k :: _) => k
   286   | _ => "unknown");
   287 
   288 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   289 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   290 fun kind_internal x = kind internalK x;
   291 fun has_internal tags = exists (equal internalK o fst) tags;
   292 
   293 
   294 
   295 (** Standardization of rules **)
   296 
   297 (*Strip extraneous shyps as far as possible*)
   298 fun strip_shyps_warning thm =
   299   let
   300     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   301     val thm' = Thm.strip_shyps thm;
   302     val xshyps = Thm.extra_shyps thm';
   303   in
   304     if null xshyps then ()
   305     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   306     thm'
   307   end;
   308 
   309 (*Generalization over a list of variables, IGNORING bad ones*)
   310 fun forall_intr_list [] th = th
   311   | forall_intr_list (y::ys) th =
   312         let val gth = forall_intr_list ys th
   313         in  forall_intr y gth   handle THM _ =>  gth  end;
   314 
   315 (*Generalization over all suitable Free variables*)
   316 fun forall_intr_frees th =
   317     let val {prop,sign,...} = rep_thm th
   318     in  forall_intr_list
   319          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   320          th
   321     end;
   322 
   323 val forall_elim_var = PureThy.forall_elim_var;
   324 val forall_elim_vars = PureThy.forall_elim_vars;
   325 
   326 fun gen_all thm =
   327   let
   328     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   329     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   330     val vs = Term.strip_all_vars prop;
   331   in foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   332 
   333 (*Specialization over a list of cterms*)
   334 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   335 
   336 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   337 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   338 
   339 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   340 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   341 
   342 (* maps |- B to A1,...,An |- B *)
   343 fun impose_hyps chyps th =
   344   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   345   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   346 
   347 (* maps A1,...,An and A1,...,An |- B to |- B *)
   348 fun satisfy_hyps ths th =
   349   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   350 
   351 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   352 fun zero_var_indexes th =
   353     let val {prop,sign,...} = rep_thm th;
   354         val vars = term_vars prop
   355         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   356         val inrs = add_term_tvars(prop,[]);
   357         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   358         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   359                      (inrs, nms')
   360         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   361         fun varpairs([],[]) = []
   362           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   363                 let val T' = typ_subst_TVars tye T
   364                 in (cterm_of sign (Var(v,T')),
   365                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   366                 end
   367           | varpairs _ = raise TERM("varpairs", []);
   368     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   369 
   370 
   371 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   372     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   373 
   374 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   375   This step can lose information.*)
   376 fun flexflex_unique th =
   377     case Seq.chop (2, flexflex_rule th) of
   378       ([th],_) => th
   379     | ([],_)   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   380     |      _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   381 
   382 fun close_derivation thm =
   383   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   384   else thm;
   385 
   386 fun standard' th =
   387   let val {maxidx,...} = rep_thm th in
   388     th
   389     |> implies_intr_hyps
   390     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   391     |> strip_shyps_warning
   392     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   393   end;
   394 
   395 val standard = close_derivation o standard' o flexflex_unique;
   396 
   397 fun local_standard th =
   398   th |> strip_shyps |> zero_var_indexes
   399   |> Thm.compress |> close_derivation;
   400 
   401 
   402 (*Convert all Vars in a theorem to Frees.  Also return a function for
   403   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   404   Similar code in type/freeze_thaw*)
   405 fun freeze_thaw th =
   406  let val fth = freezeT th
   407      val {prop, tpairs, sign, ...} = rep_thm fth
   408  in
   409    case foldr add_term_vars (prop :: Thm.terms_of_tpairs tpairs, []) of
   410        [] => (fth, fn x => x)
   411      | vars =>
   412          let fun newName (Var(ix,_), (pairs,used)) =
   413                    let val v = variant used (string_of_indexname ix)
   414                    in  ((ix,v)::pairs, v::used)  end;
   415              val (alist, _) = foldr newName (vars, ([], foldr add_term_names
   416                (prop :: Thm.terms_of_tpairs tpairs, [])))
   417              fun mk_inst (Var(v,T)) =
   418                  (cterm_of sign (Var(v,T)),
   419                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   420              val insts = map mk_inst vars
   421              fun thaw th' =
   422                  th' |> forall_intr_list (map #2 insts)
   423                      |> forall_elim_list (map #1 insts)
   424          in  (Thm.instantiate ([],insts) fth, thaw)  end
   425  end;
   426 
   427 
   428 (*Rotates a rule's premises to the left by k*)
   429 val rotate_prems = permute_prems 0;
   430 
   431 (* permute prems, where the i-th position in the argument list (counting from 0)
   432    gives the position within the original thm to be transferred to position i.
   433    Any remaining trailing positions are left unchanged. *)
   434 val rearrange_prems = let
   435   fun rearr new []      thm = thm
   436   |   rearr new (p::ps) thm = rearr (new+1)
   437      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   438      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   439   in rearr 0 end;
   440 
   441 (*Assume a new formula, read following the same conventions as axioms.
   442   Generalizes over Free variables,
   443   creates the assumption, and then strips quantifiers.
   444   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   445              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   446 fun assume_ax thy sP =
   447     let val sign = Theory.sign_of thy
   448         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   449     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   450 
   451 (*Resolution: exactly one resolvent must be produced.*)
   452 fun tha RSN (i,thb) =
   453   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   454       ([th],_) => th
   455     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   456     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   457 
   458 (*resolution: P==>Q, Q==>R gives P==>R. *)
   459 fun tha RS thb = tha RSN (1,thb);
   460 
   461 (*For joining lists of rules*)
   462 fun thas RLN (i,thbs) =
   463   let val resolve = biresolution false (map (pair false) thas) i
   464       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   465   in  List.concat (map resb thbs)  end;
   466 
   467 fun thas RL thbs = thas RLN (1,thbs);
   468 
   469 (*Resolve a list of rules against bottom_rl from right to left;
   470   makes proof trees*)
   471 fun rls MRS bottom_rl =
   472   let fun rs_aux i [] = bottom_rl
   473         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   474   in  rs_aux 1 rls  end;
   475 
   476 (*As above, but for rule lists*)
   477 fun rlss MRL bottom_rls =
   478   let fun rs_aux i [] = bottom_rls
   479         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   480   in  rs_aux 1 rlss  end;
   481 
   482 (*A version of MRS with more appropriate argument order*)
   483 fun bottom_rl OF rls = rls MRS bottom_rl;
   484 
   485 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   486   with no lifting or renaming!  Q may contain ==> or meta-quants
   487   ALWAYS deletes premise i *)
   488 fun compose(tha,i,thb) =
   489     Seq.list_of (bicompose false (false,tha,0) i thb);
   490 
   491 fun compose_single (tha,i,thb) =
   492   (case compose (tha,i,thb) of
   493     [th] => th
   494   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   495 
   496 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   497 fun tha COMP thb =
   498     case compose(tha,1,thb) of
   499         [th] => th
   500       | _ =>   raise THM("COMP", 1, [tha,thb]);
   501 
   502 
   503 (** theorem equality **)
   504 
   505 (*True if the two theorems have the same signature.*)
   506 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   507 
   508 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   509 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   510 
   511 (*Useful "distance" function for BEST_FIRST*)
   512 val size_of_thm = size_of_term o prop_of;
   513 
   514 (*maintain lists of theorems --- preserving canonical order*)
   515 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   516 fun add_rules rs rules = rs @ del_rules rs rules;
   517 val del_rule = del_rules o single;
   518 val add_rule = add_rules o single;
   519 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   520 
   521 
   522 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   523     (some) type variable renaming **)
   524 
   525  (* Can't use term_vars, because it sorts the resulting list of variable names.
   526     We instead need the unique list noramlised by the order of appearance
   527     in the term. *)
   528 fun term_vars' (t as Var(v,T)) = [t]
   529   | term_vars' (Abs(_,_,b)) = term_vars' b
   530   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   531   | term_vars' _ = [];
   532 
   533 fun forall_intr_vars th =
   534   let val {prop,sign,...} = rep_thm th;
   535       val vars = distinct (term_vars' prop);
   536   in forall_intr_list (map (cterm_of sign) vars) th end;
   537 
   538 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   539 
   540 
   541 (*** Meta-Rewriting Rules ***)
   542 
   543 fun read_prop s = read_cterm proto_sign (s, propT);
   544 
   545 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   546 fun store_standard_thm name thm = store_thm name (standard thm);
   547 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   548 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   549 
   550 val reflexive_thm =
   551   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   552   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   553 
   554 val symmetric_thm =
   555   let val xy = read_prop "x::'a::logic == y"
   556   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   557 
   558 val transitive_thm =
   559   let val xy = read_prop "x::'a::logic == y"
   560       val yz = read_prop "y::'a::logic == z"
   561       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   562   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   563 
   564 fun symmetric_fun thm = thm RS symmetric_thm;
   565 
   566 fun extensional eq =
   567   let val eq' =
   568     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   569   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   570 
   571 val imp_cong =
   572   let
   573     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   574     val AB = read_prop "PROP A ==> PROP B"
   575     val AC = read_prop "PROP A ==> PROP C"
   576     val A = read_prop "PROP A"
   577   in
   578     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   579       (implies_intr AB (implies_intr A
   580         (equal_elim (implies_elim (assume ABC) (assume A))
   581           (implies_elim (assume AB) (assume A)))))
   582       (implies_intr AC (implies_intr A
   583         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   584           (implies_elim (assume AC) (assume A)))))))
   585   end;
   586 
   587 val swap_prems_eq =
   588   let
   589     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   590     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   591     val A = read_prop "PROP A"
   592     val B = read_prop "PROP B"
   593   in
   594     store_standard_thm_open "swap_prems_eq" (equal_intr
   595       (implies_intr ABC (implies_intr B (implies_intr A
   596         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   597       (implies_intr BAC (implies_intr A (implies_intr B
   598         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   599   end;
   600 
   601 val refl_implies = reflexive implies;
   602 
   603 fun abs_def thm =
   604   let
   605     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   606     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   607       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   608         ct thm) (cvs, thm)
   609   in transitive
   610     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   611   end;
   612 
   613 
   614 (*** Some useful meta-theorems ***)
   615 
   616 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   617 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   618 val _ = store_thm "_" asm_rl;
   619 
   620 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   621 val cut_rl =
   622   store_standard_thm_open "cut_rl"
   623     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   624 
   625 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   626      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   627 val revcut_rl =
   628   let val V = read_prop "PROP V"
   629       and VW = read_prop "PROP V ==> PROP W";
   630   in
   631     store_standard_thm_open "revcut_rl"
   632       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   633   end;
   634 
   635 (*for deleting an unwanted assumption*)
   636 val thin_rl =
   637   let val V = read_prop "PROP V"
   638       and W = read_prop "PROP W";
   639   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   640 
   641 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   642 val triv_forall_equality =
   643   let val V  = read_prop "PROP V"
   644       and QV = read_prop "!!x::'a. PROP V"
   645       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   646   in
   647     store_standard_thm_open "triv_forall_equality"
   648       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   649         (implies_intr V  (forall_intr x (assume V))))
   650   end;
   651 
   652 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   653    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   654    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   655 *)
   656 val swap_prems_rl =
   657   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   658       val major = assume cmajor;
   659       val cminor1 = read_prop "PROP PhiA";
   660       val minor1 = assume cminor1;
   661       val cminor2 = read_prop "PROP PhiB";
   662       val minor2 = assume cminor2;
   663   in store_standard_thm_open "swap_prems_rl"
   664        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   665          (implies_elim (implies_elim major minor1) minor2))))
   666   end;
   667 
   668 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   669    ==> PROP ?phi == PROP ?psi
   670    Introduction rule for == as a meta-theorem.
   671 *)
   672 val equal_intr_rule =
   673   let val PQ = read_prop "PROP phi ==> PROP psi"
   674       and QP = read_prop "PROP psi ==> PROP phi"
   675   in
   676     store_standard_thm_open "equal_intr_rule"
   677       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   678   end;
   679 
   680 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   681 val equal_elim_rule1 =
   682   let val eq = read_prop "PROP phi == PROP psi"
   683       and P = read_prop "PROP phi"
   684   in store_standard_thm_open "equal_elim_rule1"
   685     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   686   end;
   687 
   688 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   689 
   690 val remdups_rl =
   691   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   692   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   693 
   694 
   695 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   696   Rewrite rule for HHF normalization.*)
   697 
   698 val norm_hhf_eq =
   699   let
   700     val cert = Thm.cterm_of proto_sign;
   701     val aT = TFree ("'a", Term.logicS);
   702     val all = Term.all aT;
   703     val x = Free ("x", aT);
   704     val phi = Free ("phi", propT);
   705     val psi = Free ("psi", aT --> propT);
   706 
   707     val cx = cert x;
   708     val cphi = cert phi;
   709     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   710     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   711   in
   712     Thm.equal_intr
   713       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   714         |> Thm.forall_elim cx
   715         |> Thm.implies_intr cphi
   716         |> Thm.forall_intr cx
   717         |> Thm.implies_intr lhs)
   718       (Thm.implies_elim
   719           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   720         |> Thm.forall_intr cx
   721         |> Thm.implies_intr cphi
   722         |> Thm.implies_intr rhs)
   723     |> store_standard_thm_open "norm_hhf_eq"
   724   end;
   725 
   726 fun is_norm_hhf tm =
   727   let
   728     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   729       | is_norm (t $ u) = is_norm t andalso is_norm u
   730       | is_norm (Abs (_, _, t)) = is_norm t
   731       | is_norm _ = true;
   732   in is_norm (Pattern.beta_eta_contract tm) end;
   733 
   734 fun norm_hhf sg t =
   735   if is_norm_hhf t then t
   736   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   737 
   738 
   739 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   740 
   741 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   742 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   743 
   744 fun read_instantiate_sg sg sinsts th =
   745     let val ts = types_sorts th;
   746         val used = add_term_tvarnames (prop_of th, []);
   747     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   748 
   749 (*Instantiate theorem th, reading instantiations under theory of th*)
   750 fun read_instantiate sinsts th =
   751     read_instantiate_sg (Thm.sign_of_thm th) sinsts th;
   752 
   753 
   754 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   755   Instantiates distinct Vars by terms, inferring type instantiations. *)
   756 local
   757   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   758     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   759         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   760         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   761         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   762         val (tye',maxi') = Type.unify (Sign.tsig_of sign') (tye, maxi) (T, U)
   763           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   764     in  (sign', tye', maxi')  end;
   765 in
   766 fun cterm_instantiate ctpairs0 th =
   767   let val (sign,tye,_) = foldr add_types (ctpairs0, (Thm.sign_of_thm th, Vartab.empty, 0))
   768       fun instT(ct,cu) = 
   769         let val inst = cterm_of sign o subst_TVars_Vartab tye o term_of
   770         in (inst ct, inst cu) end
   771       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   772   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   773   handle TERM _ =>
   774            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   775        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   776 end;
   777 
   778 
   779 (** Derived rules mainly for METAHYPS **)
   780 
   781 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   782 fun equal_abs_elim ca eqth =
   783   let val {sign=signa, t=a, ...} = rep_cterm ca
   784       and combth = combination eqth (reflexive ca)
   785       val {sign,prop,...} = rep_thm eqth
   786       val (abst,absu) = Logic.dest_equals prop
   787       val cterm = cterm_of (Sign.merge (sign,signa))
   788   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   789            (transitive combth (beta_conversion false (cterm (absu$a))))
   790   end
   791   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   792 
   793 (*Calling equal_abs_elim with multiple terms*)
   794 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   795 
   796 
   797 (*** Goal (PROP A) <==> PROP A ***)
   798 
   799 local
   800   val cert = Thm.cterm_of proto_sign;
   801   val A = Free ("A", propT);
   802   val G = Logic.mk_goal A;
   803   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   804 in
   805   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   806       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   807   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   808       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   809 end;
   810 
   811 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   812 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   813 
   814 fun implies_intr_goals cprops thm =
   815   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   816   |> implies_intr_list (map mk_cgoal cprops);
   817 
   818 
   819 
   820 (** variations on instantiate **)
   821 
   822 (*shorthand for instantiating just one variable in the current theory*)
   823 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   824 
   825 
   826 (* collect vars in left-to-right order *)
   827 
   828 fun tvars_of_terms ts = rev (foldl Term.add_tvars ([], ts));
   829 fun vars_of_terms ts = rev (foldl Term.add_vars ([], ts));
   830 
   831 fun tvars_of thm = tvars_of_terms [prop_of thm];
   832 fun vars_of thm = vars_of_terms [prop_of thm];
   833 
   834 
   835 (* instantiate by left-to-right occurrence of variables *)
   836 
   837 fun instantiate' cTs cts thm =
   838   let
   839     fun err msg =
   840       raise TYPE ("instantiate': " ^ msg,
   841         mapfilter (apsome Thm.typ_of) cTs,
   842         mapfilter (apsome Thm.term_of) cts);
   843 
   844     fun inst_of (v, ct) =
   845       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   846         handle TYPE (msg, _, _) => err msg;
   847 
   848     fun zip_vars _ [] = []
   849       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   850       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   851       | zip_vars [] _ = err "more instantiations than variables in thm";
   852 
   853     (*instantiate types first!*)
   854     val thm' =
   855       if forall is_none cTs then thm
   856       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   857     in
   858       if forall is_none cts then thm'
   859       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   860     end;
   861 
   862 
   863 
   864 (** renaming of bound variables **)
   865 
   866 (* replace bound variables x_i in thm by y_i *)
   867 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   868 
   869 fun rename_bvars [] thm = thm
   870   | rename_bvars vs thm =
   871     let
   872       val {sign, prop, ...} = rep_thm thm;
   873       fun ren (Abs (x, T, t)) = Abs (if_none (assoc (vs, x)) x, T, ren t)
   874         | ren (t $ u) = ren t $ ren u
   875         | ren t = t;
   876     in equal_elim (reflexive (cterm_of sign (ren prop))) thm end;
   877 
   878 
   879 (* renaming in left-to-right order *)
   880 
   881 fun rename_bvars' xs thm =
   882   let
   883     val {sign, prop, ...} = rep_thm thm;
   884     fun rename [] t = ([], t)
   885       | rename (x' :: xs) (Abs (x, T, t)) =
   886           let val (xs', t') = rename xs t
   887           in (xs', Abs (if_none x' x, T, t')) end
   888       | rename xs (t $ u) =
   889           let
   890             val (xs', t') = rename xs t;
   891             val (xs'', u') = rename xs' u
   892           in (xs'', t' $ u') end
   893       | rename xs t = (xs, t);
   894   in case rename xs prop of
   895       ([], prop') => equal_elim (reflexive (cterm_of sign prop')) thm
   896     | _ => error "More names than abstractions in theorem"
   897   end;
   898 
   899 
   900 
   901 (* unvarify(T) *)
   902 
   903 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   904 
   905 fun unvarifyT thm =
   906   let
   907     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   908     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   909   in instantiate' tfrees [] thm end;
   910 
   911 fun unvarify raw_thm =
   912   let
   913     val thm = unvarifyT raw_thm;
   914     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   915     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   916   in instantiate' [] frees thm end;
   917 
   918 
   919 (* tvars_intr_list *)
   920 
   921 fun tfrees_of thm =
   922   let val {hyps, prop, ...} = Thm.rep_thm thm
   923   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   924 
   925 fun tvars_intr_list tfrees thm =
   926   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   927 
   928 
   929 (* increment var indexes *)
   930 
   931 fun incr_indexes_wrt is cTs cts thms =
   932   let
   933     val maxidx =
   934       foldl Int.max (~1, is @
   935         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   936         map (#maxidx o Thm.rep_cterm) cts @
   937         map (#maxidx o Thm.rep_thm) thms);
   938   in Thm.incr_indexes (maxidx + 1) end;
   939 
   940 
   941 (* freeze_all *)
   942 
   943 (*freeze all (T)Vars; assumes thm in standard form*)
   944 
   945 fun freeze_all_TVars thm =
   946   (case tvars_of thm of
   947     [] => thm
   948   | tvars =>
   949       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   950       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   951 
   952 fun freeze_all_Vars thm =
   953   (case vars_of thm of
   954     [] => thm
   955   | vars =>
   956       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   957       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   958 
   959 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   960 
   961 
   962 (* mk_triv_goal *)
   963 
   964 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   965 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   966 
   967 
   968 
   969 (** meta-level conjunction **)
   970 
   971 local
   972   val A = read_prop "PROP A";
   973   val B = read_prop "PROP B";
   974   val C = read_prop "PROP C";
   975   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   976 
   977   val proj1 =
   978     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   979     |> forall_elim_vars 0;
   980 
   981   val proj2 =
   982     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   983     |> forall_elim_vars 0;
   984 
   985   val conj_intr_rule =
   986     forall_intr_list [A, B] (implies_intr_list [A, B]
   987       (Thm.forall_intr C (Thm.implies_intr ABC
   988         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   989     |> forall_elim_vars 0;
   990 
   991   val incr = incr_indexes_wrt [] [] [];
   992 in
   993 
   994 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   995 
   996 fun conj_intr_list [] = asm_rl
   997   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
   998 
   999 fun conj_elim th =
  1000   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
  1001   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
  1002 
  1003 fun conj_elim_list th =
  1004   let val (th1, th2) = conj_elim th
  1005   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
  1006 
  1007 fun conj_elim_precise 0 _ = []
  1008   | conj_elim_precise 1 th = [th]
  1009   | conj_elim_precise n th =
  1010       let val (th1, th2) = conj_elim th
  1011       in th1 :: conj_elim_precise (n - 1) th2 end;
  1012 
  1013 val conj_intr_thm = store_standard_thm_open "conjunctionI"
  1014   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
  1015 
  1016 end;
  1017 
  1018 end;
  1019 
  1020 structure BasicDrule: BASIC_DRULE = Drule;
  1021 open BasicDrule;