src/Pure/pattern.ML
author wenzelm
Thu Apr 22 10:52:32 2004 +0200 (2004-04-22)
changeset 14643 130076a81b84
parent 13998 75a399c2781f
child 14787 724ce6e574e3
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18   sig
    19   type type_sig
    20   type sg
    21   type env
    22   val trace_unify_fail  : bool ref
    23   val aeconv            : term * term -> bool
    24   val eta_contract      : term -> term
    25   val eta_long          : typ list -> term -> term
    26   val beta_eta_contract : term -> term
    27   val eta_contract_atom : term -> term
    28   val match             : type_sig -> term * term
    29                           -> (indexname*typ)list * (indexname*term)list
    30   val first_order_match : type_sig -> term * term
    31                           -> (indexname*typ)list * (indexname*term)list
    32   val matches           : type_sig -> term * term -> bool
    33   val matches_subterm   : type_sig -> term * term -> bool
    34   val unify             : sg * env * (term * term)list -> env
    35   val first_order       : term -> bool
    36   val pattern           : term -> bool
    37   val rewrite_term      : type_sig -> (term * term) list -> (term -> term option) list
    38                           -> term -> term
    39   exception Unif
    40   exception MATCH
    41   exception Pattern
    42   end;
    43 
    44 structure Pattern : PATTERN =
    45 struct
    46 
    47 type type_sig = Type.type_sig
    48 type sg = Sign.sg
    49 type env = Envir.env
    50 
    51 exception Unif;
    52 exception Pattern;
    53 
    54 val trace_unify_fail = ref false;
    55 
    56 (* Only for communication between unification and error message printing *)
    57 val sgr = ref Sign.pre_pure
    58 
    59 fun string_of_term env binders t = Sign.string_of_term (!sgr)
    60   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    61 
    62 fun bname binders i = fst(nth_elem(i,binders));
    63 fun bnames binders is = space_implode " " (map (bname binders) is);
    64 
    65 fun typ_clash(tye,T,U) =
    66   if !trace_unify_fail
    67   then let val t = Sign.string_of_typ (!sgr) (Envir.norm_type tye T)
    68            and u = Sign.string_of_typ (!sgr) (Envir.norm_type tye U)
    69        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    70   else ()
    71 
    72 fun clash a b =
    73   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    74 
    75 fun boundVar binders i =
    76   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    77 
    78 fun clashBB binders i j =
    79   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    80   else ()
    81 
    82 fun clashB binders i s =
    83   if !trace_unify_fail then clash (boundVar binders i) s
    84   else ()
    85 
    86 fun proj_fail(env,binders,F,is,t) =
    87   if !trace_unify_fail
    88   then let val f = Syntax.string_of_vname F
    89            val xs = bnames binders is
    90            val u = string_of_term env binders t
    91            val ys = bnames binders (loose_bnos t \\ is)
    92        in tracing("Cannot unify variable " ^ f ^
    93                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    94                "\nTerm contains additional bound variable(s) " ^ ys)
    95        end
    96   else ()
    97 
    98 fun ocheck_fail(F,t,binders,env) =
    99   if !trace_unify_fail
   100   then let val f = Syntax.string_of_vname F
   101            val u = string_of_term env binders t
   102        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
   103                   "\nCannot unify!\n")
   104        end
   105   else ()
   106 
   107 fun occurs(F,t,env) =
   108     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
   109                                  Some(t) => occ t
   110                                | None    => F=G)
   111           | occ(t1$t2)      = occ t1 orelse occ t2
   112           | occ(Abs(_,_,t)) = occ t
   113           | occ _           = false
   114     in occ t end;
   115 
   116 
   117 fun mapbnd f =
   118     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   119           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   120           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   121           | mpb _ atom           = atom
   122     in mpb 0 end;
   123 
   124 fun idx [] j     = ~10000
   125   | idx(i::is) j = if i=j then length is else idx is j;
   126 
   127 fun at xs i = nth_elem (i,xs);
   128 
   129 fun mkabs (binders,is,t)  =
   130     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   131                         in Abs(x,T,mk is) end
   132           | mk []     = t
   133     in mk is end;
   134 
   135 val incr = mapbnd (fn i => i+1);
   136 
   137 fun ints_of []             = []
   138   | ints_of (Bound i ::bs) =
   139       let val is = ints_of bs
   140       in if i mem_int is then raise Pattern else i::is end
   141   | ints_of _              = raise Pattern;
   142 
   143 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   144 
   145 
   146 fun app (s,(i::is)) = app (s$Bound(i),is)
   147   | app (s,[])      = s;
   148 
   149 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   150   | red t            []      [] = t
   151   | red t            is      jn = app (mapbnd (at jn) t,is);
   152 
   153 
   154 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   155 fun split_type (T,0,Ts)                    = (Ts,T)
   156   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   157   | split_type _                           = error("split_type");
   158 
   159 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   160   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   161   in map (at Ts) is ---> U end;
   162 
   163 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   164 
   165 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   166   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   167   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   168 
   169 
   170 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   171 fun mk_proj_list is =
   172     let fun mk(i::is,j) = if i >= 0 then j :: mk(is,j-1) else mk(is,j-1)
   173           | mk([],_)    = []
   174     in mk(is,length is - 1) end;
   175 
   176 fun proj(s,env,binders,is) =
   177     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   178         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   179               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   180                             in (Abs(a,T,t'),env') end
   181             | t => (case strip_comb t of
   182                 (c as Const _,ts) =>
   183                          let val (ts',env') = prs(ts,env,d,binders)
   184                          in (list_comb(c,ts'),env') end
   185                  | (f as Free _,ts) =>
   186                          let val (ts',env') = prs(ts,env,d,binders)
   187                          in (list_comb(f,ts'),env') end
   188                  | (Bound(i),ts) =>
   189                          let val j = trans d i
   190                          in if j < 0 then raise Unif
   191                             else let val (ts',env') = prs(ts,env,d,binders)
   192                                  in (list_comb(Bound j,ts'),env') end
   193                          end
   194                  | (Var(F as (a,_),Fty),ts) =>
   195                       let val js = ints_of' env ts;
   196                           val js' = map (trans d) js;
   197                           val ks = mk_proj_list js';
   198                           val ls = filter (fn i => i >= 0) js'
   199                           val Hty = type_of_G env (Fty,length js,ks)
   200                           val (env',H) = Envir.genvar a (env,Hty)
   201                           val env'' =
   202                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   203                       in (app(H,ls),env'') end
   204                  | _  => raise Pattern))
   205         and prs(s::ss,env,d,binders) =
   206               let val (s',env1) = pr(s,env,d,binders)
   207                   val (ss',env2) = prs(ss,env1,d,binders)
   208               in (s'::ss',env2) end
   209           | prs([],env,_,_) = ([],env)
   210    in if downto0(is,length binders - 1) then (s,env)
   211       else pr(s,env,0,binders)
   212    end;
   213 
   214 
   215 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   216 fun mk_ff_list(is,js) =
   217     let fun mk([],[],_)        = []
   218           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   219                                         else mk(is,js,k-1)
   220           | mk _               = error"mk_ff_list"
   221     in mk(is,js,length is-1) end;
   222 
   223 fun flexflex1(env,binders,F,Fty,is,js) =
   224   if is=js then env
   225   else let val ks = mk_ff_list(is,js)
   226        in mknewhnf(env,binders,is,F,Fty,ks) end;
   227 
   228 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   229   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   230             if js subset_int is
   231             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   232                  in Envir.update((F,t),env) end
   233             else let val ks = is inter_int js
   234                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   235                      val (env',H) = Envir.genvar a (env,Hty)
   236                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   237                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   238                  end;
   239   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   240 
   241 val tsgr = ref(Type.tsig0);
   242 
   243 fun unify_types(T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   244   if T=U then env
   245   else let val (iTs',maxidx') = Type.unify (!tsgr) (iTs, maxidx) (U, T)
   246        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   247        handle Type.TUNIFY => (typ_clash(iTs,T,U); raise Unif);
   248 
   249 fun unif binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   250       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   251          let val name = if ns = "" then nt else ns
   252          in unif ((name,Ts)::binders) (env,(ts,tt)) end
   253     | (Abs(ns,Ts,ts),t) => unif ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   254     | (t,Abs(nt,Tt,tt)) => unif ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   255     | p => cases(binders,env,p)
   256 
   257 and cases(binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   258        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   259          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   260                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   261       | ((Var(F,_),ss),_)             => flexrigid(env,binders,F,ints_of' env ss,t)
   262       | (_,(Var(F,_),ts))             => flexrigid(env,binders,F,ints_of' env ts,s)
   263       | ((Const c,ss),(Const d,ts))   => rigidrigid(env,binders,c,d,ss,ts)
   264       | ((Free(f),ss),(Free(g),ts))   => rigidrigid(env,binders,f,g,ss,ts)
   265       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB (env,binders,i,j,ss,ts)
   266       | ((Abs(_),_),_)                => raise Pattern
   267       | (_,(Abs(_),_))                => raise Pattern
   268       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   269       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   270       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   271       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   272       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   273       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   274 
   275 
   276 and rigidrigid (env,binders,(a,Ta),(b,Tb),ss,ts) =
   277       if a<>b then (clash a b; raise Unif)
   278       else foldl (unif binders) (unify_types(Ta,Tb,env), ss~~ts)
   279 
   280 and rigidrigidB (env,binders,i,j,ss,ts) =
   281      if i <> j then (clashBB binders i j; raise Unif)
   282      else foldl (unif binders) (env ,ss~~ts)
   283 
   284 and flexrigid (params as (env,binders,F,is,t)) =
   285       if occurs(F,t,env) then (ocheck_fail(F,t,binders,env); raise Unif)
   286       else (let val (u,env') = proj(t,env,binders,is)
   287             in Envir.update((F,mkabs(binders,is,u)),env') end
   288             handle Unif => (proj_fail params; raise Unif));
   289 
   290 fun unify(sg,env,tus) = (sgr := sg; tsgr := Sign.tsig_of sg;
   291                          foldl (unif []) (env,tus));
   292 
   293 
   294 (*Eta-contract a term (fully)*)
   295 
   296 fun eta_contract t =
   297   let
   298     exception SAME;
   299     fun eta (Abs (a, T, body)) = 
   300       ((case eta body of
   301           body' as (f $ Bound 0) => 
   302 	    if loose_bvar1 (f, 0) then Abs(a, T, body')
   303 	    else incr_boundvars ~1 f
   304         | body' => Abs (a, T, body')) handle SAME =>
   305        (case body of
   306           (f $ Bound 0) => 
   307 	    if loose_bvar1 (f, 0) then raise SAME
   308 	    else incr_boundvars ~1 f
   309         | _ => raise SAME))
   310       | eta (f $ t) =
   311           (let val f' = eta f
   312            in f' $ etah t end handle SAME => f $ eta t)
   313       | eta _ = raise SAME
   314     and etah t = (eta t handle SAME => t)
   315   in etah t end;
   316 
   317 val beta_eta_contract = eta_contract o Envir.beta_norm;
   318 
   319 (*Eta-contract a term from outside: just enough to reduce it to an atom
   320 DOESN'T QUITE WORK!
   321 *)
   322 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   323       (case  eta_contract2 body  of
   324         body' as (f $ Bound 0) =>
   325             if loose_bvar1(f,0) then Abs(a,T,body')
   326             else eta_contract_atom (incr_boundvars ~1 f)
   327       | _ => t0)
   328   | eta_contract_atom t = t
   329 and eta_contract2 (f$t) = f $ eta_contract_atom t
   330   | eta_contract2 t     = eta_contract_atom t;
   331 
   332 (* put a term into eta long beta normal form *)
   333 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   334   | eta_long Ts t = (case strip_comb t of
   335       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   336     | (u, ts) => 
   337       let
   338         val Us = binder_types (fastype_of1 (Ts, t));
   339         val i = length Us
   340       in list_abs (map (pair "x") Us,
   341         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   342           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   343       end);
   344 
   345 
   346 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   347   Note that Consts and Vars may have more than one type.*)
   348 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   349 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   350   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   351   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   352   | aconv_aux (Bound i,    Bound j)    = i=j
   353   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   354   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   355   | aconv_aux _ =  false;
   356 
   357 
   358 (*** Matching ***)
   359 
   360 exception MATCH;
   361 
   362 fun typ_match tsig args = (Type.typ_match tsig args)
   363                           handle Type.TYPE_MATCH => raise MATCH;
   364 
   365 (*First-order matching;
   366   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   367   The pattern and object may have variables in common.
   368   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   369   Object is eta-contracted on the fly (by eta-expanding the pattern).
   370   Precondition: the pattern is already eta-contracted!
   371   Note: types are matched on the fly *)
   372 fun fomatch tsig =
   373   let
   374     fun mtch (instsp as (tyinsts,insts)) = fn
   375         (Var(ixn,T), t)  =>
   376           if loose_bvar(t,0) then raise MATCH
   377           else (case assoc_string_int(insts,ixn) of
   378                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   379                            (ixn,t)::insts)
   380                 | Some u => if t aeconv u then instsp else raise MATCH)
   381       | (Free (a,T), Free (b,U)) =>
   382           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   383       | (Const (a,T), Const (b,U))  =>
   384           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   385       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   386       | (Abs(_,T,t), Abs(_,U,u))  =>
   387           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   388       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   389       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   390       | _ => raise MATCH
   391   in mtch end;
   392 
   393 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   394 
   395 (* Matching of higher-order patterns *)
   396 
   397 fun match_bind(itms,binders,ixn,is,t) =
   398   let val js = loose_bnos t
   399   in if null is
   400      then if null js then (ixn,t)::itms else raise MATCH
   401      else if js subset_int is
   402           then let val t' = if downto0(is,length binders - 1) then t
   403                             else mapbnd (idx is) t
   404                in (ixn, mkabs(binders,is,t')) :: itms end
   405           else raise MATCH
   406   end;
   407 
   408 fun match tsg (po as (pat,obj)) =
   409 let
   410   (* Pre: pat and obj have same type *)
   411   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   412     case pat of
   413       Abs(ns,Ts,ts) =>
   414         (case obj of
   415            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   416          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   417                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   418     | _ => (case obj of
   419               Abs(nt,Tt,tt) =>
   420                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   421             | _ => cases(binders,env,pat,obj))
   422 
   423   and cases(binders,env as (iTs,itms),pat,obj) =
   424     let val (ph,pargs) = strip_comb pat
   425         fun rigrig1(iTs,oargs) =
   426               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   427         fun rigrig2((a,Ta),(b,Tb),oargs) =
   428               if a<> b then raise MATCH
   429               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   430     in case ph of
   431          Var(ixn,_) =>
   432            let val is = ints_of pargs
   433            in case assoc_string_int(itms,ixn) of
   434                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   435               | Some u => if obj aeconv (red u is []) then env
   436                           else raise MATCH
   437            end
   438        | _ =>
   439            let val (oh,oargs) = strip_comb obj
   440            in case (ph,oh) of
   441                 (Const c,Const d) => rigrig2(c,d,oargs)
   442               | (Free f,Free g)   => rigrig2(f,g,oargs)
   443               | (Bound i,Bound j) => if i<>j then raise MATCH
   444                                      else rigrig1(iTs,oargs)
   445               | (Abs _, _)        => raise Pattern
   446               | (_, Abs _)        => raise Pattern
   447               | _                 => raise MATCH
   448            end
   449     end;
   450 
   451   val pT = fastype_of pat
   452   and oT = fastype_of obj
   453   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   454   val insts2 = (iTs,[])
   455 
   456 in apfst Vartab.dest (mtch [] (insts2, po)
   457    handle Pattern => fomatch tsg insts2 po)
   458 end;
   459 
   460 (*Predicate: does the pattern match the object?*)
   461 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   462 
   463 (* Does pat match a subterm of obj? *)
   464 fun matches_subterm tsig (pat,obj) =
   465   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   466             case obj of
   467               Abs(x,T,t) => let val y = variant bounds x
   468                                 val f = Free(":" ^ y,T)
   469                             in msub(x::bounds,subst_bound(f,t)) end
   470             | s$t => msub(bounds,s) orelse msub(bounds,t)
   471             | _ => false
   472   in msub([],obj) end;
   473 
   474 fun first_order(Abs(_,_,t)) = first_order t
   475   | first_order(t $ u) = first_order t andalso first_order u andalso
   476                          not(is_Var t)
   477   | first_order _ = true;
   478 
   479 fun pattern(Abs(_,_,t)) = pattern t
   480   | pattern(t) = let val (head,args) = strip_comb t
   481                  in if is_Var head
   482                     then let val _ = ints_of args in true end
   483                          handle Pattern => false
   484                     else forall pattern args
   485                  end;
   486 
   487 
   488 (* rewriting -- simple but fast *)
   489 
   490 fun rewrite_term tsig rules procs tm =
   491   let
   492     val skel0 = Bound 0;
   493 
   494     val rhs_names =
   495       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   496 
   497     fun variant_absfree (x, T, t) =
   498       let
   499         val x' = variant (add_term_free_names (t, rhs_names)) x;
   500         val t' = subst_bound (Free (x', T), t);
   501       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   502 
   503     fun match_rew tm (tm1, tm2) =
   504       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   505       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   506         handle MATCH => None
   507       end;
   508 
   509     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   510       | rew tm = (case get_first (match_rew tm) rules of
   511           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   512         | x => x);
   513 
   514     fun rew1 (Var _) _ = None
   515       | rew1 skel tm = (case rew2 skel tm of
   516           Some tm1 => (case rew tm1 of
   517               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   518             | None => Some tm1)
   519         | None => (case rew tm of
   520               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   521             | None => None))
   522 
   523     and rew2 skel (tm1 $ tm2) = (case tm1 of
   524             Abs (_, _, body) =>
   525               let val tm' = subst_bound (tm2, body)
   526               in Some (if_none (rew2 skel0 tm') tm') end
   527           | _ => 
   528             let val (skel1, skel2) = (case skel of
   529                 skel1 $ skel2 => (skel1, skel2)
   530               | _ => (skel0, skel0))
   531             in case rew1 skel1 tm1 of
   532                 Some tm1' => (case rew1 skel2 tm2 of
   533                     Some tm2' => Some (tm1' $ tm2')
   534                   | None => Some (tm1' $ tm2))
   535               | None => (case rew1 skel2 tm2 of
   536                     Some tm2' => Some (tm1 $ tm2')
   537                   | None => None)
   538             end)
   539       | rew2 skel (Abs (x, T, tm)) =
   540           let
   541             val (abs, tm') = variant_absfree (x, T, tm);
   542             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   543           in case rew1 skel' tm' of
   544               Some tm'' => Some (abs tm'')
   545             | None => None
   546           end
   547       | rew2 _ _ = None
   548 
   549   in if_none (rew1 skel0 tm) tm end;
   550 
   551 end;
   552 
   553 val trace_unify_fail = Pattern.trace_unify_fail;