src/HOL/UNITY/Transformers.thy
author nipkow
Sun Dec 10 07:12:26 2006 +0100 (2006-12-10)
changeset 21733 131dd2a27137
parent 21312 1d39091a3208
child 23767 7272a839ccd9
permissions -rw-r--r--
Modified lattice locale
     1 (*  Title:      HOL/UNITY/Transformers
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   2003  University of Cambridge
     5 
     6 Predicate Transformers.  From 
     7 
     8     David Meier and Beverly Sanders,
     9     Composing Leads-to Properties
    10     Theoretical Computer Science 243:1-2 (2000), 339-361.
    11 
    12     David Meier,
    13     Progress Properties in Program Refinement and Parallel Composition
    14     Swiss Federal Institute of Technology Zurich (1997)
    15 *)
    16 
    17 header{*Predicate Transformers*}
    18 
    19 theory Transformers imports Comp begin
    20 
    21 subsection{*Defining the Predicate Transformers @{term wp},
    22    @{term awp} and  @{term wens}*}
    23 
    24 constdefs
    25   wp :: "[('a*'a) set, 'a set] => 'a set"  
    26     --{*Dijkstra's weakest-precondition operator (for an individual command)*}
    27     "wp act B == - (act^-1 `` (-B))"
    28 
    29   awp :: "['a program, 'a set] => 'a set"  
    30     --{*Dijkstra's weakest-precondition operator (for a program)*}
    31     "awp F B == (\<Inter>act \<in> Acts F. wp act B)"
    32 
    33   wens :: "['a program, ('a*'a) set, 'a set] => 'a set"  
    34     --{*The weakest-ensures transformer*}
    35     "wens F act B == gfp(\<lambda>X. (wp act B \<inter> awp F (B \<union> X)) \<union> B)"
    36 
    37 text{*The fundamental theorem for wp*}
    38 theorem wp_iff: "(A <= wp act B) = (act `` A <= B)"
    39 by (force simp add: wp_def) 
    40 
    41 text{*This lemma is a good deal more intuitive than the definition!*}
    42 lemma in_wp_iff: "(a \<in> wp act B) = (\<forall>x. (a,x) \<in> act --> x \<in> B)"
    43 by (simp add: wp_def, blast)
    44 
    45 lemma Compl_Domain_subset_wp: "- (Domain act) \<subseteq> wp act B"
    46 by (force simp add: wp_def) 
    47 
    48 lemma wp_empty [simp]: "wp act {} = - (Domain act)"
    49 by (force simp add: wp_def)
    50 
    51 text{*The identity relation is the skip action*}
    52 lemma wp_Id [simp]: "wp Id B = B"
    53 by (simp add: wp_def) 
    54 
    55 lemma wp_totalize_act:
    56      "wp (totalize_act act) B = (wp act B \<inter> Domain act) \<union> (B - Domain act)"
    57 by (simp add: wp_def totalize_act_def, blast)
    58 
    59 lemma awp_subset: "(awp F A \<subseteq> A)"
    60 by (force simp add: awp_def wp_def)
    61 
    62 lemma awp_Int_eq: "awp F (A\<inter>B) = awp F A \<inter> awp F B"
    63 by (simp add: awp_def wp_def, blast) 
    64 
    65 text{*The fundamental theorem for awp*}
    66 theorem awp_iff_constrains: "(A <= awp F B) = (F \<in> A co B)"
    67 by (simp add: awp_def constrains_def wp_iff INT_subset_iff) 
    68 
    69 lemma awp_iff_stable: "(A \<subseteq> awp F A) = (F \<in> stable A)"
    70 by (simp add: awp_iff_constrains stable_def) 
    71 
    72 lemma stable_imp_awp_ident: "F \<in> stable A ==> awp F A = A"
    73 apply (rule equalityI [OF awp_subset]) 
    74 apply (simp add: awp_iff_stable) 
    75 done
    76 
    77 lemma wp_mono: "(A \<subseteq> B) ==> wp act A \<subseteq> wp act B"
    78 by (simp add: wp_def, blast)
    79 
    80 lemma awp_mono: "(A \<subseteq> B) ==> awp F A \<subseteq> awp F B"
    81 by (simp add: awp_def wp_def, blast)
    82 
    83 lemma wens_unfold:
    84      "wens F act B = (wp act B \<inter> awp F (B \<union> wens F act B)) \<union> B"
    85 apply (simp add: wens_def) 
    86 apply (rule gfp_unfold) 
    87 apply (simp add: mono_def wp_def awp_def, blast) 
    88 done
    89 
    90 lemma wens_Id [simp]: "wens F Id B = B"
    91 by (simp add: wens_def gfp_def wp_def awp_def Sup_set_eq, blast)
    92 
    93 text{*These two theorems justify the claim that @{term wens} returns the
    94 weakest assertion satisfying the ensures property*}
    95 lemma ensures_imp_wens: "F \<in> A ensures B ==> \<exists>act \<in> Acts F. A \<subseteq> wens F act B"
    96 apply (simp add: wens_def ensures_def transient_def, clarify) 
    97 apply (rule rev_bexI, assumption) 
    98 apply (rule gfp_upperbound)
    99 apply (simp add: constrains_def awp_def wp_def, blast)
   100 done
   101 
   102 lemma wens_ensures: "act \<in> Acts F ==> F \<in> (wens F act B) ensures B"
   103 by (simp add: wens_def gfp_def constrains_def awp_def wp_def
   104               ensures_def transient_def Sup_set_eq, blast)
   105 
   106 text{*These two results constitute assertion (4.13) of the thesis*}
   107 lemma wens_mono: "(A \<subseteq> B) ==> wens F act A \<subseteq> wens F act B"
   108 apply (simp add: wens_def wp_def awp_def) 
   109 apply (rule gfp_mono, blast) 
   110 done
   111 
   112 lemma wens_weakening: "B \<subseteq> wens F act B"
   113 by (simp add: wens_def gfp_def Sup_set_eq, blast)
   114 
   115 text{*Assertion (6), or 4.16 in the thesis*}
   116 lemma subset_wens: "A-B \<subseteq> wp act B \<inter> awp F (B \<union> A) ==> A \<subseteq> wens F act B" 
   117 apply (simp add: wens_def wp_def awp_def) 
   118 apply (rule gfp_upperbound, blast) 
   119 done
   120 
   121 text{*Assertion 4.17 in the thesis*}
   122 lemma Diff_wens_constrains: "F \<in> (wens F act A - A) co wens F act A"
   123 by (simp add: wens_def gfp_def wp_def awp_def constrains_def Sup_set_eq, blast)
   124   --{*Proved instantly, yet remarkably fragile. If @{text Un_subset_iff}
   125       is declared as an iff-rule, then it's almost impossible to prove. 
   126       One proof is via @{text meson} after expanding all definitions, but it's
   127       slow!*}
   128 
   129 text{*Assertion (7): 4.18 in the thesis.  NOTE that many of these results
   130 hold for an arbitrary action.  We often do not require @{term "act \<in> Acts F"}*}
   131 lemma stable_wens: "F \<in> stable A ==> F \<in> stable (wens F act A)"
   132 apply (simp add: stable_def)
   133 apply (drule constrains_Un [OF Diff_wens_constrains [of F act A]]) 
   134 apply (simp add: Un_Int_distrib2 Compl_partition2) 
   135 apply (erule constrains_weaken, blast) 
   136 apply (simp add: Un_subset_iff wens_weakening) 
   137 done
   138 
   139 text{*Assertion 4.20 in the thesis.*}
   140 lemma wens_Int_eq_lemma:
   141       "[|T-B \<subseteq> awp F T; act \<in> Acts F|]
   142        ==> T \<inter> wens F act B \<subseteq> wens F act (T\<inter>B)"
   143 apply (rule subset_wens) 
   144 apply (rule_tac P="\<lambda>x. ?f x \<subseteq> ?b" in ssubst [OF wens_unfold])
   145 apply (simp add: wp_def awp_def, blast)
   146 done
   147 
   148 text{*Assertion (8): 4.21 in the thesis. Here we indeed require
   149       @{term "act \<in> Acts F"}*}
   150 lemma wens_Int_eq:
   151       "[|T-B \<subseteq> awp F T; act \<in> Acts F|]
   152        ==> T \<inter> wens F act B = T \<inter> wens F act (T\<inter>B)"
   153 apply (rule equalityI)
   154  apply (simp_all add: Int_lower1 Int_subset_iff) 
   155  apply (rule wens_Int_eq_lemma, assumption+) 
   156 apply (rule subset_trans [OF _ wens_mono [of "T\<inter>B" B]], auto) 
   157 done
   158 
   159 
   160 subsection{*Defining the Weakest Ensures Set*}
   161 
   162 consts
   163   wens_set :: "['a program, 'a set] => 'a set set"
   164 
   165 inductive "wens_set F B"
   166  intros 
   167 
   168   Basis: "B \<in> wens_set F B"
   169 
   170   Wens:  "[|X \<in> wens_set F B; act \<in> Acts F|] ==> wens F act X \<in> wens_set F B"
   171 
   172   Union: "W \<noteq> {} ==> \<forall>U \<in> W. U \<in> wens_set F B ==> \<Union>W \<in> wens_set F B"
   173 
   174 lemma wens_set_imp_co: "A \<in> wens_set F B ==> F \<in> (A-B) co A"
   175 apply (erule wens_set.induct) 
   176   apply (simp add: constrains_def)
   177  apply (drule_tac act1=act and A1=X 
   178         in constrains_Un [OF Diff_wens_constrains]) 
   179  apply (erule constrains_weaken, blast) 
   180  apply (simp add: Un_subset_iff wens_weakening) 
   181 apply (rule constrains_weaken) 
   182 apply (rule_tac I=W and A="\<lambda>v. v-B" and A'="\<lambda>v. v" in constrains_UN, blast+)
   183 done
   184 
   185 lemma wens_set_imp_leadsTo: "A \<in> wens_set F B ==> F \<in> A leadsTo B"
   186 apply (erule wens_set.induct)
   187   apply (rule leadsTo_refl)  
   188  apply (blast intro: wens_ensures leadsTo_Trans) 
   189 apply (blast intro: leadsTo_Union) 
   190 done
   191 
   192 lemma leadsTo_imp_wens_set: "F \<in> A leadsTo B ==> \<exists>C \<in> wens_set F B. A \<subseteq> C"
   193 apply (erule leadsTo_induct_pre)
   194   apply (blast dest!: ensures_imp_wens intro: wens_set.Basis wens_set.Wens) 
   195  apply (clarify, drule ensures_weaken_R, assumption)  
   196  apply (blast dest!: ensures_imp_wens intro: wens_set.Wens)
   197 apply (case_tac "S={}") 
   198  apply (simp, blast intro: wens_set.Basis)
   199 apply (clarsimp dest!: bchoice simp: ball_conj_distrib Bex_def) 
   200 apply (rule_tac x = "\<Union>{Z. \<exists>U\<in>S. Z = f U}" in exI)
   201 apply (blast intro: wens_set.Union) 
   202 done
   203 
   204 text{*Assertion (9): 4.27 in the thesis.*}
   205 lemma leadsTo_iff_wens_set: "(F \<in> A leadsTo B) = (\<exists>C \<in> wens_set F B. A \<subseteq> C)"
   206 by (blast intro: leadsTo_imp_wens_set leadsTo_weaken_L wens_set_imp_leadsTo) 
   207 
   208 text{*This is the result that requires the definition of @{term wens_set} to
   209   require @{term W} to be non-empty in the Unio case, for otherwise we should
   210   always have @{term "{} \<in> wens_set F B"}.*}
   211 lemma wens_set_imp_subset: "A \<in> wens_set F B ==> B \<subseteq> A"
   212 apply (erule wens_set.induct) 
   213   apply (blast intro: wens_weakening [THEN subsetD])+
   214 done
   215 
   216 
   217 subsection{*Properties Involving Program Union*}
   218 
   219 text{*Assertion (4.30) of thesis, reoriented*}
   220 lemma awp_Join_eq: "awp (F\<squnion>G) B = awp F B \<inter> awp G B"
   221 by (simp add: awp_def wp_def, blast)
   222 
   223 lemma wens_subset: "wens F act B - B \<subseteq> wp act B \<inter> awp F (B \<union> wens F act B)"
   224 by (subst wens_unfold, fast) 
   225 
   226 text{*Assertion (4.31)*}
   227 lemma subset_wens_Join:
   228       "[|A = T \<inter> wens F act B;  T-B \<subseteq> awp F T; A-B \<subseteq> awp G (A \<union> B)|] 
   229        ==> A \<subseteq> wens (F\<squnion>G) act B"
   230 apply (subgoal_tac "(T \<inter> wens F act B) - B \<subseteq> 
   231                     wp act B \<inter> awp F (B \<union> wens F act B) \<inter> awp F T") 
   232  apply (rule subset_wens) 
   233  apply (simp add: awp_Join_eq awp_Int_eq Int_subset_iff Un_commute)
   234  apply (simp add: awp_def wp_def, blast) 
   235 apply (insert wens_subset [of F act B], blast) 
   236 done
   237 
   238 text{*Assertion (4.32)*}
   239 lemma wens_Join_subset: "wens (F\<squnion>G) act B \<subseteq> wens F act B"
   240 apply (simp add: wens_def) 
   241 apply (rule gfp_mono)
   242 apply (auto simp add: awp_Join_eq)  
   243 done
   244 
   245 text{*Lemma, because the inductive step is just too messy.*}
   246 lemma wens_Union_inductive_step:
   247   assumes awpF: "T-B \<subseteq> awp F T"
   248       and awpG: "!!X. X \<in> wens_set F B ==> (T\<inter>X) - B \<subseteq> awp G (T\<inter>X)"
   249   shows "[|X \<in> wens_set F B; act \<in> Acts F; Y \<subseteq> X; T\<inter>X = T\<inter>Y|]
   250          ==> wens (F\<squnion>G) act Y \<subseteq> wens F act X \<and>
   251              T \<inter> wens F act X = T \<inter> wens (F\<squnion>G) act Y"
   252 apply (subgoal_tac "wens (F\<squnion>G) act Y \<subseteq> wens F act X")  
   253  prefer 2
   254  apply (blast dest: wens_mono intro: wens_Join_subset [THEN subsetD], simp)
   255 apply (rule equalityI) 
   256  prefer 2 apply blast
   257 apply (simp add: Int_lower1 Int_subset_iff) 
   258 apply (frule wens_set_imp_subset) 
   259 apply (subgoal_tac "T-X \<subseteq> awp F T")  
   260  prefer 2 apply (blast intro: awpF [THEN subsetD]) 
   261 apply (rule_tac B = "wens (F\<squnion>G) act (T\<inter>X)" in subset_trans) 
   262  prefer 2 apply (blast intro!: wens_mono)
   263 apply (subst wens_Int_eq, assumption+) 
   264 apply (rule subset_wens_Join [of _ T], simp, blast)
   265 apply (subgoal_tac "T \<inter> wens F act (T\<inter>X) \<union> T\<inter>X = T \<inter> wens F act X")
   266  prefer 2
   267  apply (subst wens_Int_eq [symmetric], assumption+) 
   268  apply (blast intro: wens_weakening [THEN subsetD], simp) 
   269 apply (blast intro: awpG [THEN subsetD] wens_set.Wens)
   270 done
   271 
   272 theorem wens_Union:
   273   assumes awpF: "T-B \<subseteq> awp F T"
   274       and awpG: "!!X. X \<in> wens_set F B ==> (T\<inter>X) - B \<subseteq> awp G (T\<inter>X)"
   275       and major: "X \<in> wens_set F B"
   276   shows "\<exists>Y \<in> wens_set (F\<squnion>G) B. Y \<subseteq> X & T\<inter>X = T\<inter>Y"
   277 apply (rule wens_set.induct [OF major])
   278   txt{*Basis: trivial*}
   279   apply (blast intro: wens_set.Basis)
   280  txt{*Inductive step*}
   281  apply clarify 
   282  apply (rule_tac x = "wens (F\<squnion>G) act Y" in rev_bexI)
   283   apply (force intro: wens_set.Wens)
   284  apply (simp add: wens_Union_inductive_step [OF awpF awpG]) 
   285 txt{*Union: by Axiom of Choice*}
   286 apply (simp add: ball_conj_distrib Bex_def) 
   287 apply (clarify dest!: bchoice) 
   288 apply (rule_tac x = "\<Union>{Z. \<exists>U\<in>W. Z = f U}" in exI)
   289 apply (blast intro: wens_set.Union) 
   290 done
   291 
   292 theorem leadsTo_Join:
   293   assumes leadsTo: "F \<in> A leadsTo B"
   294       and awpF: "T-B \<subseteq> awp F T"
   295       and awpG: "!!X. X \<in> wens_set F B ==> (T\<inter>X) - B \<subseteq> awp G (T\<inter>X)"
   296   shows "F\<squnion>G \<in> T\<inter>A leadsTo B"
   297 apply (rule leadsTo [THEN leadsTo_imp_wens_set, THEN bexE]) 
   298 apply (rule wens_Union [THEN bexE]) 
   299    apply (rule awpF) 
   300   apply (erule awpG, assumption)
   301 apply (blast intro: wens_set_imp_leadsTo [THEN leadsTo_weaken_L])  
   302 done
   303 
   304 
   305 subsection {*The Set @{term "wens_set F B"} for a Single-Assignment Program*}
   306 text{*Thesis Section 4.3.3*}
   307 
   308 text{*We start by proving laws about single-assignment programs*}
   309 lemma awp_single_eq [simp]:
   310      "awp (mk_program (init, {act}, allowed)) B = B \<inter> wp act B"
   311 by (force simp add: awp_def wp_def) 
   312 
   313 lemma wp_Un_subset: "wp act A \<union> wp act B \<subseteq> wp act (A \<union> B)"
   314 by (force simp add: wp_def)
   315 
   316 lemma wp_Un_eq: "single_valued act ==> wp act (A \<union> B) = wp act A \<union> wp act B"
   317 apply (rule equalityI)
   318  apply (force simp add: wp_def single_valued_def) 
   319 apply (rule wp_Un_subset) 
   320 done
   321 
   322 lemma wp_UN_subset: "(\<Union>i\<in>I. wp act (A i)) \<subseteq> wp act (\<Union>i\<in>I. A i)"
   323 by (force simp add: wp_def)
   324 
   325 lemma wp_UN_eq:
   326      "[|single_valued act; I\<noteq>{}|]
   327       ==> wp act (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. wp act (A i))"
   328 apply (rule equalityI)
   329  prefer 2 apply (rule wp_UN_subset) 
   330  apply (simp add: wp_def Image_INT_eq) 
   331 done
   332 
   333 lemma wens_single_eq:
   334      "wens (mk_program (init, {act}, allowed)) act B = B \<union> wp act B"
   335 by (simp add: wens_def gfp_def wp_def Sup_set_eq, blast)
   336 
   337 
   338 text{*Next, we express the @{term "wens_set"} for single-assignment programs*}
   339 
   340 constdefs
   341   wens_single_finite :: "[('a*'a) set, 'a set, nat] => 'a set"  
   342     "wens_single_finite act B k == \<Union>i \<in> atMost k. ((wp act)^i) B"
   343 
   344   wens_single :: "[('a*'a) set, 'a set] => 'a set"  
   345     "wens_single act B == \<Union>i. ((wp act)^i) B"
   346 
   347 lemma wens_single_Un_eq:
   348       "single_valued act
   349        ==> wens_single act B \<union> wp act (wens_single act B) = wens_single act B"
   350 apply (rule equalityI)
   351  apply (simp_all add: Un_upper1 Un_subset_iff) 
   352 apply (simp add: wens_single_def wp_UN_eq, clarify) 
   353 apply (rule_tac a="Suc(i)" in UN_I, auto) 
   354 done
   355 
   356 lemma atMost_nat_nonempty: "atMost (k::nat) \<noteq> {}"
   357 by force
   358 
   359 lemma wens_single_finite_0 [simp]: "wens_single_finite act B 0 = B"
   360 by (simp add: wens_single_finite_def)
   361 
   362 lemma wens_single_finite_Suc:
   363       "single_valued act
   364        ==> wens_single_finite act B (Suc k) =
   365            wens_single_finite act B k \<union> wp act (wens_single_finite act B k)"
   366 apply (simp add: wens_single_finite_def image_def 
   367                  wp_UN_eq [OF _ atMost_nat_nonempty]) 
   368 apply (force elim!: le_SucE)
   369 done
   370 
   371 lemma wens_single_finite_Suc_eq_wens:
   372      "single_valued act
   373        ==> wens_single_finite act B (Suc k) =
   374            wens (mk_program (init, {act}, allowed)) act 
   375                 (wens_single_finite act B k)"
   376 by (simp add: wens_single_finite_Suc wens_single_eq) 
   377 
   378 lemma def_wens_single_finite_Suc_eq_wens:
   379      "[|F = mk_program (init, {act}, allowed); single_valued act|]
   380        ==> wens_single_finite act B (Suc k) =
   381            wens F act (wens_single_finite act B k)"
   382 by (simp add: wens_single_finite_Suc_eq_wens) 
   383 
   384 lemma wens_single_finite_Un_eq:
   385       "single_valued act
   386        ==> wens_single_finite act B k \<union> wp act (wens_single_finite act B k)
   387            \<in> range (wens_single_finite act B)"
   388 by (simp add: wens_single_finite_Suc [symmetric]) 
   389 
   390 lemma wens_single_eq_Union:
   391       "wens_single act B = \<Union>range (wens_single_finite act B)" 
   392 by (simp add: wens_single_finite_def wens_single_def, blast) 
   393 
   394 lemma wens_single_finite_eq_Union:
   395      "wens_single_finite act B n = (\<Union>k\<in>atMost n. wens_single_finite act B k)"
   396 apply (auto simp add: wens_single_finite_def) 
   397 apply (blast intro: le_trans) 
   398 done
   399 
   400 lemma wens_single_finite_mono:
   401      "m \<le> n ==> wens_single_finite act B m \<subseteq> wens_single_finite act B n"
   402 by (force simp add:  wens_single_finite_eq_Union [of act B n]) 
   403 
   404 lemma wens_single_finite_subset_wens_single:
   405       "wens_single_finite act B k \<subseteq> wens_single act B"
   406 by (simp add: wens_single_eq_Union, blast)
   407 
   408 lemma subset_wens_single_finite:
   409       "[|W \<subseteq> wens_single_finite act B ` (atMost k); single_valued act; W\<noteq>{}|]
   410        ==> \<exists>m. \<Union>W = wens_single_finite act B m"
   411 apply (induct k)
   412  apply (rule_tac x=0 in exI, simp, blast)
   413 apply (auto simp add: atMost_Suc)
   414 apply (case_tac "wens_single_finite act B (Suc k) \<in> W")
   415  prefer 2 apply blast
   416 apply (drule_tac x="Suc k" in spec)
   417 apply (erule notE, rule equalityI)
   418  prefer 2 apply blast
   419 apply (subst wens_single_finite_eq_Union)
   420 apply (simp add: atMost_Suc, blast)
   421 done
   422 
   423 text{*lemma for Union case*}
   424 lemma Union_eq_wens_single:
   425       "\<lbrakk>\<forall>k. \<not> W \<subseteq> wens_single_finite act B ` {..k};
   426         W \<subseteq> insert (wens_single act B)
   427             (range (wens_single_finite act B))\<rbrakk>
   428        \<Longrightarrow> \<Union>W = wens_single act B"
   429 apply (case_tac "wens_single act B \<in> W")
   430  apply (blast dest: wens_single_finite_subset_wens_single [THEN subsetD]) 
   431 apply (simp add: wens_single_eq_Union) 
   432 apply (rule equalityI, blast) 
   433 apply (simp add: UN_subset_iff, clarify)
   434 apply (subgoal_tac "\<exists>y\<in>W. \<exists>n. y = wens_single_finite act B n & i\<le>n")  
   435  apply (blast intro: wens_single_finite_mono [THEN subsetD]) 
   436 apply (drule_tac x=i in spec)
   437 apply (force simp add: atMost_def)
   438 done
   439 
   440 lemma wens_set_subset_single:
   441       "single_valued act
   442        ==> wens_set (mk_program (init, {act}, allowed)) B \<subseteq> 
   443            insert (wens_single act B) (range (wens_single_finite act B))"
   444 apply (rule subsetI)  
   445 apply (erule wens_set.induct)
   446   txt{*Basis*} 
   447   apply (fastsimp simp add: wens_single_finite_def)
   448  txt{*Wens inductive step*}
   449  apply (case_tac "acta = Id", simp)
   450  apply (simp add: wens_single_eq)
   451  apply (elim disjE)
   452  apply (simp add: wens_single_Un_eq)
   453  apply (force simp add: wens_single_finite_Un_eq)
   454 txt{*Union inductive step*}
   455 apply (case_tac "\<exists>k. W \<subseteq> wens_single_finite act B ` (atMost k)")
   456  apply (blast dest!: subset_wens_single_finite, simp) 
   457 apply (rule disjI1 [OF Union_eq_wens_single], blast+)
   458 done
   459 
   460 lemma wens_single_finite_in_wens_set:
   461       "single_valued act \<Longrightarrow>
   462          wens_single_finite act B k
   463          \<in> wens_set (mk_program (init, {act}, allowed)) B"
   464 apply (induct_tac k) 
   465  apply (simp add: wens_single_finite_def wens_set.Basis)
   466 apply (simp add: wens_set.Wens
   467                  wens_single_finite_Suc_eq_wens [of act B _ init allowed]) 
   468 done
   469 
   470 lemma single_subset_wens_set:
   471       "single_valued act
   472        ==> insert (wens_single act B) (range (wens_single_finite act B)) \<subseteq> 
   473            wens_set (mk_program (init, {act}, allowed)) B"
   474 apply (simp add: wens_single_eq_Union UN_eq) 
   475 apply (blast intro: wens_set.Union wens_single_finite_in_wens_set)
   476 done
   477 
   478 text{*Theorem (4.29)*}
   479 theorem wens_set_single_eq:
   480      "[|F = mk_program (init, {act}, allowed); single_valued act|]
   481       ==> wens_set F B =
   482           insert (wens_single act B) (range (wens_single_finite act B))"
   483 apply (rule equalityI)
   484  apply (simp add: wens_set_subset_single) 
   485 apply (erule ssubst, erule single_subset_wens_set) 
   486 done
   487 
   488 text{*Generalizing Misra's Fixed Point Union Theorem (4.41)*}
   489 
   490 lemma fp_leadsTo_Join:
   491     "[|T-B \<subseteq> awp F T; T-B \<subseteq> FP G; F \<in> A leadsTo B|] ==> F\<squnion>G \<in> T\<inter>A leadsTo B"
   492 apply (rule leadsTo_Join, assumption, blast)
   493 apply (simp add: FP_def awp_iff_constrains stable_def constrains_def, blast) 
   494 done
   495 
   496 end