src/HOL/Tools/hologic.ML
author haftmann
Fri May 15 16:39:18 2009 +0200 (2009-05-15)
changeset 31183 13effe47174c
parent 31135 e2d777dcf161
child 31205 98370b26c2ce
permissions -rw-r--r--
combinators for single-threaded operations
     1 (*  Title:      HOL/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val boolN: string
    12   val boolT: typ
    13   val Trueprop: term
    14   val mk_Trueprop: term -> term
    15   val dest_Trueprop: term -> term
    16   val true_const: term
    17   val false_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val Collect_const: typ -> term
    21   val mk_Collect: string * typ * term -> term
    22   val mk_mem: term * term -> term
    23   val dest_mem: term -> term * term
    24   val mk_set: typ -> term list -> term
    25   val dest_set: term -> term list
    26   val mk_UNIV: typ -> term
    27   val conj_intr: thm -> thm -> thm
    28   val conj_elim: thm -> thm * thm
    29   val conj_elims: thm -> thm list
    30   val conj: term
    31   val disj: term
    32   val imp: term
    33   val Not: term
    34   val mk_conj: term * term -> term
    35   val mk_disj: term * term -> term
    36   val mk_imp: term * term -> term
    37   val mk_not: term -> term
    38   val dest_conj: term -> term list
    39   val dest_disj: term -> term list
    40   val disjuncts: term -> term list
    41   val dest_imp: term -> term * term
    42   val dest_not: term -> term
    43   val eq_const: typ -> term
    44   val mk_eq: term * term -> term
    45   val dest_eq: term -> term * term
    46   val all_const: typ -> term
    47   val mk_all: string * typ * term -> term
    48   val list_all: (string * typ) list * term -> term
    49   val exists_const: typ -> term
    50   val mk_exists: string * typ * term -> term
    51   val choice_const: typ -> term
    52   val class_eq: string
    53   val mk_binop: string -> term * term -> term
    54   val mk_binrel: string -> term * term -> term
    55   val dest_bin: string -> typ -> term -> term * term
    56   val unitT: typ
    57   val is_unitT: typ -> bool
    58   val unit: term
    59   val is_unit: term -> bool
    60   val mk_prodT: typ * typ -> typ
    61   val dest_prodT: typ -> typ * typ
    62   val pair_const: typ -> typ -> term
    63   val mk_prod: term * term -> term
    64   val dest_prod: term -> term * term
    65   val mk_fst: term -> term
    66   val mk_snd: term -> term
    67   val split_const: typ * typ * typ -> term
    68   val mk_split: term -> term
    69   val prodT_factors: typ -> typ list
    70   val mk_tuple: typ -> term list -> term
    71   val dest_tuple: term -> term list
    72   val ap_split: typ -> typ -> term -> term
    73   val prod_factors: term -> int list list
    74   val dest_tuple': int list list -> term -> term list
    75   val prodT_factors': int list list -> typ -> typ list
    76   val ap_split': int list list -> typ -> typ -> term -> term
    77   val mk_tuple': int list list -> typ -> term list -> term
    78   val mk_tupleT: int list list -> typ list -> typ
    79   val strip_split: term -> term * typ list * int list list
    80   val natT: typ
    81   val zero: term
    82   val is_zero: term -> bool
    83   val mk_Suc: term -> term
    84   val dest_Suc: term -> term
    85   val Suc_zero: term
    86   val mk_nat: int -> term
    87   val dest_nat: term -> int
    88   val class_size: string
    89   val size_const: typ -> term
    90   val indexT: typ
    91   val intT: typ
    92   val pls_const: term
    93   val min_const: term
    94   val bit0_const: term
    95   val bit1_const: term
    96   val mk_bit: int -> term
    97   val dest_bit: term -> int
    98   val mk_numeral: int -> term
    99   val dest_numeral: term -> int
   100   val number_of_const: typ -> term
   101   val add_numerals: term -> (term * typ) list -> (term * typ) list
   102   val mk_number: typ -> int -> term
   103   val dest_number: term -> typ * int
   104   val realT: typ
   105   val nibbleT: typ
   106   val mk_nibble: int -> term
   107   val dest_nibble: term -> int
   108   val charT: typ
   109   val mk_char: int -> term
   110   val dest_char: term -> int
   111   val listT: typ -> typ
   112   val nil_const: typ -> term
   113   val cons_const: typ -> term
   114   val mk_list: typ -> term list -> term
   115   val dest_list: term -> term list
   116   val stringT: typ
   117   val mk_string: string -> term
   118   val dest_string: term -> string
   119   val message_stringT: typ
   120   val mk_message_string: string -> term
   121   val dest_message_string: term -> string
   122   val mk_typerep: typ -> term
   123   val mk_term_of: typ -> term -> term
   124   val reflect_term: term -> term
   125   val mk_return: typ -> typ -> term -> term
   126   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   127 end;
   128 
   129 structure HOLogic: HOLOGIC =
   130 struct
   131 
   132 (* HOL syntax *)
   133 
   134 val typeS: sort = ["HOL.type"];
   135 val typeT = TypeInfer.anyT typeS;
   136 
   137 
   138 (* bool and set *)
   139 
   140 val boolN = "bool";
   141 val boolT = Type (boolN, []);
   142 
   143 val true_const =  Const ("True", boolT);
   144 val false_const = Const ("False", boolT);
   145 
   146 fun mk_setT T = T --> boolT;
   147 
   148 fun dest_setT (Type ("fun", [T, Type ("bool", [])])) = T
   149   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   150 
   151 fun mk_set T ts =
   152   let
   153     val sT = mk_setT T;
   154     val empty = Const ("Set.empty", sT);
   155     fun insert t u = Const ("insert", T --> sT --> sT) $ t $ u;
   156   in fold_rev insert ts empty end;
   157 
   158 fun mk_UNIV T = Const ("Set.UNIV", mk_setT T);
   159 
   160 fun dest_set (Const ("Orderings.bot", _)) = []
   161   | dest_set (Const ("insert", _) $ t $ u) = t :: dest_set u
   162   | dest_set t = raise TERM ("dest_set", [t]);
   163 
   164 fun Collect_const T = Const ("Collect", (T --> boolT) --> mk_setT T);
   165 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   166 
   167 fun mk_mem (x, A) =
   168   let val setT = fastype_of A in
   169     Const ("op :", dest_setT setT --> setT --> boolT) $ x $ A
   170   end;
   171 
   172 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   173   | dest_mem t = raise TERM ("dest_mem", [t]);
   174 
   175 
   176 (* logic *)
   177 
   178 val Trueprop = Const ("Trueprop", boolT --> propT);
   179 
   180 fun mk_Trueprop P = Trueprop $ P;
   181 
   182 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   183   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   184 
   185 fun conj_intr thP thQ =
   186   let
   187     val (P, Q) = pairself (ObjectLogic.dest_judgment o Thm.cprop_of) (thP, thQ)
   188       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   189     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   190   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   191 
   192 fun conj_elim thPQ =
   193   let
   194     val (P, Q) = Thm.dest_binop (ObjectLogic.dest_judgment (Thm.cprop_of thPQ))
   195       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   196     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   197     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   198     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   199   in (thP, thQ) end;
   200 
   201 fun conj_elims th =
   202   let val (th1, th2) = conj_elim th
   203   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   204 
   205 val conj = @{term "op &"}
   206 and disj = @{term "op |"}
   207 and imp = @{term "op -->"}
   208 and Not = @{term "Not"};
   209 
   210 fun mk_conj (t1, t2) = conj $ t1 $ t2
   211 and mk_disj (t1, t2) = disj $ t1 $ t2
   212 and mk_imp (t1, t2) = imp $ t1 $ t2
   213 and mk_not t = Not $ t;
   214 
   215 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   216   | dest_conj t = [t];
   217 
   218 fun dest_disj (Const ("op |", _) $ t $ t') = t :: dest_disj t'
   219   | dest_disj t = [t];
   220 
   221 (*Like dest_disj, but flattens disjunctions however nested*)
   222 fun disjuncts_aux (Const ("op |", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   223   | disjuncts_aux t disjs = t::disjs;
   224 
   225 fun disjuncts t = disjuncts_aux t [];
   226 
   227 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   228   | dest_imp  t = raise TERM ("dest_imp", [t]);
   229 
   230 fun dest_not (Const ("Not", _) $ t) = t
   231   | dest_not t = raise TERM ("dest_not", [t]);
   232 
   233 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   234 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   235 
   236 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   237   | dest_eq t = raise TERM ("dest_eq", [t])
   238 
   239 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   240 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   241 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   242 
   243 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   244 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   245 
   246 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   247 
   248 val class_eq = "HOL.eq";
   249 
   250 
   251 (* binary operations and relations *)
   252 
   253 fun mk_binop c (t, u) =
   254   let val T = fastype_of t in
   255     Const (c, [T, T] ---> T) $ t $ u
   256   end;
   257 
   258 fun mk_binrel c (t, u) =
   259   let val T = fastype_of t in
   260     Const (c, [T, T] ---> boolT) $ t $ u
   261   end;
   262 
   263 (*destruct the application of a binary operator. The dummyT case is a crude
   264   way of handling polymorphic operators.*)
   265 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   266       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   267       else raise TERM ("dest_bin " ^ c, [tm])
   268   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   269 
   270 
   271 (* unit *)
   272 
   273 val unitT = Type ("Product_Type.unit", []);
   274 
   275 fun is_unitT (Type ("Product_Type.unit", [])) = true
   276   | is_unitT _ = false;
   277 
   278 val unit = Const ("Product_Type.Unity", unitT);
   279 
   280 fun is_unit (Const ("Product_Type.Unity", _)) = true
   281   | is_unit _ = false;
   282 
   283 
   284 (* prod *)
   285 
   286 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   287 
   288 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   289   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   290 
   291 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   292 
   293 fun mk_prod (t1, t2) =
   294   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   295     pair_const T1 T2 $ t1 $ t2
   296   end;
   297 
   298 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   299   | dest_prod t = raise TERM ("dest_prod", [t]);
   300 
   301 fun mk_fst p =
   302   let val pT = fastype_of p in
   303     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   304   end;
   305 
   306 fun mk_snd p =
   307   let val pT = fastype_of p in
   308     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   309   end;
   310 
   311 fun split_const (A, B, C) =
   312   Const ("split", (A --> B --> C) --> mk_prodT (A, B) --> C);
   313 
   314 fun mk_split t =
   315   (case Term.fastype_of t of
   316     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   317       Const ("split", T --> mk_prodT (A, B) --> C) $ t
   318   | _ => raise TERM ("mk_split: bad body type", [t]));
   319 
   320 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   321 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   322   | prodT_factors T = [T];
   323 
   324 (*Makes a nested tuple from a list, following the product type structure*)
   325 fun mk_tuple (Type ("*", [T1, T2])) tms =
   326         mk_prod (mk_tuple T1 tms,
   327                  mk_tuple T2 (Library.drop (length (prodT_factors T1), tms)))
   328   | mk_tuple T (t::_) = t;
   329 
   330 fun dest_tuple (Const ("Pair", _) $ t $ u) = dest_tuple t @ dest_tuple u
   331   | dest_tuple t = [t];
   332 
   333 (*In ap_split S T u, term u expects separate arguments for the factors of S,
   334   with result type T.  The call creates a new term expecting one argument
   335   of type S.*)
   336 fun ap_split T T3 u =
   337   let
   338     fun ap (T :: Ts) =
   339           (case T of
   340              Type ("*", [T1, T2]) =>
   341                split_const (T1, T2, Ts ---> T3) $ ap (T1 :: T2 :: Ts)
   342            | _ => Abs ("x", T, ap Ts))
   343       | ap [] =
   344           let val k = length (prodT_factors T)
   345           in list_comb (incr_boundvars k u, map Bound (k - 1 downto 0)) end
   346   in ap [T] end;
   347 
   348 
   349 (* operations on tuples with specific arities *)
   350 (*
   351   an "arity" of a tuple is a list of lists of integers
   352   ("factors"), denoting paths to subterms that are pairs
   353 *)
   354 
   355 fun prod_err s = raise TERM (s ^ ": inconsistent use of products", []);
   356 
   357 fun prod_factors t =
   358   let
   359     fun factors p (Const ("Pair", _) $ t $ u) =
   360           p :: factors (1::p) t @ factors (2::p) u
   361       | factors p _ = []
   362   in factors [] t end;
   363 
   364 fun dest_tuple' ps =
   365   let
   366     fun dest p t = if p mem ps then (case t of
   367         Const ("Pair", _) $ t $ u =>
   368           dest (1::p) t @ dest (2::p) u
   369       | _ => prod_err "dest_tuple'") else [t]
   370   in dest [] end;
   371 
   372 fun prodT_factors' ps =
   373   let
   374     fun factors p T = if p mem ps then (case T of
   375         Type ("*", [T1, T2]) =>
   376           factors (1::p) T1 @ factors (2::p) T2
   377       | _ => prod_err "prodT_factors'") else [T]
   378   in factors [] end;
   379 
   380 (*In ap_split' ps S T u, term u expects separate arguments for the factors of S,
   381   with result type T.  The call creates a new term expecting one argument
   382   of type S.*)
   383 fun ap_split' ps T T3 u =
   384   let
   385     fun ap ((p, T) :: pTs) =
   386           if p mem ps then (case T of
   387               Type ("*", [T1, T2]) =>
   388                 split_const (T1, T2, map snd pTs ---> T3) $
   389                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   390             | _ => prod_err "ap_split'")
   391           else Abs ("x", T, ap pTs)
   392       | ap [] =
   393           let val k = length ps
   394           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   395   in ap [([], T)] end;
   396 
   397 fun mk_tuple' ps =
   398   let
   399     fun mk p T ts =
   400       if p mem ps then (case T of
   401           Type ("*", [T1, T2]) =>
   402             let
   403               val (t, ts') = mk (1::p) T1 ts;
   404               val (u, ts'') = mk (2::p) T2 ts'
   405             in (pair_const T1 T2 $ t $ u, ts'') end
   406         | _ => prod_err "mk_tuple'")
   407       else (hd ts, tl ts)
   408   in fst oo mk [] end;
   409 
   410 fun mk_tupleT ps =
   411   let
   412     fun mk p Ts =
   413       if p mem ps then
   414         let
   415           val (T, Ts') = mk (1::p) Ts;
   416           val (U, Ts'') = mk (2::p) Ts'
   417         in (mk_prodT (T, U), Ts'') end
   418       else (hd Ts, tl Ts)
   419   in fst o mk [] end;
   420 
   421 fun strip_split t =
   422   let
   423     fun strip [] qs Ts t = (t, Ts, qs)
   424       | strip (p :: ps) qs Ts (Const ("split", _) $ t) =
   425           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   426       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   427       | strip (p :: ps) qs Ts t = strip ps qs
   428           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   429           (incr_boundvars 1 t $ Bound 0)
   430   in strip [[]] [] [] t end;
   431 
   432 
   433 (* nat *)
   434 
   435 val natT = Type ("nat", []);
   436 
   437 val zero = Const ("HOL.zero_class.zero", natT);
   438 
   439 fun is_zero (Const ("HOL.zero_class.zero", _)) = true
   440   | is_zero _ = false;
   441 
   442 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   443 
   444 fun dest_Suc (Const ("Suc", _) $ t) = t
   445   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   446 
   447 val Suc_zero = mk_Suc zero;
   448 
   449 fun mk_nat n =
   450   let
   451     fun mk 0 = zero
   452       | mk n = mk_Suc (mk (n - 1));
   453   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   454 
   455 fun dest_nat (Const ("HOL.zero_class.zero", _)) = 0
   456   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   457   | dest_nat t = raise TERM ("dest_nat", [t]);
   458 
   459 val class_size = "Nat.size";
   460 
   461 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   462 
   463 
   464 (* index *)
   465 
   466 val indexT = Type ("Code_Index.index", []);
   467 
   468 
   469 (* binary numerals and int -- non-unique representation due to leading zeros/ones! *)
   470 
   471 val intT = Type ("Int.int", []);
   472 
   473 val pls_const = Const ("Int.Pls", intT)
   474 and min_const = Const ("Int.Min", intT)
   475 and bit0_const = Const ("Int.Bit0", intT --> intT)
   476 and bit1_const = Const ("Int.Bit1", intT --> intT);
   477 
   478 fun mk_bit 0 = bit0_const
   479   | mk_bit 1 = bit1_const
   480   | mk_bit _ = raise TERM ("mk_bit", []);
   481 
   482 fun dest_bit (Const ("Int.Bit0", _)) = 0
   483   | dest_bit (Const ("Int.Bit1", _)) = 1
   484   | dest_bit t = raise TERM ("dest_bit", [t]);
   485 
   486 fun mk_numeral 0 = pls_const
   487   | mk_numeral ~1 = min_const
   488   | mk_numeral i =
   489       let val (q, r) = Integer.div_mod i 2;
   490       in mk_bit r $ mk_numeral q end;
   491 
   492 fun dest_numeral (Const ("Int.Pls", _)) = 0
   493   | dest_numeral (Const ("Int.Min", _)) = ~1
   494   | dest_numeral (Const ("Int.Bit0", _) $ bs) = 2 * dest_numeral bs
   495   | dest_numeral (Const ("Int.Bit1", _) $ bs) = 2 * dest_numeral bs + 1
   496   | dest_numeral t = raise TERM ("dest_numeral", [t]);
   497 
   498 fun number_of_const T = Const ("Int.number_class.number_of", intT --> T);
   499 
   500 fun add_numerals (Const ("Int.number_class.number_of", Type (_, [_, T])) $ t) = cons (t, T)
   501   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   502   | add_numerals (Abs (_, _, t)) = add_numerals t
   503   | add_numerals _ = I;
   504 
   505 fun mk_number T 0 = Const ("HOL.zero_class.zero", T)
   506   | mk_number T 1 = Const ("HOL.one_class.one", T)
   507   | mk_number T i = number_of_const T $ mk_numeral i;
   508 
   509 fun dest_number (Const ("HOL.zero_class.zero", T)) = (T, 0)
   510   | dest_number (Const ("HOL.one_class.one", T)) = (T, 1)
   511   | dest_number (Const ("Int.number_class.number_of", Type ("fun", [_, T])) $ t) =
   512       (T, dest_numeral t)
   513   | dest_number t = raise TERM ("dest_number", [t]);
   514 
   515 
   516 (* real *)
   517 
   518 val realT = Type ("RealDef.real", []);
   519 
   520 
   521 (* list *)
   522 
   523 fun listT T = Type ("List.list", [T]);
   524 
   525 fun nil_const T = Const ("List.list.Nil", listT T);
   526 
   527 fun cons_const T =
   528   let val lT = listT T
   529   in Const ("List.list.Cons", T --> lT --> lT) end;
   530 
   531 fun mk_list T ts =
   532   let
   533     val lT = listT T;
   534     val Nil = Const ("List.list.Nil", lT);
   535     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   536   in fold_rev Cons ts Nil end;
   537 
   538 fun dest_list (Const ("List.list.Nil", _)) = []
   539   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   540   | dest_list t = raise TERM ("dest_list", [t]);
   541 
   542 
   543 (* nibble *)
   544 
   545 val nibbleT = Type ("String.nibble", []);
   546 
   547 fun mk_nibble n =
   548   let val s =
   549     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   550     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   551     else raise TERM ("mk_nibble", [])
   552   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   553 
   554 fun dest_nibble t =
   555   let fun err () = raise TERM ("dest_nibble", [t]) in
   556     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   557       NONE => err ()
   558     | SOME c =>
   559         if size c <> 1 then err ()
   560         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   561         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   562         else err ())
   563   end;
   564 
   565 
   566 (* char *)
   567 
   568 val charT = Type ("String.char", []);
   569 
   570 fun mk_char n =
   571   if 0 <= n andalso n <= 255 then
   572     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   573       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   574   else raise TERM ("mk_char", []);
   575 
   576 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   577       dest_nibble t * 16 + dest_nibble u
   578   | dest_char t = raise TERM ("dest_char", [t]);
   579 
   580 
   581 (* string *)
   582 
   583 val stringT = Type ("String.string", []);
   584 
   585 val mk_string = mk_list charT o map (mk_char o ord) o explode;
   586 val dest_string = implode o map (chr o dest_char) o dest_list;
   587 
   588 
   589 (* message_string *)
   590 
   591 val message_stringT = Type ("String.message_string", []);
   592 
   593 fun mk_message_string s = Const ("String.message_string.STR", stringT --> message_stringT)
   594       $ mk_string s;
   595 fun dest_message_string (Const ("String.message_string.STR", _) $ t) =
   596       dest_string t
   597   | dest_message_string t = raise TERM ("dest_message_string", [t]);
   598 
   599 
   600 (* typerep and term *)
   601 
   602 val typerepT = Type ("Typerep.typerep", []);
   603 
   604 fun mk_typerep T = Const ("Typerep.typerep_class.typerep",
   605   Term.itselfT T --> typerepT) $ Logic.mk_type T;
   606 
   607 val termT = Type ("Code_Eval.term", []);
   608 
   609 fun mk_term_of T t = Const ("Code_Eval.term_of_class.term_of", T --> termT) $ t;
   610 
   611 fun reflect_term (Const (c, T)) =
   612       Const ("Code_Eval.Const", message_stringT --> typerepT --> termT)
   613         $ mk_message_string c $ mk_typerep T
   614   | reflect_term (t1 $ t2) =
   615       Const ("Code_Eval.App", termT --> termT --> termT)
   616         $ reflect_term t1 $ reflect_term t2
   617   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   618   | reflect_term t = t;
   619 
   620 
   621 (* open state monads *)
   622 
   623 fun mk_return T U x = pair_const T U $ x;
   624 
   625 fun mk_ST clauses t U (someT, V) =
   626   let
   627     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   628     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   629           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   630             $ t $ lambda (Free (v, T)) t', U)
   631       | mk_clause ((t, U), NONE) (t', U') =
   632           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   633             $ t $ t', U)
   634   in fold_rev mk_clause clauses (t, U) |> fst end;
   635 
   636 end;