src/HOL/HOL.thy
author wenzelm
Tue Feb 10 16:46:21 2015 +0100 (2015-02-10)
changeset 59499 14095f771781
parent 59498 50b60f501b05
child 59507 b468e0f8da2a
permissions -rw-r--r--
misc tuning;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
    11     "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 begin
    14 
    15 ML_file "~~/src/Tools/misc_legacy.ML"
    16 ML_file "~~/src/Tools/try.ML"
    17 ML_file "~~/src/Tools/quickcheck.ML"
    18 ML_file "~~/src/Tools/solve_direct.ML"
    19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
    20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
    21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
    22 ML_file "~~/src/Provers/hypsubst.ML"
    23 ML_file "~~/src/Provers/splitter.ML"
    24 ML_file "~~/src/Provers/classical.ML"
    25 ML_file "~~/src/Provers/blast.ML"
    26 ML_file "~~/src/Provers/clasimp.ML"
    27 ML_file "~~/src/Tools/eqsubst.ML"
    28 ML_file "~~/src/Provers/quantifier1.ML"
    29 ML_file "~~/src/Tools/atomize_elim.ML"
    30 ML_file "~~/src/Tools/cong_tac.ML"
    31 ML_file "~~/src/Tools/intuitionistic.ML" setup \<open>Intuitionistic.method_setup @{binding iprover}\<close>
    32 ML_file "~~/src/Tools/project_rule.ML"
    33 ML_file "~~/src/Tools/subtyping.ML"
    34 ML_file "~~/src/Tools/case_product.ML"
    35 
    36 
    37 ML \<open>Plugin_Name.declare_setup @{binding extraction}\<close>
    38 
    39 ML \<open>
    40   Plugin_Name.declare_setup @{binding quickcheck_random};
    41   Plugin_Name.declare_setup @{binding quickcheck_exhaustive};
    42   Plugin_Name.declare_setup @{binding quickcheck_bounded_forall};
    43   Plugin_Name.declare_setup @{binding quickcheck_full_exhaustive};
    44   Plugin_Name.declare_setup @{binding quickcheck_narrowing};
    45 \<close>
    46 ML \<open>
    47   Plugin_Name.define_setup @{binding quickcheck}
    48    [@{plugin quickcheck_exhaustive},
    49     @{plugin quickcheck_random},
    50     @{plugin quickcheck_bounded_forall},
    51     @{plugin quickcheck_full_exhaustive},
    52     @{plugin quickcheck_narrowing}]
    53 \<close>
    54 
    55 
    56 subsection {* Primitive logic *}
    57 
    58 subsubsection {* Core syntax *}
    59 
    60 setup {* Axclass.class_axiomatization (@{binding type}, []) *}
    61 default_sort type
    62 setup {* Object_Logic.add_base_sort @{sort type} *}
    63 
    64 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
    65 instance "fun" :: (type, type) type by (rule fun_arity)
    66 
    67 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
    68 instance itself :: (type) type by (rule itself_arity)
    69 
    70 typedecl bool
    71 
    72 judgment
    73   Trueprop      :: "bool => prop"                   ("(_)" 5)
    74 
    75 axiomatization
    76   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)  and
    77   eq            :: "['a, 'a] => bool"               (infixl "=" 50)  and
    78   The           :: "('a => bool) => 'a"
    79 
    80 consts
    81   True          :: bool
    82   False         :: bool
    83   Not           :: "bool => bool"                   ("~ _" [40] 40)
    84 
    85   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    86   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    87 
    88   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    89   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    90   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    91 
    92 
    93 subsubsection {* Additional concrete syntax *}
    94 
    95 notation (output)
    96   eq  (infix "=" 50)
    97 
    98 abbreviation
    99   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
   100   "x ~= y == ~ (x = y)"
   101 
   102 notation (output)
   103   not_equal  (infix "~=" 50)
   104 
   105 notation (xsymbols)
   106   Not  ("\<not> _" [40] 40) and
   107   conj  (infixr "\<and>" 35) and
   108   disj  (infixr "\<or>" 30) and
   109   implies  (infixr "\<longrightarrow>" 25) and
   110   not_equal  (infixl "\<noteq>" 50)
   111 
   112 notation (xsymbols output)
   113   not_equal  (infix "\<noteq>" 50)
   114 
   115 notation (HTML output)
   116   Not  ("\<not> _" [40] 40) and
   117   conj  (infixr "\<and>" 35) and
   118   disj  (infixr "\<or>" 30) and
   119   not_equal  (infix "\<noteq>" 50)
   120 
   121 abbreviation (iff)
   122   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   123   "A <-> B == A = B"
   124 
   125 notation (xsymbols)
   126   iff  (infixr "\<longleftrightarrow>" 25)
   127 
   128 syntax "_The" :: "[pttrn, bool] => 'a"  ("(3THE _./ _)" [0, 10] 10)
   129 translations "THE x. P" == "CONST The (%x. P)"
   130 print_translation {*
   131   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
   132       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   133       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   134 *}  -- {* To avoid eta-contraction of body *}
   135 
   136 nonterminal letbinds and letbind
   137 syntax
   138   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   139   ""            :: "letbind => letbinds"                 ("_")
   140   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   141   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   142 
   143 nonterminal case_syn and cases_syn
   144 syntax
   145   "_case_syntax" :: "['a, cases_syn] => 'b"  ("(case _ of/ _)" 10)
   146   "_case1" :: "['a, 'b] => case_syn"  ("(2_ =>/ _)" 10)
   147   "" :: "case_syn => cases_syn"  ("_")
   148   "_case2" :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   149 syntax (xsymbols)
   150   "_case1" :: "['a, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   151 
   152 notation (xsymbols)
   153   All  (binder "\<forall>" 10) and
   154   Ex  (binder "\<exists>" 10) and
   155   Ex1  (binder "\<exists>!" 10)
   156 
   157 notation (HTML output)
   158   All  (binder "\<forall>" 10) and
   159   Ex  (binder "\<exists>" 10) and
   160   Ex1  (binder "\<exists>!" 10)
   161 
   162 notation (HOL)
   163   All  (binder "! " 10) and
   164   Ex  (binder "? " 10) and
   165   Ex1  (binder "?! " 10)
   166 
   167 
   168 subsubsection {* Axioms and basic definitions *}
   169 
   170 axiomatization where
   171   refl: "t = (t::'a)" and
   172   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   173   ext: "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   174     -- {*Extensionality is built into the meta-logic, and this rule expresses
   175          a related property.  It is an eta-expanded version of the traditional
   176          rule, and similar to the ABS rule of HOL*} and
   177 
   178   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   179 
   180 axiomatization where
   181   impI: "(P ==> Q) ==> P-->Q" and
   182   mp: "[| P-->Q;  P |] ==> Q" and
   183 
   184   iff: "(P-->Q) --> (Q-->P) --> (P=Q)" and
   185   True_or_False: "(P=True) | (P=False)"
   186 
   187 defs
   188   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   189   All_def:      "All(P)    == (P = (%x. True))"
   190   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   191   False_def:    "False     == (!P. P)"
   192   not_def:      "~ P       == P-->False"
   193   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   194   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   195   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   196 
   197 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   198   where "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   199 
   200 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   201   where "Let s f \<equiv> f s"
   202 
   203 translations
   204   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   205   "let x = a in e"        == "CONST Let a (%x. e)"
   206 
   207 axiomatization undefined :: 'a
   208 
   209 class default = fixes default :: 'a
   210 
   211 
   212 subsection {* Fundamental rules *}
   213 
   214 subsubsection {* Equality *}
   215 
   216 lemma sym: "s = t ==> t = s"
   217   by (erule subst) (rule refl)
   218 
   219 lemma ssubst: "t = s ==> P s ==> P t"
   220   by (drule sym) (erule subst)
   221 
   222 lemma trans: "[| r=s; s=t |] ==> r=t"
   223   by (erule subst)
   224 
   225 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   226   by (rule trans [OF _ sym])
   227 
   228 lemma meta_eq_to_obj_eq:
   229   assumes meq: "A == B"
   230   shows "A = B"
   231   by (unfold meq) (rule refl)
   232 
   233 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   234      (* a = b
   235         |   |
   236         c = d   *)
   237 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   238 apply (rule trans)
   239 apply (rule trans)
   240 apply (rule sym)
   241 apply assumption+
   242 done
   243 
   244 text {* For calculational reasoning: *}
   245 
   246 lemma forw_subst: "a = b ==> P b ==> P a"
   247   by (rule ssubst)
   248 
   249 lemma back_subst: "P a ==> a = b ==> P b"
   250   by (rule subst)
   251 
   252 
   253 subsubsection {* Congruence rules for application *}
   254 
   255 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   256 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   257 apply (erule subst)
   258 apply (rule refl)
   259 done
   260 
   261 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   262 lemma arg_cong: "x=y ==> f(x)=f(y)"
   263 apply (erule subst)
   264 apply (rule refl)
   265 done
   266 
   267 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   268 apply (erule ssubst)+
   269 apply (rule refl)
   270 done
   271 
   272 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   273 apply (erule subst)+
   274 apply (rule refl)
   275 done
   276 
   277 ML {* fun cong_tac ctxt = Cong_Tac.cong_tac ctxt @{thm cong} *}
   278 
   279 
   280 subsubsection {* Equality of booleans -- iff *}
   281 
   282 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   283   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   284 
   285 lemma iffD2: "[| P=Q; Q |] ==> P"
   286   by (erule ssubst)
   287 
   288 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   289   by (erule iffD2)
   290 
   291 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   292   by (drule sym) (rule iffD2)
   293 
   294 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   295   by (drule sym) (rule rev_iffD2)
   296 
   297 lemma iffE:
   298   assumes major: "P=Q"
   299     and minor: "[| P --> Q; Q --> P |] ==> R"
   300   shows R
   301   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   302 
   303 
   304 subsubsection {*True*}
   305 
   306 lemma TrueI: "True"
   307   unfolding True_def by (rule refl)
   308 
   309 lemma eqTrueI: "P ==> P = True"
   310   by (iprover intro: iffI TrueI)
   311 
   312 lemma eqTrueE: "P = True ==> P"
   313   by (erule iffD2) (rule TrueI)
   314 
   315 
   316 subsubsection {*Universal quantifier*}
   317 
   318 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   319   unfolding All_def by (iprover intro: ext eqTrueI assms)
   320 
   321 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   322 apply (unfold All_def)
   323 apply (rule eqTrueE)
   324 apply (erule fun_cong)
   325 done
   326 
   327 lemma allE:
   328   assumes major: "ALL x. P(x)"
   329     and minor: "P(x) ==> R"
   330   shows R
   331   by (iprover intro: minor major [THEN spec])
   332 
   333 lemma all_dupE:
   334   assumes major: "ALL x. P(x)"
   335     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   336   shows R
   337   by (iprover intro: minor major major [THEN spec])
   338 
   339 
   340 subsubsection {* False *}
   341 
   342 text {*
   343   Depends upon @{text spec}; it is impossible to do propositional
   344   logic before quantifiers!
   345 *}
   346 
   347 lemma FalseE: "False ==> P"
   348   apply (unfold False_def)
   349   apply (erule spec)
   350   done
   351 
   352 lemma False_neq_True: "False = True ==> P"
   353   by (erule eqTrueE [THEN FalseE])
   354 
   355 
   356 subsubsection {* Negation *}
   357 
   358 lemma notI:
   359   assumes "P ==> False"
   360   shows "~P"
   361   apply (unfold not_def)
   362   apply (iprover intro: impI assms)
   363   done
   364 
   365 lemma False_not_True: "False ~= True"
   366   apply (rule notI)
   367   apply (erule False_neq_True)
   368   done
   369 
   370 lemma True_not_False: "True ~= False"
   371   apply (rule notI)
   372   apply (drule sym)
   373   apply (erule False_neq_True)
   374   done
   375 
   376 lemma notE: "[| ~P;  P |] ==> R"
   377   apply (unfold not_def)
   378   apply (erule mp [THEN FalseE])
   379   apply assumption
   380   done
   381 
   382 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   383   by (erule notE [THEN notI]) (erule meta_mp)
   384 
   385 
   386 subsubsection {*Implication*}
   387 
   388 lemma impE:
   389   assumes "P-->Q" "P" "Q ==> R"
   390   shows "R"
   391 by (iprover intro: assms mp)
   392 
   393 (* Reduces Q to P-->Q, allowing substitution in P. *)
   394 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   395 by (iprover intro: mp)
   396 
   397 lemma contrapos_nn:
   398   assumes major: "~Q"
   399       and minor: "P==>Q"
   400   shows "~P"
   401 by (iprover intro: notI minor major [THEN notE])
   402 
   403 (*not used at all, but we already have the other 3 combinations *)
   404 lemma contrapos_pn:
   405   assumes major: "Q"
   406       and minor: "P ==> ~Q"
   407   shows "~P"
   408 by (iprover intro: notI minor major notE)
   409 
   410 lemma not_sym: "t ~= s ==> s ~= t"
   411   by (erule contrapos_nn) (erule sym)
   412 
   413 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   414   by (erule subst, erule ssubst, assumption)
   415 
   416 
   417 subsubsection {*Existential quantifier*}
   418 
   419 lemma exI: "P x ==> EX x::'a. P x"
   420 apply (unfold Ex_def)
   421 apply (iprover intro: allI allE impI mp)
   422 done
   423 
   424 lemma exE:
   425   assumes major: "EX x::'a. P(x)"
   426       and minor: "!!x. P(x) ==> Q"
   427   shows "Q"
   428 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   429 apply (iprover intro: impI [THEN allI] minor)
   430 done
   431 
   432 
   433 subsubsection {*Conjunction*}
   434 
   435 lemma conjI: "[| P; Q |] ==> P&Q"
   436 apply (unfold and_def)
   437 apply (iprover intro: impI [THEN allI] mp)
   438 done
   439 
   440 lemma conjunct1: "[| P & Q |] ==> P"
   441 apply (unfold and_def)
   442 apply (iprover intro: impI dest: spec mp)
   443 done
   444 
   445 lemma conjunct2: "[| P & Q |] ==> Q"
   446 apply (unfold and_def)
   447 apply (iprover intro: impI dest: spec mp)
   448 done
   449 
   450 lemma conjE:
   451   assumes major: "P&Q"
   452       and minor: "[| P; Q |] ==> R"
   453   shows "R"
   454 apply (rule minor)
   455 apply (rule major [THEN conjunct1])
   456 apply (rule major [THEN conjunct2])
   457 done
   458 
   459 lemma context_conjI:
   460   assumes "P" "P ==> Q" shows "P & Q"
   461 by (iprover intro: conjI assms)
   462 
   463 
   464 subsubsection {*Disjunction*}
   465 
   466 lemma disjI1: "P ==> P|Q"
   467 apply (unfold or_def)
   468 apply (iprover intro: allI impI mp)
   469 done
   470 
   471 lemma disjI2: "Q ==> P|Q"
   472 apply (unfold or_def)
   473 apply (iprover intro: allI impI mp)
   474 done
   475 
   476 lemma disjE:
   477   assumes major: "P|Q"
   478       and minorP: "P ==> R"
   479       and minorQ: "Q ==> R"
   480   shows "R"
   481 by (iprover intro: minorP minorQ impI
   482                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   483 
   484 
   485 subsubsection {*Classical logic*}
   486 
   487 lemma classical:
   488   assumes prem: "~P ==> P"
   489   shows "P"
   490 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   491 apply assumption
   492 apply (rule notI [THEN prem, THEN eqTrueI])
   493 apply (erule subst)
   494 apply assumption
   495 done
   496 
   497 lemmas ccontr = FalseE [THEN classical]
   498 
   499 (*notE with premises exchanged; it discharges ~R so that it can be used to
   500   make elimination rules*)
   501 lemma rev_notE:
   502   assumes premp: "P"
   503       and premnot: "~R ==> ~P"
   504   shows "R"
   505 apply (rule ccontr)
   506 apply (erule notE [OF premnot premp])
   507 done
   508 
   509 (*Double negation law*)
   510 lemma notnotD: "~~P ==> P"
   511 apply (rule classical)
   512 apply (erule notE)
   513 apply assumption
   514 done
   515 
   516 lemma contrapos_pp:
   517   assumes p1: "Q"
   518       and p2: "~P ==> ~Q"
   519   shows "P"
   520 by (iprover intro: classical p1 p2 notE)
   521 
   522 
   523 subsubsection {*Unique existence*}
   524 
   525 lemma ex1I:
   526   assumes "P a" "!!x. P(x) ==> x=a"
   527   shows "EX! x. P(x)"
   528 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   529 
   530 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   531 lemma ex_ex1I:
   532   assumes ex_prem: "EX x. P(x)"
   533       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   534   shows "EX! x. P(x)"
   535 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   536 
   537 lemma ex1E:
   538   assumes major: "EX! x. P(x)"
   539       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   540   shows "R"
   541 apply (rule major [unfolded Ex1_def, THEN exE])
   542 apply (erule conjE)
   543 apply (iprover intro: minor)
   544 done
   545 
   546 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   547 apply (erule ex1E)
   548 apply (rule exI)
   549 apply assumption
   550 done
   551 
   552 
   553 subsubsection {*THE: definite description operator*}
   554 
   555 lemma the_equality:
   556   assumes prema: "P a"
   557       and premx: "!!x. P x ==> x=a"
   558   shows "(THE x. P x) = a"
   559 apply (rule trans [OF _ the_eq_trivial])
   560 apply (rule_tac f = "The" in arg_cong)
   561 apply (rule ext)
   562 apply (rule iffI)
   563  apply (erule premx)
   564 apply (erule ssubst, rule prema)
   565 done
   566 
   567 lemma theI:
   568   assumes "P a" and "!!x. P x ==> x=a"
   569   shows "P (THE x. P x)"
   570 by (iprover intro: assms the_equality [THEN ssubst])
   571 
   572 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   573 apply (erule ex1E)
   574 apply (erule theI)
   575 apply (erule allE)
   576 apply (erule mp)
   577 apply assumption
   578 done
   579 
   580 (*Easier to apply than theI: only one occurrence of P*)
   581 lemma theI2:
   582   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   583   shows "Q (THE x. P x)"
   584 by (iprover intro: assms theI)
   585 
   586 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   587 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   588            elim:allE impE)
   589 
   590 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   591 apply (rule the_equality)
   592 apply  assumption
   593 apply (erule ex1E)
   594 apply (erule all_dupE)
   595 apply (drule mp)
   596 apply  assumption
   597 apply (erule ssubst)
   598 apply (erule allE)
   599 apply (erule mp)
   600 apply assumption
   601 done
   602 
   603 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   604 apply (rule the_equality)
   605 apply (rule refl)
   606 apply (erule sym)
   607 done
   608 
   609 
   610 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   611 
   612 lemma disjCI:
   613   assumes "~Q ==> P" shows "P|Q"
   614 apply (rule classical)
   615 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   616 done
   617 
   618 lemma excluded_middle: "~P | P"
   619 by (iprover intro: disjCI)
   620 
   621 text {*
   622   case distinction as a natural deduction rule.
   623   Note that @{term "~P"} is the second case, not the first
   624 *}
   625 lemma case_split [case_names True False]:
   626   assumes prem1: "P ==> Q"
   627       and prem2: "~P ==> Q"
   628   shows "Q"
   629 apply (rule excluded_middle [THEN disjE])
   630 apply (erule prem2)
   631 apply (erule prem1)
   632 done
   633 
   634 (*Classical implies (-->) elimination. *)
   635 lemma impCE:
   636   assumes major: "P-->Q"
   637       and minor: "~P ==> R" "Q ==> R"
   638   shows "R"
   639 apply (rule excluded_middle [of P, THEN disjE])
   640 apply (iprover intro: minor major [THEN mp])+
   641 done
   642 
   643 (*This version of --> elimination works on Q before P.  It works best for
   644   those cases in which P holds "almost everywhere".  Can't install as
   645   default: would break old proofs.*)
   646 lemma impCE':
   647   assumes major: "P-->Q"
   648       and minor: "Q ==> R" "~P ==> R"
   649   shows "R"
   650 apply (rule excluded_middle [of P, THEN disjE])
   651 apply (iprover intro: minor major [THEN mp])+
   652 done
   653 
   654 (*Classical <-> elimination. *)
   655 lemma iffCE:
   656   assumes major: "P=Q"
   657       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   658   shows "R"
   659 apply (rule major [THEN iffE])
   660 apply (iprover intro: minor elim: impCE notE)
   661 done
   662 
   663 lemma exCI:
   664   assumes "ALL x. ~P(x) ==> P(a)"
   665   shows "EX x. P(x)"
   666 apply (rule ccontr)
   667 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   668 done
   669 
   670 
   671 subsubsection {* Intuitionistic Reasoning *}
   672 
   673 lemma impE':
   674   assumes 1: "P --> Q"
   675     and 2: "Q ==> R"
   676     and 3: "P --> Q ==> P"
   677   shows R
   678 proof -
   679   from 3 and 1 have P .
   680   with 1 have Q by (rule impE)
   681   with 2 show R .
   682 qed
   683 
   684 lemma allE':
   685   assumes 1: "ALL x. P x"
   686     and 2: "P x ==> ALL x. P x ==> Q"
   687   shows Q
   688 proof -
   689   from 1 have "P x" by (rule spec)
   690   from this and 1 show Q by (rule 2)
   691 qed
   692 
   693 lemma notE':
   694   assumes 1: "~ P"
   695     and 2: "~ P ==> P"
   696   shows R
   697 proof -
   698   from 2 and 1 have P .
   699   with 1 show R by (rule notE)
   700 qed
   701 
   702 lemma TrueE: "True ==> P ==> P" .
   703 lemma notFalseE: "~ False ==> P ==> P" .
   704 
   705 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   706   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   707   and [Pure.elim 2] = allE notE' impE'
   708   and [Pure.intro] = exI disjI2 disjI1
   709 
   710 lemmas [trans] = trans
   711   and [sym] = sym not_sym
   712   and [Pure.elim?] = iffD1 iffD2 impE
   713 
   714 
   715 subsubsection {* Atomizing meta-level connectives *}
   716 
   717 axiomatization where
   718   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   719 
   720 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   721 proof
   722   assume "!!x. P x"
   723   then show "ALL x. P x" ..
   724 next
   725   assume "ALL x. P x"
   726   then show "!!x. P x" by (rule allE)
   727 qed
   728 
   729 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   730 proof
   731   assume r: "A ==> B"
   732   show "A --> B" by (rule impI) (rule r)
   733 next
   734   assume "A --> B" and A
   735   then show B by (rule mp)
   736 qed
   737 
   738 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   739 proof
   740   assume r: "A ==> False"
   741   show "~A" by (rule notI) (rule r)
   742 next
   743   assume "~A" and A
   744   then show False by (rule notE)
   745 qed
   746 
   747 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   748 proof
   749   assume "x == y"
   750   show "x = y" by (unfold `x == y`) (rule refl)
   751 next
   752   assume "x = y"
   753   then show "x == y" by (rule eq_reflection)
   754 qed
   755 
   756 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   757 proof
   758   assume conj: "A &&& B"
   759   show "A & B"
   760   proof (rule conjI)
   761     from conj show A by (rule conjunctionD1)
   762     from conj show B by (rule conjunctionD2)
   763   qed
   764 next
   765   assume conj: "A & B"
   766   show "A &&& B"
   767   proof -
   768     from conj show A ..
   769     from conj show B ..
   770   qed
   771 qed
   772 
   773 lemmas [symmetric, rulify] = atomize_all atomize_imp
   774   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   775 
   776 
   777 subsubsection {* Atomizing elimination rules *}
   778 
   779 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   780   by rule iprover+
   781 
   782 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   783   by rule iprover+
   784 
   785 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   786   by rule iprover+
   787 
   788 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   789 
   790 
   791 subsection {* Package setup *}
   792 
   793 ML_file "Tools/hologic.ML"
   794 
   795 
   796 subsubsection {* Sledgehammer setup *}
   797 
   798 text {*
   799 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   800 that are prolific (match too many equality or membership literals) and relate to
   801 seldom-used facts. Some duplicate other rules.
   802 *}
   803 
   804 named_theorems no_atp "theorems that should be filtered out by Sledgehammer"
   805 
   806 
   807 subsubsection {* Classical Reasoner setup *}
   808 
   809 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   810   by (rule classical) iprover
   811 
   812 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   813   by (rule classical) iprover
   814 
   815 lemma thin_refl:
   816   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   817 
   818 ML {*
   819 structure Hypsubst = Hypsubst
   820 (
   821   val dest_eq = HOLogic.dest_eq
   822   val dest_Trueprop = HOLogic.dest_Trueprop
   823   val dest_imp = HOLogic.dest_imp
   824   val eq_reflection = @{thm eq_reflection}
   825   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   826   val imp_intr = @{thm impI}
   827   val rev_mp = @{thm rev_mp}
   828   val subst = @{thm subst}
   829   val sym = @{thm sym}
   830   val thin_refl = @{thm thin_refl};
   831 );
   832 open Hypsubst;
   833 
   834 structure Classical = Classical
   835 (
   836   val imp_elim = @{thm imp_elim}
   837   val not_elim = @{thm notE}
   838   val swap = @{thm swap}
   839   val classical = @{thm classical}
   840   val sizef = Drule.size_of_thm
   841   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   842 );
   843 
   844 structure Basic_Classical: BASIC_CLASSICAL = Classical;
   845 open Basic_Classical;
   846 *}
   847 
   848 setup {*
   849   (*prevent substitution on bool*)
   850   let
   851     fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   852       | non_bool_eq _ = false;
   853     fun hyp_subst_tac' ctxt =
   854       SUBGOAL (fn (goal, i) =>
   855         if Term.exists_Const non_bool_eq goal
   856         then Hypsubst.hyp_subst_tac ctxt i
   857         else no_tac);
   858   in
   859     Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
   860   end
   861 *}
   862 
   863 declare iffI [intro!]
   864   and notI [intro!]
   865   and impI [intro!]
   866   and disjCI [intro!]
   867   and conjI [intro!]
   868   and TrueI [intro!]
   869   and refl [intro!]
   870 
   871 declare iffCE [elim!]
   872   and FalseE [elim!]
   873   and impCE [elim!]
   874   and disjE [elim!]
   875   and conjE [elim!]
   876 
   877 declare ex_ex1I [intro!]
   878   and allI [intro!]
   879   and the_equality [intro]
   880   and exI [intro]
   881 
   882 declare exE [elim!]
   883   allE [elim]
   884 
   885 ML {* val HOL_cs = claset_of @{context} *}
   886 
   887 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   888   apply (erule swap)
   889   apply (erule (1) meta_mp)
   890   done
   891 
   892 declare ex_ex1I [rule del, intro! 2]
   893   and ex1I [intro]
   894 
   895 declare ext [intro]
   896 
   897 lemmas [intro?] = ext
   898   and [elim?] = ex1_implies_ex
   899 
   900 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   901 lemma alt_ex1E [elim!]:
   902   assumes major: "\<exists>!x. P x"
   903       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   904   shows R
   905 apply (rule ex1E [OF major])
   906 apply (rule prem)
   907 apply assumption
   908 apply (rule allI)+
   909 apply (tactic {* eresolve_tac @{context} [Classical.dup_elim NONE @{thm allE}] 1 *})
   910 apply iprover
   911 done
   912 
   913 ML {*
   914   structure Blast = Blast
   915   (
   916     structure Classical = Classical
   917     val Trueprop_const = dest_Const @{const Trueprop}
   918     val equality_name = @{const_name HOL.eq}
   919     val not_name = @{const_name Not}
   920     val notE = @{thm notE}
   921     val ccontr = @{thm ccontr}
   922     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   923   );
   924   val blast_tac = Blast.blast_tac;
   925 *}
   926 
   927 
   928 subsubsection {* Simplifier *}
   929 
   930 lemma eta_contract_eq: "(%s. f s) = f" ..
   931 
   932 lemma simp_thms:
   933   shows not_not: "(~ ~ P) = P"
   934   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   935   and
   936     "(P ~= Q) = (P = (~Q))"
   937     "(P | ~P) = True"    "(~P | P) = True"
   938     "(x = x) = True"
   939   and not_True_eq_False [code]: "(\<not> True) = False"
   940   and not_False_eq_True [code]: "(\<not> False) = True"
   941   and
   942     "(~P) ~= P"  "P ~= (~P)"
   943     "(True=P) = P"
   944   and eq_True: "(P = True) = P"
   945   and "(False=P) = (~P)"
   946   and eq_False: "(P = False) = (\<not> P)"
   947   and
   948     "(True --> P) = P"  "(False --> P) = True"
   949     "(P --> True) = True"  "(P --> P) = True"
   950     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   951     "(P & True) = P"  "(True & P) = P"
   952     "(P & False) = False"  "(False & P) = False"
   953     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   954     "(P & ~P) = False"    "(~P & P) = False"
   955     "(P | True) = True"  "(True | P) = True"
   956     "(P | False) = P"  "(False | P) = P"
   957     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   958     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   959   and
   960     "!!P. (EX x. x=t & P(x)) = P(t)"
   961     "!!P. (EX x. t=x & P(x)) = P(t)"
   962     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   963     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   964   by (blast, blast, blast, blast, blast, iprover+)
   965 
   966 lemma disj_absorb: "(A | A) = A"
   967   by blast
   968 
   969 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   970   by blast
   971 
   972 lemma conj_absorb: "(A & A) = A"
   973   by blast
   974 
   975 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   976   by blast
   977 
   978 lemma eq_ac:
   979   shows eq_commute: "a = b \<longleftrightarrow> b = a"
   980     and iff_left_commute: "(P \<longleftrightarrow> (Q \<longleftrightarrow> R)) \<longleftrightarrow> (Q \<longleftrightarrow> (P \<longleftrightarrow> R))"
   981     and iff_assoc: "((P \<longleftrightarrow> Q) \<longleftrightarrow> R) \<longleftrightarrow> (P \<longleftrightarrow> (Q \<longleftrightarrow> R))" by (iprover, blast+)
   982 lemma neq_commute: "a \<noteq> b \<longleftrightarrow> b \<noteq> a" by iprover
   983 
   984 lemma conj_comms:
   985   shows conj_commute: "(P&Q) = (Q&P)"
   986     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
   987 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
   988 
   989 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   990 
   991 lemma disj_comms:
   992   shows disj_commute: "(P|Q) = (Q|P)"
   993     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
   994 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
   995 
   996 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   997 
   998 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
   999 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1000 
  1001 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1002 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1003 
  1004 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1005 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1006 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1007 
  1008 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1009 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1010 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1011 
  1012 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1013 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1014 
  1015 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1016   by iprover
  1017 
  1018 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1019 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1020 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1021 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1022 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1023 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1024   by blast
  1025 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1026 
  1027 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1028 
  1029 
  1030 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1031   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1032   -- {* cases boil down to the same thing. *}
  1033   by blast
  1034 
  1035 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1036 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1037 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1038 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1039 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1040 
  1041 declare All_def [no_atp]
  1042 
  1043 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1044 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1045 
  1046 text {*
  1047   \medskip The @{text "&"} congruence rule: not included by default!
  1048   May slow rewrite proofs down by as much as 50\% *}
  1049 
  1050 lemma conj_cong:
  1051     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1052   by iprover
  1053 
  1054 lemma rev_conj_cong:
  1055     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1056   by iprover
  1057 
  1058 text {* The @{text "|"} congruence rule: not included by default! *}
  1059 
  1060 lemma disj_cong:
  1061     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1062   by blast
  1063 
  1064 
  1065 text {* \medskip if-then-else rules *}
  1066 
  1067 lemma if_True [code]: "(if True then x else y) = x"
  1068   by (unfold If_def) blast
  1069 
  1070 lemma if_False [code]: "(if False then x else y) = y"
  1071   by (unfold If_def) blast
  1072 
  1073 lemma if_P: "P ==> (if P then x else y) = x"
  1074   by (unfold If_def) blast
  1075 
  1076 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1077   by (unfold If_def) blast
  1078 
  1079 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1080   apply (rule case_split [of Q])
  1081    apply (simplesubst if_P)
  1082     prefer 3 apply (simplesubst if_not_P, blast+)
  1083   done
  1084 
  1085 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1086 by (simplesubst split_if, blast)
  1087 
  1088 lemmas if_splits [no_atp] = split_if split_if_asm
  1089 
  1090 lemma if_cancel: "(if c then x else x) = x"
  1091 by (simplesubst split_if, blast)
  1092 
  1093 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1094 by (simplesubst split_if, blast)
  1095 
  1096 lemma if_bool_eq_conj:
  1097 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1098   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1099   by (rule split_if)
  1100 
  1101 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1102   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1103   apply (simplesubst split_if, blast)
  1104   done
  1105 
  1106 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1107 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1108 
  1109 text {* \medskip let rules for simproc *}
  1110 
  1111 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1112   by (unfold Let_def)
  1113 
  1114 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1115   by (unfold Let_def)
  1116 
  1117 text {*
  1118   The following copy of the implication operator is useful for
  1119   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1120   its premise.
  1121 *}
  1122 
  1123 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1124   "simp_implies \<equiv> op ==>"
  1125 
  1126 lemma simp_impliesI:
  1127   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1128   shows "PROP P =simp=> PROP Q"
  1129   apply (unfold simp_implies_def)
  1130   apply (rule PQ)
  1131   apply assumption
  1132   done
  1133 
  1134 lemma simp_impliesE:
  1135   assumes PQ: "PROP P =simp=> PROP Q"
  1136   and P: "PROP P"
  1137   and QR: "PROP Q \<Longrightarrow> PROP R"
  1138   shows "PROP R"
  1139   apply (rule QR)
  1140   apply (rule PQ [unfolded simp_implies_def])
  1141   apply (rule P)
  1142   done
  1143 
  1144 lemma simp_implies_cong:
  1145   assumes PP' :"PROP P == PROP P'"
  1146   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1147   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1148 proof (unfold simp_implies_def, rule equal_intr_rule)
  1149   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1150   and P': "PROP P'"
  1151   from PP' [symmetric] and P' have "PROP P"
  1152     by (rule equal_elim_rule1)
  1153   then have "PROP Q" by (rule PQ)
  1154   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1155 next
  1156   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1157   and P: "PROP P"
  1158   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1159   then have "PROP Q'" by (rule P'Q')
  1160   with P'QQ' [OF P', symmetric] show "PROP Q"
  1161     by (rule equal_elim_rule1)
  1162 qed
  1163 
  1164 lemma uncurry:
  1165   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1166   shows "P \<and> Q \<longrightarrow> R"
  1167   using assms by blast
  1168 
  1169 lemma iff_allI:
  1170   assumes "\<And>x. P x = Q x"
  1171   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1172   using assms by blast
  1173 
  1174 lemma iff_exI:
  1175   assumes "\<And>x. P x = Q x"
  1176   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1177   using assms by blast
  1178 
  1179 lemma all_comm:
  1180   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1181   by blast
  1182 
  1183 lemma ex_comm:
  1184   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1185   by blast
  1186 
  1187 ML_file "Tools/simpdata.ML"
  1188 ML {* open Simpdata *}
  1189 
  1190 setup {*
  1191   map_theory_simpset (put_simpset HOL_basic_ss) #>
  1192   Simplifier.method_setup Splitter.split_modifiers
  1193 *}
  1194 
  1195 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1196 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1197 
  1198 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1199 
  1200 simproc_setup neq ("x = y") = {* fn _ =>
  1201 let
  1202   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1203   fun is_neq eq lhs rhs thm =
  1204     (case Thm.prop_of thm of
  1205       _ $ (Not $ (eq' $ l' $ r')) =>
  1206         Not = HOLogic.Not andalso eq' = eq andalso
  1207         r' aconv lhs andalso l' aconv rhs
  1208     | _ => false);
  1209   fun proc ss ct =
  1210     (case Thm.term_of ct of
  1211       eq $ lhs $ rhs =>
  1212         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1213           SOME thm => SOME (thm RS neq_to_EQ_False)
  1214         | NONE => NONE)
  1215      | _ => NONE);
  1216 in proc end;
  1217 *}
  1218 
  1219 simproc_setup let_simp ("Let x f") = {*
  1220 let
  1221   val (f_Let_unfold, x_Let_unfold) =
  1222     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1223     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1224   val (f_Let_folded, x_Let_folded) =
  1225     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1226     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1227   val g_Let_folded =
  1228     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1229     in cterm_of @{theory} g end;
  1230   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1231     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1232     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1233     | count_loose _ _ = 0;
  1234   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1235    case t
  1236     of Abs (_, _, t') => count_loose t' 0 <= 1
  1237      | _ => true;
  1238 in fn _ => fn ctxt => fn ct => if is_trivial_let (Thm.term_of ct)
  1239   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1240   else let (*Norbert Schirmer's case*)
  1241     val thy = Proof_Context.theory_of ctxt;
  1242     val t = Thm.term_of ct;
  1243     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1244   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1245     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1246       if is_Free x orelse is_Bound x orelse is_Const x
  1247       then SOME @{thm Let_def}
  1248       else
  1249         let
  1250           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1251           val cx = cterm_of thy x;
  1252           val {T = xT, ...} = rep_cterm cx;
  1253           val cf = cterm_of thy f;
  1254           val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
  1255           val (_ $ _ $ g) = prop_of fx_g;
  1256           val g' = abstract_over (x,g);
  1257           val abs_g'= Abs (n,xT,g');
  1258         in (if (g aconv g')
  1259              then
  1260                 let
  1261                   val rl =
  1262                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1263                 in SOME (rl OF [fx_g]) end
  1264              else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g') then NONE (*avoid identity conversion*)
  1265              else let
  1266                    val g'x = abs_g'$x;
  1267                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1268                    val rl = cterm_instantiate
  1269                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1270                               (g_Let_folded, cterm_of thy abs_g')]
  1271                              @{thm Let_folded};
  1272                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1273                  end)
  1274         end
  1275     | _ => NONE)
  1276   end
  1277 end *}
  1278 
  1279 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1280 proof
  1281   assume "True \<Longrightarrow> PROP P"
  1282   from this [OF TrueI] show "PROP P" .
  1283 next
  1284   assume "PROP P"
  1285   then show "PROP P" .
  1286 qed
  1287 
  1288 lemma ex_simps:
  1289   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1290   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1291   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1292   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1293   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1294   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1295   -- {* Miniscoping: pushing in existential quantifiers. *}
  1296   by (iprover | blast)+
  1297 
  1298 lemma all_simps:
  1299   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1300   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1301   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1302   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1303   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1304   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1305   -- {* Miniscoping: pushing in universal quantifiers. *}
  1306   by (iprover | blast)+
  1307 
  1308 lemmas [simp] =
  1309   triv_forall_equality (*prunes params*)
  1310   True_implies_equals  (*prune asms `True'*)
  1311   if_True
  1312   if_False
  1313   if_cancel
  1314   if_eq_cancel
  1315   imp_disjL
  1316   (*In general it seems wrong to add distributive laws by default: they
  1317     might cause exponential blow-up.  But imp_disjL has been in for a while
  1318     and cannot be removed without affecting existing proofs.  Moreover,
  1319     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1320     grounds that it allows simplification of R in the two cases.*)
  1321   conj_assoc
  1322   disj_assoc
  1323   de_Morgan_conj
  1324   de_Morgan_disj
  1325   imp_disj1
  1326   imp_disj2
  1327   not_imp
  1328   disj_not1
  1329   not_all
  1330   not_ex
  1331   cases_simp
  1332   the_eq_trivial
  1333   the_sym_eq_trivial
  1334   ex_simps
  1335   all_simps
  1336   simp_thms
  1337 
  1338 lemmas [cong] = imp_cong simp_implies_cong
  1339 lemmas [split] = split_if
  1340 
  1341 ML {* val HOL_ss = simpset_of @{context} *}
  1342 
  1343 text {* Simplifies x assuming c and y assuming ~c *}
  1344 lemma if_cong:
  1345   assumes "b = c"
  1346       and "c \<Longrightarrow> x = u"
  1347       and "\<not> c \<Longrightarrow> y = v"
  1348   shows "(if b then x else y) = (if c then u else v)"
  1349   using assms by simp
  1350 
  1351 text {* Prevents simplification of x and y:
  1352   faster and allows the execution of functional programs. *}
  1353 lemma if_weak_cong [cong]:
  1354   assumes "b = c"
  1355   shows "(if b then x else y) = (if c then x else y)"
  1356   using assms by (rule arg_cong)
  1357 
  1358 text {* Prevents simplification of t: much faster *}
  1359 lemma let_weak_cong:
  1360   assumes "a = b"
  1361   shows "(let x = a in t x) = (let x = b in t x)"
  1362   using assms by (rule arg_cong)
  1363 
  1364 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1365 lemma eq_cong2:
  1366   assumes "u = u'"
  1367   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1368   using assms by simp
  1369 
  1370 lemma if_distrib:
  1371   "f (if c then x else y) = (if c then f x else f y)"
  1372   by simp
  1373 
  1374 text{*As a simplification rule, it replaces all function equalities by
  1375   first-order equalities.*}
  1376 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1377   by auto
  1378 
  1379 
  1380 subsubsection {* Generic cases and induction *}
  1381 
  1382 text {* Rule projections: *}
  1383 
  1384 ML {*
  1385 structure Project_Rule = Project_Rule
  1386 (
  1387   val conjunct1 = @{thm conjunct1}
  1388   val conjunct2 = @{thm conjunct2}
  1389   val mp = @{thm mp}
  1390 )
  1391 *}
  1392 
  1393 definition induct_forall where
  1394   "induct_forall P == \<forall>x. P x"
  1395 
  1396 definition induct_implies where
  1397   "induct_implies A B == A \<longrightarrow> B"
  1398 
  1399 definition induct_equal where
  1400   "induct_equal x y == x = y"
  1401 
  1402 definition induct_conj where
  1403   "induct_conj A B == A \<and> B"
  1404 
  1405 definition induct_true where
  1406   "induct_true == True"
  1407 
  1408 definition induct_false where
  1409   "induct_false == False"
  1410 
  1411 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1412   by (unfold atomize_all induct_forall_def)
  1413 
  1414 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1415   by (unfold atomize_imp induct_implies_def)
  1416 
  1417 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1418   by (unfold atomize_eq induct_equal_def)
  1419 
  1420 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1421   by (unfold atomize_conj induct_conj_def)
  1422 
  1423 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1424 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1425 lemmas induct_rulify' [symmetric] = induct_atomize'
  1426 lemmas induct_rulify [symmetric] = induct_atomize
  1427 lemmas induct_rulify_fallback =
  1428   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1429   induct_true_def induct_false_def
  1430 
  1431 
  1432 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1433     induct_conj (induct_forall A) (induct_forall B)"
  1434   by (unfold induct_forall_def induct_conj_def) iprover
  1435 
  1436 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1437     induct_conj (induct_implies C A) (induct_implies C B)"
  1438   by (unfold induct_implies_def induct_conj_def) iprover
  1439 
  1440 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1441 proof
  1442   assume r: "induct_conj A B ==> PROP C" and A B
  1443   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1444 next
  1445   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1446   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1447 qed
  1448 
  1449 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1450 
  1451 lemma induct_trueI: "induct_true"
  1452   by (simp add: induct_true_def)
  1453 
  1454 text {* Method setup. *}
  1455 
  1456 ML_file "~~/src/Tools/induct.ML"
  1457 ML {*
  1458 structure Induct = Induct
  1459 (
  1460   val cases_default = @{thm case_split}
  1461   val atomize = @{thms induct_atomize}
  1462   val rulify = @{thms induct_rulify'}
  1463   val rulify_fallback = @{thms induct_rulify_fallback}
  1464   val equal_def = @{thm induct_equal_def}
  1465   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1466     | dest_def _ = NONE
  1467   fun trivial_tac ctxt = match_tac ctxt @{thms induct_trueI}
  1468 )
  1469 *}
  1470 
  1471 ML_file "~~/src/Tools/induction.ML"
  1472 
  1473 setup {*
  1474   Context.theory_map (Induct.map_simpset (fn ss => ss
  1475     addsimprocs
  1476       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1477          ["induct_false ==> PROP P ==> PROP Q"]
  1478          (fn _ =>
  1479             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1480                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1481               | _ => NONE)),
  1482        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1483          ["induct_conj P Q ==> PROP R"]
  1484          (fn _ =>
  1485             (fn _ $ (_ $ P) $ _ =>
  1486                 let
  1487                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1488                         is_conj P andalso is_conj Q
  1489                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1490                     | is_conj @{const induct_true} = true
  1491                     | is_conj @{const induct_false} = true
  1492                     | is_conj _ = false
  1493                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1494               | _ => NONE))]
  1495     |> Simplifier.set_mksimps (fn ctxt =>
  1496         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
  1497         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback})))))
  1498 *}
  1499 
  1500 text {* Pre-simplification of induction and cases rules *}
  1501 
  1502 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1503   unfolding induct_equal_def
  1504 proof
  1505   assume R: "!!x. x = t ==> PROP P x"
  1506   show "PROP P t" by (rule R [OF refl])
  1507 next
  1508   fix x assume "PROP P t" "x = t"
  1509   then show "PROP P x" by simp
  1510 qed
  1511 
  1512 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1513   unfolding induct_equal_def
  1514 proof
  1515   assume R: "!!x. t = x ==> PROP P x"
  1516   show "PROP P t" by (rule R [OF refl])
  1517 next
  1518   fix x assume "PROP P t" "t = x"
  1519   then show "PROP P x" by simp
  1520 qed
  1521 
  1522 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1523   unfolding induct_false_def induct_true_def
  1524   by (iprover intro: equal_intr_rule)
  1525 
  1526 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1527   unfolding induct_true_def
  1528 proof
  1529   assume R: "True \<Longrightarrow> PROP P"
  1530   from TrueI show "PROP P" by (rule R)
  1531 next
  1532   assume "PROP P"
  1533   then show "PROP P" .
  1534 qed
  1535 
  1536 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1537   unfolding induct_true_def
  1538   by (iprover intro: equal_intr_rule)
  1539 
  1540 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1541   unfolding induct_true_def
  1542   by (iprover intro: equal_intr_rule)
  1543 
  1544 lemma [induct_simp]: "induct_implies induct_true P == P"
  1545   by (simp add: induct_implies_def induct_true_def)
  1546 
  1547 lemma [induct_simp]: "(x = x) = True"
  1548   by (rule simp_thms)
  1549 
  1550 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1551 
  1552 ML_file "~~/src/Tools/induct_tacs.ML"
  1553 
  1554 
  1555 subsubsection {* Coherent logic *}
  1556 
  1557 ML_file "~~/src/Tools/coherent.ML"
  1558 ML {*
  1559 structure Coherent = Coherent
  1560 (
  1561   val atomize_elimL = @{thm atomize_elimL};
  1562   val atomize_exL = @{thm atomize_exL};
  1563   val atomize_conjL = @{thm atomize_conjL};
  1564   val atomize_disjL = @{thm atomize_disjL};
  1565   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
  1566 );
  1567 *}
  1568 
  1569 
  1570 subsubsection {* Reorienting equalities *}
  1571 
  1572 ML {*
  1573 signature REORIENT_PROC =
  1574 sig
  1575   val add : (term -> bool) -> theory -> theory
  1576   val proc : morphism -> Proof.context -> cterm -> thm option
  1577 end;
  1578 
  1579 structure Reorient_Proc : REORIENT_PROC =
  1580 struct
  1581   structure Data = Theory_Data
  1582   (
  1583     type T = ((term -> bool) * stamp) list;
  1584     val empty = [];
  1585     val extend = I;
  1586     fun merge data : T = Library.merge (eq_snd op =) data;
  1587   );
  1588   fun add m = Data.map (cons (m, stamp ()));
  1589   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1590 
  1591   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1592   fun proc phi ctxt ct =
  1593     let
  1594       val thy = Proof_Context.theory_of ctxt;
  1595     in
  1596       case Thm.term_of ct of
  1597         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1598       | _ => NONE
  1599     end;
  1600 end;
  1601 *}
  1602 
  1603 
  1604 subsection {* Other simple lemmas and lemma duplicates *}
  1605 
  1606 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1607   by blast+
  1608 
  1609 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1610   apply (rule iffI)
  1611   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1612   apply (fast dest!: theI')
  1613   apply (fast intro: the1_equality [symmetric])
  1614   apply (erule ex1E)
  1615   apply (rule allI)
  1616   apply (rule ex1I)
  1617   apply (erule spec)
  1618   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1619   apply (erule impE)
  1620   apply (rule allI)
  1621   apply (case_tac "xa = x")
  1622   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1623   done
  1624 
  1625 lemmas eq_sym_conv = eq_commute
  1626 
  1627 lemma nnf_simps:
  1628   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
  1629   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))"
  1630   "(\<not> \<not>(P)) = P"
  1631 by blast+
  1632 
  1633 subsection {* Basic ML bindings *}
  1634 
  1635 ML {*
  1636 val FalseE = @{thm FalseE}
  1637 val Let_def = @{thm Let_def}
  1638 val TrueI = @{thm TrueI}
  1639 val allE = @{thm allE}
  1640 val allI = @{thm allI}
  1641 val all_dupE = @{thm all_dupE}
  1642 val arg_cong = @{thm arg_cong}
  1643 val box_equals = @{thm box_equals}
  1644 val ccontr = @{thm ccontr}
  1645 val classical = @{thm classical}
  1646 val conjE = @{thm conjE}
  1647 val conjI = @{thm conjI}
  1648 val conjunct1 = @{thm conjunct1}
  1649 val conjunct2 = @{thm conjunct2}
  1650 val disjCI = @{thm disjCI}
  1651 val disjE = @{thm disjE}
  1652 val disjI1 = @{thm disjI1}
  1653 val disjI2 = @{thm disjI2}
  1654 val eq_reflection = @{thm eq_reflection}
  1655 val ex1E = @{thm ex1E}
  1656 val ex1I = @{thm ex1I}
  1657 val ex1_implies_ex = @{thm ex1_implies_ex}
  1658 val exE = @{thm exE}
  1659 val exI = @{thm exI}
  1660 val excluded_middle = @{thm excluded_middle}
  1661 val ext = @{thm ext}
  1662 val fun_cong = @{thm fun_cong}
  1663 val iffD1 = @{thm iffD1}
  1664 val iffD2 = @{thm iffD2}
  1665 val iffI = @{thm iffI}
  1666 val impE = @{thm impE}
  1667 val impI = @{thm impI}
  1668 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1669 val mp = @{thm mp}
  1670 val notE = @{thm notE}
  1671 val notI = @{thm notI}
  1672 val not_all = @{thm not_all}
  1673 val not_ex = @{thm not_ex}
  1674 val not_iff = @{thm not_iff}
  1675 val not_not = @{thm not_not}
  1676 val not_sym = @{thm not_sym}
  1677 val refl = @{thm refl}
  1678 val rev_mp = @{thm rev_mp}
  1679 val spec = @{thm spec}
  1680 val ssubst = @{thm ssubst}
  1681 val subst = @{thm subst}
  1682 val sym = @{thm sym}
  1683 val trans = @{thm trans}
  1684 *}
  1685 
  1686 ML_file "Tools/cnf.ML"
  1687 
  1688 
  1689 section {* @{text NO_MATCH} simproc *}
  1690 
  1691 text {*
  1692  The simplification procedure can be used to avoid simplification of terms of a certain form
  1693 *}
  1694 
  1695 definition NO_MATCH :: "'a \<Rightarrow> 'b \<Rightarrow> bool" where "NO_MATCH val pat \<equiv> True"
  1696 
  1697 lemma NO_MATCH_cong[cong]: "NO_MATCH val pat = NO_MATCH val pat" by (rule refl)
  1698 
  1699 declare [[coercion_args NO_MATCH - -]]
  1700 
  1701 simproc_setup NO_MATCH ("NO_MATCH val pat") = {* fn _ => fn ctxt => fn ct =>
  1702   let
  1703     val thy = Proof_Context.theory_of ctxt
  1704     val dest_binop = Term.dest_comb #> apfst (Term.dest_comb #> snd)
  1705     val m = Pattern.matches thy (dest_binop (Thm.term_of ct))
  1706   in if m then NONE else SOME @{thm NO_MATCH_def} end
  1707 *}
  1708 
  1709 text {*
  1710   This setup ensures that a rewrite rule of the form @{term "NO_MATCH val pat \<Longrightarrow> t"}
  1711   is only applied, if the pattern @{term pat} does not match the value @{term val}.
  1712 *}
  1713 
  1714 
  1715 subsection {* Code generator setup *}
  1716 
  1717 subsubsection {* Generic code generator preprocessor setup *}
  1718 
  1719 lemma conj_left_cong:
  1720   "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
  1721   by (fact arg_cong)
  1722 
  1723 lemma disj_left_cong:
  1724   "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
  1725   by (fact arg_cong)
  1726 
  1727 setup {*
  1728   Code_Preproc.map_pre (put_simpset HOL_basic_ss) #>
  1729   Code_Preproc.map_post (put_simpset HOL_basic_ss) #>
  1730   Code_Simp.map_ss (put_simpset HOL_basic_ss #>
  1731   Simplifier.add_cong @{thm conj_left_cong} #>
  1732   Simplifier.add_cong @{thm disj_left_cong})
  1733 *}
  1734 
  1735 
  1736 subsubsection {* Equality *}
  1737 
  1738 class equal =
  1739   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1740   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1741 begin
  1742 
  1743 lemma equal: "equal = (op =)"
  1744   by (rule ext equal_eq)+
  1745 
  1746 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1747   unfolding equal by rule+
  1748 
  1749 lemma eq_equal: "(op =) \<equiv> equal"
  1750   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1751 
  1752 end
  1753 
  1754 declare eq_equal [symmetric, code_post]
  1755 declare eq_equal [code]
  1756 
  1757 setup {*
  1758   Code_Preproc.map_pre (fn ctxt =>
  1759     ctxt addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1760       (fn _ => fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1761 *}
  1762 
  1763 
  1764 subsubsection {* Generic code generator foundation *}
  1765 
  1766 text {* Datatype @{typ bool} *}
  1767 
  1768 code_datatype True False
  1769 
  1770 lemma [code]:
  1771   shows "False \<and> P \<longleftrightarrow> False"
  1772     and "True \<and> P \<longleftrightarrow> P"
  1773     and "P \<and> False \<longleftrightarrow> False"
  1774     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1775 
  1776 lemma [code]:
  1777   shows "False \<or> P \<longleftrightarrow> P"
  1778     and "True \<or> P \<longleftrightarrow> True"
  1779     and "P \<or> False \<longleftrightarrow> P"
  1780     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1781 
  1782 lemma [code]:
  1783   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1784     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1785     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1786     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1787 
  1788 text {* More about @{typ prop} *}
  1789 
  1790 lemma [code nbe]:
  1791   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q"
  1792     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1793     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1794 
  1795 lemma Trueprop_code [code]:
  1796   "Trueprop True \<equiv> Code_Generator.holds"
  1797   by (auto intro!: equal_intr_rule holds)
  1798 
  1799 declare Trueprop_code [symmetric, code_post]
  1800 
  1801 text {* Equality *}
  1802 
  1803 declare simp_thms(6) [code nbe]
  1804 
  1805 instantiation itself :: (type) equal
  1806 begin
  1807 
  1808 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1809   "equal_itself x y \<longleftrightarrow> x = y"
  1810 
  1811 instance proof
  1812 qed (fact equal_itself_def)
  1813 
  1814 end
  1815 
  1816 lemma equal_itself_code [code]:
  1817   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1818   by (simp add: equal)
  1819 
  1820 setup {* Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"}) *}
  1821 
  1822 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1823 proof
  1824   assume "PROP ?ofclass"
  1825   show "PROP ?equal"
  1826     by (tactic {* ALLGOALS (resolve_tac @{context} [Thm.unconstrainT @{thm eq_equal}]) *})
  1827       (fact `PROP ?ofclass`)
  1828 next
  1829   assume "PROP ?equal"
  1830   show "PROP ?ofclass" proof
  1831   qed (simp add: `PROP ?equal`)
  1832 qed
  1833 
  1834 setup {* Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"}) *}
  1835 
  1836 setup {* Nbe.add_const_alias @{thm equal_alias_cert} *}
  1837 
  1838 text {* Cases *}
  1839 
  1840 lemma Let_case_cert:
  1841   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1842   shows "CASE x \<equiv> f x"
  1843   using assms by simp_all
  1844 
  1845 setup {*
  1846   Code.add_case @{thm Let_case_cert} #>
  1847   Code.add_undefined @{const_name undefined}
  1848 *}
  1849 
  1850 declare [[code abort: undefined]]
  1851 
  1852 
  1853 subsubsection {* Generic code generator target languages *}
  1854 
  1855 text {* type @{typ bool} *}
  1856 
  1857 code_printing
  1858   type_constructor bool \<rightharpoonup>
  1859     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
  1860 | constant True \<rightharpoonup>
  1861     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
  1862 | constant False \<rightharpoonup>
  1863     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false"
  1864 
  1865 code_reserved SML
  1866   bool true false
  1867 
  1868 code_reserved OCaml
  1869   bool
  1870 
  1871 code_reserved Scala
  1872   Boolean
  1873 
  1874 code_printing
  1875   constant Not \<rightharpoonup>
  1876     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
  1877 | constant HOL.conj \<rightharpoonup>
  1878     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
  1879 | constant HOL.disj \<rightharpoonup>
  1880     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
  1881 | constant HOL.implies \<rightharpoonup>
  1882     (SML) "!(if (_)/ then (_)/ else true)"
  1883     and (OCaml) "!(if (_)/ then (_)/ else true)"
  1884     and (Haskell) "!(if (_)/ then (_)/ else True)"
  1885     and (Scala) "!(if ((_))/ (_)/ else true)"
  1886 | constant If \<rightharpoonup>
  1887     (SML) "!(if (_)/ then (_)/ else (_))"
  1888     and (OCaml) "!(if (_)/ then (_)/ else (_))"
  1889     and (Haskell) "!(if (_)/ then (_)/ else (_))"
  1890     and (Scala) "!(if ((_))/ (_)/ else (_))"
  1891 
  1892 code_reserved SML
  1893   not
  1894 
  1895 code_reserved OCaml
  1896   not
  1897 
  1898 code_identifier
  1899   code_module Pure \<rightharpoonup>
  1900     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
  1901 
  1902 text {* using built-in Haskell equality *}
  1903 
  1904 code_printing
  1905   type_class equal \<rightharpoonup> (Haskell) "Eq"
  1906 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
  1907 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
  1908 
  1909 text {* undefined *}
  1910 
  1911 code_printing
  1912   constant undefined \<rightharpoonup>
  1913     (SML) "!(raise/ Fail/ \"undefined\")"
  1914     and (OCaml) "failwith/ \"undefined\""
  1915     and (Haskell) "error/ \"undefined\""
  1916     and (Scala) "!sys.error(\"undefined\")"
  1917 
  1918 
  1919 subsubsection {* Evaluation and normalization by evaluation *}
  1920 
  1921 method_setup eval = {*
  1922   let
  1923     fun eval_tac ctxt =
  1924       let val conv = Code_Runtime.dynamic_holds_conv ctxt
  1925       in
  1926         CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN'
  1927         resolve_tac ctxt [TrueI]
  1928       end
  1929   in
  1930     Scan.succeed (SIMPLE_METHOD' o eval_tac)
  1931   end
  1932 *} "solve goal by evaluation"
  1933 
  1934 method_setup normalization = {*
  1935   Scan.succeed (fn ctxt =>
  1936     SIMPLE_METHOD'
  1937       (CHANGED_PROP o
  1938         (CONVERSION (Nbe.dynamic_conv ctxt)
  1939           THEN_ALL_NEW (TRY o resolve_tac ctxt [TrueI]))))
  1940 *} "solve goal by normalization"
  1941 
  1942 
  1943 subsection {* Counterexample Search Units *}
  1944 
  1945 subsubsection {* Quickcheck *}
  1946 
  1947 quickcheck_params [size = 5, iterations = 50]
  1948 
  1949 
  1950 subsubsection {* Nitpick setup *}
  1951 
  1952 named_theorems nitpick_unfold "alternative definitions of constants as needed by Nitpick"
  1953   and nitpick_simp "equational specification of constants as needed by Nitpick"
  1954   and nitpick_psimp "partial equational specification of constants as needed by Nitpick"
  1955   and nitpick_choice_spec "choice specification of constants as needed by Nitpick"
  1956 
  1957 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1958         if_bool_eq_disj [no_atp]
  1959 
  1960 
  1961 subsection {* Preprocessing for the predicate compiler *}
  1962 
  1963 named_theorems code_pred_def "alternative definitions of constants for the Predicate Compiler"
  1964   and code_pred_inline "inlining definitions for the Predicate Compiler"
  1965   and code_pred_simp "simplification rules for the optimisations in the Predicate Compiler"
  1966 
  1967 
  1968 subsection {* Legacy tactics and ML bindings *}
  1969 
  1970 ML {*
  1971   (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1972   local
  1973     fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  1974       | wrong_prem (Bound _) = true
  1975       | wrong_prem _ = false;
  1976     val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1977   in
  1978     fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1979     fun smp_tac ctxt j = EVERY' [dresolve_tac ctxt (smp j), assume_tac ctxt];
  1980   end;
  1981 
  1982   local
  1983     val nnf_ss =
  1984       simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
  1985   in
  1986     fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
  1987   end
  1988 *}
  1989 
  1990 hide_const (open) eq equal
  1991 
  1992 end