src/HOL/Analysis/Complex_Analysis_Basics.thy
author paulson <lp15@cam.ac.uk>
Tue Oct 25 15:46:07 2016 +0100 (2016-10-25)
changeset 64394 141e1ed8d5a0
parent 64267 b9a1486e79be
child 65587 16a8991ab398
permissions -rw-r--r--
more new material
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "~~/src/HOL/Library/Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((op * c) has_derivative (op * c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_complex:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "op * f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 
    31 lemma fact_cancel:
    32   fixes c :: "'a::real_field"
    33   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    34   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    35 
    36 lemma bilinear_times:
    37   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    38   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    39 
    40 lemma linear_cnj: "linear cnj"
    41   using bounded_linear.linear[OF bounded_linear_cnj] .
    42 
    43 lemma tendsto_Re_upper:
    44   assumes "~ (trivial_limit F)"
    45           "(f \<longlongrightarrow> l) F"
    46           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    47     shows  "Re(l) \<le> b"
    48   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    49 
    50 lemma tendsto_Re_lower:
    51   assumes "~ (trivial_limit F)"
    52           "(f \<longlongrightarrow> l) F"
    53           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    54     shows  "b \<le> Re(l)"
    55   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    56 
    57 lemma tendsto_Im_upper:
    58   assumes "~ (trivial_limit F)"
    59           "(f \<longlongrightarrow> l) F"
    60           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    61     shows  "Im(l) \<le> b"
    62   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    63 
    64 lemma tendsto_Im_lower:
    65   assumes "~ (trivial_limit F)"
    66           "(f \<longlongrightarrow> l) F"
    67           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    68     shows  "b \<le> Im(l)"
    69   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    70 
    71 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = op * 0"
    72   by auto
    73 
    74 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = op * 1"
    75   by auto
    76 
    77 lemma continuous_mult_left:
    78   fixes c::"'a::real_normed_algebra"
    79   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    80 by (rule continuous_mult [OF continuous_const])
    81 
    82 lemma continuous_mult_right:
    83   fixes c::"'a::real_normed_algebra"
    84   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    85 by (rule continuous_mult [OF _ continuous_const])
    86 
    87 lemma continuous_on_mult_left:
    88   fixes c::"'a::real_normed_algebra"
    89   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    90 by (rule continuous_on_mult [OF continuous_on_const])
    91 
    92 lemma continuous_on_mult_right:
    93   fixes c::"'a::real_normed_algebra"
    94   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    95 by (rule continuous_on_mult [OF _ continuous_on_const])
    96 
    97 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    98   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    99   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   100   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   101 
   102 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   103   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   104   assumes "uniformly_continuous_on s f"
   105     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   106 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   107 
   108 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   109   by (rule continuous_norm [OF continuous_ident])
   110 
   111 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   112   by (intro continuous_on_id continuous_on_norm)
   113 
   114 subsection\<open>DERIV stuff\<close>
   115 
   116 lemma DERIV_zero_connected_constant:
   117   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   118   assumes "connected s"
   119       and "open s"
   120       and "finite k"
   121       and "continuous_on s f"
   122       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   123     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   124 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   125 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   126 
   127 lemma DERIV_zero_constant:
   128   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   129   shows    "\<lbrakk>convex s;
   130              \<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)\<rbrakk>
   131              \<Longrightarrow> \<exists>c. \<forall>x \<in> s. f(x) = c"
   132   by (auto simp: has_field_derivative_def lambda_zero intro: has_derivative_zero_constant)
   133 
   134 lemma DERIV_zero_unique:
   135   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   136   assumes "convex s"
   137       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   138       and "a \<in> s"
   139       and "x \<in> s"
   140     shows "f x = f a"
   141   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   142      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   143 
   144 lemma DERIV_zero_connected_unique:
   145   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   146   assumes "connected s"
   147       and "open s"
   148       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   149       and "a \<in> s"
   150       and "x \<in> s"
   151     shows "f x = f a"
   152     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   153        (metis has_field_derivative_def lambda_zero d0)
   154 
   155 lemma DERIV_transform_within:
   156   assumes "(f has_field_derivative f') (at a within s)"
   157       and "0 < d" "a \<in> s"
   158       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   159     shows "(g has_field_derivative f') (at a within s)"
   160   using assms unfolding has_field_derivative_def
   161   by (blast intro: has_derivative_transform_within)
   162 
   163 lemma DERIV_transform_within_open:
   164   assumes "DERIV f a :> f'"
   165       and "open s" "a \<in> s"
   166       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   167     shows "DERIV g a :> f'"
   168   using assms unfolding has_field_derivative_def
   169 by (metis has_derivative_transform_within_open)
   170 
   171 lemma DERIV_transform_at:
   172   assumes "DERIV f a :> f'"
   173       and "0 < d"
   174       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   175     shows "DERIV g a :> f'"
   176   by (blast intro: assms DERIV_transform_within)
   177 
   178 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   179 lemma DERIV_zero_UNIV_unique:
   180   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   181   shows "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   182 by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   183 
   184 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   185 
   186 (*MOVE? But not to Finite_Cartesian_Product*)
   187 lemma sums_vec_nth :
   188   assumes "f sums a"
   189   shows "(\<lambda>x. f x $ i) sums a $ i"
   190 using assms unfolding sums_def
   191 by (auto dest: tendsto_vec_nth [where i=i])
   192 
   193 lemma summable_vec_nth :
   194   assumes "summable f"
   195   shows "summable (\<lambda>x. f x $ i)"
   196 using assms unfolding summable_def
   197 by (blast intro: sums_vec_nth)
   198 
   199 subsection \<open>Complex number lemmas\<close>
   200 
   201 lemma
   202   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   203     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   204     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   205     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   206     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   207     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   208     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   209     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   210     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   211     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   212   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   213             continuous_on_Im continuous_on_id continuous_on_const)+
   214 
   215 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   216 proof -
   217   have "(\<real> :: complex set) = {z. Im z = 0}"
   218     by (auto simp: complex_is_Real_iff)
   219   then show ?thesis
   220     by (metis closed_halfspace_Im_eq)
   221 qed
   222 
   223 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   224   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   225 
   226 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   227 proof -
   228   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   229     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   230   then show ?thesis
   231     by (metis closed_Real_halfspace_Re_le)
   232 qed
   233 
   234 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   235   using closed_halfspace_Re_ge
   236   by (simp add: closed_Int closed_complex_Reals)
   237 
   238 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   239 proof -
   240   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   241     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   242   then show ?thesis
   243     by (metis closed_Real_halfspace_Re_ge)
   244 qed
   245 
   246 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   247 proof -
   248   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   249     by auto
   250   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   251     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   252 qed
   253 
   254 lemma real_lim:
   255   fixes l::complex
   256   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   257   shows  "l \<in> \<real>"
   258 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   259   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   260     using assms(3, 4) by (auto intro: eventually_mono)
   261 qed
   262 
   263 lemma real_lim_sequentially:
   264   fixes l::complex
   265   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   266 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   267 
   268 lemma real_series:
   269   fixes l::complex
   270   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   271 unfolding sums_def
   272 by (metis real_lim_sequentially sum_in_Reals)
   273 
   274 lemma Lim_null_comparison_Re:
   275   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   276   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   277 
   278 subsection\<open>Holomorphic functions\<close>
   279 
   280 subsection\<open>Holomorphic functions\<close>
   281 
   282 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   283            (infixl "(holomorphic'_on)" 50)
   284   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   285 
   286 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   287 
   288 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   289   by (simp add: holomorphic_on_def)
   290 
   291 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   292   by (simp add: holomorphic_on_def)
   293 
   294 lemma holomorphic_on_imp_differentiable_on:
   295     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   296   unfolding holomorphic_on_def differentiable_on_def
   297   by (simp add: field_differentiable_imp_differentiable)
   298 
   299 lemma holomorphic_on_imp_differentiable_at:
   300    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   301 using at_within_open holomorphic_on_def by fastforce
   302 
   303 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   304   by (simp add: holomorphic_on_def)
   305 
   306 lemma holomorphic_on_open:
   307     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   308   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   309 
   310 lemma holomorphic_on_imp_continuous_on:
   311     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   312   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   313 
   314 lemma holomorphic_on_subset [elim]:
   315     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   316   unfolding holomorphic_on_def
   317   by (metis field_differentiable_within_subset subsetD)
   318 
   319 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   320   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   321 
   322 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   323   by (metis holomorphic_transform)
   324 
   325 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(op * c) holomorphic_on s"
   326   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   327 
   328 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   329   unfolding holomorphic_on_def by (metis field_differentiable_const)
   330 
   331 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   332   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   333 
   334 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   335   unfolding id_def by (rule holomorphic_on_ident)
   336 
   337 lemma holomorphic_on_compose:
   338   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   339   using field_differentiable_compose_within[of f _ s g]
   340   by (auto simp: holomorphic_on_def)
   341 
   342 lemma holomorphic_on_compose_gen:
   343   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   344   by (metis holomorphic_on_compose holomorphic_on_subset)
   345 
   346 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   347   by (metis field_differentiable_minus holomorphic_on_def)
   348 
   349 lemma holomorphic_on_add [holomorphic_intros]:
   350   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   351   unfolding holomorphic_on_def by (metis field_differentiable_add)
   352 
   353 lemma holomorphic_on_diff [holomorphic_intros]:
   354   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   355   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   356 
   357 lemma holomorphic_on_mult [holomorphic_intros]:
   358   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   359   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   360 
   361 lemma holomorphic_on_inverse [holomorphic_intros]:
   362   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   363   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   364 
   365 lemma holomorphic_on_divide [holomorphic_intros]:
   366   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   367   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   368 
   369 lemma holomorphic_on_power [holomorphic_intros]:
   370   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   371   unfolding holomorphic_on_def by (metis field_differentiable_power)
   372 
   373 lemma holomorphic_on_sum [holomorphic_intros]:
   374   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   375   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   376 
   377 lemma DERIV_deriv_iff_field_differentiable:
   378   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   379   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   380 
   381 lemma holomorphic_derivI:
   382      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   383       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   384 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   385 
   386 lemma complex_derivative_chain:
   387   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   388     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   389   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   390 
   391 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   392   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   393 
   394 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   395   by (metis DERIV_imp_deriv DERIV_ident)
   396 
   397 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   398   by (simp add: id_def)
   399 
   400 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   401   by (metis DERIV_imp_deriv DERIV_const)
   402 
   403 lemma deriv_add [simp]:
   404   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   405    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   406   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   407   by (auto intro!: DERIV_imp_deriv derivative_intros)
   408 
   409 lemma deriv_diff [simp]:
   410   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   411    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   412   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   413   by (auto intro!: DERIV_imp_deriv derivative_intros)
   414 
   415 lemma deriv_mult [simp]:
   416   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   417    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   418   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   419   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   420 
   421 lemma deriv_cmult [simp]:
   422   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   423   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   424   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   425 
   426 lemma deriv_cmult_right [simp]:
   427   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   428   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   429   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   430 
   431 lemma deriv_cdivide_right [simp]:
   432   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   433   unfolding Fields.field_class.field_divide_inverse
   434   by (blast intro: deriv_cmult_right)
   435 
   436 lemma complex_derivative_transform_within_open:
   437   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   438    \<Longrightarrow> deriv f z = deriv g z"
   439   unfolding holomorphic_on_def
   440   by (rule DERIV_imp_deriv)
   441      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   442 
   443 lemma deriv_compose_linear:
   444   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   445 apply (rule DERIV_imp_deriv)
   446 apply (simp add: DERIV_deriv_iff_field_differentiable [symmetric])
   447 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   448 apply (simp add: algebra_simps)
   449 done
   450 
   451 lemma nonzero_deriv_nonconstant:
   452   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   453     shows "\<not> f constant_on S"
   454 unfolding constant_on_def
   455 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   456 
   457 lemma holomorphic_nonconstant:
   458   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   459     shows "\<not> f constant_on S"
   460     apply (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   461     using assms
   462     apply (auto simp: holomorphic_derivI)
   463     done
   464 
   465 subsection\<open>Caratheodory characterization\<close>
   466 
   467 lemma field_differentiable_caratheodory_at:
   468   "f field_differentiable (at z) \<longleftrightarrow>
   469          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   470   using CARAT_DERIV [of f]
   471   by (simp add: field_differentiable_def has_field_derivative_def)
   472 
   473 lemma field_differentiable_caratheodory_within:
   474   "f field_differentiable (at z within s) \<longleftrightarrow>
   475          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   476   using DERIV_caratheodory_within [of f]
   477   by (simp add: field_differentiable_def has_field_derivative_def)
   478 
   479 subsection\<open>Analyticity on a set\<close>
   480 
   481 definition analytic_on (infixl "(analytic'_on)" 50)
   482   where
   483    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   484 
   485 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   486   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   487      (metis centre_in_ball field_differentiable_at_within)
   488 
   489 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   490 apply (auto simp: analytic_imp_holomorphic)
   491 apply (auto simp: analytic_on_def holomorphic_on_def)
   492 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   493 
   494 lemma analytic_on_imp_differentiable_at:
   495   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f field_differentiable (at x)"
   496  apply (auto simp: analytic_on_def holomorphic_on_def)
   497 by (metis Topology_Euclidean_Space.open_ball centre_in_ball field_differentiable_within_open)
   498 
   499 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   500   by (auto simp: analytic_on_def)
   501 
   502 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   503   by (auto simp: analytic_on_def)
   504 
   505 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   506   by (auto simp: analytic_on_def)
   507 
   508 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   509   by (auto simp: analytic_on_def)
   510 
   511 lemma analytic_on_holomorphic:
   512   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   513   (is "?lhs = ?rhs")
   514 proof -
   515   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   516   proof safe
   517     assume "f analytic_on s"
   518     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   519       apply (simp add: analytic_on_def)
   520       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   521       apply (metis Topology_Euclidean_Space.open_ball analytic_on_open centre_in_ball)
   522       by (metis analytic_on_def)
   523   next
   524     fix t
   525     assume "open t" "s \<subseteq> t" "f analytic_on t"
   526     then show "f analytic_on s"
   527         by (metis analytic_on_subset)
   528   qed
   529   also have "... \<longleftrightarrow> ?rhs"
   530     by (auto simp: analytic_on_open)
   531   finally show ?thesis .
   532 qed
   533 
   534 lemma analytic_on_linear: "(op * c) analytic_on s"
   535   by (auto simp add: analytic_on_holomorphic holomorphic_on_linear)
   536 
   537 lemma analytic_on_const: "(\<lambda>z. c) analytic_on s"
   538   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   539 
   540 lemma analytic_on_ident: "(\<lambda>x. x) analytic_on s"
   541   by (simp add: analytic_on_def holomorphic_on_ident gt_ex)
   542 
   543 lemma analytic_on_id: "id analytic_on s"
   544   unfolding id_def by (rule analytic_on_ident)
   545 
   546 lemma analytic_on_compose:
   547   assumes f: "f analytic_on s"
   548       and g: "g analytic_on (f ` s)"
   549     shows "(g o f) analytic_on s"
   550 unfolding analytic_on_def
   551 proof (intro ballI)
   552   fix x
   553   assume x: "x \<in> s"
   554   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   555     by (metis analytic_on_def)
   556   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   557     by (metis analytic_on_def g image_eqI x)
   558   have "isCont f x"
   559     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   560   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   561      by (auto simp: continuous_at_ball)
   562   have "g \<circ> f holomorphic_on ball x (min d e)"
   563     apply (rule holomorphic_on_compose)
   564     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   565     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   566   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   567     by (metis d e min_less_iff_conj)
   568 qed
   569 
   570 lemma analytic_on_compose_gen:
   571   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   572              \<Longrightarrow> g o f analytic_on s"
   573 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   574 
   575 lemma analytic_on_neg:
   576   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   577 by (metis analytic_on_holomorphic holomorphic_on_minus)
   578 
   579 lemma analytic_on_add:
   580   assumes f: "f analytic_on s"
   581       and g: "g analytic_on s"
   582     shows "(\<lambda>z. f z + g z) analytic_on s"
   583 unfolding analytic_on_def
   584 proof (intro ballI)
   585   fix z
   586   assume z: "z \<in> s"
   587   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   588     by (metis analytic_on_def)
   589   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   590     by (metis analytic_on_def g z)
   591   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   592     apply (rule holomorphic_on_add)
   593     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   594     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   595   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   596     by (metis e e' min_less_iff_conj)
   597 qed
   598 
   599 lemma analytic_on_diff:
   600   assumes f: "f analytic_on s"
   601       and g: "g analytic_on s"
   602     shows "(\<lambda>z. f z - g z) analytic_on s"
   603 unfolding analytic_on_def
   604 proof (intro ballI)
   605   fix z
   606   assume z: "z \<in> s"
   607   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   608     by (metis analytic_on_def)
   609   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   610     by (metis analytic_on_def g z)
   611   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   612     apply (rule holomorphic_on_diff)
   613     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   614     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   615   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   616     by (metis e e' min_less_iff_conj)
   617 qed
   618 
   619 lemma analytic_on_mult:
   620   assumes f: "f analytic_on s"
   621       and g: "g analytic_on s"
   622     shows "(\<lambda>z. f z * g z) analytic_on s"
   623 unfolding analytic_on_def
   624 proof (intro ballI)
   625   fix z
   626   assume z: "z \<in> s"
   627   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   628     by (metis analytic_on_def)
   629   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   630     by (metis analytic_on_def g z)
   631   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   632     apply (rule holomorphic_on_mult)
   633     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   634     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   635   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   636     by (metis e e' min_less_iff_conj)
   637 qed
   638 
   639 lemma analytic_on_inverse:
   640   assumes f: "f analytic_on s"
   641       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   642     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   643 unfolding analytic_on_def
   644 proof (intro ballI)
   645   fix z
   646   assume z: "z \<in> s"
   647   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   648     by (metis analytic_on_def)
   649   have "continuous_on (ball z e) f"
   650     by (metis fh holomorphic_on_imp_continuous_on)
   651   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   652     by (metis Topology_Euclidean_Space.open_ball centre_in_ball continuous_on_open_avoid e z nz)
   653   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   654     apply (rule holomorphic_on_inverse)
   655     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   656     by (metis nz' mem_ball min_less_iff_conj)
   657   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   658     by (metis e e' min_less_iff_conj)
   659 qed
   660 
   661 lemma analytic_on_divide:
   662   assumes f: "f analytic_on s"
   663       and g: "g analytic_on s"
   664       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   665     shows "(\<lambda>z. f z / g z) analytic_on s"
   666 unfolding divide_inverse
   667 by (metis analytic_on_inverse analytic_on_mult f g nz)
   668 
   669 lemma analytic_on_power:
   670   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   671 by (induct n) (auto simp: analytic_on_const analytic_on_mult)
   672 
   673 lemma analytic_on_sum:
   674   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on s"
   675   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   676 
   677 lemma deriv_left_inverse:
   678   assumes "f holomorphic_on S" and "g holomorphic_on T"
   679       and "open S" and "open T"
   680       and "f ` S \<subseteq> T"
   681       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   682       and "w \<in> S"
   683     shows "deriv f w * deriv g (f w) = 1"
   684 proof -
   685   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   686     by (simp add: algebra_simps)
   687   also have "... = deriv (g o f) w"
   688     using assms
   689     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   690   also have "... = deriv id w"
   691     apply (rule complex_derivative_transform_within_open [where s=S])
   692     apply (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   693     apply simp
   694     done
   695   also have "... = 1"
   696     by simp
   697   finally show ?thesis .
   698 qed
   699 
   700 subsection\<open>analyticity at a point\<close>
   701 
   702 lemma analytic_at_ball:
   703   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   704 by (metis analytic_on_def singleton_iff)
   705 
   706 lemma analytic_at:
   707     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   708 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   709 
   710 lemma analytic_on_analytic_at:
   711     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   712 by (metis analytic_at_ball analytic_on_def)
   713 
   714 lemma analytic_at_two:
   715   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   716    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   717   (is "?lhs = ?rhs")
   718 proof
   719   assume ?lhs
   720   then obtain s t
   721     where st: "open s" "z \<in> s" "f holomorphic_on s"
   722               "open t" "z \<in> t" "g holomorphic_on t"
   723     by (auto simp: analytic_at)
   724   show ?rhs
   725     apply (rule_tac x="s \<inter> t" in exI)
   726     using st
   727     apply (auto simp: Diff_subset holomorphic_on_subset)
   728     done
   729 next
   730   assume ?rhs
   731   then show ?lhs
   732     by (force simp add: analytic_at)
   733 qed
   734 
   735 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   736 
   737 lemma
   738   assumes "f analytic_on {z}" "g analytic_on {z}"
   739   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   740     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   741     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   742            f z * deriv g z + deriv f z * g z"
   743 proof -
   744   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   745     using assms by (metis analytic_at_two)
   746   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   747     apply (rule DERIV_imp_deriv [OF DERIV_add])
   748     using s
   749     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   750     done
   751   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   752     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   753     using s
   754     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   755     done
   756   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   757     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   758     using s
   759     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   760     done
   761 qed
   762 
   763 lemma deriv_cmult_at:
   764   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   765 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   766 
   767 lemma deriv_cmult_right_at:
   768   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   769 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   770 
   771 subsection\<open>Complex differentiation of sequences and series\<close>
   772 
   773 (* TODO: Could probably be simplified using Uniform_Limit *)
   774 lemma has_complex_derivative_sequence:
   775   fixes s :: "complex set"
   776   assumes cvs: "convex s"
   777       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   778       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   779       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   780     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   781                        (g has_field_derivative (g' x)) (at x within s)"
   782 proof -
   783   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   784     by blast
   785   { fix e::real assume e: "e > 0"
   786     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   787       by (metis conv)
   788     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   789     proof (rule exI [of _ N], clarify)
   790       fix n y h
   791       assume "N \<le> n" "y \<in> s"
   792       then have "cmod (f' n y - g' y) \<le> e"
   793         by (metis N)
   794       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   795         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   796       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   797         by (simp add: norm_mult [symmetric] field_simps)
   798     qed
   799   } note ** = this
   800   show ?thesis
   801   unfolding has_field_derivative_def
   802   proof (rule has_derivative_sequence [OF cvs _ _ x])
   803     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (op * (f' n x))) (at x within s)"
   804       by (metis has_field_derivative_def df)
   805   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   806     by (rule tf)
   807   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   808     by (blast intro: **)
   809   qed
   810 qed
   811 
   812 lemma has_complex_derivative_series:
   813   fixes s :: "complex set"
   814   assumes cvs: "convex s"
   815       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   816       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   817                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   818       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   819     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   820 proof -
   821   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   822     by blast
   823   { fix e::real assume e: "e > 0"
   824     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   825             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   826       by (metis conv)
   827     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   828     proof (rule exI [of _ N], clarify)
   829       fix n y h
   830       assume "N \<le> n" "y \<in> s"
   831       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   832         by (metis N)
   833       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   834         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   835       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   836         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   837     qed
   838   } note ** = this
   839   show ?thesis
   840   unfolding has_field_derivative_def
   841   proof (rule has_derivative_series [OF cvs _ _ x])
   842     fix n x
   843     assume "x \<in> s"
   844     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   845       by (metis df has_field_derivative_def mult_commute_abs)
   846   next show " ((\<lambda>n. f n x) sums l)"
   847     by (rule sf)
   848   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   849     by (blast intro: **)
   850   qed
   851 qed
   852 
   853 
   854 lemma field_differentiable_series:
   855   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   856   assumes "convex s" "open s"
   857   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   858   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   859   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   860   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   861 proof -
   862   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   863     unfolding uniformly_convergent_on_def by blast
   864   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   865   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   866     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   867   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   868     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   869   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   870   from g(2)[OF x] have g': "(g has_derivative op * (g' x)) (at x)"
   871     by (simp add: has_field_derivative_def s)
   872   have "((\<lambda>x. \<Sum>n. f n x) has_derivative op * (g' x)) (at x)"
   873     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   874        (insert g, auto simp: sums_iff)
   875   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   876     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   877 qed
   878 
   879 lemma field_differentiable_series':
   880   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   881   assumes "convex s" "open s"
   882   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   883   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   884   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   885   shows   "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x0)"
   886   using field_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   887 
   888 subsection\<open>Bound theorem\<close>
   889 
   890 lemma field_differentiable_bound:
   891   fixes s :: "complex set"
   892   assumes cvs: "convex s"
   893       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   894       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   895       and "x \<in> s"  "y \<in> s"
   896     shows "norm(f x - f y) \<le> B * norm(x - y)"
   897   apply (rule differentiable_bound [OF cvs])
   898   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   899   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   900   apply fact
   901   apply fact
   902   done
   903 
   904 subsection\<open>Inverse function theorem for complex derivatives\<close>
   905 
   906 lemma has_complex_derivative_inverse_basic:
   907   fixes f :: "complex \<Rightarrow> complex"
   908   shows "DERIV f (g y) :> f' \<Longrightarrow>
   909         f' \<noteq> 0 \<Longrightarrow>
   910         continuous (at y) g \<Longrightarrow>
   911         open t \<Longrightarrow>
   912         y \<in> t \<Longrightarrow>
   913         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   914         \<Longrightarrow> DERIV g y :> inverse (f')"
   915   unfolding has_field_derivative_def
   916   apply (rule has_derivative_inverse_basic)
   917   apply (auto simp:  bounded_linear_mult_right)
   918   done
   919 
   920 (*Used only once, in Multivariate/cauchy.ml. *)
   921 lemma has_complex_derivative_inverse_strong:
   922   fixes f :: "complex \<Rightarrow> complex"
   923   shows "DERIV f x :> f' \<Longrightarrow>
   924          f' \<noteq> 0 \<Longrightarrow>
   925          open s \<Longrightarrow>
   926          x \<in> s \<Longrightarrow>
   927          continuous_on s f \<Longrightarrow>
   928          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   929          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   930   unfolding has_field_derivative_def
   931   apply (rule has_derivative_inverse_strong [of s x f g ])
   932   by auto
   933 
   934 lemma has_complex_derivative_inverse_strong_x:
   935   fixes f :: "complex \<Rightarrow> complex"
   936   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   937           f' \<noteq> 0 \<Longrightarrow>
   938           open s \<Longrightarrow>
   939           continuous_on s f \<Longrightarrow>
   940           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
   941           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   942           \<Longrightarrow> DERIV g y :> inverse (f')"
   943   unfolding has_field_derivative_def
   944   apply (rule has_derivative_inverse_strong_x [of s g y f])
   945   by auto
   946 
   947 subsection \<open>Taylor on Complex Numbers\<close>
   948 
   949 lemma sum_Suc_reindex:
   950   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   951     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   952 by (induct n) auto
   953 
   954 lemma complex_taylor:
   955   assumes s: "convex s"
   956       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
   957       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
   958       and w: "w \<in> s"
   959       and z: "z \<in> s"
   960     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   961           \<le> B * cmod(z - w)^(Suc n) / fact n"
   962 proof -
   963   have wzs: "closed_segment w z \<subseteq> s" using assms
   964     by (metis convex_contains_segment)
   965   { fix u
   966     assume "u \<in> closed_segment w z"
   967     then have "u \<in> s"
   968       by (metis wzs subsetD)
   969     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   970                       f (Suc i) u * (z-u)^i / (fact i)) =
   971               f (Suc n) u * (z-u) ^ n / (fact n)"
   972     proof (induction n)
   973       case 0 show ?case by simp
   974     next
   975       case (Suc n)
   976       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   977                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   978            f (Suc n) u * (z-u) ^ n / (fact n) +
   979            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
   980            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
   981         using Suc by simp
   982       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
   983       proof -
   984         have "(fact(Suc n)) *
   985              (f(Suc n) u *(z-u) ^ n / (fact n) +
   986                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
   987                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
   988             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
   989             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
   990             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
   991           by (simp add: algebra_simps del: fact_Suc)
   992         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
   993                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   994                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   995           by (simp del: fact_Suc)
   996         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
   997                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   998                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   999           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1000         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1001           by (simp add: algebra_simps)
  1002         finally show ?thesis
  1003         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1004       qed
  1005       finally show ?case .
  1006     qed
  1007     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1008                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1009                (at u within s)"
  1010       apply (intro derivative_eq_intros)
  1011       apply (blast intro: assms \<open>u \<in> s\<close>)
  1012       apply (rule refl)+
  1013       apply (auto simp: field_simps)
  1014       done
  1015   } note sum_deriv = this
  1016   { fix u
  1017     assume u: "u \<in> closed_segment w z"
  1018     then have us: "u \<in> s"
  1019       by (metis wzs subsetD)
  1020     have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> cmod (f (Suc n) u) * cmod (u - z) ^ n"
  1021       by (metis norm_minus_commute order_refl)
  1022     also have "... \<le> cmod (f (Suc n) u) * cmod (z - w) ^ n"
  1023       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1024     also have "... \<le> B * cmod (z - w) ^ n"
  1025       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1026     finally have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> B * cmod (z - w) ^ n" .
  1027   } note cmod_bound = this
  1028   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1029     by simp
  1030   also have "\<dots> = f 0 z / (fact 0)"
  1031     by (subst sum_zero_power) simp
  1032   finally have "cmod (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1033                 \<le> cmod ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1034                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1035     by (simp add: norm_minus_commute)
  1036   also have "... \<le> B * cmod (z - w) ^ n / (fact n) * cmod (w - z)"
  1037     apply (rule field_differentiable_bound
  1038       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1039          and s = "closed_segment w z", OF convex_closed_segment])
  1040     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1041                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1042     done
  1043   also have "...  \<le> B * cmod (z - w) ^ Suc n / (fact n)"
  1044     by (simp add: algebra_simps norm_minus_commute)
  1045   finally show ?thesis .
  1046 qed
  1047 
  1048 text\<open>Something more like the traditional MVT for real components\<close>
  1049 
  1050 lemma complex_mvt_line:
  1051   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1052     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1053 proof -
  1054   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1055     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1056   note assms[unfolded has_field_derivative_def, derivative_intros]
  1057   show ?thesis
  1058     apply (cut_tac mvt_simple
  1059                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1060                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1061     apply auto
  1062     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1063     apply (auto simp: closed_segment_def twz) []
  1064     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1065     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1066     apply (force simp: twz closed_segment_def)
  1067     done
  1068 qed
  1069 
  1070 lemma complex_taylor_mvt:
  1071   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1072     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1073             Re (f 0 z) =
  1074             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1075                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1076 proof -
  1077   { fix u
  1078     assume u: "u \<in> closed_segment w z"
  1079     have "(\<Sum>i = 0..n.
  1080                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1081                (fact i)) =
  1082           f (Suc 0) u -
  1083              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1084              (fact (Suc n)) +
  1085              (\<Sum>i = 0..n.
  1086                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1087                  (fact (Suc i)))"
  1088        by (subst sum_Suc_reindex) simp
  1089     also have "... = f (Suc 0) u -
  1090              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1091              (fact (Suc n)) +
  1092              (\<Sum>i = 0..n.
  1093                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1094                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1095       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1096     also have "... = f (Suc 0) u -
  1097              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1098              (fact (Suc n)) +
  1099              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1100       by (subst sum_Suc_diff) auto
  1101     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1102       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1103     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1104                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1105                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1106     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1107                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1108       apply (intro derivative_eq_intros)+
  1109       apply (force intro: u assms)
  1110       apply (rule refl)+
  1111       apply (auto simp: ac_simps)
  1112       done
  1113   }
  1114   then show ?thesis
  1115     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1116                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1117     apply (auto simp add: intro: open_closed_segment)
  1118     done
  1119 qed
  1120 
  1121 
  1122 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1123 
  1124 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1125     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1126   assumes "0 < e"
  1127     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1128 proof (induct n)
  1129   case 0 with assms
  1130   show ?case
  1131     apply (rule_tac x="norm (c 0) / e" in exI)
  1132     apply (auto simp: field_simps)
  1133     done
  1134 next
  1135   case (Suc n)
  1136   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1137     using Suc assms by blast
  1138   show ?case
  1139   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1140     fix z::'a
  1141     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1142     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1143       using assms by (simp add: field_simps)
  1144     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1145       using M [OF z1] by simp
  1146     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1147       by simp
  1148     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1149       by (blast intro: norm_triangle_le elim: )
  1150     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1151       by (simp add: norm_power norm_mult algebra_simps)
  1152     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1153       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1154     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1155       by simp
  1156   qed
  1157 qed
  1158 
  1159 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1160     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1161   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1162     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1163 using kn
  1164 proof (induction n)
  1165   case 0
  1166   then show ?case
  1167     using k  by simp
  1168 next
  1169   case (Suc m)
  1170   let ?even = ?case
  1171   show ?even
  1172   proof (cases "c (Suc m) = 0")
  1173     case True
  1174     then show ?even using Suc k
  1175       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1176   next
  1177     case False
  1178     then obtain M where M:
  1179           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1180       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1181       by auto
  1182     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1183     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1184       fix z::'a
  1185       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1186          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1187       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1188         using False by (simp add: field_simps)
  1189       have nz: "norm z \<le> norm z ^ Suc m"
  1190         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1191       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1192         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1193       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1194             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1195         using M [of z] Suc z1  by auto
  1196       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1197         using nz by (simp add: mult_mono del: power_Suc)
  1198       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1199         using Suc.IH
  1200         apply (auto simp: eventually_at_infinity)
  1201         apply (rule *)
  1202         apply (simp add: field_simps norm_mult norm_power)
  1203         done
  1204     qed
  1205     then show ?even
  1206       by (simp add: eventually_at_infinity)
  1207   qed
  1208 qed
  1209 
  1210 end