src/Pure/raw_simplifier.ML
author wenzelm
Mon Feb 27 15:42:07 2012 +0100 (2012-02-27)
changeset 46707 1427dcc7c9a6
parent 46465 5ba52c337cd0
child 47239 0b1829860149
permissions -rw-r--r--
eliminated odd comment from distant past;
     1 (*  Title:      Pure/raw_simplifier.ML
     2     Author:     Tobias Nipkow and Stefan Berghofer, TU Muenchen
     3 
     4 Higher-order Simplification.
     5 *)
     6 
     7 infix 4
     8   addsimps delsimps addsimprocs delsimprocs
     9   setloop' setloop addloop addloop' delloop
    10   setSSolver addSSolver setSolver addSolver;
    11 
    12 signature BASIC_RAW_SIMPLIFIER =
    13 sig
    14   val simp_depth_limit: int Config.T
    15   val simp_trace_depth_limit: int Config.T
    16   val simp_debug: bool Config.T
    17   val simp_trace: bool Config.T
    18   type rrule
    19   val eq_rrule: rrule * rrule -> bool
    20   type simpset
    21   type proc
    22   type solver
    23   val mk_solver: string -> (simpset -> int -> tactic) -> solver
    24   val empty_ss: simpset
    25   val merge_ss: simpset * simpset -> simpset
    26   val dest_ss: simpset ->
    27    {simps: (string * thm) list,
    28     procs: (string * cterm list) list,
    29     congs: (string * thm) list,
    30     weak_congs: string list,
    31     loopers: string list,
    32     unsafe_solvers: string list,
    33     safe_solvers: string list}
    34   type simproc
    35   val eq_simproc: simproc * simproc -> bool
    36   val transform_simproc: morphism -> simproc -> simproc
    37   val make_simproc: {name: string, lhss: cterm list,
    38     proc: morphism -> simpset -> cterm -> thm option, identifier: thm list} -> simproc
    39   val mk_simproc: string -> cterm list -> (theory -> simpset -> term -> thm option) -> simproc
    40   val addsimps: simpset * thm list -> simpset
    41   val delsimps: simpset * thm list -> simpset
    42   val addsimprocs: simpset * simproc list -> simpset
    43   val delsimprocs: simpset * simproc list -> simpset
    44   val setloop': simpset * (simpset -> int -> tactic) -> simpset
    45   val setloop: simpset * (int -> tactic) -> simpset
    46   val addloop': simpset * (string * (simpset -> int -> tactic)) -> simpset
    47   val addloop: simpset * (string * (int -> tactic)) -> simpset
    48   val delloop: simpset * string -> simpset
    49   val setSSolver: simpset * solver -> simpset
    50   val addSSolver: simpset * solver -> simpset
    51   val setSolver: simpset * solver -> simpset
    52   val addSolver: simpset * solver -> simpset
    53 
    54   val rewrite_rule: thm list -> thm -> thm
    55   val rewrite_goals_rule: thm list -> thm -> thm
    56   val rewrite_goals_tac: thm list -> tactic
    57   val rewrite_goal_tac: thm list -> int -> tactic
    58   val prune_params_tac: tactic
    59   val fold_rule: thm list -> thm -> thm
    60   val fold_goals_tac: thm list -> tactic
    61   val norm_hhf: thm -> thm
    62   val norm_hhf_protect: thm -> thm
    63 end;
    64 
    65 signature RAW_SIMPLIFIER =
    66 sig
    67   include BASIC_RAW_SIMPLIFIER
    68   exception SIMPLIFIER of string * thm
    69   val internal_ss: simpset ->
    70    {rules: rrule Net.net,
    71     prems: thm list,
    72     bounds: int * ((string * typ) * string) list,
    73     depth: int * bool Unsynchronized.ref,
    74     context: Proof.context option} *
    75    {congs: (string * thm) list * string list,
    76     procs: proc Net.net,
    77     mk_rews:
    78      {mk: simpset -> thm -> thm list,
    79       mk_cong: simpset -> thm -> thm,
    80       mk_sym: simpset -> thm -> thm option,
    81       mk_eq_True: simpset -> thm -> thm option,
    82       reorient: theory -> term list -> term -> term -> bool},
    83     termless: term * term -> bool,
    84     subgoal_tac: simpset -> int -> tactic,
    85     loop_tacs: (string * (simpset -> int -> tactic)) list,
    86     solvers: solver list * solver list}
    87   val prems_of: simpset -> thm list
    88   val add_simp: thm -> simpset -> simpset
    89   val del_simp: thm -> simpset -> simpset
    90   val add_eqcong: thm -> simpset -> simpset
    91   val del_eqcong: thm -> simpset -> simpset
    92   val add_cong: thm -> simpset -> simpset
    93   val del_cong: thm -> simpset -> simpset
    94   val mksimps: simpset -> thm -> thm list
    95   val set_mksimps: (simpset -> thm -> thm list) -> simpset -> simpset
    96   val set_mkcong: (simpset -> thm -> thm) -> simpset -> simpset
    97   val set_mksym: (simpset -> thm -> thm option) -> simpset -> simpset
    98   val set_mkeqTrue: (simpset -> thm -> thm option) -> simpset -> simpset
    99   val set_termless: (term * term -> bool) -> simpset -> simpset
   100   val set_subgoaler: (simpset -> int -> tactic) -> simpset -> simpset
   101   val solver: simpset -> solver -> int -> tactic
   102   val simp_depth_limit_raw: Config.raw
   103   val clear_ss: simpset -> simpset
   104   val simproc_global_i: theory -> string -> term list
   105     -> (theory -> simpset -> term -> thm option) -> simproc
   106   val simproc_global: theory -> string -> string list
   107     -> (theory -> simpset -> term -> thm option) -> simproc
   108   val simp_trace_depth_limit_raw: Config.raw
   109   val simp_trace_depth_limit_default: int Unsynchronized.ref
   110   val simp_trace_default: bool Unsynchronized.ref
   111   val simp_trace_raw: Config.raw
   112   val simp_debug_raw: Config.raw
   113   val add_prems: thm list -> simpset -> simpset
   114   val inherit_context: simpset -> simpset -> simpset
   115   val the_context: simpset -> Proof.context
   116   val context: Proof.context -> simpset -> simpset
   117   val global_context: theory -> simpset -> simpset
   118   val with_context: Proof.context -> (simpset -> simpset) -> simpset -> simpset
   119   val debug_bounds: bool Unsynchronized.ref
   120   val set_reorient: (theory -> term list -> term -> term -> bool) -> simpset -> simpset
   121   val set_solvers: solver list -> simpset -> simpset
   122   val rewrite_cterm: bool * bool * bool -> (simpset -> thm -> thm option) -> simpset -> conv
   123   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
   124   val rewrite_thm: bool * bool * bool ->
   125     (simpset -> thm -> thm option) -> simpset -> thm -> thm
   126   val generic_rewrite_goal_tac: bool * bool * bool ->
   127     (simpset -> tactic) -> simpset -> int -> tactic
   128   val rewrite: bool -> thm list -> conv
   129   val simplify: bool -> thm list -> thm -> thm
   130 end;
   131 
   132 structure Raw_Simplifier: RAW_SIMPLIFIER =
   133 struct
   134 
   135 (** datatype simpset **)
   136 
   137 (* rewrite rules *)
   138 
   139 type rrule =
   140  {thm: thm,         (*the rewrite rule*)
   141   name: string,     (*name of theorem from which rewrite rule was extracted*)
   142   lhs: term,        (*the left-hand side*)
   143   elhs: cterm,      (*the etac-contracted lhs*)
   144   extra: bool,      (*extra variables outside of elhs*)
   145   fo: bool,         (*use first-order matching*)
   146   perm: bool};      (*the rewrite rule is permutative*)
   147 
   148 (*
   149 Remarks:
   150   - elhs is used for matching,
   151     lhs only for preservation of bound variable names;
   152   - fo is set iff
   153     either elhs is first-order (no Var is applied),
   154       in which case fo-matching is complete,
   155     or elhs is not a pattern,
   156       in which case there is nothing better to do;
   157 *)
   158 
   159 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   160   Thm.eq_thm_prop (thm1, thm2);
   161 
   162 
   163 (* simplification sets, procedures, and solvers *)
   164 
   165 (*A simpset contains data required during conversion:
   166     rules: discrimination net of rewrite rules;
   167     prems: current premises;
   168     bounds: maximal index of bound variables already used
   169       (for generating new names when rewriting under lambda abstractions);
   170     depth: simp_depth and exceeded flag;
   171     congs: association list of congruence rules and
   172            a list of `weak' congruence constants.
   173            A congruence is `weak' if it avoids normalization of some argument.
   174     procs: discrimination net of simplification procedures
   175       (functions that prove rewrite rules on the fly);
   176     mk_rews:
   177       mk: turn simplification thms into rewrite rules;
   178       mk_cong: prepare congruence rules;
   179       mk_sym: turn == around;
   180       mk_eq_True: turn P into P == True;
   181     termless: relation for ordered rewriting;*)
   182 
   183 datatype simpset =
   184   Simpset of
   185    {rules: rrule Net.net,
   186     prems: thm list,
   187     bounds: int * ((string * typ) * string) list,
   188     depth: int * bool Unsynchronized.ref,
   189     context: Proof.context option} *
   190    {congs: (string * thm) list * string list,
   191     procs: proc Net.net,
   192     mk_rews:
   193      {mk: simpset -> thm -> thm list,
   194       mk_cong: simpset -> thm -> thm,
   195       mk_sym: simpset -> thm -> thm option,
   196       mk_eq_True: simpset -> thm -> thm option,
   197       reorient: theory -> term list -> term -> term -> bool},
   198     termless: term * term -> bool,
   199     subgoal_tac: simpset -> int -> tactic,
   200     loop_tacs: (string * (simpset -> int -> tactic)) list,
   201     solvers: solver list * solver list}
   202 and proc =
   203   Proc of
   204    {name: string,
   205     lhs: cterm,
   206     proc: simpset -> cterm -> thm option,
   207     id: stamp * thm list}
   208 and solver =
   209   Solver of
   210    {name: string,
   211     solver: simpset -> int -> tactic,
   212     id: stamp};
   213 
   214 
   215 fun internal_ss (Simpset args) = args;
   216 
   217 fun make_ss1 (rules, prems, bounds, depth, context) =
   218   {rules = rules, prems = prems, bounds = bounds, depth = depth, context = context};
   219 
   220 fun map_ss1 f {rules, prems, bounds, depth, context} =
   221   make_ss1 (f (rules, prems, bounds, depth, context));
   222 
   223 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   224   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   225     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   226 
   227 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   228   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   229 
   230 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   231 
   232 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   233 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   234 
   235 fun prems_of (Simpset ({prems, ...}, _)) = prems;
   236 
   237 fun eq_procid ((s1: stamp, ths1: thm list), (s2, ths2)) =
   238   s1 = s2 andalso eq_list Thm.eq_thm (ths1, ths2);
   239 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = eq_procid (id1, id2);
   240 
   241 fun mk_solver name solver = Solver {name = name, solver = solver, id = stamp ()};
   242 
   243 fun solver_name (Solver {name, ...}) = name;
   244 fun solver ss (Solver {solver = tac, ...}) = tac ss;
   245 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   246 
   247 
   248 (* simp depth *)
   249 
   250 val simp_depth_limit_raw = Config.declare "simp_depth_limit" (K (Config.Int 100));
   251 val simp_depth_limit = Config.int simp_depth_limit_raw;
   252 
   253 val simp_trace_depth_limit_default = Unsynchronized.ref 1;
   254 val simp_trace_depth_limit_raw = Config.declare "simp_trace_depth_limit"
   255   (fn _ => Config.Int (! simp_trace_depth_limit_default));
   256 val simp_trace_depth_limit = Config.int simp_trace_depth_limit_raw;
   257 
   258 fun simp_trace_depth_limit_of NONE = ! simp_trace_depth_limit_default
   259   | simp_trace_depth_limit_of (SOME ctxt) = Config.get ctxt simp_trace_depth_limit;
   260 
   261 fun trace_depth (Simpset ({depth = (depth, exceeded), context, ...}, _)) msg =
   262   if depth > simp_trace_depth_limit_of context then
   263     if ! exceeded then () else (tracing "simp_trace_depth_limit exceeded!"; exceeded := true)
   264   else
   265     (tracing (enclose "[" "]" (string_of_int depth) ^ msg); exceeded := false);
   266 
   267 val inc_simp_depth = map_simpset1 (fn (rules, prems, bounds, (depth, exceeded), context) =>
   268   (rules, prems, bounds,
   269     (depth + 1,
   270       if depth = simp_trace_depth_limit_of context then Unsynchronized.ref false else exceeded), context));
   271 
   272 fun simp_depth (Simpset ({depth = (depth, _), ...}, _)) = depth;
   273 
   274 
   275 (* diagnostics *)
   276 
   277 exception SIMPLIFIER of string * thm;
   278 
   279 val simp_debug_raw = Config.declare "simp_debug" (K (Config.Bool false));
   280 val simp_debug = Config.bool simp_debug_raw;
   281 
   282 val simp_trace_default = Unsynchronized.ref false;
   283 val simp_trace_raw = Config.declare "simp_trace" (fn _ => Config.Bool (! simp_trace_default));
   284 val simp_trace = Config.bool simp_trace_raw;
   285 
   286 fun if_enabled (Simpset ({context, ...}, _)) flag f =
   287   (case context of
   288     SOME ctxt => if Config.get ctxt flag then f ctxt else ()
   289   | NONE => ())
   290 
   291 fun if_visible (Simpset ({context, ...}, _)) f x =
   292   (case context of
   293     SOME ctxt => Context_Position.if_visible ctxt f x
   294   | NONE => ());
   295 
   296 local
   297 
   298 fun prnt ss warn a = if warn then warning a else trace_depth ss a;
   299 
   300 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   301   let
   302     val names = Term.declare_term_names t Name.context;
   303     val xs = rev (#1 (fold_map Name.variant (rev (map #2 bs)) names));
   304     fun subst (((b, T), _), x') = (Free (b, T), Syntax_Trans.mark_boundT (x', T));
   305   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   306 
   307 fun print_term ss warn a t ctxt = prnt ss warn (a () ^ "\n" ^
   308   Syntax.string_of_term ctxt
   309     (if Config.get ctxt simp_debug then t else show_bounds ss t));
   310 
   311 in
   312 
   313 fun print_term_global ss warn a thy t =
   314   print_term ss warn (K a) t (Proof_Context.init_global thy);
   315 
   316 fun debug warn a ss = if_enabled ss simp_debug (fn _ => prnt ss warn (a ()));
   317 fun trace warn a ss = if_enabled ss simp_trace (fn _ => prnt ss warn (a ()));
   318 
   319 fun debug_term warn a ss t = if_enabled ss simp_debug (print_term ss warn a t);
   320 fun trace_term warn a ss t = if_enabled ss simp_trace (print_term ss warn a t);
   321 
   322 fun trace_cterm warn a ss ct =
   323   if_enabled ss simp_trace (print_term ss warn a (Thm.term_of ct));
   324 
   325 fun trace_thm a ss th =
   326   if_enabled ss simp_trace (print_term ss false a (Thm.full_prop_of th));
   327 
   328 fun trace_named_thm a ss (th, name) =
   329   if_enabled ss simp_trace (print_term ss false
   330     (fn () => if name = "" then a () else a () ^ " " ^ quote name ^ ":")
   331     (Thm.full_prop_of th));
   332 
   333 fun warn_thm a ss th =
   334   print_term_global ss true a (Thm.theory_of_thm th) (Thm.full_prop_of th);
   335 
   336 fun cond_warn_thm a ss th = if_visible ss (fn () => warn_thm a ss th) ();
   337 
   338 end;
   339 
   340 
   341 
   342 (** simpset operations **)
   343 
   344 (* context *)
   345 
   346 fun eq_bound (x: string, (y, _)) = x = y;
   347 
   348 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds), depth, context) =>
   349   (rules, prems, (count + 1, bound :: bounds), depth, context));
   350 
   351 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   352   (rules, ths @ prems, bounds, depth, context));
   353 
   354 fun inherit_context (Simpset ({bounds, depth, context, ...}, _)) =
   355   map_simpset1 (fn (rules, prems, _, _, _) => (rules, prems, bounds, depth, context));
   356 
   357 fun the_context (Simpset ({context = SOME ctxt, ...}, _)) = ctxt
   358   | the_context _ = raise Fail "Simplifier: no proof context in simpset";
   359 
   360 fun context ctxt =
   361   map_simpset1 (fn (rules, prems, bounds, depth, _) => (rules, prems, bounds, depth, SOME ctxt));
   362 
   363 val global_context = context o Proof_Context.init_global;
   364 
   365 fun activate_context thy ss =
   366   let
   367     val ctxt = the_context ss;
   368     val ctxt' = ctxt
   369       |> Context.raw_transfer (Theory.merge (thy, Proof_Context.theory_of ctxt))
   370       |> Context_Position.set_visible false;
   371   in context ctxt' ss end;
   372 
   373 fun with_context ctxt f ss = inherit_context ss (f (context ctxt ss));
   374 
   375 
   376 (* maintain simp rules *)
   377 
   378 (* FIXME: it seems that the conditions on extra variables are too liberal if
   379 prems are nonempty: does solving the prems really guarantee instantiation of
   380 all its Vars? Better: a dynamic check each time a rule is applied.
   381 *)
   382 fun rewrite_rule_extra_vars prems elhs erhs =
   383   let
   384     val elhss = elhs :: prems;
   385     val tvars = fold Term.add_tvars elhss [];
   386     val vars = fold Term.add_vars elhss [];
   387   in
   388     erhs |> Term.exists_type (Term.exists_subtype
   389       (fn TVar v => not (member (op =) tvars v) | _ => false)) orelse
   390     erhs |> Term.exists_subterm
   391       (fn Var v => not (member (op =) vars v) | _ => false)
   392   end;
   393 
   394 fun rrule_extra_vars elhs thm =
   395   rewrite_rule_extra_vars [] (term_of elhs) (Thm.full_prop_of thm);
   396 
   397 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   398   let
   399     val t = term_of elhs;
   400     val fo = Pattern.first_order t orelse not (Pattern.pattern t);
   401     val extra = rrule_extra_vars elhs thm;
   402   in {thm = thm, name = name, lhs = lhs, elhs = elhs, extra = extra, fo = fo, perm = perm} end;
   403 
   404 fun del_rrule (rrule as {thm, elhs, ...}) ss =
   405   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   406     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds, depth, context))
   407   handle Net.DELETE => (cond_warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   408 
   409 fun insert_rrule (rrule as {thm, name, ...}) ss =
   410  (trace_named_thm (fn () => "Adding rewrite rule") ss (thm, name);
   411   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   412     let
   413       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   414       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   415     in (rules', prems, bounds, depth, context) end)
   416   handle Net.INSERT => (cond_warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   417 
   418 fun vperm (Var _, Var _) = true
   419   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   420   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   421   | vperm (t, u) = (t = u);
   422 
   423 fun var_perm (t, u) =
   424   vperm (t, u) andalso eq_set (op =) (Term.add_vars t [], Term.add_vars u []);
   425 
   426 (*simple test for looping rewrite rules and stupid orientations*)
   427 fun default_reorient thy prems lhs rhs =
   428   rewrite_rule_extra_vars prems lhs rhs
   429     orelse
   430   is_Var (head_of lhs)
   431     orelse
   432 (* turns t = x around, which causes a headache if x is a local variable -
   433    usually it is very useful :-(
   434   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   435   andalso not(exists_subterm is_Var lhs)
   436     orelse
   437 *)
   438   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   439     orelse
   440   null prems andalso Pattern.matches thy (lhs, rhs)
   441     (*the condition "null prems" is necessary because conditional rewrites
   442       with extra variables in the conditions may terminate although
   443       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   444     orelse
   445   is_Const lhs andalso not (is_Const rhs);
   446 
   447 fun decomp_simp thm =
   448   let
   449     val thy = Thm.theory_of_thm thm;
   450     val prop = Thm.prop_of thm;
   451     val prems = Logic.strip_imp_prems prop;
   452     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   453     val (lhs, rhs) = Thm.dest_equals concl handle TERM _ =>
   454       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   455     val elhs = Thm.dest_arg (Thm.cprop_of (Thm.eta_conversion lhs));
   456     val erhs = Envir.eta_contract (term_of rhs);
   457     val perm =
   458       var_perm (term_of elhs, erhs) andalso
   459       not (term_of elhs aconv erhs) andalso
   460       not (is_Var (term_of elhs));
   461   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   462 
   463 fun decomp_simp' thm =
   464   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   465     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   466     else (lhs, rhs)
   467   end;
   468 
   469 fun mk_eq_True (ss as Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   470   (case mk_eq_True ss thm of
   471     NONE => []
   472   | SOME eq_True =>
   473       let
   474         val (_, _, lhs, elhs, _, _) = decomp_simp eq_True;
   475       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   476 
   477 (*create the rewrite rule and possibly also the eq_True variant,
   478   in case there are extra vars on the rhs*)
   479 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   480   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   481     if rewrite_rule_extra_vars [] lhs rhs then
   482       mk_eq_True ss (thm2, name) @ [rrule]
   483     else [rrule]
   484   end;
   485 
   486 fun mk_rrule ss (thm, name) =
   487   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   488     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   489     else
   490       (*weak test for loops*)
   491       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   492       then mk_eq_True ss (thm, name)
   493       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   494   end;
   495 
   496 fun orient_rrule ss (thm, name) =
   497   let
   498     val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm;
   499     val Simpset (_, {mk_rews = {reorient, mk_sym, ...}, ...}) = ss;
   500   in
   501     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   502     else if reorient thy prems lhs rhs then
   503       if reorient thy prems rhs lhs
   504       then mk_eq_True ss (thm, name)
   505       else
   506         (case mk_sym ss thm of
   507           NONE => []
   508         | SOME thm' =>
   509             let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   510             in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   511     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   512   end;
   513 
   514 fun extract_rews (ss as Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   515   maps (fn thm => map (rpair (Thm.get_name_hint thm)) (mk ss thm)) thms;
   516 
   517 fun extract_safe_rrules (ss, thm) =
   518   maps (orient_rrule ss) (extract_rews (ss, [thm]));
   519 
   520 
   521 (* add/del rules explicitly *)
   522 
   523 fun comb_simps comb mk_rrule (ss, thms) =
   524   let
   525     val rews = extract_rews (ss, thms);
   526   in fold (fold comb o mk_rrule) rews ss end;
   527 
   528 fun ss addsimps thms =
   529   comb_simps insert_rrule (mk_rrule ss) (ss, thms);
   530 
   531 fun ss delsimps thms =
   532   comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   533 
   534 fun add_simp thm ss = ss addsimps [thm];
   535 fun del_simp thm ss = ss delsimps [thm];
   536 
   537 
   538 (* congs *)
   539 
   540 fun cong_name (Const (a, _)) = SOME a
   541   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   542   | cong_name _ = NONE;
   543 
   544 local
   545 
   546 fun is_full_cong_prems [] [] = true
   547   | is_full_cong_prems [] _ = false
   548   | is_full_cong_prems (p :: prems) varpairs =
   549       (case Logic.strip_assums_concl p of
   550         Const ("==", _) $ lhs $ rhs =>
   551           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   552             is_Var x andalso forall is_Bound xs andalso
   553             not (has_duplicates (op =) xs) andalso xs = ys andalso
   554             member (op =) varpairs (x, y) andalso
   555             is_full_cong_prems prems (remove (op =) (x, y) varpairs)
   556           end
   557       | _ => false);
   558 
   559 fun is_full_cong thm =
   560   let
   561     val prems = Thm.prems_of thm and concl = Thm.concl_of thm;
   562     val (lhs, rhs) = Logic.dest_equals concl;
   563     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   564   in
   565     f = g andalso not (has_duplicates (op =) (xs @ ys)) andalso length xs = length ys andalso
   566     is_full_cong_prems prems (xs ~~ ys)
   567   end;
   568 
   569 fun mk_cong (ss as Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f ss;
   570 
   571 in
   572 
   573 fun add_eqcong thm ss = ss |>
   574   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   575     let
   576       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   577         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   578     (*val lhs = Envir.eta_contract lhs;*)
   579       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   580         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   581       val (xs, weak) = congs;
   582       val _ =
   583         if AList.defined (op =) xs a
   584         then if_visible ss warning ("Overwriting congruence rule for " ^ quote a)
   585         else ();
   586       val xs' = AList.update (op =) (a, thm) xs;
   587       val weak' = if is_full_cong thm then weak else a :: weak;
   588     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   589 
   590 fun del_eqcong thm ss = ss |>
   591   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   592     let
   593       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   594         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   595     (*val lhs = Envir.eta_contract lhs;*)
   596       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   597         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   598       val (xs, _) = congs;
   599       val xs' = filter_out (fn (x : string, _) => x = a) xs;
   600       val weak' = xs' |> map_filter (fn (a, thm) =>
   601         if is_full_cong thm then NONE else SOME a);
   602     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   603 
   604 fun add_cong thm ss = add_eqcong (mk_cong ss thm) ss;
   605 fun del_cong thm ss = del_eqcong (mk_cong ss thm) ss;
   606 
   607 end;
   608 
   609 
   610 (* simprocs *)
   611 
   612 datatype simproc =
   613   Simproc of
   614     {name: string,
   615      lhss: cterm list,
   616      proc: morphism -> simpset -> cterm -> thm option,
   617      id: stamp * thm list};
   618 
   619 fun eq_simproc (Simproc {id = id1, ...}, Simproc {id = id2, ...}) = eq_procid (id1, id2);
   620 
   621 fun transform_simproc phi (Simproc {name, lhss, proc, id = (s, ths)}) =
   622   Simproc
   623    {name = name,
   624     lhss = map (Morphism.cterm phi) lhss,
   625     proc = Morphism.transform phi proc,
   626     id = (s, Morphism.fact phi ths)};
   627 
   628 fun make_simproc {name, lhss, proc, identifier} =
   629   Simproc {name = name, lhss = lhss, proc = proc, id = (stamp (), identifier)};
   630 
   631 fun mk_simproc name lhss proc =
   632   make_simproc {name = name, lhss = lhss, proc = fn _ => fn ss => fn ct =>
   633     proc (Proof_Context.theory_of (the_context ss)) ss (Thm.term_of ct), identifier = []};
   634 
   635 (* FIXME avoid global thy and Logic.varify_global *)
   636 fun simproc_global_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify_global);
   637 fun simproc_global thy name = simproc_global_i thy name o map (Syntax.read_term_global thy);
   638 
   639 
   640 local
   641 
   642 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   643  (trace_cterm false (fn () => "Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   644   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   645     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   646       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   647   handle Net.INSERT =>
   648     (if_visible ss warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   649 
   650 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   651   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   652     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   653       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   654   handle Net.DELETE =>
   655     (if_visible ss warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   656 
   657 fun prep_procs (Simproc {name, lhss, proc, id}) =
   658   lhss |> map (fn lhs => Proc {name = name, lhs = lhs, proc = Morphism.form proc, id = id});
   659 
   660 in
   661 
   662 fun ss addsimprocs ps = fold (fold add_proc o prep_procs) ps ss;
   663 fun ss delsimprocs ps = fold (fold del_proc o prep_procs) ps ss;
   664 
   665 end;
   666 
   667 
   668 (* mk_rews *)
   669 
   670 local
   671 
   672 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True, reorient},
   673       termless, subgoal_tac, loop_tacs, solvers) =>
   674   let
   675     val (mk', mk_cong', mk_sym', mk_eq_True', reorient') =
   676       f (mk, mk_cong, mk_sym, mk_eq_True, reorient);
   677     val mk_rews' = {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True',
   678       reorient = reorient'};
   679   in (congs, procs, mk_rews', termless, subgoal_tac, loop_tacs, solvers) end);
   680 
   681 in
   682 
   683 fun mksimps (ss as Simpset (_, {mk_rews = {mk, ...}, ...})) = mk ss;
   684 
   685 fun set_mksimps mk = map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True, reorient) =>
   686   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   687 
   688 fun set_mkcong mk_cong = map_mk_rews (fn (mk, _, mk_sym, mk_eq_True, reorient) =>
   689   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   690 
   691 fun set_mksym mk_sym = map_mk_rews (fn (mk, mk_cong, _, mk_eq_True, reorient) =>
   692   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   693 
   694 fun set_mkeqTrue mk_eq_True = map_mk_rews (fn (mk, mk_cong, mk_sym, _, reorient) =>
   695   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   696 
   697 fun set_reorient reorient = map_mk_rews (fn (mk, mk_cong, mk_sym, mk_eq_True, _) =>
   698   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   699 
   700 end;
   701 
   702 
   703 (* termless *)
   704 
   705 fun set_termless termless =
   706   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   707    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   708 
   709 
   710 (* tactics *)
   711 
   712 fun set_subgoaler subgoal_tac =
   713   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   714    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   715 
   716 fun ss setloop' tac = ss |>
   717   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   718    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   719 
   720 fun ss setloop tac = ss setloop' (K tac);
   721 
   722 fun ss addloop' (name, tac) = ss |>
   723   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   724     (congs, procs, mk_rews, termless, subgoal_tac,
   725      (if AList.defined (op =) loop_tacs name
   726       then if_visible ss warning ("Overwriting looper " ^ quote name)
   727       else (); AList.update (op =) (name, tac) loop_tacs), solvers));
   728 
   729 fun ss addloop (name, tac) = ss addloop' (name, K tac);
   730 
   731 fun ss delloop name = ss |>
   732   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   733     (congs, procs, mk_rews, termless, subgoal_tac,
   734      (if AList.defined (op =) loop_tacs name then ()
   735       else if_visible ss warning ("No such looper in simpset: " ^ quote name);
   736       AList.delete (op =) name loop_tacs), solvers));
   737 
   738 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   739   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   740     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   741 
   742 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   743   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   744     subgoal_tac, loop_tacs, (unsafe_solvers, insert eq_solver solver solvers)));
   745 
   746 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   747   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   748     subgoal_tac, loop_tacs, ([solver], solvers)));
   749 
   750 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   751   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   752     subgoal_tac, loop_tacs, (insert eq_solver solver unsafe_solvers, solvers)));
   753 
   754 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   755   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   756   subgoal_tac, loop_tacs, (solvers, solvers)));
   757 
   758 
   759 (* empty *)
   760 
   761 fun init_ss mk_rews termless subgoal_tac solvers =
   762   make_simpset ((Net.empty, [], (0, []), (0, Unsynchronized.ref false), NONE),
   763     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   764 
   765 fun clear_ss (ss as Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   766   init_ss mk_rews termless subgoal_tac solvers
   767   |> inherit_context ss;
   768 
   769 val empty_ss =
   770   init_ss
   771     {mk = fn _ => fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   772       mk_cong = K I,
   773       mk_sym = K (SOME o Drule.symmetric_fun),
   774       mk_eq_True = K (K NONE),
   775       reorient = default_reorient}
   776     Term_Ord.termless (K (K no_tac)) ([], []);
   777 
   778 
   779 (* merge *)  (*NOTE: ignores some fields of 2nd simpset*)
   780 
   781 fun merge_ss (ss1, ss2) =
   782   if pointer_eq (ss1, ss2) then ss1
   783   else
   784     let
   785       val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, depth = depth1, context = _},
   786        {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   787         loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   788       val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, depth = depth2, context = _},
   789        {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   790         loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   791 
   792       val rules' = Net.merge eq_rrule (rules1, rules2);
   793       val prems' = Thm.merge_thms (prems1, prems2);
   794       val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   795       val depth' = if #1 depth1 < #1 depth2 then depth2 else depth1;
   796       val congs' = merge (Thm.eq_thm_prop o pairself #2) (congs1, congs2);
   797       val weak' = merge (op =) (weak1, weak2);
   798       val procs' = Net.merge eq_proc (procs1, procs2);
   799       val loop_tacs' = AList.merge (op =) (K true) (loop_tacs1, loop_tacs2);
   800       val unsafe_solvers' = merge eq_solver (unsafe_solvers1, unsafe_solvers2);
   801       val solvers' = merge eq_solver (solvers1, solvers2);
   802     in
   803       make_simpset ((rules', prems', bounds', depth', NONE), ((congs', weak'), procs',
   804         mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   805     end;
   806 
   807 
   808 (* dest_ss *)
   809 
   810 fun dest_ss (Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...})) =
   811  {simps = Net.entries rules
   812     |> map (fn {name, thm, ...} => (name, thm)),
   813   procs = Net.entries procs
   814     |> map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   815     |> partition_eq (eq_snd eq_procid)
   816     |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps)),
   817   congs = #1 congs,
   818   weak_congs = #2 congs,
   819   loopers = map fst loop_tacs,
   820   unsafe_solvers = map solver_name (#1 solvers),
   821   safe_solvers = map solver_name (#2 solvers)};
   822 
   823 
   824 
   825 (** rewriting **)
   826 
   827 (*
   828   Uses conversions, see:
   829     L C Paulson, A higher-order implementation of rewriting,
   830     Science of Computer Programming 3 (1983), pages 119-149.
   831 *)
   832 
   833 fun check_conv msg ss thm thm' =
   834   let
   835     val thm'' = Thm.transitive thm thm' handle THM _ =>
   836      Thm.transitive thm (Thm.transitive
   837        (Thm.symmetric (Drule.beta_eta_conversion (Thm.lhs_of thm'))) thm')
   838   in if msg then trace_thm (fn () => "SUCCEEDED") ss thm' else (); SOME thm'' end
   839   handle THM _ =>
   840     let
   841       val _ $ _ $ prop0 = Thm.prop_of thm;
   842     in
   843       trace_thm (fn () => "Proved wrong thm (Check subgoaler?)") ss thm';
   844       trace_term false (fn () => "Should have proved:") ss prop0;
   845       NONE
   846     end;
   847 
   848 
   849 (* mk_procrule *)
   850 
   851 fun mk_procrule ss thm =
   852   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   853     if rewrite_rule_extra_vars prems lhs rhs
   854     then (cond_warn_thm "Extra vars on rhs:" ss thm; [])
   855     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   856   end;
   857 
   858 
   859 (* rewritec: conversion to apply the meta simpset to a term *)
   860 
   861 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   862   normalized terms by carrying around the rhs of the rewrite rule just
   863   applied. This is called the `skeleton'. It is decomposed in parallel
   864   with the term. Once a Var is encountered, the corresponding term is
   865   already in normal form.
   866   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   867 
   868 val skel0 = Bound 0;
   869 
   870 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   871   The latter may happen iff there are weak congruence rules for constants
   872   in the lhs.*)
   873 
   874 fun uncond_skel ((_, weak), (lhs, rhs)) =
   875   if null weak then rhs  (*optimization*)
   876   else if exists_Const (member (op =) weak o #1) lhs then skel0
   877   else rhs;
   878 
   879 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   880   Otherwise those vars may become instantiated with unnormalized terms
   881   while the premises are solved.*)
   882 
   883 fun cond_skel (args as (_, (lhs, rhs))) =
   884   if subset (op =) (Term.add_vars rhs [], Term.add_vars lhs []) then uncond_skel args
   885   else skel0;
   886 
   887 (*
   888   Rewriting -- we try in order:
   889     (1) beta reduction
   890     (2) unconditional rewrite rules
   891     (3) conditional rewrite rules
   892     (4) simplification procedures
   893 
   894   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   895 *)
   896 
   897 fun rewritec (prover, thyt, maxt) ss t =
   898   let
   899     val ctxt = the_context ss;
   900     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   901     val eta_thm = Thm.eta_conversion t;
   902     val eta_t' = Thm.rhs_of eta_thm;
   903     val eta_t = term_of eta_t';
   904     fun rew {thm, name, lhs, elhs, extra, fo, perm} =
   905       let
   906         val prop = Thm.prop_of thm;
   907         val (rthm, elhs') =
   908           if maxt = ~1 orelse not extra then (thm, elhs)
   909           else (Thm.incr_indexes (maxt + 1) thm, Thm.incr_indexes_cterm (maxt + 1) elhs);
   910         val insts =
   911           if fo then Thm.first_order_match (elhs', eta_t')
   912           else Thm.match (elhs', eta_t');
   913         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   914         val prop' = Thm.prop_of thm';
   915         val unconditional = (Logic.count_prems prop' = 0);
   916         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   917       in
   918         if perm andalso not (termless (rhs', lhs'))
   919         then (trace_named_thm (fn () => "Cannot apply permutative rewrite rule") ss (thm, name);
   920               trace_thm (fn () => "Term does not become smaller:") ss thm'; NONE)
   921         else (trace_named_thm (fn () => "Applying instance of rewrite rule") ss (thm, name);
   922            if unconditional
   923            then
   924              (trace_thm (fn () => "Rewriting:") ss thm';
   925               let
   926                 val lr = Logic.dest_equals prop;
   927                 val SOME thm'' = check_conv false ss eta_thm thm';
   928               in SOME (thm'', uncond_skel (congs, lr)) end)
   929            else
   930              (trace_thm (fn () => "Trying to rewrite:") ss thm';
   931               if simp_depth ss > Config.get ctxt simp_depth_limit
   932               then
   933                 let
   934                   val s = "simp_depth_limit exceeded - giving up";
   935                   val _ = trace false (fn () => s) ss;
   936                   val _ = if_visible ss warning s;
   937                 in NONE end
   938               else
   939               case prover ss thm' of
   940                 NONE => (trace_thm (fn () => "FAILED") ss thm'; NONE)
   941               | SOME thm2 =>
   942                   (case check_conv true ss eta_thm thm2 of
   943                      NONE => NONE |
   944                      SOME thm2' =>
   945                        let val concl = Logic.strip_imp_concl prop
   946                            val lr = Logic.dest_equals concl
   947                        in SOME (thm2', cond_skel (congs, lr)) end)))
   948       end
   949 
   950     fun rews [] = NONE
   951       | rews (rrule :: rrules) =
   952           let val opt = rew rrule handle Pattern.MATCH => NONE
   953           in case opt of NONE => rews rrules | some => some end;
   954 
   955     fun sort_rrules rrs =
   956       let
   957         fun is_simple ({thm, ...}: rrule) =
   958           (case Thm.prop_of thm of
   959             Const ("==", _) $ _ $ _ => true
   960           | _ => false);
   961         fun sort [] (re1, re2) = re1 @ re2
   962           | sort (rr :: rrs) (re1, re2) =
   963               if is_simple rr
   964               then sort rrs (rr :: re1, re2)
   965               else sort rrs (re1, rr :: re2);
   966       in sort rrs ([], []) end;
   967 
   968     fun proc_rews [] = NONE
   969       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   970           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   971             (debug_term false (fn () => "Trying procedure " ^ quote name ^ " on:") ss eta_t;
   972              case proc ss eta_t' of
   973                NONE => (debug false (fn () => "FAILED") ss; proc_rews ps)
   974              | SOME raw_thm =>
   975                  (trace_thm (fn () => "Procedure " ^ quote name ^ " produced rewrite rule:")
   976                    ss raw_thm;
   977                   (case rews (mk_procrule ss raw_thm) of
   978                     NONE => (trace_cterm true (fn () => "IGNORED result of simproc " ^ quote name ^
   979                       " -- does not match") ss t; proc_rews ps)
   980                   | some => some)))
   981           else proc_rews ps;
   982   in
   983     (case eta_t of
   984       Abs _ $ _ => SOME (Thm.transitive eta_thm (Thm.beta_conversion false eta_t'), skel0)
   985     | _ =>
   986       (case rews (sort_rrules (Net.match_term rules eta_t)) of
   987         NONE => proc_rews (Net.match_term procs eta_t)
   988       | some => some))
   989   end;
   990 
   991 
   992 (* conversion to apply a congruence rule to a term *)
   993 
   994 fun congc prover ss maxt cong t =
   995   let val rthm = Thm.incr_indexes (maxt + 1) cong;
   996       val rlhs = fst (Thm.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   997       val insts = Thm.match (rlhs, t)
   998       (* Thm.match can raise Pattern.MATCH;
   999          is handled when congc is called *)
  1000       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
  1001       val _ = trace_thm (fn () => "Applying congruence rule:") ss thm';
  1002       fun err (msg, thm) = (trace_thm (fn () => msg) ss thm; NONE)
  1003   in
  1004     (case prover thm' of
  1005       NONE => err ("Congruence proof failed.  Could not prove", thm')
  1006     | SOME thm2 =>
  1007         (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
  1008           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
  1009         | SOME thm2' =>
  1010             if op aconv (pairself term_of (Thm.dest_equals (cprop_of thm2')))
  1011             then NONE else SOME thm2'))
  1012   end;
  1013 
  1014 val (cA, (cB, cC)) =
  1015   apsnd Thm.dest_equals (Thm.dest_implies (hd (cprems_of Drule.imp_cong)));
  1016 
  1017 fun transitive1 NONE NONE = NONE
  1018   | transitive1 (SOME thm1) NONE = SOME thm1
  1019   | transitive1 NONE (SOME thm2) = SOME thm2
  1020   | transitive1 (SOME thm1) (SOME thm2) = SOME (Thm.transitive thm1 thm2)
  1021 
  1022 fun transitive2 thm = transitive1 (SOME thm);
  1023 fun transitive3 thm = transitive1 thm o SOME;
  1024 
  1025 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
  1026   let
  1027     fun botc skel ss t =
  1028           if is_Var skel then NONE
  1029           else
  1030           (case subc skel ss t of
  1031              some as SOME thm1 =>
  1032                (case rewritec (prover, thy, maxidx) ss (Thm.rhs_of thm1) of
  1033                   SOME (thm2, skel2) =>
  1034                     transitive2 (Thm.transitive thm1 thm2)
  1035                       (botc skel2 ss (Thm.rhs_of thm2))
  1036                 | NONE => some)
  1037            | NONE =>
  1038                (case rewritec (prover, thy, maxidx) ss t of
  1039                   SOME (thm2, skel2) => transitive2 thm2
  1040                     (botc skel2 ss (Thm.rhs_of thm2))
  1041                 | NONE => NONE))
  1042 
  1043     and try_botc ss t =
  1044           (case botc skel0 ss t of
  1045              SOME trec1 => trec1 | NONE => (Thm.reflexive t))
  1046 
  1047     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
  1048        (case term_of t0 of
  1049            Abs (a, T, _) =>
  1050              let
  1051                  val b = Name.bound (#1 bounds);
  1052                  val (v, t') = Thm.dest_abs (SOME b) t0;
  1053                  val b' = #1 (Term.dest_Free (Thm.term_of v));
  1054                  val _ =
  1055                    if b <> b' then
  1056                      warning ("Simplifier: renamed bound variable " ^
  1057                        quote b ^ " to " ^ quote b' ^ Position.str_of (Position.thread_data ()))
  1058                    else ();
  1059                  val ss' = add_bound ((b', T), a) ss;
  1060                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
  1061              in case botc skel' ss' t' of
  1062                   SOME thm => SOME (Thm.abstract_rule a v thm)
  1063                 | NONE => NONE
  1064              end
  1065          | t $ _ => (case t of
  1066              Const ("==>", _) $ _  => impc t0 ss
  1067            | Abs _ =>
  1068                let val thm = Thm.beta_conversion false t0
  1069                in case subc skel0 ss (Thm.rhs_of thm) of
  1070                     NONE => SOME thm
  1071                   | SOME thm' => SOME (Thm.transitive thm thm')
  1072                end
  1073            | _  =>
  1074                let fun appc () =
  1075                      let
  1076                        val (tskel, uskel) = case skel of
  1077                            tskel $ uskel => (tskel, uskel)
  1078                          | _ => (skel0, skel0);
  1079                        val (ct, cu) = Thm.dest_comb t0
  1080                      in
  1081                      (case botc tskel ss ct of
  1082                         SOME thm1 =>
  1083                           (case botc uskel ss cu of
  1084                              SOME thm2 => SOME (Thm.combination thm1 thm2)
  1085                            | NONE => SOME (Thm.combination thm1 (Thm.reflexive cu)))
  1086                       | NONE =>
  1087                           (case botc uskel ss cu of
  1088                              SOME thm1 => SOME (Thm.combination (Thm.reflexive ct) thm1)
  1089                            | NONE => NONE))
  1090                      end
  1091                    val (h, ts) = strip_comb t
  1092                in case cong_name h of
  1093                     SOME a =>
  1094                       (case AList.lookup (op =) (fst congs) a of
  1095                          NONE => appc ()
  1096                        | SOME cong =>
  1097   (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1098     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1099                           (let
  1100                              val thm = congc (prover ss) ss maxidx cong t0;
  1101                              val t = the_default t0 (Option.map Thm.rhs_of thm);
  1102                              val (cl, cr) = Thm.dest_comb t
  1103                              val dVar = Var(("", 0), dummyT)
  1104                              val skel =
  1105                                list_comb (h, replicate (length ts) dVar)
  1106                            in case botc skel ss cl of
  1107                                 NONE => thm
  1108                               | SOME thm' => transitive3 thm
  1109                                   (Thm.combination thm' (Thm.reflexive cr))
  1110                            end handle Pattern.MATCH => appc ()))
  1111                   | _ => appc ()
  1112                end)
  1113          | _ => NONE)
  1114 
  1115     and impc ct ss =
  1116       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
  1117 
  1118     and rules_of_prem ss prem =
  1119       if maxidx_of_term (term_of prem) <> ~1
  1120       then (trace_cterm true
  1121         (fn () => "Cannot add premise as rewrite rule because it contains (type) unknowns:")
  1122           ss prem; ([], NONE))
  1123       else
  1124         let val asm = Thm.assume prem
  1125         in (extract_safe_rrules (ss, asm), SOME asm) end
  1126 
  1127     and add_rrules (rrss, asms) ss =
  1128       (fold o fold) insert_rrule rrss ss |> add_prems (map_filter I asms)
  1129 
  1130     and disch r prem eq =
  1131       let
  1132         val (lhs, rhs) = Thm.dest_equals (Thm.cprop_of eq);
  1133         val eq' = Thm.implies_elim (Thm.instantiate
  1134           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1135           (Thm.implies_intr prem eq)
  1136       in if not r then eq' else
  1137         let
  1138           val (prem', concl) = Thm.dest_implies lhs;
  1139           val (prem'', _) = Thm.dest_implies rhs
  1140         in Thm.transitive (Thm.transitive
  1141           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1142              Drule.swap_prems_eq) eq')
  1143           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1144              Drule.swap_prems_eq)
  1145         end
  1146       end
  1147 
  1148     and rebuild [] _ _ _ _ eq = eq
  1149       | rebuild (prem :: prems) concl (_ :: rrss) (_ :: asms) ss eq =
  1150           let
  1151             val ss' = add_rrules (rev rrss, rev asms) ss;
  1152             val concl' =
  1153               Drule.mk_implies (prem, the_default concl (Option.map Thm.rhs_of eq));
  1154             val dprem = Option.map (disch false prem)
  1155           in
  1156             (case rewritec (prover, thy, maxidx) ss' concl' of
  1157               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1158             | SOME (eq', _) => transitive2 (fold (disch false)
  1159                   prems (the (transitive3 (dprem eq) eq')))
  1160                 (mut_impc0 (rev prems) (Thm.rhs_of eq') (rev rrss) (rev asms) ss))
  1161           end
  1162 
  1163     and mut_impc0 prems concl rrss asms ss =
  1164       let
  1165         val prems' = strip_imp_prems concl;
  1166         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1167       in
  1168         mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1169           (asms @ asms') [] [] [] [] ss ~1 ~1
  1170       end
  1171 
  1172     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1173         transitive1 (fold (fn (eq1, prem) => fn eq2 => transitive1 eq1
  1174             (Option.map (disch false prem) eq2)) (eqns ~~ prems') NONE)
  1175           (if changed > 0 then
  1176              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1177                [] [] [] [] ss ~1 changed
  1178            else rebuild prems' concl rrss' asms' ss
  1179              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1180 
  1181       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1182           prems' rrss' asms' eqns ss changed k =
  1183         case (if k = 0 then NONE else botc skel0 (add_rrules
  1184           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1185             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1186               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1187               (if k = 0 then 0 else k - 1)
  1188           | SOME eqn =>
  1189             let
  1190               val prem' = Thm.rhs_of eqn;
  1191               val tprems = map term_of prems;
  1192               val i = 1 + fold Integer.max (map (fn p =>
  1193                 find_index (fn q => q aconv p) tprems) (Thm.hyps_of eqn)) ~1;
  1194               val (rrs', asm') = rules_of_prem ss prem'
  1195             in mut_impc prems concl rrss asms (prem' :: prems')
  1196               (rrs' :: rrss') (asm' :: asms') (SOME (fold_rev (disch true)
  1197                 (take i prems)
  1198                 (Drule.imp_cong_rule eqn (Thm.reflexive (Drule.list_implies
  1199                   (drop i prems, concl))))) :: eqns)
  1200                   ss (length prems') ~1
  1201             end
  1202 
  1203      (*legacy code - only for backwards compatibility*)
  1204     and nonmut_impc ct ss =
  1205       let
  1206         val (prem, conc) = Thm.dest_implies ct;
  1207         val thm1 = if simprem then botc skel0 ss prem else NONE;
  1208         val prem1 = the_default prem (Option.map Thm.rhs_of thm1);
  1209         val ss1 =
  1210           if not useprem then ss
  1211           else add_rrules (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1212       in
  1213         (case botc skel0 ss1 conc of
  1214           NONE =>
  1215             (case thm1 of
  1216               NONE => NONE
  1217             | SOME thm1' => SOME (Drule.imp_cong_rule thm1' (Thm.reflexive conc)))
  1218         | SOME thm2 =>
  1219             let val thm2' = disch false prem1 thm2 in
  1220               (case thm1 of
  1221                 NONE => SOME thm2'
  1222               | SOME thm1' =>
  1223                  SOME (Thm.transitive (Drule.imp_cong_rule thm1' (Thm.reflexive conc)) thm2'))
  1224             end)
  1225       end
  1226 
  1227  in try_botc end;
  1228 
  1229 
  1230 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1231 
  1232 (*
  1233   Parameters:
  1234     mode = (simplify A,
  1235             use A in simplifying B,
  1236             use prems of B (if B is again a meta-impl.) to simplify A)
  1237            when simplifying A ==> B
  1238     prover: how to solve premises in conditional rewrites and congruences
  1239 *)
  1240 
  1241 val debug_bounds = Unsynchronized.ref false;
  1242 
  1243 fun check_bounds ss ct =
  1244   if ! debug_bounds then
  1245     let
  1246       val Simpset ({bounds = (_, bounds), ...}, _) = ss;
  1247       val bs = fold_aterms (fn Free (x, _) =>
  1248           if Name.is_bound x andalso not (AList.defined eq_bound bounds x)
  1249           then insert (op =) x else I
  1250         | _ => I) (term_of ct) [];
  1251     in
  1252       if null bs then ()
  1253       else print_term_global ss true ("Simplifier: term contains loose bounds: " ^ commas_quote bs)
  1254         (Thm.theory_of_cterm ct) (Thm.term_of ct)
  1255     end
  1256   else ();
  1257 
  1258 fun rewrite_cterm mode prover raw_ss raw_ct =
  1259   let
  1260     val thy = Thm.theory_of_cterm raw_ct;
  1261     val ct = Thm.adjust_maxidx_cterm ~1 raw_ct;
  1262     val {maxidx, ...} = Thm.rep_cterm ct;
  1263     val ss = inc_simp_depth (activate_context thy raw_ss);
  1264     val depth = simp_depth ss;
  1265     val _ =
  1266       if depth mod 20 = 0 then
  1267         if_visible ss warning ("Simplification depth " ^ string_of_int depth)
  1268       else ();
  1269     val _ = trace_cterm false (fn () => "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:") ss ct;
  1270     val _ = check_bounds ss ct;
  1271   in bottomc (mode, Option.map Drule.flexflex_unique oo prover, thy, maxidx) ss ct end;
  1272 
  1273 val simple_prover =
  1274   SINGLE o (fn ss => ALLGOALS (resolve_tac (prems_of ss)));
  1275 
  1276 fun rewrite _ [] ct = Thm.reflexive ct
  1277   | rewrite full thms ct = rewrite_cterm (full, false, false) simple_prover
  1278       (global_context (Thm.theory_of_cterm ct) empty_ss addsimps thms) ct;
  1279 
  1280 fun simplify full thms = Conv.fconv_rule (rewrite full thms);
  1281 val rewrite_rule = simplify true;
  1282 
  1283 (*simple term rewriting -- no proof*)
  1284 fun rewrite_term thy rules procs =
  1285   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1286 
  1287 fun rewrite_thm mode prover ss = Conv.fconv_rule (rewrite_cterm mode prover ss);
  1288 
  1289 (*Rewrite the subgoals of a proof state (represented by a theorem)*)
  1290 fun rewrite_goals_rule thms th =
  1291   Conv.fconv_rule (Conv.prems_conv ~1 (rewrite_cterm (true, true, true) simple_prover
  1292     (global_context (Thm.theory_of_thm th) empty_ss addsimps thms))) th;
  1293 
  1294 
  1295 (** meta-rewriting tactics **)
  1296 
  1297 (*Rewrite all subgoals*)
  1298 fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
  1299 
  1300 (*Rewrite one subgoal*)
  1301 fun generic_rewrite_goal_tac mode prover_tac ss i thm =
  1302   if 0 < i andalso i <= Thm.nprems_of thm then
  1303     Seq.single (Conv.gconv_rule (rewrite_cterm mode (SINGLE o prover_tac) ss) i thm)
  1304   else Seq.empty;
  1305 
  1306 fun rewrite_goal_tac rews =
  1307   let val ss = empty_ss addsimps rews in
  1308     fn i => fn st => generic_rewrite_goal_tac (true, false, false) (K no_tac)
  1309       (global_context (Thm.theory_of_thm st) ss) i st
  1310   end;
  1311 
  1312 (*Prunes all redundant parameters from the proof state by rewriting.*)
  1313 val prune_params_tac = rewrite_goals_tac [Drule.triv_forall_equality];
  1314 
  1315 
  1316 (* for folding definitions, handling critical pairs *)
  1317 
  1318 (*The depth of nesting in a term*)
  1319 fun term_depth (Abs (_, _, t)) = 1 + term_depth t
  1320   | term_depth (f $ t) = 1 + Int.max (term_depth f, term_depth t)
  1321   | term_depth _ = 0;
  1322 
  1323 val lhs_of_thm = #1 o Logic.dest_equals o prop_of;
  1324 
  1325 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
  1326   Returns longest lhs first to avoid folding its subexpressions.*)
  1327 fun sort_lhs_depths defs =
  1328   let val keylist = AList.make (term_depth o lhs_of_thm) defs
  1329       val keys = sort_distinct (rev_order o int_ord) (map #2 keylist)
  1330   in map (AList.find (op =) keylist) keys end;
  1331 
  1332 val rev_defs = sort_lhs_depths o map Thm.symmetric;
  1333 
  1334 fun fold_rule defs = fold rewrite_rule (rev_defs defs);
  1335 fun fold_goals_tac defs = EVERY (map rewrite_goals_tac (rev_defs defs));
  1336 
  1337 
  1338 (* HHF normal form: !! before ==>, outermost !! generalized *)
  1339 
  1340 local
  1341 
  1342 fun gen_norm_hhf ss th =
  1343   (if Drule.is_norm_hhf (Thm.prop_of th) then th
  1344    else Conv.fconv_rule
  1345     (rewrite_cterm (true, false, false) (K (K NONE)) (global_context (Thm.theory_of_thm th) ss)) th)
  1346   |> Thm.adjust_maxidx_thm ~1
  1347   |> Drule.gen_all;
  1348 
  1349 val hhf_ss = empty_ss addsimps Drule.norm_hhf_eqs;
  1350 
  1351 in
  1352 
  1353 val norm_hhf = gen_norm_hhf hhf_ss;
  1354 val norm_hhf_protect = gen_norm_hhf (hhf_ss |> add_eqcong Drule.protect_cong);
  1355 
  1356 end;
  1357 
  1358 end;
  1359 
  1360 structure Basic_Meta_Simplifier: BASIC_RAW_SIMPLIFIER = Raw_Simplifier;
  1361 open Basic_Meta_Simplifier;