src/HOL/Relation.thy
author haftmann
Sat Dec 17 15:22:00 2016 +0100 (2016-12-17)
changeset 64584 142ac30b68fe
parent 63612 7195acc2fe93
child 64632 9df24b8b6c0a
permissions -rw-r--r--
added lemmas demanded by FIXMEs
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer, TU Muenchen
     4 *)
     5 
     6 section \<open>Relations -- as sets of pairs, and binary predicates\<close>
     7 
     8 theory Relation
     9   imports Finite_Set
    10 begin
    11 
    12 text \<open>A preliminary: classical rules for reasoning on predicates\<close>
    13 
    14 declare predicate1I [Pure.intro!, intro!]
    15 declare predicate1D [Pure.dest, dest]
    16 declare predicate2I [Pure.intro!, intro!]
    17 declare predicate2D [Pure.dest, dest]
    18 declare bot1E [elim!]
    19 declare bot2E [elim!]
    20 declare top1I [intro!]
    21 declare top2I [intro!]
    22 declare inf1I [intro!]
    23 declare inf2I [intro!]
    24 declare inf1E [elim!]
    25 declare inf2E [elim!]
    26 declare sup1I1 [intro?]
    27 declare sup2I1 [intro?]
    28 declare sup1I2 [intro?]
    29 declare sup2I2 [intro?]
    30 declare sup1E [elim!]
    31 declare sup2E [elim!]
    32 declare sup1CI [intro!]
    33 declare sup2CI [intro!]
    34 declare Inf1_I [intro!]
    35 declare INF1_I [intro!]
    36 declare Inf2_I [intro!]
    37 declare INF2_I [intro!]
    38 declare Inf1_D [elim]
    39 declare INF1_D [elim]
    40 declare Inf2_D [elim]
    41 declare INF2_D [elim]
    42 declare Inf1_E [elim]
    43 declare INF1_E [elim]
    44 declare Inf2_E [elim]
    45 declare INF2_E [elim]
    46 declare Sup1_I [intro]
    47 declare SUP1_I [intro]
    48 declare Sup2_I [intro]
    49 declare SUP2_I [intro]
    50 declare Sup1_E [elim!]
    51 declare SUP1_E [elim!]
    52 declare Sup2_E [elim!]
    53 declare SUP2_E [elim!]
    54 
    55 
    56 subsection \<open>Fundamental\<close>
    57 
    58 subsubsection \<open>Relations as sets of pairs\<close>
    59 
    60 type_synonym 'a rel = "('a \<times> 'a) set"
    61 
    62 lemma subrelI: "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    63   \<comment> \<open>Version of @{thm [source] subsetI} for binary relations\<close>
    64   by auto
    65 
    66 lemma lfp_induct2:
    67   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    68     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    69   \<comment> \<open>Version of @{thm [source] lfp_induct} for binary relations\<close>
    70   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    71 
    72 
    73 subsubsection \<open>Conversions between set and predicate relations\<close>
    74 
    75 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    79   by (simp add: set_eq_iff fun_eq_iff)
    80 
    81 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    85   by (simp add: subset_iff le_fun_def)
    86 
    87 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    97   by (auto simp add: fun_eq_iff)
    98 
    99 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   103   by (simp add: inf_fun_def)
   104 
   105 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   109   by (simp add: sup_fun_def)
   110 
   111 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   142   by (simp add: fun_eq_iff)
   143 
   144 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   145   by (simp add: fun_eq_iff)
   146 
   147 
   148 subsection \<open>Properties of relations\<close>
   149 
   150 subsubsection \<open>Reflexivity\<close>
   151 
   152 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   153   where "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   154 
   155 abbreviation refl :: "'a rel \<Rightarrow> bool" \<comment> \<open>reflexivity over a type\<close>
   156   where "refl \<equiv> refl_on UNIV"
   157 
   158 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   159   where "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   160 
   161 lemma reflp_refl_eq [pred_set_conv]: "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r"
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI [intro?]: "r \<subseteq> A \<times> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> (x, x) \<in> r) \<Longrightarrow> refl_on A r"
   165   unfolding refl_on_def by (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r \<Longrightarrow> a \<in> A \<Longrightarrow> (a, a) \<in> r"
   168   unfolding refl_on_def by blast
   169 
   170 lemma refl_onD1: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> x \<in> A"
   171   unfolding refl_on_def by blast
   172 
   173 lemma refl_onD2: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> y \<in> A"
   174   unfolding refl_on_def by blast
   175 
   176 lemma reflpI [intro?]: "(\<And>x. r x x) \<Longrightarrow> reflp r"
   177   by (auto intro: refl_onI simp add: reflp_def)
   178 
   179 lemma reflpE:
   180   assumes "reflp r"
   181   obtains "r x x"
   182   using assms by (auto dest: refl_onD simp add: reflp_def)
   183 
   184 lemma reflpD [dest?]:
   185   assumes "reflp r"
   186   shows "r x x"
   187   using assms by (auto elim: reflpE)
   188 
   189 lemma refl_on_Int: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<inter> B) (r \<inter> s)"
   190   unfolding refl_on_def by blast
   191 
   192 lemma reflp_inf: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   193   by (auto intro: reflpI elim: reflpE)
   194 
   195 lemma refl_on_Un: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<union> B) (r \<union> s)"
   196   unfolding refl_on_def by blast
   197 
   198 lemma reflp_sup: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   199   by (auto intro: reflpI elim: reflpE)
   200 
   201 lemma refl_on_INTER: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (INTER S A) (INTER S r)"
   202   unfolding refl_on_def by fast
   203 
   204 lemma refl_on_UNION: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   205   unfolding refl_on_def by blast
   206 
   207 lemma refl_on_empty [simp]: "refl_on {} {}"
   208   by (simp add: refl_on_def)
   209 
   210 lemma refl_on_singleton [simp]: "refl_on {x} {(x, x)}"
   211 by (blast intro: refl_onI)
   212 
   213 lemma refl_on_def' [nitpick_unfold, code]:
   214   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   215   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   216 
   217 lemma reflp_equality [simp]: "reflp op ="
   218   by (simp add: reflp_def)
   219 
   220 lemma reflp_mono: "reflp R \<Longrightarrow> (\<And>x y. R x y \<longrightarrow> Q x y) \<Longrightarrow> reflp Q"
   221   by (auto intro: reflpI dest: reflpD)
   222 
   223 
   224 subsubsection \<open>Irreflexivity\<close>
   225 
   226 definition irrefl :: "'a rel \<Rightarrow> bool"
   227   where "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   228 
   229 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   230   where "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   231 
   232 lemma irreflp_irrefl_eq [pred_set_conv]: "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R"
   233   by (simp add: irrefl_def irreflp_def)
   234 
   235 lemma irreflI [intro?]: "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   236   by (simp add: irrefl_def)
   237 
   238 lemma irreflpI [intro?]: "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   239   by (fact irreflI [to_pred])
   240 
   241 lemma irrefl_distinct [code]: "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   242   by (auto simp add: irrefl_def)
   243 
   244 
   245 subsubsection \<open>Asymmetry\<close>
   246 
   247 inductive asym :: "'a rel \<Rightarrow> bool"
   248   where asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   249 
   250 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   251   where asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   252 
   253 lemma asymp_asym_eq [pred_set_conv]: "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R"
   254   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   255 
   256 
   257 subsubsection \<open>Symmetry\<close>
   258 
   259 definition sym :: "'a rel \<Rightarrow> bool"
   260   where "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   261 
   262 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   263   where "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   264 
   265 lemma symp_sym_eq [pred_set_conv]: "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r"
   266   by (simp add: sym_def symp_def)
   267 
   268 lemma symI [intro?]: "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   269   by (unfold sym_def) iprover
   270 
   271 lemma sympI [intro?]: "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   272   by (fact symI [to_pred])
   273 
   274 lemma symE:
   275   assumes "sym r" and "(b, a) \<in> r"
   276   obtains "(a, b) \<in> r"
   277   using assms by (simp add: sym_def)
   278 
   279 lemma sympE:
   280   assumes "symp r" and "r b a"
   281   obtains "r a b"
   282   using assms by (rule symE [to_pred])
   283 
   284 lemma symD [dest?]:
   285   assumes "sym r" and "(b, a) \<in> r"
   286   shows "(a, b) \<in> r"
   287   using assms by (rule symE)
   288 
   289 lemma sympD [dest?]:
   290   assumes "symp r" and "r b a"
   291   shows "r a b"
   292   using assms by (rule symD [to_pred])
   293 
   294 lemma sym_Int: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   295   by (fast intro: symI elim: symE)
   296 
   297 lemma symp_inf: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   298   by (fact sym_Int [to_pred])
   299 
   300 lemma sym_Un: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   301   by (fast intro: symI elim: symE)
   302 
   303 lemma symp_sup: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   304   by (fact sym_Un [to_pred])
   305 
   306 lemma sym_INTER: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   307   by (fast intro: symI elim: symE)
   308 
   309 lemma symp_INF: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   310   by (fact sym_INTER [to_pred])
   311 
   312 lemma sym_UNION: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   313   by (fast intro: symI elim: symE)
   314 
   315 lemma symp_SUP: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   316   by (fact sym_UNION [to_pred])
   317 
   318 
   319 subsubsection \<open>Antisymmetry\<close>
   320 
   321 definition antisym :: "'a rel \<Rightarrow> bool"
   322   where "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   323 
   324 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   325   where "antisymP r \<equiv> antisym {(x, y). r x y}" (* FIXME proper logical operation *)
   326 
   327 lemma antisymI [intro?]: "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (y, x) \<in> r \<Longrightarrow> x = y) \<Longrightarrow> antisym r"
   328   unfolding antisym_def by iprover
   329 
   330 lemma antisymD [dest?]: "antisym r \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r \<Longrightarrow> a = b"
   331   unfolding antisym_def by iprover
   332 
   333 lemma antisym_subset: "r \<subseteq> s \<Longrightarrow> antisym s \<Longrightarrow> antisym r"
   334   unfolding antisym_def by blast
   335 
   336 lemma antisym_empty [simp]: "antisym {}"
   337   unfolding antisym_def by blast
   338 
   339 lemma antisymP_equality [simp]: "antisymP op ="
   340   by (auto intro: antisymI)
   341 
   342 lemma antisym_singleton [simp]: "antisym {x}"
   343 by (blast intro: antisymI)
   344 
   345 
   346 subsubsection \<open>Transitivity\<close>
   347 
   348 definition trans :: "'a rel \<Rightarrow> bool"
   349   where "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   350 
   351 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   352   where "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   353 
   354 lemma transp_trans_eq [pred_set_conv]: "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r"
   355   by (simp add: trans_def transp_def)
   356 
   357 lemma transI [intro?]: "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   358   by (unfold trans_def) iprover
   359 
   360 lemma transpI [intro?]: "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   361   by (fact transI [to_pred])
   362 
   363 lemma transE:
   364   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   365   obtains "(x, z) \<in> r"
   366   using assms by (unfold trans_def) iprover
   367 
   368 lemma transpE:
   369   assumes "transp r" and "r x y" and "r y z"
   370   obtains "r x z"
   371   using assms by (rule transE [to_pred])
   372 
   373 lemma transD [dest?]:
   374   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   375   shows "(x, z) \<in> r"
   376   using assms by (rule transE)
   377 
   378 lemma transpD [dest?]:
   379   assumes "transp r" and "r x y" and "r y z"
   380   shows "r x z"
   381   using assms by (rule transD [to_pred])
   382 
   383 lemma trans_Int: "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   384   by (fast intro: transI elim: transE)
   385 
   386 lemma transp_inf: "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   387   by (fact trans_Int [to_pred])
   388 
   389 lemma trans_INTER: "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   390   by (fast intro: transI elim: transD)
   391 
   392 lemma transp_INF: "\<forall>x\<in>S. transp (r x) \<Longrightarrow> transp (INFIMUM S r)"
   393   by (fact trans_INTER [to_pred])
   394     
   395 lemma trans_join [code]: "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   396   by (auto simp add: trans_def)
   397 
   398 lemma transp_trans: "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   399   by (simp add: trans_def transp_def)
   400 
   401 lemma transp_equality [simp]: "transp op ="
   402   by (auto intro: transpI)
   403 
   404 lemma trans_empty [simp]: "trans {}"
   405   by (blast intro: transI)
   406 
   407 lemma transp_empty [simp]: "transp (\<lambda>x y. False)"
   408   using trans_empty[to_pred] by (simp add: bot_fun_def)
   409 
   410 lemma trans_singleton [simp]: "trans {(a, a)}"
   411   by (blast intro: transI)
   412 
   413 lemma transp_singleton [simp]: "transp (\<lambda>x y. x = a \<and> y = a)"
   414   by (simp add: transp_def)
   415 
   416 
   417 subsubsection \<open>Totality\<close>
   418 
   419 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   420   where "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   421 
   422 lemma total_onI [intro?]:
   423   "(\<And>x y. \<lbrakk>x \<in> A; y \<in> A; x \<noteq> y\<rbrakk> \<Longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r) \<Longrightarrow> total_on A r"
   424   unfolding total_on_def by blast
   425 
   426 abbreviation "total \<equiv> total_on UNIV"
   427 
   428 lemma total_on_empty [simp]: "total_on {} r"
   429   by (simp add: total_on_def)
   430 
   431 lemma total_on_singleton [simp]: "total_on {x} {(x, x)}"
   432   unfolding total_on_def by blast
   433 
   434 
   435 subsubsection \<open>Single valued relations\<close>
   436 
   437 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   438   where "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   439 
   440 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   441   where "single_valuedP r \<equiv> single_valued {(x, y). r x y}" (* FIXME proper logical operation *)
   442 
   443 lemma single_valuedI: "\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z) \<Longrightarrow> single_valued r"
   444   unfolding single_valued_def .
   445 
   446 lemma single_valuedD: "single_valued r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (x, z) \<in> r \<Longrightarrow> y = z"
   447   by (simp add: single_valued_def)
   448 
   449 lemma single_valued_empty[simp]: "single_valued {}"
   450   by (simp add: single_valued_def)
   451 
   452 lemma single_valued_subset: "r \<subseteq> s \<Longrightarrow> single_valued s \<Longrightarrow> single_valued r"
   453   unfolding single_valued_def by blast
   454 
   455 
   456 subsection \<open>Relation operations\<close>
   457 
   458 subsubsection \<open>The identity relation\<close>
   459 
   460 definition Id :: "'a rel"
   461   where [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   462 
   463 lemma IdI [intro]: "(a, a) \<in> Id"
   464   by (simp add: Id_def)
   465 
   466 lemma IdE [elim!]: "p \<in> Id \<Longrightarrow> (\<And>x. p = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   467   unfolding Id_def by (iprover elim: CollectE)
   468 
   469 lemma pair_in_Id_conv [iff]: "(a, b) \<in> Id \<longleftrightarrow> a = b"
   470   unfolding Id_def by blast
   471 
   472 lemma refl_Id: "refl Id"
   473   by (simp add: refl_on_def)
   474 
   475 lemma antisym_Id: "antisym Id"
   476   \<comment> \<open>A strange result, since \<open>Id\<close> is also symmetric.\<close>
   477   by (simp add: antisym_def)
   478 
   479 lemma sym_Id: "sym Id"
   480   by (simp add: sym_def)
   481 
   482 lemma trans_Id: "trans Id"
   483   by (simp add: trans_def)
   484 
   485 lemma single_valued_Id [simp]: "single_valued Id"
   486   by (unfold single_valued_def) blast
   487 
   488 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   489   by (simp add: irrefl_def)
   490 
   491 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   492   unfolding antisym_def trans_def by blast
   493 
   494 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   495   by (simp add: total_on_def)
   496 
   497 lemma Id_fstsnd_eq: "Id = {x. fst x = snd x}"
   498   by force
   499 
   500 
   501 subsubsection \<open>Diagonal: identity over a set\<close>
   502 
   503 definition Id_on :: "'a set \<Rightarrow> 'a rel"
   504   where "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   505 
   506 lemma Id_on_empty [simp]: "Id_on {} = {}"
   507   by (simp add: Id_on_def)
   508 
   509 lemma Id_on_eqI: "a = b \<Longrightarrow> a \<in> A \<Longrightarrow> (a, b) \<in> Id_on A"
   510   by (simp add: Id_on_def)
   511 
   512 lemma Id_onI [intro!]: "a \<in> A \<Longrightarrow> (a, a) \<in> Id_on A"
   513   by (rule Id_on_eqI) (rule refl)
   514 
   515 lemma Id_onE [elim!]: "c \<in> Id_on A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> c = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   516   \<comment> \<open>The general elimination rule.\<close>
   517   unfolding Id_on_def by (iprover elim!: UN_E singletonE)
   518 
   519 lemma Id_on_iff: "(x, y) \<in> Id_on A \<longleftrightarrow> x = y \<and> x \<in> A"
   520   by blast
   521 
   522 lemma Id_on_def' [nitpick_unfold]: "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   523   by auto
   524 
   525 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   526   by blast
   527 
   528 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   529   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   530 
   531 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   532   unfolding antisym_def by blast
   533 
   534 lemma sym_Id_on [simp]: "sym (Id_on A)"
   535   by (rule symI) clarify
   536 
   537 lemma trans_Id_on [simp]: "trans (Id_on A)"
   538   by (fast intro: transI elim: transD)
   539 
   540 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   541   unfolding single_valued_def by blast
   542 
   543 
   544 subsubsection \<open>Composition\<close>
   545 
   546 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set"  (infixr "O" 75)
   547   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   548   where relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   549 
   550 notation relcompp (infixr "OO" 75)
   551 
   552 lemmas relcomppI = relcompp.intros
   553 
   554 text \<open>
   555   For historic reasons, the elimination rules are not wholly corresponding.
   556   Feel free to consolidate this.
   557 \<close>
   558 
   559 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   560 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   561 
   562 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   563   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   564   apply (cases xz)
   565   apply simp
   566   apply (erule relcompEpair)
   567   apply iprover
   568   done
   569 
   570 lemma R_O_Id [simp]: "R O Id = R"
   571   by fast
   572 
   573 lemma Id_O_R [simp]: "Id O R = R"
   574   by fast
   575 
   576 lemma relcomp_empty1 [simp]: "{} O R = {}"
   577   by blast
   578 
   579 lemma relcompp_bot1 [simp]: "\<bottom> OO R = \<bottom>"
   580   by (fact relcomp_empty1 [to_pred])
   581 
   582 lemma relcomp_empty2 [simp]: "R O {} = {}"
   583   by blast
   584 
   585 lemma relcompp_bot2 [simp]: "R OO \<bottom> = \<bottom>"
   586   by (fact relcomp_empty2 [to_pred])
   587 
   588 lemma O_assoc: "(R O S) O T = R O (S O T)"
   589   by blast
   590 
   591 lemma relcompp_assoc: "(r OO s) OO t = r OO (s OO t)"
   592   by (fact O_assoc [to_pred])
   593 
   594 lemma trans_O_subset: "trans r \<Longrightarrow> r O r \<subseteq> r"
   595   by (unfold trans_def) blast
   596 
   597 lemma transp_relcompp_less_eq: "transp r \<Longrightarrow> r OO r \<le> r "
   598   by (fact trans_O_subset [to_pred])
   599 
   600 lemma relcomp_mono: "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   601   by blast
   602 
   603 lemma relcompp_mono: "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   604   by (fact relcomp_mono [to_pred])
   605 
   606 lemma relcomp_subset_Sigma: "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   607   by blast
   608 
   609 lemma relcomp_distrib [simp]: "R O (S \<union> T) = (R O S) \<union> (R O T)"
   610   by auto
   611 
   612 lemma relcompp_distrib [simp]: "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   613   by (fact relcomp_distrib [to_pred])
   614 
   615 lemma relcomp_distrib2 [simp]: "(S \<union> T) O R = (S O R) \<union> (T O R)"
   616   by auto
   617 
   618 lemma relcompp_distrib2 [simp]: "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   619   by (fact relcomp_distrib2 [to_pred])
   620 
   621 lemma relcomp_UNION_distrib: "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   622   by auto
   623 
   624 lemma relcompp_SUP_distrib: "s OO SUPREMUM I r = (\<Squnion>i\<in>I. s OO r i)"
   625   by (fact relcomp_UNION_distrib [to_pred])
   626     
   627 lemma relcomp_UNION_distrib2: "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   628   by auto
   629 
   630 lemma relcompp_SUP_distrib2: "SUPREMUM I r OO s = (\<Squnion>i\<in>I. r i OO s)"
   631   by (fact relcomp_UNION_distrib2 [to_pred])
   632     
   633 lemma single_valued_relcomp: "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   634   unfolding single_valued_def by blast
   635 
   636 lemma relcomp_unfold: "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   637   by (auto simp add: set_eq_iff)
   638 
   639 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   640   unfolding relcomp_unfold [to_pred] ..
   641 
   642 lemma eq_OO: "op = OO R = R"
   643   by blast
   644 
   645 lemma OO_eq: "R OO op = = R"
   646   by blast
   647 
   648 
   649 subsubsection \<open>Converse\<close>
   650 
   651 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set"  ("(_\<inverse>)" [1000] 999)
   652   for r :: "('a \<times> 'b) set"
   653   where "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   654 
   655 notation conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   656 
   657 notation (ASCII)
   658   converse  ("(_^-1)" [1000] 999) and
   659   conversep ("(_^--1)" [1000] 1000)
   660 
   661 lemma converseI [sym]: "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   662   by (fact converse.intros)
   663 
   664 lemma conversepI (* CANDIDATE [sym] *): "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   665   by (fact conversep.intros)
   666 
   667 lemma converseD [sym]: "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   668   by (erule converse.cases) iprover
   669 
   670 lemma conversepD (* CANDIDATE [sym] *): "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   671   by (fact converseD [to_pred])
   672 
   673 lemma converseE [elim!]: "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   674   \<comment> \<open>More general than \<open>converseD\<close>, as it ``splits'' the member of the relation.\<close>
   675   apply (cases yx)
   676   apply simp
   677   apply (erule converse.cases)
   678   apply iprover
   679   done
   680 
   681 lemmas conversepE [elim!] = conversep.cases
   682 
   683 lemma converse_iff [iff]: "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   684   by (auto intro: converseI)
   685 
   686 lemma conversep_iff [iff]: "r\<inverse>\<inverse> a b = r b a"
   687   by (fact converse_iff [to_pred])
   688 
   689 lemma converse_converse [simp]: "(r\<inverse>)\<inverse> = r"
   690   by (simp add: set_eq_iff)
   691 
   692 lemma conversep_conversep [simp]: "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   693   by (fact converse_converse [to_pred])
   694 
   695 lemma converse_empty[simp]: "{}\<inverse> = {}"
   696   by auto
   697 
   698 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   699   by auto
   700 
   701 lemma converse_relcomp: "(r O s)\<inverse> = s\<inverse> O r\<inverse>"
   702   by blast
   703 
   704 lemma converse_relcompp: "(r OO s)\<inverse>\<inverse> = s\<inverse>\<inverse> OO r\<inverse>\<inverse>"
   705   by (iprover intro: order_antisym conversepI relcomppI elim: relcomppE dest: conversepD)
   706 
   707 lemma converse_Int: "(r \<inter> s)\<inverse> = r\<inverse> \<inter> s\<inverse>"
   708   by blast
   709 
   710 lemma converse_meet: "(r \<sqinter> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<sqinter> s\<inverse>\<inverse>"
   711   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   712 
   713 lemma converse_Un: "(r \<union> s)\<inverse> = r\<inverse> \<union> s\<inverse>"
   714   by blast
   715 
   716 lemma converse_join: "(r \<squnion> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<squnion> s\<inverse>\<inverse>"
   717   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   718 
   719 lemma converse_INTER: "(INTER S r)\<inverse> = (INT x:S. (r x)\<inverse>)"
   720   by fast
   721 
   722 lemma converse_UNION: "(UNION S r)\<inverse> = (UN x:S. (r x)\<inverse>)"
   723   by blast
   724 
   725 lemma converse_mono[simp]: "r\<inverse> \<subseteq> s \<inverse> \<longleftrightarrow> r \<subseteq> s"
   726   by auto
   727 
   728 lemma conversep_mono[simp]: "r\<inverse>\<inverse> \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<le> s"
   729   by (fact converse_mono[to_pred])
   730 
   731 lemma converse_inject[simp]: "r\<inverse> = s \<inverse> \<longleftrightarrow> r = s"
   732   by auto
   733 
   734 lemma conversep_inject[simp]: "r\<inverse>\<inverse> = s \<inverse>\<inverse> \<longleftrightarrow> r = s"
   735   by (fact converse_inject[to_pred])
   736 
   737 lemma converse_subset_swap: "r \<subseteq> s \<inverse> \<longleftrightarrow> r \<inverse> \<subseteq> s"
   738   by auto
   739 
   740 lemma conversep_le_swap: "r \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<inverse>\<inverse> \<le> s"
   741   by (fact converse_subset_swap[to_pred])
   742 
   743 lemma converse_Id [simp]: "Id\<inverse> = Id"
   744   by blast
   745 
   746 lemma converse_Id_on [simp]: "(Id_on A)\<inverse> = Id_on A"
   747   by blast
   748 
   749 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   750   by (auto simp: refl_on_def)
   751 
   752 lemma sym_converse [simp]: "sym (converse r) = sym r"
   753   unfolding sym_def by blast
   754 
   755 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   756   unfolding antisym_def by blast
   757 
   758 lemma trans_converse [simp]: "trans (converse r) = trans r"
   759   unfolding trans_def by blast
   760 
   761 lemma sym_conv_converse_eq: "sym r \<longleftrightarrow> r\<inverse> = r"
   762   unfolding sym_def by fast
   763 
   764 lemma sym_Un_converse: "sym (r \<union> r\<inverse>)"
   765   unfolding sym_def by blast
   766 
   767 lemma sym_Int_converse: "sym (r \<inter> r\<inverse>)"
   768   unfolding sym_def by blast
   769 
   770 lemma total_on_converse [simp]: "total_on A (r\<inverse>) = total_on A r"
   771   by (auto simp: total_on_def)
   772 
   773 lemma finite_converse [iff]: "finite (r\<inverse>) = finite r"
   774   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   775   by (auto elim: finite_imageD simp: inj_on_def)
   776 
   777 lemma conversep_noteq [simp]: "(op \<noteq>)\<inverse>\<inverse> = op \<noteq>"
   778   by (auto simp add: fun_eq_iff)
   779 
   780 lemma conversep_eq [simp]: "(op =)\<inverse>\<inverse> = op ="
   781   by (auto simp add: fun_eq_iff)
   782 
   783 lemma converse_unfold [code]: "r\<inverse> = {(y, x). (x, y) \<in> r}"
   784   by (simp add: set_eq_iff)
   785 
   786 
   787 subsubsection \<open>Domain, range and field\<close>
   788 
   789 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set" for r :: "('a \<times> 'b) set"
   790   where DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   791 
   792 lemmas DomainPI = Domainp.DomainI
   793 
   794 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   795 inductive_cases DomainpE [elim!]: "Domainp r a"
   796 
   797 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set" for r :: "('a \<times> 'b) set"
   798   where RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   799 
   800 lemmas RangePI = Rangep.RangeI
   801 
   802 inductive_cases RangeE [elim!]: "b \<in> Range r"
   803 inductive_cases RangepE [elim!]: "Rangep r b"
   804 
   805 definition Field :: "'a rel \<Rightarrow> 'a set"
   806   where "Field r = Domain r \<union> Range r"
   807 
   808 lemma FieldI1: "(i, j) \<in> R \<Longrightarrow> i \<in> Field R"
   809   unfolding Field_def by blast
   810 
   811 lemma FieldI2: "(i, j) \<in> R \<Longrightarrow> j \<in> Field R"
   812   unfolding Field_def by auto
   813 
   814 lemma Domain_fst [code]: "Domain r = fst ` r"
   815   by force
   816 
   817 lemma Range_snd [code]: "Range r = snd ` r"
   818   by force
   819 
   820 lemma fst_eq_Domain: "fst ` R = Domain R"
   821   by force
   822 
   823 lemma snd_eq_Range: "snd ` R = Range R"
   824   by force
   825 
   826 lemma range_fst [simp]: "range fst = UNIV"
   827   by (auto simp: fst_eq_Domain)
   828 
   829 lemma range_snd [simp]: "range snd = UNIV"
   830   by (auto simp: snd_eq_Range)
   831 
   832 lemma Domain_empty [simp]: "Domain {} = {}"
   833   by auto
   834 
   835 lemma Range_empty [simp]: "Range {} = {}"
   836   by auto
   837 
   838 lemma Field_empty [simp]: "Field {} = {}"
   839   by (simp add: Field_def)
   840 
   841 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   842   by auto
   843 
   844 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   845   by auto
   846 
   847 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   848   by blast
   849 
   850 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   851   by blast
   852 
   853 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   854   by (auto simp add: Field_def)
   855 
   856 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   857   by blast
   858 
   859 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   860   by blast
   861 
   862 lemma Domain_Id [simp]: "Domain Id = UNIV"
   863   by blast
   864 
   865 lemma Range_Id [simp]: "Range Id = UNIV"
   866   by blast
   867 
   868 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   869   by blast
   870 
   871 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   872   by blast
   873 
   874 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   875   by blast
   876 
   877 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   878   by blast
   879 
   880 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   881   by (auto simp: Field_def)
   882 
   883 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   884   by blast
   885 
   886 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   887   by blast
   888 
   889 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   890   by blast
   891 
   892 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   893   by blast
   894 
   895 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   896   by blast
   897 
   898 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   899   by blast
   900 
   901 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   902   by (auto simp: Field_def)
   903 
   904 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   905   by auto
   906 
   907 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   908   by blast
   909 
   910 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   911   by (auto simp: Field_def)
   912 
   913 lemma Domain_Collect_case_prod [simp]: "Domain {(x, y). P x y} = {x. \<exists>y. P x y}"
   914   by auto
   915 
   916 lemma Range_Collect_case_prod [simp]: "Range {(x, y). P x y} = {y. \<exists>x. P x y}"
   917   by auto
   918 
   919 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   920   by (induct set: finite) auto
   921 
   922 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   923   by (induct set: finite) auto
   924 
   925 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   926   by (simp add: Field_def finite_Domain finite_Range)
   927 
   928 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   929   by blast
   930 
   931 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   932   by blast
   933 
   934 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   935   by (auto simp: Field_def Domain_def Range_def)
   936 
   937 lemma Domain_unfold: "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   938   by blast
   939 
   940 lemma Field_square [simp]: "Field (x \<times> x) = x"
   941   unfolding Field_def by blast
   942 
   943 
   944 subsubsection \<open>Image of a set under a relation\<close>
   945 
   946 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set"  (infixr "``" 90)
   947   where "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   948 
   949 lemma Image_iff: "b \<in> r``A \<longleftrightarrow> (\<exists>x\<in>A. (x, b) \<in> r)"
   950   by (simp add: Image_def)
   951 
   952 lemma Image_singleton: "r``{a} = {b. (a, b) \<in> r}"
   953   by (simp add: Image_def)
   954 
   955 lemma Image_singleton_iff [iff]: "b \<in> r``{a} \<longleftrightarrow> (a, b) \<in> r"
   956   by (rule Image_iff [THEN trans]) simp
   957 
   958 lemma ImageI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> r``A"
   959   unfolding Image_def by blast
   960 
   961 lemma ImageE [elim!]: "b \<in> r `` A \<Longrightarrow> (\<And>x. (x, b) \<in> r \<Longrightarrow> x \<in> A \<Longrightarrow> P) \<Longrightarrow> P"
   962   unfolding Image_def by (iprover elim!: CollectE bexE)
   963 
   964 lemma rev_ImageI: "a \<in> A \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> b \<in> r `` A"
   965   \<comment> \<open>This version's more effective when we already have the required \<open>a\<close>\<close>
   966   by blast
   967 
   968 lemma Image_empty [simp]: "R``{} = {}"
   969   by blast
   970 
   971 lemma Image_Id [simp]: "Id `` A = A"
   972   by blast
   973 
   974 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   975   by blast
   976 
   977 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   978   by blast
   979 
   980 lemma Image_Int_eq: "single_valued (converse R) \<Longrightarrow> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   981   by (auto simp: single_valued_def)
   982 
   983 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   984   by blast
   985 
   986 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   987   by blast
   988 
   989 lemma Image_subset: "r \<subseteq> A \<times> B \<Longrightarrow> r``C \<subseteq> B"
   990   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   991 
   992 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   993   \<comment> \<open>NOT suitable for rewriting\<close>
   994   by blast
   995 
   996 lemma Image_mono: "r' \<subseteq> r \<Longrightarrow> A' \<subseteq> A \<Longrightarrow> (r' `` A') \<subseteq> (r `` A)"
   997   by blast
   998 
   999 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1000   by blast
  1001 
  1002 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1003   by auto
  1004 
  1005 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1006   by blast
  1007 
  1008 text \<open>Converse inclusion requires some assumptions\<close>
  1009 lemma Image_INT_eq: "single_valued (r\<inverse>) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1010   apply (rule equalityI)
  1011    apply (rule Image_INT_subset)
  1012   apply (auto simp add: single_valued_def)
  1013   apply blast
  1014   done
  1015 
  1016 lemma Image_subset_eq: "r``A \<subseteq> B \<longleftrightarrow> A \<subseteq> - ((r\<inverse>) `` (- B))"
  1017   by blast
  1018 
  1019 lemma Image_Collect_case_prod [simp]: "{(x, y). P x y} `` A = {y. \<exists>x\<in>A. P x y}"
  1020   by auto
  1021 
  1022 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1023   by auto
  1024 
  1025 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1026   by auto
  1027 
  1028 
  1029 subsubsection \<open>Inverse image\<close>
  1030 
  1031 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1032   where "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1033 
  1034 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1035   where "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1036 
  1037 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1038   by (simp add: inv_image_def inv_imagep_def)
  1039 
  1040 lemma sym_inv_image: "sym r \<Longrightarrow> sym (inv_image r f)"
  1041   unfolding sym_def inv_image_def by blast
  1042 
  1043 lemma trans_inv_image: "trans r \<Longrightarrow> trans (inv_image r f)"
  1044   unfolding trans_def inv_image_def
  1045   apply (simp (no_asm))
  1046   apply blast
  1047   done
  1048 
  1049 lemma in_inv_image[simp]: "(x, y) \<in> inv_image r f \<longleftrightarrow> (f x, f y) \<in> r"
  1050   by (auto simp:inv_image_def)
  1051 
  1052 lemma converse_inv_image[simp]: "(inv_image R f)\<inverse> = inv_image (R\<inverse>) f"
  1053   unfolding inv_image_def converse_unfold by auto
  1054 
  1055 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1056   by (simp add: inv_imagep_def)
  1057 
  1058 
  1059 subsubsection \<open>Powerset\<close>
  1060 
  1061 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1062   where "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1063 
  1064 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1065   by (auto simp add: Powp_def fun_eq_iff)
  1066 
  1067 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1068 
  1069 
  1070 subsubsection \<open>Expressing relation operations via @{const Finite_Set.fold}\<close>
  1071 
  1072 lemma Id_on_fold:
  1073   assumes "finite A"
  1074   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1075 proof -
  1076   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)"
  1077     by standard auto
  1078   from assms show ?thesis
  1079     unfolding Id_on_def by (induct A) simp_all
  1080 qed
  1081 
  1082 lemma comp_fun_commute_Image_fold:
  1083   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1084 proof -
  1085   interpret comp_fun_idem Set.insert
  1086     by (fact comp_fun_idem_insert)
  1087   show ?thesis
  1088     by standard (auto simp: fun_eq_iff comp_fun_commute split: prod.split)
  1089 qed
  1090 
  1091 lemma Image_fold:
  1092   assumes "finite R"
  1093   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1094 proof -
  1095   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1096     by (rule comp_fun_commute_Image_fold)
  1097   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1098     by (force intro: rev_ImageI)
  1099   show ?thesis
  1100     using assms by (induct R) (auto simp: *)
  1101 qed
  1102 
  1103 lemma insert_relcomp_union_fold:
  1104   assumes "finite S"
  1105   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1106 proof -
  1107   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1108   proof -
  1109     interpret comp_fun_idem Set.insert
  1110       by (fact comp_fun_idem_insert)
  1111     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1112       by standard (auto simp add: fun_eq_iff split: prod.split)
  1113   qed
  1114   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x, z) \<in> S}"
  1115     by (auto simp: relcomp_unfold intro!: exI)
  1116   show ?thesis
  1117     unfolding * using \<open>finite S\<close> by (induct S) (auto split: prod.split)
  1118 qed
  1119 
  1120 lemma insert_relcomp_fold:
  1121   assumes "finite S"
  1122   shows "Set.insert x R O S =
  1123     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1124 proof -
  1125   have "Set.insert x R O S = ({x} O S) \<union> (R O S)"
  1126     by auto
  1127   then show ?thesis
  1128     by (auto simp: insert_relcomp_union_fold [OF assms])
  1129 qed
  1130 
  1131 lemma comp_fun_commute_relcomp_fold:
  1132   assumes "finite S"
  1133   shows "comp_fun_commute (\<lambda>(x,y) A.
  1134     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1135 proof -
  1136   have *: "\<And>a b A.
  1137     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1138     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1139   show ?thesis
  1140     by standard (auto simp: *)
  1141 qed
  1142 
  1143 lemma relcomp_fold:
  1144   assumes "finite R" "finite S"
  1145   shows "R O S = Finite_Set.fold
  1146     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1147   using assms
  1148   by (induct R)
  1149     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1150       cong: if_cong)
  1151 
  1152 text \<open>Misc\<close>
  1153 
  1154 abbreviation (input) transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
  1155   where "transP r \<equiv> trans {(x, y). r x y}"  (* FIXME drop *)
  1156 
  1157 abbreviation (input) "RangeP \<equiv> Rangep"
  1158 abbreviation (input) "DomainP \<equiv> Domainp"
  1159 
  1160 end