src/HOL/Set.thy
author paulson
Fri Sep 26 10:34:57 2003 +0200 (2003-09-26)
changeset 14208 144f45277d5a
parent 14098 54f130df1136
child 14302 6c24235e8d5d
permissions -rw-r--r--
misc tidying
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      == "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "UN x. B"     == "UN x:UNIV. B"
    81   "INT x y. B"  == "INT x. INT y. B"
    82   "INT x. B"    == "INTER UNIV (%x. B)"
    83   "INT x. B"    == "INT x:UNIV. B"
    84   "UN x:A. B"   == "UNION A (%x. B)"
    85   "INT x:A. B"  == "INTER A (%x. B)"
    86   "ALL x:A. P"  == "Ball A (%x. P)"
    87   "EX x:A. P"   == "Bex A (%x. P)"
    88 
    89 syntax (output)
    90   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    91   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    92   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    93   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    94 
    95 syntax (xsymbols)
    96   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    97   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    98   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    99   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
   100   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
   101   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   102   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   103   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   104   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   105   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   106   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   107   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   108   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   109   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   110   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   111   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   112   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   113   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   114 
   115 translations
   116   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   117   "op \<subset>" => "op <  :: _ set => _ set => bool"
   118 
   119 
   120 typed_print_translation {*
   121   let
   122     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   123           list_comb (Syntax.const "_setle", ts)
   124       | le_tr' _ _ _ = raise Match;
   125 
   126     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   127           list_comb (Syntax.const "_setless", ts)
   128       | less_tr' _ _ _ = raise Match;
   129   in [("op <=", le_tr'), ("op <", less_tr')] end
   130 *}
   131 
   132 text {*
   133   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   134   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   135   only translated if @{text "[0..n] subset bvs(e)"}.
   136 *}
   137 
   138 parse_translation {*
   139   let
   140     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   141 
   142     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   143       | nvars _ = 1;
   144 
   145     fun setcompr_tr [e, idts, b] =
   146       let
   147         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   148         val P = Syntax.const "op &" $ eq $ b;
   149         val exP = ex_tr [idts, P];
   150       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   151 
   152   in [("@SetCompr", setcompr_tr)] end;
   153 *}
   154 
   155 (* To avoid eta-contraction of body: *)
   156 print_translation {*
   157 let
   158   fun btr' syn [A,Abs abs] =
   159     let val (x,t) = atomic_abs_tr' abs
   160     in Syntax.const syn $ x $ A $ t end
   161 in
   162 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   163  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   164 end
   165 *}
   166 
   167 print_translation {*
   168 let
   169   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   170 
   171   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   172     let
   173       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   174         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   175             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   176             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   177         | check _ = false
   178 
   179         fun tr' (_ $ abs) =
   180           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   181           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   182     in if check (P, 0) then tr' P
   183        else let val (x,t) = atomic_abs_tr' abs
   184             in Syntax.const "@Coll" $ x $ t end
   185     end;
   186   in [("Collect", setcompr_tr')] end;
   187 *}
   188 
   189 
   190 subsection {* Rules and definitions *}
   191 
   192 text {* Isomorphisms between predicates and sets. *}
   193 
   194 axioms
   195   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   196   Collect_mem_eq [simp]: "{x. x:A} = A"
   197 
   198 defs
   199   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   200   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   201 
   202 defs (overloaded)
   203   subset_def:   "A <= B         == ALL x:A. x:B"
   204   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   205   Compl_def:    "- A            == {x. ~x:A}"
   206   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   207 
   208 defs
   209   Un_def:       "A Un B         == {x. x:A | x:B}"
   210   Int_def:      "A Int B        == {x. x:A & x:B}"
   211   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   212   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   213   Inter_def:    "Inter S        == (INT x:S. x)"
   214   Union_def:    "Union S        == (UN x:S. x)"
   215   Pow_def:      "Pow A          == {B. B <= A}"
   216   empty_def:    "{}             == {x. False}"
   217   UNIV_def:     "UNIV           == {x. True}"
   218   insert_def:   "insert a B     == {x. x=a} Un B"
   219   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   220 
   221 
   222 subsection {* Lemmas and proof tool setup *}
   223 
   224 subsubsection {* Relating predicates and sets *}
   225 
   226 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   227   by simp
   228 
   229 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   230   by simp
   231 
   232 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   233   by simp
   234 
   235 lemmas CollectE = CollectD [elim_format]
   236 
   237 
   238 subsubsection {* Bounded quantifiers *}
   239 
   240 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   241   by (simp add: Ball_def)
   242 
   243 lemmas strip = impI allI ballI
   244 
   245 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   246   by (simp add: Ball_def)
   247 
   248 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   249   by (unfold Ball_def) blast
   250 ML {* bind_thm("rev_ballE",permute_prems 1 1 (thm "ballE")) *}
   251 
   252 text {*
   253   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   254   @{prop "a:A"}; creates assumption @{prop "P a"}.
   255 *}
   256 
   257 ML {*
   258   local val ballE = thm "ballE"
   259   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   260 *}
   261 
   262 text {*
   263   Gives better instantiation for bound:
   264 *}
   265 
   266 ML_setup {*
   267   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   268 *}
   269 
   270 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   271   -- {* Normally the best argument order: @{prop "P x"} constrains the
   272     choice of @{prop "x:A"}. *}
   273   by (unfold Bex_def) blast
   274 
   275 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   276   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   277   by (unfold Bex_def) blast
   278 
   279 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   280   by (unfold Bex_def) blast
   281 
   282 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   283   by (unfold Bex_def) blast
   284 
   285 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   286   -- {* Trival rewrite rule. *}
   287   by (simp add: Ball_def)
   288 
   289 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   290   -- {* Dual form for existentials. *}
   291   by (simp add: Bex_def)
   292 
   293 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   294   by blast
   295 
   296 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   297   by blast
   298 
   299 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   300   by blast
   301 
   302 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   303   by blast
   304 
   305 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   306   by blast
   307 
   308 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   309   by blast
   310 
   311 ML_setup {*
   312   local
   313     val Ball_def = thm "Ball_def";
   314     val Bex_def = thm "Bex_def";
   315 
   316     val prove_bex_tac =
   317       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   318     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   319 
   320     val prove_ball_tac =
   321       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   322     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   323   in
   324     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   325       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   326     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   327       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   328   end;
   329 
   330   Addsimprocs [defBALL_regroup, defBEX_regroup];
   331 *}
   332 
   333 
   334 subsubsection {* Congruence rules *}
   335 
   336 lemma ball_cong [cong]:
   337   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   338     (ALL x:A. P x) = (ALL x:B. Q x)"
   339   by (simp add: Ball_def)
   340 
   341 lemma bex_cong [cong]:
   342   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   343     (EX x:A. P x) = (EX x:B. Q x)"
   344   by (simp add: Bex_def cong: conj_cong)
   345 
   346 
   347 subsubsection {* Subsets *}
   348 
   349 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   350   by (simp add: subset_def)
   351 
   352 text {*
   353   \medskip Map the type @{text "'a set => anything"} to just @{typ
   354   'a}; for overloading constants whose first argument has type @{typ
   355   "'a set"}.
   356 *}
   357 
   358 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   359   -- {* Rule in Modus Ponens style. *}
   360   by (unfold subset_def) blast
   361 
   362 declare subsetD [intro?] -- FIXME
   363 
   364 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   365   -- {* The same, with reversed premises for use with @{text erule} --
   366       cf @{text rev_mp}. *}
   367   by (rule subsetD)
   368 
   369 declare rev_subsetD [intro?] -- FIXME
   370 
   371 text {*
   372   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   373 *}
   374 
   375 ML {*
   376   local val rev_subsetD = thm "rev_subsetD"
   377   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   378 *}
   379 
   380 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   381   -- {* Classical elimination rule. *}
   382   by (unfold subset_def) blast
   383 
   384 text {*
   385   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   386   creates the assumption @{prop "c \<in> B"}.
   387 *}
   388 
   389 ML {*
   390   local val subsetCE = thm "subsetCE"
   391   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   392 *}
   393 
   394 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   395   by blast
   396 
   397 lemma subset_refl: "A \<subseteq> A"
   398   by fast
   399 
   400 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   401   by blast
   402 
   403 
   404 subsubsection {* Equality *}
   405 
   406 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   407   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   408    apply (rule Collect_mem_eq)
   409   apply (rule Collect_mem_eq)
   410   done
   411 
   412 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   413   -- {* Anti-symmetry of the subset relation. *}
   414   by (rules intro: set_ext subsetD)
   415 
   416 lemmas equalityI [intro!] = subset_antisym
   417 
   418 text {*
   419   \medskip Equality rules from ZF set theory -- are they appropriate
   420   here?
   421 *}
   422 
   423 lemma equalityD1: "A = B ==> A \<subseteq> B"
   424   by (simp add: subset_refl)
   425 
   426 lemma equalityD2: "A = B ==> B \<subseteq> A"
   427   by (simp add: subset_refl)
   428 
   429 text {*
   430   \medskip Be careful when adding this to the claset as @{text
   431   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   432   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   433 *}
   434 
   435 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   436   by (simp add: subset_refl)
   437 
   438 lemma equalityCE [elim]:
   439     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   440   by blast
   441 
   442 text {*
   443   \medskip Lemma for creating induction formulae -- for "pattern
   444   matching" on @{text p}.  To make the induction hypotheses usable,
   445   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   446   variables in @{text p}.
   447 *}
   448 
   449 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   450   by simp
   451 
   452 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   453   by simp
   454 
   455 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   456   by simp
   457 
   458 
   459 subsubsection {* The universal set -- UNIV *}
   460 
   461 lemma UNIV_I [simp]: "x : UNIV"
   462   by (simp add: UNIV_def)
   463 
   464 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   465 
   466 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   467   by simp
   468 
   469 lemma subset_UNIV: "A \<subseteq> UNIV"
   470   by (rule subsetI) (rule UNIV_I)
   471 
   472 text {*
   473   \medskip Eta-contracting these two rules (to remove @{text P})
   474   causes them to be ignored because of their interaction with
   475   congruence rules.
   476 *}
   477 
   478 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   479   by (simp add: Ball_def)
   480 
   481 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   482   by (simp add: Bex_def)
   483 
   484 
   485 subsubsection {* The empty set *}
   486 
   487 lemma empty_iff [simp]: "(c : {}) = False"
   488   by (simp add: empty_def)
   489 
   490 lemma emptyE [elim!]: "a : {} ==> P"
   491   by simp
   492 
   493 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   494     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   495   by blast
   496 
   497 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   498   by blast
   499 
   500 lemma equals0D: "A = {} ==> a \<notin> A"
   501     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   502   by blast
   503 
   504 lemma ball_empty [simp]: "Ball {} P = True"
   505   by (simp add: Ball_def)
   506 
   507 lemma bex_empty [simp]: "Bex {} P = False"
   508   by (simp add: Bex_def)
   509 
   510 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   511   by (blast elim: equalityE)
   512 
   513 
   514 subsubsection {* The Powerset operator -- Pow *}
   515 
   516 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   517   by (simp add: Pow_def)
   518 
   519 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   520   by (simp add: Pow_def)
   521 
   522 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   523   by (simp add: Pow_def)
   524 
   525 lemma Pow_bottom: "{} \<in> Pow B"
   526   by simp
   527 
   528 lemma Pow_top: "A \<in> Pow A"
   529   by (simp add: subset_refl)
   530 
   531 
   532 subsubsection {* Set complement *}
   533 
   534 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   535   by (unfold Compl_def) blast
   536 
   537 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   538   by (unfold Compl_def) blast
   539 
   540 text {*
   541   \medskip This form, with negated conclusion, works well with the
   542   Classical prover.  Negated assumptions behave like formulae on the
   543   right side of the notional turnstile ... *}
   544 
   545 lemma ComplD: "c : -A ==> c~:A"
   546   by (unfold Compl_def) blast
   547 
   548 lemmas ComplE [elim!] = ComplD [elim_format]
   549 
   550 
   551 subsubsection {* Binary union -- Un *}
   552 
   553 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   554   by (unfold Un_def) blast
   555 
   556 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   557   by simp
   558 
   559 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   560   by simp
   561 
   562 text {*
   563   \medskip Classical introduction rule: no commitment to @{prop A} vs
   564   @{prop B}.
   565 *}
   566 
   567 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   568   by auto
   569 
   570 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   571   by (unfold Un_def) blast
   572 
   573 
   574 subsubsection {* Binary intersection -- Int *}
   575 
   576 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   577   by (unfold Int_def) blast
   578 
   579 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   580   by simp
   581 
   582 lemma IntD1: "c : A Int B ==> c:A"
   583   by simp
   584 
   585 lemma IntD2: "c : A Int B ==> c:B"
   586   by simp
   587 
   588 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   589   by simp
   590 
   591 
   592 subsubsection {* Set difference *}
   593 
   594 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   595   by (unfold set_diff_def) blast
   596 
   597 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   598   by simp
   599 
   600 lemma DiffD1: "c : A - B ==> c : A"
   601   by simp
   602 
   603 lemma DiffD2: "c : A - B ==> c : B ==> P"
   604   by simp
   605 
   606 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   607   by simp
   608 
   609 
   610 subsubsection {* Augmenting a set -- insert *}
   611 
   612 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   613   by (unfold insert_def) blast
   614 
   615 lemma insertI1: "a : insert a B"
   616   by simp
   617 
   618 lemma insertI2: "a : B ==> a : insert b B"
   619   by simp
   620 
   621 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   622   by (unfold insert_def) blast
   623 
   624 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   625   -- {* Classical introduction rule. *}
   626   by auto
   627 
   628 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   629   by auto
   630 
   631 
   632 subsubsection {* Singletons, using insert *}
   633 
   634 lemma singletonI [intro!]: "a : {a}"
   635     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   636   by (rule insertI1)
   637 
   638 lemma singletonD: "b : {a} ==> b = a"
   639   by blast
   640 
   641 lemmas singletonE [elim!] = singletonD [elim_format]
   642 
   643 lemma singleton_iff: "(b : {a}) = (b = a)"
   644   by blast
   645 
   646 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   647   by blast
   648 
   649 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   650   by blast
   651 
   652 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   653   by blast
   654 
   655 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   656   by fast
   657 
   658 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   659   by blast
   660 
   661 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   662   by blast
   663 
   664 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   665   by blast
   666 
   667 
   668 subsubsection {* Unions of families *}
   669 
   670 text {*
   671   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   672 *}
   673 
   674 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   675   by (unfold UNION_def) blast
   676 
   677 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   678   -- {* The order of the premises presupposes that @{term A} is rigid;
   679     @{term b} may be flexible. *}
   680   by auto
   681 
   682 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   683   by (unfold UNION_def) blast
   684 
   685 lemma UN_cong [cong]:
   686     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   687   by (simp add: UNION_def)
   688 
   689 
   690 subsubsection {* Intersections of families *}
   691 
   692 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   693 
   694 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   695   by (unfold INTER_def) blast
   696 
   697 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   698   by (unfold INTER_def) blast
   699 
   700 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   701   by auto
   702 
   703 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   704   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   705   by (unfold INTER_def) blast
   706 
   707 lemma INT_cong [cong]:
   708     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   709   by (simp add: INTER_def)
   710 
   711 
   712 subsubsection {* Union *}
   713 
   714 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   715   by (unfold Union_def) blast
   716 
   717 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   718   -- {* The order of the premises presupposes that @{term C} is rigid;
   719     @{term A} may be flexible. *}
   720   by auto
   721 
   722 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   723   by (unfold Union_def) blast
   724 
   725 
   726 subsubsection {* Inter *}
   727 
   728 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   729   by (unfold Inter_def) blast
   730 
   731 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   732   by (simp add: Inter_def)
   733 
   734 text {*
   735   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   736   contains @{term A} as an element, but @{prop "A:X"} can hold when
   737   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   738 *}
   739 
   740 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   741   by auto
   742 
   743 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   744   -- {* ``Classical'' elimination rule -- does not require proving
   745     @{prop "X:C"}. *}
   746   by (unfold Inter_def) blast
   747 
   748 text {*
   749   \medskip Image of a set under a function.  Frequently @{term b} does
   750   not have the syntactic form of @{term "f x"}.
   751 *}
   752 
   753 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   754   by (unfold image_def) blast
   755 
   756 lemma imageI: "x : A ==> f x : f ` A"
   757   by (rule image_eqI) (rule refl)
   758 
   759 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   760   -- {* This version's more effective when we already have the
   761     required @{term x}. *}
   762   by (unfold image_def) blast
   763 
   764 lemma imageE [elim!]:
   765   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   766   -- {* The eta-expansion gives variable-name preservation. *}
   767   by (unfold image_def) blast
   768 
   769 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   770   by blast
   771 
   772 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   773   by blast
   774 
   775 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   776   -- {* This rewrite rule would confuse users if made default. *}
   777   by blast
   778 
   779 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   780   apply safe
   781    prefer 2 apply fast
   782   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   783   done
   784 
   785 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   786   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   787     @{text hypsubst}, but breaks too many existing proofs. *}
   788   by blast
   789 
   790 text {*
   791   \medskip Range of a function -- just a translation for image!
   792 *}
   793 
   794 lemma range_eqI: "b = f x ==> b \<in> range f"
   795   by simp
   796 
   797 lemma rangeI: "f x \<in> range f"
   798   by simp
   799 
   800 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   801   by blast
   802 
   803 
   804 subsubsection {* Set reasoning tools *}
   805 
   806 text {*
   807   Rewrite rules for boolean case-splitting: faster than @{text
   808   "split_if [split]"}.
   809 *}
   810 
   811 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   812   by (rule split_if)
   813 
   814 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   815   by (rule split_if)
   816 
   817 text {*
   818   Split ifs on either side of the membership relation.  Not for @{text
   819   "[simp]"} -- can cause goals to blow up!
   820 *}
   821 
   822 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   823   by (rule split_if)
   824 
   825 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   826   by (rule split_if)
   827 
   828 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   829 
   830 lemmas mem_simps =
   831   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   832   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   833   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   834 
   835 (*Would like to add these, but the existing code only searches for the
   836   outer-level constant, which in this case is just "op :"; we instead need
   837   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   838   apply, then the formula should be kept.
   839   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   840    ("op Int", [IntD1,IntD2]),
   841    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   842  *)
   843 
   844 ML_setup {*
   845   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   846   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   847 *}
   848 
   849 declare subset_UNIV [simp] subset_refl [simp]
   850 
   851 
   852 subsubsection {* The ``proper subset'' relation *}
   853 
   854 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   855   by (unfold psubset_def) blast
   856 
   857 lemma psubsetE [elim!]: 
   858     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   859   by (unfold psubset_def) blast
   860 
   861 lemma psubset_insert_iff:
   862   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   863   by (auto simp add: psubset_def subset_insert_iff)
   864 
   865 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   866   by (simp only: psubset_def)
   867 
   868 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   869   by (simp add: psubset_eq)
   870 
   871 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   872   by (auto simp add: psubset_eq)
   873 
   874 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   875   by (auto simp add: psubset_eq)
   876 
   877 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   878   by (unfold psubset_def) blast
   879 
   880 lemma atomize_ball:
   881     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   882   by (simp only: Ball_def atomize_all atomize_imp)
   883 
   884 declare atomize_ball [symmetric, rulify]
   885 
   886 
   887 subsection {* Further set-theory lemmas *}
   888 
   889 subsubsection {* Derived rules involving subsets. *}
   890 
   891 text {* @{text insert}. *}
   892 
   893 lemma subset_insertI: "B \<subseteq> insert a B"
   894   apply (rule subsetI)
   895   apply (erule insertI2)
   896   done
   897 
   898 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   899   by blast
   900 
   901 
   902 text {* \medskip Big Union -- least upper bound of a set. *}
   903 
   904 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   905   by (rules intro: subsetI UnionI)
   906 
   907 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   908   by (rules intro: subsetI elim: UnionE dest: subsetD)
   909 
   910 
   911 text {* \medskip General union. *}
   912 
   913 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   914   by blast
   915 
   916 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   917   by (rules intro: subsetI elim: UN_E dest: subsetD)
   918 
   919 
   920 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   921 
   922 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   923   by blast
   924 
   925 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   926   by (rules intro: InterI subsetI dest: subsetD)
   927 
   928 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   929   by blast
   930 
   931 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   932   by (rules intro: INT_I subsetI dest: subsetD)
   933 
   934 
   935 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   936 
   937 lemma Un_upper1: "A \<subseteq> A \<union> B"
   938   by blast
   939 
   940 lemma Un_upper2: "B \<subseteq> A \<union> B"
   941   by blast
   942 
   943 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   944   by blast
   945 
   946 
   947 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   948 
   949 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   950   by blast
   951 
   952 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   953   by blast
   954 
   955 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   956   by blast
   957 
   958 
   959 text {* \medskip Set difference. *}
   960 
   961 lemma Diff_subset: "A - B \<subseteq> A"
   962   by blast
   963 
   964 
   965 text {* \medskip Monotonicity. *}
   966 
   967 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   968   apply (rule Un_least)
   969    apply (rule Un_upper1 [THEN mono])
   970   apply (rule Un_upper2 [THEN mono])
   971   done
   972 
   973 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   974   apply (rule Int_greatest)
   975    apply (rule Int_lower1 [THEN mono])
   976   apply (rule Int_lower2 [THEN mono])
   977   done
   978 
   979 
   980 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
   981 
   982 text {* @{text "{}"}. *}
   983 
   984 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
   985   -- {* supersedes @{text "Collect_False_empty"} *}
   986   by auto
   987 
   988 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
   989   by blast
   990 
   991 lemma not_psubset_empty [iff]: "\<not> (A < {})"
   992   by (unfold psubset_def) blast
   993 
   994 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
   995   by auto
   996 
   997 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
   998   by blast
   999 
  1000 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1001   by blast
  1002 
  1003 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1004   by blast
  1005 
  1006 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1007   by blast
  1008 
  1009 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1010   by blast
  1011 
  1012 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1013   by blast
  1014 
  1015 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1016   by blast
  1017 
  1018 
  1019 text {* \medskip @{text insert}. *}
  1020 
  1021 lemma insert_is_Un: "insert a A = {a} Un A"
  1022   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1023   by blast
  1024 
  1025 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1026   by blast
  1027 
  1028 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1029 
  1030 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1031   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1032   -- {* with \emph{quadratic} running time *}
  1033   by blast
  1034 
  1035 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1036   by blast
  1037 
  1038 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1039   by blast
  1040 
  1041 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1042   by blast
  1043 
  1044 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1045   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1046   apply (rule_tac x = "A - {a}" in exI, blast)
  1047   done
  1048 
  1049 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1050   by auto
  1051 
  1052 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1053   by blast
  1054 
  1055 lemma insert_disjoint[simp]:
  1056  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1057 by blast
  1058 
  1059 lemma disjoint_insert[simp]:
  1060  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1061 by blast
  1062 
  1063 text {* \medskip @{text image}. *}
  1064 
  1065 lemma image_empty [simp]: "f`{} = {}"
  1066   by blast
  1067 
  1068 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1069   by blast
  1070 
  1071 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1072   by blast
  1073 
  1074 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1075   by blast
  1076 
  1077 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1078   by blast
  1079 
  1080 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1081   by blast
  1082 
  1083 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1084   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1085   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1086   -- {* equational properties than does the RHS. *}
  1087   by blast
  1088 
  1089 lemma if_image_distrib [simp]:
  1090   "(\<lambda>x. if P x then f x else g x) ` S
  1091     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1092   by (auto simp add: image_def)
  1093 
  1094 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1095   by (simp add: image_def)
  1096 
  1097 
  1098 text {* \medskip @{text range}. *}
  1099 
  1100 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1101   by auto
  1102 
  1103 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1104 by (subst image_image, simp)
  1105 
  1106 
  1107 text {* \medskip @{text Int} *}
  1108 
  1109 lemma Int_absorb [simp]: "A \<inter> A = A"
  1110   by blast
  1111 
  1112 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1113   by blast
  1114 
  1115 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1116   by blast
  1117 
  1118 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1119   by blast
  1120 
  1121 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1122   by blast
  1123 
  1124 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1125   -- {* Intersection is an AC-operator *}
  1126 
  1127 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1128   by blast
  1129 
  1130 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1131   by blast
  1132 
  1133 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1134   by blast
  1135 
  1136 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1137   by blast
  1138 
  1139 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1140   by blast
  1141 
  1142 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1143   by blast
  1144 
  1145 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1146   by blast
  1147 
  1148 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1149   by blast
  1150 
  1151 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1152   by blast
  1153 
  1154 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1155   by blast
  1156 
  1157 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1158   by blast
  1159 
  1160 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1161   by blast
  1162 
  1163 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1164   by blast
  1165 
  1166 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1167   by blast
  1168 
  1169 
  1170 text {* \medskip @{text Un}. *}
  1171 
  1172 lemma Un_absorb [simp]: "A \<union> A = A"
  1173   by blast
  1174 
  1175 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1176   by blast
  1177 
  1178 lemma Un_commute: "A \<union> B = B \<union> A"
  1179   by blast
  1180 
  1181 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1182   by blast
  1183 
  1184 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1185   by blast
  1186 
  1187 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1188   -- {* Union is an AC-operator *}
  1189 
  1190 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1191   by blast
  1192 
  1193 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1194   by blast
  1195 
  1196 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1197   by blast
  1198 
  1199 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1200   by blast
  1201 
  1202 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1203   by blast
  1204 
  1205 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1206   by blast
  1207 
  1208 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1209   by blast
  1210 
  1211 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1212   by blast
  1213 
  1214 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1215   by blast
  1216 
  1217 lemma Int_insert_left:
  1218     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1219   by auto
  1220 
  1221 lemma Int_insert_right:
  1222     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1223   by auto
  1224 
  1225 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1226   by blast
  1227 
  1228 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1229   by blast
  1230 
  1231 lemma Un_Int_crazy:
  1232     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1233   by blast
  1234 
  1235 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1236   by blast
  1237 
  1238 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1239   by blast
  1240 
  1241 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1242   by blast
  1243 
  1244 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1245   by blast
  1246 
  1247 
  1248 text {* \medskip Set complement *}
  1249 
  1250 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1251   by blast
  1252 
  1253 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1254   by blast
  1255 
  1256 lemma Compl_partition: "A \<union> -A = UNIV"
  1257   by blast
  1258 
  1259 lemma Compl_partition2: "-A \<union> A = UNIV"
  1260   by blast
  1261 
  1262 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1263   by blast
  1264 
  1265 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1266   by blast
  1267 
  1268 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1269   by blast
  1270 
  1271 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1272   by blast
  1273 
  1274 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1275   by blast
  1276 
  1277 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1278   by blast
  1279 
  1280 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1281   -- {* Halmos, Naive Set Theory, page 16. *}
  1282   by blast
  1283 
  1284 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1285   by blast
  1286 
  1287 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1288   by blast
  1289 
  1290 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1291   by blast
  1292 
  1293 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1294   by blast
  1295 
  1296 
  1297 text {* \medskip @{text Union}. *}
  1298 
  1299 lemma Union_empty [simp]: "Union({}) = {}"
  1300   by blast
  1301 
  1302 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1303   by blast
  1304 
  1305 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1306   by blast
  1307 
  1308 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1309   by blast
  1310 
  1311 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1312   by blast
  1313 
  1314 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1315   by blast
  1316 
  1317 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1318   by blast
  1319 
  1320 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1321   by blast
  1322 
  1323 
  1324 text {* \medskip @{text Inter}. *}
  1325 
  1326 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1327   by blast
  1328 
  1329 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1330   by blast
  1331 
  1332 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1333   by blast
  1334 
  1335 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1336   by blast
  1337 
  1338 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1339   by blast
  1340 
  1341 lemma Inter_UNIV_conv [iff]:
  1342   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1343   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1344   by blast+
  1345 
  1346 
  1347 text {*
  1348   \medskip @{text UN} and @{text INT}.
  1349 
  1350   Basic identities: *}
  1351 
  1352 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1353   by blast
  1354 
  1355 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1356   by blast
  1357 
  1358 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1359   by blast
  1360 
  1361 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1362   by blast
  1363 
  1364 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1365   by blast
  1366 
  1367 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1368   by blast
  1369 
  1370 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1371   by blast
  1372 
  1373 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1374   by blast
  1375 
  1376 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1377   by blast
  1378 
  1379 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1380   by blast
  1381 
  1382 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1383   by blast
  1384 
  1385 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1386   by blast
  1387 
  1388 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1389   by blast
  1390 
  1391 lemma INT_insert_distrib:
  1392     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1393   by blast
  1394 
  1395 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1396   by blast
  1397 
  1398 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1399   by blast
  1400 
  1401 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1402   by blast
  1403 
  1404 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1405   by auto
  1406 
  1407 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1408   by auto
  1409 
  1410 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1411   by blast
  1412 
  1413 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1414   -- {* Look: it has an \emph{existential} quantifier *}
  1415   by blast
  1416 
  1417 lemma UNION_empty_conv[iff]:
  1418   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1419   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1420 by blast+
  1421 
  1422 lemma INTER_UNIV_conv[iff]:
  1423  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1424  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1425 by blast+
  1426 
  1427 
  1428 text {* \medskip Distributive laws: *}
  1429 
  1430 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1431   by blast
  1432 
  1433 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1434   by blast
  1435 
  1436 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1437   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1438   -- {* Union of a family of unions *}
  1439   by blast
  1440 
  1441 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1442   -- {* Equivalent version *}
  1443   by blast
  1444 
  1445 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1446   by blast
  1447 
  1448 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1449   by blast
  1450 
  1451 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1452   -- {* Equivalent version *}
  1453   by blast
  1454 
  1455 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1456   -- {* Halmos, Naive Set Theory, page 35. *}
  1457   by blast
  1458 
  1459 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1460   by blast
  1461 
  1462 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1463   by blast
  1464 
  1465 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1466   by blast
  1467 
  1468 
  1469 text {* \medskip Bounded quantifiers.
  1470 
  1471   The following are not added to the default simpset because
  1472   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1473 
  1474 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1475   by blast
  1476 
  1477 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1478   by blast
  1479 
  1480 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1481   by blast
  1482 
  1483 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1484   by blast
  1485 
  1486 
  1487 text {* \medskip Set difference. *}
  1488 
  1489 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1490   by blast
  1491 
  1492 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1493   by blast
  1494 
  1495 lemma Diff_cancel [simp]: "A - A = {}"
  1496   by blast
  1497 
  1498 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1499   by (blast elim: equalityE)
  1500 
  1501 lemma empty_Diff [simp]: "{} - A = {}"
  1502   by blast
  1503 
  1504 lemma Diff_empty [simp]: "A - {} = A"
  1505   by blast
  1506 
  1507 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1508   by blast
  1509 
  1510 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1511   by blast
  1512 
  1513 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1514   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1515   by blast
  1516 
  1517 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1518   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1519   by blast
  1520 
  1521 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1522   by auto
  1523 
  1524 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1525   by blast
  1526 
  1527 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1528   by blast
  1529 
  1530 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1531   by auto
  1532 
  1533 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1534   by blast
  1535 
  1536 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1537   by blast
  1538 
  1539 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1540   by blast
  1541 
  1542 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1543   by blast
  1544 
  1545 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1546   by blast
  1547 
  1548 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1549   by blast
  1550 
  1551 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1552   by blast
  1553 
  1554 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1555   by blast
  1556 
  1557 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1558   by blast
  1559 
  1560 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1561   by blast
  1562 
  1563 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1564   by blast
  1565 
  1566 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1567   by auto
  1568 
  1569 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1570   by blast
  1571 
  1572 
  1573 text {* \medskip Quantification over type @{typ bool}. *}
  1574 
  1575 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1576   apply auto
  1577   apply (tactic {* case_tac "b" 1 *}, auto)
  1578   done
  1579 
  1580 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1581   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1582 
  1583 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1584   apply auto
  1585   apply (tactic {* case_tac "b" 1 *}, auto)
  1586   done
  1587 
  1588 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1589   by (auto simp add: split_if_mem2)
  1590 
  1591 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1592   apply auto
  1593   apply (tactic {* case_tac "b" 1 *}, auto)
  1594   done
  1595 
  1596 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1597   apply auto
  1598   apply (tactic {* case_tac "b" 1 *}, auto)
  1599   done
  1600 
  1601 
  1602 text {* \medskip @{text Pow} *}
  1603 
  1604 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1605   by (auto simp add: Pow_def)
  1606 
  1607 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1608   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1609 
  1610 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1611   by (blast intro: exI [where ?x = "- u", standard])
  1612 
  1613 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1614   by blast
  1615 
  1616 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1617   by blast
  1618 
  1619 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1620   by blast
  1621 
  1622 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1623   by blast
  1624 
  1625 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1626   by blast
  1627 
  1628 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1629   by blast
  1630 
  1631 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1632   by blast
  1633 
  1634 
  1635 text {* \medskip Miscellany. *}
  1636 
  1637 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1638   by blast
  1639 
  1640 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1641   by blast
  1642 
  1643 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1644   by (unfold psubset_def) blast
  1645 
  1646 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1647   by blast
  1648 
  1649 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1650   by blast
  1651 
  1652 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1653   by rules
  1654 
  1655 
  1656 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1657            and Intersections. *}
  1658 
  1659 lemma UN_simps [simp]:
  1660   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1661   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1662   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1663   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1664   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1665   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1666   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1667   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1668   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1669   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1670   by auto
  1671 
  1672 lemma INT_simps [simp]:
  1673   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1674   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1675   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1676   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1677   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1678   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1679   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1680   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1681   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1682   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1683   by auto
  1684 
  1685 lemma ball_simps [simp]:
  1686   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1687   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1688   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1689   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1690   "!!P. (ALL x:{}. P x) = True"
  1691   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1692   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1693   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1694   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1695   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1696   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1697   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1698   by auto
  1699 
  1700 lemma bex_simps [simp]:
  1701   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1702   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1703   "!!P. (EX x:{}. P x) = False"
  1704   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1705   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1706   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1707   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1708   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1709   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1710   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1711   by auto
  1712 
  1713 lemma ball_conj_distrib:
  1714   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1715   by blast
  1716 
  1717 lemma bex_disj_distrib:
  1718   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1719   by blast
  1720 
  1721 
  1722 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1723 
  1724 lemma UN_extend_simps:
  1725   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1726   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1727   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1728   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1729   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1730   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1731   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1732   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1733   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1734   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1735   by auto
  1736 
  1737 lemma INT_extend_simps:
  1738   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1739   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1740   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1741   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1742   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1743   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1744   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1745   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1746   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1747   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1748   by auto
  1749 
  1750 
  1751 subsubsection {* Monotonicity of various operations *}
  1752 
  1753 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1754   by blast
  1755 
  1756 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1757   by blast
  1758 
  1759 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1760   by blast
  1761 
  1762 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1763   by blast
  1764 
  1765 lemma UN_mono:
  1766   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1767     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1768   by (blast dest: subsetD)
  1769 
  1770 lemma INT_anti_mono:
  1771   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1772     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1773   -- {* The last inclusion is POSITIVE! *}
  1774   by (blast dest: subsetD)
  1775 
  1776 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1777   by blast
  1778 
  1779 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1780   by blast
  1781 
  1782 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1783   by blast
  1784 
  1785 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1786   by blast
  1787 
  1788 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1789   by blast
  1790 
  1791 text {* \medskip Monotonicity of implications. *}
  1792 
  1793 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1794   apply (rule impI)
  1795   apply (erule subsetD, assumption)
  1796   done
  1797 
  1798 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1799   by rules
  1800 
  1801 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1802   by rules
  1803 
  1804 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1805   by rules
  1806 
  1807 lemma imp_refl: "P --> P" ..
  1808 
  1809 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1810   by rules
  1811 
  1812 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1813   by rules
  1814 
  1815 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1816   by blast
  1817 
  1818 lemma Int_Collect_mono:
  1819     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1820   by blast
  1821 
  1822 lemmas basic_monos =
  1823   subset_refl imp_refl disj_mono conj_mono
  1824   ex_mono Collect_mono in_mono
  1825 
  1826 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1827   by rules
  1828 
  1829 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1830   by rules
  1831 
  1832 lemma Least_mono:
  1833   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1834     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1835     -- {* Courtesy of Stephan Merz *}
  1836   apply clarify
  1837   apply (erule_tac P = "%x. x : S" in LeastI2, fast)
  1838   apply (rule LeastI2)
  1839   apply (auto elim: monoD intro!: order_antisym)
  1840   done
  1841 
  1842 
  1843 subsection {* Inverse image of a function *}
  1844 
  1845 constdefs
  1846   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1847   "f -` B == {x. f x : B}"
  1848 
  1849 
  1850 subsubsection {* Basic rules *}
  1851 
  1852 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1853   by (unfold vimage_def) blast
  1854 
  1855 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1856   by simp
  1857 
  1858 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1859   by (unfold vimage_def) blast
  1860 
  1861 lemma vimageI2: "f a : A ==> a : f -` A"
  1862   by (unfold vimage_def) fast
  1863 
  1864 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1865   by (unfold vimage_def) blast
  1866 
  1867 lemma vimageD: "a : f -` A ==> f a : A"
  1868   by (unfold vimage_def) fast
  1869 
  1870 
  1871 subsubsection {* Equations *}
  1872 
  1873 lemma vimage_empty [simp]: "f -` {} = {}"
  1874   by blast
  1875 
  1876 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1877   by blast
  1878 
  1879 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1880   by blast
  1881 
  1882 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1883   by fast
  1884 
  1885 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1886   by blast
  1887 
  1888 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1889   by blast
  1890 
  1891 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1892   by blast
  1893 
  1894 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1895   by blast
  1896 
  1897 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1898   by blast
  1899 
  1900 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1901   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1902   by blast
  1903 
  1904 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1905   by blast
  1906 
  1907 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1908   by blast
  1909 
  1910 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1911   -- {* NOT suitable for rewriting *}
  1912   by blast
  1913 
  1914 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1915   -- {* monotonicity *}
  1916   by blast
  1917 
  1918 
  1919 subsection {* Transitivity rules for calculational reasoning *}
  1920 
  1921 lemma forw_subst: "a = b ==> P b ==> P a"
  1922   by (rule ssubst)
  1923 
  1924 lemma back_subst: "P a ==> a = b ==> P b"
  1925   by (rule subst)
  1926 
  1927 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1928   by (rule subsetD)
  1929 
  1930 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1931   by (rule subsetD)
  1932 
  1933 lemma order_neq_le_trans: "a ~= b ==> (a::'a::order) <= b ==> a < b"
  1934   by (simp add: order_less_le)
  1935 
  1936 lemma order_le_neq_trans: "(a::'a::order) <= b ==> a ~= b ==> a < b"
  1937   by (simp add: order_less_le)
  1938 
  1939 lemma order_less_asym': "(a::'a::order) < b ==> b < a ==> P"
  1940   by (rule order_less_asym)
  1941 
  1942 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1943   by (rule subst)
  1944 
  1945 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1946   by (rule ssubst)
  1947 
  1948 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1949   by (rule subst)
  1950 
  1951 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1952   by (rule ssubst)
  1953 
  1954 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1955   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1956 proof -
  1957   assume r: "!!x y. x < y ==> f x < f y"
  1958   assume "a < b" hence "f a < f b" by (rule r)
  1959   also assume "f b < c"
  1960   finally (order_less_trans) show ?thesis .
  1961 qed
  1962 
  1963 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1964   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1965 proof -
  1966   assume r: "!!x y. x < y ==> f x < f y"
  1967   assume "a < f b"
  1968   also assume "b < c" hence "f b < f c" by (rule r)
  1969   finally (order_less_trans) show ?thesis .
  1970 qed
  1971 
  1972 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1973   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1974 proof -
  1975   assume r: "!!x y. x <= y ==> f x <= f y"
  1976   assume "a <= b" hence "f a <= f b" by (rule r)
  1977   also assume "f b < c"
  1978   finally (order_le_less_trans) show ?thesis .
  1979 qed
  1980 
  1981 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  1982   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1983 proof -
  1984   assume r: "!!x y. x < y ==> f x < f y"
  1985   assume "a <= f b"
  1986   also assume "b < c" hence "f b < f c" by (rule r)
  1987   finally (order_le_less_trans) show ?thesis .
  1988 qed
  1989 
  1990 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  1991   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1992 proof -
  1993   assume r: "!!x y. x < y ==> f x < f y"
  1994   assume "a < b" hence "f a < f b" by (rule r)
  1995   also assume "f b <= c"
  1996   finally (order_less_le_trans) show ?thesis .
  1997 qed
  1998 
  1999 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  2000   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  2001 proof -
  2002   assume r: "!!x y. x <= y ==> f x <= f y"
  2003   assume "a < f b"
  2004   also assume "b <= c" hence "f b <= f c" by (rule r)
  2005   finally (order_less_le_trans) show ?thesis .
  2006 qed
  2007 
  2008 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  2009   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2010 proof -
  2011   assume r: "!!x y. x <= y ==> f x <= f y"
  2012   assume "a <= f b"
  2013   also assume "b <= c" hence "f b <= f c" by (rule r)
  2014   finally (order_trans) show ?thesis .
  2015 qed
  2016 
  2017 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  2018   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2019 proof -
  2020   assume r: "!!x y. x <= y ==> f x <= f y"
  2021   assume "a <= b" hence "f a <= f b" by (rule r)
  2022   also assume "f b <= c"
  2023   finally (order_trans) show ?thesis .
  2024 qed
  2025 
  2026 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  2027   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2028 proof -
  2029   assume r: "!!x y. x <= y ==> f x <= f y"
  2030   assume "a <= b" hence "f a <= f b" by (rule r)
  2031   also assume "f b = c"
  2032   finally (ord_le_eq_trans) show ?thesis .
  2033 qed
  2034 
  2035 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2036   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2037 proof -
  2038   assume r: "!!x y. x <= y ==> f x <= f y"
  2039   assume "a = f b"
  2040   also assume "b <= c" hence "f b <= f c" by (rule r)
  2041   finally (ord_eq_le_trans) show ?thesis .
  2042 qed
  2043 
  2044 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2045   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2046 proof -
  2047   assume r: "!!x y. x < y ==> f x < f y"
  2048   assume "a < b" hence "f a < f b" by (rule r)
  2049   also assume "f b = c"
  2050   finally (ord_less_eq_trans) show ?thesis .
  2051 qed
  2052 
  2053 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2054   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2055 proof -
  2056   assume r: "!!x y. x < y ==> f x < f y"
  2057   assume "a = f b"
  2058   also assume "b < c" hence "f b < f c" by (rule r)
  2059   finally (ord_eq_less_trans) show ?thesis .
  2060 qed
  2061 
  2062 text {*
  2063   Note that this list of rules is in reverse order of priorities.
  2064 *}
  2065 
  2066 lemmas basic_trans_rules [trans] =
  2067   order_less_subst2
  2068   order_less_subst1
  2069   order_le_less_subst2
  2070   order_le_less_subst1
  2071   order_less_le_subst2
  2072   order_less_le_subst1
  2073   order_subst2
  2074   order_subst1
  2075   ord_le_eq_subst
  2076   ord_eq_le_subst
  2077   ord_less_eq_subst
  2078   ord_eq_less_subst
  2079   forw_subst
  2080   back_subst
  2081   rev_mp
  2082   mp
  2083   set_rev_mp
  2084   set_mp
  2085   order_neq_le_trans
  2086   order_le_neq_trans
  2087   order_less_trans
  2088   order_less_asym'
  2089   order_le_less_trans
  2090   order_less_le_trans
  2091   order_trans
  2092   order_antisym
  2093   ord_le_eq_trans
  2094   ord_eq_le_trans
  2095   ord_less_eq_trans
  2096   ord_eq_less_trans
  2097   trans
  2098 
  2099 end