src/HOL/Set.ML
author paulson
Fri Nov 05 12:47:29 1999 +0100 (1999-11-05)
changeset 8001 14c8843cd35b
parent 7969 7a20317850ab
child 8005 b64d86018785
permissions -rw-r--r--
new psubset lemma
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 bind_thm ("CollectE", make_elim CollectD);
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> ? x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(? x:A. P) = ((? x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (! x:A. P(x)) = (! x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (? x:A. P(x)) = (? x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("op ``", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   156 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   157 qed "contra_subsetD";
   158 
   159 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   160 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   161 qed "rev_contra_subsetD";
   162 
   163 (*Classical elimination rule*)
   164 val major::prems = Goalw [subset_def] 
   165     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   166 by (rtac (major RS ballE) 1);
   167 by (REPEAT (eresolve_tac prems 1));
   168 qed "subsetCE";
   169 
   170 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   171 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   172 
   173 AddSIs [subsetI];
   174 AddEs  [subsetD, subsetCE];
   175 
   176 Goal "A <= (A::'a set)";
   177 by (Fast_tac 1);
   178 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   179 
   180 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   181 by (Blast_tac 1);
   182 qed "subset_trans";
   183 
   184 
   185 section "Equality";
   186 
   187 (*Anti-symmetry of the subset relation*)
   188 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   189 by (rtac set_ext 1);
   190 by (blast_tac (claset() addIs [subsetD]) 1);
   191 qed "subset_antisym";
   192 val equalityI = subset_antisym;
   193 
   194 AddSIs [equalityI];
   195 
   196 (* Equality rules from ZF set theory -- are they appropriate here? *)
   197 Goal "A = B ==> A<=(B::'a set)";
   198 by (etac ssubst 1);
   199 by (rtac subset_refl 1);
   200 qed "equalityD1";
   201 
   202 Goal "A = B ==> B<=(A::'a set)";
   203 by (etac ssubst 1);
   204 by (rtac subset_refl 1);
   205 qed "equalityD2";
   206 
   207 val prems = Goal
   208     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   209 by (resolve_tac prems 1);
   210 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   211 qed "equalityE";
   212 
   213 val major::prems = Goal
   214     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   215 by (rtac (major RS equalityE) 1);
   216 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   217 qed "equalityCE";
   218 
   219 (*Lemma for creating induction formulae -- for "pattern matching" on p
   220   To make the induction hypotheses usable, apply "spec" or "bspec" to
   221   put universal quantifiers over the free variables in p. *)
   222 val prems = Goal 
   223     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   224 by (rtac mp 1);
   225 by (REPEAT (resolve_tac (refl::prems) 1));
   226 qed "setup_induction";
   227 
   228 
   229 section "The universal set -- UNIV";
   230 
   231 Goalw [UNIV_def] "x : UNIV";
   232 by (rtac CollectI 1);
   233 by (rtac TrueI 1);
   234 qed "UNIV_I";
   235 
   236 Addsimps [UNIV_I];
   237 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   238 
   239 Goal "A <= UNIV";
   240 by (rtac subsetI 1);
   241 by (rtac UNIV_I 1);
   242 qed "subset_UNIV";
   243 
   244 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   245     because of their interaction with congruence rules. **)
   246 
   247 Goalw [Ball_def] "Ball UNIV P = All P";
   248 by (Simp_tac 1);
   249 qed "ball_UNIV";
   250 
   251 Goalw [Bex_def] "Bex UNIV P = Ex P";
   252 by (Simp_tac 1);
   253 qed "bex_UNIV";
   254 Addsimps [ball_UNIV, bex_UNIV];
   255 
   256 
   257 section "The empty set -- {}";
   258 
   259 Goalw [empty_def] "(c : {}) = False";
   260 by (Blast_tac 1) ;
   261 qed "empty_iff";
   262 
   263 Addsimps [empty_iff];
   264 
   265 Goal "a:{} ==> P";
   266 by (Full_simp_tac 1);
   267 qed "emptyE";
   268 
   269 AddSEs [emptyE];
   270 
   271 Goal "{} <= A";
   272 by (Blast_tac 1) ;
   273 qed "empty_subsetI";
   274 
   275 (*One effect is to delete the ASSUMPTION {} <= A*)
   276 AddIffs [empty_subsetI];
   277 
   278 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   279 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   280 qed "equals0I";
   281 
   282 (*Use for reasoning about disjointness: A Int B = {} *)
   283 Goal "A={} ==> a ~: A";
   284 by (Blast_tac 1) ;
   285 qed "equals0D";
   286 
   287 AddDs [equals0D, sym RS equals0D];
   288 
   289 Goalw [Ball_def] "Ball {} P = True";
   290 by (Simp_tac 1);
   291 qed "ball_empty";
   292 
   293 Goalw [Bex_def] "Bex {} P = False";
   294 by (Simp_tac 1);
   295 qed "bex_empty";
   296 Addsimps [ball_empty, bex_empty];
   297 
   298 Goal "UNIV ~= {}";
   299 by (blast_tac (claset() addEs [equalityE]) 1);
   300 qed "UNIV_not_empty";
   301 AddIffs [UNIV_not_empty];
   302 
   303 
   304 
   305 section "The Powerset operator -- Pow";
   306 
   307 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   308 by (Asm_simp_tac 1);
   309 qed "Pow_iff";
   310 
   311 AddIffs [Pow_iff]; 
   312 
   313 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   314 by (etac CollectI 1);
   315 qed "PowI";
   316 
   317 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   318 by (etac CollectD 1);
   319 qed "PowD";
   320 
   321 
   322 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   323 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   324 
   325 
   326 section "Set complement";
   327 
   328 Goalw [Compl_def] "(c : -A) = (c~:A)";
   329 by (Blast_tac 1);
   330 qed "Compl_iff";
   331 
   332 Addsimps [Compl_iff];
   333 
   334 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   335 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   336 qed "ComplI";
   337 
   338 (*This form, with negated conclusion, works well with the Classical prover.
   339   Negated assumptions behave like formulae on the right side of the notional
   340   turnstile...*)
   341 Goalw [Compl_def] "c : -A ==> c~:A";
   342 by (etac CollectD 1);
   343 qed "ComplD";
   344 
   345 val ComplE = make_elim ComplD;
   346 
   347 AddSIs [ComplI];
   348 AddSEs [ComplE];
   349 
   350 
   351 section "Binary union -- Un";
   352 
   353 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   354 by (Blast_tac 1);
   355 qed "Un_iff";
   356 Addsimps [Un_iff];
   357 
   358 Goal "c:A ==> c : A Un B";
   359 by (Asm_simp_tac 1);
   360 qed "UnI1";
   361 
   362 Goal "c:B ==> c : A Un B";
   363 by (Asm_simp_tac 1);
   364 qed "UnI2";
   365 
   366 (*Classical introduction rule: no commitment to A vs B*)
   367 
   368 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   369 by (Simp_tac 1);
   370 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   371 qed "UnCI";
   372 
   373 val major::prems = Goalw [Un_def]
   374     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   375 by (rtac (major RS CollectD RS disjE) 1);
   376 by (REPEAT (eresolve_tac prems 1));
   377 qed "UnE";
   378 
   379 AddSIs [UnCI];
   380 AddSEs [UnE];
   381 
   382 
   383 section "Binary intersection -- Int";
   384 
   385 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   386 by (Blast_tac 1);
   387 qed "Int_iff";
   388 Addsimps [Int_iff];
   389 
   390 Goal "[| c:A;  c:B |] ==> c : A Int B";
   391 by (Asm_simp_tac 1);
   392 qed "IntI";
   393 
   394 Goal "c : A Int B ==> c:A";
   395 by (Asm_full_simp_tac 1);
   396 qed "IntD1";
   397 
   398 Goal "c : A Int B ==> c:B";
   399 by (Asm_full_simp_tac 1);
   400 qed "IntD2";
   401 
   402 val [major,minor] = Goal
   403     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   404 by (rtac minor 1);
   405 by (rtac (major RS IntD1) 1);
   406 by (rtac (major RS IntD2) 1);
   407 qed "IntE";
   408 
   409 AddSIs [IntI];
   410 AddSEs [IntE];
   411 
   412 section "Set difference";
   413 
   414 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   415 by (Blast_tac 1);
   416 qed "Diff_iff";
   417 Addsimps [Diff_iff];
   418 
   419 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   420 by (Asm_simp_tac 1) ;
   421 qed "DiffI";
   422 
   423 Goal "c : A - B ==> c : A";
   424 by (Asm_full_simp_tac 1) ;
   425 qed "DiffD1";
   426 
   427 Goal "[| c : A - B;  c : B |] ==> P";
   428 by (Asm_full_simp_tac 1) ;
   429 qed "DiffD2";
   430 
   431 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   432 by (resolve_tac prems 1);
   433 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   434 qed "DiffE";
   435 
   436 AddSIs [DiffI];
   437 AddSEs [DiffE];
   438 
   439 
   440 section "Augmenting a set -- insert";
   441 
   442 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   443 by (Blast_tac 1);
   444 qed "insert_iff";
   445 Addsimps [insert_iff];
   446 
   447 Goal "a : insert a B";
   448 by (Simp_tac 1);
   449 qed "insertI1";
   450 
   451 Goal "!!a. a : B ==> a : insert b B";
   452 by (Asm_simp_tac 1);
   453 qed "insertI2";
   454 
   455 val major::prems = Goalw [insert_def]
   456     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   457 by (rtac (major RS UnE) 1);
   458 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   459 qed "insertE";
   460 
   461 (*Classical introduction rule*)
   462 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   463 by (Simp_tac 1);
   464 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   465 qed "insertCI";
   466 
   467 AddSIs [insertCI]; 
   468 AddSEs [insertE];
   469 
   470 Goal "A <= insert x B ==> A <= B & x ~: A | (? B'. A = insert x B' & B' <= B)";
   471 by (case_tac "x:A" 1);
   472 by  (Fast_tac 2);
   473 by (rtac disjI2 1);
   474 by (res_inst_tac [("x","A-{x}")] exI 1);
   475 by (Fast_tac 1);
   476 qed "subset_insertD";
   477 
   478 section "Singletons, using insert";
   479 
   480 Goal "a : {a}";
   481 by (rtac insertI1 1) ;
   482 qed "singletonI";
   483 
   484 Goal "b : {a} ==> b=a";
   485 by (Blast_tac 1);
   486 qed "singletonD";
   487 
   488 bind_thm ("singletonE", make_elim singletonD);
   489 
   490 Goal "(b : {a}) = (b=a)";
   491 by (Blast_tac 1);
   492 qed "singleton_iff";
   493 
   494 Goal "{a}={b} ==> a=b";
   495 by (blast_tac (claset() addEs [equalityE]) 1);
   496 qed "singleton_inject";
   497 
   498 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   499 AddSIs [singletonI];   
   500 AddSDs [singleton_inject];
   501 AddSEs [singletonE];
   502 
   503 Goal "{b} = insert a A = (a = b & A <= {b})";
   504 by (safe_tac (claset() addSEs [equalityE]));
   505 by   (ALLGOALS Blast_tac);
   506 qed "singleton_insert_inj_eq";
   507 
   508 Goal "(insert a A = {b} ) = (a = b & A <= {b})";
   509 by (rtac (singleton_insert_inj_eq RS (eq_sym_conv RS trans)) 1);
   510 qed "singleton_insert_inj_eq'";
   511 
   512 Goal "A <= {x} ==> A={} | A = {x}";
   513 by (Fast_tac 1);
   514 qed "subset_singletonD";
   515 
   516 Goal "{x. x=a} = {a}";
   517 by (Blast_tac 1);
   518 qed "singleton_conv";
   519 Addsimps [singleton_conv];
   520 
   521 Goal "{x. a=x} = {a}";
   522 by (Blast_tac 1);
   523 qed "singleton_conv2";
   524 Addsimps [singleton_conv2];
   525 
   526 
   527 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   528 
   529 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   530 by (Blast_tac 1);
   531 qed "UN_iff";
   532 
   533 Addsimps [UN_iff];
   534 
   535 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   536 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   537 by Auto_tac;
   538 qed "UN_I";
   539 
   540 val major::prems = Goalw [UNION_def]
   541     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   542 by (rtac (major RS CollectD RS bexE) 1);
   543 by (REPEAT (ares_tac prems 1));
   544 qed "UN_E";
   545 
   546 AddIs  [UN_I];
   547 AddSEs [UN_E];
   548 
   549 val prems = Goalw [UNION_def]
   550     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   551 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   552 by (asm_simp_tac (simpset() addsimps prems) 1);
   553 qed "UN_cong";
   554 
   555 
   556 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   557 
   558 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   559 by Auto_tac;
   560 qed "INT_iff";
   561 
   562 Addsimps [INT_iff];
   563 
   564 val prems = Goalw [INTER_def]
   565     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   566 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   567 qed "INT_I";
   568 
   569 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   570 by Auto_tac;
   571 qed "INT_D";
   572 
   573 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   574 val major::prems = Goalw [INTER_def]
   575     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   576 by (rtac (major RS CollectD RS ballE) 1);
   577 by (REPEAT (eresolve_tac prems 1));
   578 qed "INT_E";
   579 
   580 AddSIs [INT_I];
   581 AddEs  [INT_D, INT_E];
   582 
   583 val prems = Goalw [INTER_def]
   584     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   585 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   586 by (asm_simp_tac (simpset() addsimps prems) 1);
   587 qed "INT_cong";
   588 
   589 
   590 section "Union";
   591 
   592 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   593 by (Blast_tac 1);
   594 qed "Union_iff";
   595 
   596 Addsimps [Union_iff];
   597 
   598 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   599 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   600 by Auto_tac;
   601 qed "UnionI";
   602 
   603 val major::prems = Goalw [Union_def]
   604     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   605 by (rtac (major RS UN_E) 1);
   606 by (REPEAT (ares_tac prems 1));
   607 qed "UnionE";
   608 
   609 AddIs  [UnionI];
   610 AddSEs [UnionE];
   611 
   612 
   613 section "Inter";
   614 
   615 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   616 by (Blast_tac 1);
   617 qed "Inter_iff";
   618 
   619 Addsimps [Inter_iff];
   620 
   621 val prems = Goalw [Inter_def]
   622     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   623 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   624 qed "InterI";
   625 
   626 (*A "destruct" rule -- every X in C contains A as an element, but
   627   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   628 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   629 by Auto_tac;
   630 qed "InterD";
   631 
   632 (*"Classical" elimination rule -- does not require proving X:C *)
   633 val major::prems = Goalw [Inter_def]
   634     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   635 by (rtac (major RS INT_E) 1);
   636 by (REPEAT (eresolve_tac prems 1));
   637 qed "InterE";
   638 
   639 AddSIs [InterI];
   640 AddEs  [InterD, InterE];
   641 
   642 
   643 (*** Image of a set under a function ***)
   644 
   645 (*Frequently b does not have the syntactic form of f(x).*)
   646 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   647 by (Blast_tac 1);
   648 qed "image_eqI";
   649 Addsimps [image_eqI];
   650 
   651 bind_thm ("imageI", refl RS image_eqI);
   652 
   653 (*The eta-expansion gives variable-name preservation.*)
   654 val major::prems = Goalw [image_def]
   655     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   656 by (rtac (major RS CollectD RS bexE) 1);
   657 by (REPEAT (ares_tac prems 1));
   658 qed "imageE";
   659 
   660 AddIs  [image_eqI];
   661 AddSEs [imageE]; 
   662 
   663 Goal "f``(A Un B) = f``A Un f``B";
   664 by (Blast_tac 1);
   665 qed "image_Un";
   666 
   667 Goal "(z : f``A) = (EX x:A. z = f x)";
   668 by (Blast_tac 1);
   669 qed "image_iff";
   670 
   671 (*This rewrite rule would confuse users if made default.*)
   672 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   673 by (Blast_tac 1);
   674 qed "image_subset_iff";
   675 
   676 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   677   many existing proofs.*)
   678 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   679 by (blast_tac (claset() addIs prems) 1);
   680 qed "image_subsetI";
   681 
   682 
   683 (*** Range of a function -- just a translation for image! ***)
   684 
   685 Goal "b=f(x) ==> b : range(f)";
   686 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   687 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   688 
   689 bind_thm ("rangeI", UNIV_I RS imageI);
   690 
   691 val [major,minor] = Goal 
   692     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   693 by (rtac (major RS imageE) 1);
   694 by (etac minor 1);
   695 qed "rangeE";
   696 
   697 
   698 (*** Set reasoning tools ***)
   699 
   700 
   701 (** Rewrite rules for boolean case-splitting: faster than 
   702 	addsplits[split_if]
   703 **)
   704 
   705 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   706 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   707 
   708 (*Split ifs on either side of the membership relation.
   709 	Not for Addsimps -- can cause goals to blow up!*)
   710 bind_thm ("split_if_mem1", 
   711     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   712 bind_thm ("split_if_mem2", 
   713     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   714 
   715 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   716 		  split_if_mem1, split_if_mem2];
   717 
   718 
   719 (*Each of these has ALREADY been added to simpset() above.*)
   720 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   721                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   722 
   723 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   724 
   725 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   726 
   727 Addsimps[subset_UNIV, subset_refl];
   728 
   729 
   730 (*** The 'proper subset' relation (<) ***)
   731 
   732 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   733 by (Blast_tac 1);
   734 qed "psubsetI";
   735 AddXIs [psubsetI];
   736 
   737 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   738 by Auto_tac;
   739 qed "psubset_insertD";
   740 
   741 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   742 
   743 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   744 
   745 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   746 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   747 qed "psubset_subset_trans";
   748 
   749 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   750 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   751 qed "subset_psubset_trans";
   752 
   753 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   754 by (Blast_tac 1);
   755 qed "psubset_imp_ex_mem";
   756 
   757 
   758 (* attributes *)
   759 
   760 local
   761 
   762 fun gen_rulify_prems x =
   763   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   764     rule_by_tactic (REPEAT (ALLGOALS (resolve_tac [allI, ballI, impI])))))) x;
   765 
   766 in
   767 
   768 val rulify_prems_attrib_setup =
   769  [Attrib.add_attributes
   770   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   771 
   772 end;