src/HOL/SetInterval.thy
author haftmann
Wed Jun 30 16:46:44 2010 +0200 (2010-06-30)
changeset 37659 14cabf5fa710
parent 37388 793618618f78
child 37664 2946b8f057df
permissions -rw-r--r--
more speaking names
     1 (*  Title:      HOL/SetInterval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory SetInterval
    12 imports Int Nat_Transfer
    13 begin
    14 
    15 context ord
    16 begin
    17 definition
    18   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    19   "{..<u} == {x. x < u}"
    20 
    21 definition
    22   atMost      :: "'a => 'a set" ("(1{.._})") where
    23   "{..u} == {x. x \<le> u}"
    24 
    25 definition
    26   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    27   "{l<..} == {x. l<x}"
    28 
    29 definition
    30   atLeast     :: "'a => 'a set" ("(1{_..})") where
    31   "{l..} == {x. l\<le>x}"
    32 
    33 definition
    34   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    35   "{l<..<u} == {l<..} Int {..<u}"
    36 
    37 definition
    38   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    39   "{l..<u} == {l..} Int {..<u}"
    40 
    41 definition
    42   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    43   "{l<..u} == {l<..} Int {..u}"
    44 
    45 definition
    46   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    47   "{l..u} == {l..} Int {..u}"
    48 
    49 end
    50 
    51 
    52 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    53 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    54 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    55 
    56 syntax
    57   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" [0, 0, 10] 10)
    58   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" [0, 0, 10] 10)
    59   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" [0, 0, 10] 10)
    60   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" [0, 0, 10] 10)
    61 
    62 syntax (xsymbols)
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" [0, 0, 10] 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" [0, 0, 10] 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" [0, 0, 10] 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (latex output)
    69   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    70   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" [0, 0, 10] 10)
    71   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    72   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" [0, 0, 10] 10)
    73 
    74 translations
    75   "UN i<=n. A"  == "UN i:{..n}. A"
    76   "UN i<n. A"   == "UN i:{..<n}. A"
    77   "INT i<=n. A" == "INT i:{..n}. A"
    78   "INT i<n. A"  == "INT i:{..<n}. A"
    79 
    80 
    81 subsection {* Various equivalences *}
    82 
    83 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    84 by (simp add: lessThan_def)
    85 
    86 lemma Compl_lessThan [simp]:
    87     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    88 apply (auto simp add: lessThan_def atLeast_def)
    89 done
    90 
    91 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    92 by auto
    93 
    94 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    95 by (simp add: greaterThan_def)
    96 
    97 lemma Compl_greaterThan [simp]:
    98     "!!k:: 'a::linorder. -greaterThan k = atMost k"
    99   by (auto simp add: greaterThan_def atMost_def)
   100 
   101 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   102 apply (subst Compl_greaterThan [symmetric])
   103 apply (rule double_complement)
   104 done
   105 
   106 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   107 by (simp add: atLeast_def)
   108 
   109 lemma Compl_atLeast [simp]:
   110     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   111   by (auto simp add: lessThan_def atLeast_def)
   112 
   113 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   114 by (simp add: atMost_def)
   115 
   116 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   117 by (blast intro: order_antisym)
   118 
   119 
   120 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   121 
   122 lemma atLeast_subset_iff [iff]:
   123      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   124 by (blast intro: order_trans)
   125 
   126 lemma atLeast_eq_iff [iff]:
   127      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   128 by (blast intro: order_antisym order_trans)
   129 
   130 lemma greaterThan_subset_iff [iff]:
   131      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   132 apply (auto simp add: greaterThan_def)
   133  apply (subst linorder_not_less [symmetric], blast)
   134 done
   135 
   136 lemma greaterThan_eq_iff [iff]:
   137      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   138 apply (rule iffI)
   139  apply (erule equalityE)
   140  apply simp_all
   141 done
   142 
   143 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   144 by (blast intro: order_trans)
   145 
   146 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   147 by (blast intro: order_antisym order_trans)
   148 
   149 lemma lessThan_subset_iff [iff]:
   150      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   151 apply (auto simp add: lessThan_def)
   152  apply (subst linorder_not_less [symmetric], blast)
   153 done
   154 
   155 lemma lessThan_eq_iff [iff]:
   156      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   157 apply (rule iffI)
   158  apply (erule equalityE)
   159  apply simp_all
   160 done
   161 
   162 
   163 subsection {*Two-sided intervals*}
   164 
   165 context ord
   166 begin
   167 
   168 lemma greaterThanLessThan_iff [simp,no_atp]:
   169   "(i : {l<..<u}) = (l < i & i < u)"
   170 by (simp add: greaterThanLessThan_def)
   171 
   172 lemma atLeastLessThan_iff [simp,no_atp]:
   173   "(i : {l..<u}) = (l <= i & i < u)"
   174 by (simp add: atLeastLessThan_def)
   175 
   176 lemma greaterThanAtMost_iff [simp,no_atp]:
   177   "(i : {l<..u}) = (l < i & i <= u)"
   178 by (simp add: greaterThanAtMost_def)
   179 
   180 lemma atLeastAtMost_iff [simp,no_atp]:
   181   "(i : {l..u}) = (l <= i & i <= u)"
   182 by (simp add: atLeastAtMost_def)
   183 
   184 text {* The above four lemmas could be declared as iffs. Unfortunately this
   185 breaks many proofs. Since it only helps blast, it is better to leave well
   186 alone *}
   187 
   188 end
   189 
   190 subsubsection{* Emptyness, singletons, subset *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastatMost_empty[simp]:
   196   "b < a \<Longrightarrow> {a..b} = {}"
   197 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   198 
   199 lemma atLeastatMost_empty_iff[simp]:
   200   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   201 by auto (blast intro: order_trans)
   202 
   203 lemma atLeastatMost_empty_iff2[simp]:
   204   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   205 by auto (blast intro: order_trans)
   206 
   207 lemma atLeastLessThan_empty[simp]:
   208   "b <= a \<Longrightarrow> {a..<b} = {}"
   209 by(auto simp: atLeastLessThan_def)
   210 
   211 lemma atLeastLessThan_empty_iff[simp]:
   212   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   213 by auto (blast intro: le_less_trans)
   214 
   215 lemma atLeastLessThan_empty_iff2[simp]:
   216   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   217 by auto (blast intro: le_less_trans)
   218 
   219 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   220 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   221 
   222 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   223 by auto (blast intro: less_le_trans)
   224 
   225 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   226 by auto (blast intro: less_le_trans)
   227 
   228 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   229 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   230 
   231 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   232 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   233 
   234 lemma atLeastAtMost_singleton': "a = b \<Longrightarrow> {a .. b} = {a}" by simp
   235 
   236 lemma atLeastatMost_subset_iff[simp]:
   237   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   238 unfolding atLeastAtMost_def atLeast_def atMost_def
   239 by (blast intro: order_trans)
   240 
   241 lemma atLeastatMost_psubset_iff:
   242   "{a..b} < {c..d} \<longleftrightarrow>
   243    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   244 by(simp add: psubset_eq expand_set_eq less_le_not_le)(blast intro: order_trans)
   245 
   246 lemma atLeastAtMost_singleton_iff[simp]:
   247   "{a .. b} = {c} \<longleftrightarrow> a = b \<and> b = c"
   248 proof
   249   assume "{a..b} = {c}"
   250   hence "\<not> (\<not> a \<le> b)" unfolding atLeastatMost_empty_iff[symmetric] by simp
   251   moreover with `{a..b} = {c}` have "c \<le> a \<and> b \<le> c" by auto
   252   ultimately show "a = b \<and> b = c" by auto
   253 qed simp
   254 
   255 end
   256 
   257 lemma (in linorder) atLeastLessThan_subset_iff:
   258   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   259 apply (auto simp:subset_eq Ball_def)
   260 apply(frule_tac x=a in spec)
   261 apply(erule_tac x=d in allE)
   262 apply (simp add: less_imp_le)
   263 done
   264 
   265 subsubsection {* Intersection *}
   266 
   267 context linorder
   268 begin
   269 
   270 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   271 by auto
   272 
   273 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   274 by auto
   275 
   276 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   277 by auto
   278 
   279 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   280 by auto
   281 
   282 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   283 by auto
   284 
   285 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   286 by auto
   287 
   288 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   289 by auto
   290 
   291 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   292 by auto
   293 
   294 end
   295 
   296 
   297 subsection {* Intervals of natural numbers *}
   298 
   299 subsubsection {* The Constant @{term lessThan} *}
   300 
   301 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   302 by (simp add: lessThan_def)
   303 
   304 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   305 by (simp add: lessThan_def less_Suc_eq, blast)
   306 
   307 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   308 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   309 
   310 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   311 by blast
   312 
   313 subsubsection {* The Constant @{term greaterThan} *}
   314 
   315 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   316 apply (simp add: greaterThan_def)
   317 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   318 done
   319 
   320 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   321 apply (simp add: greaterThan_def)
   322 apply (auto elim: linorder_neqE)
   323 done
   324 
   325 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   326 by blast
   327 
   328 subsubsection {* The Constant @{term atLeast} *}
   329 
   330 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   331 by (unfold atLeast_def UNIV_def, simp)
   332 
   333 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   334 apply (simp add: atLeast_def)
   335 apply (simp add: Suc_le_eq)
   336 apply (simp add: order_le_less, blast)
   337 done
   338 
   339 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   340   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   341 
   342 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   343 by blast
   344 
   345 subsubsection {* The Constant @{term atMost} *}
   346 
   347 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   348 by (simp add: atMost_def)
   349 
   350 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   351 apply (simp add: atMost_def)
   352 apply (simp add: less_Suc_eq order_le_less, blast)
   353 done
   354 
   355 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   356 by blast
   357 
   358 subsubsection {* The Constant @{term atLeastLessThan} *}
   359 
   360 text{*The orientation of the following 2 rules is tricky. The lhs is
   361 defined in terms of the rhs.  Hence the chosen orientation makes sense
   362 in this theory --- the reverse orientation complicates proofs (eg
   363 nontermination). But outside, when the definition of the lhs is rarely
   364 used, the opposite orientation seems preferable because it reduces a
   365 specific concept to a more general one. *}
   366 
   367 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   368 by(simp add:lessThan_def atLeastLessThan_def)
   369 
   370 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   371 by(simp add:atMost_def atLeastAtMost_def)
   372 
   373 declare atLeast0LessThan[symmetric, code_unfold]
   374         atLeast0AtMost[symmetric, code_unfold]
   375 
   376 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   377 by (simp add: atLeastLessThan_def)
   378 
   379 subsubsection {* Intervals of nats with @{term Suc} *}
   380 
   381 text{*Not a simprule because the RHS is too messy.*}
   382 lemma atLeastLessThanSuc:
   383     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   384 by (auto simp add: atLeastLessThan_def)
   385 
   386 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   387 by (auto simp add: atLeastLessThan_def)
   388 (*
   389 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   390 by (induct k, simp_all add: atLeastLessThanSuc)
   391 
   392 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   393 by (auto simp add: atLeastLessThan_def)
   394 *)
   395 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   396   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   397 
   398 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   399   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   400     greaterThanAtMost_def)
   401 
   402 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   403   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   404     greaterThanLessThan_def)
   405 
   406 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   407 by (auto simp add: atLeastAtMost_def)
   408 
   409 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   410   apply (induct k) 
   411   apply (simp_all add: atLeastLessThanSuc)   
   412   done
   413 
   414 subsubsection {* Image *}
   415 
   416 lemma image_add_atLeastAtMost:
   417   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   418 proof
   419   show "?A \<subseteq> ?B" by auto
   420 next
   421   show "?B \<subseteq> ?A"
   422   proof
   423     fix n assume a: "n : ?B"
   424     hence "n - k : {i..j}" by auto
   425     moreover have "n = (n - k) + k" using a by auto
   426     ultimately show "n : ?A" by blast
   427   qed
   428 qed
   429 
   430 lemma image_add_atLeastLessThan:
   431   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   432 proof
   433   show "?A \<subseteq> ?B" by auto
   434 next
   435   show "?B \<subseteq> ?A"
   436   proof
   437     fix n assume a: "n : ?B"
   438     hence "n - k : {i..<j}" by auto
   439     moreover have "n = (n - k) + k" using a by auto
   440     ultimately show "n : ?A" by blast
   441   qed
   442 qed
   443 
   444 corollary image_Suc_atLeastAtMost[simp]:
   445   "Suc ` {i..j} = {Suc i..Suc j}"
   446 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   447 
   448 corollary image_Suc_atLeastLessThan[simp]:
   449   "Suc ` {i..<j} = {Suc i..<Suc j}"
   450 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   451 
   452 lemma image_add_int_atLeastLessThan:
   453     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   454   apply (auto simp add: image_def)
   455   apply (rule_tac x = "x - l" in bexI)
   456   apply auto
   457   done
   458 
   459 context ordered_ab_group_add
   460 begin
   461 
   462 lemma
   463   fixes x :: 'a
   464   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   465   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   466 proof safe
   467   fix y assume "y < -x"
   468   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   469   have "- (-y) \<in> uminus ` {x<..}"
   470     by (rule imageI) (simp add: *)
   471   thus "y \<in> uminus ` {x<..}" by simp
   472 next
   473   fix y assume "y \<le> -x"
   474   have "- (-y) \<in> uminus ` {x..}"
   475     by (rule imageI) (insert `y \<le> -x`[THEN le_imp_neg_le], simp)
   476   thus "y \<in> uminus ` {x..}" by simp
   477 qed simp_all
   478 
   479 lemma
   480   fixes x :: 'a
   481   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   482   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   483 proof -
   484   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   485     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   486   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   487     by (simp_all add: image_image
   488         del: image_uminus_greaterThan image_uminus_atLeast)
   489 qed
   490 
   491 lemma
   492   fixes x :: 'a
   493   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   494   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   495   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   496   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   497   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   498       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   499 end
   500 
   501 subsubsection {* Finiteness *}
   502 
   503 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   504   by (induct k) (simp_all add: lessThan_Suc)
   505 
   506 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   507   by (induct k) (simp_all add: atMost_Suc)
   508 
   509 lemma finite_greaterThanLessThan [iff]:
   510   fixes l :: nat shows "finite {l<..<u}"
   511 by (simp add: greaterThanLessThan_def)
   512 
   513 lemma finite_atLeastLessThan [iff]:
   514   fixes l :: nat shows "finite {l..<u}"
   515 by (simp add: atLeastLessThan_def)
   516 
   517 lemma finite_greaterThanAtMost [iff]:
   518   fixes l :: nat shows "finite {l<..u}"
   519 by (simp add: greaterThanAtMost_def)
   520 
   521 lemma finite_atLeastAtMost [iff]:
   522   fixes l :: nat shows "finite {l..u}"
   523 by (simp add: atLeastAtMost_def)
   524 
   525 text {* A bounded set of natural numbers is finite. *}
   526 lemma bounded_nat_set_is_finite:
   527   "(ALL i:N. i < (n::nat)) ==> finite N"
   528 apply (rule finite_subset)
   529  apply (rule_tac [2] finite_lessThan, auto)
   530 done
   531 
   532 text {* A set of natural numbers is finite iff it is bounded. *}
   533 lemma finite_nat_set_iff_bounded:
   534   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   535 proof
   536   assume f:?F  show ?B
   537     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   538 next
   539   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   540 qed
   541 
   542 lemma finite_nat_set_iff_bounded_le:
   543   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   544 apply(simp add:finite_nat_set_iff_bounded)
   545 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   546 done
   547 
   548 lemma finite_less_ub:
   549      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   550 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   551 
   552 text{* Any subset of an interval of natural numbers the size of the
   553 subset is exactly that interval. *}
   554 
   555 lemma subset_card_intvl_is_intvl:
   556   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   557 proof cases
   558   assume "finite A"
   559   thus "PROP ?P"
   560   proof(induct A rule:finite_linorder_max_induct)
   561     case empty thus ?case by auto
   562   next
   563     case (insert b A)
   564     moreover hence "b ~: A" by auto
   565     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   566       using `b ~: A` insert by fastsimp+
   567     ultimately show ?case by auto
   568   qed
   569 next
   570   assume "~finite A" thus "PROP ?P" by simp
   571 qed
   572 
   573 
   574 subsubsection {* Proving Inclusions and Equalities between Unions *}
   575 
   576 lemma UN_le_eq_Un0:
   577   "(\<Union>i\<le>n::nat. M i) = (\<Union>i\<in>{1..n}. M i) \<union> M 0" (is "?A = ?B")
   578 proof
   579   show "?A <= ?B"
   580   proof
   581     fix x assume "x : ?A"
   582     then obtain i where i: "i\<le>n" "x : M i" by auto
   583     show "x : ?B"
   584     proof(cases i)
   585       case 0 with i show ?thesis by simp
   586     next
   587       case (Suc j) with i show ?thesis by auto
   588     qed
   589   qed
   590 next
   591   show "?B <= ?A" by auto
   592 qed
   593 
   594 lemma UN_le_add_shift:
   595   "(\<Union>i\<le>n::nat. M(i+k)) = (\<Union>i\<in>{k..n+k}. M i)" (is "?A = ?B")
   596 proof
   597   show "?A <= ?B" by fastsimp
   598 next
   599   show "?B <= ?A"
   600   proof
   601     fix x assume "x : ?B"
   602     then obtain i where i: "i : {k..n+k}" "x : M(i)" by auto
   603     hence "i-k\<le>n & x : M((i-k)+k)" by auto
   604     thus "x : ?A" by blast
   605   qed
   606 qed
   607 
   608 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
   609   by (auto simp add: atLeast0LessThan) 
   610 
   611 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
   612   by (subst UN_UN_finite_eq [symmetric]) blast
   613 
   614 lemma UN_finite2_subset: 
   615      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
   616   apply (rule UN_finite_subset)
   617   apply (subst UN_UN_finite_eq [symmetric, of B]) 
   618   apply blast
   619   done
   620 
   621 lemma UN_finite2_eq:
   622   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
   623   apply (rule subset_antisym)
   624    apply (rule UN_finite2_subset, blast)
   625  apply (rule UN_finite2_subset [where k=k])
   626  apply (force simp add: atLeastLessThan_add_Un [of 0])
   627  done
   628 
   629 
   630 subsubsection {* Cardinality *}
   631 
   632 lemma card_lessThan [simp]: "card {..<u} = u"
   633   by (induct u, simp_all add: lessThan_Suc)
   634 
   635 lemma card_atMost [simp]: "card {..u} = Suc u"
   636   by (simp add: lessThan_Suc_atMost [THEN sym])
   637 
   638 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   639   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   640   apply (erule ssubst, rule card_lessThan)
   641   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   642   apply (erule subst)
   643   apply (rule card_image)
   644   apply (simp add: inj_on_def)
   645   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   646   apply (rule_tac x = "x - l" in exI)
   647   apply arith
   648   done
   649 
   650 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   651   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   652 
   653 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   654   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   655 
   656 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   657   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   658 
   659 lemma ex_bij_betw_nat_finite:
   660   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   661 apply(drule finite_imp_nat_seg_image_inj_on)
   662 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   663 done
   664 
   665 lemma ex_bij_betw_finite_nat:
   666   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   667 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   668 
   669 lemma finite_same_card_bij:
   670   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   671 apply(drule ex_bij_betw_finite_nat)
   672 apply(drule ex_bij_betw_nat_finite)
   673 apply(auto intro!:bij_betw_trans)
   674 done
   675 
   676 lemma ex_bij_betw_nat_finite_1:
   677   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   678 by (rule finite_same_card_bij) auto
   679 
   680 
   681 subsection {* Intervals of integers *}
   682 
   683 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   684   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   685 
   686 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   687   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   688 
   689 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   690     "{l+1..<u} = {l<..<u::int}"
   691   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   692 
   693 subsubsection {* Finiteness *}
   694 
   695 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   696     {(0::int)..<u} = int ` {..<nat u}"
   697   apply (unfold image_def lessThan_def)
   698   apply auto
   699   apply (rule_tac x = "nat x" in exI)
   700   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
   701   done
   702 
   703 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   704   apply (case_tac "0 \<le> u")
   705   apply (subst image_atLeastZeroLessThan_int, assumption)
   706   apply (rule finite_imageI)
   707   apply auto
   708   done
   709 
   710 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   711   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   712   apply (erule subst)
   713   apply (rule finite_imageI)
   714   apply (rule finite_atLeastZeroLessThan_int)
   715   apply (rule image_add_int_atLeastLessThan)
   716   done
   717 
   718 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   719   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   720 
   721 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   722   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   723 
   724 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   725   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   726 
   727 
   728 subsubsection {* Cardinality *}
   729 
   730 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   731   apply (case_tac "0 \<le> u")
   732   apply (subst image_atLeastZeroLessThan_int, assumption)
   733   apply (subst card_image)
   734   apply (auto simp add: inj_on_def)
   735   done
   736 
   737 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   738   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   739   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   740   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   741   apply (erule subst)
   742   apply (rule card_image)
   743   apply (simp add: inj_on_def)
   744   apply (rule image_add_int_atLeastLessThan)
   745   done
   746 
   747 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   748 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   749 apply (auto simp add: algebra_simps)
   750 done
   751 
   752 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   753 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   754 
   755 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   756 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   757 
   758 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   759 proof -
   760   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   761   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   762 qed
   763 
   764 lemma card_less:
   765 assumes zero_in_M: "0 \<in> M"
   766 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   767 proof -
   768   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   769   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   770 qed
   771 
   772 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   773 apply (rule card_bij_eq [of Suc _ _ "\<lambda>x. x - Suc 0"])
   774 apply simp
   775 apply fastsimp
   776 apply auto
   777 apply (rule inj_on_diff_nat)
   778 apply auto
   779 apply (case_tac x)
   780 apply auto
   781 apply (case_tac xa)
   782 apply auto
   783 apply (case_tac xa)
   784 apply auto
   785 done
   786 
   787 lemma card_less_Suc:
   788   assumes zero_in_M: "0 \<in> M"
   789     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   790 proof -
   791   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   792   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   793     by (auto simp only: insert_Diff)
   794   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   795   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   796     apply (subst card_insert)
   797     apply simp_all
   798     apply (subst b)
   799     apply (subst card_less_Suc2[symmetric])
   800     apply simp_all
   801     done
   802   with c show ?thesis by simp
   803 qed
   804 
   805 
   806 subsection {*Lemmas useful with the summation operator setsum*}
   807 
   808 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   809 
   810 subsubsection {* Disjoint Unions *}
   811 
   812 text {* Singletons and open intervals *}
   813 
   814 lemma ivl_disj_un_singleton:
   815   "{l::'a::linorder} Un {l<..} = {l..}"
   816   "{..<u} Un {u::'a::linorder} = {..u}"
   817   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   818   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   819   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   820   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   821 by auto
   822 
   823 text {* One- and two-sided intervals *}
   824 
   825 lemma ivl_disj_un_one:
   826   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   827   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   828   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   829   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   830   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   831   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   832   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   833   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   834 by auto
   835 
   836 text {* Two- and two-sided intervals *}
   837 
   838 lemma ivl_disj_un_two:
   839   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   840   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   841   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   842   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   843   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   844   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   845   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   846   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   847 by auto
   848 
   849 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   850 
   851 subsubsection {* Disjoint Intersections *}
   852 
   853 text {* One- and two-sided intervals *}
   854 
   855 lemma ivl_disj_int_one:
   856   "{..l::'a::order} Int {l<..<u} = {}"
   857   "{..<l} Int {l..<u} = {}"
   858   "{..l} Int {l<..u} = {}"
   859   "{..<l} Int {l..u} = {}"
   860   "{l<..u} Int {u<..} = {}"
   861   "{l<..<u} Int {u..} = {}"
   862   "{l..u} Int {u<..} = {}"
   863   "{l..<u} Int {u..} = {}"
   864   by auto
   865 
   866 text {* Two- and two-sided intervals *}
   867 
   868 lemma ivl_disj_int_two:
   869   "{l::'a::order<..<m} Int {m..<u} = {}"
   870   "{l<..m} Int {m<..<u} = {}"
   871   "{l..<m} Int {m..<u} = {}"
   872   "{l..m} Int {m<..<u} = {}"
   873   "{l<..<m} Int {m..u} = {}"
   874   "{l<..m} Int {m<..u} = {}"
   875   "{l..<m} Int {m..u} = {}"
   876   "{l..m} Int {m<..u} = {}"
   877   by auto
   878 
   879 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
   880 
   881 subsubsection {* Some Differences *}
   882 
   883 lemma ivl_diff[simp]:
   884  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   885 by(auto)
   886 
   887 
   888 subsubsection {* Some Subset Conditions *}
   889 
   890 lemma ivl_subset [simp,no_atp]:
   891  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   892 apply(auto simp:linorder_not_le)
   893 apply(rule ccontr)
   894 apply(insert linorder_le_less_linear[of i n])
   895 apply(clarsimp simp:linorder_not_le)
   896 apply(fastsimp)
   897 done
   898 
   899 
   900 subsection {* Summation indexed over intervals *}
   901 
   902 syntax
   903   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   904   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   905   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   906   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   907 syntax (xsymbols)
   908   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   909   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   910   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   911   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   912 syntax (HTML output)
   913   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   914   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   915   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   916   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   917 syntax (latex_sum output)
   918   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   919  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   920   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   921  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   922   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   923  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   924   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   925  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   926 
   927 translations
   928   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
   929   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
   930   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
   931   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
   932 
   933 text{* The above introduces some pretty alternative syntaxes for
   934 summation over intervals:
   935 \begin{center}
   936 \begin{tabular}{lll}
   937 Old & New & \LaTeX\\
   938 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   939 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   940 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   941 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   942 \end{tabular}
   943 \end{center}
   944 The left column shows the term before introduction of the new syntax,
   945 the middle column shows the new (default) syntax, and the right column
   946 shows a special syntax. The latter is only meaningful for latex output
   947 and has to be activated explicitly by setting the print mode to
   948 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   949 antiquotations). It is not the default \LaTeX\ output because it only
   950 works well with italic-style formulae, not tt-style.
   951 
   952 Note that for uniformity on @{typ nat} it is better to use
   953 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   954 not provide all lemmas available for @{term"{m..<n}"} also in the
   955 special form for @{term"{..<n}"}. *}
   956 
   957 text{* This congruence rule should be used for sums over intervals as
   958 the standard theorem @{text[source]setsum_cong} does not work well
   959 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   960 the context. *}
   961 
   962 lemma setsum_ivl_cong:
   963  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   964  setsum f {a..<b} = setsum g {c..<d}"
   965 by(rule setsum_cong, simp_all)
   966 
   967 (* FIXME why are the following simp rules but the corresponding eqns
   968 on intervals are not? *)
   969 
   970 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   971 by (simp add:atMost_Suc add_ac)
   972 
   973 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   974 by (simp add:lessThan_Suc add_ac)
   975 
   976 lemma setsum_cl_ivl_Suc[simp]:
   977   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   978 by (auto simp:add_ac atLeastAtMostSuc_conv)
   979 
   980 lemma setsum_op_ivl_Suc[simp]:
   981   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   982 by (auto simp:add_ac atLeastLessThanSuc)
   983 (*
   984 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   985     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   986 by (auto simp:add_ac atLeastAtMostSuc_conv)
   987 *)
   988 
   989 lemma setsum_head:
   990   fixes n :: nat
   991   assumes mn: "m <= n" 
   992   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   993 proof -
   994   from mn
   995   have "{m..n} = {m} \<union> {m<..n}"
   996     by (auto intro: ivl_disj_un_singleton)
   997   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   998     by (simp add: atLeast0LessThan)
   999   also have "\<dots> = ?rhs" by simp
  1000   finally show ?thesis .
  1001 qed
  1002 
  1003 lemma setsum_head_Suc:
  1004   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
  1005 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
  1006 
  1007 lemma setsum_head_upt_Suc:
  1008   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
  1009 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
  1010 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
  1011 done
  1012 
  1013 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
  1014   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1015 proof-
  1016   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
  1017   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
  1018     atLeastSucAtMost_greaterThanAtMost)
  1019 qed
  1020 
  1021 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1022   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
  1023 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
  1024 
  1025 lemma setsum_diff_nat_ivl:
  1026 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1027 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1028   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
  1029 using setsum_add_nat_ivl [of m n p f,symmetric]
  1030 apply (simp add: add_ac)
  1031 done
  1032 
  1033 lemma setsum_natinterval_difff:
  1034   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1035   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1036           (if m <= n then f m - f(n + 1) else 0)"
  1037 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
  1038 
  1039 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
  1040 
  1041 lemma setsum_setsum_restrict:
  1042   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
  1043   by (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
  1044      (rule setsum_commute)
  1045 
  1046 lemma setsum_image_gen: assumes fS: "finite S"
  1047   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1048 proof-
  1049   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
  1050   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
  1051     by simp
  1052   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1053     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
  1054   finally show ?thesis .
  1055 qed
  1056 
  1057 lemma setsum_le_included:
  1058   fixes f :: "'a \<Rightarrow> 'b::ordered_comm_monoid_add"
  1059   assumes "finite s" "finite t"
  1060   and "\<forall>y\<in>t. 0 \<le> g y" "(\<forall>x\<in>s. \<exists>y\<in>t. i y = x \<and> f x \<le> g y)"
  1061   shows "setsum f s \<le> setsum g t"
  1062 proof -
  1063   have "setsum f s \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) s"
  1064   proof (rule setsum_mono)
  1065     fix y assume "y \<in> s"
  1066     with assms obtain z where z: "z \<in> t" "y = i z" "f y \<le> g z" by auto
  1067     with assms show "f y \<le> setsum g {x \<in> t. i x = y}" (is "?A y \<le> ?B y")
  1068       using order_trans[of "?A (i z)" "setsum g {z}" "?B (i z)", intro]
  1069       by (auto intro!: setsum_mono2)
  1070   qed
  1071   also have "... \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) (i ` t)"
  1072     using assms(2-4) by (auto intro!: setsum_mono2 setsum_nonneg)
  1073   also have "... \<le> setsum g t"
  1074     using assms by (auto simp: setsum_image_gen[symmetric])
  1075   finally show ?thesis .
  1076 qed
  1077 
  1078 lemma setsum_multicount_gen:
  1079   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
  1080   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
  1081 proof-
  1082   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
  1083   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
  1084     using assms(3) by auto
  1085   finally show ?thesis .
  1086 qed
  1087 
  1088 lemma setsum_multicount:
  1089   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
  1090   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
  1091 proof-
  1092   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
  1093   also have "\<dots> = ?r" by(simp add: mult_commute)
  1094   finally show ?thesis by auto
  1095 qed
  1096 
  1097 
  1098 subsection{* Shifting bounds *}
  1099 
  1100 lemma setsum_shift_bounds_nat_ivl:
  1101   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1102 by (induct "n", auto simp:atLeastLessThanSuc)
  1103 
  1104 lemma setsum_shift_bounds_cl_nat_ivl:
  1105   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1106 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
  1107 apply (simp add:image_add_atLeastAtMost o_def)
  1108 done
  1109 
  1110 corollary setsum_shift_bounds_cl_Suc_ivl:
  1111   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1112 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1113 
  1114 corollary setsum_shift_bounds_Suc_ivl:
  1115   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1116 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1117 
  1118 lemma setsum_shift_lb_Suc0_0:
  1119   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1120 by(simp add:setsum_head_Suc)
  1121 
  1122 lemma setsum_shift_lb_Suc0_0_upt:
  1123   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1124 apply(cases k)apply simp
  1125 apply(simp add:setsum_head_upt_Suc)
  1126 done
  1127 
  1128 subsection {* The formula for geometric sums *}
  1129 
  1130 lemma geometric_sum:
  1131   assumes "x \<noteq> 1"
  1132   shows "(\<Sum>i=0..<n. x ^ i) = (x ^ n - 1) / (x - 1::'a::field)"
  1133 proof -
  1134   from assms obtain y where "y = x - 1" and "y \<noteq> 0" by simp_all
  1135   moreover have "(\<Sum>i=0..<n. (y + 1) ^ i) = ((y + 1) ^ n - 1) / y"
  1136   proof (induct n)
  1137     case 0 then show ?case by simp
  1138   next
  1139     case (Suc n)
  1140     moreover with `y \<noteq> 0` have "(1 + y) ^ n = (y * inverse y) * (1 + y) ^ n" by simp 
  1141     ultimately show ?case by (simp add: field_simps divide_inverse)
  1142   qed
  1143   ultimately show ?thesis by simp
  1144 qed
  1145 
  1146 
  1147 subsection {* The formula for arithmetic sums *}
  1148 
  1149 lemma gauss_sum:
  1150   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
  1151    of_nat n*((of_nat n)+1)"
  1152 proof (induct n)
  1153   case 0
  1154   show ?case by simp
  1155 next
  1156   case (Suc n)
  1157   then show ?case by (simp add: algebra_simps)
  1158 qed
  1159 
  1160 theorem arith_series_general:
  1161   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1162   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1163 proof cases
  1164   assume ngt1: "n > 1"
  1165   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1166   have
  1167     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1168      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1169     by (rule setsum_addf)
  1170   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1171   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1172     unfolding One_nat_def
  1173     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1174   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
  1175     by (simp add: left_distrib right_distrib)
  1176   also from ngt1 have "{1..<n} = {1..n - 1}"
  1177     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1178   also from ngt1
  1179   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
  1180     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1181        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1182   finally show ?thesis by (simp add: algebra_simps)
  1183 next
  1184   assume "\<not>(n > 1)"
  1185   hence "n = 1 \<or> n = 0" by auto
  1186   thus ?thesis by (auto simp: algebra_simps)
  1187 qed
  1188 
  1189 lemma arith_series_nat:
  1190   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1191 proof -
  1192   have
  1193     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1194     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1195     by (rule arith_series_general)
  1196   thus ?thesis
  1197     unfolding One_nat_def by auto
  1198 qed
  1199 
  1200 lemma arith_series_int:
  1201   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1202   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1203 proof -
  1204   have
  1205     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1206     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1207     by (rule arith_series_general)
  1208   thus ?thesis by simp
  1209 qed
  1210 
  1211 lemma sum_diff_distrib:
  1212   fixes P::"nat\<Rightarrow>nat"
  1213   shows
  1214   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1215   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1216 proof (induct n)
  1217   case 0 show ?case by simp
  1218 next
  1219   case (Suc n)
  1220 
  1221   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1222   let ?rhs = "\<Sum>x<n. P x - Q x"
  1223 
  1224   from Suc have "?lhs = ?rhs" by simp
  1225   moreover
  1226   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1227   moreover
  1228   from Suc have
  1229     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1230     by (subst diff_diff_left[symmetric],
  1231         subst diff_add_assoc2)
  1232        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1233   ultimately
  1234   show ?case by simp
  1235 qed
  1236 
  1237 subsection {* Products indexed over intervals *}
  1238 
  1239 syntax
  1240   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1241   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1242   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1243   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1244 syntax (xsymbols)
  1245   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1246   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1247   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1248   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1249 syntax (HTML output)
  1250   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1251   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1252   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1253   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1254 syntax (latex_prod output)
  1255   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1256  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1257   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1258  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1259   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1260  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1261   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1262  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1263 
  1264 translations
  1265   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1266   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1267   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1268   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1269 
  1270 subsection {* Transfer setup *}
  1271 
  1272 lemma transfer_nat_int_set_functions:
  1273     "{..n} = nat ` {0..int n}"
  1274     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1275   apply (auto simp add: image_def)
  1276   apply (rule_tac x = "int x" in bexI)
  1277   apply auto
  1278   apply (rule_tac x = "int x" in bexI)
  1279   apply auto
  1280   done
  1281 
  1282 lemma transfer_nat_int_set_function_closures:
  1283     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1284   by (simp add: nat_set_def)
  1285 
  1286 declare transfer_morphism_nat_int[transfer add
  1287   return: transfer_nat_int_set_functions
  1288     transfer_nat_int_set_function_closures
  1289 ]
  1290 
  1291 lemma transfer_int_nat_set_functions:
  1292     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1293   by (simp only: is_nat_def transfer_nat_int_set_functions
  1294     transfer_nat_int_set_function_closures
  1295     transfer_nat_int_set_return_embed nat_0_le
  1296     cong: transfer_nat_int_set_cong)
  1297 
  1298 lemma transfer_int_nat_set_function_closures:
  1299     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1300   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1301 
  1302 declare transfer_morphism_int_nat[transfer add
  1303   return: transfer_int_nat_set_functions
  1304     transfer_int_nat_set_function_closures
  1305 ]
  1306 
  1307 end