src/HOL/Binomial.thy
 author haftmann Mon Aug 14 13:46:06 2006 +0200 (2006-08-14) changeset 20380 14f9f2a1caa6 parent 20217 25b068a99d2b permissions -rw-r--r--
simplified code generator setup
1 (*  Title:      HOL/Binomial.thy
2     ID:         \$Id\$
3     Author:     Lawrence C Paulson
4     Copyright   1997  University of Cambridge
5 *)
7 header{*Binomial Coefficients*}
9 theory Binomial
10 imports GCD
11 begin
13 text{*This development is based on the work of Andy Gordon and
14 Florian Kammueller*}
16 consts
17   binomial :: "nat \<Rightarrow> nat \<Rightarrow> nat"      (infixl "choose" 65)
19 primrec
20   binomial_0:   "(0     choose k) = (if k = 0 then 1 else 0)"
22   binomial_Suc: "(Suc n choose k) =
23                  (if k = 0 then 1 else (n choose (k - 1)) + (n choose k))"
25 lemma binomial_n_0 [simp]: "(n choose 0) = 1"
26 by (cases n) simp_all
28 lemma binomial_0_Suc [simp]: "(0 choose Suc k) = 0"
29 by simp
31 lemma binomial_Suc_Suc [simp]:
32      "(Suc n choose Suc k) = (n choose k) + (n choose Suc k)"
33 by simp
35 lemma binomial_eq_0 [rule_format]: "\<forall>k. n < k --> (n choose k) = 0"
36 apply (induct "n")
37 apply auto
38 done
40 declare binomial_0 [simp del] binomial_Suc [simp del]
42 lemma binomial_n_n [simp]: "(n choose n) = 1"
43 apply (induct "n")
44 apply (simp_all add: binomial_eq_0)
45 done
47 lemma binomial_Suc_n [simp]: "(Suc n choose n) = Suc n"
48 by (induct "n", simp_all)
50 lemma binomial_1 [simp]: "(n choose Suc 0) = n"
51 by (induct "n", simp_all)
53 lemma zero_less_binomial [rule_format]: "k \<le> n --> 0 < (n choose k)"
54 by (rule_tac m = n and n = k in diff_induct, simp_all)
56 lemma binomial_eq_0_iff: "(n choose k = 0) = (n<k)"
57 apply (safe intro!: binomial_eq_0)
58 apply (erule contrapos_pp)
59 apply (simp add: zero_less_binomial)
60 done
62 lemma zero_less_binomial_iff: "(0 < n choose k) = (k\<le>n)"
63 by (simp add: linorder_not_less [symmetric] binomial_eq_0_iff [symmetric])
65 (*Might be more useful if re-oriented*)
66 lemma Suc_times_binomial_eq [rule_format]:
67      "\<forall>k. k \<le> n --> Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"
68 apply (induct "n")
69 apply (simp add: binomial_0, clarify)
70 apply (case_tac "k")
71 apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq
72                       binomial_eq_0)
73 done
75 text{*This is the well-known version, but it's harder to use because of the
76   need to reason about division.*}
77 lemma binomial_Suc_Suc_eq_times:
78      "k \<le> n ==> (Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"
79 by (simp add: Suc_times_binomial_eq div_mult_self_is_m zero_less_Suc
80         del: mult_Suc mult_Suc_right)
82 text{*Another version, with -1 instead of Suc.*}
83 lemma times_binomial_minus1_eq:
84      "[|k \<le> n;  0<k|] ==> (n choose k) * k = n * ((n - 1) choose (k - 1))"
85 apply (cut_tac n = "n - 1" and k = "k - 1" in Suc_times_binomial_eq)
86 apply (simp split add: nat_diff_split, auto)
87 done
89 subsubsection {* Theorems about @{text "choose"} *}
91 text {*
92   \medskip Basic theorem about @{text "choose"}.  By Florian
93   Kamm\"uller, tidied by LCP.
94 *}
96 lemma card_s_0_eq_empty:
97     "finite A ==> card {B. B \<subseteq> A & card B = 0} = 1"
98   apply (simp cong add: conj_cong add: finite_subset [THEN card_0_eq])
99   apply (simp cong add: rev_conj_cong)
100   done
102 lemma choose_deconstruct: "finite M ==> x \<notin> M
103   ==> {s. s <= insert x M & card(s) = Suc k}
104        = {s. s <= M & card(s) = Suc k} Un
105          {s. EX t. t <= M & card(t) = k & s = insert x t}"
106   apply safe
107    apply (auto intro: finite_subset [THEN card_insert_disjoint])
108   apply (drule_tac x = "xa - {x}" in spec)
109   apply (subgoal_tac "x \<notin> xa", auto)
110   apply (erule rev_mp, subst card_Diff_singleton)
111   apply (auto intro: finite_subset)
112   done
114 text{*There are as many subsets of @{term A} having cardinality @{term k}
115  as there are sets obtained from the former by inserting a fixed element
116  @{term x} into each.*}
117 lemma constr_bij:
118    "[|finite A; x \<notin> A|] ==>
119     card {B. EX C. C <= A & card(C) = k & B = insert x C} =
120     card {B. B <= A & card(B) = k}"
121   apply (rule_tac f = "%s. s - {x}" and g = "insert x" in card_bij_eq)
122        apply (auto elim!: equalityE simp add: inj_on_def)
123     apply (subst Diff_insert0, auto)
124    txt {* finiteness of the two sets *}
125    apply (rule_tac [2] B = "Pow (A)" in finite_subset)
126    apply (rule_tac B = "Pow (insert x A)" in finite_subset)
127    apply fast+
128   done
130 text {*
131   Main theorem: combinatorial statement about number of subsets of a set.
132 *}
134 lemma n_sub_lemma:
135   "!!A. finite A ==> card {B. B <= A & card B = k} = (card A choose k)"
136   apply (induct k)
137    apply (simp add: card_s_0_eq_empty, atomize)
138   apply (rotate_tac -1, erule finite_induct)
139    apply (simp_all (no_asm_simp) cong add: conj_cong
140      add: card_s_0_eq_empty choose_deconstruct)
141   apply (subst card_Un_disjoint)
142      prefer 4 apply (force simp add: constr_bij)
143     prefer 3 apply force
144    prefer 2 apply (blast intro: finite_Pow_iff [THEN iffD2]
145      finite_subset [of _ "Pow (insert x F)", standard])
146   apply (blast intro: finite_Pow_iff [THEN iffD2, THEN [2] finite_subset])
147   done
149 theorem n_subsets:
150     "finite A ==> card {B. B <= A & card B = k} = (card A choose k)"
151   by (simp add: n_sub_lemma)
154 text{* The binomial theorem (courtesy of Tobias Nipkow): *}
156 theorem binomial: "(a+b::nat)^n = (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
157 proof (induct n)
158   case 0 thus ?case by simp
159 next
160   case (Suc n)
161   have decomp: "{0..n+1} = {0} \<union> {n+1} \<union> {1..n}"
162     by (auto simp add:atLeastAtMost_def atLeast_def atMost_def)
163   have decomp2: "{0..n} = {0} \<union> {1..n}"
164     by (auto simp add:atLeastAtMost_def atLeast_def atMost_def)
165   have "(a+b::nat)^(n+1) = (a+b) * (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
166     using Suc by simp
167   also have "\<dots> =  a*(\<Sum>k=0..n. (n choose k) * a^k * b^(n-k)) +
168                    b*(\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
169     by(rule nat_distrib)
170   also have "\<dots> = (\<Sum>k=0..n. (n choose k) * a^(k+1) * b^(n-k)) +
171                   (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k+1))"
172     by(simp add: setsum_right_distrib mult_ac)
173   also have "\<dots> = (\<Sum>k=0..n. (n choose k) * a^k * b^(n+1-k)) +
174                   (\<Sum>k=1..n+1. (n choose (k - 1)) * a^k * b^(n+1-k))"
175     by (simp add:setsum_shift_bounds_cl_Suc_ivl Suc_diff_le
176              del:setsum_cl_ivl_Suc)
177   also have "\<dots> = a^(n+1) + b^(n+1) +
178                   (\<Sum>k=1..n. (n choose (k - 1)) * a^k * b^(n+1-k)) +
179                   (\<Sum>k=1..n. (n choose k) * a^k * b^(n+1-k))"
180     by(simp add: decomp2)
181   also have
182     "\<dots> = a^(n+1) + b^(n+1) + (\<Sum>k=1..n. (n+1 choose k) * a^k * b^(n+1-k))"
183     by(simp add: nat_distrib setsum_addf binomial.simps)
184   also have "\<dots> = (\<Sum>k=0..n+1. (n+1 choose k) * a^k * b^(n+1-k))"
185     using decomp by simp
186   finally show ?case by simp
187 qed
189 end