src/HOL/Map.thy
author haftmann
Mon Aug 14 13:46:06 2006 +0200 (2006-08-14)
changeset 20380 14f9f2a1caa6
parent 19947 29b376397cd5
child 20800 69c82605efcf
permissions -rw-r--r--
simplified code generator setup
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 syntax (xsymbols)
    19   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    20 
    21 abbreviation
    22   empty     ::  "'a ~=> 'b"
    23   "empty == %x. None"
    24 
    25 definition
    26   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "o'_m" 55)
    27   "f o_m g  == (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    28 
    29 const_syntax (xsymbols)
    30   map_comp  (infixl "\<circ>\<^sub>m" 55)
    31 
    32 consts
    33 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    34 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" (infixl "|`"  110)
    35 dom	:: "('a ~=> 'b) => 'a set"
    36 ran	:: "('a ~=> 'b) => 'b set"
    37 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    38 map_upds:: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    39 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    40 
    41 const_syntax (latex output)
    42   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    43 
    44 nonterminals
    45   maplets maplet
    46 
    47 syntax
    48   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    49   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    50   ""         :: "maplet => maplets"             ("_")
    51   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    52   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    53   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    54 
    55 syntax (xsymbols)
    56   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    57   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    58 
    59 translations
    60   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    61   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    62   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    63   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    64   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    65   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    66 
    67 defs
    68 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    69 restrict_map_def: "m|`A == %x. if x : A then m x else None"
    70 
    71 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    72 
    73 dom_def: "dom(m) == {a. m a ~= None}"
    74 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    75 
    76 map_le_def: "m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2  ==  ALL a : dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a"
    77 
    78 primrec
    79   "map_of [] = empty"
    80   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    81 
    82 (* special purpose constants that should be defined somewhere else and
    83 whose syntax is a bit odd as well:
    84 
    85  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    86 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    87   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    88 
    89 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    90 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    91 map_subst::"('a ~=> 'b) => 'b => 'b => 
    92 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    93 
    94 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    95 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    96 
    97   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    98 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
    99   map_subst :: "('a ~=> 'b) => 'b => 'b => 
   100 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
   101 
   102 
   103 subsection {* @{term [source] map_upd_s} *}
   104 
   105 lemma map_upd_s_apply [simp]: 
   106   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   107 by (simp add: map_upd_s_def)
   108 
   109 lemma map_subst_apply [simp]: 
   110   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   111 by (simp add: map_subst_def)
   112 
   113 *)
   114 
   115 subsection {* @{term [source] empty} *}
   116 
   117 lemma empty_upd_none[simp]: "empty(x := None) = empty"
   118 apply (rule ext)
   119 apply (simp (no_asm))
   120 done
   121 
   122 
   123 (* FIXME: what is this sum_case nonsense?? *)
   124 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   125 apply (rule ext)
   126 apply (simp (no_asm) split add: sum.split)
   127 done
   128 
   129 subsection {* @{term [source] map_upd} *}
   130 
   131 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   132 apply (rule ext)
   133 apply (simp (no_asm_simp))
   134 done
   135 
   136 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   137 apply safe
   138 apply (drule_tac x = k in fun_cong)
   139 apply (simp (no_asm_use))
   140 done
   141 
   142 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   143 by (drule fun_cong [of _ _ a], auto)
   144 
   145 lemma map_upd_Some_unfold: 
   146   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   147 by auto
   148 
   149 lemma image_map_upd[simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   150 by fastsimp
   151 
   152 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   153 apply (unfold image_def)
   154 apply (simp (no_asm_use) add: full_SetCompr_eq)
   155 apply (rule finite_subset)
   156 prefer 2 apply assumption
   157 apply auto
   158 done
   159 
   160 
   161 (* FIXME: what is this sum_case nonsense?? *)
   162 subsection {* @{term [source] sum_case} and @{term [source] empty}/@{term [source] map_upd} *}
   163 
   164 lemma sum_case_map_upd_empty[simp]:
   165  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   166 apply (rule ext)
   167 apply (simp (no_asm) split add: sum.split)
   168 done
   169 
   170 lemma sum_case_empty_map_upd[simp]:
   171  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   172 apply (rule ext)
   173 apply (simp (no_asm) split add: sum.split)
   174 done
   175 
   176 lemma sum_case_map_upd_map_upd[simp]:
   177  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   178 apply (rule ext)
   179 apply (simp (no_asm) split add: sum.split)
   180 done
   181 
   182 
   183 subsection {* @{term [source] map_of} *}
   184 
   185 lemma map_of_eq_None_iff:
   186  "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   187 by (induct xys) simp_all
   188 
   189 lemma map_of_is_SomeD:
   190  "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   191 apply(induct xys)
   192  apply simp
   193 apply(clarsimp split:if_splits)
   194 done
   195 
   196 lemma map_of_eq_Some_iff[simp]:
   197  "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   198 apply(induct xys)
   199  apply(simp)
   200 apply(auto simp:map_of_eq_None_iff[symmetric])
   201 done
   202 
   203 lemma Some_eq_map_of_iff[simp]:
   204  "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   205 by(auto simp del:map_of_eq_Some_iff simp add:map_of_eq_Some_iff[symmetric])
   206 
   207 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   208   \<Longrightarrow> map_of xys x = Some y"
   209 apply (induct xys)
   210  apply simp
   211 apply force
   212 done
   213 
   214 lemma map_of_zip_is_None[simp]:
   215   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   216 by (induct rule:list_induct2, simp_all)
   217 
   218 lemma finite_range_map_of: "finite (range (map_of xys))"
   219 apply (induct xys)
   220 apply  (simp_all (no_asm) add: image_constant)
   221 apply (rule finite_subset)
   222 prefer 2 apply assumption
   223 apply auto
   224 done
   225 
   226 lemma map_of_SomeD [rule_format]: "map_of xs k = Some y --> (k,y):set xs"
   227 by (induct "xs", auto)
   228 
   229 lemma map_of_mapk_SomeI [rule_format]:
   230      "inj f ==> map_of t k = Some x -->  
   231         map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   232 apply (induct "t")
   233 apply  (auto simp add: inj_eq)
   234 done
   235 
   236 lemma weak_map_of_SomeI [rule_format]:
   237      "(k, x) : set l --> (\<exists>x. map_of l k = Some x)"
   238 by (induct "l", auto)
   239 
   240 lemma map_of_filter_in: 
   241 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   242 apply (rule mp)
   243 prefer 2 apply assumption
   244 apply (erule thin_rl)
   245 apply (induct "xs", auto)
   246 done
   247 
   248 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   249 by (induct "xs", auto)
   250 
   251 
   252 subsection {* @{term [source] option_map} related *}
   253 
   254 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   255 apply (rule ext)
   256 apply (simp (no_asm))
   257 done
   258 
   259 lemma option_map_o_map_upd[simp]:
   260  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   261 apply (rule ext)
   262 apply (simp (no_asm))
   263 done
   264 
   265 subsection {* @{term [source] map_comp} related *}
   266 
   267 lemma map_comp_empty [simp]: 
   268   "m \<circ>\<^sub>m empty = empty"
   269   "empty \<circ>\<^sub>m m = empty"
   270   by (auto simp add: map_comp_def intro: ext split: option.splits)
   271 
   272 lemma map_comp_simps [simp]: 
   273   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   274   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'" 
   275   by (auto simp add: map_comp_def)
   276 
   277 lemma map_comp_Some_iff:
   278   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)" 
   279   by (auto simp add: map_comp_def split: option.splits)
   280 
   281 lemma map_comp_None_iff:
   282   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) " 
   283   by (auto simp add: map_comp_def split: option.splits)
   284 
   285 subsection {* @{text "++"} *}
   286 
   287 lemma map_add_empty[simp]: "m ++ empty = m"
   288 apply (unfold map_add_def)
   289 apply (simp (no_asm))
   290 done
   291 
   292 lemma empty_map_add[simp]: "empty ++ m = m"
   293 apply (unfold map_add_def)
   294 apply (rule ext)
   295 apply (simp split add: option.split)
   296 done
   297 
   298 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   299 apply(rule ext)
   300 apply(simp add: map_add_def split:option.split)
   301 done
   302 
   303 lemma map_add_Some_iff: 
   304  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   305 apply (unfold map_add_def)
   306 apply (simp (no_asm) split add: option.split)
   307 done
   308 
   309 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   310 declare map_add_SomeD [dest!]
   311 
   312 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   313 by (subst map_add_Some_iff, fast)
   314 
   315 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   316 apply (unfold map_add_def)
   317 apply (simp (no_asm) split add: option.split)
   318 done
   319 
   320 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   321 apply (unfold map_add_def)
   322 apply (rule ext, auto)
   323 done
   324 
   325 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   326 by(simp add:map_upds_def)
   327 
   328 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   329 apply (unfold map_add_def)
   330 apply (induct "xs")
   331 apply (simp (no_asm))
   332 apply (rule ext)
   333 apply (simp (no_asm_simp) split add: option.split)
   334 done
   335 
   336 declare fun_upd_apply [simp del]
   337 lemma finite_range_map_of_map_add:
   338  "finite (range f) ==> finite (range (f ++ map_of l))"
   339 apply (induct "l", auto)
   340 apply (erule finite_range_updI)
   341 done
   342 declare fun_upd_apply [simp]
   343 
   344 lemma inj_on_map_add_dom[iff]:
   345  "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   346 by(fastsimp simp add:map_add_def dom_def inj_on_def split:option.splits)
   347 
   348 subsection {* @{term [source] restrict_map} *}
   349 
   350 lemma restrict_map_to_empty[simp]: "m|`{} = empty"
   351 by(simp add: restrict_map_def)
   352 
   353 lemma restrict_map_empty[simp]: "empty|`D = empty"
   354 by(simp add: restrict_map_def)
   355 
   356 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   357 by (auto simp: restrict_map_def)
   358 
   359 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   360 by (auto simp: restrict_map_def)
   361 
   362 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   363 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   364 
   365 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   366 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   367 
   368 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   369 by (rule ext, auto simp: restrict_map_def)
   370 
   371 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   372 by (rule ext, auto simp: restrict_map_def)
   373 
   374 lemma restrict_fun_upd[simp]:
   375  "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   376 by(simp add: restrict_map_def expand_fun_eq)
   377 
   378 lemma fun_upd_None_restrict[simp]:
   379   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   380 by(simp add: restrict_map_def expand_fun_eq)
   381 
   382 lemma fun_upd_restrict:
   383  "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   384 by(simp add: restrict_map_def expand_fun_eq)
   385 
   386 lemma fun_upd_restrict_conv[simp]:
   387  "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   388 by(simp add: restrict_map_def expand_fun_eq)
   389 
   390 
   391 subsection {* @{term [source] map_upds} *}
   392 
   393 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   394 by(simp add:map_upds_def)
   395 
   396 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   397 by(simp add:map_upds_def)
   398 
   399 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   400 by(simp add:map_upds_def)
   401 
   402 lemma map_upds_append1[simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   403   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   404 apply(induct xs)
   405  apply(clarsimp simp add:neq_Nil_conv)
   406 apply (case_tac ys, simp, simp)
   407 done
   408 
   409 lemma map_upds_list_update2_drop[simp]:
   410  "\<And>m ys i. \<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   411      \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   412 apply (induct xs, simp)
   413 apply (case_tac ys, simp)
   414 apply(simp split:nat.split)
   415 done
   416 
   417 lemma map_upd_upds_conv_if: "!!x y ys f.
   418  (f(x|->y))(xs [|->] ys) =
   419  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   420                                   else (f(xs [|->] ys))(x|->y))"
   421 apply (induct xs, simp)
   422 apply(case_tac ys)
   423  apply(auto split:split_if simp:fun_upd_twist)
   424 done
   425 
   426 lemma map_upds_twist [simp]:
   427  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   428 apply(insert set_take_subset)
   429 apply (fastsimp simp add: map_upd_upds_conv_if)
   430 done
   431 
   432 lemma map_upds_apply_nontin[simp]:
   433  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   434 apply (induct xs, simp)
   435 apply(case_tac ys)
   436  apply(auto simp: map_upd_upds_conv_if)
   437 done
   438 
   439 lemma fun_upds_append_drop[simp]:
   440   "!!m ys. size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   441 apply(induct xs)
   442  apply (simp)
   443 apply(case_tac ys)
   444 apply simp_all
   445 done
   446 
   447 lemma fun_upds_append2_drop[simp]:
   448   "!!m ys. size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   449 apply(induct xs)
   450  apply (simp)
   451 apply(case_tac ys)
   452 apply simp_all
   453 done
   454 
   455 
   456 lemma restrict_map_upds[simp]: "!!m ys.
   457  \<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   458  \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   459 apply (induct xs, simp)
   460 apply (case_tac ys, simp)
   461 apply(simp add:Diff_insert[symmetric] insert_absorb)
   462 apply(simp add: map_upd_upds_conv_if)
   463 done
   464 
   465 
   466 subsection {* @{term [source] dom} *}
   467 
   468 lemma domI: "m a = Some b ==> a : dom m"
   469 by (unfold dom_def, auto)
   470 (* declare domI [intro]? *)
   471 
   472 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   473 apply (case_tac "m a") 
   474 apply (auto simp add: dom_def) 
   475 done
   476 
   477 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   478 by (unfold dom_def, auto)
   479 declare domIff [simp del]
   480 
   481 lemma dom_empty[simp]: "dom empty = {}"
   482 apply (unfold dom_def)
   483 apply (simp (no_asm))
   484 done
   485 
   486 lemma dom_fun_upd[simp]:
   487  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   488 by (simp add:dom_def) blast
   489 
   490 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   491 apply(induct xys)
   492 apply(auto simp del:fun_upd_apply)
   493 done
   494 
   495 lemma dom_map_of_conv_image_fst:
   496   "dom(map_of xys) = fst ` (set xys)"
   497 by(force simp: dom_map_of)
   498 
   499 lemma dom_map_of_zip[simp]: "[| length xs = length ys; distinct xs |] ==>
   500   dom(map_of(zip xs ys)) = set xs"
   501 by(induct rule: list_induct2, simp_all)
   502 
   503 lemma finite_dom_map_of: "finite (dom (map_of l))"
   504 apply (unfold dom_def)
   505 apply (induct "l")
   506 apply (auto simp add: insert_Collect [symmetric])
   507 done
   508 
   509 lemma dom_map_upds[simp]:
   510  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   511 apply (induct xs, simp)
   512 apply (case_tac ys, auto)
   513 done
   514 
   515 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   516 by (unfold dom_def, auto)
   517 
   518 lemma dom_override_on[simp]:
   519  "dom(override_on f g A) =
   520  (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   521 by(auto simp add: dom_def override_on_def)
   522 
   523 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   524 apply(rule ext)
   525 apply(force simp: map_add_def dom_def split:option.split) 
   526 done
   527 
   528 subsection {* @{term [source] ran} *}
   529 
   530 lemma ranI: "m a = Some b ==> b : ran m" 
   531 by (auto simp add: ran_def)
   532 (* declare ranI [intro]? *)
   533 
   534 lemma ran_empty[simp]: "ran empty = {}"
   535 apply (unfold ran_def)
   536 apply (simp (no_asm))
   537 done
   538 
   539 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   540 apply (unfold ran_def, auto)
   541 apply (subgoal_tac "~ (aa = a) ")
   542 apply auto
   543 done
   544 
   545 subsection {* @{text "map_le"} *}
   546 
   547 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   548 by(simp add:map_le_def)
   549 
   550 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   551 by(force simp add:map_le_def)
   552 
   553 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   554 by(fastsimp simp add:map_le_def)
   555 
   556 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   557 by(force simp add:map_le_def)
   558 
   559 lemma map_le_upds[simp]:
   560  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   561 apply (induct as, simp)
   562 apply (case_tac bs, auto)
   563 done
   564 
   565 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   566   by (fastsimp simp add: map_le_def dom_def)
   567 
   568 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   569   by (simp add: map_le_def)
   570 
   571 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   572   by (auto simp add: map_le_def dom_def)
   573 
   574 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   575   apply (unfold map_le_def)
   576   apply (rule ext)
   577   apply (case_tac "x \<in> dom f", simp)
   578   apply (case_tac "x \<in> dom g", simp, fastsimp)
   579 done
   580 
   581 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   582   by (fastsimp simp add: map_le_def)
   583 
   584 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   585 by(fastsimp simp add:map_add_def map_le_def expand_fun_eq split:option.splits)
   586 
   587 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   588 by (fastsimp simp add: map_le_def map_add_def dom_def)
   589 
   590 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   591 by (clarsimp simp add: map_le_def map_add_def dom_def split:option.splits)
   592 
   593 end