src/HOL/Nat.thy
author haftmann
Mon Aug 14 13:46:06 2006 +0200 (2006-08-14)
changeset 20380 14f9f2a1caa6
parent 20355 50aaae6ae4db
child 20588 c847c56edf0c
permissions -rw-r--r--
simplified code generator setup
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Wellfounded_Recursion Ring_and_Field
    13 begin
    14 
    15 subsection {* Type @{text ind} *}
    16 
    17 typedecl ind
    18 
    19 axiomatization
    20   Zero_Rep :: ind and
    21   Suc_Rep :: "ind => ind"
    22 where
    23   -- {* the axiom of infinity in 2 parts *}
    24   inj_Suc_Rep:          "inj Suc_Rep" and
    25   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    26 
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 consts
    33   Nat :: "ind set"
    34 
    35 inductive Nat
    36 intros
    37   Zero_RepI: "Zero_Rep : Nat"
    38   Suc_RepI: "i : Nat ==> Suc_Rep i : Nat"
    39 
    40 global
    41 
    42 typedef (open Nat)
    43   nat = Nat by (rule exI, rule Nat.Zero_RepI)
    44 
    45 instance nat :: "{ord, zero, one}" ..
    46 
    47 
    48 text {* Abstract constants and syntax *}
    49 
    50 consts
    51   Suc :: "nat => nat"
    52   pred_nat :: "(nat * nat) set"
    53 
    54 local
    55 
    56 defs
    57   Zero_nat_def: "0 == Abs_Nat Zero_Rep"
    58   Suc_def:      "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    59   One_nat_def:  "1 == Suc 0"
    60 
    61   -- {* nat operations *}
    62   pred_nat_def: "pred_nat == {(m, n). n = Suc m}"
    63 
    64   less_def: "m < n == (m, n) : trancl pred_nat"
    65 
    66   le_def: "m \<le> (n::nat) == ~ (n < m)"
    67 
    68 declare One_nat_def [simp]
    69 
    70 
    71 text {* Induction *}
    72 
    73 theorem nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    74   apply (unfold Zero_nat_def Suc_def)
    75   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76   apply (erule Rep_Nat [THEN Nat.induct])
    77   apply (iprover elim: Abs_Nat_inverse [THEN subst])
    78   done
    79 
    80 text {* Distinctness of constructors *}
    81 
    82 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    83   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject Rep_Nat Suc_RepI Zero_RepI
    84                 Suc_Rep_not_Zero_Rep) 
    85 
    86 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    87   by (rule not_sym, rule Suc_not_Zero not_sym)
    88 
    89 lemma Suc_neq_Zero: "Suc m = 0 ==> R"
    90   by (rule notE, rule Suc_not_Zero)
    91 
    92 lemma Zero_neq_Suc: "0 = Suc m ==> R"
    93   by (rule Suc_neq_Zero, erule sym)
    94 
    95 text {* Injectiveness of @{term Suc} *}
    96 
    97 lemma inj_Suc[simp]: "inj_on Suc N"
    98   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat Suc_RepI 
    99                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject) 
   100 
   101 lemma Suc_inject: "Suc x = Suc y ==> x = y"
   102   by (rule inj_Suc [THEN injD])
   103 
   104 lemma Suc_Suc_eq [iff]: "(Suc m = Suc n) = (m = n)"
   105   by (rule inj_Suc [THEN inj_eq])
   106 
   107 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
   108   by auto
   109 
   110 text {* @{typ nat} is a datatype *}
   111 
   112 rep_datatype nat
   113   distinct  Suc_not_Zero Zero_not_Suc
   114   inject    Suc_Suc_eq
   115   induction nat_induct
   116 
   117 lemma n_not_Suc_n: "n \<noteq> Suc n"
   118   by (induct n) simp_all
   119 
   120 lemma Suc_n_not_n: "Suc t \<noteq> t"
   121   by (rule not_sym, rule n_not_Suc_n)
   122 
   123 text {* A special form of induction for reasoning
   124   about @{term "m < n"} and @{term "m - n"} *}
   125 
   126 theorem diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   127     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   128   apply (rule_tac x = m in spec)
   129   apply (induct n)
   130   prefer 2
   131   apply (rule allI)
   132   apply (induct_tac x, iprover+)
   133   done
   134 
   135 subsection {* Basic properties of "less than" *}
   136 
   137 lemma wf_pred_nat: "wf pred_nat"
   138   apply (unfold wf_def pred_nat_def, clarify)
   139   apply (induct_tac x, blast+)
   140   done
   141 
   142 lemma wf_less: "wf {(x, y::nat). x < y}"
   143   apply (unfold less_def)
   144   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_subset], blast)
   145   done
   146 
   147 lemma less_eq: "((m, n) : pred_nat^+) = (m < n)"
   148   apply (unfold less_def)
   149   apply (rule refl)
   150   done
   151 
   152 subsubsection {* Introduction properties *}
   153 
   154 lemma less_trans: "i < j ==> j < k ==> i < (k::nat)"
   155   apply (unfold less_def)
   156   apply (rule trans_trancl [THEN transD], assumption+)
   157   done
   158 
   159 lemma lessI [iff]: "n < Suc n"
   160   apply (unfold less_def pred_nat_def)
   161   apply (simp add: r_into_trancl)
   162   done
   163 
   164 lemma less_SucI: "i < j ==> i < Suc j"
   165   apply (rule less_trans, assumption)
   166   apply (rule lessI)
   167   done
   168 
   169 lemma zero_less_Suc [iff]: "0 < Suc n"
   170   apply (induct n)
   171   apply (rule lessI)
   172   apply (erule less_trans)
   173   apply (rule lessI)
   174   done
   175 
   176 subsubsection {* Elimination properties *}
   177 
   178 lemma less_not_sym: "n < m ==> ~ m < (n::nat)"
   179   apply (unfold less_def)
   180   apply (blast intro: wf_pred_nat wf_trancl [THEN wf_asym])
   181   done
   182 
   183 lemma less_asym:
   184   assumes h1: "(n::nat) < m" and h2: "~ P ==> m < n" shows P
   185   apply (rule contrapos_np)
   186   apply (rule less_not_sym)
   187   apply (rule h1)
   188   apply (erule h2)
   189   done
   190 
   191 lemma less_not_refl: "~ n < (n::nat)"
   192   apply (unfold less_def)
   193   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_not_refl])
   194   done
   195 
   196 lemma less_irrefl [elim!]: "(n::nat) < n ==> R"
   197   by (rule notE, rule less_not_refl)
   198 
   199 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)" by blast
   200 
   201 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   202   by (rule not_sym, rule less_not_refl2)
   203 
   204 lemma lessE:
   205   assumes major: "i < k"
   206   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   207   shows P
   208   apply (rule major [unfolded less_def pred_nat_def, THEN tranclE], simp_all)
   209   apply (erule p1)
   210   apply (rule p2)
   211   apply (simp add: less_def pred_nat_def, assumption)
   212   done
   213 
   214 lemma not_less0 [iff]: "~ n < (0::nat)"
   215   by (blast elim: lessE)
   216 
   217 lemma less_zeroE: "(n::nat) < 0 ==> R"
   218   by (rule notE, rule not_less0)
   219 
   220 lemma less_SucE: assumes major: "m < Suc n"
   221   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   222   apply (rule major [THEN lessE])
   223   apply (rule eq, blast)
   224   apply (rule less, blast)
   225   done
   226 
   227 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   228   by (blast elim!: less_SucE intro: less_trans)
   229 
   230 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   231   by (simp add: less_Suc_eq)
   232 
   233 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   234   by (simp add: less_Suc_eq)
   235 
   236 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   237   by (induct n) (fast elim: less_trans lessE)+
   238 
   239 text {* "Less than" is a linear ordering *}
   240 lemma less_linear: "m < n | m = n | n < (m::nat)"
   241   apply (induct m)
   242   apply (induct n)
   243   apply (rule refl [THEN disjI1, THEN disjI2])
   244   apply (rule zero_less_Suc [THEN disjI1])
   245   apply (blast intro: Suc_mono less_SucI elim: lessE)
   246   done
   247 
   248 text {* "Less than" is antisymmetric, sort of *}
   249 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   250 apply(simp only:less_Suc_eq)
   251 apply blast
   252 done
   253 
   254 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   255   using less_linear by blast
   256 
   257 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   258   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   259   shows "P n m"
   260   apply (rule less_linear [THEN disjE])
   261   apply (erule_tac [2] disjE)
   262   apply (erule lessCase)
   263   apply (erule sym [THEN eqCase])
   264   apply (erule major)
   265   done
   266 
   267 
   268 subsubsection {* Inductive (?) properties *}
   269 
   270 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   271   apply (simp add: nat_neq_iff)
   272   apply (blast elim!: less_irrefl less_SucE elim: less_asym)
   273   done
   274 
   275 lemma Suc_lessD: "Suc m < n ==> m < n"
   276   apply (induct n)
   277   apply (fast intro!: lessI [THEN less_SucI] elim: less_trans lessE)+
   278   done
   279 
   280 lemma Suc_lessE: assumes major: "Suc i < k"
   281   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   282   apply (rule major [THEN lessE])
   283   apply (erule lessI [THEN minor])
   284   apply (erule Suc_lessD [THEN minor], assumption)
   285   done
   286 
   287 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   288   by (blast elim: lessE dest: Suc_lessD)
   289 
   290 lemma Suc_less_eq [iff, code]: "(Suc m < Suc n) = (m < n)"
   291   apply (rule iffI)
   292   apply (erule Suc_less_SucD)
   293   apply (erule Suc_mono)
   294   done
   295 
   296 lemma less_trans_Suc:
   297   assumes le: "i < j" shows "j < k ==> Suc i < k"
   298   apply (induct k, simp_all)
   299   apply (insert le)
   300   apply (simp add: less_Suc_eq)
   301   apply (blast dest: Suc_lessD)
   302   done
   303 
   304 lemma [code]: "((n::nat) < 0) = False" by simp
   305 lemma [code]: "(0 < Suc n) = True" by simp
   306 
   307 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   308 lemma not_less_eq: "(~ m < n) = (n < Suc m)"
   309 by (rule_tac m = m and n = n in diff_induct, simp_all)
   310 
   311 text {* Complete induction, aka course-of-values induction *}
   312 lemma nat_less_induct:
   313   assumes prem: "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   314   apply (rule_tac a=n in wf_induct)
   315   apply (rule wf_pred_nat [THEN wf_trancl])
   316   apply (rule prem)
   317   apply (unfold less_def, assumption)
   318   done
   319 
   320 lemmas less_induct = nat_less_induct [rule_format, case_names less]
   321 
   322 subsection {* Properties of "less than or equal" *}
   323 
   324 text {* Was @{text le_eq_less_Suc}, but this orientation is more useful *}
   325 lemma less_Suc_eq_le: "(m < Suc n) = (m \<le> n)"
   326   by (unfold le_def, rule not_less_eq [symmetric])
   327 
   328 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   329   by (rule less_Suc_eq_le [THEN iffD2])
   330 
   331 lemma le0 [iff]: "(0::nat) \<le> n"
   332   by (unfold le_def, rule not_less0)
   333 
   334 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   335   by (simp add: le_def)
   336 
   337 lemma le_0_eq [iff]: "((i::nat) \<le> 0) = (i = 0)"
   338   by (induct i) (simp_all add: le_def)
   339 
   340 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   341   by (simp del: less_Suc_eq_le add: less_Suc_eq_le [symmetric] less_Suc_eq)
   342 
   343 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   344   by (drule le_Suc_eq [THEN iffD1], iprover+)
   345 
   346 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   347   apply (simp add: le_def less_Suc_eq)
   348   apply (blast elim!: less_irrefl less_asym)
   349   done -- {* formerly called lessD *}
   350 
   351 lemma Suc_leD: "Suc(m) \<le> n ==> m \<le> n"
   352   by (simp add: le_def less_Suc_eq)
   353 
   354 text {* Stronger version of @{text Suc_leD} *}
   355 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   356   apply (simp add: le_def less_Suc_eq)
   357   using less_linear
   358   apply blast
   359   done
   360 
   361 lemma Suc_le_eq: "(Suc m \<le> n) = (m < n)"
   362   by (blast intro: Suc_leI Suc_le_lessD)
   363 
   364 lemma le_SucI: "m \<le> n ==> m \<le> Suc n"
   365   by (unfold le_def) (blast dest: Suc_lessD)
   366 
   367 lemma less_imp_le: "m < n ==> m \<le> (n::nat)"
   368   by (unfold le_def) (blast elim: less_asym)
   369 
   370 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   371 lemmas le_simps = less_imp_le less_Suc_eq_le Suc_le_eq
   372 
   373 
   374 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   375 
   376 lemma le_imp_less_or_eq: "m \<le> n ==> m < n | m = (n::nat)"
   377   apply (unfold le_def)
   378   using less_linear
   379   apply (blast elim: less_irrefl less_asym)
   380   done
   381 
   382 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   383   apply (unfold le_def)
   384   using less_linear
   385   apply (blast elim!: less_irrefl elim: less_asym)
   386   done
   387 
   388 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   389   by (iprover intro: less_or_eq_imp_le le_imp_less_or_eq)
   390 
   391 text {* Useful with @{text Blast}. *}
   392 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   393   by (rule less_or_eq_imp_le, rule disjI2)
   394 
   395 lemma le_refl: "n \<le> (n::nat)"
   396   by (simp add: le_eq_less_or_eq)
   397 
   398 lemma le_less_trans: "[| i \<le> j; j < k |] ==> i < (k::nat)"
   399   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   400 
   401 lemma less_le_trans: "[| i < j; j \<le> k |] ==> i < (k::nat)"
   402   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   403 
   404 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   405   by (blast dest!: le_imp_less_or_eq intro: less_or_eq_imp_le less_trans)
   406 
   407 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   408   by (blast dest!: le_imp_less_or_eq elim!: less_irrefl elim: less_asym)
   409 
   410 lemma Suc_le_mono [iff]: "(Suc n \<le> Suc m) = (n \<le> m)"
   411   by (simp add: le_simps)
   412 
   413 text {* Axiom @{text order_less_le} of class @{text order}: *}
   414 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   415   by (simp add: le_def nat_neq_iff) (blast elim!: less_asym)
   416 
   417 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   418   by (rule iffD2, rule nat_less_le, rule conjI)
   419 
   420 text {* Axiom @{text linorder_linear} of class @{text linorder}: *}
   421 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   422   apply (simp add: le_eq_less_or_eq)
   423   using less_linear
   424   apply blast
   425   done
   426 
   427 text {* Type {@typ nat} is a wellfounded linear order *}
   428 
   429 instance nat :: "{order, linorder, wellorder}"
   430   by intro_classes
   431     (assumption |
   432       rule le_refl le_trans le_anti_sym nat_less_le nat_le_linear wf_less)+
   433 
   434 lemmas linorder_neqE_nat = linorder_neqE[where 'a = nat]
   435 
   436 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   437   by (blast elim!: less_SucE)
   438 
   439 text {*
   440   Rewrite @{term "n < Suc m"} to @{term "n = m"}
   441   if @{term "~ n < m"} or @{term "m \<le> n"} hold.
   442   Not suitable as default simprules because they often lead to looping
   443 *}
   444 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   445   by (rule not_less_less_Suc_eq, rule leD)
   446 
   447 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   448 
   449 
   450 text {*
   451   Re-orientation of the equations @{text "0 = x"} and @{text "1 = x"}. 
   452   No longer added as simprules (they loop) 
   453   but via @{text reorient_simproc} in Bin
   454 *}
   455 
   456 text {* Polymorphic, not just for @{typ nat} *}
   457 lemma zero_reorient: "(0 = x) = (x = 0)"
   458   by auto
   459 
   460 lemma one_reorient: "(1 = x) = (x = 1)"
   461   by auto
   462 
   463 subsection {* Arithmetic operators *}
   464 
   465 axclass power < type
   466 
   467 consts
   468   power :: "('a::power) => nat => 'a"            (infixr "^" 80)
   469 
   470 
   471 text {* arithmetic operators @{text "+ -"} and @{text "*"} *}
   472 
   473 instance nat :: "{plus, minus, times, power}" ..
   474 
   475 text {* size of a datatype value; overloaded *}
   476 consts size :: "'a => nat"
   477 
   478 primrec
   479   add_0:    "0 + n = n"
   480   add_Suc:  "Suc m + n = Suc (m + n)"
   481 
   482 primrec
   483   diff_0:   "m - 0 = m"
   484   diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   485 
   486 primrec
   487   mult_0:   "0 * n = 0"
   488   mult_Suc: "Suc m * n = n + (m * n)"
   489 
   490 text {* These two rules ease the use of primitive recursion. 
   491 NOTE USE OF @{text "=="} *}
   492 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   493   by simp
   494 
   495 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   496   by simp
   497 
   498 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   499   by (case_tac n) simp_all
   500 
   501 lemma gr_implies_not0: "!!n::nat. m<n ==> n \<noteq> 0"
   502   by (case_tac n) simp_all
   503 
   504 lemma neq0_conv [iff]: "!!n::nat. (n \<noteq> 0) = (0 < n)"
   505   by (case_tac n) simp_all
   506 
   507 text {* This theorem is useful with @{text blast} *}
   508 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   509   by (rule iffD1, rule neq0_conv, iprover)
   510 
   511 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   512   by (fast intro: not0_implies_Suc)
   513 
   514 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   515   apply (rule iffI)
   516   apply (rule ccontr, simp_all)
   517   done
   518 
   519 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   520   by (induct m') simp_all
   521 
   522 text {* Useful in certain inductive arguments *}
   523 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   524   by (case_tac m) simp_all
   525 
   526 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   527   apply (rule nat_less_induct)
   528   apply (case_tac n)
   529   apply (case_tac [2] nat)
   530   apply (blast intro: less_trans)+
   531   done
   532 
   533 subsection {* @{text LEAST} theorems for type @{typ nat}*}
   534 
   535 lemma Least_Suc:
   536      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   537   apply (case_tac "n", auto)
   538   apply (frule LeastI)
   539   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   540   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   541   apply (erule_tac [2] Least_le)
   542   apply (case_tac "LEAST x. P x", auto)
   543   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   544   apply (blast intro: order_antisym)
   545   done
   546 
   547 lemma Least_Suc2:
   548      "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   549   by (erule (1) Least_Suc [THEN ssubst], simp)
   550 
   551 
   552 
   553 subsection {* @{term min} and @{term max} *}
   554 
   555 lemma min_0L [simp]: "min 0 n = (0::nat)"
   556   by (rule min_leastL) simp
   557 
   558 lemma min_0R [simp]: "min n 0 = (0::nat)"
   559   by (rule min_leastR) simp
   560 
   561 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   562   by (simp add: min_of_mono)
   563 
   564 lemma max_0L [simp]: "max 0 n = (n::nat)"
   565   by (rule max_leastL) simp
   566 
   567 lemma max_0R [simp]: "max n 0 = (n::nat)"
   568   by (rule max_leastR) simp
   569 
   570 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   571   by (simp add: max_of_mono)
   572 
   573 
   574 subsection {* Basic rewrite rules for the arithmetic operators *}
   575 
   576 text {* Difference *}
   577 
   578 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   579   by (induct n) simp_all
   580 
   581 lemma diff_Suc_Suc [simp, code]: "Suc(m) - Suc(n) = m - n"
   582   by (induct n) simp_all
   583 
   584 
   585 text {*
   586   Could be (and is, below) generalized in various ways
   587   However, none of the generalizations are currently in the simpset,
   588   and I dread to think what happens if I put them in
   589 *}
   590 lemma Suc_pred [simp]: "0 < n ==> Suc (n - Suc 0) = n"
   591   by (simp split add: nat.split)
   592 
   593 declare diff_Suc [simp del, code del]
   594 
   595 
   596 subsection {* Addition *}
   597 
   598 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   599   by (induct m) simp_all
   600 
   601 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   602   by (induct m) simp_all
   603 
   604 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   605   by simp
   606 
   607 
   608 text {* Associative law for addition *}
   609 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   610   by (induct m) simp_all
   611 
   612 text {* Commutative law for addition *}
   613 lemma nat_add_commute: "m + n = n + (m::nat)"
   614   by (induct m) simp_all
   615 
   616 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   617   apply (rule mk_left_commute [of "op +"])
   618   apply (rule nat_add_assoc)
   619   apply (rule nat_add_commute)
   620   done
   621 
   622 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   623   by (induct k) simp_all
   624 
   625 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   626   by (induct k) simp_all
   627 
   628 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   629   by (induct k) simp_all
   630 
   631 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   632   by (induct k) simp_all
   633 
   634 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   635 
   636 lemma add_is_0 [iff]: "!!m::nat. (m + n = 0) = (m = 0 & n = 0)"
   637   by (case_tac m) simp_all
   638 
   639 lemma add_is_1: "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   640   by (case_tac m) simp_all
   641 
   642 lemma one_is_add: "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   643   by (rule trans, rule eq_commute, rule add_is_1)
   644 
   645 lemma add_gr_0 [iff]: "!!m::nat. (0 < m + n) = (0 < m | 0 < n)"
   646   by (simp del: neq0_conv add: neq0_conv [symmetric])
   647 
   648 lemma add_eq_self_zero: "!!m::nat. m + n = m ==> n = 0"
   649   apply (drule add_0_right [THEN ssubst])
   650   apply (simp add: nat_add_assoc del: add_0_right)
   651   done
   652 
   653 
   654 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   655 apply(induct k)
   656  apply simp
   657 apply(drule comp_inj_on[OF _ inj_Suc])
   658 apply (simp add:o_def)
   659 done
   660 
   661 
   662 subsection {* Multiplication *}
   663 
   664 text {* right annihilation in product *}
   665 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   666   by (induct m) simp_all
   667 
   668 text {* right successor law for multiplication *}
   669 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   670   by (induct m) (simp_all add: nat_add_left_commute)
   671 
   672 text {* Commutative law for multiplication *}
   673 lemma nat_mult_commute: "m * n = n * (m::nat)"
   674   by (induct m) simp_all
   675 
   676 text {* addition distributes over multiplication *}
   677 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   678   by (induct m) (simp_all add: nat_add_assoc nat_add_left_commute)
   679 
   680 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   681   by (induct m) (simp_all add: nat_add_assoc)
   682 
   683 text {* Associative law for multiplication *}
   684 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   685   by (induct m) (simp_all add: add_mult_distrib)
   686 
   687 
   688 text{*The naturals form a @{text comm_semiring_1_cancel}*}
   689 instance nat :: comm_semiring_1_cancel
   690 proof
   691   fix i j k :: nat
   692   show "(i + j) + k = i + (j + k)" by (rule nat_add_assoc)
   693   show "i + j = j + i" by (rule nat_add_commute)
   694   show "0 + i = i" by simp
   695   show "(i * j) * k = i * (j * k)" by (rule nat_mult_assoc)
   696   show "i * j = j * i" by (rule nat_mult_commute)
   697   show "1 * i = i" by simp
   698   show "(i + j) * k = i * k + j * k" by (simp add: add_mult_distrib)
   699   show "0 \<noteq> (1::nat)" by simp
   700   assume "k+i = k+j" thus "i=j" by simp
   701 qed
   702 
   703 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   704   apply (induct m)
   705   apply (induct_tac [2] n, simp_all)
   706   done
   707 
   708 subsection {* Monotonicity of Addition *}
   709 
   710 text {* strict, in 1st argument *}
   711 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   712   by (induct k) simp_all
   713 
   714 text {* strict, in both arguments *}
   715 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   716   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   717   apply (induct j, simp_all)
   718   done
   719 
   720 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   721 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   722   apply (induct n)
   723   apply (simp_all add: order_le_less)
   724   apply (blast elim!: less_SucE 
   725                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   726   done
   727 
   728 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   729 lemma mult_less_mono2: "(i::nat) < j ==> 0 < k ==> k * i < k * j"
   730   apply (erule_tac m1 = 0 in less_imp_Suc_add [THEN exE], simp)
   731   apply (induct_tac x) 
   732   apply (simp_all add: add_less_mono)
   733   done
   734 
   735 
   736 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   737 instance nat :: ordered_semidom
   738 proof
   739   fix i j k :: nat
   740   show "0 < (1::nat)" by simp
   741   show "i \<le> j ==> k + i \<le> k + j" by simp
   742   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   743 qed
   744 
   745 lemma nat_mult_1: "(1::nat) * n = n"
   746   by simp
   747 
   748 lemma nat_mult_1_right: "n * (1::nat) = n"
   749   by simp
   750 
   751 
   752 subsection {* Additional theorems about "less than" *}
   753 
   754 text{*An induction rule for estabilishing binary relations*}
   755 lemma less_Suc_induct: 
   756   assumes less:  "i < j"
   757      and  step:  "!!i. P i (Suc i)"
   758      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   759   shows "P i j"
   760 proof -
   761   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add) 
   762   have "P i (Suc(i+k))"
   763   proof (induct k)
   764     case 0 
   765     show ?case by (simp add: step) 
   766   next
   767     case (Suc k)
   768     thus ?case by (auto intro: prems)
   769   qed
   770   thus "P i j" by (simp add: j) 
   771 qed
   772 
   773 
   774 text {* A [clumsy] way of lifting @{text "<"}
   775   monotonicity to @{text "\<le>"} monotonicity *}
   776 lemma less_mono_imp_le_mono:
   777   assumes lt_mono: "!!i j::nat. i < j ==> f i < f j"
   778   and le: "i \<le> j" shows "f i \<le> ((f j)::nat)" using le
   779   apply (simp add: order_le_less)
   780   apply (blast intro!: lt_mono)
   781   done
   782 
   783 text {* non-strict, in 1st argument *}
   784 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   785   by (rule add_right_mono)
   786 
   787 text {* non-strict, in both arguments *}
   788 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   789   by (rule add_mono)
   790 
   791 lemma le_add2: "n \<le> ((m + n)::nat)"
   792   by (insert add_right_mono [of 0 m n], simp) 
   793 
   794 lemma le_add1: "n \<le> ((n + m)::nat)"
   795   by (simp add: add_commute, rule le_add2)
   796 
   797 lemma less_add_Suc1: "i < Suc (i + m)"
   798   by (rule le_less_trans, rule le_add1, rule lessI)
   799 
   800 lemma less_add_Suc2: "i < Suc (m + i)"
   801   by (rule le_less_trans, rule le_add2, rule lessI)
   802 
   803 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   804   by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   805 
   806 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   807   by (rule le_trans, assumption, rule le_add1)
   808 
   809 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   810   by (rule le_trans, assumption, rule le_add2)
   811 
   812 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   813   by (rule less_le_trans, assumption, rule le_add1)
   814 
   815 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   816   by (rule less_le_trans, assumption, rule le_add2)
   817 
   818 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   819   apply (rule le_less_trans [of _ "i+j"]) 
   820   apply (simp_all add: le_add1)
   821   done
   822 
   823 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   824   apply (rule notI)
   825   apply (erule add_lessD1 [THEN less_irrefl])
   826   done
   827 
   828 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   829   by (simp add: add_commute not_add_less1)
   830 
   831 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   832   apply (rule order_trans [of _ "m+k"]) 
   833   apply (simp_all add: le_add1)
   834   done
   835 
   836 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   837   apply (simp add: add_commute)
   838   apply (erule add_leD1)
   839   done
   840 
   841 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   842   by (blast dest: add_leD1 add_leD2)
   843 
   844 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   845 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   846   by (force simp del: add_Suc_right
   847     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   848 
   849 
   850 
   851 subsection {* Difference *}
   852 
   853 lemma diff_self_eq_0 [simp]: "(m::nat) - m = 0"
   854   by (induct m) simp_all
   855 
   856 text {* Addition is the inverse of subtraction:
   857   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   858 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   859   by (induct m n rule: diff_induct) simp_all
   860 
   861 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   862   by (simp add: add_diff_inverse linorder_not_less)
   863 
   864 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   865   by (simp add: le_add_diff_inverse add_commute)
   866 
   867 
   868 subsection {* More results about difference *}
   869 
   870 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   871   by (induct m n rule: diff_induct) simp_all
   872 
   873 lemma diff_less_Suc: "m - n < Suc m"
   874   apply (induct m n rule: diff_induct)
   875   apply (erule_tac [3] less_SucE)
   876   apply (simp_all add: less_Suc_eq)
   877   done
   878 
   879 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   880   by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   881 
   882 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   883   by (rule le_less_trans, rule diff_le_self)
   884 
   885 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   886   by (induct i j rule: diff_induct) simp_all
   887 
   888 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   889   by (simp add: diff_diff_left)
   890 
   891 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   892   apply (case_tac "n", safe)
   893   apply (simp add: le_simps)
   894   done
   895 
   896 text {* This and the next few suggested by Florian Kammueller *}
   897 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   898   by (simp add: diff_diff_left add_commute)
   899 
   900 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   901   by (induct j k rule: diff_induct) simp_all
   902 
   903 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   904   by (simp add: add_commute diff_add_assoc)
   905 
   906 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   907   by (induct n) simp_all
   908 
   909 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   910   by (simp add: diff_add_assoc)
   911 
   912 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   913   apply safe
   914   apply (simp_all add: diff_add_inverse2)
   915   done
   916 
   917 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   918   by (induct m n rule: diff_induct) simp_all
   919 
   920 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   921   by (rule iffD2, rule diff_is_0_eq)
   922 
   923 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   924   by (induct m n rule: diff_induct) simp_all
   925 
   926 lemma less_imp_add_positive: "i < j  ==> \<exists>k::nat. 0 < k & i + k = j"
   927   apply (rule_tac x = "j - i" in exI)
   928   apply (simp (no_asm_simp) add: add_diff_inverse less_not_sym)
   929   done
   930 
   931 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
   932   apply (induct k i rule: diff_induct)
   933   apply (simp_all (no_asm))
   934   apply iprover
   935   done
   936 
   937 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
   938   apply (rule diff_self_eq_0 [THEN subst])
   939   apply (rule zero_induct_lemma, iprover+)
   940   done
   941 
   942 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   943   by (induct k) simp_all
   944 
   945 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   946   by (simp add: diff_cancel add_commute)
   947 
   948 lemma diff_add_0: "n - (n + m) = (0::nat)"
   949   by (induct n) simp_all
   950 
   951 
   952 text {* Difference distributes over multiplication *}
   953 
   954 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   955   by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   956 
   957 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   958   by (simp add: diff_mult_distrib mult_commute [of k])
   959   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   960 
   961 lemmas nat_distrib =
   962   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   963 
   964 
   965 subsection {* Monotonicity of Multiplication *}
   966 
   967 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
   968   by (simp add: mult_right_mono) 
   969 
   970 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
   971   by (simp add: mult_left_mono) 
   972 
   973 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
   974 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
   975   by (simp add: mult_mono) 
   976 
   977 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
   978   by (simp add: mult_strict_right_mono) 
   979 
   980 text{*Differs from the standard @{text zero_less_mult_iff} in that
   981       there are no negative numbers.*}
   982 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
   983   apply (induct m)
   984   apply (case_tac [2] n, simp_all)
   985   done
   986 
   987 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
   988   apply (induct m)
   989   apply (case_tac [2] n, simp_all)
   990   done
   991 
   992 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   993   apply (induct m, simp)
   994   apply (induct n, simp, fastsimp)
   995   done
   996 
   997 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   998   apply (rule trans)
   999   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
  1000   done
  1001 
  1002 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1003   apply (safe intro!: mult_less_mono1)
  1004   apply (case_tac k, auto)
  1005   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1006   apply (blast intro: mult_le_mono1)
  1007   done
  1008 
  1009 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1010   by (simp add: mult_commute [of k])
  1011 
  1012 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1013 by (simp add: linorder_not_less [symmetric], auto)
  1014 
  1015 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1016 by (simp add: linorder_not_less [symmetric], auto)
  1017 
  1018 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
  1019   apply (cut_tac less_linear, safe, auto)
  1020   apply (drule mult_less_mono1, assumption, simp)+
  1021   done
  1022 
  1023 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
  1024   by (simp add: mult_commute [of k])
  1025 
  1026 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1027   by (subst mult_less_cancel1) simp
  1028 
  1029 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1030   by (subst mult_le_cancel1) simp
  1031 
  1032 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
  1033   by (subst mult_cancel1) simp
  1034 
  1035 text {* Lemma for @{text gcd} *}
  1036 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1037   apply (drule sym)
  1038   apply (rule disjCI)
  1039   apply (rule nat_less_cases, erule_tac [2] _)
  1040   apply (fastsimp elim!: less_SucE)
  1041   apply (fastsimp dest: mult_less_mono2)
  1042   done
  1043 
  1044 subsection {* Code generator setup *}
  1045 
  1046 lemma one_is_suc_zero [code inline]:
  1047   "1 = Suc 0"
  1048   by simp
  1049 
  1050 end