src/HOL/Relation.thy
author haftmann
Mon Aug 14 13:46:06 2006 +0200 (2006-08-14)
changeset 20380 14f9f2a1caa6
parent 19656 09be06943252
child 20716 a6686a8e1b68
permissions -rw-r--r--
simplified code generator setup
     1 (*  Title:      HOL/Relation.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 *)
     6 
     7 header {* Relations *}
     8 
     9 theory Relation
    10 imports Product_Type
    11 begin
    12 
    13 subsection {* Definitions *}
    14 
    15 definition
    16   converse :: "('a * 'b) set => ('b * 'a) set"    ("(_^-1)" [1000] 999)
    17   "r^-1 == {(y, x). (x, y) : r}"
    18 
    19 const_syntax (xsymbols)
    20   converse  ("(_\<inverse>)" [1000] 999)
    21 
    22 definition
    23   rel_comp  :: "[('b * 'c) set, ('a * 'b) set] => ('a * 'c) set"  (infixr "O" 60)
    24   "r O s == {(x,z). EX y. (x, y) : s & (y, z) : r}"
    25 
    26   Image :: "[('a * 'b) set, 'a set] => 'b set"                (infixl "``" 90)
    27   "r `` s == {y. EX x:s. (x,y):r}"
    28 
    29   Id    :: "('a * 'a) set"  -- {* the identity relation *}
    30   "Id == {p. EX x. p = (x,x)}"
    31 
    32   diag  :: "'a set => ('a * 'a) set"  -- {* diagonal: identity over a set *}
    33   "diag A == \<Union>x\<in>A. {(x,x)}"
    34 
    35   Domain :: "('a * 'b) set => 'a set"
    36   "Domain r == {x. EX y. (x,y):r}"
    37 
    38   Range  :: "('a * 'b) set => 'b set"
    39   "Range r == Domain(r^-1)"
    40 
    41   Field :: "('a * 'a) set => 'a set"
    42   "Field r == Domain r \<union> Range r"
    43 
    44   refl   :: "['a set, ('a * 'a) set] => bool"  -- {* reflexivity over a set *}
    45   "refl A r == r \<subseteq> A \<times> A & (ALL x: A. (x,x) : r)"
    46 
    47   sym    :: "('a * 'a) set => bool"  -- {* symmetry predicate *}
    48   "sym r == ALL x y. (x,y): r --> (y,x): r"
    49 
    50   antisym:: "('a * 'a) set => bool"  -- {* antisymmetry predicate *}
    51   "antisym r == ALL x y. (x,y):r --> (y,x):r --> x=y"
    52 
    53   trans  :: "('a * 'a) set => bool"  -- {* transitivity predicate *}
    54   "trans r == (ALL x y z. (x,y):r --> (y,z):r --> (x,z):r)"
    55 
    56   single_valued :: "('a * 'b) set => bool"
    57   "single_valued r == ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z)"
    58 
    59   inv_image :: "('b * 'b) set => ('a => 'b) => ('a * 'a) set"
    60   "inv_image r f == {(x, y). (f x, f y) : r}"
    61 
    62 abbreviation
    63   reflexive :: "('a * 'a) set => bool"  -- {* reflexivity over a type *}
    64   "reflexive == refl UNIV"
    65 
    66 
    67 subsection {* The identity relation *}
    68 
    69 lemma IdI [intro]: "(a, a) : Id"
    70   by (simp add: Id_def)
    71 
    72 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
    73   by (unfold Id_def) (iprover elim: CollectE)
    74 
    75 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
    76   by (unfold Id_def) blast
    77 
    78 lemma reflexive_Id: "reflexive Id"
    79   by (simp add: refl_def)
    80 
    81 lemma antisym_Id: "antisym Id"
    82   -- {* A strange result, since @{text Id} is also symmetric. *}
    83   by (simp add: antisym_def)
    84 
    85 lemma sym_Id: "sym Id"
    86   by (simp add: sym_def)
    87 
    88 lemma trans_Id: "trans Id"
    89   by (simp add: trans_def)
    90 
    91 
    92 subsection {* Diagonal: identity over a set *}
    93 
    94 lemma diag_empty [simp]: "diag {} = {}"
    95   by (simp add: diag_def) 
    96 
    97 lemma diag_eqI: "a = b ==> a : A ==> (a, b) : diag A"
    98   by (simp add: diag_def)
    99 
   100 lemma diagI [intro!]: "a : A ==> (a, a) : diag A"
   101   by (rule diag_eqI) (rule refl)
   102 
   103 lemma diagE [elim!]:
   104   "c : diag A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   105   -- {* The general elimination rule. *}
   106   by (unfold diag_def) (iprover elim!: UN_E singletonE)
   107 
   108 lemma diag_iff: "((x, y) : diag A) = (x = y & x : A)"
   109   by blast
   110 
   111 lemma diag_subset_Times: "diag A \<subseteq> A \<times> A"
   112   by blast
   113 
   114 
   115 subsection {* Composition of two relations *}
   116 
   117 lemma rel_compI [intro]:
   118   "(a, b) : s ==> (b, c) : r ==> (a, c) : r O s"
   119   by (unfold rel_comp_def) blast
   120 
   121 lemma rel_compE [elim!]: "xz : r O s ==>
   122   (!!x y z. xz = (x, z) ==> (x, y) : s ==> (y, z) : r  ==> P) ==> P"
   123   by (unfold rel_comp_def) (iprover elim!: CollectE splitE exE conjE)
   124 
   125 lemma rel_compEpair:
   126   "(a, c) : r O s ==> (!!y. (a, y) : s ==> (y, c) : r ==> P) ==> P"
   127   by (iprover elim: rel_compE Pair_inject ssubst)
   128 
   129 lemma R_O_Id [simp]: "R O Id = R"
   130   by fast
   131 
   132 lemma Id_O_R [simp]: "Id O R = R"
   133   by fast
   134 
   135 lemma O_assoc: "(R O S) O T = R O (S O T)"
   136   by blast
   137 
   138 lemma trans_O_subset: "trans r ==> r O r \<subseteq> r"
   139   by (unfold trans_def) blast
   140 
   141 lemma rel_comp_mono: "r' \<subseteq> r ==> s' \<subseteq> s ==> (r' O s') \<subseteq> (r O s)"
   142   by blast
   143 
   144 lemma rel_comp_subset_Sigma:
   145     "s \<subseteq> A \<times> B ==> r \<subseteq> B \<times> C ==> (r O s) \<subseteq> A \<times> C"
   146   by blast
   147 
   148 
   149 subsection {* Reflexivity *}
   150 
   151 lemma reflI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl A r"
   152   by (unfold refl_def) (iprover intro!: ballI)
   153 
   154 lemma reflD: "refl A r ==> a : A ==> (a, a) : r"
   155   by (unfold refl_def) blast
   156 
   157 lemma reflD1: "refl A r ==> (x, y) : r ==> x : A"
   158   by (unfold refl_def) blast
   159 
   160 lemma reflD2: "refl A r ==> (x, y) : r ==> y : A"
   161   by (unfold refl_def) blast
   162 
   163 lemma refl_Int: "refl A r ==> refl B s ==> refl (A \<inter> B) (r \<inter> s)"
   164   by (unfold refl_def) blast
   165 
   166 lemma refl_Un: "refl A r ==> refl B s ==> refl (A \<union> B) (r \<union> s)"
   167   by (unfold refl_def) blast
   168 
   169 lemma refl_INTER:
   170   "ALL x:S. refl (A x) (r x) ==> refl (INTER S A) (INTER S r)"
   171   by (unfold refl_def) fast
   172 
   173 lemma refl_UNION:
   174   "ALL x:S. refl (A x) (r x) \<Longrightarrow> refl (UNION S A) (UNION S r)"
   175   by (unfold refl_def) blast
   176 
   177 lemma refl_diag: "refl A (diag A)"
   178   by (rule reflI [OF diag_subset_Times diagI])
   179 
   180 
   181 subsection {* Antisymmetry *}
   182 
   183 lemma antisymI:
   184   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   185   by (unfold antisym_def) iprover
   186 
   187 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   188   by (unfold antisym_def) iprover
   189 
   190 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   191   by (unfold antisym_def) blast
   192 
   193 lemma antisym_empty [simp]: "antisym {}"
   194   by (unfold antisym_def) blast
   195 
   196 lemma antisym_diag [simp]: "antisym (diag A)"
   197   by (unfold antisym_def) blast
   198 
   199 
   200 subsection {* Symmetry *}
   201 
   202 lemma symI: "(!!a b. (a, b) : r ==> (b, a) : r) ==> sym r"
   203   by (unfold sym_def) iprover
   204 
   205 lemma symD: "sym r ==> (a, b) : r ==> (b, a) : r"
   206   by (unfold sym_def, blast)
   207 
   208 lemma sym_Int: "sym r ==> sym s ==> sym (r \<inter> s)"
   209   by (fast intro: symI dest: symD)
   210 
   211 lemma sym_Un: "sym r ==> sym s ==> sym (r \<union> s)"
   212   by (fast intro: symI dest: symD)
   213 
   214 lemma sym_INTER: "ALL x:S. sym (r x) ==> sym (INTER S r)"
   215   by (fast intro: symI dest: symD)
   216 
   217 lemma sym_UNION: "ALL x:S. sym (r x) ==> sym (UNION S r)"
   218   by (fast intro: symI dest: symD)
   219 
   220 lemma sym_diag [simp]: "sym (diag A)"
   221   by (rule symI) clarify
   222 
   223 
   224 subsection {* Transitivity *}
   225 
   226 lemma transI:
   227   "(!!x y z. (x, y) : r ==> (y, z) : r ==> (x, z) : r) ==> trans r"
   228   by (unfold trans_def) iprover
   229 
   230 lemma transD: "trans r ==> (a, b) : r ==> (b, c) : r ==> (a, c) : r"
   231   by (unfold trans_def) iprover
   232 
   233 lemma trans_Int: "trans r ==> trans s ==> trans (r \<inter> s)"
   234   by (fast intro: transI elim: transD)
   235 
   236 lemma trans_INTER: "ALL x:S. trans (r x) ==> trans (INTER S r)"
   237   by (fast intro: transI elim: transD)
   238 
   239 lemma trans_diag [simp]: "trans (diag A)"
   240   by (fast intro: transI elim: transD)
   241 
   242 
   243 subsection {* Converse *}
   244 
   245 lemma converse_iff [iff]: "((a,b): r^-1) = ((b,a) : r)"
   246   by (simp add: converse_def)
   247 
   248 lemma converseI[sym]: "(a, b) : r ==> (b, a) : r^-1"
   249   by (simp add: converse_def)
   250 
   251 lemma converseD[sym]: "(a,b) : r^-1 ==> (b, a) : r"
   252   by (simp add: converse_def)
   253 
   254 lemma converseE [elim!]:
   255   "yx : r^-1 ==> (!!x y. yx = (y, x) ==> (x, y) : r ==> P) ==> P"
   256     -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   257   by (unfold converse_def) (iprover elim!: CollectE splitE bexE)
   258 
   259 lemma converse_converse [simp]: "(r^-1)^-1 = r"
   260   by (unfold converse_def) blast
   261 
   262 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   263   by blast
   264 
   265 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   266   by blast
   267 
   268 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   269   by blast
   270 
   271 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   272   by fast
   273 
   274 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   275   by blast
   276 
   277 lemma converse_Id [simp]: "Id^-1 = Id"
   278   by blast
   279 
   280 lemma converse_diag [simp]: "(diag A)^-1 = diag A"
   281   by blast
   282 
   283 lemma refl_converse [simp]: "refl A (converse r) = refl A r"
   284   by (unfold refl_def) auto
   285 
   286 lemma sym_converse [simp]: "sym (converse r) = sym r"
   287   by (unfold sym_def) blast
   288 
   289 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   290   by (unfold antisym_def) blast
   291 
   292 lemma trans_converse [simp]: "trans (converse r) = trans r"
   293   by (unfold trans_def) blast
   294 
   295 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   296   by (unfold sym_def) fast
   297 
   298 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   299   by (unfold sym_def) blast
   300 
   301 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   302   by (unfold sym_def) blast
   303 
   304 
   305 subsection {* Domain *}
   306 
   307 lemma Domain_iff: "(a : Domain r) = (EX y. (a, y) : r)"
   308   by (unfold Domain_def) blast
   309 
   310 lemma DomainI [intro]: "(a, b) : r ==> a : Domain r"
   311   by (iprover intro!: iffD2 [OF Domain_iff])
   312 
   313 lemma DomainE [elim!]:
   314   "a : Domain r ==> (!!y. (a, y) : r ==> P) ==> P"
   315   by (iprover dest!: iffD1 [OF Domain_iff])
   316 
   317 lemma Domain_empty [simp]: "Domain {} = {}"
   318   by blast
   319 
   320 lemma Domain_insert: "Domain (insert (a, b) r) = insert a (Domain r)"
   321   by blast
   322 
   323 lemma Domain_Id [simp]: "Domain Id = UNIV"
   324   by blast
   325 
   326 lemma Domain_diag [simp]: "Domain (diag A) = A"
   327   by blast
   328 
   329 lemma Domain_Un_eq: "Domain(A \<union> B) = Domain(A) \<union> Domain(B)"
   330   by blast
   331 
   332 lemma Domain_Int_subset: "Domain(A \<inter> B) \<subseteq> Domain(A) \<inter> Domain(B)"
   333   by blast
   334 
   335 lemma Domain_Diff_subset: "Domain(A) - Domain(B) \<subseteq> Domain(A - B)"
   336   by blast
   337 
   338 lemma Domain_Union: "Domain (Union S) = (\<Union>A\<in>S. Domain A)"
   339   by blast
   340 
   341 lemma Domain_mono: "r \<subseteq> s ==> Domain r \<subseteq> Domain s"
   342   by blast
   343 
   344 
   345 subsection {* Range *}
   346 
   347 lemma Range_iff: "(a : Range r) = (EX y. (y, a) : r)"
   348   by (simp add: Domain_def Range_def)
   349 
   350 lemma RangeI [intro]: "(a, b) : r ==> b : Range r"
   351   by (unfold Range_def) (iprover intro!: converseI DomainI)
   352 
   353 lemma RangeE [elim!]: "b : Range r ==> (!!x. (x, b) : r ==> P) ==> P"
   354   by (unfold Range_def) (iprover elim!: DomainE dest!: converseD)
   355 
   356 lemma Range_empty [simp]: "Range {} = {}"
   357   by blast
   358 
   359 lemma Range_insert: "Range (insert (a, b) r) = insert b (Range r)"
   360   by blast
   361 
   362 lemma Range_Id [simp]: "Range Id = UNIV"
   363   by blast
   364 
   365 lemma Range_diag [simp]: "Range (diag A) = A"
   366   by auto
   367 
   368 lemma Range_Un_eq: "Range(A \<union> B) = Range(A) \<union> Range(B)"
   369   by blast
   370 
   371 lemma Range_Int_subset: "Range(A \<inter> B) \<subseteq> Range(A) \<inter> Range(B)"
   372   by blast
   373 
   374 lemma Range_Diff_subset: "Range(A) - Range(B) \<subseteq> Range(A - B)"
   375   by blast
   376 
   377 lemma Range_Union: "Range (Union S) = (\<Union>A\<in>S. Range A)"
   378   by blast
   379 
   380 
   381 subsection {* Image of a set under a relation *}
   382 
   383 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   384   by (simp add: Image_def)
   385 
   386 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   387   by (simp add: Image_def)
   388 
   389 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   390   by (rule Image_iff [THEN trans]) simp
   391 
   392 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   393   by (unfold Image_def) blast
   394 
   395 lemma ImageE [elim!]:
   396     "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   397   by (unfold Image_def) (iprover elim!: CollectE bexE)
   398 
   399 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   400   -- {* This version's more effective when we already have the required @{text a} *}
   401   by blast
   402 
   403 lemma Image_empty [simp]: "R``{} = {}"
   404   by blast
   405 
   406 lemma Image_Id [simp]: "Id `` A = A"
   407   by blast
   408 
   409 lemma Image_diag [simp]: "diag A `` B = A \<inter> B"
   410   by blast
   411 
   412 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   413   by blast
   414 
   415 lemma Image_Int_eq:
   416      "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   417   by (simp add: single_valued_def, blast) 
   418 
   419 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   420   by blast
   421 
   422 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   423   by blast
   424 
   425 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   426   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   427 
   428 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   429   -- {* NOT suitable for rewriting *}
   430   by blast
   431 
   432 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   433   by blast
   434 
   435 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   436   by blast
   437 
   438 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   439   by blast
   440 
   441 text{*Converse inclusion requires some assumptions*}
   442 lemma Image_INT_eq:
   443      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   444 apply (rule equalityI)
   445  apply (rule Image_INT_subset) 
   446 apply  (simp add: single_valued_def, blast)
   447 done
   448 
   449 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   450   by blast
   451 
   452 
   453 subsection {* Single valued relations *}
   454 
   455 lemma single_valuedI:
   456   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   457   by (unfold single_valued_def)
   458 
   459 lemma single_valuedD:
   460   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   461   by (simp add: single_valued_def)
   462 
   463 lemma single_valued_rel_comp:
   464   "single_valued r ==> single_valued s ==> single_valued (r O s)"
   465   by (unfold single_valued_def) blast
   466 
   467 lemma single_valued_subset:
   468   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   469   by (unfold single_valued_def) blast
   470 
   471 lemma single_valued_Id [simp]: "single_valued Id"
   472   by (unfold single_valued_def) blast
   473 
   474 lemma single_valued_diag [simp]: "single_valued (diag A)"
   475   by (unfold single_valued_def) blast
   476 
   477 
   478 subsection {* Graphs given by @{text Collect} *}
   479 
   480 lemma Domain_Collect_split [simp]: "Domain{(x,y). P x y} = {x. EX y. P x y}"
   481   by auto
   482 
   483 lemma Range_Collect_split [simp]: "Range{(x,y). P x y} = {y. EX x. P x y}"
   484   by auto
   485 
   486 lemma Image_Collect_split [simp]: "{(x,y). P x y} `` A = {y. EX x:A. P x y}"
   487   by auto
   488 
   489 
   490 subsection {* Inverse image *}
   491 
   492 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
   493   by (unfold sym_def inv_image_def) blast
   494 
   495 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
   496   apply (unfold trans_def inv_image_def)
   497   apply (simp (no_asm))
   498   apply blast
   499   done
   500 
   501 end