src/HOL/Wellfounded_Recursion.thy
author haftmann
Mon Aug 14 13:46:06 2006 +0200 (2006-08-14)
changeset 20380 14f9f2a1caa6
parent 20185 183f08468e19
child 20435 d2a30fed7596
permissions -rw-r--r--
simplified code generator setup
     1 (*  ID:         $Id$
     2     Author:     Tobias Nipkow
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {*Well-founded Recursion*}
     7 
     8 theory Wellfounded_Recursion
     9 imports Transitive_Closure
    10 begin
    11 
    12 consts
    13   wfrec_rel :: "('a * 'a) set => (('a => 'b) => 'a => 'b) => ('a * 'b) set"
    14 
    15 inductive "wfrec_rel R F"
    16 intros
    17   wfrecI: "ALL z. (z, x) : R --> (z, g z) : wfrec_rel R F ==>
    18             (x, F g x) : wfrec_rel R F"
    19 
    20 constdefs
    21   wf         :: "('a * 'a)set => bool"
    22   "wf(r) == (!P. (!x. (!y. (y,x):r --> P(y)) --> P(x)) --> (!x. P(x)))"
    23 
    24   acyclic :: "('a*'a)set => bool"
    25   "acyclic r == !x. (x,x) ~: r^+"
    26 
    27   cut        :: "('a => 'b) => ('a * 'a)set => 'a => 'a => 'b"
    28   "cut f r x == (%y. if (y,x):r then f y else arbitrary)"
    29 
    30   adm_wf :: "('a * 'a) set => (('a => 'b) => 'a => 'b) => bool"
    31   "adm_wf R F == ALL f g x.
    32      (ALL z. (z, x) : R --> f z = g z) --> F f x = F g x"
    33 
    34   wfrec :: "('a * 'a) set => (('a => 'b) => 'a => 'b) => 'a => 'b"
    35   "wfrec R F == %x. THE y. (x, y) : wfrec_rel R (%f x. F (cut f R x) x)"
    36 
    37 axclass wellorder \<subseteq> linorder
    38   wf: "wf {(x,y::'a::ord). x<y}"
    39 
    40 
    41 lemma wfUNIVI: 
    42    "(!!P x. (ALL x. (ALL y. (y,x) : r --> P(y)) --> P(x)) ==> P(x)) ==> wf(r)"
    43 by (unfold wf_def, blast)
    44 
    45 text{*Restriction to domain @{term A} and range @{term B}.  If @{term r} is
    46     well-founded over their intersection, then @{term "wf r"}*}
    47 lemma wfI: 
    48  "[| r \<subseteq> A <*> B; 
    49      !!x P. [|\<forall>x. (\<forall>y. (y,x) : r --> P y) --> P x;  x : A; x : B |] ==> P x |]
    50   ==>  wf r"
    51 by (unfold wf_def, blast)
    52 
    53 lemma wf_induct: 
    54     "[| wf(r);           
    55         !!x.[| ALL y. (y,x): r --> P(y) |] ==> P(x)  
    56      |]  ==>  P(a)"
    57 by (unfold wf_def, blast)
    58 
    59 lemmas wf_induct_rule = wf_induct [rule_format, consumes 1, case_names less, induct set: wf]
    60 
    61 lemma wf_not_sym [rule_format]: "wf(r) ==> ALL x. (a,x):r --> (x,a)~:r"
    62 by (erule_tac a=a in wf_induct, blast)
    63 
    64 (* [| wf r;  ~Z ==> (a,x) : r;  (x,a) ~: r ==> Z |] ==> Z *)
    65 lemmas wf_asym = wf_not_sym [elim_format]
    66 
    67 lemma wf_not_refl [simp]: "wf(r) ==> (a,a) ~: r"
    68 by (blast elim: wf_asym)
    69 
    70 (* [| wf r;  (a,a) ~: r ==> PROP W |] ==> PROP W *)
    71 lemmas wf_irrefl = wf_not_refl [elim_format]
    72 
    73 text{*transitive closure of a well-founded relation is well-founded! *}
    74 lemma wf_trancl: "wf(r) ==> wf(r^+)"
    75 apply (subst wf_def, clarify)
    76 apply (rule allE, assumption)
    77   --{*Retains the universal formula for later use!*}
    78 apply (erule mp)
    79 apply (erule_tac a = x in wf_induct)
    80 apply (blast elim: tranclE)
    81 done
    82 
    83 lemma wf_converse_trancl: "wf (r^-1) ==> wf ((r^+)^-1)"
    84 apply (subst trancl_converse [symmetric])
    85 apply (erule wf_trancl)
    86 done
    87 
    88 
    89 subsubsection{*Other simple well-foundedness results*}
    90 
    91 
    92 text{*Minimal-element characterization of well-foundedness*}
    93 lemma wf_eq_minimal: "wf r = (\<forall>Q x. x\<in>Q --> (\<exists>z\<in>Q. \<forall>y. (y,z)\<in>r --> y\<notin>Q))"
    94 proof (intro iffI strip)
    95   fix Q::"'a set" and x
    96   assume "wf r" and "x \<in> Q"
    97   thus "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> r \<longrightarrow> y \<notin> Q"
    98     by (unfold wf_def, 
    99         blast dest: spec [of _ "%x. x\<in>Q \<longrightarrow> (\<exists>z\<in>Q. \<forall>y. (y,z) \<in> r \<longrightarrow> y\<notin>Q)"]) 
   100 next
   101   assume "\<forall>Q x. x \<in> Q \<longrightarrow> (\<exists>z\<in>Q. \<forall>y. (y, z) \<in> r \<longrightarrow> y \<notin> Q)"
   102   thus "wf r" by (unfold wf_def, force)
   103 qed
   104 
   105 text{*Well-foundedness of subsets*}
   106 lemma wf_subset: "[| wf(r);  p<=r |] ==> wf(p)"
   107 apply (simp (no_asm_use) add: wf_eq_minimal)
   108 apply fast
   109 done
   110 
   111 text{*Well-foundedness of the empty relation*}
   112 lemma wf_empty [iff]: "wf({})"
   113 by (simp add: wf_def)
   114 
   115 lemma wf_Int1: "wf r ==> wf (r Int r')"
   116 by (erule wf_subset, rule Int_lower1)
   117 
   118 lemma wf_Int2: "wf r ==> wf (r' Int r)"
   119 by (erule wf_subset, rule Int_lower2)
   120 
   121 text{*Well-foundedness of insert*}
   122 lemma wf_insert [iff]: "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)"
   123 apply (rule iffI)
   124  apply (blast elim: wf_trancl [THEN wf_irrefl]
   125               intro: rtrancl_into_trancl1 wf_subset 
   126                      rtrancl_mono [THEN [2] rev_subsetD])
   127 apply (simp add: wf_eq_minimal, safe)
   128 apply (rule allE, assumption, erule impE, blast) 
   129 apply (erule bexE)
   130 apply (rename_tac "a", case_tac "a = x")
   131  prefer 2
   132 apply blast 
   133 apply (case_tac "y:Q")
   134  prefer 2 apply blast
   135 apply (rule_tac x = "{z. z:Q & (z,y) : r^*}" in allE)
   136  apply assumption
   137 apply (erule_tac V = "ALL Q. (EX x. x : Q) --> ?P Q" in thin_rl) 
   138   --{*essential for speed*}
   139 txt{*Blast with new substOccur fails*}
   140 apply (fast intro: converse_rtrancl_into_rtrancl)
   141 done
   142 
   143 text{*Well-foundedness of image*}
   144 lemma wf_prod_fun_image: "[| wf r; inj f |] ==> wf(prod_fun f f ` r)"
   145 apply (simp only: wf_eq_minimal, clarify)
   146 apply (case_tac "EX p. f p : Q")
   147 apply (erule_tac x = "{p. f p : Q}" in allE)
   148 apply (fast dest: inj_onD, blast)
   149 done
   150 
   151 
   152 subsubsection{*Well-Foundedness Results for Unions*}
   153 
   154 text{*Well-foundedness of indexed union with disjoint domains and ranges*}
   155 
   156 lemma wf_UN: "[| ALL i:I. wf(r i);  
   157          ALL i:I. ALL j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {}  
   158       |] ==> wf(UN i:I. r i)"
   159 apply (simp only: wf_eq_minimal, clarify)
   160 apply (rename_tac A a, case_tac "EX i:I. EX a:A. EX b:A. (b,a) : r i")
   161  prefer 2
   162  apply force 
   163 apply clarify
   164 apply (drule bspec, assumption)  
   165 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r i) }" in allE)
   166 apply (blast elim!: allE)  
   167 done
   168 
   169 lemma wf_Union: 
   170  "[| ALL r:R. wf r;  
   171      ALL r:R. ALL s:R. r ~= s --> Domain r Int Range s = {}  
   172   |] ==> wf(Union R)"
   173 apply (simp add: Union_def)
   174 apply (blast intro: wf_UN)
   175 done
   176 
   177 (*Intuition: we find an (R u S)-min element of a nonempty subset A
   178              by case distinction.
   179   1. There is a step a -R-> b with a,b : A.
   180      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   181      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   182      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   183      have an S-successor and is thus S-min in A as well.
   184   2. There is no such step.
   185      Pick an S-min element of A. In this case it must be an R-min
   186      element of A as well.
   187 
   188 *)
   189 lemma wf_Un:
   190      "[| wf r; wf s; Domain r Int Range s = {} |] ==> wf(r Un s)"
   191 apply (simp only: wf_eq_minimal, clarify) 
   192 apply (rename_tac A a)
   193 apply (case_tac "EX a:A. EX b:A. (b,a) : r") 
   194  prefer 2
   195  apply simp
   196  apply (drule_tac x=A in spec)+
   197  apply blast 
   198 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r) }" in allE)+
   199 apply (blast elim!: allE)  
   200 done
   201 
   202 subsubsection {*acyclic*}
   203 
   204 lemma acyclicI: "ALL x. (x, x) ~: r^+ ==> acyclic r"
   205 by (simp add: acyclic_def)
   206 
   207 lemma wf_acyclic: "wf r ==> acyclic r"
   208 apply (simp add: acyclic_def)
   209 apply (blast elim: wf_trancl [THEN wf_irrefl])
   210 done
   211 
   212 lemma acyclic_insert [iff]:
   213      "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)"
   214 apply (simp add: acyclic_def trancl_insert)
   215 apply (blast intro: rtrancl_trans)
   216 done
   217 
   218 lemma acyclic_converse [iff]: "acyclic(r^-1) = acyclic r"
   219 by (simp add: acyclic_def trancl_converse)
   220 
   221 lemma acyclic_impl_antisym_rtrancl: "acyclic r ==> antisym(r^*)"
   222 apply (simp add: acyclic_def antisym_def)
   223 apply (blast elim: rtranclE intro: rtrancl_into_trancl1 rtrancl_trancl_trancl)
   224 done
   225 
   226 (* Other direction:
   227 acyclic = no loops
   228 antisym = only self loops
   229 Goalw [acyclic_def,antisym_def] "antisym( r^* ) ==> acyclic(r - Id)
   230 ==> antisym( r^* ) = acyclic(r - Id)";
   231 *)
   232 
   233 lemma acyclic_subset: "[| acyclic s; r <= s |] ==> acyclic r"
   234 apply (simp add: acyclic_def)
   235 apply (blast intro: trancl_mono)
   236 done
   237 
   238 
   239 subsection{*Well-Founded Recursion*}
   240 
   241 text{*cut*}
   242 
   243 lemma cuts_eq: "(cut f r x = cut g r x) = (ALL y. (y,x):r --> f(y)=g(y))"
   244 by (simp add: expand_fun_eq cut_def)
   245 
   246 lemma cut_apply: "(x,a):r ==> (cut f r a)(x) = f(x)"
   247 by (simp add: cut_def)
   248 
   249 text{*Inductive characterization of wfrec combinator; for details see:  
   250 John Harrison, "Inductive definitions: automation and application"*}
   251 
   252 lemma wfrec_unique: "[| adm_wf R F; wf R |] ==> EX! y. (x, y) : wfrec_rel R F"
   253 apply (simp add: adm_wf_def)
   254 apply (erule_tac a=x in wf_induct) 
   255 apply (rule ex1I)
   256 apply (rule_tac g = "%x. THE y. (x, y) : wfrec_rel R F" in wfrec_rel.wfrecI)
   257 apply (fast dest!: theI')
   258 apply (erule wfrec_rel.cases, simp)
   259 apply (erule allE, erule allE, erule allE, erule mp)
   260 apply (fast intro: the_equality [symmetric])
   261 done
   262 
   263 lemma adm_lemma: "adm_wf R (%f x. F (cut f R x) x)"
   264 apply (simp add: adm_wf_def)
   265 apply (intro strip)
   266 apply (rule cuts_eq [THEN iffD2, THEN subst], assumption)
   267 apply (rule refl)
   268 done
   269 
   270 lemma wfrec: "wf(r) ==> wfrec r H a = H (cut (wfrec r H) r a) a"
   271 apply (simp add: wfrec_def)
   272 apply (rule adm_lemma [THEN wfrec_unique, THEN the1_equality], assumption)
   273 apply (rule wfrec_rel.wfrecI)
   274 apply (intro strip)
   275 apply (erule adm_lemma [THEN wfrec_unique, THEN theI'])
   276 done
   277 
   278 
   279 text{** This form avoids giant explosions in proofs.  NOTE USE OF ==*}
   280 lemma def_wfrec: "[| f==wfrec r H;  wf(r) |] ==> f(a) = H (cut f r a) a"
   281 apply auto
   282 apply (blast intro: wfrec)
   283 done
   284 
   285 
   286 subsection {* Code generator setup *}
   287 
   288 consts_code
   289   "wfrec"   ("\<module>wfrec?")
   290 attach {*
   291 fun wfrec f x = f (wfrec f) x;
   292 *}
   293 
   294 setup {*
   295   CodegenPackage.add_appconst ("wfrec", CodegenPackage.appgen_wfrec)
   296 *}
   297 
   298 code_constapp
   299   wfrec
   300     ml (target_atom "(let fun wfrec f x = f (wfrec f) x in wfrec end)")
   301     haskell (target_atom "(wfrec where wfrec f x = f (wfrec f) x)")
   302 
   303 subsection{*Variants for TFL: the Recdef Package*}
   304 
   305 lemma tfl_wf_induct: "ALL R. wf R -->  
   306        (ALL P. (ALL x. (ALL y. (y,x):R --> P y) --> P x) --> (ALL x. P x))"
   307 apply clarify
   308 apply (rule_tac r = R and P = P and a = x in wf_induct, assumption, blast)
   309 done
   310 
   311 lemma tfl_cut_apply: "ALL f R. (x,a):R --> (cut f R a)(x) = f(x)"
   312 apply clarify
   313 apply (rule cut_apply, assumption)
   314 done
   315 
   316 lemma tfl_wfrec:
   317      "ALL M R f. (f=wfrec R M) --> wf R --> (ALL x. f x = M (cut f R x) x)"
   318 apply clarify
   319 apply (erule wfrec)
   320 done
   321 
   322 subsection {*LEAST and wellorderings*}
   323 
   324 text{* See also @{text wf_linord_ex_has_least} and its consequences in
   325  @{text Wellfounded_Relations.ML}*}
   326 
   327 lemma wellorder_Least_lemma [rule_format]:
   328      "P (k::'a::wellorder) --> P (LEAST x. P(x)) & (LEAST x. P(x)) <= k"
   329 apply (rule_tac a = k in wf [THEN wf_induct])
   330 apply (rule impI)
   331 apply (rule classical)
   332 apply (rule_tac s = x in Least_equality [THEN ssubst], auto)
   333 apply (auto simp add: linorder_not_less [symmetric])
   334 done
   335 
   336 lemmas LeastI   = wellorder_Least_lemma [THEN conjunct1, standard]
   337 lemmas Least_le = wellorder_Least_lemma [THEN conjunct2, standard]
   338 
   339 -- "The following 3 lemmas are due to Brian Huffman"
   340 lemma LeastI_ex: "EX x::'a::wellorder. P x ==> P (Least P)"
   341 apply (erule exE)
   342 apply (erule LeastI)
   343 done
   344 
   345 lemma LeastI2:
   346   "[| P (a::'a::wellorder); !!x. P x ==> Q x |] ==> Q (Least P)"
   347 by (blast intro: LeastI)
   348 
   349 lemma LeastI2_ex:
   350   "[| EX a::'a::wellorder. P a; !!x. P x ==> Q x |] ==> Q (Least P)"
   351 by (blast intro: LeastI_ex)
   352 
   353 lemma not_less_Least: "[| k < (LEAST x. P x) |] ==> ~P (k::'a::wellorder)"
   354 apply (simp (no_asm_use) add: linorder_not_le [symmetric])
   355 apply (erule contrapos_nn)
   356 apply (erule Least_le)
   357 done
   358 
   359 ML
   360 {*
   361 val wf_def = thm "wf_def";
   362 val wfUNIVI = thm "wfUNIVI";
   363 val wfI = thm "wfI";
   364 val wf_induct = thm "wf_induct";
   365 val wf_not_sym = thm "wf_not_sym";
   366 val wf_asym = thm "wf_asym";
   367 val wf_not_refl = thm "wf_not_refl";
   368 val wf_irrefl = thm "wf_irrefl";
   369 val wf_trancl = thm "wf_trancl";
   370 val wf_converse_trancl = thm "wf_converse_trancl";
   371 val wf_eq_minimal = thm "wf_eq_minimal";
   372 val wf_subset = thm "wf_subset";
   373 val wf_empty = thm "wf_empty";
   374 val wf_insert = thm "wf_insert";
   375 val wf_UN = thm "wf_UN";
   376 val wf_Union = thm "wf_Union";
   377 val wf_Un = thm "wf_Un";
   378 val wf_prod_fun_image = thm "wf_prod_fun_image";
   379 val acyclicI = thm "acyclicI";
   380 val wf_acyclic = thm "wf_acyclic";
   381 val acyclic_insert = thm "acyclic_insert";
   382 val acyclic_converse = thm "acyclic_converse";
   383 val acyclic_impl_antisym_rtrancl = thm "acyclic_impl_antisym_rtrancl";
   384 val acyclic_subset = thm "acyclic_subset";
   385 val cuts_eq = thm "cuts_eq";
   386 val cut_apply = thm "cut_apply";
   387 val wfrec_unique = thm "wfrec_unique";
   388 val wfrec = thm "wfrec";
   389 val def_wfrec = thm "def_wfrec";
   390 val tfl_wf_induct = thm "tfl_wf_induct";
   391 val tfl_cut_apply = thm "tfl_cut_apply";
   392 val tfl_wfrec = thm "tfl_wfrec";
   393 val LeastI = thm "LeastI";
   394 val Least_le = thm "Least_le";
   395 val not_less_Least = thm "not_less_Least";
   396 *}
   397 
   398 end