src/HOL/hologic.ML
author haftmann
Mon Aug 14 13:46:06 2006 +0200 (2006-08-14)
changeset 20380 14f9f2a1caa6
parent 19481 a6205c6203ea
child 20485 3078fd2eec7b
permissions -rw-r--r--
simplified code generator setup
     1 (*  Title:      HOL/hologic.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Abstract syntax operations for HOL.
     6 *)
     7 
     8 signature HOLOGIC =
     9 sig
    10   val typeS: sort
    11   val typeT: typ
    12   val boolN: string
    13   val boolT: typ
    14   val false_const: term
    15   val true_const: term
    16   val mk_setT: typ -> typ
    17   val dest_setT: typ -> typ
    18   val Trueprop: term
    19   val mk_Trueprop: term -> term
    20   val dest_Trueprop: term -> term
    21   val conj: term
    22   val disj: term
    23   val imp: term
    24   val Not: term
    25   val mk_conj: term * term -> term
    26   val mk_disj: term * term -> term
    27   val mk_imp: term * term -> term
    28   val mk_not: term -> term
    29   val dest_conj: term -> term list
    30   val dest_disj: term -> term list
    31   val dest_imp: term -> term * term
    32   val dest_not: term -> term
    33   val dest_concls: term -> term list
    34   val eq_const: typ -> term
    35   val all_const: typ -> term
    36   val exists_const: typ -> term
    37   val choice_const: typ -> term
    38   val Collect_const: typ -> term
    39   val mk_eq: term * term -> term
    40   val dest_eq: term -> term * term
    41   val mk_all: string * typ * term -> term
    42   val list_all: (string * typ) list * term -> term
    43   val mk_exists: string * typ * term -> term
    44   val mk_Collect: string * typ * term -> term
    45   val mk_mem: term * term -> term
    46   val dest_mem: term -> term * term
    47   val mk_UNIV: typ -> term
    48   val mk_binop: string -> term * term -> term
    49   val mk_binrel: string -> term * term -> term
    50   val dest_bin: string -> typ -> term -> term * term
    51   val unitT: typ
    52   val is_unitT: typ -> bool
    53   val unit: term
    54   val is_unit: term -> bool
    55   val mk_prodT: typ * typ -> typ
    56   val dest_prodT: typ -> typ * typ
    57   val pair_const: typ -> typ -> term
    58   val mk_prod: term * term -> term
    59   val dest_prod: term -> term * term
    60   val mk_fst: term -> term
    61   val mk_snd: term -> term
    62   val mk_split: term -> term
    63   val prodT_factors: typ -> typ list
    64   val split_const: typ * typ * typ -> term
    65   val mk_tuple: typ -> term list -> term
    66   val natT: typ
    67   val zero: term
    68   val is_zero: term -> bool
    69   val mk_Suc: term -> term
    70   val dest_Suc: term -> term
    71   val mk_nat: int -> term
    72   val dest_nat: term -> int
    73   val intT: typ
    74   val mk_int: IntInf.int -> term
    75   val realT: typ
    76   val bitT: typ
    77   val B0_const: term
    78   val B1_const: term
    79   val binT: typ
    80   val pls_const: term
    81   val min_const: term
    82   val bit_const: term
    83   val number_of_const: typ -> term
    84   val int_of: int list -> IntInf.int
    85   val dest_binum: term -> IntInf.int
    86   val mk_binum: IntInf.int -> term
    87   val bin_of : term -> int list
    88   val listT : typ -> typ
    89   val mk_list: ('a -> term) -> typ -> 'a list -> term
    90   val dest_list: term -> term list
    91 end;
    92 
    93 
    94 structure HOLogic: HOLOGIC =
    95 struct
    96 
    97 (* HOL syntax *)
    98 
    99 val typeS: sort = ["HOL.type"];
   100 val typeT = TypeInfer.anyT typeS;
   101 
   102 
   103 (* bool and set *)
   104 
   105 val boolN = "bool";
   106 val boolT = Type (boolN, []);
   107 
   108 val true_const =  Const ("True", boolT);
   109 val false_const = Const ("False", boolT);
   110 
   111 fun mk_setT T = Type ("set", [T]);
   112 
   113 fun dest_setT (Type ("set", [T])) = T
   114   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   115 
   116 
   117 (* logic *)
   118 
   119 val Trueprop = Const ("Trueprop", boolT --> propT);
   120 
   121 fun mk_Trueprop P = Trueprop $ P;
   122 
   123 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   124   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   125 
   126 
   127 val conj = Const ("op &", [boolT, boolT] ---> boolT)
   128 and disj = Const ("op |", [boolT, boolT] ---> boolT)
   129 and imp = Const ("op -->", [boolT, boolT] ---> boolT)
   130 and Not = Const ("Not", boolT --> boolT);
   131 
   132 fun mk_conj (t1, t2) = conj $ t1 $ t2
   133 and mk_disj (t1, t2) = disj $ t1 $ t2
   134 and mk_imp (t1, t2) = imp $ t1 $ t2
   135 and mk_not t = Not $ t;
   136 
   137 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   138   | dest_conj t = [t];
   139 
   140 fun dest_disj (Const ("op |", _) $ t $ t') = t :: dest_disj t'
   141   | dest_disj t = [t];
   142 
   143 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   144   | dest_imp  t = raise TERM ("dest_imp", [t]);
   145 
   146 fun dest_not (Const ("Not", _) $ t) = t
   147   | dest_not t = raise TERM ("dest_not", [t]);
   148 
   149 fun imp_concl_of t = imp_concl_of (#2 (dest_imp t)) handle TERM _ => t;
   150 val dest_concls = map imp_concl_of o dest_conj o dest_Trueprop;
   151 
   152 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   153 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   154 
   155 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   156   | dest_eq t = raise TERM ("dest_eq", [t])
   157 
   158 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   159 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   160 fun list_all (vs,x) = foldr (fn ((x, T), P) => all_const T $ Abs (x, T, P)) x vs;
   161 
   162 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   163 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   164 
   165 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T)
   166 
   167 fun Collect_const T = Const ("Collect", [T --> boolT] ---> mk_setT T);
   168 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   169 
   170 fun mk_mem (x, A) =
   171   let val setT = fastype_of A in
   172     Const ("op :", [dest_setT setT, setT] ---> boolT) $ x $ A
   173   end;
   174 
   175 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   176   | dest_mem t = raise TERM ("dest_mem", [t]);
   177 
   178 fun mk_UNIV T = Const ("UNIV", mk_setT T);
   179 
   180 
   181 (* binary operations and relations *)
   182 
   183 fun mk_binop c (t, u) =
   184   let val T = fastype_of t in
   185     Const (c, [T, T] ---> T) $ t $ u
   186   end;
   187 
   188 fun mk_binrel c (t, u) =
   189   let val T = fastype_of t in
   190     Const (c, [T, T] ---> boolT) $ t $ u
   191   end;
   192 
   193 (*destruct the application of a binary operator. The dummyT case is a crude
   194   way of handling polymorphic operators.*)
   195 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   196       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   197       else raise TERM ("dest_bin " ^ c, [tm])
   198   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   199 
   200 
   201 (* unit *)
   202 
   203 val unitT = Type ("Product_Type.unit", []);
   204 
   205 fun is_unitT (Type ("Product_Type.unit", [])) = true
   206   | is_unitT _ = false;
   207 
   208 val unit = Const ("Product_Type.Unity", unitT);
   209 
   210 fun is_unit (Const ("Product_Type.Unity", _)) = true
   211   | is_unit _ = false;
   212 
   213 
   214 (* prod *)
   215 
   216 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   217 
   218 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   219   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   220 
   221 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   222 
   223 fun mk_prod (t1, t2) =
   224   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   225     pair_const T1 T2 $ t1 $ t2
   226   end;
   227 
   228 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   229   | dest_prod t = raise TERM ("dest_prod", [t]);
   230 
   231 fun mk_fst p =
   232   let val pT = fastype_of p in
   233     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   234   end;
   235 
   236 fun mk_snd p =
   237   let val pT = fastype_of p in
   238     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   239   end;
   240 
   241 fun split_const (A, B, C) =
   242   Const ("split", (A --> B --> C) --> mk_prodT (A, B) --> C);
   243 
   244 fun mk_split t =
   245   (case Term.fastype_of t of
   246     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   247       Const ("split", T --> mk_prodT (A, B) --> C) $ t
   248   | _ => raise TERM ("mk_split: bad body type", [t]));
   249 
   250 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   251 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   252   | prodT_factors T = [T];
   253 
   254 (*Makes a nested tuple from a list, following the product type structure*)
   255 fun mk_tuple (Type ("*", [T1, T2])) tms =
   256         mk_prod (mk_tuple T1 tms,
   257                  mk_tuple T2 (Library.drop (length (prodT_factors T1), tms)))
   258   | mk_tuple T (t::_) = t;
   259 
   260 
   261 (* nat *)
   262 
   263 val natT = Type ("nat", []);
   264 
   265 val zero = Const ("0", natT);
   266 
   267 fun is_zero (Const ("0", _)) = true
   268   | is_zero _ = false;
   269 
   270 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   271 
   272 fun dest_Suc (Const ("Suc", _) $ t) = t
   273   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   274 
   275 fun mk_nat 0 = zero
   276   | mk_nat n = mk_Suc (mk_nat (n - 1));
   277 
   278 fun dest_nat (Const ("0", _)) = 0
   279   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   280   | dest_nat t = raise TERM ("dest_nat", [t]);
   281 
   282 
   283 (* binary numerals *)
   284 
   285 val binT = Type ("Numeral.bin", []);
   286 
   287 val bitT = Type ("Numeral.bit", []);
   288 
   289 val B0_const = Const ("Numeral.bit.B0", bitT);
   290 val B1_const =  Const ("Numeral.bit.B1", bitT);
   291 
   292 val pls_const = Const ("Numeral.Pls", binT)
   293 and min_const = Const ("Numeral.Min", binT)
   294 and bit_const = Const ("Numeral.Bit", [binT, bitT] ---> binT);
   295 
   296 fun number_of_const T = Const ("Numeral.number_of", binT --> T);
   297 
   298 fun int_of [] = 0
   299   | int_of (b :: bs) = IntInf.fromInt b + (2 * int_of bs);
   300 
   301 (*When called from a print translation, the Numeral qualifier will probably have
   302   been removed from Bit, bin.B0, etc.*)
   303 fun dest_bit (Const ("Numeral.bit.B0", _)) = 0
   304   | dest_bit (Const ("Numeral.bit.B1", _)) = 1
   305   | dest_bit (Const ("bit.B0", _)) = 0
   306   | dest_bit (Const ("bit.B1", _)) = 1
   307   | dest_bit t = raise TERM("dest_bit", [t]);
   308 
   309 fun bin_of (Const ("Numeral.Pls", _)) = []
   310   | bin_of (Const ("Numeral.Min", _)) = [~1]
   311   | bin_of (Const ("Numeral.Bit", _) $ bs $ b) = dest_bit b :: bin_of bs
   312   | bin_of (Const ("Bit", _) $ bs $ b) = dest_bit b :: bin_of bs
   313   | bin_of t = raise TERM("bin_of", [t]);
   314 
   315 val dest_binum = int_of o bin_of;
   316 
   317 fun mk_bit 0 = B0_const
   318   | mk_bit 1 = B1_const
   319   | mk_bit _ = sys_error "mk_bit";
   320 
   321 fun mk_binum n =
   322   let
   323     fun mk_bit n = if n = 0 then B0_const else B1_const;
   324 
   325     fun bin_of n =
   326       if n = 0 then pls_const
   327       else if n = ~1 then min_const
   328       else
   329         let
   330           (*val (q,r) = IntInf.divMod (n, 2): doesn't work in SML 110.0.7,
   331             but in newer versions!  FIXME: put this back after new SML released!*)
   332           val q = IntInf.div (n, 2);
   333           val r = IntInf.mod (n, 2);
   334         in bit_const $ bin_of q $ mk_bit r end;
   335   in bin_of n end;
   336 
   337 
   338 (* int *)
   339 
   340 val intT = Type ("IntDef.int", []);
   341 
   342 fun mk_int 0 = Const ("0", intT)
   343   | mk_int 1 = Const ("1", intT)
   344   | mk_int i = number_of_const intT $ mk_binum i;
   345 
   346 
   347 (* real *)
   348 
   349 val realT = Type ("RealDef.real", []);
   350 
   351 
   352 (* list *)
   353 
   354 fun listT T =  Type ("List.list", [T])
   355 
   356 fun mk_list f T [] = Const ("List.list.Nil", listT T)
   357   | mk_list f T (x :: xs) = Const ("List.list.Cons",
   358       T --> listT T --> listT T) $ f x $
   359         mk_list f T xs;
   360 
   361 fun dest_list (Const ("List.list.Nil", _)) = []
   362   | dest_list (Const ("List.list.Cons", _) $ x $ xs) = x :: dest_list xs
   363   | dest_list t = raise TERM ("dest_list", [t]);
   364 
   365 end;