src/HOL/Fun.thy
author hoelzl
Tue Mar 26 12:20:58 2013 +0100 (2013-03-26)
changeset 51526 155263089e7b
parent 49905 a81f95693c68
child 51598 5dbe537087aa
permissions -rw-r--r--
move SEQ.thy and Lim.thy to Limits.thy
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattices
    10 keywords "enriched_type" :: thy_goal
    11 begin
    12 
    13 lemma apply_inverse:
    14   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    15   by auto
    16 
    17 
    18 subsection {* The Identity Function @{text id} *}
    19 
    20 definition id :: "'a \<Rightarrow> 'a" where
    21   "id = (\<lambda>x. x)"
    22 
    23 lemma id_apply [simp]: "id x = x"
    24   by (simp add: id_def)
    25 
    26 lemma image_id [simp]: "image id = id"
    27   by (simp add: id_def fun_eq_iff)
    28 
    29 lemma vimage_id [simp]: "vimage id = id"
    30   by (simp add: id_def fun_eq_iff)
    31 
    32 
    33 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    34 
    35 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    36   "f o g = (\<lambda>x. f (g x))"
    37 
    38 notation (xsymbols)
    39   comp  (infixl "\<circ>" 55)
    40 
    41 notation (HTML output)
    42   comp  (infixl "\<circ>" 55)
    43 
    44 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    45   by (simp add: comp_def)
    46 
    47 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    48   by (simp add: fun_eq_iff)
    49 
    50 lemma id_comp [simp]: "id o g = g"
    51   by (simp add: fun_eq_iff)
    52 
    53 lemma comp_id [simp]: "f o id = f"
    54   by (simp add: fun_eq_iff)
    55 
    56 lemma comp_eq_dest:
    57   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_eq_elim:
    61   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    62   by (simp add: fun_eq_iff) 
    63 
    64 lemma image_comp:
    65   "(f o g) ` r = f ` (g ` r)"
    66   by auto
    67 
    68 lemma vimage_comp:
    69   "(g \<circ> f) -` x = f -` (g -` x)"
    70   by auto
    71 
    72 lemma INF_comp:
    73   "INFI A (g \<circ> f) = INFI (f ` A) g"
    74   by (simp add: INF_def image_comp)
    75 
    76 lemma SUP_comp:
    77   "SUPR A (g \<circ> f) = SUPR (f ` A) g"
    78   by (simp add: SUP_def image_comp)
    79 
    80 
    81 subsection {* The Forward Composition Operator @{text fcomp} *}
    82 
    83 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    84   "f \<circ>> g = (\<lambda>x. g (f x))"
    85 
    86 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    87   by (simp add: fcomp_def)
    88 
    89 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    90   by (simp add: fcomp_def)
    91 
    92 lemma id_fcomp [simp]: "id \<circ>> g = g"
    93   by (simp add: fcomp_def)
    94 
    95 lemma fcomp_id [simp]: "f \<circ>> id = f"
    96   by (simp add: fcomp_def)
    97 
    98 code_const fcomp
    99   (Eval infixl 1 "#>")
   100 
   101 no_notation fcomp (infixl "\<circ>>" 60)
   102 
   103 
   104 subsection {* Mapping functions *}
   105 
   106 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   107   "map_fun f g h = g \<circ> h \<circ> f"
   108 
   109 lemma map_fun_apply [simp]:
   110   "map_fun f g h x = g (h (f x))"
   111   by (simp add: map_fun_def)
   112 
   113 
   114 subsection {* Injectivity and Bijectivity *}
   115 
   116 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   117   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   118 
   119 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   120   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   121 
   122 text{*A common special case: functions injective, surjective or bijective over
   123 the entire domain type.*}
   124 
   125 abbreviation
   126   "inj f \<equiv> inj_on f UNIV"
   127 
   128 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   129   "surj f \<equiv> (range f = UNIV)"
   130 
   131 abbreviation
   132   "bij f \<equiv> bij_betw f UNIV UNIV"
   133 
   134 text{* The negated case: *}
   135 translations
   136 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   137 
   138 lemma injI:
   139   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   140   shows "inj f"
   141   using assms unfolding inj_on_def by auto
   142 
   143 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   144   by (unfold inj_on_def, blast)
   145 
   146 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   147 by (simp add: inj_on_def)
   148 
   149 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   150 by (force simp add: inj_on_def)
   151 
   152 lemma inj_on_cong:
   153   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   154 unfolding inj_on_def by auto
   155 
   156 lemma inj_on_strict_subset:
   157   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   158 unfolding inj_on_def unfolding image_def by blast
   159 
   160 lemma inj_comp:
   161   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   162   by (simp add: inj_on_def)
   163 
   164 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   165   by (simp add: inj_on_def fun_eq_iff)
   166 
   167 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   168 by (simp add: inj_on_eq_iff)
   169 
   170 lemma inj_on_id[simp]: "inj_on id A"
   171   by (simp add: inj_on_def)
   172 
   173 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   174 by (simp add: inj_on_def)
   175 
   176 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   177 unfolding inj_on_def by blast
   178 
   179 lemma inj_on_INTER:
   180   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   181 unfolding inj_on_def by blast
   182 
   183 lemma inj_on_Inter:
   184   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   185 unfolding inj_on_def by blast
   186 
   187 lemma inj_on_UNION_chain:
   188   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   189          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   190   shows "inj_on f (\<Union> i \<in> I. A i)"
   191 proof -
   192   {
   193     fix i j x y
   194     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   195       and ***: "f x = f y"
   196     have "x = y"
   197     proof -
   198       {
   199         assume "A i \<le> A j"
   200         with ** have "x \<in> A j" by auto
   201         with INJ * ** *** have ?thesis
   202         by(auto simp add: inj_on_def)
   203       }
   204       moreover
   205       {
   206         assume "A j \<le> A i"
   207         with ** have "y \<in> A i" by auto
   208         with INJ * ** *** have ?thesis
   209         by(auto simp add: inj_on_def)
   210       }
   211       ultimately show ?thesis using CH * by blast
   212     qed
   213   }
   214   then show ?thesis by (unfold inj_on_def UNION_eq) auto
   215 qed
   216 
   217 lemma surj_id: "surj id"
   218 by simp
   219 
   220 lemma bij_id[simp]: "bij id"
   221 by (simp add: bij_betw_def)
   222 
   223 lemma inj_onI:
   224     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   225 by (simp add: inj_on_def)
   226 
   227 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   228 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   229 
   230 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   231 by (unfold inj_on_def, blast)
   232 
   233 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   234 by (blast dest!: inj_onD)
   235 
   236 lemma comp_inj_on:
   237      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   238 by (simp add: comp_def inj_on_def)
   239 
   240 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   241 apply(simp add:inj_on_def image_def)
   242 apply blast
   243 done
   244 
   245 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   246   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   247 apply(unfold inj_on_def)
   248 apply blast
   249 done
   250 
   251 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   252 by (unfold inj_on_def, blast)
   253 
   254 lemma inj_singleton: "inj (%s. {s})"
   255 by (simp add: inj_on_def)
   256 
   257 lemma inj_on_empty[iff]: "inj_on f {}"
   258 by(simp add: inj_on_def)
   259 
   260 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   261 by (unfold inj_on_def, blast)
   262 
   263 lemma inj_on_Un:
   264  "inj_on f (A Un B) =
   265   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   266 apply(unfold inj_on_def)
   267 apply (blast intro:sym)
   268 done
   269 
   270 lemma inj_on_insert[iff]:
   271   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   272 apply(unfold inj_on_def)
   273 apply (blast intro:sym)
   274 done
   275 
   276 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   277 apply(unfold inj_on_def)
   278 apply (blast)
   279 done
   280 
   281 lemma comp_inj_on_iff:
   282   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   283 by(auto simp add: comp_inj_on inj_on_def)
   284 
   285 lemma inj_on_imageI2:
   286   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   287 by(auto simp add: comp_inj_on inj_on_def)
   288 
   289 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   290   by auto
   291 
   292 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   293   using *[symmetric] by auto
   294 
   295 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   296   by (simp add: surj_def)
   297 
   298 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   299   by (simp add: surj_def, blast)
   300 
   301 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   302 apply (simp add: comp_def surj_def, clarify)
   303 apply (drule_tac x = y in spec, clarify)
   304 apply (drule_tac x = x in spec, blast)
   305 done
   306 
   307 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   308   unfolding bij_betw_def by auto
   309 
   310 lemma bij_betw_empty1:
   311   assumes "bij_betw f {} A"
   312   shows "A = {}"
   313 using assms unfolding bij_betw_def by blast
   314 
   315 lemma bij_betw_empty2:
   316   assumes "bij_betw f A {}"
   317   shows "A = {}"
   318 using assms unfolding bij_betw_def by blast
   319 
   320 lemma inj_on_imp_bij_betw:
   321   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   322 unfolding bij_betw_def by simp
   323 
   324 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   325   unfolding bij_betw_def ..
   326 
   327 lemma bijI: "[| inj f; surj f |] ==> bij f"
   328 by (simp add: bij_def)
   329 
   330 lemma bij_is_inj: "bij f ==> inj f"
   331 by (simp add: bij_def)
   332 
   333 lemma bij_is_surj: "bij f ==> surj f"
   334 by (simp add: bij_def)
   335 
   336 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   337 by (simp add: bij_betw_def)
   338 
   339 lemma bij_betw_trans:
   340   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   341 by(auto simp add:bij_betw_def comp_inj_on)
   342 
   343 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   344   by (rule bij_betw_trans)
   345 
   346 lemma bij_betw_comp_iff:
   347   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   348 by(auto simp add: bij_betw_def inj_on_def)
   349 
   350 lemma bij_betw_comp_iff2:
   351   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   352   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   353 using assms
   354 proof(auto simp add: bij_betw_comp_iff)
   355   assume *: "bij_betw (f' \<circ> f) A A''"
   356   thus "bij_betw f A A'"
   357   using IM
   358   proof(auto simp add: bij_betw_def)
   359     assume "inj_on (f' \<circ> f) A"
   360     thus "inj_on f A" using inj_on_imageI2 by blast
   361   next
   362     fix a' assume **: "a' \<in> A'"
   363     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   364     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   365     unfolding bij_betw_def by force
   366     hence "f a \<in> A'" using IM by auto
   367     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   368     thus "a' \<in> f ` A" using 1 by auto
   369   qed
   370 qed
   371 
   372 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   373 proof -
   374   have i: "inj_on f A" and s: "f ` A = B"
   375     using assms by(auto simp:bij_betw_def)
   376   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   377   { fix a b assume P: "?P b a"
   378     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   379     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   380     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   381   } note g = this
   382   have "inj_on ?g B"
   383   proof(rule inj_onI)
   384     fix x y assume "x:B" "y:B" "?g x = ?g y"
   385     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   386     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   387     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   388   qed
   389   moreover have "?g ` B = A"
   390   proof(auto simp:image_def)
   391     fix b assume "b:B"
   392     with s obtain a where P: "?P b a" unfolding image_def by blast
   393     thus "?g b \<in> A" using g[OF P] by auto
   394   next
   395     fix a assume "a:A"
   396     then obtain b where P: "?P b a" using s unfolding image_def by blast
   397     then have "b:B" using s unfolding image_def by blast
   398     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   399   qed
   400   ultimately show ?thesis by(auto simp:bij_betw_def)
   401 qed
   402 
   403 lemma bij_betw_cong:
   404   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   405 unfolding bij_betw_def inj_on_def by force
   406 
   407 lemma bij_betw_id[intro, simp]:
   408   "bij_betw id A A"
   409 unfolding bij_betw_def id_def by auto
   410 
   411 lemma bij_betw_id_iff:
   412   "bij_betw id A B \<longleftrightarrow> A = B"
   413 by(auto simp add: bij_betw_def)
   414 
   415 lemma bij_betw_combine:
   416   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   417   shows "bij_betw f (A \<union> C) (B \<union> D)"
   418   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   419 
   420 lemma bij_betw_UNION_chain:
   421   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   422          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   423   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   424 proof (unfold bij_betw_def, auto)
   425   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   426   using BIJ bij_betw_def[of f] by auto
   427   thus "inj_on f (\<Union> i \<in> I. A i)"
   428   using CH inj_on_UNION_chain[of I A f] by auto
   429 next
   430   fix i x
   431   assume *: "i \<in> I" "x \<in> A i"
   432   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   433   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   434 next
   435   fix i x'
   436   assume *: "i \<in> I" "x' \<in> A' i"
   437   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   438   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   439     using * by blast
   440   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by (simp add: image_def)
   441 qed
   442 
   443 lemma bij_betw_subset:
   444   assumes BIJ: "bij_betw f A A'" and
   445           SUB: "B \<le> A" and IM: "f ` B = B'"
   446   shows "bij_betw f B B'"
   447 using assms
   448 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   449 
   450 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   451 by simp
   452 
   453 lemma surj_vimage_empty:
   454   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   455   using surj_image_vimage_eq[OF `surj f`, of A]
   456   by (intro iffI) fastforce+
   457 
   458 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   459 by (simp add: inj_on_def, blast)
   460 
   461 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   462 by (blast intro: sym)
   463 
   464 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   465 by (unfold inj_on_def, blast)
   466 
   467 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   468 apply (unfold bij_def)
   469 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   470 done
   471 
   472 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   473 by(blast dest: inj_onD)
   474 
   475 lemma inj_on_image_Int:
   476    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   477 apply (simp add: inj_on_def, blast)
   478 done
   479 
   480 lemma inj_on_image_set_diff:
   481    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   482 apply (simp add: inj_on_def, blast)
   483 done
   484 
   485 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   486 by (simp add: inj_on_def, blast)
   487 
   488 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   489 by (simp add: inj_on_def, blast)
   490 
   491 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   492 by (blast dest: injD)
   493 
   494 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   495 by (simp add: inj_on_def, blast)
   496 
   497 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   498 by (blast dest: injD)
   499 
   500 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   501 lemma image_INT:
   502    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   503     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   504 apply (simp add: inj_on_def, blast)
   505 done
   506 
   507 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   508   it doesn't matter whether A is empty*)
   509 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   510 apply (simp add: bij_def)
   511 apply (simp add: inj_on_def surj_def, blast)
   512 done
   513 
   514 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   515 by auto
   516 
   517 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   518 by (auto simp add: inj_on_def)
   519 
   520 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   521 apply (simp add: bij_def)
   522 apply (rule equalityI)
   523 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   524 done
   525 
   526 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   527   -- {* The inverse image of a singleton under an injective function
   528          is included in a singleton. *}
   529   apply (auto simp add: inj_on_def)
   530   apply (blast intro: the_equality [symmetric])
   531   done
   532 
   533 lemma inj_on_vimage_singleton:
   534   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   535   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   536 
   537 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   538   by (auto intro!: inj_onI)
   539 
   540 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   541   by (auto intro!: inj_onI dest: strict_mono_eq)
   542 
   543 
   544 subsection{*Function Updating*}
   545 
   546 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   547   "fun_upd f a b == % x. if x=a then b else f x"
   548 
   549 nonterminal updbinds and updbind
   550 
   551 syntax
   552   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   553   ""         :: "updbind => updbinds"             ("_")
   554   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   555   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   556 
   557 translations
   558   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   559   "f(x:=y)" == "CONST fun_upd f x y"
   560 
   561 (* Hint: to define the sum of two functions (or maps), use sum_case.
   562          A nice infix syntax could be defined (in Datatype.thy or below) by
   563 notation
   564   sum_case  (infixr "'(+')"80)
   565 *)
   566 
   567 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   568 apply (simp add: fun_upd_def, safe)
   569 apply (erule subst)
   570 apply (rule_tac [2] ext, auto)
   571 done
   572 
   573 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   574   by (simp only: fun_upd_idem_iff)
   575 
   576 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   577   by (simp only: fun_upd_idem)
   578 
   579 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   580 by (simp add: fun_upd_def)
   581 
   582 (* fun_upd_apply supersedes these two,   but they are useful
   583    if fun_upd_apply is intentionally removed from the simpset *)
   584 lemma fun_upd_same: "(f(x:=y)) x = y"
   585 by simp
   586 
   587 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   588 by simp
   589 
   590 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   591 by (simp add: fun_eq_iff)
   592 
   593 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   594 by (rule ext, auto)
   595 
   596 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   597 by (fastforce simp:inj_on_def image_def)
   598 
   599 lemma fun_upd_image:
   600      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   601 by auto
   602 
   603 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   604   by auto
   605 
   606 lemma UNION_fun_upd:
   607   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
   608 by (auto split: if_splits)
   609 
   610 
   611 subsection {* @{text override_on} *}
   612 
   613 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   614   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   615 
   616 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   617 by(simp add:override_on_def)
   618 
   619 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   620 by(simp add:override_on_def)
   621 
   622 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   623 by(simp add:override_on_def)
   624 
   625 
   626 subsection {* @{text swap} *}
   627 
   628 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   629   "swap a b f = f (a := f b, b:= f a)"
   630 
   631 lemma swap_self [simp]: "swap a a f = f"
   632 by (simp add: swap_def)
   633 
   634 lemma swap_commute: "swap a b f = swap b a f"
   635 by (rule ext, simp add: fun_upd_def swap_def)
   636 
   637 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   638 by (rule ext, simp add: fun_upd_def swap_def)
   639 
   640 lemma swap_triple:
   641   assumes "a \<noteq> c" and "b \<noteq> c"
   642   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   643   using assms by (simp add: fun_eq_iff swap_def)
   644 
   645 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   646 by (rule ext, simp add: fun_upd_def swap_def)
   647 
   648 lemma swap_image_eq [simp]:
   649   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   650 proof -
   651   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   652     using assms by (auto simp: image_iff swap_def)
   653   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   654   with subset[of f] show ?thesis by auto
   655 qed
   656 
   657 lemma inj_on_imp_inj_on_swap:
   658   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   659   by (simp add: inj_on_def swap_def, blast)
   660 
   661 lemma inj_on_swap_iff [simp]:
   662   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   663 proof
   664   assume "inj_on (swap a b f) A"
   665   with A have "inj_on (swap a b (swap a b f)) A"
   666     by (iprover intro: inj_on_imp_inj_on_swap)
   667   thus "inj_on f A" by simp
   668 next
   669   assume "inj_on f A"
   670   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   671 qed
   672 
   673 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   674   by simp
   675 
   676 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   677   by simp
   678 
   679 lemma bij_betw_swap_iff [simp]:
   680   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   681   by (auto simp: bij_betw_def)
   682 
   683 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   684   by simp
   685 
   686 hide_const (open) swap
   687 
   688 subsection {* Inversion of injective functions *}
   689 
   690 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   691   "the_inv_into A f == %x. THE y. y : A & f y = x"
   692 
   693 lemma the_inv_into_f_f:
   694   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   695 apply (simp add: the_inv_into_def inj_on_def)
   696 apply blast
   697 done
   698 
   699 lemma f_the_inv_into_f:
   700   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   701 apply (simp add: the_inv_into_def)
   702 apply (rule the1I2)
   703  apply(blast dest: inj_onD)
   704 apply blast
   705 done
   706 
   707 lemma the_inv_into_into:
   708   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   709 apply (simp add: the_inv_into_def)
   710 apply (rule the1I2)
   711  apply(blast dest: inj_onD)
   712 apply blast
   713 done
   714 
   715 lemma the_inv_into_onto[simp]:
   716   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   717 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   718 
   719 lemma the_inv_into_f_eq:
   720   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   721   apply (erule subst)
   722   apply (erule the_inv_into_f_f, assumption)
   723   done
   724 
   725 lemma the_inv_into_comp:
   726   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   727   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   728 apply (rule the_inv_into_f_eq)
   729   apply (fast intro: comp_inj_on)
   730  apply (simp add: f_the_inv_into_f the_inv_into_into)
   731 apply (simp add: the_inv_into_into)
   732 done
   733 
   734 lemma inj_on_the_inv_into:
   735   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   736 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   737 
   738 lemma bij_betw_the_inv_into:
   739   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   740 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   741 
   742 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   743   "the_inv f \<equiv> the_inv_into UNIV f"
   744 
   745 lemma the_inv_f_f:
   746   assumes "inj f"
   747   shows "the_inv f (f x) = x" using assms UNIV_I
   748   by (rule the_inv_into_f_f)
   749 
   750 
   751 subsection {* Cantor's Paradox *}
   752 
   753 lemma Cantors_paradox [no_atp]:
   754   "\<not>(\<exists>f. f ` A = Pow A)"
   755 proof clarify
   756   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   757   let ?X = "{a \<in> A. a \<notin> f a}"
   758   have "?X \<in> Pow A" unfolding Pow_def by auto
   759   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   760   thus False by best
   761 qed
   762 
   763 subsection {* Setup *} 
   764 
   765 subsubsection {* Proof tools *}
   766 
   767 text {* simplifies terms of the form
   768   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   769 
   770 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   771 let
   772   fun gen_fun_upd NONE T _ _ = NONE
   773     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   774   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   775   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   776     let
   777       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   778             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   779         | find t = NONE
   780     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   781 
   782   fun proc ss ct =
   783     let
   784       val ctxt = Simplifier.the_context ss
   785       val t = Thm.term_of ct
   786     in
   787       case find_double t of
   788         (T, NONE) => NONE
   789       | (T, SOME rhs) =>
   790           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   791             (fn _ =>
   792               rtac eq_reflection 1 THEN
   793               rtac ext 1 THEN
   794               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   795     end
   796 in proc end
   797 *}
   798 
   799 
   800 subsubsection {* Code generator *}
   801 
   802 code_const "op \<circ>"
   803   (SML infixl 5 "o")
   804   (Haskell infixr 9 ".")
   805 
   806 code_const "id"
   807   (Haskell "id")
   808 
   809 
   810 subsubsection {* Functorial structure of types *}
   811 
   812 ML_file "Tools/enriched_type.ML"
   813 
   814 enriched_type map_fun: map_fun
   815   by (simp_all add: fun_eq_iff)
   816 
   817 enriched_type vimage
   818   by (simp_all add: fun_eq_iff vimage_comp)
   819 
   820 text {* Legacy theorem names *}
   821 
   822 lemmas o_def = comp_def
   823 lemmas o_apply = comp_apply
   824 lemmas o_assoc = comp_assoc [symmetric]
   825 lemmas id_o = id_comp
   826 lemmas o_id = comp_id
   827 lemmas o_eq_dest = comp_eq_dest
   828 lemmas o_eq_elim = comp_eq_elim
   829 lemmas image_compose = image_comp
   830 lemmas vimage_compose = vimage_comp
   831 
   832 end
   833