src/HOL/Limits.thy
author hoelzl
Tue Mar 26 12:20:58 2013 +0100 (2013-03-26)
changeset 51526 155263089e7b
parent 51524 7cb5ac44ca9e
child 51529 2d2f59e6055a
permissions -rw-r--r--
move SEQ.thy and Lim.thy to Limits.thy
     1 (*  Title:      Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 (* Unfortunately eventually_within was overwritten by Multivariate_Analysis.
    16    Hence it was references as Limits.eventually_within, but now it is Basic_Topology.eventually_within *)
    17 lemmas eventually_within = eventually_within
    18 
    19 subsection {* Filter going to infinity norm *}
    20 
    21 definition at_infinity :: "'a::real_normed_vector filter" where
    22   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    23 
    24 lemma eventually_at_infinity:
    25   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    26 unfolding at_infinity_def
    27 proof (rule eventually_Abs_filter, rule is_filter.intro)
    28   fix P Q :: "'a \<Rightarrow> bool"
    29   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    30   then obtain r s where
    31     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    32   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    33   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    34 qed auto
    35 
    36 lemma at_infinity_eq_at_top_bot:
    37   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    38   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    39 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    40   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    41   then guess r ..
    42   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    43   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    44 next
    45   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    46   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    47   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    48     by (intro exI[of _ "max p (-q)"])
    49        (auto simp: abs_real_def)
    50 qed
    51 
    52 lemma at_top_le_at_infinity:
    53   "at_top \<le> (at_infinity :: real filter)"
    54   unfolding at_infinity_eq_at_top_bot by simp
    55 
    56 lemma at_bot_le_at_infinity:
    57   "at_bot \<le> (at_infinity :: real filter)"
    58   unfolding at_infinity_eq_at_top_bot by simp
    59 
    60 subsection {* Boundedness *}
    61 
    62 lemma Bfun_def:
    63   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    64   unfolding Bfun_metric_def norm_conv_dist
    65 proof safe
    66   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    67   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    68     by (intro always_eventually) (metis dist_commute dist_triangle)
    69   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    70     by eventually_elim auto
    71   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    72     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    73 qed auto
    74 
    75 lemma BfunI:
    76   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    77 unfolding Bfun_def
    78 proof (intro exI conjI allI)
    79   show "0 < max K 1" by simp
    80 next
    81   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    82     using K by (rule eventually_elim1, simp)
    83 qed
    84 
    85 lemma BfunE:
    86   assumes "Bfun f F"
    87   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    88 using assms unfolding Bfun_def by fast
    89 
    90 subsection {* Convergence to Zero *}
    91 
    92 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
    93   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
    94 
    95 lemma ZfunI:
    96   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
    97   unfolding Zfun_def by simp
    98 
    99 lemma ZfunD:
   100   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   101   unfolding Zfun_def by simp
   102 
   103 lemma Zfun_ssubst:
   104   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   105   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   106 
   107 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   108   unfolding Zfun_def by simp
   109 
   110 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   111   unfolding Zfun_def by simp
   112 
   113 lemma Zfun_imp_Zfun:
   114   assumes f: "Zfun f F"
   115   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   116   shows "Zfun (\<lambda>x. g x) F"
   117 proof (cases)
   118   assume K: "0 < K"
   119   show ?thesis
   120   proof (rule ZfunI)
   121     fix r::real assume "0 < r"
   122     hence "0 < r / K"
   123       using K by (rule divide_pos_pos)
   124     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   125       using ZfunD [OF f] by fast
   126     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   127     proof eventually_elim
   128       case (elim x)
   129       hence "norm (f x) * K < r"
   130         by (simp add: pos_less_divide_eq K)
   131       thus ?case
   132         by (simp add: order_le_less_trans [OF elim(1)])
   133     qed
   134   qed
   135 next
   136   assume "\<not> 0 < K"
   137   hence K: "K \<le> 0" by (simp only: not_less)
   138   show ?thesis
   139   proof (rule ZfunI)
   140     fix r :: real
   141     assume "0 < r"
   142     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   143     proof eventually_elim
   144       case (elim x)
   145       also have "norm (f x) * K \<le> norm (f x) * 0"
   146         using K norm_ge_zero by (rule mult_left_mono)
   147       finally show ?case
   148         using `0 < r` by simp
   149     qed
   150   qed
   151 qed
   152 
   153 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   154   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   155 
   156 lemma Zfun_add:
   157   assumes f: "Zfun f F" and g: "Zfun g F"
   158   shows "Zfun (\<lambda>x. f x + g x) F"
   159 proof (rule ZfunI)
   160   fix r::real assume "0 < r"
   161   hence r: "0 < r / 2" by simp
   162   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   163     using f r by (rule ZfunD)
   164   moreover
   165   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   166     using g r by (rule ZfunD)
   167   ultimately
   168   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   169   proof eventually_elim
   170     case (elim x)
   171     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   172       by (rule norm_triangle_ineq)
   173     also have "\<dots> < r/2 + r/2"
   174       using elim by (rule add_strict_mono)
   175     finally show ?case
   176       by simp
   177   qed
   178 qed
   179 
   180 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   181   unfolding Zfun_def by simp
   182 
   183 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   184   by (simp only: diff_minus Zfun_add Zfun_minus)
   185 
   186 lemma (in bounded_linear) Zfun:
   187   assumes g: "Zfun g F"
   188   shows "Zfun (\<lambda>x. f (g x)) F"
   189 proof -
   190   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   191     using bounded by fast
   192   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   193     by simp
   194   with g show ?thesis
   195     by (rule Zfun_imp_Zfun)
   196 qed
   197 
   198 lemma (in bounded_bilinear) Zfun:
   199   assumes f: "Zfun f F"
   200   assumes g: "Zfun g F"
   201   shows "Zfun (\<lambda>x. f x ** g x) F"
   202 proof (rule ZfunI)
   203   fix r::real assume r: "0 < r"
   204   obtain K where K: "0 < K"
   205     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   206     using pos_bounded by fast
   207   from K have K': "0 < inverse K"
   208     by (rule positive_imp_inverse_positive)
   209   have "eventually (\<lambda>x. norm (f x) < r) F"
   210     using f r by (rule ZfunD)
   211   moreover
   212   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   213     using g K' by (rule ZfunD)
   214   ultimately
   215   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   216   proof eventually_elim
   217     case (elim x)
   218     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   219       by (rule norm_le)
   220     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   221       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   222     also from K have "r * inverse K * K = r"
   223       by simp
   224     finally show ?case .
   225   qed
   226 qed
   227 
   228 lemma (in bounded_bilinear) Zfun_left:
   229   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   230   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   231 
   232 lemma (in bounded_bilinear) Zfun_right:
   233   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   234   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   235 
   236 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   237 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   238 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   239 
   240 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   241   by (simp only: tendsto_iff Zfun_def dist_norm)
   242 
   243 subsubsection {* Distance and norms *}
   244 
   245 lemma tendsto_norm [tendsto_intros]:
   246   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   247   unfolding norm_conv_dist by (intro tendsto_intros)
   248 
   249 lemma continuous_norm [continuous_intros]:
   250   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   251   unfolding continuous_def by (rule tendsto_norm)
   252 
   253 lemma continuous_on_norm [continuous_on_intros]:
   254   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   255   unfolding continuous_on_def by (auto intro: tendsto_norm)
   256 
   257 lemma tendsto_norm_zero:
   258   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   259   by (drule tendsto_norm, simp)
   260 
   261 lemma tendsto_norm_zero_cancel:
   262   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   263   unfolding tendsto_iff dist_norm by simp
   264 
   265 lemma tendsto_norm_zero_iff:
   266   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   267   unfolding tendsto_iff dist_norm by simp
   268 
   269 lemma tendsto_rabs [tendsto_intros]:
   270   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   271   by (fold real_norm_def, rule tendsto_norm)
   272 
   273 lemma continuous_rabs [continuous_intros]:
   274   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   275   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   276 
   277 lemma continuous_on_rabs [continuous_on_intros]:
   278   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   279   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   280 
   281 lemma tendsto_rabs_zero:
   282   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   283   by (fold real_norm_def, rule tendsto_norm_zero)
   284 
   285 lemma tendsto_rabs_zero_cancel:
   286   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   287   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   288 
   289 lemma tendsto_rabs_zero_iff:
   290   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   291   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   292 
   293 subsubsection {* Addition and subtraction *}
   294 
   295 lemma tendsto_add [tendsto_intros]:
   296   fixes a b :: "'a::real_normed_vector"
   297   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   298   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   299 
   300 lemma continuous_add [continuous_intros]:
   301   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   302   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   303   unfolding continuous_def by (rule tendsto_add)
   304 
   305 lemma continuous_on_add [continuous_on_intros]:
   306   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   307   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   308   unfolding continuous_on_def by (auto intro: tendsto_add)
   309 
   310 lemma tendsto_add_zero:
   311   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   312   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   313   by (drule (1) tendsto_add, simp)
   314 
   315 lemma tendsto_minus [tendsto_intros]:
   316   fixes a :: "'a::real_normed_vector"
   317   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   318   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   319 
   320 lemma continuous_minus [continuous_intros]:
   321   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   322   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   323   unfolding continuous_def by (rule tendsto_minus)
   324 
   325 lemma continuous_on_minus [continuous_on_intros]:
   326   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   327   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   328   unfolding continuous_on_def by (auto intro: tendsto_minus)
   329 
   330 lemma tendsto_minus_cancel:
   331   fixes a :: "'a::real_normed_vector"
   332   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   333   by (drule tendsto_minus, simp)
   334 
   335 lemma tendsto_minus_cancel_left:
   336     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   337   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   338   by auto
   339 
   340 lemma tendsto_diff [tendsto_intros]:
   341   fixes a b :: "'a::real_normed_vector"
   342   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   343   by (simp add: diff_minus tendsto_add tendsto_minus)
   344 
   345 lemma continuous_diff [continuous_intros]:
   346   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   347   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   348   unfolding continuous_def by (rule tendsto_diff)
   349 
   350 lemma continuous_on_diff [continuous_on_intros]:
   351   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   352   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   353   unfolding continuous_on_def by (auto intro: tendsto_diff)
   354 
   355 lemma tendsto_setsum [tendsto_intros]:
   356   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   357   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   358   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   359 proof (cases "finite S")
   360   assume "finite S" thus ?thesis using assms
   361     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   362 next
   363   assume "\<not> finite S" thus ?thesis
   364     by (simp add: tendsto_const)
   365 qed
   366 
   367 lemma continuous_setsum [continuous_intros]:
   368   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   369   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   370   unfolding continuous_def by (rule tendsto_setsum)
   371 
   372 lemma continuous_on_setsum [continuous_intros]:
   373   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   374   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   375   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   376 
   377 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   378 
   379 subsubsection {* Linear operators and multiplication *}
   380 
   381 lemma (in bounded_linear) tendsto:
   382   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   383   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   384 
   385 lemma (in bounded_linear) continuous:
   386   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   387   using tendsto[of g _ F] by (auto simp: continuous_def)
   388 
   389 lemma (in bounded_linear) continuous_on:
   390   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   391   using tendsto[of g] by (auto simp: continuous_on_def)
   392 
   393 lemma (in bounded_linear) tendsto_zero:
   394   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   395   by (drule tendsto, simp only: zero)
   396 
   397 lemma (in bounded_bilinear) tendsto:
   398   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   399   by (simp only: tendsto_Zfun_iff prod_diff_prod
   400                  Zfun_add Zfun Zfun_left Zfun_right)
   401 
   402 lemma (in bounded_bilinear) continuous:
   403   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   404   using tendsto[of f _ F g] by (auto simp: continuous_def)
   405 
   406 lemma (in bounded_bilinear) continuous_on:
   407   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   408   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   409 
   410 lemma (in bounded_bilinear) tendsto_zero:
   411   assumes f: "(f ---> 0) F"
   412   assumes g: "(g ---> 0) F"
   413   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   414   using tendsto [OF f g] by (simp add: zero_left)
   415 
   416 lemma (in bounded_bilinear) tendsto_left_zero:
   417   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   418   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   419 
   420 lemma (in bounded_bilinear) tendsto_right_zero:
   421   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   422   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   423 
   424 lemmas tendsto_of_real [tendsto_intros] =
   425   bounded_linear.tendsto [OF bounded_linear_of_real]
   426 
   427 lemmas tendsto_scaleR [tendsto_intros] =
   428   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   429 
   430 lemmas tendsto_mult [tendsto_intros] =
   431   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   432 
   433 lemmas continuous_of_real [continuous_intros] =
   434   bounded_linear.continuous [OF bounded_linear_of_real]
   435 
   436 lemmas continuous_scaleR [continuous_intros] =
   437   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   438 
   439 lemmas continuous_mult [continuous_intros] =
   440   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   441 
   442 lemmas continuous_on_of_real [continuous_on_intros] =
   443   bounded_linear.continuous_on [OF bounded_linear_of_real]
   444 
   445 lemmas continuous_on_scaleR [continuous_on_intros] =
   446   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   447 
   448 lemmas continuous_on_mult [continuous_on_intros] =
   449   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   450 
   451 lemmas tendsto_mult_zero =
   452   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   453 
   454 lemmas tendsto_mult_left_zero =
   455   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   456 
   457 lemmas tendsto_mult_right_zero =
   458   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   459 
   460 lemma tendsto_power [tendsto_intros]:
   461   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   462   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   463   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   464 
   465 lemma continuous_power [continuous_intros]:
   466   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   467   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   468   unfolding continuous_def by (rule tendsto_power)
   469 
   470 lemma continuous_on_power [continuous_on_intros]:
   471   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   472   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   473   unfolding continuous_on_def by (auto intro: tendsto_power)
   474 
   475 lemma tendsto_setprod [tendsto_intros]:
   476   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   477   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   478   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   479 proof (cases "finite S")
   480   assume "finite S" thus ?thesis using assms
   481     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   482 next
   483   assume "\<not> finite S" thus ?thesis
   484     by (simp add: tendsto_const)
   485 qed
   486 
   487 lemma continuous_setprod [continuous_intros]:
   488   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   489   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   490   unfolding continuous_def by (rule tendsto_setprod)
   491 
   492 lemma continuous_on_setprod [continuous_intros]:
   493   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   494   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   495   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   496 
   497 subsubsection {* Inverse and division *}
   498 
   499 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   500   assumes f: "Zfun f F"
   501   assumes g: "Bfun g F"
   502   shows "Zfun (\<lambda>x. f x ** g x) F"
   503 proof -
   504   obtain K where K: "0 \<le> K"
   505     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   506     using nonneg_bounded by fast
   507   obtain B where B: "0 < B"
   508     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   509     using g by (rule BfunE)
   510   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   511   using norm_g proof eventually_elim
   512     case (elim x)
   513     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   514       by (rule norm_le)
   515     also have "\<dots> \<le> norm (f x) * B * K"
   516       by (intro mult_mono' order_refl norm_g norm_ge_zero
   517                 mult_nonneg_nonneg K elim)
   518     also have "\<dots> = norm (f x) * (B * K)"
   519       by (rule mult_assoc)
   520     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   521   qed
   522   with f show ?thesis
   523     by (rule Zfun_imp_Zfun)
   524 qed
   525 
   526 lemma (in bounded_bilinear) flip:
   527   "bounded_bilinear (\<lambda>x y. y ** x)"
   528   apply default
   529   apply (rule add_right)
   530   apply (rule add_left)
   531   apply (rule scaleR_right)
   532   apply (rule scaleR_left)
   533   apply (subst mult_commute)
   534   using bounded by fast
   535 
   536 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   537   assumes f: "Bfun f F"
   538   assumes g: "Zfun g F"
   539   shows "Zfun (\<lambda>x. f x ** g x) F"
   540   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   541 
   542 lemma Bfun_inverse_lemma:
   543   fixes x :: "'a::real_normed_div_algebra"
   544   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   545   apply (subst nonzero_norm_inverse, clarsimp)
   546   apply (erule (1) le_imp_inverse_le)
   547   done
   548 
   549 lemma Bfun_inverse:
   550   fixes a :: "'a::real_normed_div_algebra"
   551   assumes f: "(f ---> a) F"
   552   assumes a: "a \<noteq> 0"
   553   shows "Bfun (\<lambda>x. inverse (f x)) F"
   554 proof -
   555   from a have "0 < norm a" by simp
   556   hence "\<exists>r>0. r < norm a" by (rule dense)
   557   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   558   have "eventually (\<lambda>x. dist (f x) a < r) F"
   559     using tendstoD [OF f r1] by fast
   560   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   561   proof eventually_elim
   562     case (elim x)
   563     hence 1: "norm (f x - a) < r"
   564       by (simp add: dist_norm)
   565     hence 2: "f x \<noteq> 0" using r2 by auto
   566     hence "norm (inverse (f x)) = inverse (norm (f x))"
   567       by (rule nonzero_norm_inverse)
   568     also have "\<dots> \<le> inverse (norm a - r)"
   569     proof (rule le_imp_inverse_le)
   570       show "0 < norm a - r" using r2 by simp
   571     next
   572       have "norm a - norm (f x) \<le> norm (a - f x)"
   573         by (rule norm_triangle_ineq2)
   574       also have "\<dots> = norm (f x - a)"
   575         by (rule norm_minus_commute)
   576       also have "\<dots> < r" using 1 .
   577       finally show "norm a - r \<le> norm (f x)" by simp
   578     qed
   579     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   580   qed
   581   thus ?thesis by (rule BfunI)
   582 qed
   583 
   584 lemma tendsto_inverse [tendsto_intros]:
   585   fixes a :: "'a::real_normed_div_algebra"
   586   assumes f: "(f ---> a) F"
   587   assumes a: "a \<noteq> 0"
   588   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   589 proof -
   590   from a have "0 < norm a" by simp
   591   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   592     by (rule tendstoD)
   593   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   594     unfolding dist_norm by (auto elim!: eventually_elim1)
   595   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   596     - (inverse (f x) * (f x - a) * inverse a)) F"
   597     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   598   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   599     by (intro Zfun_minus Zfun_mult_left
   600       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   601       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   602   ultimately show ?thesis
   603     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   604 qed
   605 
   606 lemma continuous_inverse:
   607   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   608   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   609   shows "continuous F (\<lambda>x. inverse (f x))"
   610   using assms unfolding continuous_def by (rule tendsto_inverse)
   611 
   612 lemma continuous_at_within_inverse[continuous_intros]:
   613   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   614   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   615   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   616   using assms unfolding continuous_within by (rule tendsto_inverse)
   617 
   618 lemma isCont_inverse[continuous_intros, simp]:
   619   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   620   assumes "isCont f a" and "f a \<noteq> 0"
   621   shows "isCont (\<lambda>x. inverse (f x)) a"
   622   using assms unfolding continuous_at by (rule tendsto_inverse)
   623 
   624 lemma continuous_on_inverse[continuous_on_intros]:
   625   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   626   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   627   shows "continuous_on s (\<lambda>x. inverse (f x))"
   628   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   629 
   630 lemma tendsto_divide [tendsto_intros]:
   631   fixes a b :: "'a::real_normed_field"
   632   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   633     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   634   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   635 
   636 lemma continuous_divide:
   637   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   638   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   639   shows "continuous F (\<lambda>x. (f x) / (g x))"
   640   using assms unfolding continuous_def by (rule tendsto_divide)
   641 
   642 lemma continuous_at_within_divide[continuous_intros]:
   643   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   644   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   645   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   646   using assms unfolding continuous_within by (rule tendsto_divide)
   647 
   648 lemma isCont_divide[continuous_intros, simp]:
   649   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   650   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   651   shows "isCont (\<lambda>x. (f x) / g x) a"
   652   using assms unfolding continuous_at by (rule tendsto_divide)
   653 
   654 lemma continuous_on_divide[continuous_on_intros]:
   655   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   656   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   657   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   658   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   659 
   660 lemma tendsto_sgn [tendsto_intros]:
   661   fixes l :: "'a::real_normed_vector"
   662   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   663   unfolding sgn_div_norm by (simp add: tendsto_intros)
   664 
   665 lemma continuous_sgn:
   666   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   667   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   668   shows "continuous F (\<lambda>x. sgn (f x))"
   669   using assms unfolding continuous_def by (rule tendsto_sgn)
   670 
   671 lemma continuous_at_within_sgn[continuous_intros]:
   672   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   673   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   674   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   675   using assms unfolding continuous_within by (rule tendsto_sgn)
   676 
   677 lemma isCont_sgn[continuous_intros]:
   678   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   679   assumes "isCont f a" and "f a \<noteq> 0"
   680   shows "isCont (\<lambda>x. sgn (f x)) a"
   681   using assms unfolding continuous_at by (rule tendsto_sgn)
   682 
   683 lemma continuous_on_sgn[continuous_on_intros]:
   684   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   685   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   686   shows "continuous_on s (\<lambda>x. sgn (f x))"
   687   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   688 
   689 lemma filterlim_at_infinity:
   690   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   691   assumes "0 \<le> c"
   692   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   693   unfolding filterlim_iff eventually_at_infinity
   694 proof safe
   695   fix P :: "'a \<Rightarrow> bool" and b
   696   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   697     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   698   have "max b (c + 1) > c" by auto
   699   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   700     by auto
   701   then show "eventually (\<lambda>x. P (f x)) F"
   702   proof eventually_elim
   703     fix x assume "max b (c + 1) \<le> norm (f x)"
   704     with P show "P (f x)" by auto
   705   qed
   706 qed force
   707 
   708 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   709 
   710 text {*
   711 
   712 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   713 @{term "at_right x"} and also @{term "at_right 0"}.
   714 
   715 *}
   716 
   717 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   718 
   719 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::real)"
   720   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   721   by (intro allI ex_cong) (auto simp: dist_real_def field_simps)
   722 
   723 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::real)"
   724   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   725   apply (intro allI ex_cong)
   726   apply (auto simp: dist_real_def field_simps)
   727   apply (erule_tac x="-x" in allE)
   728   apply simp
   729   done
   730 
   731 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::real)"
   732   unfolding at_def filtermap_nhds_shift[symmetric]
   733   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   734 
   735 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   736   unfolding filtermap_at_shift[symmetric]
   737   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   738 
   739 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   740   using filtermap_at_right_shift[of "-a" 0] by simp
   741 
   742 lemma filterlim_at_right_to_0:
   743   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   744   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   745 
   746 lemma eventually_at_right_to_0:
   747   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   748   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   749 
   750 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::real)"
   751   unfolding at_def filtermap_nhds_minus[symmetric]
   752   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   753 
   754 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   755   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   756 
   757 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   758   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   759 
   760 lemma filterlim_at_left_to_right:
   761   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   762   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   763 
   764 lemma eventually_at_left_to_right:
   765   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   766   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   767 
   768 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   769   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   770   by (metis le_minus_iff minus_minus)
   771 
   772 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   773   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   774 
   775 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   776   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   777 
   778 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   779   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   780 
   781 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   782   unfolding filterlim_at_top eventually_at_bot_dense
   783   by (metis leI minus_less_iff order_less_asym)
   784 
   785 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   786   unfolding filterlim_at_bot eventually_at_top_dense
   787   by (metis leI less_minus_iff order_less_asym)
   788 
   789 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   790   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   791   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   792   by auto
   793 
   794 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   795   unfolding filterlim_uminus_at_top by simp
   796 
   797 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   798   unfolding filterlim_at_top_gt[where c=0] eventually_within at_def
   799 proof safe
   800   fix Z :: real assume [arith]: "0 < Z"
   801   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   802     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   803   then show "eventually (\<lambda>x. x \<in> - {0} \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   804     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
   805 qed
   806 
   807 lemma filterlim_inverse_at_top:
   808   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
   809   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
   810      (simp add: filterlim_def eventually_filtermap le_within_iff at_def eventually_elim1)
   811 
   812 lemma filterlim_inverse_at_bot_neg:
   813   "LIM x (at_left (0::real)). inverse x :> at_bot"
   814   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
   815 
   816 lemma filterlim_inverse_at_bot:
   817   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
   818   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
   819   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
   820 
   821 lemma tendsto_inverse_0:
   822   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
   823   shows "(inverse ---> (0::'a)) at_infinity"
   824   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
   825 proof safe
   826   fix r :: real assume "0 < r"
   827   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
   828   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
   829     fix x :: 'a
   830     from `0 < r` have "0 < inverse (r / 2)" by simp
   831     also assume *: "inverse (r / 2) \<le> norm x"
   832     finally show "norm (inverse x) < r"
   833       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
   834   qed
   835 qed
   836 
   837 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
   838 proof (rule antisym)
   839   have "(inverse ---> (0::real)) at_top"
   840     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
   841   then show "filtermap inverse at_top \<le> at_right (0::real)"
   842     unfolding at_within_eq
   843     by (intro le_withinI) (simp_all add: eventually_filtermap eventually_gt_at_top filterlim_def)
   844 next
   845   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
   846     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
   847   then show "at_right (0::real) \<le> filtermap inverse at_top"
   848     by (simp add: filtermap_ident filtermap_filtermap)
   849 qed
   850 
   851 lemma eventually_at_right_to_top:
   852   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
   853   unfolding at_right_to_top eventually_filtermap ..
   854 
   855 lemma filterlim_at_right_to_top:
   856   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
   857   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
   858 
   859 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
   860   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
   861 
   862 lemma eventually_at_top_to_right:
   863   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
   864   unfolding at_top_to_right eventually_filtermap ..
   865 
   866 lemma filterlim_at_top_to_right:
   867   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
   868   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
   869 
   870 lemma filterlim_inverse_at_infinity:
   871   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   872   shows "filterlim inverse at_infinity (at (0::'a))"
   873   unfolding filterlim_at_infinity[OF order_refl]
   874 proof safe
   875   fix r :: real assume "0 < r"
   876   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
   877     unfolding eventually_at norm_inverse
   878     by (intro exI[of _ "inverse r"])
   879        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
   880 qed
   881 
   882 lemma filterlim_inverse_at_iff:
   883   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   884   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
   885   unfolding filterlim_def filtermap_filtermap[symmetric]
   886 proof
   887   assume "filtermap g F \<le> at_infinity"
   888   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
   889     by (rule filtermap_mono)
   890   also have "\<dots> \<le> at 0"
   891     using tendsto_inverse_0
   892     by (auto intro!: le_withinI exI[of _ 1]
   893              simp: eventually_filtermap eventually_at_infinity filterlim_def at_def)
   894   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
   895 next
   896   assume "filtermap inverse (filtermap g F) \<le> at 0"
   897   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
   898     by (rule filtermap_mono)
   899   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
   900     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
   901 qed
   902 
   903 lemma tendsto_inverse_0_at_top:
   904   "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
   905  by (metis at_top_le_at_infinity filterlim_at filterlim_inverse_at_iff filterlim_mono order_refl)
   906 
   907 text {*
   908 
   909 We only show rules for multiplication and addition when the functions are either against a real
   910 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
   911 
   912 *}
   913 
   914 lemma filterlim_tendsto_pos_mult_at_top: 
   915   assumes f: "(f ---> c) F" and c: "0 < c"
   916   assumes g: "LIM x F. g x :> at_top"
   917   shows "LIM x F. (f x * g x :: real) :> at_top"
   918   unfolding filterlim_at_top_gt[where c=0]
   919 proof safe
   920   fix Z :: real assume "0 < Z"
   921   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
   922     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
   923              simp: dist_real_def abs_real_def split: split_if_asm)
   924   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
   925     unfolding filterlim_at_top by auto
   926   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   927   proof eventually_elim
   928     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
   929     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
   930       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   931     with `0 < c` show "Z \<le> f x * g x"
   932        by simp
   933   qed
   934 qed
   935 
   936 lemma filterlim_at_top_mult_at_top: 
   937   assumes f: "LIM x F. f x :> at_top"
   938   assumes g: "LIM x F. g x :> at_top"
   939   shows "LIM x F. (f x * g x :: real) :> at_top"
   940   unfolding filterlim_at_top_gt[where c=0]
   941 proof safe
   942   fix Z :: real assume "0 < Z"
   943   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
   944     unfolding filterlim_at_top by auto
   945   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   946     unfolding filterlim_at_top by auto
   947   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   948   proof eventually_elim
   949     fix x assume "1 \<le> f x" "Z \<le> g x"
   950     with `0 < Z` have "1 * Z \<le> f x * g x"
   951       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   952     then show "Z \<le> f x * g x"
   953        by simp
   954   qed
   955 qed
   956 
   957 lemma filterlim_tendsto_pos_mult_at_bot:
   958   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
   959   shows "LIM x F. f x * g x :> at_bot"
   960   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
   961   unfolding filterlim_uminus_at_bot by simp
   962 
   963 lemma filterlim_tendsto_add_at_top: 
   964   assumes f: "(f ---> c) F"
   965   assumes g: "LIM x F. g x :> at_top"
   966   shows "LIM x F. (f x + g x :: real) :> at_top"
   967   unfolding filterlim_at_top_gt[where c=0]
   968 proof safe
   969   fix Z :: real assume "0 < Z"
   970   from f have "eventually (\<lambda>x. c - 1 < f x) F"
   971     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
   972   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
   973     unfolding filterlim_at_top by auto
   974   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   975     by eventually_elim simp
   976 qed
   977 
   978 lemma LIM_at_top_divide:
   979   fixes f g :: "'a \<Rightarrow> real"
   980   assumes f: "(f ---> a) F" "0 < a"
   981   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
   982   shows "LIM x F. f x / g x :> at_top"
   983   unfolding divide_inverse
   984   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
   985 
   986 lemma filterlim_at_top_add_at_top: 
   987   assumes f: "LIM x F. f x :> at_top"
   988   assumes g: "LIM x F. g x :> at_top"
   989   shows "LIM x F. (f x + g x :: real) :> at_top"
   990   unfolding filterlim_at_top_gt[where c=0]
   991 proof safe
   992   fix Z :: real assume "0 < Z"
   993   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
   994     unfolding filterlim_at_top by auto
   995   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   996     unfolding filterlim_at_top by auto
   997   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   998     by eventually_elim simp
   999 qed
  1000 
  1001 lemma tendsto_divide_0:
  1002   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1003   assumes f: "(f ---> c) F"
  1004   assumes g: "LIM x F. g x :> at_infinity"
  1005   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1006   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1007 
  1008 lemma linear_plus_1_le_power:
  1009   fixes x :: real
  1010   assumes x: "0 \<le> x"
  1011   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1012 proof (induct n)
  1013   case (Suc n)
  1014   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1015     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1016   also have "\<dots> \<le> (x + 1)^Suc n"
  1017     using Suc x by (simp add: mult_left_mono)
  1018   finally show ?case .
  1019 qed simp
  1020 
  1021 lemma filterlim_realpow_sequentially_gt1:
  1022   fixes x :: "'a :: real_normed_div_algebra"
  1023   assumes x[arith]: "1 < norm x"
  1024   shows "LIM n sequentially. x ^ n :> at_infinity"
  1025 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1026   fix y :: real assume "0 < y"
  1027   have "0 < norm x - 1" by simp
  1028   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1029   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1030   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1031   also have "\<dots> = norm x ^ N" by simp
  1032   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1033     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1034   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1035     unfolding eventually_sequentially
  1036     by (auto simp: norm_power)
  1037 qed simp
  1038 
  1039 
  1040 subsection {* Limits of Sequences *}
  1041 
  1042 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1043   by simp
  1044 
  1045 lemma LIMSEQ_iff:
  1046   fixes L :: "'a::real_normed_vector"
  1047   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1048 unfolding LIMSEQ_def dist_norm ..
  1049 
  1050 lemma LIMSEQ_I:
  1051   fixes L :: "'a::real_normed_vector"
  1052   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1053 by (simp add: LIMSEQ_iff)
  1054 
  1055 lemma LIMSEQ_D:
  1056   fixes L :: "'a::real_normed_vector"
  1057   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1058 by (simp add: LIMSEQ_iff)
  1059 
  1060 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1061   unfolding tendsto_def eventually_sequentially
  1062   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1063 
  1064 lemma Bseq_inverse_lemma:
  1065   fixes x :: "'a::real_normed_div_algebra"
  1066   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1067 apply (subst nonzero_norm_inverse, clarsimp)
  1068 apply (erule (1) le_imp_inverse_le)
  1069 done
  1070 
  1071 lemma Bseq_inverse:
  1072   fixes a :: "'a::real_normed_div_algebra"
  1073   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1074   by (rule Bfun_inverse)
  1075 
  1076 lemma LIMSEQ_diff_approach_zero:
  1077   fixes L :: "'a::real_normed_vector"
  1078   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1079   by (drule (1) tendsto_add, simp)
  1080 
  1081 lemma LIMSEQ_diff_approach_zero2:
  1082   fixes L :: "'a::real_normed_vector"
  1083   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1084   by (drule (1) tendsto_diff, simp)
  1085 
  1086 text{*An unbounded sequence's inverse tends to 0*}
  1087 
  1088 lemma LIMSEQ_inverse_zero:
  1089   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1090   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1091   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1092   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1093   done
  1094 
  1095 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1096 
  1097 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1098   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1099             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1100 
  1101 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1102 infinity is now easily proved*}
  1103 
  1104 lemma LIMSEQ_inverse_real_of_nat_add:
  1105      "(%n. r + inverse(real(Suc n))) ----> r"
  1106   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1107 
  1108 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1109      "(%n. r + -inverse(real(Suc n))) ----> r"
  1110   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1111   by auto
  1112 
  1113 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1114      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1115   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1116   by auto
  1117 
  1118 subsection {* Convergence on sequences *}
  1119 
  1120 lemma convergent_add:
  1121   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1122   assumes "convergent (\<lambda>n. X n)"
  1123   assumes "convergent (\<lambda>n. Y n)"
  1124   shows "convergent (\<lambda>n. X n + Y n)"
  1125   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1126 
  1127 lemma convergent_setsum:
  1128   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1129   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1130   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1131 proof (cases "finite A")
  1132   case True from this and assms show ?thesis
  1133     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1134 qed (simp add: convergent_const)
  1135 
  1136 lemma (in bounded_linear) convergent:
  1137   assumes "convergent (\<lambda>n. X n)"
  1138   shows "convergent (\<lambda>n. f (X n))"
  1139   using assms unfolding convergent_def by (fast intro: tendsto)
  1140 
  1141 lemma (in bounded_bilinear) convergent:
  1142   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1143   shows "convergent (\<lambda>n. X n ** Y n)"
  1144   using assms unfolding convergent_def by (fast intro: tendsto)
  1145 
  1146 lemma convergent_minus_iff:
  1147   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1148   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1149 apply (simp add: convergent_def)
  1150 apply (auto dest: tendsto_minus)
  1151 apply (drule tendsto_minus, auto)
  1152 done
  1153 
  1154 subsection {* Bounded Monotonic Sequences *}
  1155 
  1156 subsubsection {* Bounded Sequences *}
  1157 
  1158 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
  1159   by (intro BfunI) (auto simp: eventually_sequentially)
  1160 
  1161 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
  1162   by (intro BfunI) (auto simp: eventually_sequentially)
  1163 
  1164 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
  1165   unfolding Bfun_def eventually_sequentially
  1166 proof safe
  1167   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
  1168   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
  1169     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] min_max.less_supI2)
  1170        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
  1171 qed auto
  1172 
  1173 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
  1174 unfolding Bseq_def by auto
  1175 
  1176 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
  1177 by (simp add: Bseq_def)
  1178 
  1179 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
  1180 by (auto simp add: Bseq_def)
  1181 
  1182 lemma lemma_NBseq_def:
  1183   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
  1184 proof safe
  1185   fix K :: real
  1186   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
  1187   then have "K \<le> real (Suc n)" by auto
  1188   moreover assume "\<forall>m. norm (X m) \<le> K"
  1189   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
  1190     by (blast intro: order_trans)
  1191   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
  1192 qed (force simp add: real_of_nat_Suc)
  1193 
  1194 text{* alternative definition for Bseq *}
  1195 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
  1196 apply (simp add: Bseq_def)
  1197 apply (simp (no_asm) add: lemma_NBseq_def)
  1198 done
  1199 
  1200 lemma lemma_NBseq_def2:
  1201      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
  1202 apply (subst lemma_NBseq_def, auto)
  1203 apply (rule_tac x = "Suc N" in exI)
  1204 apply (rule_tac [2] x = N in exI)
  1205 apply (auto simp add: real_of_nat_Suc)
  1206  prefer 2 apply (blast intro: order_less_imp_le)
  1207 apply (drule_tac x = n in spec, simp)
  1208 done
  1209 
  1210 (* yet another definition for Bseq *)
  1211 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
  1212 by (simp add: Bseq_def lemma_NBseq_def2)
  1213 
  1214 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
  1215 
  1216 text{*alternative formulation for boundedness*}
  1217 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1218 apply (unfold Bseq_def, safe)
  1219 apply (rule_tac [2] x = "k + norm x" in exI)
  1220 apply (rule_tac x = K in exI, simp)
  1221 apply (rule exI [where x = 0], auto)
  1222 apply (erule order_less_le_trans, simp)
  1223 apply (drule_tac x=n in spec, fold diff_minus)
  1224 apply (drule order_trans [OF norm_triangle_ineq2])
  1225 apply simp
  1226 done
  1227 
  1228 text{*alternative formulation for boundedness*}
  1229 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1230 apply safe
  1231 apply (simp add: Bseq_def, safe)
  1232 apply (rule_tac x = "K + norm (X N)" in exI)
  1233 apply auto
  1234 apply (erule order_less_le_trans, simp)
  1235 apply (rule_tac x = N in exI, safe)
  1236 apply (drule_tac x = n in spec)
  1237 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1238 apply (auto simp add: Bseq_iff2)
  1239 done
  1240 
  1241 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1242 apply (simp add: Bseq_def)
  1243 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1244 apply (drule_tac x = n in spec, arith)
  1245 done
  1246 
  1247 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
  1248 
  1249 lemma Bseq_isUb:
  1250   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
  1251 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
  1252 
  1253 text{* Use completeness of reals (supremum property)
  1254    to show that any bounded sequence has a least upper bound*}
  1255 
  1256 lemma Bseq_isLub:
  1257   "!!(X::nat=>real). Bseq X ==>
  1258    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
  1259 by (blast intro: reals_complete Bseq_isUb)
  1260 
  1261 subsubsection{*A Bounded and Monotonic Sequence Converges*}
  1262 
  1263 (* TODO: delete *)
  1264 (* FIXME: one use in NSA/HSEQ.thy *)
  1265 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
  1266   apply (rule_tac x="X m" in exI)
  1267   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
  1268   unfolding eventually_sequentially
  1269   apply blast
  1270   done
  1271 
  1272 text {* A monotone sequence converges to its least upper bound. *}
  1273 
  1274 lemma isLub_mono_imp_LIMSEQ:
  1275   fixes X :: "nat \<Rightarrow> real"
  1276   assumes u: "isLub UNIV {x. \<exists>n. X n = x} u" (* FIXME: use 'range X' *)
  1277   assumes X: "\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n"
  1278   shows "X ----> u"
  1279 proof (rule LIMSEQ_I)
  1280   have 1: "\<forall>n. X n \<le> u"
  1281     using isLubD2 [OF u] by auto
  1282   have "\<forall>y. (\<forall>n. X n \<le> y) \<longrightarrow> u \<le> y"
  1283     using isLub_le_isUb [OF u] by (auto simp add: isUb_def setle_def)
  1284   hence 2: "\<forall>y<u. \<exists>n. y < X n"
  1285     by (metis not_le)
  1286   fix r :: real assume "0 < r"
  1287   hence "u - r < u" by simp
  1288   hence "\<exists>m. u - r < X m" using 2 by simp
  1289   then obtain m where "u - r < X m" ..
  1290   with X have "\<forall>n\<ge>m. u - r < X n"
  1291     by (fast intro: less_le_trans)
  1292   hence "\<exists>m. \<forall>n\<ge>m. u - r < X n" ..
  1293   thus "\<exists>m. \<forall>n\<ge>m. norm (X n - u) < r"
  1294     using 1 by (simp add: diff_less_eq add_commute)
  1295 qed
  1296 
  1297 text{*A standard proof of the theorem for monotone increasing sequence*}
  1298 
  1299 lemma Bseq_mono_convergent:
  1300    "Bseq X \<Longrightarrow> \<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> convergent (X::nat=>real)"
  1301   by (metis Bseq_isLub isLub_mono_imp_LIMSEQ convergentI)
  1302 
  1303 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
  1304   by (simp add: Bseq_def)
  1305 
  1306 text{*Main monotonicity theorem*}
  1307 
  1308 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1309   by (metis monoseq_iff incseq_def decseq_eq_incseq convergent_minus_iff Bseq_minus_iff
  1310             Bseq_mono_convergent)
  1311 
  1312 lemma Cauchy_iff:
  1313   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1314   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1315   unfolding Cauchy_def dist_norm ..
  1316 
  1317 lemma CauchyI:
  1318   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1319   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1320 by (simp add: Cauchy_iff)
  1321 
  1322 lemma CauchyD:
  1323   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1324   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1325 by (simp add: Cauchy_iff)
  1326 
  1327 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
  1328   apply (simp add: subset_eq)
  1329   apply (rule BseqI'[where K="max (norm a) (norm b)"])
  1330   apply (erule_tac x=n in allE)
  1331   apply auto
  1332   done
  1333 
  1334 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
  1335   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
  1336 
  1337 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
  1338   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
  1339 
  1340 lemma incseq_convergent:
  1341   fixes X :: "nat \<Rightarrow> real"
  1342   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1343   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1344 proof atomize_elim
  1345   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1346   obtain L where "X ----> L"
  1347     by (auto simp: convergent_def monoseq_def incseq_def)
  1348   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1349     by (auto intro!: exI[of _ L] incseq_le)
  1350 qed
  1351 
  1352 lemma decseq_convergent:
  1353   fixes X :: "nat \<Rightarrow> real"
  1354   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1355   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1356 proof atomize_elim
  1357   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1358   obtain L where "X ----> L"
  1359     by (auto simp: convergent_def monoseq_def decseq_def)
  1360   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1361     by (auto intro!: exI[of _ L] decseq_le)
  1362 qed
  1363 
  1364 subsubsection {* Cauchy Sequences are Bounded *}
  1365 
  1366 text{*A Cauchy sequence is bounded -- this is the standard
  1367   proof mechanization rather than the nonstandard proof*}
  1368 
  1369 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1370           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1371 apply (clarify, drule spec, drule (1) mp)
  1372 apply (simp only: norm_minus_commute)
  1373 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1374 apply simp
  1375 done
  1376 
  1377 class banach = real_normed_vector + complete_space
  1378 
  1379 instance real :: banach by default
  1380 
  1381 subsection {* Power Sequences *}
  1382 
  1383 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1384 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1385   also fact that bounded and monotonic sequence converges.*}
  1386 
  1387 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1388 apply (simp add: Bseq_def)
  1389 apply (rule_tac x = 1 in exI)
  1390 apply (simp add: power_abs)
  1391 apply (auto dest: power_mono)
  1392 done
  1393 
  1394 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1395 apply (clarify intro!: mono_SucI2)
  1396 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1397 done
  1398 
  1399 lemma convergent_realpow:
  1400   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1401 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1402 
  1403 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1404   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1405 
  1406 lemma LIMSEQ_realpow_zero:
  1407   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1408 proof cases
  1409   assume "0 \<le> x" and "x \<noteq> 0"
  1410   hence x0: "0 < x" by simp
  1411   assume x1: "x < 1"
  1412   from x0 x1 have "1 < inverse x"
  1413     by (rule one_less_inverse)
  1414   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1415     by (rule LIMSEQ_inverse_realpow_zero)
  1416   thus ?thesis by (simp add: power_inverse)
  1417 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1418 
  1419 lemma LIMSEQ_power_zero:
  1420   fixes x :: "'a::{real_normed_algebra_1}"
  1421   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1422 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1423 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1424 apply (simp add: power_abs norm_power_ineq)
  1425 done
  1426 
  1427 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1428   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1429 
  1430 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1431 
  1432 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1433   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1434 
  1435 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1436   by (rule LIMSEQ_power_zero) simp
  1437 
  1438 
  1439 subsection {* Limits of Functions *}
  1440 
  1441 lemma LIM_eq:
  1442   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1443   shows "f -- a --> L =
  1444      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1445 by (simp add: LIM_def dist_norm)
  1446 
  1447 lemma LIM_I:
  1448   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1449   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1450       ==> f -- a --> L"
  1451 by (simp add: LIM_eq)
  1452 
  1453 lemma LIM_D:
  1454   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1455   shows "[| f -- a --> L; 0<r |]
  1456       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1457 by (simp add: LIM_eq)
  1458 
  1459 lemma LIM_offset:
  1460   fixes a :: "'a::real_normed_vector"
  1461   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1462 apply (rule topological_tendstoI)
  1463 apply (drule (2) topological_tendstoD)
  1464 apply (simp only: eventually_at dist_norm)
  1465 apply (clarify, rule_tac x=d in exI, safe)
  1466 apply (drule_tac x="x + k" in spec)
  1467 apply (simp add: algebra_simps)
  1468 done
  1469 
  1470 lemma LIM_offset_zero:
  1471   fixes a :: "'a::real_normed_vector"
  1472   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1473 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1474 
  1475 lemma LIM_offset_zero_cancel:
  1476   fixes a :: "'a::real_normed_vector"
  1477   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1478 by (drule_tac k="- a" in LIM_offset, simp)
  1479 
  1480 lemma LIM_zero:
  1481   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1482   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1483 unfolding tendsto_iff dist_norm by simp
  1484 
  1485 lemma LIM_zero_cancel:
  1486   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1487   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1488 unfolding tendsto_iff dist_norm by simp
  1489 
  1490 lemma LIM_zero_iff:
  1491   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1492   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1493 unfolding tendsto_iff dist_norm by simp
  1494 
  1495 lemma LIM_imp_LIM:
  1496   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1497   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1498   assumes f: "f -- a --> l"
  1499   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1500   shows "g -- a --> m"
  1501   by (rule metric_LIM_imp_LIM [OF f],
  1502     simp add: dist_norm le)
  1503 
  1504 lemma LIM_equal2:
  1505   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1506   assumes 1: "0 < R"
  1507   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1508   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1509 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1510 
  1511 lemma LIM_compose2:
  1512   fixes a :: "'a::real_normed_vector"
  1513   assumes f: "f -- a --> b"
  1514   assumes g: "g -- b --> c"
  1515   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1516   shows "(\<lambda>x. g (f x)) -- a --> c"
  1517 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1518 
  1519 lemma real_LIM_sandwich_zero:
  1520   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1521   assumes f: "f -- a --> 0"
  1522   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1523   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1524   shows "g -- a --> 0"
  1525 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1526   fix x assume x: "x \<noteq> a"
  1527   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1528   also have "g x \<le> f x" by (rule 2 [OF x])
  1529   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1530   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1531   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1532 qed
  1533 
  1534 
  1535 subsection {* Continuity *}
  1536 
  1537 lemma LIM_isCont_iff:
  1538   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1539   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1540 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1541 
  1542 lemma isCont_iff:
  1543   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1544   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1545 by (simp add: isCont_def LIM_isCont_iff)
  1546 
  1547 lemma isCont_LIM_compose2:
  1548   fixes a :: "'a::real_normed_vector"
  1549   assumes f [unfolded isCont_def]: "isCont f a"
  1550   assumes g: "g -- f a --> l"
  1551   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1552   shows "(\<lambda>x. g (f x)) -- a --> l"
  1553 by (rule LIM_compose2 [OF f g inj])
  1554 
  1555 
  1556 lemma isCont_norm [simp]:
  1557   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1558   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1559   by (fact continuous_norm)
  1560 
  1561 lemma isCont_rabs [simp]:
  1562   fixes f :: "'a::t2_space \<Rightarrow> real"
  1563   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1564   by (fact continuous_rabs)
  1565 
  1566 lemma isCont_add [simp]:
  1567   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1568   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1569   by (fact continuous_add)
  1570 
  1571 lemma isCont_minus [simp]:
  1572   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1573   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1574   by (fact continuous_minus)
  1575 
  1576 lemma isCont_diff [simp]:
  1577   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1578   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1579   by (fact continuous_diff)
  1580 
  1581 lemma isCont_mult [simp]:
  1582   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1583   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1584   by (fact continuous_mult)
  1585 
  1586 lemma (in bounded_linear) isCont:
  1587   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1588   by (fact continuous)
  1589 
  1590 lemma (in bounded_bilinear) isCont:
  1591   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1592   by (fact continuous)
  1593 
  1594 lemmas isCont_scaleR [simp] = 
  1595   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1596 
  1597 lemmas isCont_of_real [simp] =
  1598   bounded_linear.isCont [OF bounded_linear_of_real]
  1599 
  1600 lemma isCont_power [simp]:
  1601   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1602   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1603   by (fact continuous_power)
  1604 
  1605 lemma isCont_setsum [simp]:
  1606   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1607   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1608   by (auto intro: continuous_setsum)
  1609 
  1610 lemmas isCont_intros =
  1611   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
  1612   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
  1613   isCont_of_real isCont_power isCont_sgn isCont_setsum
  1614 
  1615 subsection {* Uniform Continuity *}
  1616 
  1617 lemma (in bounded_linear) isUCont: "isUCont f"
  1618 unfolding isUCont_def dist_norm
  1619 proof (intro allI impI)
  1620   fix r::real assume r: "0 < r"
  1621   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1622     using pos_bounded by fast
  1623   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1624   proof (rule exI, safe)
  1625     from r K show "0 < r / K" by (rule divide_pos_pos)
  1626   next
  1627     fix x y :: 'a
  1628     assume xy: "norm (x - y) < r / K"
  1629     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1630     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1631     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1632     finally show "norm (f x - f y) < r" .
  1633   qed
  1634 qed
  1635 
  1636 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1637 by (rule isUCont [THEN isUCont_Cauchy])
  1638 
  1639 
  1640 lemma LIM_less_bound: 
  1641   fixes f :: "real \<Rightarrow> real"
  1642   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1643   shows "0 \<le> f x"
  1644 proof (rule tendsto_le_const)
  1645   show "(f ---> f x) (at_left x)"
  1646     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1647   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1648     using ev by (auto simp: eventually_within_less dist_real_def intro!: exI[of _ "x - b"])
  1649 qed simp
  1650 
  1651 end
  1652