src/HOL/Hilbert_Choice.thy
author hoelzl
Mon Jun 30 15:45:25 2014 +0200 (2014-06-30)
changeset 57448 159e45728ceb
parent 57275 0ddb5b755cdc
child 58074 87a8cc594bf6
permissions -rw-r--r--
more equalities of topological filters; strengthen dependent_nat_choice; tuned a couple of proofs
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded
    10 keywords "specification" :: thy_goal
    11 begin
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 axiomatization Eps :: "('a => bool) => 'a" where
    16   someI: "P x ==> P (Eps P)"
    17 
    18 syntax (epsilon)
    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    20 syntax (HOL)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" == "CONST Eps (%x. P)"
    26 
    27 print_translation {*
    28   [(@{const_syntax Eps}, fn _ => fn [Abs abs] =>
    29       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
    30       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    31 *} -- {* to avoid eta-contraction of body *}
    32 
    33 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
    34 "inv_into A f == %x. SOME y. y : A & f y = x"
    35 
    36 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
    37 "inv == inv_into UNIV"
    38 
    39 
    40 subsection {*Hilbert's Epsilon-operator*}
    41 
    42 text{*Easier to apply than @{text someI} if the witness comes from an
    43 existential formula*}
    44 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    45 apply (erule exE)
    46 apply (erule someI)
    47 done
    48 
    49 text{*Easier to apply than @{text someI} because the conclusion has only one
    50 occurrence of @{term P}.*}
    51 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    52 by (blast intro: someI)
    53 
    54 text{*Easier to apply than @{text someI2} if the witness comes from an
    55 existential formula*}
    56 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    57 by (blast intro: someI2)
    58 
    59 lemma some_equality [intro]:
    60      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    61 by (blast intro: someI2)
    62 
    63 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    64 by blast
    65 
    66 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    67 by (blast intro: someI)
    68 
    69 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    70 apply (rule some_equality)
    71 apply (rule refl, assumption)
    72 done
    73 
    74 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    75 apply (rule some_equality)
    76 apply (rule refl)
    77 apply (erule sym)
    78 done
    79 
    80 
    81 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    82 
    83 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    84 by (fast elim: someI)
    85 
    86 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    87 by (fast elim: someI)
    88 
    89 lemma choice_iff: "(\<forall>x. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x. Q x (f x))"
    90 by (fast elim: someI)
    91 
    92 lemma choice_iff': "(\<forall>x. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x. P x \<longrightarrow> Q x (f x))"
    93 by (fast elim: someI)
    94 
    95 lemma bchoice_iff: "(\<forall>x\<in>S. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. Q x (f x))"
    96 by (fast elim: someI)
    97 
    98 lemma bchoice_iff': "(\<forall>x\<in>S. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. P x \<longrightarrow> Q x (f x))"
    99 by (fast elim: someI)
   100 
   101 lemma dependent_nat_choice:
   102   assumes  1: "\<exists>x. P 0 x" and 
   103            2: "\<And>x n. P n x \<Longrightarrow> \<exists>y. P (Suc n) y \<and> Q n x y"
   104   shows "\<exists>f. \<forall>n. P n (f n) \<and> Q n (f n) (f (Suc n))"
   105 proof (intro exI allI conjI)
   106   fix n def f \<equiv> "rec_nat (SOME x. P 0 x) (\<lambda>n x. SOME y. P (Suc n) y \<and> Q n x y)"
   107   have "P 0 (f 0)" "\<And>n. P n (f n) \<Longrightarrow> P (Suc n) (f (Suc n)) \<and> Q n (f n) (f (Suc n))"
   108     using someI_ex[OF 1] someI_ex[OF 2] by (simp_all add: f_def)
   109   then show "P n (f n)" "Q n (f n) (f (Suc n))"
   110     by (induct n) auto
   111 qed
   112 
   113 subsection {*Function Inverse*}
   114 
   115 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
   116 by(simp add: inv_into_def)
   117 
   118 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
   119 apply (simp add: inv_into_def)
   120 apply (fast intro: someI2)
   121 done
   122 
   123 lemma inv_id [simp]: "inv id = id"
   124 by (simp add: inv_into_def id_def)
   125 
   126 lemma inv_into_f_f [simp]:
   127   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
   128 apply (simp add: inv_into_def inj_on_def)
   129 apply (blast intro: someI2)
   130 done
   131 
   132 lemma inv_f_f: "inj f ==> inv f (f x) = x"
   133 by simp
   134 
   135 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
   136 apply (simp add: inv_into_def)
   137 apply (fast intro: someI2)
   138 done
   139 
   140 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
   141 apply (erule subst)
   142 apply (fast intro: inv_into_f_f)
   143 done
   144 
   145 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
   146 by (simp add:inv_into_f_eq)
   147 
   148 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
   149   by (blast intro: inv_into_f_eq)
   150 
   151 text{*But is it useful?*}
   152 lemma inj_transfer:
   153   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   154   shows "P x"
   155 proof -
   156   have "f x \<in> range f" by auto
   157   hence "P(inv f (f x))" by (rule minor)
   158   thus "P x" by (simp add: inv_into_f_f [OF injf])
   159 qed
   160 
   161 lemma inj_iff: "(inj f) = (inv f o f = id)"
   162 apply (simp add: o_def fun_eq_iff)
   163 apply (blast intro: inj_on_inverseI inv_into_f_f)
   164 done
   165 
   166 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   167 by (simp add: inj_iff)
   168 
   169 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   170 by (simp add: comp_assoc)
   171 
   172 lemma inv_into_image_cancel[simp]:
   173   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
   174 by(fastforce simp: image_def)
   175 
   176 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   177 by (blast intro!: surjI inv_into_f_f)
   178 
   179 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   180 by (simp add: f_inv_into_f)
   181 
   182 lemma inv_into_injective:
   183   assumes eq: "inv_into A f x = inv_into A f y"
   184       and x: "x: f`A"
   185       and y: "y: f`A"
   186   shows "x=y"
   187 proof -
   188   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
   189   thus ?thesis by (simp add: f_inv_into_f x y)
   190 qed
   191 
   192 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
   193 by (blast intro: inj_onI dest: inv_into_injective injD)
   194 
   195 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
   196 by (auto simp add: bij_betw_def inj_on_inv_into)
   197 
   198 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   199 by (simp add: inj_on_inv_into)
   200 
   201 lemma surj_iff: "(surj f) = (f o inv f = id)"
   202 by (auto intro!: surjI simp: surj_f_inv_f fun_eq_iff[where 'b='a])
   203 
   204 lemma surj_iff_all: "surj f \<longleftrightarrow> (\<forall>x. f (inv f x) = x)"
   205   unfolding surj_iff by (simp add: o_def fun_eq_iff)
   206 
   207 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   208 apply (rule ext)
   209 apply (drule_tac x = "inv f x" in spec)
   210 apply (simp add: surj_f_inv_f)
   211 done
   212 
   213 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   214 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   215 
   216 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   217 apply (rule ext)
   218 apply (auto simp add: inv_into_def)
   219 done
   220 
   221 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   222 apply (rule inv_equality)
   223 apply (auto simp add: bij_def surj_f_inv_f)
   224 done
   225 
   226 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   227     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   228     inv f could be any function at all, including the identity function.
   229     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   230     inv(inv f)=f all fail.
   231 **)
   232 
   233 lemma inv_into_comp:
   234   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   235   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
   236 apply (rule inv_into_f_eq)
   237   apply (fast intro: comp_inj_on)
   238  apply (simp add: inv_into_into)
   239 apply (simp add: f_inv_into_f inv_into_into)
   240 done
   241 
   242 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   243 apply (rule inv_equality)
   244 apply (auto simp add: bij_def surj_f_inv_f)
   245 done
   246 
   247 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   248 by (simp add: image_eq_UN surj_f_inv_f)
   249 
   250 lemma image_inv_f_f: "inj f ==> inv f ` (f ` A) = A"
   251   by (simp add: image_eq_UN)
   252 
   253 lemma inv_image_comp: "inj f ==> inv f ` (f ` X) = X"
   254   by (fact image_inv_f_f)
   255 
   256 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   257 apply auto
   258 apply (force simp add: bij_is_inj)
   259 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   260 done
   261 
   262 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   263 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   264 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   265 done
   266 
   267 lemma finite_fun_UNIVD1:
   268   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   269   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   270   shows "finite (UNIV :: 'a set)"
   271 proof -
   272   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
   273   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
   274     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
   275   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
   276   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
   277   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
   278   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   279   proof (rule UNIV_eq_I)
   280     fix x :: 'a
   281     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
   282     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
   283   qed
   284   ultimately show "finite (UNIV :: 'a set)" by simp
   285 qed
   286 
   287 text {*
   288   Every infinite set contains a countable subset. More precisely we
   289   show that a set @{text S} is infinite if and only if there exists an
   290   injective function from the naturals into @{text S}.
   291 
   292   The ``only if'' direction is harder because it requires the
   293   construction of a sequence of pairwise different elements of an
   294   infinite set @{text S}. The idea is to construct a sequence of
   295   non-empty and infinite subsets of @{text S} obtained by successively
   296   removing elements of @{text S}.
   297 *}
   298 
   299 lemma infinite_countable_subset:
   300   assumes inf: "\<not> finite (S::'a set)"
   301   shows "\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S"
   302   -- {* Courtesy of Stephan Merz *}
   303 proof -
   304   def Sseq \<equiv> "rec_nat S (\<lambda>n T. T - {SOME e. e \<in> T})"
   305   def pick \<equiv> "\<lambda>n. (SOME e. e \<in> Sseq n)"
   306   { fix n have "Sseq n \<subseteq> S" "\<not> finite (Sseq n)" by (induct n) (auto simp add: Sseq_def inf) }
   307   moreover then have *: "\<And>n. pick n \<in> Sseq n"
   308     unfolding pick_def by (subst (asm) finite.simps) (auto simp add: ex_in_conv intro: someI_ex)
   309   ultimately have "range pick \<subseteq> S" by auto
   310   moreover
   311   { fix n m                 
   312     have "pick n \<notin> Sseq (n + Suc m)" by (induct m) (auto simp add: Sseq_def pick_def)
   313     with * have "pick n \<noteq> pick (n + Suc m)" by auto
   314   }
   315   then have "inj pick" by (intro linorder_injI) (auto simp add: less_iff_Suc_add)
   316   ultimately show ?thesis by blast
   317 qed
   318 
   319 lemma infinite_iff_countable_subset: "\<not> finite S \<longleftrightarrow> (\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S)"
   320   -- {* Courtesy of Stephan Merz *}
   321   using finite_imageD finite_subset infinite_UNIV_char_0 infinite_countable_subset by auto
   322 
   323 lemma image_inv_into_cancel:
   324   assumes SURJ: "f`A=A'" and SUB: "B' \<le> A'"
   325   shows "f `((inv_into A f)`B') = B'"
   326   using assms
   327 proof (auto simp add: f_inv_into_f)
   328   let ?f' = "(inv_into A f)"
   329   fix a' assume *: "a' \<in> B'"
   330   then have "a' \<in> A'" using SUB by auto
   331   then have "a' = f (?f' a')"
   332     using SURJ by (auto simp add: f_inv_into_f)
   333   then show "a' \<in> f ` (?f' ` B')" using * by blast
   334 qed
   335 
   336 lemma inv_into_inv_into_eq:
   337   assumes "bij_betw f A A'" "a \<in> A"
   338   shows "inv_into A' (inv_into A f) a = f a"
   339 proof -
   340   let ?f' = "inv_into A f"   let ?f'' = "inv_into A' ?f'"
   341   have 1: "bij_betw ?f' A' A" using assms
   342   by (auto simp add: bij_betw_inv_into)
   343   obtain a' where 2: "a' \<in> A'" and 3: "?f' a' = a"
   344     using 1 `a \<in> A` unfolding bij_betw_def by force
   345   hence "?f'' a = a'"
   346     using `a \<in> A` 1 3 by (auto simp add: f_inv_into_f bij_betw_def)
   347   moreover have "f a = a'" using assms 2 3
   348     by (auto simp add: bij_betw_def)
   349   ultimately show "?f'' a = f a" by simp
   350 qed
   351 
   352 lemma inj_on_iff_surj:
   353   assumes "A \<noteq> {}"
   354   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> A') \<longleftrightarrow> (\<exists>g. g ` A' = A)"
   355 proof safe
   356   fix f assume INJ: "inj_on f A" and INCL: "f ` A \<le> A'"
   357   let ?phi = "\<lambda>a' a. a \<in> A \<and> f a = a'"  let ?csi = "\<lambda>a. a \<in> A"
   358   let ?g = "\<lambda>a'. if a' \<in> f ` A then (SOME a. ?phi a' a) else (SOME a. ?csi a)"
   359   have "?g ` A' = A"
   360   proof
   361     show "?g ` A' \<le> A"
   362     proof clarify
   363       fix a' assume *: "a' \<in> A'"
   364       show "?g a' \<in> A"
   365       proof cases
   366         assume Case1: "a' \<in> f ` A"
   367         then obtain a where "?phi a' a" by blast
   368         hence "?phi a' (SOME a. ?phi a' a)" using someI[of "?phi a'" a] by blast
   369         with Case1 show ?thesis by auto
   370       next
   371         assume Case2: "a' \<notin> f ` A"
   372         hence "?csi (SOME a. ?csi a)" using assms someI_ex[of ?csi] by blast
   373         with Case2 show ?thesis by auto
   374       qed
   375     qed
   376   next
   377     show "A \<le> ?g ` A'"
   378     proof-
   379       {fix a assume *: "a \<in> A"
   380        let ?b = "SOME aa. ?phi (f a) aa"
   381        have "?phi (f a) a" using * by auto
   382        hence 1: "?phi (f a) ?b" using someI[of "?phi(f a)" a] by blast
   383        hence "?g(f a) = ?b" using * by auto
   384        moreover have "a = ?b" using 1 INJ * by (auto simp add: inj_on_def)
   385        ultimately have "?g(f a) = a" by simp
   386        with INCL * have "?g(f a) = a \<and> f a \<in> A'" by auto
   387       }
   388       thus ?thesis by force
   389     qed
   390   qed
   391   thus "\<exists>g. g ` A' = A" by blast
   392 next
   393   fix g  let ?f = "inv_into A' g"
   394   have "inj_on ?f (g ` A')"
   395     by (auto simp add: inj_on_inv_into)
   396   moreover
   397   {fix a' assume *: "a' \<in> A'"
   398    let ?phi = "\<lambda> b'. b' \<in> A' \<and> g b' = g a'"
   399    have "?phi a'" using * by auto
   400    hence "?phi(SOME b'. ?phi b')" using someI[of ?phi] by blast
   401    hence "?f(g a') \<in> A'" unfolding inv_into_def by auto
   402   }
   403   ultimately show "\<exists>f. inj_on f (g ` A') \<and> f ` g ` A' \<subseteq> A'" by auto
   404 qed
   405 
   406 lemma Ex_inj_on_UNION_Sigma:
   407   "\<exists>f. (inj_on f (\<Union> i \<in> I. A i) \<and> f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i))"
   408 proof
   409   let ?phi = "\<lambda> a i. i \<in> I \<and> a \<in> A i"
   410   let ?sm = "\<lambda> a. SOME i. ?phi a i"
   411   let ?f = "\<lambda>a. (?sm a, a)"
   412   have "inj_on ?f (\<Union> i \<in> I. A i)" unfolding inj_on_def by auto
   413   moreover
   414   { { fix i a assume "i \<in> I" and "a \<in> A i"
   415       hence "?sm a \<in> I \<and> a \<in> A(?sm a)" using someI[of "?phi a" i] by auto
   416     }
   417     hence "?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)" by auto
   418   }
   419   ultimately
   420   show "inj_on ?f (\<Union> i \<in> I. A i) \<and> ?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)"
   421   by auto
   422 qed
   423 
   424 lemma inv_unique_comp:
   425   assumes fg: "f \<circ> g = id"
   426     and gf: "g \<circ> f = id"
   427   shows "inv f = g"
   428   using fg gf inv_equality[of g f] by (auto simp add: fun_eq_iff)
   429 
   430 
   431 subsection {* The Cantor-Bernstein Theorem *}
   432 
   433 lemma Cantor_Bernstein_aux:
   434   shows "\<exists>A' h. A' \<le> A \<and>
   435                 (\<forall>a \<in> A'. a \<notin> g`(B - f ` A')) \<and>
   436                 (\<forall>a \<in> A'. h a = f a) \<and>
   437                 (\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a))"
   438 proof-
   439   obtain H where H_def: "H = (\<lambda> A'. A - (g`(B - (f ` A'))))" by blast
   440   have 0: "mono H" unfolding mono_def H_def by blast
   441   then obtain A' where 1: "H A' = A'" using lfp_unfold by blast
   442   hence 2: "A' = A - (g`(B - (f ` A')))" unfolding H_def by simp
   443   hence 3: "A' \<le> A" by blast
   444   have 4: "\<forall>a \<in> A'.  a \<notin> g`(B - f ` A')"
   445   using 2 by blast
   446   have 5: "\<forall>a \<in> A - A'. \<exists>b \<in> B - (f ` A'). a = g b"
   447   using 2 by blast
   448   (*  *)
   449   obtain h where h_def:
   450   "h = (\<lambda> a. if a \<in> A' then f a else (SOME b. b \<in> B - (f ` A') \<and> a = g b))" by blast
   451   hence "\<forall>a \<in> A'. h a = f a" by auto
   452   moreover
   453   have "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   454   proof
   455     fix a assume *: "a \<in> A - A'"
   456     let ?phi = "\<lambda> b. b \<in> B - (f ` A') \<and> a = g b"
   457     have "h a = (SOME b. ?phi b)" using h_def * by auto
   458     moreover have "\<exists>b. ?phi b" using 5 *  by auto
   459     ultimately show  "?phi (h a)" using someI_ex[of ?phi] by auto
   460   qed
   461   ultimately show ?thesis using 3 4 by blast
   462 qed
   463 
   464 theorem Cantor_Bernstein:
   465   assumes INJ1: "inj_on f A" and SUB1: "f ` A \<le> B" and
   466           INJ2: "inj_on g B" and SUB2: "g ` B \<le> A"
   467   shows "\<exists>h. bij_betw h A B"
   468 proof-
   469   obtain A' and h where 0: "A' \<le> A" and
   470   1: "\<forall>a \<in> A'. a \<notin> g`(B - f ` A')" and
   471   2: "\<forall>a \<in> A'. h a = f a" and
   472   3: "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   473   using Cantor_Bernstein_aux[of A g B f] by blast
   474   have "inj_on h A"
   475   proof (intro inj_onI)
   476     fix a1 a2
   477     assume 4: "a1 \<in> A" and 5: "a2 \<in> A" and 6: "h a1 = h a2"
   478     show "a1 = a2"
   479     proof(cases "a1 \<in> A'")
   480       assume Case1: "a1 \<in> A'"
   481       show ?thesis
   482       proof(cases "a2 \<in> A'")
   483         assume Case11: "a2 \<in> A'"
   484         hence "f a1 = f a2" using Case1 2 6 by auto
   485         thus ?thesis using INJ1 Case1 Case11 0
   486         unfolding inj_on_def by blast
   487       next
   488         assume Case12: "a2 \<notin> A'"
   489         hence False using 3 5 2 6 Case1 by force
   490         thus ?thesis by simp
   491       qed
   492     next
   493     assume Case2: "a1 \<notin> A'"
   494       show ?thesis
   495       proof(cases "a2 \<in> A'")
   496         assume Case21: "a2 \<in> A'"
   497         hence False using 3 4 2 6 Case2 by auto
   498         thus ?thesis by simp
   499       next
   500         assume Case22: "a2 \<notin> A'"
   501         hence "a1 = g(h a1) \<and> a2 = g(h a2)" using Case2 4 5 3 by auto
   502         thus ?thesis using 6 by simp
   503       qed
   504     qed
   505   qed
   506   (*  *)
   507   moreover
   508   have "h ` A = B"
   509   proof safe
   510     fix a assume "a \<in> A"
   511     thus "h a \<in> B" using SUB1 2 3 by (cases "a \<in> A'") auto
   512   next
   513     fix b assume *: "b \<in> B"
   514     show "b \<in> h ` A"
   515     proof(cases "b \<in> f ` A'")
   516       assume Case1: "b \<in> f ` A'"
   517       then obtain a where "a \<in> A' \<and> b = f a" by blast
   518       thus ?thesis using 2 0 by force
   519     next
   520       assume Case2: "b \<notin> f ` A'"
   521       hence "g b \<notin> A'" using 1 * by auto
   522       hence 4: "g b \<in> A - A'" using * SUB2 by auto
   523       hence "h(g b) \<in> B \<and> g(h(g b)) = g b"
   524       using 3 by auto
   525       hence "h(g b) = b" using * INJ2 unfolding inj_on_def by auto
   526       thus ?thesis using 4 by force
   527     qed
   528   qed
   529   (*  *)
   530   ultimately show ?thesis unfolding bij_betw_def by auto
   531 qed
   532 
   533 subsection {*Other Consequences of Hilbert's Epsilon*}
   534 
   535 text {*Hilbert's Epsilon and the @{term split} Operator*}
   536 
   537 text{*Looping simprule*}
   538 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   539   by simp
   540 
   541 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   542   by (simp add: split_def)
   543 
   544 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   545   by blast
   546 
   547 
   548 text{*A relation is wellfounded iff it has no infinite descending chain*}
   549 lemma wf_iff_no_infinite_down_chain:
   550   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   551 apply (simp only: wf_eq_minimal)
   552 apply (rule iffI)
   553  apply (rule notI)
   554  apply (erule exE)
   555  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   556 apply (erule contrapos_np, simp, clarify)
   557 apply (subgoal_tac "\<forall>n. rec_nat x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   558  apply (rule_tac x = "rec_nat x (%i y. @z. z:Q & (z,y) :r)" in exI)
   559  apply (rule allI, simp)
   560  apply (rule someI2_ex, blast, blast)
   561 apply (rule allI)
   562 apply (induct_tac "n", simp_all)
   563 apply (rule someI2_ex, blast+)
   564 done
   565 
   566 lemma wf_no_infinite_down_chainE:
   567   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   568 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   569 
   570 
   571 text{*A dynamically-scoped fact for TFL *}
   572 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   573   by (blast intro: someI)
   574 
   575 
   576 subsection {* Least value operator *}
   577 
   578 definition
   579   LeastM :: "['a => 'b::ord, 'a => bool] => 'a" where
   580   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   581 
   582 syntax
   583   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   584 translations
   585   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
   586 
   587 lemma LeastMI2:
   588   "P x ==> (!!y. P y ==> m x <= m y)
   589     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   590     ==> Q (LeastM m P)"
   591   apply (simp add: LeastM_def)
   592   apply (rule someI2_ex, blast, blast)
   593   done
   594 
   595 lemma LeastM_equality:
   596   "P k ==> (!!x. P x ==> m k <= m x)
   597     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   598   apply (rule LeastMI2, assumption, blast)
   599   apply (blast intro!: order_antisym)
   600   done
   601 
   602 lemma wf_linord_ex_has_least:
   603   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   604     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   605   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   606   apply (drule_tac x = "m`Collect P" in spec, force)
   607   done
   608 
   609 lemma ex_has_least_nat:
   610     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   611   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   612   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   613    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   614   done
   615 
   616 lemma LeastM_nat_lemma:
   617     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   618   apply (simp add: LeastM_def)
   619   apply (rule someI_ex)
   620   apply (erule ex_has_least_nat)
   621   done
   622 
   623 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1]
   624 
   625 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   626 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   627 
   628 
   629 subsection {* Greatest value operator *}
   630 
   631 definition
   632   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a" where
   633   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   634 
   635 definition
   636   Greatest :: "('a::ord => bool) => 'a" (binder "GREATEST " 10) where
   637   "Greatest == GreatestM (%x. x)"
   638 
   639 syntax
   640   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
   641       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   642 translations
   643   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
   644 
   645 lemma GreatestMI2:
   646   "P x ==> (!!y. P y ==> m y <= m x)
   647     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   648     ==> Q (GreatestM m P)"
   649   apply (simp add: GreatestM_def)
   650   apply (rule someI2_ex, blast, blast)
   651   done
   652 
   653 lemma GreatestM_equality:
   654  "P k ==> (!!x. P x ==> m x <= m k)
   655     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   656   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   657   apply (blast intro!: order_antisym)
   658   done
   659 
   660 lemma Greatest_equality:
   661   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   662   apply (simp add: Greatest_def)
   663   apply (erule GreatestM_equality, blast)
   664   done
   665 
   666 lemma ex_has_greatest_nat_lemma:
   667   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   668     ==> \<exists>y. P y & ~ (m y < m k + n)"
   669   apply (induct n, force)
   670   apply (force simp add: le_Suc_eq)
   671   done
   672 
   673 lemma ex_has_greatest_nat:
   674   "P k ==> \<forall>y. P y --> m y < b
   675     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   676   apply (rule ccontr)
   677   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   678     apply (subgoal_tac [3] "m k <= b", auto)
   679   done
   680 
   681 lemma GreatestM_nat_lemma:
   682   "P k ==> \<forall>y. P y --> m y < b
   683     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   684   apply (simp add: GreatestM_def)
   685   apply (rule someI_ex)
   686   apply (erule ex_has_greatest_nat, assumption)
   687   done
   688 
   689 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1]
   690 
   691 lemma GreatestM_nat_le:
   692   "P x ==> \<forall>y. P y --> m y < b
   693     ==> (m x::nat) <= m (GreatestM m P)"
   694   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   695   done
   696 
   697 
   698 text {* \medskip Specialization to @{text GREATEST}. *}
   699 
   700 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   701   apply (simp add: Greatest_def)
   702   apply (rule GreatestM_natI, auto)
   703   done
   704 
   705 lemma Greatest_le:
   706     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   707   apply (simp add: Greatest_def)
   708   apply (rule GreatestM_nat_le, auto)
   709   done
   710 
   711 
   712 subsection {* An aside: bounded accessible part *}
   713 
   714 text {* Finite monotone eventually stable sequences *}
   715 
   716 lemma finite_mono_remains_stable_implies_strict_prefix:
   717   fixes f :: "nat \<Rightarrow> 'a::order"
   718   assumes S: "finite (range f)" "mono f" and eq: "\<forall>n. f n = f (Suc n) \<longrightarrow> f (Suc n) = f (Suc (Suc n))"
   719   shows "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m < f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   720   using assms
   721 proof -
   722   have "\<exists>n. f n = f (Suc n)"
   723   proof (rule ccontr)
   724     assume "\<not> ?thesis"
   725     then have "\<And>n. f n \<noteq> f (Suc n)" by auto
   726     then have "\<And>n. f n < f (Suc n)"
   727       using  `mono f` by (auto simp: le_less mono_iff_le_Suc)
   728     with lift_Suc_mono_less_iff[of f]
   729     have *: "\<And>n m. n < m \<Longrightarrow> f n < f m" by auto
   730     have "inj f"
   731     proof (intro injI)
   732       fix x y
   733       assume "f x = f y"
   734       then show "x = y" by (cases x y rule: linorder_cases) (auto dest: *)
   735     qed
   736     with `finite (range f)` have "finite (UNIV::nat set)"
   737       by (rule finite_imageD)
   738     then show False by simp
   739   qed
   740   then obtain n where n: "f n = f (Suc n)" ..
   741   def N \<equiv> "LEAST n. f n = f (Suc n)"
   742   have N: "f N = f (Suc N)"
   743     unfolding N_def using n by (rule LeastI)
   744   show ?thesis
   745   proof (intro exI[of _ N] conjI allI impI)
   746     fix n assume "N \<le> n"
   747     then have "\<And>m. N \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m = f N"
   748     proof (induct rule: dec_induct)
   749       case (step n) then show ?case
   750         using eq[rule_format, of "n - 1"] N
   751         by (cases n) (auto simp add: le_Suc_eq)
   752     qed simp
   753     from this[of n] `N \<le> n` show "f N = f n" by auto
   754   next
   755     fix n m :: nat assume "m < n" "n \<le> N"
   756     then show "f m < f n"
   757     proof (induct rule: less_Suc_induct[consumes 1])
   758       case (1 i)
   759       then have "i < N" by simp
   760       then have "f i \<noteq> f (Suc i)"
   761         unfolding N_def by (rule not_less_Least)
   762       with `mono f` show ?case by (simp add: mono_iff_le_Suc less_le)
   763     qed auto
   764   qed
   765 qed
   766 
   767 lemma finite_mono_strict_prefix_implies_finite_fixpoint:
   768   fixes f :: "nat \<Rightarrow> 'a set"
   769   assumes S: "\<And>i. f i \<subseteq> S" "finite S"
   770     and inj: "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   771   shows "f (card S) = (\<Union>n. f n)"
   772 proof -
   773   from inj obtain N where inj: "(\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n)" and eq: "(\<forall>n\<ge>N. f N = f n)" by auto
   774 
   775   { fix i have "i \<le> N \<Longrightarrow> i \<le> card (f i)"
   776     proof (induct i)
   777       case 0 then show ?case by simp
   778     next
   779       case (Suc i)
   780       with inj[rule_format, of "Suc i" i]
   781       have "(f i) \<subset> (f (Suc i))" by auto
   782       moreover have "finite (f (Suc i))" using S by (rule finite_subset)
   783       ultimately have "card (f i) < card (f (Suc i))" by (intro psubset_card_mono)
   784       with Suc show ?case using inj by auto
   785     qed
   786   }
   787   then have "N \<le> card (f N)" by simp
   788   also have "\<dots> \<le> card S" using S by (intro card_mono)
   789   finally have "f (card S) = f N" using eq by auto
   790   then show ?thesis using eq inj[rule_format, of N]
   791     apply auto
   792     apply (case_tac "n < N")
   793     apply (auto simp: not_less)
   794     done
   795 qed
   796 
   797 
   798 subsection {* More on injections, bijections, and inverses *}
   799 
   800 lemma infinite_imp_bij_betw:
   801 assumes INF: "\<not> finite A"
   802 shows "\<exists>h. bij_betw h A (A - {a})"
   803 proof(cases "a \<in> A")
   804   assume Case1: "a \<notin> A"  hence "A - {a} = A" by blast
   805   thus ?thesis using bij_betw_id[of A] by auto
   806 next
   807   assume Case2: "a \<in> A"
   808 find_theorems "\<not> finite _"
   809   have "\<not> finite (A - {a})" using INF by auto
   810   with infinite_iff_countable_subset[of "A - {a}"] obtain f::"nat \<Rightarrow> 'a"
   811   where 1: "inj f" and 2: "f ` UNIV \<le> A - {a}" by blast
   812   obtain g where g_def: "g = (\<lambda> n. if n = 0 then a else f (Suc n))" by blast
   813   obtain A' where A'_def: "A' = g ` UNIV" by blast
   814   have temp: "\<forall>y. f y \<noteq> a" using 2 by blast
   815   have 3: "inj_on g UNIV \<and> g ` UNIV \<le> A \<and> a \<in> g ` UNIV"
   816   proof(auto simp add: Case2 g_def, unfold inj_on_def, intro ballI impI,
   817         case_tac "x = 0", auto simp add: 2)
   818     fix y  assume "a = (if y = 0 then a else f (Suc y))"
   819     thus "y = 0" using temp by (case_tac "y = 0", auto)
   820   next
   821     fix x y
   822     assume "f (Suc x) = (if y = 0 then a else f (Suc y))"
   823     thus "x = y" using 1 temp unfolding inj_on_def by (case_tac "y = 0", auto)
   824   next
   825     fix n show "f (Suc n) \<in> A" using 2 by blast
   826   qed
   827   hence 4: "bij_betw g UNIV A' \<and> a \<in> A' \<and> A' \<le> A"
   828   using inj_on_imp_bij_betw[of g] unfolding A'_def by auto
   829   hence 5: "bij_betw (inv g) A' UNIV"
   830   by (auto simp add: bij_betw_inv_into)
   831   (*  *)
   832   obtain n where "g n = a" using 3 by auto
   833   hence 6: "bij_betw g (UNIV - {n}) (A' - {a})"
   834   using 3 4 unfolding A'_def
   835   by clarify (rule bij_betw_subset, auto simp: image_set_diff)
   836   (*  *)
   837   obtain v where v_def: "v = (\<lambda> m. if m < n then m else Suc m)" by blast
   838   have 7: "bij_betw v UNIV (UNIV - {n})"
   839   proof(unfold bij_betw_def inj_on_def, intro conjI, clarify)
   840     fix m1 m2 assume "v m1 = v m2"
   841     thus "m1 = m2"
   842     by(case_tac "m1 < n", case_tac "m2 < n",
   843        auto simp add: inj_on_def v_def, case_tac "m2 < n", auto)
   844   next
   845     show "v ` UNIV = UNIV - {n}"
   846     proof(auto simp add: v_def)
   847       fix m assume *: "m \<noteq> n" and **: "m \<notin> Suc ` {m'. \<not> m' < n}"
   848       {assume "n \<le> m" with * have 71: "Suc n \<le> m" by auto
   849        then obtain m' where 72: "m = Suc m'" using Suc_le_D by auto
   850        with 71 have "n \<le> m'" by auto
   851        with 72 ** have False by auto
   852       }
   853       thus "m < n" by force
   854     qed
   855   qed
   856   (*  *)
   857   obtain h' where h'_def: "h' = g o v o (inv g)" by blast
   858   hence 8: "bij_betw h' A' (A' - {a})" using 5 7 6
   859   by (auto simp add: bij_betw_trans)
   860   (*  *)
   861   obtain h where h_def: "h = (\<lambda> b. if b \<in> A' then h' b else b)" by blast
   862   have "\<forall>b \<in> A'. h b = h' b" unfolding h_def by auto
   863   hence "bij_betw h  A' (A' - {a})" using 8 bij_betw_cong[of A' h] by auto
   864   moreover
   865   {have "\<forall>b \<in> A - A'. h b = b" unfolding h_def by auto
   866    hence "bij_betw h  (A - A') (A - A')"
   867    using bij_betw_cong[of "A - A'" h id] bij_betw_id[of "A - A'"] by auto
   868   }
   869   moreover
   870   have "(A' Int (A - A') = {} \<and> A' \<union> (A - A') = A) \<and>
   871         ((A' - {a}) Int (A - A') = {} \<and> (A' - {a}) \<union> (A - A') = A - {a})"
   872   using 4 by blast
   873   ultimately have "bij_betw h A (A - {a})"
   874   using bij_betw_combine[of h A' "A' - {a}" "A - A'" "A - A'"] by simp
   875   thus ?thesis by blast
   876 qed
   877 
   878 lemma infinite_imp_bij_betw2:
   879 assumes INF: "\<not> finite A"
   880 shows "\<exists>h. bij_betw h A (A \<union> {a})"
   881 proof(cases "a \<in> A")
   882   assume Case1: "a \<in> A"  hence "A \<union> {a} = A" by blast
   883   thus ?thesis using bij_betw_id[of A] by auto
   884 next
   885   let ?A' = "A \<union> {a}"
   886   assume Case2: "a \<notin> A" hence "A = ?A' - {a}" by blast
   887   moreover have "\<not> finite ?A'" using INF by auto
   888   ultimately obtain f where "bij_betw f ?A' A"
   889   using infinite_imp_bij_betw[of ?A' a] by auto
   890   hence "bij_betw(inv_into ?A' f) A ?A'" using bij_betw_inv_into by blast
   891   thus ?thesis by auto
   892 qed
   893 
   894 lemma bij_betw_inv_into_left:
   895 assumes BIJ: "bij_betw f A A'" and IN: "a \<in> A"
   896 shows "(inv_into A f) (f a) = a"
   897 using assms unfolding bij_betw_def
   898 by clarify (rule inv_into_f_f)
   899 
   900 lemma bij_betw_inv_into_right:
   901 assumes "bij_betw f A A'" "a' \<in> A'"
   902 shows "f(inv_into A f a') = a'"
   903 using assms unfolding bij_betw_def using f_inv_into_f by force
   904 
   905 lemma bij_betw_inv_into_subset:
   906 assumes BIJ: "bij_betw f A A'" and
   907         SUB: "B \<le> A" and IM: "f ` B = B'"
   908 shows "bij_betw (inv_into A f) B' B"
   909 using assms unfolding bij_betw_def
   910 by (auto intro: inj_on_inv_into)
   911 
   912 
   913 subsection {* Specification package -- Hilbertized version *}
   914 
   915 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   916   by (simp only: someI_ex)
   917 
   918 ML_file "Tools/choice_specification.ML"
   919 
   920 end
   921