src/HOL/Complex.thy
author haftmann
Wed Dec 03 15:58:44 2008 +0100 (2008-12-03)
changeset 28952 15a4b2cf8c34
parent 28944 src/HOL/Complex/Complex.thy@e27abf0db984
child 29233 ce6d35a0bed6
permissions -rw-r--r--
made repository layout more coherent with logical distribution structure; stripped some $Id$s
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: "{field, division_by_zero}"
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Exponentiation *}
   161 
   162 instantiation complex :: recpower
   163 begin
   164 
   165 primrec power_complex where
   166   complexpow_0:     "z ^ 0     = (1\<Colon>complex)"
   167   | complexpow_Suc: "z ^ Suc n = (z\<Colon>complex) * z ^ n"
   168 
   169 instance by intro_classes simp_all
   170 
   171 end
   172 
   173 
   174 subsection {* Numerals and Arithmetic *}
   175 
   176 instantiation complex :: number_ring
   177 begin
   178 
   179 definition number_of_complex where
   180   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   181 
   182 instance
   183   by intro_classes (simp only: complex_number_of_def)
   184 
   185 end
   186 
   187 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   188 by (induct n) simp_all
   189 
   190 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   191 by (induct n) simp_all
   192 
   193 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   194 by (cases z rule: int_diff_cases) simp
   195 
   196 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   197 by (cases z rule: int_diff_cases) simp
   198 
   199 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   200 unfolding number_of_eq by (rule complex_Re_of_int)
   201 
   202 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   203 unfolding number_of_eq by (rule complex_Im_of_int)
   204 
   205 lemma Complex_eq_number_of [simp]:
   206   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   207 by (simp add: expand_complex_eq)
   208 
   209 
   210 subsection {* Scalar Multiplication *}
   211 
   212 instantiation complex :: real_field
   213 begin
   214 
   215 definition
   216   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   217 
   218 lemma complex_scaleR [simp]:
   219   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   220   unfolding complex_scaleR_def by simp
   221 
   222 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   223   unfolding complex_scaleR_def by simp
   224 
   225 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   226   unfolding complex_scaleR_def by simp
   227 
   228 instance
   229 proof
   230   fix a b :: real and x y :: complex
   231   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   232     by (simp add: expand_complex_eq right_distrib)
   233   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   234     by (simp add: expand_complex_eq left_distrib)
   235   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   236     by (simp add: expand_complex_eq mult_assoc)
   237   show "scaleR 1 x = x"
   238     by (simp add: expand_complex_eq)
   239   show "scaleR a x * y = scaleR a (x * y)"
   240     by (simp add: expand_complex_eq ring_simps)
   241   show "x * scaleR a y = scaleR a (x * y)"
   242     by (simp add: expand_complex_eq ring_simps)
   243 qed
   244 
   245 end
   246 
   247 
   248 subsection{* Properties of Embedding from Reals *}
   249 
   250 abbreviation
   251   complex_of_real :: "real \<Rightarrow> complex" where
   252     "complex_of_real \<equiv> of_real"
   253 
   254 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   255 by (simp add: of_real_def complex_scaleR_def)
   256 
   257 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   258 by (simp add: complex_of_real_def)
   259 
   260 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   261 by (simp add: complex_of_real_def)
   262 
   263 lemma Complex_add_complex_of_real [simp]:
   264      "Complex x y + complex_of_real r = Complex (x+r) y"
   265 by (simp add: complex_of_real_def)
   266 
   267 lemma complex_of_real_add_Complex [simp]:
   268      "complex_of_real r + Complex x y = Complex (r+x) y"
   269 by (simp add: complex_of_real_def)
   270 
   271 lemma Complex_mult_complex_of_real:
   272      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   273 by (simp add: complex_of_real_def)
   274 
   275 lemma complex_of_real_mult_Complex:
   276      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   277 by (simp add: complex_of_real_def)
   278 
   279 
   280 subsection {* Vector Norm *}
   281 
   282 instantiation complex :: real_normed_field
   283 begin
   284 
   285 definition
   286   complex_norm_def: "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   287 
   288 abbreviation
   289   cmod :: "complex \<Rightarrow> real" where
   290   "cmod \<equiv> norm"
   291 
   292 definition
   293   complex_sgn_def: "sgn x = x /\<^sub>R cmod x"
   294 
   295 lemmas cmod_def = complex_norm_def
   296 
   297 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   298   by (simp add: complex_norm_def)
   299 
   300 instance
   301 proof
   302   fix r :: real and x y :: complex
   303   show "0 \<le> norm x"
   304     by (induct x) simp
   305   show "(norm x = 0) = (x = 0)"
   306     by (induct x) simp
   307   show "norm (x + y) \<le> norm x + norm y"
   308     by (induct x, induct y)
   309        (simp add: real_sqrt_sum_squares_triangle_ineq)
   310   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   311     by (induct x)
   312        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   313   show "norm (x * y) = norm x * norm y"
   314     by (induct x, induct y)
   315        (simp add: real_sqrt_mult [symmetric] power2_eq_square ring_simps)
   316   show "sgn x = x /\<^sub>R cmod x" by(simp add: complex_sgn_def)
   317 qed
   318 
   319 end
   320 
   321 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   322 by simp
   323 
   324 lemma cmod_complex_polar [simp]:
   325      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   326 by (simp add: norm_mult)
   327 
   328 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   329 unfolding complex_norm_def
   330 by (rule real_sqrt_sum_squares_ge1)
   331 
   332 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   333 by (rule order_trans [OF _ norm_ge_zero], simp)
   334 
   335 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   336 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   337 
   338 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   339 
   340 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   341 by (cases x) simp
   342 
   343 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   344 by (cases x) simp
   345 
   346 subsection {* Completeness of the Complexes *}
   347 
   348 interpretation Re: bounded_linear ["Re"]
   349 apply (unfold_locales, simp, simp)
   350 apply (rule_tac x=1 in exI)
   351 apply (simp add: complex_norm_def)
   352 done
   353 
   354 interpretation Im: bounded_linear ["Im"]
   355 apply (unfold_locales, simp, simp)
   356 apply (rule_tac x=1 in exI)
   357 apply (simp add: complex_norm_def)
   358 done
   359 
   360 lemma LIMSEQ_Complex:
   361   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   362 apply (rule LIMSEQ_I)
   363 apply (subgoal_tac "0 < r / sqrt 2")
   364 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   365 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   366 apply (rename_tac M N, rule_tac x="max M N" in exI, safe)
   367 apply (simp add: real_sqrt_sum_squares_less)
   368 apply (simp add: divide_pos_pos)
   369 done
   370 
   371 instance complex :: banach
   372 proof
   373   fix X :: "nat \<Rightarrow> complex"
   374   assume X: "Cauchy X"
   375   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   376     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   377   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   378     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   379   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   380     using LIMSEQ_Complex [OF 1 2] by simp
   381   thus "convergent X"
   382     by (rule convergentI)
   383 qed
   384 
   385 
   386 subsection {* The Complex Number @{term "\<i>"} *}
   387 
   388 definition
   389   "ii" :: complex  ("\<i>") where
   390   i_def: "ii \<equiv> Complex 0 1"
   391 
   392 lemma complex_Re_i [simp]: "Re ii = 0"
   393 by (simp add: i_def)
   394 
   395 lemma complex_Im_i [simp]: "Im ii = 1"
   396 by (simp add: i_def)
   397 
   398 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   399 by (simp add: i_def)
   400 
   401 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   402 by (simp add: expand_complex_eq)
   403 
   404 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   405 by (simp add: expand_complex_eq)
   406 
   407 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   408 by (simp add: expand_complex_eq)
   409 
   410 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   411 by (simp add: expand_complex_eq)
   412 
   413 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   414 by (simp add: expand_complex_eq)
   415 
   416 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   417 by (simp add: i_def complex_of_real_def)
   418 
   419 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   420 by (simp add: i_def complex_of_real_def)
   421 
   422 lemma i_squared [simp]: "ii * ii = -1"
   423 by (simp add: i_def)
   424 
   425 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   426 by (simp add: power2_eq_square)
   427 
   428 lemma inverse_i [simp]: "inverse ii = - ii"
   429 by (rule inverse_unique, simp)
   430 
   431 
   432 subsection {* Complex Conjugation *}
   433 
   434 definition
   435   cnj :: "complex \<Rightarrow> complex" where
   436   "cnj z = Complex (Re z) (- Im z)"
   437 
   438 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   439 by (simp add: cnj_def)
   440 
   441 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   442 by (simp add: cnj_def)
   443 
   444 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   445 by (simp add: cnj_def)
   446 
   447 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   448 by (simp add: expand_complex_eq)
   449 
   450 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   451 by (simp add: cnj_def)
   452 
   453 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   454 by (simp add: expand_complex_eq)
   455 
   456 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   457 by (simp add: expand_complex_eq)
   458 
   459 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   460 by (simp add: expand_complex_eq)
   461 
   462 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   463 by (simp add: expand_complex_eq)
   464 
   465 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   466 by (simp add: expand_complex_eq)
   467 
   468 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   469 by (simp add: expand_complex_eq)
   470 
   471 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   472 by (simp add: expand_complex_eq)
   473 
   474 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   475 by (simp add: complex_inverse_def)
   476 
   477 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   478 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   479 
   480 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   481 by (induct n, simp_all add: complex_cnj_mult)
   482 
   483 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   484 by (simp add: expand_complex_eq)
   485 
   486 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   487 by (simp add: expand_complex_eq)
   488 
   489 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   490 by (simp add: expand_complex_eq)
   491 
   492 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   493 by (simp add: expand_complex_eq)
   494 
   495 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   496 by (simp add: complex_norm_def)
   497 
   498 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   499 by (simp add: expand_complex_eq)
   500 
   501 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   502 by (simp add: expand_complex_eq)
   503 
   504 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   505 by (simp add: expand_complex_eq)
   506 
   507 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   508 by (simp add: expand_complex_eq)
   509 
   510 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   511 by (simp add: expand_complex_eq power2_eq_square)
   512 
   513 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   514 by (simp add: norm_mult power2_eq_square)
   515 
   516 interpretation cnj: bounded_linear ["cnj"]
   517 apply (unfold_locales)
   518 apply (rule complex_cnj_add)
   519 apply (rule complex_cnj_scaleR)
   520 apply (rule_tac x=1 in exI, simp)
   521 done
   522 
   523 
   524 subsection{*The Functions @{term sgn} and @{term arg}*}
   525 
   526 text {*------------ Argand -------------*}
   527 
   528 definition
   529   arg :: "complex => real" where
   530   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   531 
   532 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   533 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   534 
   535 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   536 by (simp add: i_def complex_of_real_def)
   537 
   538 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   539 by (simp add: i_def complex_one_def)
   540 
   541 lemma complex_eq_cancel_iff2 [simp]:
   542      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   543 by (simp add: complex_of_real_def)
   544 
   545 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   546 by (simp add: complex_sgn_def divide_inverse)
   547 
   548 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   549 by (simp add: complex_sgn_def divide_inverse)
   550 
   551 lemma complex_inverse_complex_split:
   552      "inverse(complex_of_real x + ii * complex_of_real y) =
   553       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   554       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   555 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   556 
   557 (*----------------------------------------------------------------------------*)
   558 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   559 (* many of the theorems are not used - so should they be kept?                *)
   560 (*----------------------------------------------------------------------------*)
   561 
   562 lemma cos_arg_i_mult_zero_pos:
   563    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   564 apply (simp add: arg_def abs_if)
   565 apply (rule_tac a = "pi/2" in someI2, auto)
   566 apply (rule order_less_trans [of _ 0], auto)
   567 done
   568 
   569 lemma cos_arg_i_mult_zero_neg:
   570    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   571 apply (simp add: arg_def abs_if)
   572 apply (rule_tac a = "- pi/2" in someI2, auto)
   573 apply (rule order_trans [of _ 0], auto)
   574 done
   575 
   576 lemma cos_arg_i_mult_zero [simp]:
   577      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   578 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   579 
   580 
   581 subsection{*Finally! Polar Form for Complex Numbers*}
   582 
   583 definition
   584 
   585   (* abbreviation for (cos a + i sin a) *)
   586   cis :: "real => complex" where
   587   "cis a = Complex (cos a) (sin a)"
   588 
   589 definition
   590   (* abbreviation for r*(cos a + i sin a) *)
   591   rcis :: "[real, real] => complex" where
   592   "rcis r a = complex_of_real r * cis a"
   593 
   594 definition
   595   (* e ^ (x + iy) *)
   596   expi :: "complex => complex" where
   597   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   598 
   599 lemma complex_split_polar:
   600      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   601 apply (induct z)
   602 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   603 done
   604 
   605 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   606 apply (induct z)
   607 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   608 done
   609 
   610 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   611 by (simp add: rcis_def cis_def)
   612 
   613 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   614 by (simp add: rcis_def cis_def)
   615 
   616 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   617 proof -
   618   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   619     by (simp only: power_mult_distrib right_distrib)
   620   thus ?thesis by simp
   621 qed
   622 
   623 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   624 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   625 
   626 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   627 by (simp add: cmod_def power2_eq_square)
   628 
   629 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   630 by simp
   631 
   632 
   633 (*---------------------------------------------------------------------------*)
   634 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   635 (*---------------------------------------------------------------------------*)
   636 
   637 lemma cis_rcis_eq: "cis a = rcis 1 a"
   638 by (simp add: rcis_def)
   639 
   640 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   641 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   642               complex_of_real_def)
   643 
   644 lemma cis_mult: "cis a * cis b = cis (a + b)"
   645 by (simp add: cis_rcis_eq rcis_mult)
   646 
   647 lemma cis_zero [simp]: "cis 0 = 1"
   648 by (simp add: cis_def complex_one_def)
   649 
   650 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   651 by (simp add: rcis_def)
   652 
   653 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   654 by (simp add: rcis_def)
   655 
   656 lemma complex_of_real_minus_one:
   657    "complex_of_real (-(1::real)) = -(1::complex)"
   658 by (simp add: complex_of_real_def complex_one_def)
   659 
   660 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   661 by (simp add: mult_assoc [symmetric])
   662 
   663 
   664 lemma cis_real_of_nat_Suc_mult:
   665    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   666 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   667 
   668 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   669 apply (induct_tac "n")
   670 apply (auto simp add: cis_real_of_nat_Suc_mult)
   671 done
   672 
   673 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   674 by (simp add: rcis_def power_mult_distrib DeMoivre)
   675 
   676 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   677 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   678 
   679 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   680 by (simp add: divide_inverse rcis_def)
   681 
   682 lemma cis_divide: "cis a / cis b = cis (a - b)"
   683 by (simp add: complex_divide_def cis_mult real_diff_def)
   684 
   685 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   686 apply (simp add: complex_divide_def)
   687 apply (case_tac "r2=0", simp)
   688 apply (simp add: rcis_inverse rcis_mult real_diff_def)
   689 done
   690 
   691 lemma Re_cis [simp]: "Re(cis a) = cos a"
   692 by (simp add: cis_def)
   693 
   694 lemma Im_cis [simp]: "Im(cis a) = sin a"
   695 by (simp add: cis_def)
   696 
   697 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   698 by (auto simp add: DeMoivre)
   699 
   700 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   701 by (auto simp add: DeMoivre)
   702 
   703 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   704 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   705 
   706 lemma expi_zero [simp]: "expi (0::complex) = 1"
   707 by (simp add: expi_def)
   708 
   709 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   710 apply (insert rcis_Ex [of z])
   711 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   712 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   713 done
   714 
   715 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   716 by (simp add: expi_def cis_def)
   717 
   718 end