src/HOL/Tools/hologic.ML
author wenzelm
Wed Dec 01 15:35:40 2010 +0100 (2010-12-01)
changeset 40845 15b97bd4b5c0
parent 40627 becf5d5187cc
child 41339 481c89fabcbc
permissions -rw-r--r--
just one HOLogic.mk_comp;
     1 (*  Title:      HOL/Tools/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val mk_comp: term * term -> term
    12   val boolN: string
    13   val boolT: typ
    14   val Trueprop: term
    15   val mk_Trueprop: term -> term
    16   val dest_Trueprop: term -> term
    17   val true_const: term
    18   val false_const: term
    19   val mk_setT: typ -> typ
    20   val dest_setT: typ -> typ
    21   val Collect_const: typ -> term
    22   val mk_Collect: string * typ * term -> term
    23   val mk_mem: term * term -> term
    24   val dest_mem: term -> term * term
    25   val mk_set: typ -> term list -> term
    26   val dest_set: term -> term list
    27   val mk_UNIV: typ -> term
    28   val conj_intr: thm -> thm -> thm
    29   val conj_elim: thm -> thm * thm
    30   val conj_elims: thm -> thm list
    31   val conj: term
    32   val disj: term
    33   val imp: term
    34   val Not: term
    35   val mk_conj: term * term -> term
    36   val mk_disj: term * term -> term
    37   val mk_imp: term * term -> term
    38   val mk_not: term -> term
    39   val dest_conj: term -> term list
    40   val dest_disj: term -> term list
    41   val disjuncts: term -> term list
    42   val dest_imp: term -> term * term
    43   val dest_not: term -> term
    44   val eq_const: typ -> term
    45   val mk_eq: term * term -> term
    46   val dest_eq: term -> term * term
    47   val all_const: typ -> term
    48   val mk_all: string * typ * term -> term
    49   val list_all: (string * typ) list * term -> term
    50   val exists_const: typ -> term
    51   val mk_exists: string * typ * term -> term
    52   val choice_const: typ -> term
    53   val class_equal: string
    54   val mk_binop: string -> term * term -> term
    55   val mk_binrel: string -> term * term -> term
    56   val dest_bin: string -> typ -> term -> term * term
    57   val unitT: typ
    58   val is_unitT: typ -> bool
    59   val unit: term
    60   val is_unit: term -> bool
    61   val mk_prodT: typ * typ -> typ
    62   val dest_prodT: typ -> typ * typ
    63   val pair_const: typ -> typ -> term
    64   val mk_prod: term * term -> term
    65   val dest_prod: term -> term * term
    66   val mk_fst: term -> term
    67   val mk_snd: term -> term
    68   val split_const: typ * typ * typ -> term
    69   val mk_split: term -> term
    70   val flatten_tupleT: typ -> typ list
    71   val tupled_lambda: term -> term -> term
    72   val mk_tupleT: typ list -> typ
    73   val strip_tupleT: typ -> typ list
    74   val mk_tuple: term list -> term
    75   val strip_tuple: term -> term list
    76   val mk_ptupleT: int list list -> typ list -> typ
    77   val strip_ptupleT: int list list -> typ -> typ list
    78   val flat_tupleT_paths: typ -> int list list
    79   val mk_ptuple: int list list -> typ -> term list -> term
    80   val strip_ptuple: int list list -> term -> term list
    81   val flat_tuple_paths: term -> int list list
    82   val mk_psplits: int list list -> typ -> typ -> term -> term
    83   val strip_psplits: term -> term * typ list * int list list
    84   val natT: typ
    85   val zero: term
    86   val is_zero: term -> bool
    87   val mk_Suc: term -> term
    88   val dest_Suc: term -> term
    89   val Suc_zero: term
    90   val mk_nat: int -> term
    91   val dest_nat: term -> int
    92   val class_size: string
    93   val size_const: typ -> term
    94   val code_numeralT: typ
    95   val intT: typ
    96   val pls_const: term
    97   val min_const: term
    98   val bit0_const: term
    99   val bit1_const: term
   100   val mk_bit: int -> term
   101   val dest_bit: term -> int
   102   val mk_numeral: int -> term
   103   val dest_numeral: term -> int
   104   val number_of_const: typ -> term
   105   val add_numerals: term -> (term * typ) list -> (term * typ) list
   106   val mk_number: typ -> int -> term
   107   val dest_number: term -> typ * int
   108   val realT: typ
   109   val nibbleT: typ
   110   val mk_nibble: int -> term
   111   val dest_nibble: term -> int
   112   val charT: typ
   113   val mk_char: int -> term
   114   val dest_char: term -> int
   115   val listT: typ -> typ
   116   val nil_const: typ -> term
   117   val cons_const: typ -> term
   118   val mk_list: typ -> term list -> term
   119   val dest_list: term -> term list
   120   val stringT: typ
   121   val mk_string: string -> term
   122   val dest_string: term -> string
   123   val literalT: typ
   124   val mk_literal: string -> term
   125   val dest_literal: term -> string
   126   val mk_typerep: typ -> term
   127   val termT: typ
   128   val term_of_const: typ -> term
   129   val mk_term_of: typ -> term -> term
   130   val reflect_term: term -> term
   131   val mk_valtermify_app: string -> (string * typ) list -> typ -> term
   132   val mk_return: typ -> typ -> term -> term
   133   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   134   val mk_random: typ -> term -> term
   135 end;
   136 
   137 structure HOLogic: HOLOGIC =
   138 struct
   139 
   140 (* HOL syntax *)
   141 
   142 val typeS: sort = ["HOL.type"];
   143 val typeT = Type_Infer.anyT typeS;
   144 
   145 
   146 (* functions *)
   147 
   148 fun mk_comp (f, g) =
   149   let
   150     val fT = fastype_of f;
   151     val gT = fastype_of g;
   152     val compT = fT --> gT --> domain_type gT --> range_type fT;
   153   in Const ("Fun.comp", compT) $ f $ g end;
   154 
   155 
   156 (* bool and set *)
   157 
   158 val boolN = "HOL.bool";
   159 val boolT = Type (boolN, []);
   160 
   161 val true_const =  Const ("HOL.True", boolT);
   162 val false_const = Const ("HOL.False", boolT);
   163 
   164 fun mk_setT T = T --> boolT;
   165 
   166 fun dest_setT (Type ("fun", [T, Type ("HOL.bool", [])])) = T
   167   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   168 
   169 fun mk_set T ts =
   170   let
   171     val sT = mk_setT T;
   172     val empty = Const ("Orderings.bot_class.bot", sT);
   173     fun insert t u = Const ("Set.insert", T --> sT --> sT) $ t $ u;
   174   in fold_rev insert ts empty end;
   175 
   176 fun mk_UNIV T = Const ("Orderings.top_class.top", mk_setT T);
   177 
   178 fun dest_set (Const ("Orderings.bot_class.bot", _)) = []
   179   | dest_set (Const ("Set.insert", _) $ t $ u) = t :: dest_set u
   180   | dest_set t = raise TERM ("dest_set", [t]);
   181 
   182 fun Collect_const T = Const ("Set.Collect", (T --> boolT) --> mk_setT T);
   183 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   184 
   185 fun mk_mem (x, A) =
   186   let val setT = fastype_of A in
   187     Const ("Set.member", dest_setT setT --> setT --> boolT) $ x $ A
   188   end;
   189 
   190 fun dest_mem (Const ("Set.member", _) $ x $ A) = (x, A)
   191   | dest_mem t = raise TERM ("dest_mem", [t]);
   192 
   193 
   194 (* logic *)
   195 
   196 val Trueprop = Const ("HOL.Trueprop", boolT --> propT);
   197 
   198 fun mk_Trueprop P = Trueprop $ P;
   199 
   200 fun dest_Trueprop (Const ("HOL.Trueprop", _) $ P) = P
   201   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   202 
   203 fun conj_intr thP thQ =
   204   let
   205     val (P, Q) = pairself (Object_Logic.dest_judgment o Thm.cprop_of) (thP, thQ)
   206       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   207     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   208   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   209 
   210 fun conj_elim thPQ =
   211   let
   212     val (P, Q) = Thm.dest_binop (Object_Logic.dest_judgment (Thm.cprop_of thPQ))
   213       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   214     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   215     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   216     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   217   in (thP, thQ) end;
   218 
   219 fun conj_elims th =
   220   let val (th1, th2) = conj_elim th
   221   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   222 
   223 val conj = @{term HOL.conj}
   224 and disj = @{term HOL.disj}
   225 and imp = @{term implies}
   226 and Not = @{term Not};
   227 
   228 fun mk_conj (t1, t2) = conj $ t1 $ t2
   229 and mk_disj (t1, t2) = disj $ t1 $ t2
   230 and mk_imp (t1, t2) = imp $ t1 $ t2
   231 and mk_not t = Not $ t;
   232 
   233 fun dest_conj (Const ("HOL.conj", _) $ t $ t') = t :: dest_conj t'
   234   | dest_conj t = [t];
   235 
   236 fun dest_disj (Const ("HOL.disj", _) $ t $ t') = t :: dest_disj t'
   237   | dest_disj t = [t];
   238 
   239 (*Like dest_disj, but flattens disjunctions however nested*)
   240 fun disjuncts_aux (Const ("HOL.disj", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   241   | disjuncts_aux t disjs = t::disjs;
   242 
   243 fun disjuncts t = disjuncts_aux t [];
   244 
   245 fun dest_imp (Const ("HOL.implies", _) $ A $ B) = (A, B)
   246   | dest_imp  t = raise TERM ("dest_imp", [t]);
   247 
   248 fun dest_not (Const ("HOL.Not", _) $ t) = t
   249   | dest_not t = raise TERM ("dest_not", [t]);
   250 
   251 fun eq_const T = Const ("HOL.eq", T --> T --> boolT);
   252 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   253 
   254 fun dest_eq (Const ("HOL.eq", _) $ lhs $ rhs) = (lhs, rhs)
   255   | dest_eq t = raise TERM ("dest_eq", [t])
   256 
   257 fun all_const T = Const ("HOL.All", [T --> boolT] ---> boolT);
   258 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   259 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   260 
   261 fun exists_const T = Const ("HOL.Ex", [T --> boolT] ---> boolT);
   262 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   263 
   264 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   265 
   266 val class_equal = "HOL.equal";
   267 
   268 
   269 (* binary operations and relations *)
   270 
   271 fun mk_binop c (t, u) =
   272   let val T = fastype_of t in
   273     Const (c, [T, T] ---> T) $ t $ u
   274   end;
   275 
   276 fun mk_binrel c (t, u) =
   277   let val T = fastype_of t in
   278     Const (c, [T, T] ---> boolT) $ t $ u
   279   end;
   280 
   281 (*destruct the application of a binary operator. The dummyT case is a crude
   282   way of handling polymorphic operators.*)
   283 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   284       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   285       else raise TERM ("dest_bin " ^ c, [tm])
   286   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   287 
   288 
   289 (* unit *)
   290 
   291 val unitT = Type ("Product_Type.unit", []);
   292 
   293 fun is_unitT (Type ("Product_Type.unit", [])) = true
   294   | is_unitT _ = false;
   295 
   296 val unit = Const ("Product_Type.Unity", unitT);
   297 
   298 fun is_unit (Const ("Product_Type.Unity", _)) = true
   299   | is_unit _ = false;
   300 
   301 
   302 (* prod *)
   303 
   304 fun mk_prodT (T1, T2) = Type ("Product_Type.prod", [T1, T2]);
   305 
   306 fun dest_prodT (Type ("Product_Type.prod", [T1, T2])) = (T1, T2)
   307   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   308 
   309 fun pair_const T1 T2 = Const ("Product_Type.Pair", [T1, T2] ---> mk_prodT (T1, T2));
   310 
   311 fun mk_prod (t1, t2) =
   312   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   313     pair_const T1 T2 $ t1 $ t2
   314   end;
   315 
   316 fun dest_prod (Const ("Product_Type.Pair", _) $ t1 $ t2) = (t1, t2)
   317   | dest_prod t = raise TERM ("dest_prod", [t]);
   318 
   319 fun mk_fst p =
   320   let val pT = fastype_of p in
   321     Const ("Product_Type.fst", pT --> fst (dest_prodT pT)) $ p
   322   end;
   323 
   324 fun mk_snd p =
   325   let val pT = fastype_of p in
   326     Const ("Product_Type.snd", pT --> snd (dest_prodT pT)) $ p
   327   end;
   328 
   329 fun split_const (A, B, C) =
   330   Const ("Product_Type.prod.prod_case", (A --> B --> C) --> mk_prodT (A, B) --> C);
   331 
   332 fun mk_split t =
   333   (case Term.fastype_of t of
   334     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   335       Const ("Product_Type.prod.prod_case", T --> mk_prodT (A, B) --> C) $ t
   336   | _ => raise TERM ("mk_split: bad body type", [t]));
   337 
   338 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   339 fun flatten_tupleT (Type ("Product_Type.prod", [T1, T2])) = flatten_tupleT T1 @ flatten_tupleT T2
   340   | flatten_tupleT T = [T];
   341 
   342 (*abstraction over nested tuples*)
   343 fun tupled_lambda (x as Free _) b = lambda x b
   344   | tupled_lambda (x as Var _) b = lambda x b
   345   | tupled_lambda (Const ("Product_Type.Pair", _) $ u $ v) b =
   346       mk_split (tupled_lambda u (tupled_lambda v b))
   347   | tupled_lambda (Const ("Product_Type.Unity", _)) b =
   348       Abs ("x", unitT, b)
   349   | tupled_lambda t _ = raise TERM ("tupled_lambda: bad tuple", [t]);
   350 
   351 
   352 (* tuples with right-fold structure *)
   353 
   354 fun mk_tupleT [] = unitT
   355   | mk_tupleT Ts = foldr1 mk_prodT Ts;
   356 
   357 fun strip_tupleT (Type ("Product_Type.unit", [])) = []
   358   | strip_tupleT (Type ("Product_Type.prod", [T1, T2])) = T1 :: strip_tupleT T2
   359   | strip_tupleT T = [T];
   360 
   361 fun mk_tuple [] = unit
   362   | mk_tuple ts = foldr1 mk_prod ts;
   363 
   364 fun strip_tuple (Const ("Product_Type.Unity", _)) = []
   365   | strip_tuple (Const ("Product_Type.Pair", _) $ t1 $ t2) = t1 :: strip_tuple t2
   366   | strip_tuple t = [t];
   367 
   368 
   369 (* tuples with specific arities
   370 
   371    an "arity" of a tuple is a list of lists of integers,
   372    denoting paths to subterms that are pairs
   373 *)
   374 
   375 fun ptuple_err s = raise TERM (s ^ ": inconsistent use of nested products", []);
   376 
   377 fun mk_ptupleT ps =
   378   let
   379     fun mk p Ts =
   380       if member (op =) ps p then
   381         let
   382           val (T, Ts') = mk (1::p) Ts;
   383           val (U, Ts'') = mk (2::p) Ts'
   384         in (mk_prodT (T, U), Ts'') end
   385       else (hd Ts, tl Ts)
   386   in fst o mk [] end;
   387 
   388 fun strip_ptupleT ps =
   389   let
   390     fun factors p T = if member (op =) ps p then (case T of
   391         Type ("Product_Type.prod", [T1, T2]) =>
   392           factors (1::p) T1 @ factors (2::p) T2
   393       | _ => ptuple_err "strip_ptupleT") else [T]
   394   in factors [] end;
   395 
   396 val flat_tupleT_paths =
   397   let
   398     fun factors p (Type ("Product_Type.prod", [T1, T2])) =
   399           p :: factors (1::p) T1 @ factors (2::p) T2
   400       | factors p _ = []
   401   in factors [] end;
   402 
   403 fun mk_ptuple ps =
   404   let
   405     fun mk p T ts =
   406       if member (op =) ps p then (case T of
   407           Type ("Product_Type.prod", [T1, T2]) =>
   408             let
   409               val (t, ts') = mk (1::p) T1 ts;
   410               val (u, ts'') = mk (2::p) T2 ts'
   411             in (pair_const T1 T2 $ t $ u, ts'') end
   412         | _ => ptuple_err "mk_ptuple")
   413       else (hd ts, tl ts)
   414   in fst oo mk [] end;
   415 
   416 fun strip_ptuple ps =
   417   let
   418     fun dest p t = if member (op =) ps p then (case t of
   419         Const ("Product_Type.Pair", _) $ t $ u =>
   420           dest (1::p) t @ dest (2::p) u
   421       | _ => ptuple_err "strip_ptuple") else [t]
   422   in dest [] end;
   423 
   424 val flat_tuple_paths =
   425   let
   426     fun factors p (Const ("Product_Type.Pair", _) $ t $ u) =
   427           p :: factors (1::p) t @ factors (2::p) u
   428       | factors p _ = []
   429   in factors [] end;
   430 
   431 (*In mk_psplits ps S T u, term u expects separate arguments for the factors of S,
   432   with result type T.  The call creates a new term expecting one argument
   433   of type S.*)
   434 fun mk_psplits ps T T3 u =
   435   let
   436     fun ap ((p, T) :: pTs) =
   437           if member (op =) ps p then (case T of
   438               Type ("Product_Type.prod", [T1, T2]) =>
   439                 split_const (T1, T2, map snd pTs ---> T3) $
   440                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   441             | _ => ptuple_err "mk_psplits")
   442           else Abs ("x", T, ap pTs)
   443       | ap [] =
   444           let val k = length ps
   445           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   446   in ap [([], T)] end;
   447 
   448 val strip_psplits =
   449   let
   450     fun strip [] qs Ts t = (t, rev Ts, qs)
   451       | strip (p :: ps) qs Ts (Const ("Product_Type.prod.prod_case", _) $ t) =
   452           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   453       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   454       | strip (p :: ps) qs Ts t = strip ps qs
   455           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   456           (incr_boundvars 1 t $ Bound 0)
   457   in strip [[]] [] [] end;
   458 
   459 
   460 (* nat *)
   461 
   462 val natT = Type ("Nat.nat", []);
   463 
   464 val zero = Const ("Groups.zero_class.zero", natT);
   465 
   466 fun is_zero (Const ("Groups.zero_class.zero", _)) = true
   467   | is_zero _ = false;
   468 
   469 fun mk_Suc t = Const ("Nat.Suc", natT --> natT) $ t;
   470 
   471 fun dest_Suc (Const ("Nat.Suc", _) $ t) = t
   472   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   473 
   474 val Suc_zero = mk_Suc zero;
   475 
   476 fun mk_nat n =
   477   let
   478     fun mk 0 = zero
   479       | mk n = mk_Suc (mk (n - 1));
   480   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   481 
   482 fun dest_nat (Const ("Groups.zero_class.zero", _)) = 0
   483   | dest_nat (Const ("Nat.Suc", _) $ t) = dest_nat t + 1
   484   | dest_nat t = raise TERM ("dest_nat", [t]);
   485 
   486 val class_size = "Nat.size";
   487 
   488 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   489 
   490 
   491 (* code numeral *)
   492 
   493 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   494 
   495 
   496 (* binary numerals and int -- non-unique representation due to leading zeros/ones! *)
   497 
   498 val intT = Type ("Int.int", []);
   499 
   500 val pls_const = Const ("Int.Pls", intT)
   501 and min_const = Const ("Int.Min", intT)
   502 and bit0_const = Const ("Int.Bit0", intT --> intT)
   503 and bit1_const = Const ("Int.Bit1", intT --> intT);
   504 
   505 fun mk_bit 0 = bit0_const
   506   | mk_bit 1 = bit1_const
   507   | mk_bit _ = raise TERM ("mk_bit", []);
   508 
   509 fun dest_bit (Const ("Int.Bit0", _)) = 0
   510   | dest_bit (Const ("Int.Bit1", _)) = 1
   511   | dest_bit t = raise TERM ("dest_bit", [t]);
   512 
   513 fun mk_numeral 0 = pls_const
   514   | mk_numeral ~1 = min_const
   515   | mk_numeral i =
   516       let val (q, r) = Integer.div_mod i 2;
   517       in mk_bit r $ mk_numeral q end;
   518 
   519 fun dest_numeral (Const ("Int.Pls", _)) = 0
   520   | dest_numeral (Const ("Int.Min", _)) = ~1
   521   | dest_numeral (Const ("Int.Bit0", _) $ bs) = 2 * dest_numeral bs
   522   | dest_numeral (Const ("Int.Bit1", _) $ bs) = 2 * dest_numeral bs + 1
   523   | dest_numeral t = raise TERM ("dest_numeral", [t]);
   524 
   525 fun number_of_const T = Const ("Int.number_class.number_of", intT --> T);
   526 
   527 fun add_numerals (Const ("Int.number_class.number_of", Type (_, [_, T])) $ t) = cons (t, T)
   528   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   529   | add_numerals (Abs (_, _, t)) = add_numerals t
   530   | add_numerals _ = I;
   531 
   532 fun mk_number T 0 = Const ("Groups.zero_class.zero", T)
   533   | mk_number T 1 = Const ("Groups.one_class.one", T)
   534   | mk_number T i = number_of_const T $ mk_numeral i;
   535 
   536 fun dest_number (Const ("Groups.zero_class.zero", T)) = (T, 0)
   537   | dest_number (Const ("Groups.one_class.one", T)) = (T, 1)
   538   | dest_number (Const ("Int.number_class.number_of", Type ("fun", [_, T])) $ t) =
   539       (T, dest_numeral t)
   540   | dest_number t = raise TERM ("dest_number", [t]);
   541 
   542 
   543 (* real *)
   544 
   545 val realT = Type ("RealDef.real", []);
   546 
   547 
   548 (* list *)
   549 
   550 fun listT T = Type ("List.list", [T]);
   551 
   552 fun nil_const T = Const ("List.list.Nil", listT T);
   553 
   554 fun cons_const T =
   555   let val lT = listT T
   556   in Const ("List.list.Cons", T --> lT --> lT) end;
   557 
   558 fun mk_list T ts =
   559   let
   560     val lT = listT T;
   561     val Nil = Const ("List.list.Nil", lT);
   562     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   563   in fold_rev Cons ts Nil end;
   564 
   565 fun dest_list (Const ("List.list.Nil", _)) = []
   566   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   567   | dest_list t = raise TERM ("dest_list", [t]);
   568 
   569 
   570 (* nibble *)
   571 
   572 val nibbleT = Type ("String.nibble", []);
   573 
   574 fun mk_nibble n =
   575   let val s =
   576     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   577     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   578     else raise TERM ("mk_nibble", [])
   579   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   580 
   581 fun dest_nibble t =
   582   let fun err () = raise TERM ("dest_nibble", [t]) in
   583     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   584       NONE => err ()
   585     | SOME c =>
   586         if size c <> 1 then err ()
   587         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   588         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   589         else err ())
   590   end;
   591 
   592 
   593 (* char *)
   594 
   595 val charT = Type ("String.char", []);
   596 
   597 fun mk_char n =
   598   if 0 <= n andalso n <= 255 then
   599     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   600       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   601   else raise TERM ("mk_char", []);
   602 
   603 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   604       dest_nibble t * 16 + dest_nibble u
   605   | dest_char t = raise TERM ("dest_char", [t]);
   606 
   607 
   608 (* string *)
   609 
   610 val stringT = listT charT;
   611 
   612 val mk_string = mk_list charT o map (mk_char o ord) o raw_explode;
   613 val dest_string = implode o map (chr o dest_char) o dest_list;
   614 
   615 
   616 (* literal *)
   617 
   618 val literalT = Type ("String.literal", []);
   619 
   620 fun mk_literal s = Const ("String.STR", stringT --> literalT)
   621       $ mk_string s;
   622 fun dest_literal (Const ("String.STR", _) $ t) =
   623       dest_string t
   624   | dest_literal t = raise TERM ("dest_literal", [t]);
   625 
   626 
   627 (* typerep and term *)
   628 
   629 val typerepT = Type ("Typerep.typerep", []);
   630 
   631 fun mk_typerep (Type (tyco, Ts)) = Const ("Typerep.typerep.Typerep",
   632       literalT --> listT typerepT --> typerepT) $ mk_literal tyco
   633         $ mk_list typerepT (map mk_typerep Ts)
   634   | mk_typerep (T as TFree _) = Const ("Typerep.typerep_class.typerep",
   635       Term.itselfT T --> typerepT) $ Logic.mk_type T;
   636 
   637 val termT = Type ("Code_Evaluation.term", []);
   638 
   639 fun term_of_const T = Const ("Code_Evaluation.term_of_class.term_of", T --> termT);
   640 
   641 fun mk_term_of T t = term_of_const T $ t;
   642 
   643 fun reflect_term (Const (c, T)) =
   644       Const ("Code_Evaluation.Const", literalT --> typerepT --> termT)
   645         $ mk_literal c $ mk_typerep T
   646   | reflect_term (t1 $ t2) =
   647       Const ("Code_Evaluation.App", termT --> termT --> termT)
   648         $ reflect_term t1 $ reflect_term t2
   649   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   650   | reflect_term t = t;
   651 
   652 fun mk_valtermify_app c vs T =
   653   let
   654     fun termifyT T = mk_prodT (T, unitT --> termT);
   655     fun valapp T T' = Const ("Code_Evaluation.valapp",
   656       termifyT (T --> T') --> termifyT T --> termifyT T');
   657     fun mk_fTs [] _ = []
   658       | mk_fTs (_ :: Ts) T = (Ts ---> T) :: mk_fTs Ts T;
   659     val Ts = map snd vs;
   660     val t = Const (c, Ts ---> T);
   661     val tt = mk_prod (t, Abs ("u", unitT, reflect_term t));
   662     fun app (fT, (v, T)) t = valapp T fT $ t $ Free (v, termifyT T);
   663   in fold app (mk_fTs Ts T ~~ vs) tt end;
   664 
   665 
   666 (* open state monads *)
   667 
   668 fun mk_return T U x = pair_const T U $ x;
   669 
   670 fun mk_ST clauses t U (someT, V) =
   671   let
   672     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   673     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   674           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   675             $ t $ lambda (Free (v, T)) t', U)
   676       | mk_clause ((t, U), NONE) (t', U') =
   677           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   678             $ t $ t', U)
   679   in fold_rev mk_clause clauses (t, U) |> fst end;
   680 
   681 
   682 (* random seeds *)
   683 
   684 val random_seedT = mk_prodT (code_numeralT, code_numeralT);
   685 
   686 fun mk_random T t = Const ("Quickcheck.random_class.random", code_numeralT
   687   --> random_seedT --> mk_prodT (mk_prodT (T, unitT --> termT), random_seedT)) $ t;
   688 
   689 end;