src/Pure/Isar/toplevel.ML
author wenzelm
Tue Sep 29 11:49:22 2009 +0200 (2009-09-29)
changeset 32738 15bb09ca0378
parent 32062 457f5bcd3d76
child 32792 a08a2b962a09
permissions -rw-r--r--
explicit indication of Unsynchronized.ref;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type generic_theory
    11   type state
    12   val toplevel: state
    13   val is_toplevel: state -> bool
    14   val is_theory: state -> bool
    15   val is_proof: state -> bool
    16   val level: state -> int
    17   val presentation_context_of: state -> Proof.context
    18   val previous_context_of: state -> Proof.context option
    19   val context_of: state -> Proof.context
    20   val generic_theory_of: state -> generic_theory
    21   val theory_of: state -> theory
    22   val proof_of: state -> Proof.state
    23   val proof_position_of: state -> int
    24   val enter_proof_body: state -> Proof.state
    25   val print_state_context: state -> unit
    26   val print_state: bool -> state -> unit
    27   val quiet: bool Unsynchronized.ref
    28   val debug: bool Unsynchronized.ref
    29   val interact: bool Unsynchronized.ref
    30   val timing: bool Unsynchronized.ref
    31   val profiling: int Unsynchronized.ref
    32   val skip_proofs: bool Unsynchronized.ref
    33   exception TERMINATE
    34   exception TOPLEVEL_ERROR
    35   val program: (unit -> 'a) -> 'a
    36   type transition
    37   val empty: transition
    38   val init_of: transition -> string option
    39   val name_of: transition -> string
    40   val pos_of: transition -> Position.T
    41   val str_of: transition -> string
    42   val name: string -> transition -> transition
    43   val position: Position.T -> transition -> transition
    44   val interactive: bool -> transition -> transition
    45   val print: transition -> transition
    46   val no_timing: transition -> transition
    47   val init_theory: string -> (bool -> theory) -> (theory -> unit) -> transition -> transition
    48   val exit: transition -> transition
    49   val keep: (state -> unit) -> transition -> transition
    50   val keep': (bool -> state -> unit) -> transition -> transition
    51   val imperative: (unit -> unit) -> transition -> transition
    52   val ignored: Position.T -> transition
    53   val malformed: Position.T -> string -> transition
    54   val theory: (theory -> theory) -> transition -> transition
    55   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    56   val theory': (bool -> theory -> theory) -> transition -> transition
    57   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    58   val end_local_theory: transition -> transition
    59   val local_theory': xstring option -> (bool -> local_theory -> local_theory) ->
    60     transition -> transition
    61   val local_theory: xstring option -> (local_theory -> local_theory) -> transition -> transition
    62   val present_local_theory: xstring option -> (state -> unit) -> transition -> transition
    63   val local_theory_to_proof': xstring option -> (bool -> local_theory -> Proof.state) ->
    64     transition -> transition
    65   val local_theory_to_proof: xstring option -> (local_theory -> Proof.state) ->
    66     transition -> transition
    67   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    68   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    69   val forget_proof: transition -> transition
    70   val present_proof: (state -> unit) -> transition -> transition
    71   val proofs': (bool -> Proof.state -> Proof.state Seq.seq) -> transition -> transition
    72   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    73   val proofs: (Proof.state -> Proof.state Seq.seq) -> transition -> transition
    74   val proof: (Proof.state -> Proof.state) -> transition -> transition
    75   val actual_proof: (ProofNode.T -> ProofNode.T) -> transition -> transition
    76   val skip_proof: (int -> int) -> transition -> transition
    77   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    78   val get_id: transition -> string option
    79   val put_id: string -> transition -> transition
    80   val unknown_theory: transition -> transition
    81   val unknown_proof: transition -> transition
    82   val unknown_context: transition -> transition
    83   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    84   val status: transition -> Markup.T -> unit
    85   val error_msg: transition -> exn * string -> unit
    86   val add_hook: (transition -> state -> state -> unit) -> unit
    87   val transition: bool -> transition -> state -> (state * (exn * string) option) option
    88   val commit_exit: Position.T -> transition
    89   val command: transition -> state -> state
    90   val run_command: string -> transition -> state -> state option
    91   val excursion: (transition * transition list) list -> (transition * state) list lazy
    92 end;
    93 
    94 structure Toplevel: TOPLEVEL =
    95 struct
    96 
    97 (** toplevel state **)
    98 
    99 exception UNDEF = Runtime.UNDEF;
   100 
   101 
   102 (* local theory wrappers *)
   103 
   104 type generic_theory = Context.generic;    (*theory or local_theory*)
   105 
   106 val loc_init = TheoryTarget.context;
   107 val loc_exit = LocalTheory.exit_global;
   108 
   109 fun loc_begin loc (Context.Theory thy) = loc_init (the_default "-" loc) thy
   110   | loc_begin NONE (Context.Proof lthy) = lthy
   111   | loc_begin (SOME loc) (Context.Proof lthy) = loc_init loc (loc_exit lthy);
   112 
   113 fun loc_finish _ (Context.Theory _) = Context.Theory o loc_exit
   114   | loc_finish NONE (Context.Proof _) = Context.Proof o LocalTheory.restore
   115   | loc_finish (SOME _) (Context.Proof lthy) = fn lthy' =>
   116       Context.Proof (LocalTheory.reinit (LocalTheory.raw_theory (K (loc_exit lthy')) lthy));
   117 
   118 
   119 (* datatype node *)
   120 
   121 datatype node =
   122   Theory of generic_theory * Proof.context option
   123     (*theory with presentation context*) |
   124   Proof of ProofNode.T * ((Proof.context -> generic_theory) * generic_theory)
   125     (*proof node, finish, original theory*) |
   126   SkipProof of int * (generic_theory * generic_theory);
   127     (*proof depth, resulting theory, original theory*)
   128 
   129 val the_global_theory = fn Theory (Context.Theory thy, _) => thy | _ => raise UNDEF;
   130 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   131 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   132 
   133 fun cases_node f _ (Theory (gthy, _)) = f gthy
   134   | cases_node _ g (Proof (prf, _)) = g (ProofNode.current prf)
   135   | cases_node f _ (SkipProof (_, (gthy, _))) = f gthy;
   136 
   137 val context_node = cases_node Context.proof_of Proof.context_of;
   138 
   139 
   140 (* datatype state *)
   141 
   142 type node_info = node * (theory -> unit);  (*node with exit operation*)
   143 datatype state = State of node_info option * node_info option;  (*current, previous*)
   144 
   145 val toplevel = State (NONE, NONE);
   146 
   147 fun is_toplevel (State (NONE, _)) = true
   148   | is_toplevel _ = false;
   149 
   150 fun level (State (NONE, _)) = 0
   151   | level (State (SOME (Theory _, _), _)) = 0
   152   | level (State (SOME (Proof (prf, _), _), _)) = Proof.level (ProofNode.current prf)
   153   | level (State (SOME (SkipProof (d, _), _), _)) = d + 1;   (*different notion of proof depth!*)
   154 
   155 fun str_of_state (State (NONE, _)) = "at top level"
   156   | str_of_state (State (SOME (Theory (Context.Theory _, _), _), _)) = "in theory mode"
   157   | str_of_state (State (SOME (Theory (Context.Proof _, _), _), _)) = "in local theory mode"
   158   | str_of_state (State (SOME (Proof _, _), _)) = "in proof mode"
   159   | str_of_state (State (SOME (SkipProof _, _), _)) = "in skipped proof mode";
   160 
   161 
   162 (* current node *)
   163 
   164 fun node_of (State (NONE, _)) = raise UNDEF
   165   | node_of (State (SOME (node, _), _)) = node;
   166 
   167 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   168 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   169 
   170 fun node_case f g state = cases_node f g (node_of state);
   171 
   172 fun presentation_context_of state =
   173   (case try node_of state of
   174     SOME (Theory (_, SOME ctxt)) => ctxt
   175   | SOME node => context_node node
   176   | NONE => raise UNDEF);
   177 
   178 fun previous_context_of (State (_, NONE)) = NONE
   179   | previous_context_of (State (_, SOME (prev, _))) = SOME (context_node prev);
   180 
   181 val context_of = node_case Context.proof_of Proof.context_of;
   182 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   183 val theory_of = node_case Context.theory_of Proof.theory_of;
   184 val proof_of = node_case (fn _ => raise UNDEF) I;
   185 
   186 fun proof_position_of state =
   187   (case node_of state of
   188     Proof (prf, _) => ProofNode.position prf
   189   | _ => raise UNDEF);
   190 
   191 val enter_proof_body = node_case (Proof.init o Context.proof_of) Proof.enter_forward;
   192 
   193 
   194 (* print state *)
   195 
   196 val pretty_context = LocalTheory.pretty o Context.cases (TheoryTarget.init NONE) I;
   197 
   198 fun print_state_context state =
   199   (case try node_of state of
   200     NONE => []
   201   | SOME (Theory (gthy, _)) => pretty_context gthy
   202   | SOME (Proof (_, (_, gthy))) => pretty_context gthy
   203   | SOME (SkipProof (_, (gthy, _))) => pretty_context gthy)
   204   |> Pretty.chunks |> Pretty.writeln;
   205 
   206 fun print_state prf_only state =
   207   (case try node_of state of
   208     NONE => []
   209   | SOME (Theory (gthy, _)) => if prf_only then [] else pretty_context gthy
   210   | SOME (Proof (prf, _)) =>
   211       Proof.pretty_state (ProofNode.position prf) (ProofNode.current prf)
   212   | SOME (SkipProof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)])
   213   |> Pretty.markup_chunks Markup.state |> Pretty.writeln;
   214 
   215 
   216 
   217 (** toplevel transitions **)
   218 
   219 val quiet = Unsynchronized.ref false;
   220 val debug = Output.debugging;
   221 val interact = Unsynchronized.ref false;
   222 val timing = Output.timing;
   223 val profiling = Unsynchronized.ref 0;
   224 val skip_proofs = Unsynchronized.ref false;
   225 
   226 exception TERMINATE = Runtime.TERMINATE;
   227 exception EXCURSION_FAIL = Runtime.EXCURSION_FAIL;
   228 exception TOPLEVEL_ERROR = Runtime.TOPLEVEL_ERROR;
   229 
   230 fun program f =
   231  (f
   232   |> Runtime.controlled_execution
   233   |> Runtime.toplevel_error ML_Compiler.exn_message) ();
   234 
   235 
   236 (* node transactions -- maintaining stable checkpoints *)
   237 
   238 exception FAILURE of state * exn;
   239 
   240 local
   241 
   242 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   243   | reset_presentation node = node;
   244 
   245 fun is_draft_theory (Theory (gthy, _)) = Context.is_draft (Context.theory_of gthy)
   246   | is_draft_theory _ = false;
   247 
   248 fun is_stale state = Context.is_stale (theory_of state) handle Runtime.UNDEF => false;
   249 
   250 fun stale_error NONE = SOME (ERROR "Stale theory encountered after successful execution!")
   251   | stale_error some = some;
   252 
   253 fun map_theory f (Theory (gthy, ctxt)) =
   254       Theory (Context.mapping f (LocalTheory.raw_theory f) gthy, ctxt)
   255   | map_theory _ node = node;
   256 
   257 in
   258 
   259 fun apply_transaction pos f g (node, exit) =
   260   let
   261     val _ = is_draft_theory node andalso error "Illegal draft theory in toplevel state";
   262     val cont_node = reset_presentation node;
   263     val back_node = map_theory (Theory.checkpoint o Theory.copy) cont_node;
   264     fun state_error e nd = (State (SOME (nd, exit), SOME (node, exit)), e);
   265 
   266     val (result, err) =
   267       cont_node
   268       |> Runtime.controlled_execution f
   269       |> map_theory Theory.checkpoint
   270       |> state_error NONE
   271       handle exn => state_error (SOME exn) cont_node;
   272 
   273     val (result', err') =
   274       if is_stale result then state_error (stale_error err) back_node
   275       else (result, err);
   276   in
   277     (case err' of
   278       NONE => tap g result'
   279     | SOME exn => raise FAILURE (result', exn))
   280   end;
   281 
   282 end;
   283 
   284 
   285 (* primitive transitions *)
   286 
   287 datatype trans =
   288   Init of string * (bool -> theory) * (theory -> unit) | (*theory name, init, exit*)
   289   Exit |                                         (*formal exit of theory -- without committing*)
   290   CommitExit |                                   (*exit and commit final theory*)
   291   Keep of bool -> state -> unit |                (*peek at state*)
   292   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   293 
   294 local
   295 
   296 fun apply_tr int _ (Init (_, f, exit)) (State (NONE, _)) =
   297       State (SOME (Theory (Context.Theory (Theory.checkpoint (f int)), NONE), exit), NONE)
   298   | apply_tr _ _ Exit (State (prev as SOME (Theory (Context.Theory _, _), _), _)) =
   299       State (NONE, prev)
   300   | apply_tr _ _ CommitExit (State (NONE, SOME (Theory (Context.Theory thy, _), exit))) =
   301       (Runtime.controlled_execution exit thy; toplevel)
   302   | apply_tr int _ (Keep f) state =
   303       Runtime.controlled_execution (fn x => tap (f int) x) state
   304   | apply_tr int pos (Transaction (f, g)) (State (SOME state, _)) =
   305       apply_transaction pos (fn x => f int x) g state
   306   | apply_tr _ _ _ _ = raise UNDEF;
   307 
   308 fun apply_union _ _ [] state = raise FAILURE (state, UNDEF)
   309   | apply_union int pos (tr :: trs) state =
   310       apply_union int pos trs state
   311         handle Runtime.UNDEF => apply_tr int pos tr state
   312           | FAILURE (alt_state, UNDEF) => apply_tr int pos tr alt_state
   313           | exn as FAILURE _ => raise exn
   314           | exn => raise FAILURE (state, exn);
   315 
   316 in
   317 
   318 fun apply_trans int pos trs state = (apply_union int pos trs state, NONE)
   319   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   320 
   321 end;
   322 
   323 
   324 (* datatype transition *)
   325 
   326 datatype transition = Transition of
   327  {name: string,              (*command name*)
   328   pos: Position.T,           (*source position*)
   329   int_only: bool,            (*interactive-only*)
   330   print: bool,               (*print result state*)
   331   no_timing: bool,           (*suppress timing*)
   332   trans: trans list};        (*primitive transitions (union)*)
   333 
   334 fun make_transition (name, pos, int_only, print, no_timing, trans) =
   335   Transition {name = name, pos = pos, int_only = int_only, print = print, no_timing = no_timing,
   336     trans = trans};
   337 
   338 fun map_transition f (Transition {name, pos, int_only, print, no_timing, trans}) =
   339   make_transition (f (name, pos, int_only, print, no_timing, trans));
   340 
   341 val empty = make_transition ("", Position.none, false, false, false, []);
   342 
   343 
   344 (* diagnostics *)
   345 
   346 fun init_of (Transition {trans = [Init (name, _, _)], ...}) = SOME name
   347   | init_of _ = NONE;
   348 
   349 fun name_of (Transition {name, ...}) = name;
   350 fun pos_of (Transition {pos, ...}) = pos;
   351 fun str_of tr = quote (name_of tr) ^ Position.str_of (pos_of tr);
   352 
   353 fun command_msg msg tr = msg ^ "command " ^ str_of tr;
   354 fun at_command tr = command_msg "At " tr ^ ".";
   355 
   356 fun type_error tr state =
   357   ERROR (command_msg "Illegal application of " tr ^ " " ^ str_of_state state);
   358 
   359 
   360 (* modify transitions *)
   361 
   362 fun name name = map_transition (fn (_, pos, int_only, print, no_timing, trans) =>
   363   (name, pos, int_only, print, no_timing, trans));
   364 
   365 fun position pos = map_transition (fn (name, _, int_only, print, no_timing, trans) =>
   366   (name, pos, int_only, print, no_timing, trans));
   367 
   368 fun interactive int_only = map_transition (fn (name, pos, _, print, no_timing, trans) =>
   369   (name, pos, int_only, print, no_timing, trans));
   370 
   371 val no_timing = map_transition (fn (name, pos, int_only, print, _, trans) =>
   372   (name, pos, int_only, print, true, trans));
   373 
   374 fun add_trans tr = map_transition (fn (name, pos, int_only, print, no_timing, trans) =>
   375   (name, pos, int_only, print, no_timing, tr :: trans));
   376 
   377 val reset_trans = map_transition (fn (name, pos, int_only, print, no_timing, _) =>
   378   (name, pos, int_only, print, no_timing, []));
   379 
   380 fun set_print print = map_transition (fn (name, pos, int_only, _, no_timing, trans) =>
   381   (name, pos, int_only, print, no_timing, trans));
   382 
   383 val print = set_print true;
   384 
   385 
   386 (* basic transitions *)
   387 
   388 fun init_theory name f exit = add_trans (Init (name, f, exit));
   389 val exit = add_trans Exit;
   390 val keep' = add_trans o Keep;
   391 
   392 fun present_transaction f g = add_trans (Transaction (f, g));
   393 fun transaction f = present_transaction f (K ());
   394 
   395 fun keep f = add_trans (Keep (fn _ => f));
   396 fun imperative f = keep (fn _ => f ());
   397 
   398 fun ignored pos = empty |> name "<ignored>" |> position pos |> imperative I;
   399 fun malformed pos msg =
   400   empty |> name "<malformed>" |> position pos |> imperative (fn () => error msg);
   401 
   402 val unknown_theory = imperative (fn () => warning "Unknown theory context");
   403 val unknown_proof = imperative (fn () => warning "Unknown proof context");
   404 val unknown_context = imperative (fn () => warning "Unknown context");
   405 
   406 
   407 (* theory transitions *)
   408 
   409 fun generic_theory f = transaction (fn _ =>
   410   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   411     | _ => raise UNDEF));
   412 
   413 fun theory' f = transaction (fn int =>
   414   (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (f int thy), NONE)
   415     | _ => raise UNDEF));
   416 
   417 fun theory f = theory' (K f);
   418 
   419 fun begin_local_theory begin f = transaction (fn _ =>
   420   (fn Theory (Context.Theory thy, _) =>
   421         let
   422           val lthy = f thy;
   423           val gthy = if begin then Context.Proof lthy else Context.Theory (loc_exit lthy);
   424         in Theory (gthy, SOME lthy) end
   425     | _ => raise UNDEF));
   426 
   427 val end_local_theory = transaction (fn _ =>
   428   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (loc_exit lthy), SOME lthy)
   429     | _ => raise UNDEF));
   430 
   431 local
   432 
   433 fun local_theory_presentation loc f = present_transaction (fn int =>
   434   (fn Theory (gthy, _) =>
   435         let
   436           val finish = loc_finish loc gthy;
   437           val lthy' = f int (loc_begin loc gthy);
   438         in Theory (finish lthy', SOME lthy') end
   439     | _ => raise UNDEF));
   440 
   441 in
   442 
   443 fun local_theory' loc f = local_theory_presentation loc f (K ());
   444 fun local_theory loc f = local_theory' loc (K f);
   445 fun present_local_theory loc = local_theory_presentation loc (K I);
   446 
   447 end;
   448 
   449 
   450 (* proof transitions *)
   451 
   452 fun end_proof f = transaction (fn int =>
   453   (fn Proof (prf, (finish, _)) =>
   454         let val state = ProofNode.current prf in
   455           if can (Proof.assert_bottom true) state then
   456             let
   457               val ctxt' = f int state;
   458               val gthy' = finish ctxt';
   459             in Theory (gthy', SOME ctxt') end
   460           else raise UNDEF
   461         end
   462     | SkipProof (0, (gthy, _)) => Theory (gthy, NONE)
   463     | _ => raise UNDEF));
   464 
   465 local
   466 
   467 fun begin_proof init finish = transaction (fn int =>
   468   (fn Theory (gthy, _) =>
   469     let
   470       val prf = init int gthy;
   471       val skip = ! skip_proofs;
   472       val schematic = Proof.schematic_goal prf;
   473     in
   474       if skip andalso schematic then
   475         warning "Cannot skip proof of schematic goal statement"
   476       else ();
   477       if skip andalso not schematic then
   478         SkipProof (0, (finish gthy (Proof.global_skip_proof int prf), gthy))
   479       else Proof (ProofNode.init prf, (finish gthy, gthy))
   480     end
   481   | _ => raise UNDEF));
   482 
   483 in
   484 
   485 fun local_theory_to_proof' loc f = begin_proof
   486   (fn int => fn gthy => f int (loc_begin loc gthy))
   487   (loc_finish loc);
   488 
   489 fun local_theory_to_proof loc f = local_theory_to_proof' loc (K f);
   490 
   491 fun theory_to_proof f = begin_proof
   492   (K (fn Context.Theory thy => f thy | _ => raise UNDEF))
   493   (K (Context.Theory o ProofContext.theory_of));
   494 
   495 end;
   496 
   497 val forget_proof = transaction (fn _ =>
   498   (fn Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   499     | SkipProof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   500     | _ => raise UNDEF));
   501 
   502 val present_proof = present_transaction (fn _ =>
   503   (fn Proof (prf, x) => Proof (ProofNode.apply I prf, x)
   504     | skip as SkipProof _ => skip
   505     | _ => raise UNDEF));
   506 
   507 fun proofs' f = transaction (fn int =>
   508   (fn Proof (prf, x) => Proof (ProofNode.applys (f int) prf, x)
   509     | skip as SkipProof _ => skip
   510     | _ => raise UNDEF));
   511 
   512 fun proof' f = proofs' (Seq.single oo f);
   513 val proofs = proofs' o K;
   514 val proof = proof' o K;
   515 
   516 fun actual_proof f = transaction (fn _ =>
   517   (fn Proof (prf, x) => Proof (f prf, x)
   518     | _ => raise UNDEF));
   519 
   520 fun skip_proof f = transaction (fn _ =>
   521   (fn SkipProof (h, x) => SkipProof (f h, x)
   522     | _ => raise UNDEF));
   523 
   524 fun skip_proof_to_theory pred = transaction (fn _ =>
   525   (fn SkipProof (d, (gthy, _)) => if pred d then Theory (gthy, NONE) else raise UNDEF
   526   | _ => raise UNDEF));
   527 
   528 
   529 
   530 (** toplevel transactions **)
   531 
   532 (* identification *)
   533 
   534 fun get_id (Transition {pos, ...}) = Position.get_id pos;
   535 fun put_id id (tr as Transition {pos, ...}) = position (Position.put_id id pos) tr;
   536 
   537 
   538 (* thread position *)
   539 
   540 fun setmp_thread_position (Transition {pos, ...}) f x =
   541   Position.setmp_thread_data pos f x;
   542 
   543 fun status tr m =
   544   setmp_thread_position tr (fn () => Output.status (Markup.markup m "")) ();
   545 
   546 fun error_msg tr exn_info =
   547   setmp_thread_position tr (fn () =>
   548     Output.error_msg (ML_Compiler.exn_message (EXCURSION_FAIL exn_info))) ();
   549 
   550 
   551 (* post-transition hooks *)
   552 
   553 local val hooks = Unsynchronized.ref ([]: (transition -> state -> state -> unit) list) in
   554 
   555 fun add_hook f = CRITICAL (fn () => Unsynchronized.change hooks (cons f));
   556 fun get_hooks () = CRITICAL (fn () => ! hooks);
   557 
   558 end;
   559 
   560 
   561 (* apply transitions *)
   562 
   563 local
   564 
   565 fun app int (tr as Transition {trans, pos, print, no_timing, ...}) =
   566   setmp_thread_position tr (fn state =>
   567     let
   568       fun do_timing f x = (warning (command_msg "" tr); timeap f x);
   569       fun do_profiling f x = profile (! profiling) f x;
   570 
   571       val (result, status) =
   572          state |> (apply_trans int pos trans
   573           |> (if ! profiling > 0 andalso not no_timing then do_profiling else I)
   574           |> (if ! profiling > 0 orelse ! timing andalso not no_timing then do_timing else I));
   575 
   576       val _ = if int andalso not (! quiet) andalso print then print_state false result else ();
   577     in (result, Option.map (fn UNDEF => type_error tr state | exn => exn) status) end);
   578 
   579 in
   580 
   581 fun transition int tr st =
   582   let
   583     val hooks = get_hooks ();
   584     fun apply_hooks st' = hooks |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   585 
   586     val ctxt = try context_of st;
   587     val res =
   588       (case app int tr st of
   589         (_, SOME TERMINATE) => NONE
   590       | (st', SOME (EXCURSION_FAIL exn_info)) => SOME (st', SOME exn_info)
   591       | (st', SOME exn) => SOME (st', SOME (Runtime.exn_context ctxt exn, at_command tr))
   592       | (st', NONE) => SOME (st', NONE));
   593     val _ = (case res of SOME (st', NONE) => apply_hooks st' | _ => ());
   594   in res end;
   595 
   596 end;
   597 
   598 
   599 (* commit final exit *)
   600 
   601 fun commit_exit pos =
   602   name "end" empty
   603   |> position pos
   604   |> add_trans CommitExit
   605   |> imperative (fn () => warning "Expected to find finished theory");
   606 
   607 
   608 (* nested commands *)
   609 
   610 fun command tr st =
   611   (case transition (! interact) tr st of
   612     SOME (st', NONE) => st'
   613   | SOME (_, SOME exn_info) => raise EXCURSION_FAIL exn_info
   614   | NONE => raise EXCURSION_FAIL (TERMINATE, at_command tr));
   615 
   616 fun command_result tr st =
   617   let val st' = command tr st
   618   in (st', st') end;
   619 
   620 fun run_command thy_name tr st =
   621   (case
   622       (case init_of tr of
   623         SOME name => Exn.capture (fn () => ThyLoad.check_name thy_name name) ()
   624       | NONE => Exn.Result ()) of
   625     Exn.Result () =>
   626       (case transition true tr st of
   627         SOME (st', NONE) => (status tr Markup.finished; SOME st')
   628       | SOME (_, SOME exn_info) => (error_msg tr exn_info; status tr Markup.failed; NONE)
   629       | NONE => (error_msg tr (TERMINATE, at_command tr); status tr Markup.failed; NONE))
   630   | Exn.Exn exn => (error_msg tr (exn, at_command tr); status tr Markup.failed; NONE));
   631 
   632 
   633 (* excursion of units, consisting of commands with proof *)
   634 
   635 structure States = ProofDataFun
   636 (
   637   type T = state list future option;
   638   fun init _ = NONE;
   639 );
   640 
   641 fun proof_result immediate (tr, proof_trs) st =
   642   let val st' = command tr st in
   643     if immediate orelse null proof_trs orelse
   644       not (can proof_of st') orelse Proof.is_relevant (proof_of st')
   645     then
   646       let val (states, st'') = fold_map command_result proof_trs st'
   647       in (Lazy.value ((tr, st') :: (proof_trs ~~ states)), st'') end
   648     else
   649       let
   650         val (body_trs, end_tr) = split_last proof_trs;
   651         val finish = Context.Theory o ProofContext.theory_of;
   652 
   653         val future_proof = Proof.global_future_proof
   654           (fn prf =>
   655             Future.fork_pri ~1 (fn () =>
   656               let val (states, result_state) =
   657                 (case st' of State (SOME (Proof (_, (_, orig_gthy)), exit), prev)
   658                   => State (SOME (Proof (ProofNode.init prf, (finish, orig_gthy)), exit), prev))
   659                 |> fold_map command_result body_trs
   660                 ||> command (end_tr |> set_print false);
   661               in (states, presentation_context_of result_state) end))
   662           #> (fn (states, ctxt) => States.put (SOME states) ctxt);
   663 
   664         val st'' = st' |> command (end_tr |> reset_trans |> end_proof (K future_proof));
   665 
   666         val states =
   667           (case States.get (presentation_context_of st'') of
   668             NONE => sys_error ("No future states for " ^ name_of tr ^ Position.str_of (pos_of tr))
   669           | SOME states => states);
   670         val result = Lazy.lazy
   671           (fn () => (tr, st') :: (body_trs ~~ Future.join states) @ [(end_tr, st'')]);
   672 
   673       in (result, st'') end
   674   end;
   675 
   676 fun excursion input =
   677   let
   678     val end_pos = if null input then error "No input" else pos_of (fst (List.last input));
   679 
   680     val immediate = not (Goal.future_enabled ());
   681     val (results, end_state) = fold_map (proof_result immediate) input toplevel;
   682     val _ =
   683       (case end_state of
   684         State (NONE, SOME (Theory (Context.Theory _, _), _)) =>
   685           command (commit_exit end_pos) end_state
   686       | _ => error "Unfinished development at end of input");
   687   in Lazy.lazy (fn () => maps Lazy.force results) end;
   688 
   689 end;