src/Pure/goal.ML
author wenzelm
Tue Sep 29 11:49:22 2009 +0200 (2009-09-29)
changeset 32738 15bb09ca0378
parent 32365 9b74d0339c44
child 32788 a65deb8f9434
permissions -rw-r--r--
explicit indication of Unsynchronized.ref;
     1 (*  Title:      Pure/goal.ML
     2     Author:     Makarius
     3 
     4 Goals in tactical theorem proving.
     5 *)
     6 
     7 signature BASIC_GOAL =
     8 sig
     9   val parallel_proofs: int Unsynchronized.ref
    10   val SELECT_GOAL: tactic -> int -> tactic
    11   val CONJUNCTS: tactic -> int -> tactic
    12   val PRECISE_CONJUNCTS: int -> tactic -> int -> tactic
    13   val PARALLEL_CHOICE: tactic list -> tactic
    14   val PARALLEL_GOALS: tactic -> tactic
    15 end;
    16 
    17 signature GOAL =
    18 sig
    19   include BASIC_GOAL
    20   val init: cterm -> thm
    21   val protect: thm -> thm
    22   val conclude: thm -> thm
    23   val check_finished: Proof.context -> thm -> unit
    24   val finish: Proof.context -> thm -> thm
    25   val norm_result: thm -> thm
    26   val future_enabled: unit -> bool
    27   val local_future_enabled: unit -> bool
    28   val future_result: Proof.context -> thm future -> term -> thm
    29   val prove_internal: cterm list -> cterm -> (thm list -> tactic) -> thm
    30   val prove_multi: Proof.context -> string list -> term list -> term list ->
    31     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    32   val prove_future: Proof.context -> string list -> term list -> term ->
    33     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    34   val prove: Proof.context -> string list -> term list -> term ->
    35     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    36   val prove_global: theory -> string list -> term list -> term ->
    37     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    38   val extract: int -> int -> thm -> thm Seq.seq
    39   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    40   val conjunction_tac: int -> tactic
    41   val precise_conjunction_tac: int -> int -> tactic
    42   val recover_conjunction_tac: tactic
    43   val norm_hhf_tac: int -> tactic
    44   val compose_hhf_tac: thm -> int -> tactic
    45   val assume_rule_tac: Proof.context -> int -> tactic
    46 end;
    47 
    48 structure Goal: GOAL =
    49 struct
    50 
    51 (** goals **)
    52 
    53 (*
    54   -------- (init)
    55   C ==> #C
    56 *)
    57 val init =
    58   let val A = #1 (Thm.dest_implies (Thm.cprop_of Drule.protectI))
    59   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    60 
    61 (*
    62    C
    63   --- (protect)
    64   #C
    65 *)
    66 fun protect th = Drule.comp_no_flatten (th, 0) 1 Drule.protectI;
    67 
    68 (*
    69   A ==> ... ==> #C
    70   ---------------- (conclude)
    71   A ==> ... ==> C
    72 *)
    73 fun conclude th = Drule.comp_no_flatten (th, Thm.nprems_of th) 1 Drule.protectD;
    74 
    75 (*
    76   #C
    77   --- (finish)
    78    C
    79 *)
    80 fun check_finished ctxt th =
    81   (case Thm.nprems_of th of
    82     0 => ()
    83   | n => raise THM ("Proof failed.\n" ^
    84       Pretty.string_of (Pretty.chunks
    85         (Goal_Display.pretty_goals ctxt {total = true, main = true, maxgoals = n} th)) ^
    86       "\n" ^ string_of_int n ^ " unsolved goal(s)!", 0, [th]));
    87 
    88 fun finish ctxt th = (check_finished ctxt th; conclude th);
    89 
    90 
    91 
    92 (** results **)
    93 
    94 (* normal form *)
    95 
    96 val norm_result =
    97   Drule.flexflex_unique
    98   #> MetaSimplifier.norm_hhf_protect
    99   #> Thm.strip_shyps
   100   #> Drule.zero_var_indexes;
   101 
   102 
   103 (* future_enabled *)
   104 
   105 val parallel_proofs = Unsynchronized.ref 1;
   106 
   107 fun future_enabled () =
   108   Multithreading.enabled () andalso Future.is_worker () andalso ! parallel_proofs >= 1;
   109 
   110 fun local_future_enabled () = future_enabled () andalso ! parallel_proofs >= 2;
   111 
   112 
   113 (* future_result *)
   114 
   115 fun future_result ctxt result prop =
   116   let
   117     val thy = ProofContext.theory_of ctxt;
   118     val _ = Context.reject_draft thy;
   119     val cert = Thm.cterm_of thy;
   120     val certT = Thm.ctyp_of thy;
   121 
   122     val assms = Assumption.all_assms_of ctxt;
   123     val As = map Thm.term_of assms;
   124 
   125     val xs = map Free (fold Term.add_frees (prop :: As) []);
   126     val fixes = map cert xs;
   127 
   128     val tfrees = fold Term.add_tfrees (prop :: As) [];
   129     val instT = map (fn (a, S) => (certT (TVar ((a, 0), S)), certT (TFree (a, S)))) tfrees;
   130 
   131     val global_prop =
   132       cert (Term.map_types Logic.varifyT (fold_rev Logic.all xs (Logic.list_implies (As, prop))))
   133       |> Thm.weaken_sorts (Variable.sorts_of ctxt);
   134     val global_result = result |> Future.map
   135       (Thm.adjust_maxidx_thm ~1 #>
   136         Drule.implies_intr_list assms #>
   137         Drule.forall_intr_list fixes #>
   138         Thm.generalize (map #1 tfrees, []) 0);
   139     val local_result =
   140       Thm.future global_result global_prop
   141       |> Thm.instantiate (instT, [])
   142       |> Drule.forall_elim_list fixes
   143       |> fold (Thm.elim_implies o Thm.assume) assms;
   144   in local_result end;
   145 
   146 
   147 
   148 (** tactical theorem proving **)
   149 
   150 (* prove_internal -- minimal checks, no normalization of result! *)
   151 
   152 fun prove_internal casms cprop tac =
   153   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   154     SOME th => Drule.implies_intr_list casms
   155       (finish (Syntax.init_pretty_global (Thm.theory_of_thm th)) th)
   156   | NONE => error "Tactic failed.");
   157 
   158 
   159 (* prove_common etc. *)
   160 
   161 fun prove_common immediate ctxt xs asms props tac =
   162   let
   163     val thy = ProofContext.theory_of ctxt;
   164     val string_of_term = Syntax.string_of_term ctxt;
   165 
   166     val pos = Position.thread_data ();
   167     fun err msg = cat_error msg
   168       ("The error(s) above occurred for the goal statement:\n" ^
   169         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)) ^
   170         (case Position.str_of pos of "" => "" | s => "\n" ^ s));
   171 
   172     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   173       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   174     val casms = map cert_safe asms;
   175     val cprops = map cert_safe props;
   176 
   177     val (prems, ctxt') = ctxt
   178       |> Variable.add_fixes_direct xs
   179       |> fold Variable.declare_term (asms @ props)
   180       |> Assumption.add_assumes casms
   181       ||> Variable.set_body true;
   182     val sorts = Variable.sorts_of ctxt';
   183 
   184     val stmt = Thm.weaken_sorts sorts (Conjunction.mk_conjunction_balanced cprops);
   185 
   186     fun result () =
   187       (case SINGLE (tac {prems = prems, context = ctxt'}) (init stmt) of
   188         NONE => err "Tactic failed."
   189       | SOME st =>
   190           let val res = finish ctxt' st handle THM (msg, _, _) => err msg in
   191             if Unify.matches_list thy [Thm.term_of stmt] [Thm.prop_of res]
   192             then Thm.check_shyps sorts res
   193             else err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res))
   194           end);
   195     val res =
   196       if immediate orelse #maxidx (Thm.rep_cterm stmt) >= 0 orelse not (future_enabled ())
   197       then result ()
   198       else future_result ctxt' (Future.fork_pri ~1 result) (Thm.term_of stmt);
   199   in
   200     Conjunction.elim_balanced (length props) res
   201     |> map (Assumption.export false ctxt' ctxt)
   202     |> Variable.export ctxt' ctxt
   203     |> map Drule.zero_var_indexes
   204   end;
   205 
   206 val prove_multi = prove_common true;
   207 
   208 fun prove_future ctxt xs asms prop tac = hd (prove_common false ctxt xs asms [prop] tac);
   209 fun prove ctxt xs asms prop tac = hd (prove_common true ctxt xs asms [prop] tac);
   210 
   211 fun prove_global thy xs asms prop tac =
   212   Drule.standard (prove (ProofContext.init thy) xs asms prop tac);
   213 
   214 
   215 
   216 (** goal structure **)
   217 
   218 (* nested goals *)
   219 
   220 fun extract i n st =
   221   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   222    else if n = 1 then Seq.single (Thm.cprem_of st i)
   223    else
   224      Seq.single (Conjunction.mk_conjunction_balanced (map (Thm.cprem_of st) (i upto i + n - 1))))
   225   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   226 
   227 fun retrofit i n st' st =
   228   (if n = 1 then st
   229    else st |> Drule.with_subgoal i (Conjunction.uncurry_balanced n))
   230   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   231 
   232 fun SELECT_GOAL tac i st =
   233   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   234   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   235 
   236 
   237 (* multiple goals *)
   238 
   239 fun precise_conjunction_tac 0 i = eq_assume_tac i
   240   | precise_conjunction_tac 1 i = SUBGOAL (K all_tac) i
   241   | precise_conjunction_tac n i = PRIMITIVE (Drule.with_subgoal i (Conjunction.curry_balanced n));
   242 
   243 val adhoc_conjunction_tac = REPEAT_ALL_NEW
   244   (SUBGOAL (fn (goal, i) =>
   245     if can Logic.dest_conjunction goal then rtac Conjunction.conjunctionI i
   246     else no_tac));
   247 
   248 val conjunction_tac = SUBGOAL (fn (goal, i) =>
   249   precise_conjunction_tac (length (Logic.dest_conjunctions goal)) i ORELSE
   250   TRY (adhoc_conjunction_tac i));
   251 
   252 val recover_conjunction_tac = PRIMITIVE (fn th =>
   253   Conjunction.uncurry_balanced (Thm.nprems_of th) th);
   254 
   255 fun PRECISE_CONJUNCTS n tac =
   256   SELECT_GOAL (precise_conjunction_tac n 1
   257     THEN tac
   258     THEN recover_conjunction_tac);
   259 
   260 fun CONJUNCTS tac =
   261   SELECT_GOAL (conjunction_tac 1
   262     THEN tac
   263     THEN recover_conjunction_tac);
   264 
   265 
   266 (* hhf normal form *)
   267 
   268 val norm_hhf_tac =
   269   rtac Drule.asm_rl  (*cheap approximation -- thanks to builtin Logic.flatten_params*)
   270   THEN' SUBGOAL (fn (t, i) =>
   271     if Drule.is_norm_hhf t then all_tac
   272     else MetaSimplifier.rewrite_goal_tac Drule.norm_hhf_eqs i);
   273 
   274 fun compose_hhf_tac th i st =
   275   PRIMSEQ (Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of st i) th, 0) i) st;
   276 
   277 
   278 (* non-atomic goal assumptions *)
   279 
   280 fun non_atomic (Const ("==>", _) $ _ $ _) = true
   281   | non_atomic (Const ("all", _) $ _) = true
   282   | non_atomic _ = false;
   283 
   284 fun assume_rule_tac ctxt = norm_hhf_tac THEN' CSUBGOAL (fn (goal, i) =>
   285   let
   286     val ((_, goal'), ctxt') = Variable.focus goal ctxt;
   287     val goal'' = Drule.cterm_rule (singleton (Variable.export ctxt' ctxt)) goal';
   288     val Rs = filter (non_atomic o Thm.term_of) (Drule.strip_imp_prems goal'');
   289     val tacs = Rs |> map (fn R =>
   290       Tactic.etac (MetaSimplifier.norm_hhf (Thm.trivial R)) THEN_ALL_NEW assume_tac);
   291   in fold_rev (curry op APPEND') tacs (K no_tac) i end);
   292 
   293 
   294 (* parallel tacticals *)
   295 
   296 (*parallel choice of single results*)
   297 fun PARALLEL_CHOICE tacs st =
   298   (case Par_List.get_some (fn tac => SINGLE tac st) tacs of
   299     NONE => Seq.empty
   300   | SOME st' => Seq.single st');
   301 
   302 (*parallel refinement of non-schematic goal by single results*)
   303 fun PARALLEL_GOALS tac st =
   304   let
   305     val st0 = Thm.adjust_maxidx_thm ~1 st;
   306     val _ = Thm.maxidx_of st0 >= 0 andalso
   307       raise THM ("PARALLEL_GOALS: schematic goal state", 0, [st]);
   308 
   309     exception FAILED;
   310     fun try_tac g =
   311       (case SINGLE tac g of
   312         NONE => raise FAILED
   313       | SOME g' => g');
   314 
   315     val goals = Drule.strip_imp_prems (Thm.cprop_of st0);
   316     val results = Par_List.map (try_tac o init) goals;
   317   in ALLGOALS (fn i => retrofit i 1 (nth results (i - 1))) st0 end
   318   handle FAILED => Seq.empty;
   319 
   320 end;
   321 
   322 structure Basic_Goal: BASIC_GOAL = Goal;
   323 open Basic_Goal;