src/HOLCF/Fixrec.thy
author huffman
Thu Feb 07 03:30:32 2008 +0100 (2008-02-07)
changeset 26046 1624b3304bb9
parent 25158 271e499f2d03
child 28891 f199def7a6a5
permissions -rw-r--r--
fix broken syntax translations
     1 (*  Title:      HOLCF/Fixrec.thy
     2     ID:         $Id$
     3     Author:     Amber Telfer and Brian Huffman
     4 *)
     5 
     6 header "Package for defining recursive functions in HOLCF"
     7 
     8 theory Fixrec
     9 imports Sprod Ssum Up One Tr Fix
    10 uses ("Tools/fixrec_package.ML")
    11 begin
    12 
    13 subsection {* Maybe monad type *}
    14 
    15 defaultsort cpo
    16 
    17 pcpodef (open) 'a maybe = "UNIV::(one ++ 'a u) set"
    18 by simp
    19 
    20 constdefs
    21   fail :: "'a maybe"
    22   "fail \<equiv> Abs_maybe (sinl\<cdot>ONE)"
    23 
    24 constdefs
    25   return :: "'a \<rightarrow> 'a maybe" where
    26   "return \<equiv> \<Lambda> x. Abs_maybe (sinr\<cdot>(up\<cdot>x))"
    27 
    28 definition
    29   maybe_when :: "'b \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a maybe \<rightarrow> 'b::pcpo" where
    30   "maybe_when = (\<Lambda> f r m. sscase\<cdot>(\<Lambda> x. f)\<cdot>(fup\<cdot>r)\<cdot>(Rep_maybe m))"
    31 
    32 lemma maybeE:
    33   "\<lbrakk>p = \<bottom> \<Longrightarrow> Q; p = fail \<Longrightarrow> Q; \<And>x. p = return\<cdot>x \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    34 apply (unfold fail_def return_def)
    35 apply (cases p, rename_tac r)
    36 apply (rule_tac p=r in ssumE, simp add: Abs_maybe_strict)
    37 apply (rule_tac p=x in oneE, simp, simp)
    38 apply (rule_tac p=y in upE, simp, simp add: cont_Abs_maybe)
    39 done
    40 
    41 lemma return_defined [simp]: "return\<cdot>x \<noteq> \<bottom>"
    42 by (simp add: return_def cont_Abs_maybe Abs_maybe_defined)
    43 
    44 lemma fail_defined [simp]: "fail \<noteq> \<bottom>"
    45 by (simp add: fail_def Abs_maybe_defined)
    46 
    47 lemma return_eq [simp]: "(return\<cdot>x = return\<cdot>y) = (x = y)"
    48 by (simp add: return_def cont_Abs_maybe Abs_maybe_inject)
    49 
    50 lemma return_neq_fail [simp]:
    51   "return\<cdot>x \<noteq> fail" "fail \<noteq> return\<cdot>x"
    52 by (simp_all add: return_def fail_def cont_Abs_maybe Abs_maybe_inject)
    53 
    54 lemma maybe_when_rews [simp]:
    55   "maybe_when\<cdot>f\<cdot>r\<cdot>\<bottom> = \<bottom>"
    56   "maybe_when\<cdot>f\<cdot>r\<cdot>fail = f"
    57   "maybe_when\<cdot>f\<cdot>r\<cdot>(return\<cdot>x) = r\<cdot>x"
    58 by (simp_all add: return_def fail_def maybe_when_def cont_Rep_maybe
    59                   cont_Abs_maybe Abs_maybe_inverse Rep_maybe_strict)
    60 
    61 translations
    62   "case m of fail \<Rightarrow> t1 | return\<cdot>x \<Rightarrow> t2" == "CONST maybe_when\<cdot>t1\<cdot>(\<Lambda> x. t2)\<cdot>m"
    63 
    64 
    65 subsubsection {* Monadic bind operator *}
    66 
    67 definition
    68   bind :: "'a maybe \<rightarrow> ('a \<rightarrow> 'b maybe) \<rightarrow> 'b maybe" where
    69   "bind = (\<Lambda> m f. case m of fail \<Rightarrow> fail | return\<cdot>x \<Rightarrow> f\<cdot>x)"
    70 
    71 text {* monad laws *}
    72 
    73 lemma bind_strict [simp]: "bind\<cdot>\<bottom>\<cdot>f = \<bottom>"
    74 by (simp add: bind_def)
    75 
    76 lemma bind_fail [simp]: "bind\<cdot>fail\<cdot>f = fail"
    77 by (simp add: bind_def)
    78 
    79 lemma left_unit [simp]: "bind\<cdot>(return\<cdot>a)\<cdot>k = k\<cdot>a"
    80 by (simp add: bind_def)
    81 
    82 lemma right_unit [simp]: "bind\<cdot>m\<cdot>return = m"
    83 by (rule_tac p=m in maybeE, simp_all)
    84 
    85 lemma bind_assoc:
    86  "bind\<cdot>(bind\<cdot>m\<cdot>k)\<cdot>h = bind\<cdot>m\<cdot>(\<Lambda> a. bind\<cdot>(k\<cdot>a)\<cdot>h)"
    87 by (rule_tac p=m in maybeE, simp_all)
    88 
    89 subsubsection {* Run operator *}
    90 
    91 definition
    92   run:: "'a maybe \<rightarrow> 'a::pcpo" where
    93   "run = maybe_when\<cdot>\<bottom>\<cdot>ID"
    94 
    95 text {* rewrite rules for run *}
    96 
    97 lemma run_strict [simp]: "run\<cdot>\<bottom> = \<bottom>"
    98 by (simp add: run_def)
    99 
   100 lemma run_fail [simp]: "run\<cdot>fail = \<bottom>"
   101 by (simp add: run_def)
   102 
   103 lemma run_return [simp]: "run\<cdot>(return\<cdot>x) = x"
   104 by (simp add: run_def)
   105 
   106 subsubsection {* Monad plus operator *}
   107 
   108 definition
   109   mplus :: "'a maybe \<rightarrow> 'a maybe \<rightarrow> 'a maybe" where
   110   "mplus = (\<Lambda> m1 m2. case m1 of fail \<Rightarrow> m2 | return\<cdot>x \<Rightarrow> m1)"
   111 
   112 abbreviation
   113   mplus_syn :: "['a maybe, 'a maybe] \<Rightarrow> 'a maybe"  (infixr "+++" 65)  where
   114   "m1 +++ m2 == mplus\<cdot>m1\<cdot>m2"
   115 
   116 text {* rewrite rules for mplus *}
   117 
   118 lemma mplus_strict [simp]: "\<bottom> +++ m = \<bottom>"
   119 by (simp add: mplus_def)
   120 
   121 lemma mplus_fail [simp]: "fail +++ m = m"
   122 by (simp add: mplus_def)
   123 
   124 lemma mplus_return [simp]: "return\<cdot>x +++ m = return\<cdot>x"
   125 by (simp add: mplus_def)
   126 
   127 lemma mplus_fail2 [simp]: "m +++ fail = m"
   128 by (rule_tac p=m in maybeE, simp_all)
   129 
   130 lemma mplus_assoc: "(x +++ y) +++ z = x +++ (y +++ z)"
   131 by (rule_tac p=x in maybeE, simp_all)
   132 
   133 subsubsection {* Fatbar combinator *}
   134 
   135 definition
   136   fatbar :: "('a \<rightarrow> 'b maybe) \<rightarrow> ('a \<rightarrow> 'b maybe) \<rightarrow> ('a \<rightarrow> 'b maybe)" where
   137   "fatbar = (\<Lambda> a b x. a\<cdot>x +++ b\<cdot>x)"
   138 
   139 abbreviation
   140   fatbar_syn :: "['a \<rightarrow> 'b maybe, 'a \<rightarrow> 'b maybe] \<Rightarrow> 'a \<rightarrow> 'b maybe" (infixr "\<parallel>" 60)  where
   141   "m1 \<parallel> m2 == fatbar\<cdot>m1\<cdot>m2"
   142 
   143 lemma fatbar1: "m\<cdot>x = \<bottom> \<Longrightarrow> (m \<parallel> ms)\<cdot>x = \<bottom>"
   144 by (simp add: fatbar_def)
   145 
   146 lemma fatbar2: "m\<cdot>x = fail \<Longrightarrow> (m \<parallel> ms)\<cdot>x = ms\<cdot>x"
   147 by (simp add: fatbar_def)
   148 
   149 lemma fatbar3: "m\<cdot>x = return\<cdot>y \<Longrightarrow> (m \<parallel> ms)\<cdot>x = return\<cdot>y"
   150 by (simp add: fatbar_def)
   151 
   152 lemmas fatbar_simps = fatbar1 fatbar2 fatbar3
   153 
   154 lemma run_fatbar1: "m\<cdot>x = \<bottom> \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = \<bottom>"
   155 by (simp add: fatbar_def)
   156 
   157 lemma run_fatbar2: "m\<cdot>x = fail \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = run\<cdot>(ms\<cdot>x)"
   158 by (simp add: fatbar_def)
   159 
   160 lemma run_fatbar3: "m\<cdot>x = return\<cdot>y \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = y"
   161 by (simp add: fatbar_def)
   162 
   163 lemmas run_fatbar_simps [simp] = run_fatbar1 run_fatbar2 run_fatbar3
   164 
   165 subsection {* Case branch combinator *}
   166 
   167 constdefs
   168   branch :: "('a \<rightarrow> 'b maybe) \<Rightarrow> ('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'c maybe)"
   169   "branch p \<equiv> \<Lambda> r x. bind\<cdot>(p\<cdot>x)\<cdot>(\<Lambda> y. return\<cdot>(r\<cdot>y))"
   170 
   171 lemma branch_rews:
   172   "p\<cdot>x = \<bottom> \<Longrightarrow> branch p\<cdot>r\<cdot>x = \<bottom>"
   173   "p\<cdot>x = fail \<Longrightarrow> branch p\<cdot>r\<cdot>x = fail"
   174   "p\<cdot>x = return\<cdot>y \<Longrightarrow> branch p\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>y)"
   175 by (simp_all add: branch_def)
   176 
   177 lemma branch_return [simp]: "branch return\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>x)"
   178 by (simp add: branch_def)
   179 
   180 
   181 subsection {* Case syntax *}
   182 
   183 nonterminals
   184   Case_syn  Cases_syn
   185 
   186 syntax
   187   "_Case_syntax":: "['a, Cases_syn] => 'b"               ("(Case _ of/ _)" 10)
   188   "_Case1"      :: "['a, 'b] => Case_syn"                ("(2_ =>/ _)" 10)
   189   ""            :: "Case_syn => Cases_syn"               ("_")
   190   "_Case2"      :: "[Case_syn, Cases_syn] => Cases_syn"  ("_/ | _")
   191 
   192 syntax (xsymbols)
   193   "_Case1"      :: "['a, 'b] => Case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   194 
   195 translations
   196   "_Case_syntax x ms" == "CONST Fixrec.run\<cdot>(ms\<cdot>x)"
   197   "_Case2 m ms" == "m \<parallel> ms"
   198 
   199 text {* Parsing Case expressions *}
   200 
   201 syntax
   202   "_pat" :: "'a"
   203   "_var" :: "'a"
   204   "_noargs" :: "'a"
   205 
   206 translations
   207   "_Case1 p r" => "CONST branch (_pat p)\<cdot>(_var p r)"
   208   "_var (_args x y) r" => "CONST csplit\<cdot>(_var x (_var y r))"
   209   "_var _noargs r" => "CONST unit_when\<cdot>r"
   210 
   211 parse_translation {*
   212 (* rewrites (_pat x) => (return) *)
   213 (* rewrites (_var x t) => (Abs_CFun (%x. t)) *)
   214   [("_pat", K (Syntax.const "Fixrec.return")),
   215    mk_binder_tr ("_var", "Abs_CFun")];
   216 *}
   217 
   218 text {* Printing Case expressions *}
   219 
   220 syntax
   221   "_match" :: "'a"
   222 
   223 print_translation {*
   224   let
   225     fun dest_LAM (Const (@{const_syntax Rep_CFun},_) $ Const (@{const_syntax unit_when},_) $ t) =
   226           (Syntax.const "_noargs", t)
   227     |   dest_LAM (Const (@{const_syntax Rep_CFun},_) $ Const (@{const_syntax csplit},_) $ t) =
   228           let
   229             val (v1, t1) = dest_LAM t;
   230             val (v2, t2) = dest_LAM t1;
   231           in (Syntax.const "_args" $ v1 $ v2, t2) end 
   232     |   dest_LAM (Const (@{const_syntax Abs_CFun},_) $ t) =
   233           let
   234             val abs = case t of Abs abs => abs
   235                 | _ => ("x", dummyT, incr_boundvars 1 t $ Bound 0);
   236             val (x, t') = atomic_abs_tr' abs;
   237           in (Syntax.const "_var" $ x, t') end
   238     |   dest_LAM _ = raise Match; (* too few vars: abort translation *)
   239 
   240     fun Case1_tr' [Const(@{const_syntax branch},_) $ p, r] =
   241           let val (v, t) = dest_LAM r;
   242           in Syntax.const "_Case1" $ (Syntax.const "_match" $ p $ v) $ t end;
   243 
   244   in [(@{const_syntax Rep_CFun}, Case1_tr')] end;
   245 *}
   246 
   247 translations
   248   "x" <= "_match Fixrec.return (_var x)"
   249 
   250 
   251 subsection {* Pattern combinators for data constructors *}
   252 
   253 types ('a, 'b) pat = "'a \<rightarrow> 'b maybe"
   254 
   255 definition
   256   cpair_pat :: "('a, 'c) pat \<Rightarrow> ('b, 'd) pat \<Rightarrow> ('a \<times> 'b, 'c \<times> 'd) pat" where
   257   "cpair_pat p1 p2 = (\<Lambda>\<langle>x, y\<rangle>.
   258     bind\<cdot>(p1\<cdot>x)\<cdot>(\<Lambda> a. bind\<cdot>(p2\<cdot>y)\<cdot>(\<Lambda> b. return\<cdot>\<langle>a, b\<rangle>)))"
   259 
   260 definition
   261   spair_pat ::
   262   "('a, 'c) pat \<Rightarrow> ('b, 'd) pat \<Rightarrow> ('a::pcpo \<otimes> 'b::pcpo, 'c \<times> 'd) pat" where
   263   "spair_pat p1 p2 = (\<Lambda>(:x, y:). cpair_pat p1 p2\<cdot>\<langle>x, y\<rangle>)"
   264 
   265 definition
   266   sinl_pat :: "('a, 'c) pat \<Rightarrow> ('a::pcpo \<oplus> 'b::pcpo, 'c) pat" where
   267   "sinl_pat p = sscase\<cdot>p\<cdot>(\<Lambda> x. fail)"
   268 
   269 definition
   270   sinr_pat :: "('b, 'c) pat \<Rightarrow> ('a::pcpo \<oplus> 'b::pcpo, 'c) pat" where
   271   "sinr_pat p = sscase\<cdot>(\<Lambda> x. fail)\<cdot>p"
   272 
   273 definition
   274   up_pat :: "('a, 'b) pat \<Rightarrow> ('a u, 'b) pat" where
   275   "up_pat p = fup\<cdot>p"
   276 
   277 definition
   278   TT_pat :: "(tr, unit) pat" where
   279   "TT_pat = (\<Lambda> b. If b then return\<cdot>() else fail fi)"
   280 
   281 definition
   282   FF_pat :: "(tr, unit) pat" where
   283   "FF_pat = (\<Lambda> b. If b then fail else return\<cdot>() fi)"
   284 
   285 definition
   286   ONE_pat :: "(one, unit) pat" where
   287   "ONE_pat = (\<Lambda> ONE. return\<cdot>())"
   288 
   289 text {* Parse translations (patterns) *}
   290 translations
   291   "_pat (XCONST cpair\<cdot>x\<cdot>y)" => "CONST cpair_pat (_pat x) (_pat y)"
   292   "_pat (XCONST spair\<cdot>x\<cdot>y)" => "CONST spair_pat (_pat x) (_pat y)"
   293   "_pat (XCONST sinl\<cdot>x)" => "CONST sinl_pat (_pat x)"
   294   "_pat (XCONST sinr\<cdot>x)" => "CONST sinr_pat (_pat x)"
   295   "_pat (XCONST up\<cdot>x)" => "CONST up_pat (_pat x)"
   296   "_pat (XCONST TT)" => "CONST TT_pat"
   297   "_pat (XCONST FF)" => "CONST FF_pat"
   298   "_pat (XCONST ONE)" => "CONST ONE_pat"
   299 
   300 text {* CONST version is also needed for constructors with special syntax *}
   301 translations
   302   "_pat (CONST cpair\<cdot>x\<cdot>y)" => "CONST cpair_pat (_pat x) (_pat y)"
   303   "_pat (CONST spair\<cdot>x\<cdot>y)" => "CONST spair_pat (_pat x) (_pat y)"
   304 
   305 text {* Parse translations (variables) *}
   306 translations
   307   "_var (XCONST cpair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   308   "_var (XCONST spair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   309   "_var (XCONST sinl\<cdot>x) r" => "_var x r"
   310   "_var (XCONST sinr\<cdot>x) r" => "_var x r"
   311   "_var (XCONST up\<cdot>x) r" => "_var x r"
   312   "_var (XCONST TT) r" => "_var _noargs r"
   313   "_var (XCONST FF) r" => "_var _noargs r"
   314   "_var (XCONST ONE) r" => "_var _noargs r"
   315 
   316 translations
   317   "_var (CONST cpair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   318   "_var (CONST spair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   319 
   320 text {* Print translations *}
   321 translations
   322   "CONST cpair\<cdot>(_match p1 v1)\<cdot>(_match p2 v2)"
   323       <= "_match (CONST cpair_pat p1 p2) (_args v1 v2)"
   324   "CONST spair\<cdot>(_match p1 v1)\<cdot>(_match p2 v2)"
   325       <= "_match (CONST spair_pat p1 p2) (_args v1 v2)"
   326   "CONST sinl\<cdot>(_match p1 v1)" <= "_match (CONST sinl_pat p1) v1"
   327   "CONST sinr\<cdot>(_match p1 v1)" <= "_match (CONST sinr_pat p1) v1"
   328   "CONST up\<cdot>(_match p1 v1)" <= "_match (CONST up_pat p1) v1"
   329   "CONST TT" <= "_match (CONST TT_pat) _noargs"
   330   "CONST FF" <= "_match (CONST FF_pat) _noargs"
   331   "CONST ONE" <= "_match (CONST ONE_pat) _noargs"
   332 
   333 lemma cpair_pat1:
   334   "branch p\<cdot>r\<cdot>x = \<bottom> \<Longrightarrow> branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = \<bottom>"
   335 apply (simp add: branch_def cpair_pat_def)
   336 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   337 done
   338 
   339 lemma cpair_pat2:
   340   "branch p\<cdot>r\<cdot>x = fail \<Longrightarrow> branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = fail"
   341 apply (simp add: branch_def cpair_pat_def)
   342 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   343 done
   344 
   345 lemma cpair_pat3:
   346   "branch p\<cdot>r\<cdot>x = return\<cdot>s \<Longrightarrow>
   347    branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = branch q\<cdot>s\<cdot>y"
   348 apply (simp add: branch_def cpair_pat_def)
   349 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   350 apply (rule_tac p="q\<cdot>y" in maybeE, simp_all)
   351 done
   352 
   353 lemmas cpair_pat [simp] =
   354   cpair_pat1 cpair_pat2 cpair_pat3
   355 
   356 lemma spair_pat [simp]:
   357   "branch (spair_pat p1 p2)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   358   "\<lbrakk>x \<noteq> \<bottom>; y \<noteq> \<bottom>\<rbrakk>
   359      \<Longrightarrow> branch (spair_pat p1 p2)\<cdot>r\<cdot>(:x, y:) =
   360          branch (cpair_pat p1 p2)\<cdot>r\<cdot>\<langle>x, y\<rangle>"
   361 by (simp_all add: branch_def spair_pat_def)
   362 
   363 lemma sinl_pat [simp]:
   364   "branch (sinl_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   365   "x \<noteq> \<bottom> \<Longrightarrow> branch (sinl_pat p)\<cdot>r\<cdot>(sinl\<cdot>x) = branch p\<cdot>r\<cdot>x"
   366   "y \<noteq> \<bottom> \<Longrightarrow> branch (sinl_pat p)\<cdot>r\<cdot>(sinr\<cdot>y) = fail"
   367 by (simp_all add: branch_def sinl_pat_def)
   368 
   369 lemma sinr_pat [simp]:
   370   "branch (sinr_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   371   "x \<noteq> \<bottom> \<Longrightarrow> branch (sinr_pat p)\<cdot>r\<cdot>(sinl\<cdot>x) = fail"
   372   "y \<noteq> \<bottom> \<Longrightarrow> branch (sinr_pat p)\<cdot>r\<cdot>(sinr\<cdot>y) = branch p\<cdot>r\<cdot>y"
   373 by (simp_all add: branch_def sinr_pat_def)
   374 
   375 lemma up_pat [simp]:
   376   "branch (up_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   377   "branch (up_pat p)\<cdot>r\<cdot>(up\<cdot>x) = branch p\<cdot>r\<cdot>x"
   378 by (simp_all add: branch_def up_pat_def)
   379 
   380 lemma TT_pat [simp]:
   381   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   382   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>TT = return\<cdot>r"
   383   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>FF = fail"
   384 by (simp_all add: branch_def TT_pat_def)
   385 
   386 lemma FF_pat [simp]:
   387   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   388   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>TT = fail"
   389   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>FF = return\<cdot>r"
   390 by (simp_all add: branch_def FF_pat_def)
   391 
   392 lemma ONE_pat [simp]:
   393   "branch ONE_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   394   "branch ONE_pat\<cdot>(unit_when\<cdot>r)\<cdot>ONE = return\<cdot>r"
   395 by (simp_all add: branch_def ONE_pat_def)
   396 
   397 
   398 subsection {* Wildcards, as-patterns, and lazy patterns *}
   399 
   400 syntax
   401   "_as_pat" :: "[idt, 'a] \<Rightarrow> 'a" (infixr "\<as>" 10)
   402   "_lazy_pat" :: "'a \<Rightarrow> 'a" ("\<lazy> _" [1000] 1000)
   403 
   404 definition
   405   wild_pat :: "'a \<rightarrow> unit maybe" where
   406   "wild_pat = (\<Lambda> x. return\<cdot>())"
   407 
   408 definition
   409   as_pat :: "('a \<rightarrow> 'b maybe) \<Rightarrow> 'a \<rightarrow> ('a \<times> 'b) maybe" where
   410   "as_pat p = (\<Lambda> x. bind\<cdot>(p\<cdot>x)\<cdot>(\<Lambda> a. return\<cdot>\<langle>x, a\<rangle>))"
   411 
   412 definition
   413   lazy_pat :: "('a \<rightarrow> 'b::pcpo maybe) \<Rightarrow> ('a \<rightarrow> 'b maybe)" where
   414   "lazy_pat p = (\<Lambda> x. return\<cdot>(run\<cdot>(p\<cdot>x)))"
   415 
   416 text {* Parse translations (patterns) *}
   417 translations
   418   "_pat _" => "CONST wild_pat"
   419   "_pat (_as_pat x y)" => "CONST as_pat (_pat y)"
   420   "_pat (_lazy_pat x)" => "CONST lazy_pat (_pat x)"
   421 
   422 text {* Parse translations (variables) *}
   423 translations
   424   "_var _ r" => "_var _noargs r"
   425   "_var (_as_pat x y) r" => "_var (_args x y) r"
   426   "_var (_lazy_pat x) r" => "_var x r"
   427 
   428 text {* Print translations *}
   429 translations
   430   "_" <= "_match (CONST wild_pat) _noargs"
   431   "_as_pat x (_match p v)" <= "_match (CONST as_pat p) (_args (_var x) v)"
   432   "_lazy_pat (_match p v)" <= "_match (CONST lazy_pat p) v"
   433 
   434 text {* Lazy patterns in lambda abstractions *}
   435 translations
   436   "_cabs (_lazy_pat p) r" == "CONST Fixrec.run oo (_Case1 (_lazy_pat p) r)"
   437 
   438 lemma wild_pat [simp]: "branch wild_pat\<cdot>(unit_when\<cdot>r)\<cdot>x = return\<cdot>r"
   439 by (simp add: branch_def wild_pat_def)
   440 
   441 lemma as_pat [simp]:
   442   "branch (as_pat p)\<cdot>(csplit\<cdot>r)\<cdot>x = branch p\<cdot>(r\<cdot>x)\<cdot>x"
   443 apply (simp add: branch_def as_pat_def)
   444 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   445 done
   446 
   447 lemma lazy_pat [simp]:
   448   "branch p\<cdot>r\<cdot>x = \<bottom> \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>\<bottom>)"
   449   "branch p\<cdot>r\<cdot>x = fail \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>\<bottom>)"
   450   "branch p\<cdot>r\<cdot>x = return\<cdot>s \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>s"
   451 apply (simp_all add: branch_def lazy_pat_def)
   452 apply (rule_tac [!] p="p\<cdot>x" in maybeE, simp_all)
   453 done
   454 
   455 
   456 subsection {* Match functions for built-in types *}
   457 
   458 defaultsort pcpo
   459 
   460 definition
   461   match_UU :: "'a \<rightarrow> unit maybe" where
   462   "match_UU = (\<Lambda> x. fail)"
   463 
   464 definition
   465   match_cpair :: "'a::cpo \<times> 'b::cpo \<rightarrow> ('a \<times> 'b) maybe" where
   466   "match_cpair = csplit\<cdot>(\<Lambda> x y. return\<cdot><x,y>)"
   467 
   468 definition
   469   match_spair :: "'a \<otimes> 'b \<rightarrow> ('a \<times> 'b) maybe" where
   470   "match_spair = ssplit\<cdot>(\<Lambda> x y. return\<cdot><x,y>)"
   471 
   472 definition
   473   match_sinl :: "'a \<oplus> 'b \<rightarrow> 'a maybe" where
   474   "match_sinl = sscase\<cdot>return\<cdot>(\<Lambda> y. fail)"
   475 
   476 definition
   477   match_sinr :: "'a \<oplus> 'b \<rightarrow> 'b maybe" where
   478   "match_sinr = sscase\<cdot>(\<Lambda> x. fail)\<cdot>return"
   479 
   480 definition
   481   match_up :: "'a::cpo u \<rightarrow> 'a maybe" where
   482   "match_up = fup\<cdot>return"
   483 
   484 definition
   485   match_ONE :: "one \<rightarrow> unit maybe" where
   486   "match_ONE = (\<Lambda> ONE. return\<cdot>())"
   487  
   488 definition
   489   match_TT :: "tr \<rightarrow> unit maybe" where
   490   "match_TT = (\<Lambda> b. If b then return\<cdot>() else fail fi)"
   491  
   492 definition
   493   match_FF :: "tr \<rightarrow> unit maybe" where
   494   "match_FF = (\<Lambda> b. If b then fail else return\<cdot>() fi)"
   495 
   496 lemma match_UU_simps [simp]:
   497   "match_UU\<cdot>x = fail"
   498 by (simp add: match_UU_def)
   499 
   500 lemma match_cpair_simps [simp]:
   501   "match_cpair\<cdot><x,y> = return\<cdot><x,y>"
   502 by (simp add: match_cpair_def)
   503 
   504 lemma match_spair_simps [simp]:
   505   "\<lbrakk>x \<noteq> \<bottom>; y \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> match_spair\<cdot>(:x,y:) = return\<cdot><x,y>"
   506   "match_spair\<cdot>\<bottom> = \<bottom>"
   507 by (simp_all add: match_spair_def)
   508 
   509 lemma match_sinl_simps [simp]:
   510   "x \<noteq> \<bottom> \<Longrightarrow> match_sinl\<cdot>(sinl\<cdot>x) = return\<cdot>x"
   511   "x \<noteq> \<bottom> \<Longrightarrow> match_sinl\<cdot>(sinr\<cdot>x) = fail"
   512   "match_sinl\<cdot>\<bottom> = \<bottom>"
   513 by (simp_all add: match_sinl_def)
   514 
   515 lemma match_sinr_simps [simp]:
   516   "x \<noteq> \<bottom> \<Longrightarrow> match_sinr\<cdot>(sinr\<cdot>x) = return\<cdot>x"
   517   "x \<noteq> \<bottom> \<Longrightarrow> match_sinr\<cdot>(sinl\<cdot>x) = fail"
   518   "match_sinr\<cdot>\<bottom> = \<bottom>"
   519 by (simp_all add: match_sinr_def)
   520 
   521 lemma match_up_simps [simp]:
   522   "match_up\<cdot>(up\<cdot>x) = return\<cdot>x"
   523   "match_up\<cdot>\<bottom> = \<bottom>"
   524 by (simp_all add: match_up_def)
   525 
   526 lemma match_ONE_simps [simp]:
   527   "match_ONE\<cdot>ONE = return\<cdot>()"
   528   "match_ONE\<cdot>\<bottom> = \<bottom>"
   529 by (simp_all add: match_ONE_def)
   530 
   531 lemma match_TT_simps [simp]:
   532   "match_TT\<cdot>TT = return\<cdot>()"
   533   "match_TT\<cdot>FF = fail"
   534   "match_TT\<cdot>\<bottom> = \<bottom>"
   535 by (simp_all add: match_TT_def)
   536 
   537 lemma match_FF_simps [simp]:
   538   "match_FF\<cdot>FF = return\<cdot>()"
   539   "match_FF\<cdot>TT = fail"
   540   "match_FF\<cdot>\<bottom> = \<bottom>"
   541 by (simp_all add: match_FF_def)
   542 
   543 subsection {* Mutual recursion *}
   544 
   545 text {*
   546   The following rules are used to prove unfolding theorems from
   547   fixed-point definitions of mutually recursive functions.
   548 *}
   549 
   550 lemma cpair_equalI: "\<lbrakk>x \<equiv> cfst\<cdot>p; y \<equiv> csnd\<cdot>p\<rbrakk> \<Longrightarrow> <x,y> \<equiv> p"
   551 by (simp add: surjective_pairing_Cprod2)
   552 
   553 lemma cpair_eqD1: "<x,y> = <x',y'> \<Longrightarrow> x = x'"
   554 by simp
   555 
   556 lemma cpair_eqD2: "<x,y> = <x',y'> \<Longrightarrow> y = y'"
   557 by simp
   558 
   559 text {* lemma for proving rewrite rules *}
   560 
   561 lemma ssubst_lhs: "\<lbrakk>t = s; P s = Q\<rbrakk> \<Longrightarrow> P t = Q"
   562 by simp
   563 
   564 
   565 subsection {* Initializing the fixrec package *}
   566 
   567 use "Tools/fixrec_package.ML"
   568 
   569 hide (open) const return bind fail run
   570 
   571 end