src/HOL/Groebner_Basis.thy
author chaieb
Mon Jun 11 16:23:17 2007 +0200 (2007-06-11)
changeset 23327 1654013ec97c
parent 23312 6e32a5bfc30f
child 23330 01c09922ce59
permissions -rw-r--r--
Added instantiation of algebra method to fields
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     ID:         $Id$
     3     Author:     Amine Chaieb, TU Muenchen
     4 *)
     5 
     6 header {* Semiring normalization and Groebner Bases *}
     7 
     8 theory Groebner_Basis
     9 imports NatBin
    10 uses
    11   "Tools/Groebner_Basis/misc.ML"
    12   "Tools/Groebner_Basis/normalizer_data.ML"
    13   ("Tools/Groebner_Basis/normalizer.ML")
    14   ("Tools/Groebner_Basis/groebner.ML")
    15 begin
    16 
    17 subsection {* Semiring normalization *}
    18 
    19 setup NormalizerData.setup
    20 
    21 
    22 locale gb_semiring =
    23   fixes add mul pwr r0 r1
    24   assumes add_a:"(add x (add y z) = add (add x y) z)"
    25     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    26     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    27     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    28     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    29     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    30 begin
    31 
    32 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    33 proof (induct p)
    34   case 0
    35   then show ?case by (auto simp add: pwr_0 mul_1)
    36 next
    37   case Suc
    38   from this [symmetric] show ?case
    39     by (auto simp add: pwr_Suc mul_1 mul_a)
    40 qed
    41 
    42 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    43 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    44   fix q x y
    45   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    46   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    47     by (simp add: mul_a)
    48   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    49   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    50   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    51     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    52 qed
    53 
    54 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    55 proof (induct p arbitrary: q)
    56   case 0
    57   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    58 next
    59   case Suc
    60   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    61 qed
    62 
    63 
    64 subsubsection {* Declaring the abstract theory *}
    65 
    66 lemma semiring_ops:
    67   includes meta_term_syntax
    68   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    69     and "TERM r0" and "TERM r1"
    70   by rule+
    71 
    72 lemma semiring_rules:
    73   "add (mul a m) (mul b m) = mul (add a b) m"
    74   "add (mul a m) m = mul (add a r1) m"
    75   "add m (mul a m) = mul (add a r1) m"
    76   "add m m = mul (add r1 r1) m"
    77   "add r0 a = a"
    78   "add a r0 = a"
    79   "mul a b = mul b a"
    80   "mul (add a b) c = add (mul a c) (mul b c)"
    81   "mul r0 a = r0"
    82   "mul a r0 = r0"
    83   "mul r1 a = a"
    84   "mul a r1 = a"
    85   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    86   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    87   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    88   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    89   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    90   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    91   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    92   "add (add a b) (add c d) = add (add a c) (add b d)"
    93   "add (add a b) c = add a (add b c)"
    94   "add a (add c d) = add c (add a d)"
    95   "add (add a b) c = add (add a c) b"
    96   "add a c = add c a"
    97   "add a (add c d) = add (add a c) d"
    98   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    99   "mul x (pwr x q) = pwr x (Suc q)"
   100   "mul (pwr x q) x = pwr x (Suc q)"
   101   "mul x x = pwr x 2"
   102   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
   103   "pwr (pwr x p) q = pwr x (p * q)"
   104   "pwr x 0 = r1"
   105   "pwr x 1 = x"
   106   "mul x (add y z) = add (mul x y) (mul x z)"
   107   "pwr x (Suc q) = mul x (pwr x q)"
   108   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   109   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   110 proof -
   111   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   112 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   113 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   114 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   115 next show "add r0 a = a" using add_0 by simp
   116 next show "add a r0 = a" using add_0 add_c by simp
   117 next show "mul a b = mul b a" using mul_c by simp
   118 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   119 next show "mul r0 a = r0" using mul_0 by simp
   120 next show "mul a r0 = r0" using mul_0 mul_c by simp
   121 next show "mul r1 a = a" using mul_1 by simp
   122 next show "mul a r1 = a" using mul_1 mul_c by simp
   123 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   124     using mul_c mul_a by simp
   125 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   126     using mul_a by simp
   127 next
   128   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   129   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   130   finally
   131   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   132     using mul_c by simp
   133 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   134 next
   135   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   136 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   137 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   138 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   139     using add_c add_a by simp
   140 next show "add (add a b) c = add a (add b c)" using add_a by simp
   141 next show "add a (add c d) = add c (add a d)"
   142     apply (simp add: add_a) by (simp only: add_c)
   143 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   144 next show "add a c = add c a" by (rule add_c)
   145 next show "add a (add c d) = add (add a c) d" using add_a by simp
   146 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   147 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   148 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   149 next show "mul x x = pwr x 2" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   150 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   151 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   152 next show "pwr x 0 = r1" using pwr_0 .
   153 next show "pwr x 1 = x" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   154 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   155 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   156 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number mul_pwr)
   157 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   158     by (simp add: nat_number pwr_Suc mul_pwr)
   159 qed
   160 
   161 
   162 lemma "axioms" [normalizer
   163     semiring ops: semiring_ops
   164     semiring rules: semiring_rules]:
   165   "gb_semiring add mul pwr r0 r1" .
   166 
   167 end
   168 
   169 interpretation class_semiring: gb_semiring
   170     ["op +" "op *" "op ^" "0::'a::{comm_semiring_1, recpower}" "1"]
   171   by unfold_locales (auto simp add: ring_eq_simps power_Suc)
   172 
   173 lemmas nat_arith =
   174   add_nat_number_of diff_nat_number_of mult_nat_number_of eq_nat_number_of less_nat_number_of
   175 
   176 lemma not_iszero_Numeral1: "\<not> iszero (Numeral1::'a::number_ring)"
   177   by (simp add: numeral_1_eq_1)
   178 lemmas comp_arith = Let_def arith_simps nat_arith rel_simps if_False
   179   if_True add_0 add_Suc add_number_of_left mult_number_of_left
   180   numeral_1_eq_1[symmetric] Suc_eq_add_numeral_1
   181   numeral_0_eq_0[symmetric] numerals[symmetric] not_iszero_1
   182   iszero_number_of_1 iszero_number_of_0 nonzero_number_of_Min
   183   iszero_number_of_Pls iszero_0 not_iszero_Numeral1
   184 
   185 lemmas semiring_norm = comp_arith
   186 
   187 ML {*
   188   fun numeral_is_const ct =
   189     can HOLogic.dest_number (Thm.term_of ct);
   190 
   191   val numeral_conv =
   192     Conv.then_conv (Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}),
   193    Simplifier.rewrite (HOL_basic_ss addsimps
   194   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}));
   195 *}
   196 
   197 ML {*
   198   fun int_of_rat x =
   199     (case Rat.quotient_of_rat x of (i, 1) => i
   200     | _ => error "int_of_rat: bad int")
   201 *}
   202 
   203 declaration {*
   204   NormalizerData.funs @{thm class_semiring.axioms}
   205    {is_const = fn phi => numeral_is_const,
   206     dest_const = fn phi => fn ct =>
   207       Rat.rat_of_int (snd
   208         (HOLogic.dest_number (Thm.term_of ct)
   209           handle TERM _ => error "ring_dest_const")),
   210     mk_const = fn phi => fn cT => fn x =>
   211       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   212     conv = fn phi => numeral_conv}
   213 *}
   214 
   215 
   216 locale gb_ring = gb_semiring +
   217   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   218     and neg :: "'a \<Rightarrow> 'a"
   219   assumes neg_mul: "neg x = mul (neg r1) x"
   220     and sub_add: "sub x y = add x (neg y)"
   221 begin
   222 
   223 lemma ring_ops:
   224   includes meta_term_syntax
   225   shows "TERM (sub x y)" and "TERM (neg x)" .
   226 
   227 lemmas ring_rules = neg_mul sub_add
   228 
   229 lemma "axioms" [normalizer
   230   semiring ops: semiring_ops
   231   semiring rules: semiring_rules
   232   ring ops: ring_ops
   233   ring rules: ring_rules]:
   234   "gb_ring add mul pwr r0 r1 sub neg" .
   235 
   236 end
   237 
   238 
   239 interpretation class_ring: gb_ring ["op +" "op *" "op ^"
   240     "0::'a::{comm_semiring_1,recpower,number_ring}" 1 "op -" "uminus"]
   241   by unfold_locales simp_all
   242 
   243 
   244 declaration {*
   245   NormalizerData.funs @{thm class_ring.axioms}
   246    {is_const = fn phi => numeral_is_const,
   247     dest_const = fn phi => fn ct =>
   248       Rat.rat_of_int (snd
   249         (HOLogic.dest_number (Thm.term_of ct)
   250           handle TERM _ => error "ring_dest_const")),
   251     mk_const = fn phi => fn cT => fn x =>
   252       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   253     conv = fn phi => numeral_conv}
   254 *}
   255 
   256 use "Tools/Groebner_Basis/normalizer.ML"
   257 
   258 method_setup sring_norm = {*
   259   Method.ctxt_args (fn ctxt => Method.SIMPLE_METHOD' (Normalizer.semiring_normalize_tac ctxt))
   260 *} "Semiring_normalizer"
   261 
   262 
   263 locale gb_field = gb_ring +
   264   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   265     and inverse:: "'a \<Rightarrow> 'a"
   266   assumes divide: "divide x y = mul x (inverse y)"
   267      and inverse: "inverse x = divide r1 x"
   268 begin
   269 
   270 lemma "axioms" [normalizer
   271   semiring ops: semiring_ops
   272   semiring rules: semiring_rules
   273   ring ops: ring_ops
   274   ring rules: ring_rules]:
   275   "gb_field add mul pwr r0 r1 sub neg divide inverse" .
   276 
   277 end
   278 
   279 subsection {* Groebner Bases *}
   280 
   281 locale semiringb = gb_semiring +
   282   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   283   and add_mul_solve: "add (mul w y) (mul x z) =
   284     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   285 begin
   286 
   287 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   288 proof-
   289   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   290   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   291     using add_mul_solve by blast
   292   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   293     by simp
   294 qed
   295 
   296 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   297   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   298 proof(clarify)
   299   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   300     and eq: "add b (mul r c) = add b (mul r d)"
   301   hence "mul r c = mul r d" using cnd add_cancel by simp
   302   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   303     using mul_0 add_cancel by simp
   304   thus "False" using add_mul_solve nz cnd by simp
   305 qed
   306 
   307 declare "axioms" [normalizer del]
   308 
   309 lemma "axioms" [normalizer
   310   semiring ops: semiring_ops
   311   semiring rules: semiring_rules
   312   idom rules: noteq_reduce add_scale_eq_noteq]:
   313   "semiringb add mul pwr r0 r1" .
   314 
   315 end
   316 
   317 locale ringb = semiringb + gb_ring
   318 begin
   319 
   320 declare "axioms" [normalizer del]
   321 
   322 lemma "axioms" [normalizer
   323   semiring ops: semiring_ops
   324   semiring rules: semiring_rules
   325   ring ops: ring_ops
   326   ring rules: ring_rules
   327   idom rules: noteq_reduce add_scale_eq_noteq]:
   328   "ringb add mul pwr r0 r1 sub neg" .
   329 
   330 end
   331 
   332 lemma no_zero_divirors_neq0:
   333   assumes az: "(a::'a::no_zero_divisors) \<noteq> 0"
   334     and ab: "a*b = 0" shows "b = 0"
   335 proof -
   336   { assume bz: "b \<noteq> 0"
   337     from no_zero_divisors [OF az bz] ab have False by blast }
   338   thus "b = 0" by blast
   339 qed
   340 
   341 interpretation class_ringb: ringb
   342   ["op +" "op *" "op ^" "0::'a::{idom,recpower,number_ring}" "1" "op -" "uminus"]
   343 proof(unfold_locales, simp add: ring_eq_simps power_Suc, auto)
   344   fix w x y z ::"'a::{idom,recpower,number_ring}"
   345   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   346   hence ynz': "y - z \<noteq> 0" by simp
   347   from p have "w * y + x* z - w*z - x*y = 0" by simp
   348   hence "w* (y - z) - x * (y - z) = 0" by (simp add: ring_eq_simps)
   349   hence "(y - z) * (w - x) = 0" by (simp add: ring_eq_simps)
   350   with  no_zero_divirors_neq0 [OF ynz']
   351   have "w - x = 0" by blast
   352   thus "w = x"  by simp
   353 qed
   354 
   355 
   356 declaration {*
   357   NormalizerData.funs @{thm class_ringb.axioms}
   358    {is_const = fn phi => numeral_is_const,
   359     dest_const = fn phi => fn ct =>
   360       Rat.rat_of_int (snd
   361         (HOLogic.dest_number (Thm.term_of ct)
   362           handle TERM _ => error "ring_dest_const")),
   363     mk_const = fn phi => fn cT => fn x =>
   364       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   365     conv = fn phi => numeral_conv}
   366 *}
   367 
   368 
   369 interpretation natgb: semiringb
   370   ["op +" "op *" "op ^" "0::nat" "1"]
   371 proof (unfold_locales, simp add: ring_eq_simps power_Suc)
   372   fix w x y z ::"nat"
   373   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   374     hence "y < z \<or> y > z" by arith
   375     moreover {
   376       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   377       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   378       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz ring_eq_simps)
   379       hence "x*k = w*k" by simp
   380       hence "w = x" using kp by (simp add: mult_cancel2) }
   381     moreover {
   382       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   383       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   384       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz ring_eq_simps)
   385       hence "w*k = x*k" by simp
   386       hence "w = x" using kp by (simp add: mult_cancel2)}
   387     ultimately have "w=x" by blast }
   388   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   389 qed
   390 
   391 declaration {*
   392   NormalizerData.funs @{thm natgb.axioms}
   393    {is_const = fn phi => numeral_is_const,
   394     dest_const = fn phi => fn ct =>
   395       Rat.rat_of_int (snd
   396         (HOLogic.dest_number (Thm.term_of ct)
   397           handle TERM _ => error "ring_dest_const")),
   398     mk_const = fn phi => fn cT => fn x =>
   399       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   400     conv = fn phi => numeral_conv}
   401 *}
   402 
   403 locale fieldgb = ringb + gb_field
   404 begin
   405 
   406 declare "axioms" [normalizer del]
   407 
   408 lemma "axioms" [normalizer
   409   semiring ops: semiring_ops
   410   semiring rules: semiring_rules
   411   ring ops: ring_ops
   412   ring rules: ring_rules
   413   idom rules: noteq_reduce add_scale_eq_noteq]:
   414   "fieldgb add mul pwr r0 r1 sub neg divide inverse" by unfold_locales
   415 end
   416 
   417 
   418 
   419 lemmas bool_simps = simp_thms(1-34)
   420 lemma dnf:
   421     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   422     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   423   by blast+
   424 
   425 lemmas weak_dnf_simps = dnf bool_simps
   426 
   427 lemma nnf_simps:
   428     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   429     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   430   by blast+
   431 
   432 lemma PFalse:
   433     "P \<equiv> False \<Longrightarrow> \<not> P"
   434     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   435   by auto
   436 
   437 use "Tools/Groebner_Basis/groebner.ML"
   438 
   439 ML {*
   440   fun algebra_tac ctxt i = ObjectLogic.full_atomize_tac i THEN (fn st =>
   441   rtac (Groebner.ring_conv ctxt (Thm.dest_arg (nth (cprems_of st) (i - 1)))) i st);
   442 *}
   443 
   444 method_setup algebra = {*
   445   Method.ctxt_args (Method.SIMPLE_METHOD' o algebra_tac)
   446 *} ""
   447 
   448 
   449 
   450 end