src/HOL/Analysis/Complex_Analysis_Basics.thy
author paulson <lp15@cam.ac.uk>
Thu Apr 27 15:59:00 2017 +0100 (2017-04-27)
changeset 65587 16a8991ab398
parent 64394 141e1ed8d5a0
child 66089 def95e0bc529
permissions -rw-r--r--
New material (and some tidying) purely in the Analysis directory
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "~~/src/HOL/Library/Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((op * c) has_derivative (op * c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_complex:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "op * f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 
    31 lemma fact_cancel:
    32   fixes c :: "'a::real_field"
    33   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    34   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    35 
    36 lemma bilinear_times:
    37   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    38   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    39 
    40 lemma linear_cnj: "linear cnj"
    41   using bounded_linear.linear[OF bounded_linear_cnj] .
    42 
    43 lemma tendsto_Re_upper:
    44   assumes "~ (trivial_limit F)"
    45           "(f \<longlongrightarrow> l) F"
    46           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    47     shows  "Re(l) \<le> b"
    48   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    49 
    50 lemma tendsto_Re_lower:
    51   assumes "~ (trivial_limit F)"
    52           "(f \<longlongrightarrow> l) F"
    53           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    54     shows  "b \<le> Re(l)"
    55   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    56 
    57 lemma tendsto_Im_upper:
    58   assumes "~ (trivial_limit F)"
    59           "(f \<longlongrightarrow> l) F"
    60           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    61     shows  "Im(l) \<le> b"
    62   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    63 
    64 lemma tendsto_Im_lower:
    65   assumes "~ (trivial_limit F)"
    66           "(f \<longlongrightarrow> l) F"
    67           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    68     shows  "b \<le> Im(l)"
    69   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    70 
    71 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = op * 0"
    72   by auto
    73 
    74 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = op * 1"
    75   by auto
    76 
    77 lemma continuous_mult_left:
    78   fixes c::"'a::real_normed_algebra"
    79   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    80 by (rule continuous_mult [OF continuous_const])
    81 
    82 lemma continuous_mult_right:
    83   fixes c::"'a::real_normed_algebra"
    84   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    85 by (rule continuous_mult [OF _ continuous_const])
    86 
    87 lemma continuous_on_mult_left:
    88   fixes c::"'a::real_normed_algebra"
    89   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    90 by (rule continuous_on_mult [OF continuous_on_const])
    91 
    92 lemma continuous_on_mult_right:
    93   fixes c::"'a::real_normed_algebra"
    94   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    95 by (rule continuous_on_mult [OF _ continuous_on_const])
    96 
    97 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    98   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    99   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   100   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   101 
   102 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   103   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   104   assumes "uniformly_continuous_on s f"
   105     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   106 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   107 
   108 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   109   by (rule continuous_norm [OF continuous_ident])
   110 
   111 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   112   by (intro continuous_on_id continuous_on_norm)
   113 
   114 subsection\<open>DERIV stuff\<close>
   115 
   116 lemma DERIV_zero_connected_constant:
   117   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   118   assumes "connected s"
   119       and "open s"
   120       and "finite k"
   121       and "continuous_on s f"
   122       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   123     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   124 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   125 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   126 
   127 lemma DERIV_zero_constant:
   128   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   129   shows    "\<lbrakk>convex s;
   130              \<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)\<rbrakk>
   131              \<Longrightarrow> \<exists>c. \<forall>x \<in> s. f(x) = c"
   132   by (auto simp: has_field_derivative_def lambda_zero intro: has_derivative_zero_constant)
   133 
   134 lemma DERIV_zero_unique:
   135   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   136   assumes "convex s"
   137       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   138       and "a \<in> s"
   139       and "x \<in> s"
   140     shows "f x = f a"
   141   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   142      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   143 
   144 lemma DERIV_zero_connected_unique:
   145   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   146   assumes "connected s"
   147       and "open s"
   148       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   149       and "a \<in> s"
   150       and "x \<in> s"
   151     shows "f x = f a"
   152     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   153        (metis has_field_derivative_def lambda_zero d0)
   154 
   155 lemma DERIV_transform_within:
   156   assumes "(f has_field_derivative f') (at a within s)"
   157       and "0 < d" "a \<in> s"
   158       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   159     shows "(g has_field_derivative f') (at a within s)"
   160   using assms unfolding has_field_derivative_def
   161   by (blast intro: has_derivative_transform_within)
   162 
   163 lemma DERIV_transform_within_open:
   164   assumes "DERIV f a :> f'"
   165       and "open s" "a \<in> s"
   166       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   167     shows "DERIV g a :> f'"
   168   using assms unfolding has_field_derivative_def
   169 by (metis has_derivative_transform_within_open)
   170 
   171 lemma DERIV_transform_at:
   172   assumes "DERIV f a :> f'"
   173       and "0 < d"
   174       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   175     shows "DERIV g a :> f'"
   176   by (blast intro: assms DERIV_transform_within)
   177 
   178 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   179 lemma DERIV_zero_UNIV_unique:
   180   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   181   shows "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   182 by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   183 
   184 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   185 
   186 (*MOVE? But not to Finite_Cartesian_Product*)
   187 lemma sums_vec_nth :
   188   assumes "f sums a"
   189   shows "(\<lambda>x. f x $ i) sums a $ i"
   190 using assms unfolding sums_def
   191 by (auto dest: tendsto_vec_nth [where i=i])
   192 
   193 lemma summable_vec_nth :
   194   assumes "summable f"
   195   shows "summable (\<lambda>x. f x $ i)"
   196 using assms unfolding summable_def
   197 by (blast intro: sums_vec_nth)
   198 
   199 subsection \<open>Complex number lemmas\<close>
   200 
   201 lemma
   202   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   203     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   204     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   205     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   206     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   207     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   208     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   209     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   210     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   211     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   212   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   213             continuous_on_Im continuous_on_id continuous_on_const)+
   214 
   215 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   216 proof -
   217   have "(\<real> :: complex set) = {z. Im z = 0}"
   218     by (auto simp: complex_is_Real_iff)
   219   then show ?thesis
   220     by (metis closed_halfspace_Im_eq)
   221 qed
   222 
   223 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   224   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   225 
   226 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   227 proof -
   228   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   229     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   230   then show ?thesis
   231     by (metis closed_Real_halfspace_Re_le)
   232 qed
   233 
   234 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   235   using closed_halfspace_Re_ge
   236   by (simp add: closed_Int closed_complex_Reals)
   237 
   238 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   239 proof -
   240   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   241     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   242   then show ?thesis
   243     by (metis closed_Real_halfspace_Re_ge)
   244 qed
   245 
   246 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   247 proof -
   248   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   249     by auto
   250   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   251     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   252 qed
   253 
   254 lemma real_lim:
   255   fixes l::complex
   256   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   257   shows  "l \<in> \<real>"
   258 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   259   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   260     using assms(3, 4) by (auto intro: eventually_mono)
   261 qed
   262 
   263 lemma real_lim_sequentially:
   264   fixes l::complex
   265   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   266 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   267 
   268 lemma real_series:
   269   fixes l::complex
   270   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   271 unfolding sums_def
   272 by (metis real_lim_sequentially sum_in_Reals)
   273 
   274 lemma Lim_null_comparison_Re:
   275   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   276   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   277 
   278 subsection\<open>Holomorphic functions\<close>
   279 
   280 subsection\<open>Holomorphic functions\<close>
   281 
   282 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   283            (infixl "(holomorphic'_on)" 50)
   284   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   285 
   286 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   287 
   288 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   289   by (simp add: holomorphic_on_def)
   290 
   291 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   292   by (simp add: holomorphic_on_def)
   293 
   294 lemma holomorphic_on_imp_differentiable_on:
   295     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   296   unfolding holomorphic_on_def differentiable_on_def
   297   by (simp add: field_differentiable_imp_differentiable)
   298 
   299 lemma holomorphic_on_imp_differentiable_at:
   300    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   301 using at_within_open holomorphic_on_def by fastforce
   302 
   303 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   304   by (simp add: holomorphic_on_def)
   305 
   306 lemma holomorphic_on_open:
   307     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   308   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   309 
   310 lemma holomorphic_on_imp_continuous_on:
   311     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   312   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   313 
   314 lemma holomorphic_on_subset [elim]:
   315     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   316   unfolding holomorphic_on_def
   317   by (metis field_differentiable_within_subset subsetD)
   318 
   319 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   320   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   321 
   322 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   323   by (metis holomorphic_transform)
   324 
   325 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(op * c) holomorphic_on s"
   326   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   327 
   328 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   329   unfolding holomorphic_on_def by (metis field_differentiable_const)
   330 
   331 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   332   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   333 
   334 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   335   unfolding id_def by (rule holomorphic_on_ident)
   336 
   337 lemma holomorphic_on_compose:
   338   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   339   using field_differentiable_compose_within[of f _ s g]
   340   by (auto simp: holomorphic_on_def)
   341 
   342 lemma holomorphic_on_compose_gen:
   343   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   344   by (metis holomorphic_on_compose holomorphic_on_subset)
   345 
   346 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   347   by (metis field_differentiable_minus holomorphic_on_def)
   348 
   349 lemma holomorphic_on_add [holomorphic_intros]:
   350   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   351   unfolding holomorphic_on_def by (metis field_differentiable_add)
   352 
   353 lemma holomorphic_on_diff [holomorphic_intros]:
   354   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   355   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   356 
   357 lemma holomorphic_on_mult [holomorphic_intros]:
   358   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   359   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   360 
   361 lemma holomorphic_on_inverse [holomorphic_intros]:
   362   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   363   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   364 
   365 lemma holomorphic_on_divide [holomorphic_intros]:
   366   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   367   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   368 
   369 lemma holomorphic_on_power [holomorphic_intros]:
   370   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   371   unfolding holomorphic_on_def by (metis field_differentiable_power)
   372 
   373 lemma holomorphic_on_sum [holomorphic_intros]:
   374   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   375   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   376 
   377 lemma DERIV_deriv_iff_field_differentiable:
   378   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   379   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   380 
   381 lemma holomorphic_derivI:
   382      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   383       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   384 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   385 
   386 lemma complex_derivative_chain:
   387   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   388     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   389   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   390 
   391 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   392   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   393 
   394 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   395   by (metis DERIV_imp_deriv DERIV_ident)
   396 
   397 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   398   by (simp add: id_def)
   399 
   400 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   401   by (metis DERIV_imp_deriv DERIV_const)
   402 
   403 lemma deriv_add [simp]:
   404   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   405    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   406   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   407   by (auto intro!: DERIV_imp_deriv derivative_intros)
   408 
   409 lemma deriv_diff [simp]:
   410   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   411    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   412   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   413   by (auto intro!: DERIV_imp_deriv derivative_intros)
   414 
   415 lemma deriv_mult [simp]:
   416   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   417    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   418   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   419   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   420 
   421 lemma deriv_cmult [simp]:
   422   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   423   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   424   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   425 
   426 lemma deriv_cmult_right [simp]:
   427   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   428   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   429   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   430 
   431 lemma deriv_cdivide_right [simp]:
   432   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   433   unfolding Fields.field_class.field_divide_inverse
   434   by (blast intro: deriv_cmult_right)
   435 
   436 lemma complex_derivative_transform_within_open:
   437   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   438    \<Longrightarrow> deriv f z = deriv g z"
   439   unfolding holomorphic_on_def
   440   by (rule DERIV_imp_deriv)
   441      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   442 
   443 lemma deriv_compose_linear:
   444   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   445 apply (rule DERIV_imp_deriv)
   446 apply (simp add: DERIV_deriv_iff_field_differentiable [symmetric])
   447 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   448 apply (simp add: algebra_simps)
   449 done
   450 
   451 lemma nonzero_deriv_nonconstant:
   452   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   453     shows "\<not> f constant_on S"
   454 unfolding constant_on_def
   455 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   456 
   457 lemma holomorphic_nonconstant:
   458   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   459     shows "\<not> f constant_on S"
   460     apply (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   461     using assms
   462     apply (auto simp: holomorphic_derivI)
   463     done
   464 
   465 subsection\<open>Caratheodory characterization\<close>
   466 
   467 lemma field_differentiable_caratheodory_at:
   468   "f field_differentiable (at z) \<longleftrightarrow>
   469          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   470   using CARAT_DERIV [of f]
   471   by (simp add: field_differentiable_def has_field_derivative_def)
   472 
   473 lemma field_differentiable_caratheodory_within:
   474   "f field_differentiable (at z within s) \<longleftrightarrow>
   475          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   476   using DERIV_caratheodory_within [of f]
   477   by (simp add: field_differentiable_def has_field_derivative_def)
   478 
   479 subsection\<open>Analyticity on a set\<close>
   480 
   481 definition analytic_on (infixl "(analytic'_on)" 50)
   482   where
   483    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   484 
   485 named_theorems analytic_intros "introduction rules for proving analyticity"
   486 
   487 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   488   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   489      (metis centre_in_ball field_differentiable_at_within)
   490 
   491 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   492 apply (auto simp: analytic_imp_holomorphic)
   493 apply (auto simp: analytic_on_def holomorphic_on_def)
   494 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   495 
   496 lemma analytic_on_imp_differentiable_at:
   497   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f field_differentiable (at x)"
   498  apply (auto simp: analytic_on_def holomorphic_on_def)
   499 by (metis Topology_Euclidean_Space.open_ball centre_in_ball field_differentiable_within_open)
   500 
   501 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   502   by (auto simp: analytic_on_def)
   503 
   504 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   505   by (auto simp: analytic_on_def)
   506 
   507 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   508   by (auto simp: analytic_on_def)
   509 
   510 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   511   by (auto simp: analytic_on_def)
   512 
   513 lemma analytic_on_holomorphic:
   514   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   515   (is "?lhs = ?rhs")
   516 proof -
   517   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   518   proof safe
   519     assume "f analytic_on s"
   520     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   521       apply (simp add: analytic_on_def)
   522       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   523       apply (metis Topology_Euclidean_Space.open_ball analytic_on_open centre_in_ball)
   524       by (metis analytic_on_def)
   525   next
   526     fix t
   527     assume "open t" "s \<subseteq> t" "f analytic_on t"
   528     then show "f analytic_on s"
   529         by (metis analytic_on_subset)
   530   qed
   531   also have "... \<longleftrightarrow> ?rhs"
   532     by (auto simp: analytic_on_open)
   533   finally show ?thesis .
   534 qed
   535 
   536 lemma analytic_on_linear [analytic_intros,simp]: "(op * c) analytic_on s"
   537   by (auto simp add: analytic_on_holomorphic)
   538 
   539 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on s"
   540   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   541 
   542 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on s"
   543   by (simp add: analytic_on_def gt_ex)
   544 
   545 lemma analytic_on_id [analytic_intros]: "id analytic_on s"
   546   unfolding id_def by (rule analytic_on_ident)
   547 
   548 lemma analytic_on_compose:
   549   assumes f: "f analytic_on s"
   550       and g: "g analytic_on (f ` s)"
   551     shows "(g o f) analytic_on s"
   552 unfolding analytic_on_def
   553 proof (intro ballI)
   554   fix x
   555   assume x: "x \<in> s"
   556   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   557     by (metis analytic_on_def)
   558   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   559     by (metis analytic_on_def g image_eqI x)
   560   have "isCont f x"
   561     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   562   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   563      by (auto simp: continuous_at_ball)
   564   have "g \<circ> f holomorphic_on ball x (min d e)"
   565     apply (rule holomorphic_on_compose)
   566     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   567     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   568   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   569     by (metis d e min_less_iff_conj)
   570 qed
   571 
   572 lemma analytic_on_compose_gen:
   573   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   574              \<Longrightarrow> g o f analytic_on s"
   575 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   576 
   577 lemma analytic_on_neg [analytic_intros]:
   578   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   579 by (metis analytic_on_holomorphic holomorphic_on_minus)
   580 
   581 lemma analytic_on_add [analytic_intros]:
   582   assumes f: "f analytic_on s"
   583       and g: "g analytic_on s"
   584     shows "(\<lambda>z. f z + g z) analytic_on s"
   585 unfolding analytic_on_def
   586 proof (intro ballI)
   587   fix z
   588   assume z: "z \<in> s"
   589   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   590     by (metis analytic_on_def)
   591   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   592     by (metis analytic_on_def g z)
   593   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   594     apply (rule holomorphic_on_add)
   595     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   596     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   597   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   598     by (metis e e' min_less_iff_conj)
   599 qed
   600 
   601 lemma analytic_on_diff [analytic_intros]:
   602   assumes f: "f analytic_on s"
   603       and g: "g analytic_on s"
   604     shows "(\<lambda>z. f z - g z) analytic_on s"
   605 unfolding analytic_on_def
   606 proof (intro ballI)
   607   fix z
   608   assume z: "z \<in> s"
   609   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   610     by (metis analytic_on_def)
   611   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   612     by (metis analytic_on_def g z)
   613   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   614     apply (rule holomorphic_on_diff)
   615     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   616     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   617   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   618     by (metis e e' min_less_iff_conj)
   619 qed
   620 
   621 lemma analytic_on_mult [analytic_intros]:
   622   assumes f: "f analytic_on s"
   623       and g: "g analytic_on s"
   624     shows "(\<lambda>z. f z * g z) analytic_on s"
   625 unfolding analytic_on_def
   626 proof (intro ballI)
   627   fix z
   628   assume z: "z \<in> s"
   629   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   630     by (metis analytic_on_def)
   631   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   632     by (metis analytic_on_def g z)
   633   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   634     apply (rule holomorphic_on_mult)
   635     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   636     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   637   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   638     by (metis e e' min_less_iff_conj)
   639 qed
   640 
   641 lemma analytic_on_inverse [analytic_intros]:
   642   assumes f: "f analytic_on s"
   643       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   644     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   645 unfolding analytic_on_def
   646 proof (intro ballI)
   647   fix z
   648   assume z: "z \<in> s"
   649   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   650     by (metis analytic_on_def)
   651   have "continuous_on (ball z e) f"
   652     by (metis fh holomorphic_on_imp_continuous_on)
   653   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   654     by (metis Topology_Euclidean_Space.open_ball centre_in_ball continuous_on_open_avoid e z nz)
   655   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   656     apply (rule holomorphic_on_inverse)
   657     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   658     by (metis nz' mem_ball min_less_iff_conj)
   659   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   660     by (metis e e' min_less_iff_conj)
   661 qed
   662 
   663 lemma analytic_on_divide [analytic_intros]:
   664   assumes f: "f analytic_on s"
   665       and g: "g analytic_on s"
   666       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   667     shows "(\<lambda>z. f z / g z) analytic_on s"
   668 unfolding divide_inverse
   669 by (metis analytic_on_inverse analytic_on_mult f g nz)
   670 
   671 lemma analytic_on_power [analytic_intros]:
   672   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   673 by (induct n) (auto simp: analytic_on_mult)
   674 
   675 lemma analytic_on_sum [analytic_intros]:
   676   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on s"
   677   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   678 
   679 lemma deriv_left_inverse:
   680   assumes "f holomorphic_on S" and "g holomorphic_on T"
   681       and "open S" and "open T"
   682       and "f ` S \<subseteq> T"
   683       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   684       and "w \<in> S"
   685     shows "deriv f w * deriv g (f w) = 1"
   686 proof -
   687   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   688     by (simp add: algebra_simps)
   689   also have "... = deriv (g o f) w"
   690     using assms
   691     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   692   also have "... = deriv id w"
   693     apply (rule complex_derivative_transform_within_open [where s=S])
   694     apply (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   695     apply simp
   696     done
   697   also have "... = 1"
   698     by simp
   699   finally show ?thesis .
   700 qed
   701 
   702 subsection\<open>analyticity at a point\<close>
   703 
   704 lemma analytic_at_ball:
   705   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   706 by (metis analytic_on_def singleton_iff)
   707 
   708 lemma analytic_at:
   709     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   710 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   711 
   712 lemma analytic_on_analytic_at:
   713     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   714 by (metis analytic_at_ball analytic_on_def)
   715 
   716 lemma analytic_at_two:
   717   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   718    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   719   (is "?lhs = ?rhs")
   720 proof
   721   assume ?lhs
   722   then obtain s t
   723     where st: "open s" "z \<in> s" "f holomorphic_on s"
   724               "open t" "z \<in> t" "g holomorphic_on t"
   725     by (auto simp: analytic_at)
   726   show ?rhs
   727     apply (rule_tac x="s \<inter> t" in exI)
   728     using st
   729     apply (auto simp: Diff_subset holomorphic_on_subset)
   730     done
   731 next
   732   assume ?rhs
   733   then show ?lhs
   734     by (force simp add: analytic_at)
   735 qed
   736 
   737 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   738 
   739 lemma
   740   assumes "f analytic_on {z}" "g analytic_on {z}"
   741   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   742     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   743     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   744            f z * deriv g z + deriv f z * g z"
   745 proof -
   746   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   747     using assms by (metis analytic_at_two)
   748   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   749     apply (rule DERIV_imp_deriv [OF DERIV_add])
   750     using s
   751     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   752     done
   753   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   754     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   755     using s
   756     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   757     done
   758   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   759     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   760     using s
   761     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   762     done
   763 qed
   764 
   765 lemma deriv_cmult_at:
   766   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   767 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   768 
   769 lemma deriv_cmult_right_at:
   770   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   771 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   772 
   773 subsection\<open>Complex differentiation of sequences and series\<close>
   774 
   775 (* TODO: Could probably be simplified using Uniform_Limit *)
   776 lemma has_complex_derivative_sequence:
   777   fixes s :: "complex set"
   778   assumes cvs: "convex s"
   779       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   780       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   781       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   782     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   783                        (g has_field_derivative (g' x)) (at x within s)"
   784 proof -
   785   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   786     by blast
   787   { fix e::real assume e: "e > 0"
   788     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   789       by (metis conv)
   790     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   791     proof (rule exI [of _ N], clarify)
   792       fix n y h
   793       assume "N \<le> n" "y \<in> s"
   794       then have "cmod (f' n y - g' y) \<le> e"
   795         by (metis N)
   796       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   797         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   798       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   799         by (simp add: norm_mult [symmetric] field_simps)
   800     qed
   801   } note ** = this
   802   show ?thesis
   803   unfolding has_field_derivative_def
   804   proof (rule has_derivative_sequence [OF cvs _ _ x])
   805     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (op * (f' n x))) (at x within s)"
   806       by (metis has_field_derivative_def df)
   807   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   808     by (rule tf)
   809   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   810     by (blast intro: **)
   811   qed
   812 qed
   813 
   814 lemma has_complex_derivative_series:
   815   fixes s :: "complex set"
   816   assumes cvs: "convex s"
   817       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   818       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   819                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   820       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   821     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   822 proof -
   823   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   824     by blast
   825   { fix e::real assume e: "e > 0"
   826     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   827             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   828       by (metis conv)
   829     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   830     proof (rule exI [of _ N], clarify)
   831       fix n y h
   832       assume "N \<le> n" "y \<in> s"
   833       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   834         by (metis N)
   835       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   836         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   837       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   838         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   839     qed
   840   } note ** = this
   841   show ?thesis
   842   unfolding has_field_derivative_def
   843   proof (rule has_derivative_series [OF cvs _ _ x])
   844     fix n x
   845     assume "x \<in> s"
   846     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   847       by (metis df has_field_derivative_def mult_commute_abs)
   848   next show " ((\<lambda>n. f n x) sums l)"
   849     by (rule sf)
   850   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   851     by (blast intro: **)
   852   qed
   853 qed
   854 
   855 
   856 lemma field_differentiable_series:
   857   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   858   assumes "convex s" "open s"
   859   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   860   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   861   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   862   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   863 proof -
   864   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   865     unfolding uniformly_convergent_on_def by blast
   866   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   867   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   868     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   869   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   870     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   871   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   872   from g(2)[OF x] have g': "(g has_derivative op * (g' x)) (at x)"
   873     by (simp add: has_field_derivative_def s)
   874   have "((\<lambda>x. \<Sum>n. f n x) has_derivative op * (g' x)) (at x)"
   875     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   876        (insert g, auto simp: sums_iff)
   877   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   878     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   879 qed
   880 
   881 lemma field_differentiable_series':
   882   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   883   assumes "convex s" "open s"
   884   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   885   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   886   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   887   shows   "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x0)"
   888   using field_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   889 
   890 subsection\<open>Bound theorem\<close>
   891 
   892 lemma field_differentiable_bound:
   893   fixes s :: "complex set"
   894   assumes cvs: "convex s"
   895       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   896       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   897       and "x \<in> s"  "y \<in> s"
   898     shows "norm(f x - f y) \<le> B * norm(x - y)"
   899   apply (rule differentiable_bound [OF cvs])
   900   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   901   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   902   apply fact
   903   apply fact
   904   done
   905 
   906 subsection\<open>Inverse function theorem for complex derivatives\<close>
   907 
   908 lemma has_complex_derivative_inverse_basic:
   909   fixes f :: "complex \<Rightarrow> complex"
   910   shows "DERIV f (g y) :> f' \<Longrightarrow>
   911         f' \<noteq> 0 \<Longrightarrow>
   912         continuous (at y) g \<Longrightarrow>
   913         open t \<Longrightarrow>
   914         y \<in> t \<Longrightarrow>
   915         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   916         \<Longrightarrow> DERIV g y :> inverse (f')"
   917   unfolding has_field_derivative_def
   918   apply (rule has_derivative_inverse_basic)
   919   apply (auto simp:  bounded_linear_mult_right)
   920   done
   921 
   922 (*Used only once, in Multivariate/cauchy.ml. *)
   923 lemma has_complex_derivative_inverse_strong:
   924   fixes f :: "complex \<Rightarrow> complex"
   925   shows "DERIV f x :> f' \<Longrightarrow>
   926          f' \<noteq> 0 \<Longrightarrow>
   927          open s \<Longrightarrow>
   928          x \<in> s \<Longrightarrow>
   929          continuous_on s f \<Longrightarrow>
   930          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   931          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   932   unfolding has_field_derivative_def
   933   apply (rule has_derivative_inverse_strong [of s x f g ])
   934   by auto
   935 
   936 lemma has_complex_derivative_inverse_strong_x:
   937   fixes f :: "complex \<Rightarrow> complex"
   938   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   939           f' \<noteq> 0 \<Longrightarrow>
   940           open s \<Longrightarrow>
   941           continuous_on s f \<Longrightarrow>
   942           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
   943           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   944           \<Longrightarrow> DERIV g y :> inverse (f')"
   945   unfolding has_field_derivative_def
   946   apply (rule has_derivative_inverse_strong_x [of s g y f])
   947   by auto
   948 
   949 subsection \<open>Taylor on Complex Numbers\<close>
   950 
   951 lemma sum_Suc_reindex:
   952   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   953     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   954 by (induct n) auto
   955 
   956 lemma complex_taylor:
   957   assumes s: "convex s"
   958       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
   959       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
   960       and w: "w \<in> s"
   961       and z: "z \<in> s"
   962     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   963           \<le> B * cmod(z - w)^(Suc n) / fact n"
   964 proof -
   965   have wzs: "closed_segment w z \<subseteq> s" using assms
   966     by (metis convex_contains_segment)
   967   { fix u
   968     assume "u \<in> closed_segment w z"
   969     then have "u \<in> s"
   970       by (metis wzs subsetD)
   971     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   972                       f (Suc i) u * (z-u)^i / (fact i)) =
   973               f (Suc n) u * (z-u) ^ n / (fact n)"
   974     proof (induction n)
   975       case 0 show ?case by simp
   976     next
   977       case (Suc n)
   978       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   979                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   980            f (Suc n) u * (z-u) ^ n / (fact n) +
   981            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
   982            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
   983         using Suc by simp
   984       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
   985       proof -
   986         have "(fact(Suc n)) *
   987              (f(Suc n) u *(z-u) ^ n / (fact n) +
   988                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
   989                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
   990             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
   991             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
   992             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
   993           by (simp add: algebra_simps del: fact_Suc)
   994         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
   995                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   996                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   997           by (simp del: fact_Suc)
   998         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
   999                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1000                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1001           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1002         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1003           by (simp add: algebra_simps)
  1004         finally show ?thesis
  1005         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1006       qed
  1007       finally show ?case .
  1008     qed
  1009     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1010                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1011                (at u within s)"
  1012       apply (intro derivative_eq_intros)
  1013       apply (blast intro: assms \<open>u \<in> s\<close>)
  1014       apply (rule refl)+
  1015       apply (auto simp: field_simps)
  1016       done
  1017   } note sum_deriv = this
  1018   { fix u
  1019     assume u: "u \<in> closed_segment w z"
  1020     then have us: "u \<in> s"
  1021       by (metis wzs subsetD)
  1022     have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> cmod (f (Suc n) u) * cmod (u - z) ^ n"
  1023       by (metis norm_minus_commute order_refl)
  1024     also have "... \<le> cmod (f (Suc n) u) * cmod (z - w) ^ n"
  1025       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1026     also have "... \<le> B * cmod (z - w) ^ n"
  1027       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1028     finally have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> B * cmod (z - w) ^ n" .
  1029   } note cmod_bound = this
  1030   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1031     by simp
  1032   also have "\<dots> = f 0 z / (fact 0)"
  1033     by (subst sum_zero_power) simp
  1034   finally have "cmod (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1035                 \<le> cmod ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1036                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1037     by (simp add: norm_minus_commute)
  1038   also have "... \<le> B * cmod (z - w) ^ n / (fact n) * cmod (w - z)"
  1039     apply (rule field_differentiable_bound
  1040       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1041          and s = "closed_segment w z", OF convex_closed_segment])
  1042     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1043                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1044     done
  1045   also have "...  \<le> B * cmod (z - w) ^ Suc n / (fact n)"
  1046     by (simp add: algebra_simps norm_minus_commute)
  1047   finally show ?thesis .
  1048 qed
  1049 
  1050 text\<open>Something more like the traditional MVT for real components\<close>
  1051 
  1052 lemma complex_mvt_line:
  1053   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1054     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1055 proof -
  1056   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1057     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1058   note assms[unfolded has_field_derivative_def, derivative_intros]
  1059   show ?thesis
  1060     apply (cut_tac mvt_simple
  1061                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1062                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1063     apply auto
  1064     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1065     apply (auto simp: closed_segment_def twz) []
  1066     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1067     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1068     apply (force simp: twz closed_segment_def)
  1069     done
  1070 qed
  1071 
  1072 lemma complex_taylor_mvt:
  1073   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1074     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1075             Re (f 0 z) =
  1076             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1077                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1078 proof -
  1079   { fix u
  1080     assume u: "u \<in> closed_segment w z"
  1081     have "(\<Sum>i = 0..n.
  1082                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1083                (fact i)) =
  1084           f (Suc 0) u -
  1085              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1086              (fact (Suc n)) +
  1087              (\<Sum>i = 0..n.
  1088                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1089                  (fact (Suc i)))"
  1090        by (subst sum_Suc_reindex) simp
  1091     also have "... = f (Suc 0) u -
  1092              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1093              (fact (Suc n)) +
  1094              (\<Sum>i = 0..n.
  1095                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1096                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1097       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1098     also have "... = f (Suc 0) u -
  1099              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1100              (fact (Suc n)) +
  1101              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1102       by (subst sum_Suc_diff) auto
  1103     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1104       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1105     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1106                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1107                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1108     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1109                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1110       apply (intro derivative_eq_intros)+
  1111       apply (force intro: u assms)
  1112       apply (rule refl)+
  1113       apply (auto simp: ac_simps)
  1114       done
  1115   }
  1116   then show ?thesis
  1117     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1118                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1119     apply (auto simp add: intro: open_closed_segment)
  1120     done
  1121 qed
  1122 
  1123 
  1124 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1125 
  1126 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1127     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1128   assumes "0 < e"
  1129     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1130 proof (induct n)
  1131   case 0 with assms
  1132   show ?case
  1133     apply (rule_tac x="norm (c 0) / e" in exI)
  1134     apply (auto simp: field_simps)
  1135     done
  1136 next
  1137   case (Suc n)
  1138   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1139     using Suc assms by blast
  1140   show ?case
  1141   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1142     fix z::'a
  1143     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1144     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1145       using assms by (simp add: field_simps)
  1146     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1147       using M [OF z1] by simp
  1148     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1149       by simp
  1150     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1151       by (blast intro: norm_triangle_le elim: )
  1152     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1153       by (simp add: norm_power norm_mult algebra_simps)
  1154     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1155       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1156     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1157       by simp
  1158   qed
  1159 qed
  1160 
  1161 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1162     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1163   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1164     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1165 using kn
  1166 proof (induction n)
  1167   case 0
  1168   then show ?case
  1169     using k  by simp
  1170 next
  1171   case (Suc m)
  1172   let ?even = ?case
  1173   show ?even
  1174   proof (cases "c (Suc m) = 0")
  1175     case True
  1176     then show ?even using Suc k
  1177       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1178   next
  1179     case False
  1180     then obtain M where M:
  1181           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1182       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1183       by auto
  1184     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1185     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1186       fix z::'a
  1187       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1188          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1189       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1190         using False by (simp add: field_simps)
  1191       have nz: "norm z \<le> norm z ^ Suc m"
  1192         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1193       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1194         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1195       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1196             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1197         using M [of z] Suc z1  by auto
  1198       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1199         using nz by (simp add: mult_mono del: power_Suc)
  1200       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1201         using Suc.IH
  1202         apply (auto simp: eventually_at_infinity)
  1203         apply (rule *)
  1204         apply (simp add: field_simps norm_mult norm_power)
  1205         done
  1206     qed
  1207     then show ?even
  1208       by (simp add: eventually_at_infinity)
  1209   qed
  1210 qed
  1211 
  1212 end