src/HOL/HOL.thy
author haftmann
Tue Dec 22 15:39:01 2015 +0100 (2015-12-22)
changeset 61914 16bfe0a6702d
parent 61799 4cf66f21b764
child 61941 31f2105521ee
permissions -rw-r--r--
stripped some legacy
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>The basis of Higher-Order Logic\<close>
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
    11     "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 begin
    14 
    15 ML_file "~~/src/Tools/misc_legacy.ML"
    16 ML_file "~~/src/Tools/try.ML"
    17 ML_file "~~/src/Tools/quickcheck.ML"
    18 ML_file "~~/src/Tools/solve_direct.ML"
    19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
    20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
    21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
    22 ML_file "~~/src/Provers/hypsubst.ML"
    23 ML_file "~~/src/Provers/splitter.ML"
    24 ML_file "~~/src/Provers/classical.ML"
    25 ML_file "~~/src/Provers/blast.ML"
    26 ML_file "~~/src/Provers/clasimp.ML"
    27 ML_file "~~/src/Tools/eqsubst.ML"
    28 ML_file "~~/src/Provers/quantifier1.ML"
    29 ML_file "~~/src/Tools/atomize_elim.ML"
    30 ML_file "~~/src/Tools/cong_tac.ML"
    31 ML_file "~~/src/Tools/intuitionistic.ML" setup \<open>Intuitionistic.method_setup @{binding iprover}\<close>
    32 ML_file "~~/src/Tools/project_rule.ML"
    33 ML_file "~~/src/Tools/subtyping.ML"
    34 ML_file "~~/src/Tools/case_product.ML"
    35 
    36 
    37 ML \<open>Plugin_Name.declare_setup @{binding extraction}\<close>
    38 
    39 ML \<open>
    40   Plugin_Name.declare_setup @{binding quickcheck_random};
    41   Plugin_Name.declare_setup @{binding quickcheck_exhaustive};
    42   Plugin_Name.declare_setup @{binding quickcheck_bounded_forall};
    43   Plugin_Name.declare_setup @{binding quickcheck_full_exhaustive};
    44   Plugin_Name.declare_setup @{binding quickcheck_narrowing};
    45 \<close>
    46 ML \<open>
    47   Plugin_Name.define_setup @{binding quickcheck}
    48    [@{plugin quickcheck_exhaustive},
    49     @{plugin quickcheck_random},
    50     @{plugin quickcheck_bounded_forall},
    51     @{plugin quickcheck_full_exhaustive},
    52     @{plugin quickcheck_narrowing}]
    53 \<close>
    54 
    55 
    56 subsection \<open>Primitive logic\<close>
    57 
    58 subsubsection \<open>Core syntax\<close>
    59 
    60 setup \<open>Axclass.class_axiomatization (@{binding type}, [])\<close>
    61 default_sort type
    62 setup \<open>Object_Logic.add_base_sort @{sort type}\<close>
    63 
    64 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
    65 instance "fun" :: (type, type) type by (rule fun_arity)
    66 
    67 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
    68 instance itself :: (type) type by (rule itself_arity)
    69 
    70 typedecl bool
    71 
    72 judgment
    73   Trueprop      :: "bool \<Rightarrow> prop"                   ("(_)" 5)
    74 
    75 axiomatization
    76   implies       :: "[bool, bool] \<Rightarrow> bool"           (infixr "-->" 25)  and
    77   eq            :: "['a, 'a] \<Rightarrow> bool"               (infixl "=" 50)  and
    78   The           :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    79 
    80 consts
    81   True          :: bool
    82   False         :: bool
    83   Not           :: "bool \<Rightarrow> bool"                   ("~ _" [40] 40)
    84 
    85   conj          :: "[bool, bool] \<Rightarrow> bool"           (infixr "&" 35)
    86   disj          :: "[bool, bool] \<Rightarrow> bool"           (infixr "|" 30)
    87 
    88   All           :: "('a \<Rightarrow> bool) \<Rightarrow> bool"           (binder "ALL " 10)
    89   Ex            :: "('a \<Rightarrow> bool) \<Rightarrow> bool"           (binder "EX " 10)
    90   Ex1           :: "('a \<Rightarrow> bool) \<Rightarrow> bool"           (binder "EX! " 10)
    91 
    92 
    93 subsubsection \<open>Additional concrete syntax\<close>
    94 
    95 notation (output)
    96   eq  (infix "=" 50)
    97 
    98 abbreviation
    99   not_equal :: "['a, 'a] \<Rightarrow> bool"  (infixl "~=" 50) where
   100   "x ~= y \<equiv> ~ (x = y)"
   101 
   102 notation (output)
   103   not_equal  (infix "~=" 50)
   104 
   105 notation (xsymbols)
   106   Not  ("\<not> _" [40] 40) and
   107   conj  (infixr "\<and>" 35) and
   108   disj  (infixr "\<or>" 30) and
   109   implies  (infixr "\<longrightarrow>" 25) and
   110   not_equal  (infixl "\<noteq>" 50)
   111 
   112 notation (xsymbols output)
   113   not_equal  (infix "\<noteq>" 50)
   114 
   115 abbreviation (iff)
   116   iff :: "[bool, bool] \<Rightarrow> bool"  (infixr "<->" 25) where
   117   "A <-> B \<equiv> A = B"
   118 
   119 notation (xsymbols)
   120   iff  (infixr "\<longleftrightarrow>" 25)
   121 
   122 syntax "_The" :: "[pttrn, bool] \<Rightarrow> 'a"  ("(3THE _./ _)" [0, 10] 10)
   123 translations "THE x. P" \<rightleftharpoons> "CONST The (\<lambda>x. P)"
   124 print_translation \<open>
   125   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
   126       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   127       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   128 \<close>  \<comment> \<open>To avoid eta-contraction of body\<close>
   129 
   130 nonterminal letbinds and letbind
   131 syntax
   132   "_bind"       :: "[pttrn, 'a] \<Rightarrow> letbind"              ("(2_ =/ _)" 10)
   133   ""            :: "letbind \<Rightarrow> letbinds"                 ("_")
   134   "_binds"      :: "[letbind, letbinds] \<Rightarrow> letbinds"     ("_;/ _")
   135   "_Let"        :: "[letbinds, 'a] \<Rightarrow> 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   136 
   137 nonterminal case_syn and cases_syn
   138 syntax
   139   "_case_syntax" :: "['a, cases_syn] \<Rightarrow> 'b"  ("(case _ of/ _)" 10)
   140   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ =>/ _)" 10)
   141   "" :: "case_syn \<Rightarrow> cases_syn"  ("_")
   142   "_case2" :: "[case_syn, cases_syn] \<Rightarrow> cases_syn"  ("_/ | _")
   143 syntax (xsymbols)
   144   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   145 
   146 notation (xsymbols)
   147   All  (binder "\<forall>" 10) and
   148   Ex  (binder "\<exists>" 10) and
   149   Ex1  (binder "\<exists>!" 10)
   150 
   151 notation (HOL)
   152   All  (binder "! " 10) and
   153   Ex  (binder "? " 10) and
   154   Ex1  (binder "?! " 10)
   155 
   156 
   157 subsubsection \<open>Axioms and basic definitions\<close>
   158 
   159 axiomatization where
   160   refl: "t = (t::'a)" and
   161   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   162   ext: "(\<And>x::'a. (f x ::'b) = g x) \<Longrightarrow> (\<lambda>x. f x) = (\<lambda>x. g x)"
   163     \<comment> \<open>Extensionality is built into the meta-logic, and this rule expresses
   164          a related property.  It is an eta-expanded version of the traditional
   165          rule, and similar to the ABS rule of HOL\<close> and
   166 
   167   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   168 
   169 axiomatization where
   170   impI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<longrightarrow> Q" and
   171   mp: "\<lbrakk>P \<longrightarrow> Q; P\<rbrakk> \<Longrightarrow> Q" and
   172 
   173   iff: "(P \<longrightarrow> Q) \<longrightarrow> (Q \<longrightarrow> P) \<longrightarrow> (P = Q)" and
   174   True_or_False: "(P = True) \<or> (P = False)"
   175 
   176 defs
   177   True_def:     "True      \<equiv> ((\<lambda>x::bool. x) = (\<lambda>x. x))"
   178   All_def:      "All P     \<equiv> (P = (\<lambda>x. True))"
   179   Ex_def:       "Ex P      \<equiv> \<forall>Q. (\<forall>x. P x \<longrightarrow> Q) \<longrightarrow> Q"
   180   False_def:    "False     \<equiv> (\<forall>P. P)"
   181   not_def:      "\<not> P       \<equiv> P \<longrightarrow> False"
   182   and_def:      "P \<and> Q     \<equiv> \<forall>R. (P \<longrightarrow> Q \<longrightarrow> R) \<longrightarrow> R"
   183   or_def:       "P \<or> Q     \<equiv> \<forall>R. (P \<longrightarrow> R) \<longrightarrow> (Q \<longrightarrow> R) \<longrightarrow> R"
   184   Ex1_def:      "Ex1 P     \<equiv> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> y = x)"
   185 
   186 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   187   where "If P x y \<equiv> (THE z::'a. (P = True \<longrightarrow> z = x) \<and> (P = False \<longrightarrow> z = y))"
   188 
   189 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   190   where "Let s f \<equiv> f s"
   191 
   192 translations
   193   "_Let (_binds b bs) e"  \<rightleftharpoons> "_Let b (_Let bs e)"
   194   "let x = a in e"        \<rightleftharpoons> "CONST Let a (\<lambda>x. e)"
   195 
   196 axiomatization undefined :: 'a
   197 
   198 class default = fixes default :: 'a
   199 
   200 
   201 subsection \<open>Fundamental rules\<close>
   202 
   203 subsubsection \<open>Equality\<close>
   204 
   205 lemma sym: "s = t \<Longrightarrow> t = s"
   206   by (erule subst) (rule refl)
   207 
   208 lemma ssubst: "t = s \<Longrightarrow> P s \<Longrightarrow> P t"
   209   by (drule sym) (erule subst)
   210 
   211 lemma trans: "\<lbrakk>r = s; s = t\<rbrakk> \<Longrightarrow> r = t"
   212   by (erule subst)
   213 
   214 lemma trans_sym [Pure.elim?]: "r = s \<Longrightarrow> t = s \<Longrightarrow> r = t"
   215   by (rule trans [OF _ sym])
   216 
   217 lemma meta_eq_to_obj_eq:
   218   assumes meq: "A \<equiv> B"
   219   shows "A = B"
   220   by (unfold meq) (rule refl)
   221 
   222 text \<open>Useful with \<open>erule\<close> for proving equalities from known equalities.\<close>
   223      (* a = b
   224         |   |
   225         c = d   *)
   226 lemma box_equals: "\<lbrakk>a = b; a = c; b = d\<rbrakk> \<Longrightarrow> c = d"
   227 apply (rule trans)
   228 apply (rule trans)
   229 apply (rule sym)
   230 apply assumption+
   231 done
   232 
   233 text \<open>For calculational reasoning:\<close>
   234 
   235 lemma forw_subst: "a = b \<Longrightarrow> P b \<Longrightarrow> P a"
   236   by (rule ssubst)
   237 
   238 lemma back_subst: "P a \<Longrightarrow> a = b \<Longrightarrow> P b"
   239   by (rule subst)
   240 
   241 
   242 subsubsection \<open>Congruence rules for application\<close>
   243 
   244 text \<open>Similar to \<open>AP_THM\<close> in Gordon's HOL.\<close>
   245 lemma fun_cong: "(f :: 'a \<Rightarrow> 'b) = g \<Longrightarrow> f x = g x"
   246 apply (erule subst)
   247 apply (rule refl)
   248 done
   249 
   250 text \<open>Similar to \<open>AP_TERM\<close> in Gordon's HOL and FOL's \<open>subst_context\<close>.\<close>
   251 lemma arg_cong: "x = y \<Longrightarrow> f x = f y"
   252 apply (erule subst)
   253 apply (rule refl)
   254 done
   255 
   256 lemma arg_cong2: "\<lbrakk>a = b; c = d\<rbrakk> \<Longrightarrow> f a c = f b d"
   257 apply (erule ssubst)+
   258 apply (rule refl)
   259 done
   260 
   261 lemma cong: "\<lbrakk>f = g; (x::'a) = y\<rbrakk> \<Longrightarrow> f x = g y"
   262 apply (erule subst)+
   263 apply (rule refl)
   264 done
   265 
   266 ML \<open>fun cong_tac ctxt = Cong_Tac.cong_tac ctxt @{thm cong}\<close>
   267 
   268 
   269 subsubsection \<open>Equality of booleans -- iff\<close>
   270 
   271 lemma iffI: assumes "P \<Longrightarrow> Q" and "Q \<Longrightarrow> P" shows "P = Q"
   272   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   273 
   274 lemma iffD2: "\<lbrakk>P = Q; Q\<rbrakk> \<Longrightarrow> P"
   275   by (erule ssubst)
   276 
   277 lemma rev_iffD2: "\<lbrakk>Q; P = Q\<rbrakk> \<Longrightarrow> P"
   278   by (erule iffD2)
   279 
   280 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   281   by (drule sym) (rule iffD2)
   282 
   283 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   284   by (drule sym) (rule rev_iffD2)
   285 
   286 lemma iffE:
   287   assumes major: "P = Q"
   288     and minor: "\<lbrakk>P \<longrightarrow> Q; Q \<longrightarrow> P\<rbrakk> \<Longrightarrow> R"
   289   shows R
   290   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   291 
   292 
   293 subsubsection \<open>True\<close>
   294 
   295 lemma TrueI: "True"
   296   unfolding True_def by (rule refl)
   297 
   298 lemma eqTrueI: "P \<Longrightarrow> P = True"
   299   by (iprover intro: iffI TrueI)
   300 
   301 lemma eqTrueE: "P = True \<Longrightarrow> P"
   302   by (erule iffD2) (rule TrueI)
   303 
   304 
   305 subsubsection \<open>Universal quantifier\<close>
   306 
   307 lemma allI: assumes "\<And>x::'a. P x" shows "\<forall>x. P x"
   308   unfolding All_def by (iprover intro: ext eqTrueI assms)
   309 
   310 lemma spec: "\<forall>x::'a. P x \<Longrightarrow> P x"
   311 apply (unfold All_def)
   312 apply (rule eqTrueE)
   313 apply (erule fun_cong)
   314 done
   315 
   316 lemma allE:
   317   assumes major: "\<forall>x. P x"
   318     and minor: "P x \<Longrightarrow> R"
   319   shows R
   320   by (iprover intro: minor major [THEN spec])
   321 
   322 lemma all_dupE:
   323   assumes major: "\<forall>x. P x"
   324     and minor: "\<lbrakk>P x; \<forall>x. P x\<rbrakk> \<Longrightarrow> R"
   325   shows R
   326   by (iprover intro: minor major major [THEN spec])
   327 
   328 
   329 subsubsection \<open>False\<close>
   330 
   331 text \<open>
   332   Depends upon \<open>spec\<close>; it is impossible to do propositional
   333   logic before quantifiers!
   334 \<close>
   335 
   336 lemma FalseE: "False \<Longrightarrow> P"
   337   apply (unfold False_def)
   338   apply (erule spec)
   339   done
   340 
   341 lemma False_neq_True: "False = True \<Longrightarrow> P"
   342   by (erule eqTrueE [THEN FalseE])
   343 
   344 
   345 subsubsection \<open>Negation\<close>
   346 
   347 lemma notI:
   348   assumes "P \<Longrightarrow> False"
   349   shows "\<not> P"
   350   apply (unfold not_def)
   351   apply (iprover intro: impI assms)
   352   done
   353 
   354 lemma False_not_True: "False \<noteq> True"
   355   apply (rule notI)
   356   apply (erule False_neq_True)
   357   done
   358 
   359 lemma True_not_False: "True \<noteq> False"
   360   apply (rule notI)
   361   apply (drule sym)
   362   apply (erule False_neq_True)
   363   done
   364 
   365 lemma notE: "\<lbrakk>\<not> P; P\<rbrakk> \<Longrightarrow> R"
   366   apply (unfold not_def)
   367   apply (erule mp [THEN FalseE])
   368   apply assumption
   369   done
   370 
   371 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   372   by (erule notE [THEN notI]) (erule meta_mp)
   373 
   374 
   375 subsubsection \<open>Implication\<close>
   376 
   377 lemma impE:
   378   assumes "P \<longrightarrow> Q" P "Q \<Longrightarrow> R"
   379   shows R
   380 by (iprover intro: assms mp)
   381 
   382 (* Reduces Q to P \<longrightarrow> Q, allowing substitution in P. *)
   383 lemma rev_mp: "\<lbrakk>P; P \<longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   384 by (iprover intro: mp)
   385 
   386 lemma contrapos_nn:
   387   assumes major: "\<not> Q"
   388       and minor: "P \<Longrightarrow> Q"
   389   shows "\<not> P"
   390 by (iprover intro: notI minor major [THEN notE])
   391 
   392 (*not used at all, but we already have the other 3 combinations *)
   393 lemma contrapos_pn:
   394   assumes major: "Q"
   395       and minor: "P \<Longrightarrow> \<not> Q"
   396   shows "\<not> P"
   397 by (iprover intro: notI minor major notE)
   398 
   399 lemma not_sym: "t \<noteq> s \<Longrightarrow> s \<noteq> t"
   400   by (erule contrapos_nn) (erule sym)
   401 
   402 lemma eq_neq_eq_imp_neq: "\<lbrakk>x = a; a \<noteq> b; b = y\<rbrakk> \<Longrightarrow> x \<noteq> y"
   403   by (erule subst, erule ssubst, assumption)
   404 
   405 
   406 subsubsection \<open>Existential quantifier\<close>
   407 
   408 lemma exI: "P x \<Longrightarrow> \<exists>x::'a. P x"
   409 apply (unfold Ex_def)
   410 apply (iprover intro: allI allE impI mp)
   411 done
   412 
   413 lemma exE:
   414   assumes major: "\<exists>x::'a. P x"
   415       and minor: "\<And>x. P x \<Longrightarrow> Q"
   416   shows "Q"
   417 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   418 apply (iprover intro: impI [THEN allI] minor)
   419 done
   420 
   421 
   422 subsubsection \<open>Conjunction\<close>
   423 
   424 lemma conjI: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> P \<and> Q"
   425 apply (unfold and_def)
   426 apply (iprover intro: impI [THEN allI] mp)
   427 done
   428 
   429 lemma conjunct1: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> P"
   430 apply (unfold and_def)
   431 apply (iprover intro: impI dest: spec mp)
   432 done
   433 
   434 lemma conjunct2: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> Q"
   435 apply (unfold and_def)
   436 apply (iprover intro: impI dest: spec mp)
   437 done
   438 
   439 lemma conjE:
   440   assumes major: "P \<and> Q"
   441       and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R"
   442   shows R
   443 apply (rule minor)
   444 apply (rule major [THEN conjunct1])
   445 apply (rule major [THEN conjunct2])
   446 done
   447 
   448 lemma context_conjI:
   449   assumes P "P \<Longrightarrow> Q" shows "P \<and> Q"
   450 by (iprover intro: conjI assms)
   451 
   452 
   453 subsubsection \<open>Disjunction\<close>
   454 
   455 lemma disjI1: "P \<Longrightarrow> P \<or> Q"
   456 apply (unfold or_def)
   457 apply (iprover intro: allI impI mp)
   458 done
   459 
   460 lemma disjI2: "Q \<Longrightarrow> P \<or> Q"
   461 apply (unfold or_def)
   462 apply (iprover intro: allI impI mp)
   463 done
   464 
   465 lemma disjE:
   466   assumes major: "P \<or> Q"
   467       and minorP: "P \<Longrightarrow> R"
   468       and minorQ: "Q \<Longrightarrow> R"
   469   shows R
   470 by (iprover intro: minorP minorQ impI
   471                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   472 
   473 
   474 subsubsection \<open>Classical logic\<close>
   475 
   476 lemma classical:
   477   assumes prem: "\<not> P \<Longrightarrow> P"
   478   shows P
   479 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   480 apply assumption
   481 apply (rule notI [THEN prem, THEN eqTrueI])
   482 apply (erule subst)
   483 apply assumption
   484 done
   485 
   486 lemmas ccontr = FalseE [THEN classical]
   487 
   488 (*notE with premises exchanged; it discharges \<not> R so that it can be used to
   489   make elimination rules*)
   490 lemma rev_notE:
   491   assumes premp: P
   492       and premnot: "\<not> R \<Longrightarrow> \<not> P"
   493   shows R
   494 apply (rule ccontr)
   495 apply (erule notE [OF premnot premp])
   496 done
   497 
   498 (*Double negation law*)
   499 lemma notnotD: "\<not>\<not> P \<Longrightarrow> P"
   500 apply (rule classical)
   501 apply (erule notE)
   502 apply assumption
   503 done
   504 
   505 lemma contrapos_pp:
   506   assumes p1: Q
   507       and p2: "\<not> P \<Longrightarrow> \<not> Q"
   508   shows P
   509 by (iprover intro: classical p1 p2 notE)
   510 
   511 
   512 subsubsection \<open>Unique existence\<close>
   513 
   514 lemma ex1I:
   515   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a"
   516   shows "\<exists>!x. P x"
   517 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   518 
   519 text\<open>Sometimes easier to use: the premises have no shared variables.  Safe!\<close>
   520 lemma ex_ex1I:
   521   assumes ex_prem: "\<exists>x. P x"
   522       and eq: "\<And>x y. \<lbrakk>P x; P y\<rbrakk> \<Longrightarrow> x = y"
   523   shows "\<exists>!x. P x"
   524 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   525 
   526 lemma ex1E:
   527   assumes major: "\<exists>!x. P x"
   528       and minor: "\<And>x. \<lbrakk>P x; \<forall>y. P y \<longrightarrow> y = x\<rbrakk> \<Longrightarrow> R"
   529   shows R
   530 apply (rule major [unfolded Ex1_def, THEN exE])
   531 apply (erule conjE)
   532 apply (iprover intro: minor)
   533 done
   534 
   535 lemma ex1_implies_ex: "\<exists>!x. P x \<Longrightarrow> \<exists>x. P x"
   536 apply (erule ex1E)
   537 apply (rule exI)
   538 apply assumption
   539 done
   540 
   541 
   542 subsubsection \<open>Classical intro rules for disjunction and existential quantifiers\<close>
   543 
   544 lemma disjCI:
   545   assumes "\<not> Q \<Longrightarrow> P" shows "P \<or> Q"
   546 apply (rule classical)
   547 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   548 done
   549 
   550 lemma excluded_middle: "\<not> P \<or> P"
   551 by (iprover intro: disjCI)
   552 
   553 text \<open>
   554   case distinction as a natural deduction rule.
   555   Note that @{term "\<not> P"} is the second case, not the first
   556 \<close>
   557 lemma case_split [case_names True False]:
   558   assumes prem1: "P \<Longrightarrow> Q"
   559       and prem2: "\<not> P \<Longrightarrow> Q"
   560   shows Q
   561 apply (rule excluded_middle [THEN disjE])
   562 apply (erule prem2)
   563 apply (erule prem1)
   564 done
   565 
   566 (*Classical implies (\<longrightarrow>) elimination. *)
   567 lemma impCE:
   568   assumes major: "P \<longrightarrow> Q"
   569       and minor: "\<not> P \<Longrightarrow> R" "Q \<Longrightarrow> R"
   570   shows R
   571 apply (rule excluded_middle [of P, THEN disjE])
   572 apply (iprover intro: minor major [THEN mp])+
   573 done
   574 
   575 (*This version of \<longrightarrow> elimination works on Q before P.  It works best for
   576   those cases in which P holds "almost everywhere".  Can't install as
   577   default: would break old proofs.*)
   578 lemma impCE':
   579   assumes major: "P \<longrightarrow> Q"
   580       and minor: "Q \<Longrightarrow> R" "\<not> P \<Longrightarrow> R"
   581   shows R
   582 apply (rule excluded_middle [of P, THEN disjE])
   583 apply (iprover intro: minor major [THEN mp])+
   584 done
   585 
   586 (*Classical <-> elimination. *)
   587 lemma iffCE:
   588   assumes major: "P = Q"
   589       and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R" "\<lbrakk>\<not> P; \<not> Q\<rbrakk> \<Longrightarrow> R"
   590   shows R
   591 apply (rule major [THEN iffE])
   592 apply (iprover intro: minor elim: impCE notE)
   593 done
   594 
   595 lemma exCI:
   596   assumes "\<forall>x. \<not> P x \<Longrightarrow> P a"
   597   shows "\<exists>x. P x"
   598 apply (rule ccontr)
   599 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   600 done
   601 
   602 
   603 subsubsection \<open>Intuitionistic Reasoning\<close>
   604 
   605 lemma impE':
   606   assumes 1: "P \<longrightarrow> Q"
   607     and 2: "Q \<Longrightarrow> R"
   608     and 3: "P \<longrightarrow> Q \<Longrightarrow> P"
   609   shows R
   610 proof -
   611   from 3 and 1 have P .
   612   with 1 have Q by (rule impE)
   613   with 2 show R .
   614 qed
   615 
   616 lemma allE':
   617   assumes 1: "\<forall>x. P x"
   618     and 2: "P x \<Longrightarrow> \<forall>x. P x \<Longrightarrow> Q"
   619   shows Q
   620 proof -
   621   from 1 have "P x" by (rule spec)
   622   from this and 1 show Q by (rule 2)
   623 qed
   624 
   625 lemma notE':
   626   assumes 1: "\<not> P"
   627     and 2: "\<not> P \<Longrightarrow> P"
   628   shows R
   629 proof -
   630   from 2 and 1 have P .
   631   with 1 show R by (rule notE)
   632 qed
   633 
   634 lemma TrueE: "True \<Longrightarrow> P \<Longrightarrow> P" .
   635 lemma notFalseE: "\<not> False \<Longrightarrow> P \<Longrightarrow> P" .
   636 
   637 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   638   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   639   and [Pure.elim 2] = allE notE' impE'
   640   and [Pure.intro] = exI disjI2 disjI1
   641 
   642 lemmas [trans] = trans
   643   and [sym] = sym not_sym
   644   and [Pure.elim?] = iffD1 iffD2 impE
   645 
   646 
   647 subsubsection \<open>Atomizing meta-level connectives\<close>
   648 
   649 axiomatization where
   650   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   651 
   652 lemma atomize_all [atomize]: "(\<And>x. P x) \<equiv> Trueprop (\<forall>x. P x)"
   653 proof
   654   assume "\<And>x. P x"
   655   then show "\<forall>x. P x" ..
   656 next
   657   assume "\<forall>x. P x"
   658   then show "\<And>x. P x" by (rule allE)
   659 qed
   660 
   661 lemma atomize_imp [atomize]: "(A \<Longrightarrow> B) \<equiv> Trueprop (A \<longrightarrow> B)"
   662 proof
   663   assume r: "A \<Longrightarrow> B"
   664   show "A \<longrightarrow> B" by (rule impI) (rule r)
   665 next
   666   assume "A \<longrightarrow> B" and A
   667   then show B by (rule mp)
   668 qed
   669 
   670 lemma atomize_not: "(A \<Longrightarrow> False) \<equiv> Trueprop (\<not> A)"
   671 proof
   672   assume r: "A \<Longrightarrow> False"
   673   show "\<not> A" by (rule notI) (rule r)
   674 next
   675   assume "\<not> A" and A
   676   then show False by (rule notE)
   677 qed
   678 
   679 lemma atomize_eq [atomize, code]: "(x \<equiv> y) \<equiv> Trueprop (x = y)"
   680 proof
   681   assume "x \<equiv> y"
   682   show "x = y" by (unfold \<open>x \<equiv> y\<close>) (rule refl)
   683 next
   684   assume "x = y"
   685   then show "x \<equiv> y" by (rule eq_reflection)
   686 qed
   687 
   688 lemma atomize_conj [atomize]: "(A &&& B) \<equiv> Trueprop (A \<and> B)"
   689 proof
   690   assume conj: "A &&& B"
   691   show "A \<and> B"
   692   proof (rule conjI)
   693     from conj show A by (rule conjunctionD1)
   694     from conj show B by (rule conjunctionD2)
   695   qed
   696 next
   697   assume conj: "A \<and> B"
   698   show "A &&& B"
   699   proof -
   700     from conj show A ..
   701     from conj show B ..
   702   qed
   703 qed
   704 
   705 lemmas [symmetric, rulify] = atomize_all atomize_imp
   706   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   707 
   708 
   709 subsubsection \<open>Atomizing elimination rules\<close>
   710 
   711 lemma atomize_exL[atomize_elim]: "(\<And>x. P x \<Longrightarrow> Q) \<equiv> ((\<exists>x. P x) \<Longrightarrow> Q)"
   712   by rule iprover+
   713 
   714 lemma atomize_conjL[atomize_elim]: "(A \<Longrightarrow> B \<Longrightarrow> C) \<equiv> (A \<and> B \<Longrightarrow> C)"
   715   by rule iprover+
   716 
   717 lemma atomize_disjL[atomize_elim]: "((A \<Longrightarrow> C) \<Longrightarrow> (B \<Longrightarrow> C) \<Longrightarrow> C) \<equiv> ((A \<or> B \<Longrightarrow> C) \<Longrightarrow> C)"
   718   by rule iprover+
   719 
   720 lemma atomize_elimL[atomize_elim]: "(\<And>B. (A \<Longrightarrow> B) \<Longrightarrow> B) \<equiv> Trueprop A" ..
   721 
   722 
   723 subsection \<open>Package setup\<close>
   724 
   725 ML_file "Tools/hologic.ML"
   726 
   727 
   728 subsubsection \<open>Sledgehammer setup\<close>
   729 
   730 text \<open>
   731 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   732 that are prolific (match too many equality or membership literals) and relate to
   733 seldom-used facts. Some duplicate other rules.
   734 \<close>
   735 
   736 named_theorems no_atp "theorems that should be filtered out by Sledgehammer"
   737 
   738 
   739 subsubsection \<open>Classical Reasoner setup\<close>
   740 
   741 lemma imp_elim: "P \<longrightarrow> Q \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   742   by (rule classical) iprover
   743 
   744 lemma swap: "\<not> P \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> R"
   745   by (rule classical) iprover
   746 
   747 lemma thin_refl: "\<And>X. \<lbrakk>x = x; PROP W\<rbrakk> \<Longrightarrow> PROP W" .
   748 
   749 ML \<open>
   750 structure Hypsubst = Hypsubst
   751 (
   752   val dest_eq = HOLogic.dest_eq
   753   val dest_Trueprop = HOLogic.dest_Trueprop
   754   val dest_imp = HOLogic.dest_imp
   755   val eq_reflection = @{thm eq_reflection}
   756   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   757   val imp_intr = @{thm impI}
   758   val rev_mp = @{thm rev_mp}
   759   val subst = @{thm subst}
   760   val sym = @{thm sym}
   761   val thin_refl = @{thm thin_refl};
   762 );
   763 open Hypsubst;
   764 
   765 structure Classical = Classical
   766 (
   767   val imp_elim = @{thm imp_elim}
   768   val not_elim = @{thm notE}
   769   val swap = @{thm swap}
   770   val classical = @{thm classical}
   771   val sizef = Drule.size_of_thm
   772   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   773 );
   774 
   775 structure Basic_Classical: BASIC_CLASSICAL = Classical;
   776 open Basic_Classical;
   777 \<close>
   778 
   779 setup \<open>
   780   (*prevent substitution on bool*)
   781   let
   782     fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   783       | non_bool_eq _ = false;
   784     fun hyp_subst_tac' ctxt =
   785       SUBGOAL (fn (goal, i) =>
   786         if Term.exists_Const non_bool_eq goal
   787         then Hypsubst.hyp_subst_tac ctxt i
   788         else no_tac);
   789   in
   790     Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
   791   end
   792 \<close>
   793 
   794 declare iffI [intro!]
   795   and notI [intro!]
   796   and impI [intro!]
   797   and disjCI [intro!]
   798   and conjI [intro!]
   799   and TrueI [intro!]
   800   and refl [intro!]
   801 
   802 declare iffCE [elim!]
   803   and FalseE [elim!]
   804   and impCE [elim!]
   805   and disjE [elim!]
   806   and conjE [elim!]
   807 
   808 declare ex_ex1I [intro!]
   809   and allI [intro!]
   810   and exI [intro]
   811 
   812 declare exE [elim!]
   813   allE [elim]
   814 
   815 ML \<open>val HOL_cs = claset_of @{context}\<close>
   816 
   817 lemma contrapos_np: "\<not> Q \<Longrightarrow> (\<not> P \<Longrightarrow> Q) \<Longrightarrow> P"
   818   apply (erule swap)
   819   apply (erule (1) meta_mp)
   820   done
   821 
   822 declare ex_ex1I [rule del, intro! 2]
   823   and ex1I [intro]
   824 
   825 declare ext [intro]
   826 
   827 lemmas [intro?] = ext
   828   and [elim?] = ex1_implies_ex
   829 
   830 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   831 lemma alt_ex1E [elim!]:
   832   assumes major: "\<exists>!x. P x"
   833       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   834   shows R
   835 apply (rule ex1E [OF major])
   836 apply (rule prem)
   837 apply assumption
   838 apply (rule allI)+
   839 apply (tactic \<open>eresolve_tac @{context} [Classical.dup_elim @{context} @{thm allE}] 1\<close>)
   840 apply iprover
   841 done
   842 
   843 ML \<open>
   844   structure Blast = Blast
   845   (
   846     structure Classical = Classical
   847     val Trueprop_const = dest_Const @{const Trueprop}
   848     val equality_name = @{const_name HOL.eq}
   849     val not_name = @{const_name Not}
   850     val notE = @{thm notE}
   851     val ccontr = @{thm ccontr}
   852     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   853   );
   854   val blast_tac = Blast.blast_tac;
   855 \<close>
   856 
   857 
   858 subsubsection \<open>THE: definite description operator\<close>
   859 
   860 lemma the_equality [intro]:
   861   assumes "P a"
   862       and "\<And>x. P x \<Longrightarrow> x = a"
   863   shows "(THE x. P x) = a"
   864   by (blast intro: assms trans [OF arg_cong [where f=The] the_eq_trivial])
   865 
   866 lemma theI:
   867   assumes "P a" and "\<And>x. P x \<Longrightarrow> x = a"
   868   shows "P (THE x. P x)"
   869 by (iprover intro: assms the_equality [THEN ssubst])
   870 
   871 lemma theI': "\<exists>!x. P x \<Longrightarrow> P (THE x. P x)"
   872   by (blast intro: theI)
   873 
   874 (*Easier to apply than theI: only one occurrence of P*)
   875 lemma theI2:
   876   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a" "\<And>x. P x \<Longrightarrow> Q x"
   877   shows "Q (THE x. P x)"
   878 by (iprover intro: assms theI)
   879 
   880 lemma the1I2: assumes "\<exists>!x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   881 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   882            elim:allE impE)
   883 
   884 lemma the1_equality [elim?]: "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> (THE x. P x) = a"
   885   by blast
   886 
   887 lemma the_sym_eq_trivial: "(THE y. x = y) = x"
   888   by blast
   889 
   890 
   891 subsubsection \<open>Simplifier\<close>
   892 
   893 lemma eta_contract_eq: "(\<lambda>s. f s) = f" ..
   894 
   895 lemma simp_thms:
   896   shows not_not: "(\<not> \<not> P) = P"
   897   and Not_eq_iff: "((\<not> P) = (\<not> Q)) = (P = Q)"
   898   and
   899     "(P \<noteq> Q) = (P = (\<not> Q))"
   900     "(P \<or> \<not>P) = True"    "(\<not> P \<or> P) = True"
   901     "(x = x) = True"
   902   and not_True_eq_False [code]: "(\<not> True) = False"
   903   and not_False_eq_True [code]: "(\<not> False) = True"
   904   and
   905     "(\<not> P) \<noteq> P"  "P \<noteq> (\<not> P)"
   906     "(True = P) = P"
   907   and eq_True: "(P = True) = P"
   908   and "(False = P) = (\<not> P)"
   909   and eq_False: "(P = False) = (\<not> P)"
   910   and
   911     "(True \<longrightarrow> P) = P"  "(False \<longrightarrow> P) = True"
   912     "(P \<longrightarrow> True) = True"  "(P \<longrightarrow> P) = True"
   913     "(P \<longrightarrow> False) = (\<not> P)"  "(P \<longrightarrow> \<not> P) = (\<not> P)"
   914     "(P \<and> True) = P"  "(True \<and> P) = P"
   915     "(P \<and> False) = False"  "(False \<and> P) = False"
   916     "(P \<and> P) = P"  "(P \<and> (P \<and> Q)) = (P \<and> Q)"
   917     "(P \<and> \<not> P) = False"    "(\<not> P \<and> P) = False"
   918     "(P \<or> True) = True"  "(True \<or> P) = True"
   919     "(P \<or> False) = P"  "(False \<or> P) = P"
   920     "(P \<or> P) = P"  "(P \<or> (P \<or> Q)) = (P \<or> Q)" and
   921     "(\<forall>x. P) = P"  "(\<exists>x. P) = P"  "\<exists>x. x = t"  "\<exists>x. t = x"
   922   and
   923     "\<And>P. (\<exists>x. x = t \<and> P x) = P t"
   924     "\<And>P. (\<exists>x. t = x \<and> P x) = P t"
   925     "\<And>P. (\<forall>x. x = t \<longrightarrow> P x) = P t"
   926     "\<And>P. (\<forall>x. t = x \<longrightarrow> P x) = P t"
   927   by (blast, blast, blast, blast, blast, iprover+)
   928 
   929 lemma disj_absorb: "(A \<or> A) = A"
   930   by blast
   931 
   932 lemma disj_left_absorb: "(A \<or> (A \<or> B)) = (A \<or> B)"
   933   by blast
   934 
   935 lemma conj_absorb: "(A \<and> A) = A"
   936   by blast
   937 
   938 lemma conj_left_absorb: "(A \<and> (A \<and> B)) = (A \<and> B)"
   939   by blast
   940 
   941 lemma eq_ac:
   942   shows eq_commute: "a = b \<longleftrightarrow> b = a"
   943     and iff_left_commute: "(P \<longleftrightarrow> (Q \<longleftrightarrow> R)) \<longleftrightarrow> (Q \<longleftrightarrow> (P \<longleftrightarrow> R))"
   944     and iff_assoc: "((P \<longleftrightarrow> Q) \<longleftrightarrow> R) \<longleftrightarrow> (P \<longleftrightarrow> (Q \<longleftrightarrow> R))" by (iprover, blast+)
   945 lemma neq_commute: "a \<noteq> b \<longleftrightarrow> b \<noteq> a" by iprover
   946 
   947 lemma conj_comms:
   948   shows conj_commute: "(P \<and> Q) = (Q \<and> P)"
   949     and conj_left_commute: "(P \<and> (Q \<and> R)) = (Q \<and> (P \<and> R))" by iprover+
   950 lemma conj_assoc: "((P \<and> Q) \<and> R) = (P \<and> (Q \<and> R))" by iprover
   951 
   952 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   953 
   954 lemma disj_comms:
   955   shows disj_commute: "(P \<or> Q) = (Q \<or> P)"
   956     and disj_left_commute: "(P \<or> (Q \<or> R)) = (Q \<or> (P \<or> R))" by iprover+
   957 lemma disj_assoc: "((P \<or> Q) \<or> R) = (P \<or> (Q \<or> R))" by iprover
   958 
   959 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   960 
   961 lemma conj_disj_distribL: "(P \<and> (Q \<or> R)) = (P \<and> Q \<or> P \<and> R)" by iprover
   962 lemma conj_disj_distribR: "((P \<or> Q) \<and> R) = (P \<and> R \<or> Q \<and> R)" by iprover
   963 
   964 lemma disj_conj_distribL: "(P \<or> (Q \<and> R)) = ((P \<or> Q) \<and> (P \<or> R))" by iprover
   965 lemma disj_conj_distribR: "((P \<and> Q) \<or> R) = ((P \<or> R) \<and> (Q \<or> R))" by iprover
   966 
   967 lemma imp_conjR: "(P \<longrightarrow> (Q \<and> R)) = ((P \<longrightarrow> Q) \<and> (P \<longrightarrow> R))" by iprover
   968 lemma imp_conjL: "((P \<and> Q) \<longrightarrow> R) = (P \<longrightarrow> (Q \<longrightarrow> R))" by iprover
   969 lemma imp_disjL: "((P \<or> Q) \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" by iprover
   970 
   971 text \<open>These two are specialized, but \<open>imp_disj_not1\<close> is useful in \<open>Auth/Yahalom\<close>.\<close>
   972 lemma imp_disj_not1: "(P \<longrightarrow> Q \<or> R) = (\<not> Q \<longrightarrow> P \<longrightarrow> R)" by blast
   973 lemma imp_disj_not2: "(P \<longrightarrow> Q \<or> R) = (\<not> R \<longrightarrow> P \<longrightarrow> Q)" by blast
   974 
   975 lemma imp_disj1: "((P \<longrightarrow> Q) \<or> R) = (P \<longrightarrow> Q \<or> R)" by blast
   976 lemma imp_disj2: "(Q \<or> (P \<longrightarrow> R)) = (P \<longrightarrow> Q \<or> R)" by blast
   977 
   978 lemma imp_cong: "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<longrightarrow> Q) = (P' \<longrightarrow> Q'))"
   979   by iprover
   980 
   981 lemma de_Morgan_disj: "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not> Q)" by iprover
   982 lemma de_Morgan_conj: "(\<not> (P \<and> Q)) = (\<not> P \<or> \<not> Q)" by blast
   983 lemma not_imp: "(\<not> (P \<longrightarrow> Q)) = (P \<and> \<not> Q)" by blast
   984 lemma not_iff: "(P \<noteq> Q) = (P = (\<not> Q))" by blast
   985 lemma disj_not1: "(\<not> P \<or> Q) = (P \<longrightarrow> Q)" by blast
   986 lemma disj_not2: "(P \<or> \<not> Q) = (Q \<longrightarrow> P)"  \<comment> \<open>changes orientation :-(\<close>
   987   by blast
   988 lemma imp_conv_disj: "(P \<longrightarrow> Q) = ((\<not> P) \<or> Q)" by blast
   989 
   990 lemma iff_conv_conj_imp: "(P = Q) = ((P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P))" by iprover
   991 
   992 
   993 lemma cases_simp: "((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> Q)) = Q"
   994   \<comment> \<open>Avoids duplication of subgoals after \<open>split_if\<close>, when the true and false\<close>
   995   \<comment> \<open>cases boil down to the same thing.\<close>
   996   by blast
   997 
   998 lemma not_all: "(\<not> (\<forall>x. P x)) = (\<exists>x. \<not> P x)" by blast
   999 lemma imp_all: "((\<forall>x. P x) \<longrightarrow> Q) = (\<exists>x. P x \<longrightarrow> Q)" by blast
  1000 lemma not_ex: "(\<not> (\<exists>x. P x)) = (\<forall>x. \<not> P x)" by iprover
  1001 lemma imp_ex: "((\<exists>x. P x) \<longrightarrow> Q) = (\<forall>x. P x \<longrightarrow> Q)" by iprover
  1002 lemma all_not_ex: "(\<forall>x. P x) = (\<not> (\<exists>x. \<not> P x ))" by blast
  1003 
  1004 declare All_def [no_atp]
  1005 
  1006 lemma ex_disj_distrib: "(\<exists>x. P x \<or> Q x) = ((\<exists>x. P x) \<or> (\<exists>x. Q x))" by iprover
  1007 lemma all_conj_distrib: "(\<forall>x. P x \<and> Q x) = ((\<forall>x. P x) \<and> (\<forall>x. Q x))" by iprover
  1008 
  1009 text \<open>
  1010   \medskip The \<open>\<and>\<close> congruence rule: not included by default!
  1011   May slow rewrite proofs down by as much as 50\%\<close>
  1012 
  1013 lemma conj_cong:
  1014     "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<and> Q) = (P' \<and> Q'))"
  1015   by iprover
  1016 
  1017 lemma rev_conj_cong:
  1018     "(Q = Q') \<Longrightarrow> (Q' \<Longrightarrow> (P = P')) \<Longrightarrow> ((P \<and> Q) = (P' \<and> Q'))"
  1019   by iprover
  1020 
  1021 text \<open>The \<open>|\<close> congruence rule: not included by default!\<close>
  1022 
  1023 lemma disj_cong:
  1024     "(P = P') \<Longrightarrow> (\<not> P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<or> Q) = (P' \<or> Q'))"
  1025   by blast
  1026 
  1027 
  1028 text \<open>\medskip if-then-else rules\<close>
  1029 
  1030 lemma if_True [code]: "(if True then x else y) = x"
  1031   by (unfold If_def) blast
  1032 
  1033 lemma if_False [code]: "(if False then x else y) = y"
  1034   by (unfold If_def) blast
  1035 
  1036 lemma if_P: "P \<Longrightarrow> (if P then x else y) = x"
  1037   by (unfold If_def) blast
  1038 
  1039 lemma if_not_P: "\<not> P \<Longrightarrow> (if P then x else y) = y"
  1040   by (unfold If_def) blast
  1041 
  1042 lemma split_if: "P (if Q then x else y) = ((Q \<longrightarrow> P x) \<and> (\<not> Q \<longrightarrow> P y))"
  1043   apply (rule case_split [of Q])
  1044    apply (simplesubst if_P)
  1045     prefer 3 apply (simplesubst if_not_P, blast+)
  1046   done
  1047 
  1048 lemma split_if_asm: "P (if Q then x else y) = (\<not> ((Q \<and> \<not> P x) \<or> (\<not> Q \<and> \<not> P y)))"
  1049 by (simplesubst split_if, blast)
  1050 
  1051 lemmas if_splits [no_atp] = split_if split_if_asm
  1052 
  1053 lemma if_cancel: "(if c then x else x) = x"
  1054 by (simplesubst split_if, blast)
  1055 
  1056 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1057 by (simplesubst split_if, blast)
  1058 
  1059 lemma if_bool_eq_conj: "(if P then Q else R) = ((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R))"
  1060   \<comment> \<open>This form is useful for expanding \<open>if\<close>s on the RIGHT of the \<open>\<Longrightarrow>\<close> symbol.\<close>
  1061   by (rule split_if)
  1062 
  1063 lemma if_bool_eq_disj: "(if P then Q else R) = ((P \<and> Q) \<or> (\<not> P \<and> R))"
  1064   \<comment> \<open>And this form is useful for expanding \<open>if\<close>s on the LEFT.\<close>
  1065   by (simplesubst split_if) blast
  1066 
  1067 lemma Eq_TrueI: "P \<Longrightarrow> P \<equiv> True" by (unfold atomize_eq) iprover
  1068 lemma Eq_FalseI: "\<not> P \<Longrightarrow> P \<equiv> False" by (unfold atomize_eq) iprover
  1069 
  1070 text \<open>\medskip let rules for simproc\<close>
  1071 
  1072 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow> Let x f \<equiv> Let x g"
  1073   by (unfold Let_def)
  1074 
  1075 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow> Let x f \<equiv> g"
  1076   by (unfold Let_def)
  1077 
  1078 text \<open>
  1079   The following copy of the implication operator is useful for
  1080   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1081   its premise.
  1082 \<close>
  1083 
  1084 definition simp_implies :: "[prop, prop] \<Rightarrow> prop"  (infixr "=simp=>" 1) where
  1085   "simp_implies \<equiv> op \<Longrightarrow>"
  1086 
  1087 lemma simp_impliesI:
  1088   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1089   shows "PROP P =simp=> PROP Q"
  1090   apply (unfold simp_implies_def)
  1091   apply (rule PQ)
  1092   apply assumption
  1093   done
  1094 
  1095 lemma simp_impliesE:
  1096   assumes PQ: "PROP P =simp=> PROP Q"
  1097   and P: "PROP P"
  1098   and QR: "PROP Q \<Longrightarrow> PROP R"
  1099   shows "PROP R"
  1100   apply (rule QR)
  1101   apply (rule PQ [unfolded simp_implies_def])
  1102   apply (rule P)
  1103   done
  1104 
  1105 lemma simp_implies_cong:
  1106   assumes PP' :"PROP P \<equiv> PROP P'"
  1107   and P'QQ': "PROP P' \<Longrightarrow> (PROP Q \<equiv> PROP Q')"
  1108   shows "(PROP P =simp=> PROP Q) \<equiv> (PROP P' =simp=> PROP Q')"
  1109 proof (unfold simp_implies_def, rule equal_intr_rule)
  1110   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1111   and P': "PROP P'"
  1112   from PP' [symmetric] and P' have "PROP P"
  1113     by (rule equal_elim_rule1)
  1114   then have "PROP Q" by (rule PQ)
  1115   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1116 next
  1117   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1118   and P: "PROP P"
  1119   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1120   then have "PROP Q'" by (rule P'Q')
  1121   with P'QQ' [OF P', symmetric] show "PROP Q"
  1122     by (rule equal_elim_rule1)
  1123 qed
  1124 
  1125 lemma uncurry:
  1126   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1127   shows "P \<and> Q \<longrightarrow> R"
  1128   using assms by blast
  1129 
  1130 lemma iff_allI:
  1131   assumes "\<And>x. P x = Q x"
  1132   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1133   using assms by blast
  1134 
  1135 lemma iff_exI:
  1136   assumes "\<And>x. P x = Q x"
  1137   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1138   using assms by blast
  1139 
  1140 lemma all_comm:
  1141   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1142   by blast
  1143 
  1144 lemma ex_comm:
  1145   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1146   by blast
  1147 
  1148 ML_file "Tools/simpdata.ML"
  1149 ML \<open>open Simpdata\<close>
  1150 
  1151 setup \<open>
  1152   map_theory_simpset (put_simpset HOL_basic_ss) #>
  1153   Simplifier.method_setup Splitter.split_modifiers
  1154 \<close>
  1155 
  1156 simproc_setup defined_Ex ("\<exists>x. P x") = \<open>fn _ => Quantifier1.rearrange_ex\<close>
  1157 simproc_setup defined_All ("\<forall>x. P x") = \<open>fn _ => Quantifier1.rearrange_all\<close>
  1158 
  1159 text \<open>Simproc for proving \<open>(y = x) \<equiv> False\<close> from premise \<open>\<not> (x = y)\<close>:\<close>
  1160 
  1161 simproc_setup neq ("x = y") = \<open>fn _ =>
  1162 let
  1163   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1164   fun is_neq eq lhs rhs thm =
  1165     (case Thm.prop_of thm of
  1166       _ $ (Not $ (eq' $ l' $ r')) =>
  1167         Not = HOLogic.Not andalso eq' = eq andalso
  1168         r' aconv lhs andalso l' aconv rhs
  1169     | _ => false);
  1170   fun proc ss ct =
  1171     (case Thm.term_of ct of
  1172       eq $ lhs $ rhs =>
  1173         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1174           SOME thm => SOME (thm RS neq_to_EQ_False)
  1175         | NONE => NONE)
  1176      | _ => NONE);
  1177 in proc end;
  1178 \<close>
  1179 
  1180 simproc_setup let_simp ("Let x f") = \<open>
  1181 let
  1182   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1183     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1184     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1185     | count_loose _ _ = 0;
  1186   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1187     (case t of
  1188       Abs (_, _, t') => count_loose t' 0 <= 1
  1189     | _ => true);
  1190 in
  1191   fn _ => fn ctxt => fn ct =>
  1192     if is_trivial_let (Thm.term_of ct)
  1193     then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1194     else
  1195       let (*Norbert Schirmer's case*)
  1196         val t = Thm.term_of ct;
  1197         val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1198       in
  1199         Option.map (hd o Variable.export ctxt' ctxt o single)
  1200           (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1201             if is_Free x orelse is_Bound x orelse is_Const x
  1202             then SOME @{thm Let_def}
  1203             else
  1204               let
  1205                 val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1206                 val cx = Thm.cterm_of ctxt x;
  1207                 val xT = Thm.typ_of_cterm cx;
  1208                 val cf = Thm.cterm_of ctxt f;
  1209                 val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
  1210                 val (_ $ _ $ g) = Thm.prop_of fx_g;
  1211                 val g' = abstract_over (x, g);
  1212                 val abs_g'= Abs (n, xT, g');
  1213               in
  1214                 if g aconv g' then
  1215                   let
  1216                     val rl =
  1217                       infer_instantiate ctxt [(("f", 0), cf), (("x", 0), cx)] @{thm Let_unfold};
  1218                   in SOME (rl OF [fx_g]) end
  1219                 else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g')
  1220                 then NONE (*avoid identity conversion*)
  1221                 else
  1222                   let
  1223                     val g'x = abs_g' $ x;
  1224                     val g_g'x = Thm.symmetric (Thm.beta_conversion false (Thm.cterm_of ctxt g'x));
  1225                     val rl =
  1226                       @{thm Let_folded} |> infer_instantiate ctxt
  1227                         [(("f", 0), Thm.cterm_of ctxt f),
  1228                          (("x", 0), cx),
  1229                          (("g", 0), Thm.cterm_of ctxt abs_g')];
  1230                   in SOME (rl OF [Thm.transitive fx_g g_g'x]) end
  1231               end
  1232           | _ => NONE)
  1233       end
  1234 end\<close>
  1235 
  1236 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1237 proof
  1238   assume "True \<Longrightarrow> PROP P"
  1239   from this [OF TrueI] show "PROP P" .
  1240 next
  1241   assume "PROP P"
  1242   then show "PROP P" .
  1243 qed
  1244 
  1245 lemma implies_True_equals: "(PROP P \<Longrightarrow> True) \<equiv> Trueprop True"
  1246   by standard (intro TrueI)
  1247 
  1248 lemma False_implies_equals: "(False \<Longrightarrow> P) \<equiv> Trueprop True"
  1249   by standard simp_all
  1250 
  1251 (* This is not made a simp rule because it does not improve any proofs
  1252    but slows some AFP entries down by 5% (cpu time). May 2015 *)
  1253 lemma implies_False_swap: "NO_MATCH (Trueprop False) P \<Longrightarrow>
  1254   (False \<Longrightarrow> PROP P \<Longrightarrow> PROP Q) \<equiv> (PROP P \<Longrightarrow> False \<Longrightarrow> PROP Q)"
  1255 by(rule swap_prems_eq)
  1256 
  1257 lemma ex_simps:
  1258   "\<And>P Q. (\<exists>x. P x \<and> Q)   = ((\<exists>x. P x) \<and> Q)"
  1259   "\<And>P Q. (\<exists>x. P \<and> Q x)   = (P \<and> (\<exists>x. Q x))"
  1260   "\<And>P Q. (\<exists>x. P x \<or> Q)   = ((\<exists>x. P x) \<or> Q)"
  1261   "\<And>P Q. (\<exists>x. P \<or> Q x)   = (P \<or> (\<exists>x. Q x))"
  1262   "\<And>P Q. (\<exists>x. P x \<longrightarrow> Q) = ((\<forall>x. P x) \<longrightarrow> Q)"
  1263   "\<And>P Q. (\<exists>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<exists>x. Q x))"
  1264   \<comment> \<open>Miniscoping: pushing in existential quantifiers.\<close>
  1265   by (iprover | blast)+
  1266 
  1267 lemma all_simps:
  1268   "\<And>P Q. (\<forall>x. P x \<and> Q)   = ((\<forall>x. P x) \<and> Q)"
  1269   "\<And>P Q. (\<forall>x. P \<and> Q x)   = (P \<and> (\<forall>x. Q x))"
  1270   "\<And>P Q. (\<forall>x. P x \<or> Q)   = ((\<forall>x. P x) \<or> Q)"
  1271   "\<And>P Q. (\<forall>x. P \<or> Q x)   = (P \<or> (\<forall>x. Q x))"
  1272   "\<And>P Q. (\<forall>x. P x \<longrightarrow> Q) = ((\<exists>x. P x) \<longrightarrow> Q)"
  1273   "\<And>P Q. (\<forall>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<forall>x. Q x))"
  1274   \<comment> \<open>Miniscoping: pushing in universal quantifiers.\<close>
  1275   by (iprover | blast)+
  1276 
  1277 lemmas [simp] =
  1278   triv_forall_equality (*prunes params*)
  1279   True_implies_equals implies_True_equals (*prune True in asms*)
  1280   False_implies_equals (*prune False in asms*)
  1281   if_True
  1282   if_False
  1283   if_cancel
  1284   if_eq_cancel
  1285   imp_disjL
  1286   (*In general it seems wrong to add distributive laws by default: they
  1287     might cause exponential blow-up.  But imp_disjL has been in for a while
  1288     and cannot be removed without affecting existing proofs.  Moreover,
  1289     rewriting by "(P \<or> Q \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" might be justified on the
  1290     grounds that it allows simplification of R in the two cases.*)
  1291   conj_assoc
  1292   disj_assoc
  1293   de_Morgan_conj
  1294   de_Morgan_disj
  1295   imp_disj1
  1296   imp_disj2
  1297   not_imp
  1298   disj_not1
  1299   not_all
  1300   not_ex
  1301   cases_simp
  1302   the_eq_trivial
  1303   the_sym_eq_trivial
  1304   ex_simps
  1305   all_simps
  1306   simp_thms
  1307 
  1308 lemmas [cong] = imp_cong simp_implies_cong
  1309 lemmas [split] = split_if
  1310 
  1311 ML \<open>val HOL_ss = simpset_of @{context}\<close>
  1312 
  1313 text \<open>Simplifies @{term x} assuming @{prop c} and @{term y} assuming @{prop "\<not> c"}\<close>
  1314 lemma if_cong:
  1315   assumes "b = c"
  1316       and "c \<Longrightarrow> x = u"
  1317       and "\<not> c \<Longrightarrow> y = v"
  1318   shows "(if b then x else y) = (if c then u else v)"
  1319   using assms by simp
  1320 
  1321 text \<open>Prevents simplification of x and y:
  1322   faster and allows the execution of functional programs.\<close>
  1323 lemma if_weak_cong [cong]:
  1324   assumes "b = c"
  1325   shows "(if b then x else y) = (if c then x else y)"
  1326   using assms by (rule arg_cong)
  1327 
  1328 text \<open>Prevents simplification of t: much faster\<close>
  1329 lemma let_weak_cong:
  1330   assumes "a = b"
  1331   shows "(let x = a in t x) = (let x = b in t x)"
  1332   using assms by (rule arg_cong)
  1333 
  1334 text \<open>To tidy up the result of a simproc.  Only the RHS will be simplified.\<close>
  1335 lemma eq_cong2:
  1336   assumes "u = u'"
  1337   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1338   using assms by simp
  1339 
  1340 lemma if_distrib:
  1341   "f (if c then x else y) = (if c then f x else f y)"
  1342   by simp
  1343 
  1344 text\<open>As a simplification rule, it replaces all function equalities by
  1345   first-order equalities.\<close>
  1346 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1347   by auto
  1348 
  1349 
  1350 subsubsection \<open>Generic cases and induction\<close>
  1351 
  1352 text \<open>Rule projections:\<close>
  1353 ML \<open>
  1354 structure Project_Rule = Project_Rule
  1355 (
  1356   val conjunct1 = @{thm conjunct1}
  1357   val conjunct2 = @{thm conjunct2}
  1358   val mp = @{thm mp}
  1359 );
  1360 \<close>
  1361 
  1362 context
  1363 begin
  1364 
  1365 qualified definition "induct_forall P \<equiv> \<forall>x. P x"
  1366 qualified definition "induct_implies A B \<equiv> A \<longrightarrow> B"
  1367 qualified definition "induct_equal x y \<equiv> x = y"
  1368 qualified definition "induct_conj A B \<equiv> A \<and> B"
  1369 qualified definition "induct_true \<equiv> True"
  1370 qualified definition "induct_false \<equiv> False"
  1371 
  1372 lemma induct_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (induct_forall (\<lambda>x. P x))"
  1373   by (unfold atomize_all induct_forall_def)
  1374 
  1375 lemma induct_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (induct_implies A B)"
  1376   by (unfold atomize_imp induct_implies_def)
  1377 
  1378 lemma induct_equal_eq: "(x \<equiv> y) \<equiv> Trueprop (induct_equal x y)"
  1379   by (unfold atomize_eq induct_equal_def)
  1380 
  1381 lemma induct_conj_eq: "(A &&& B) \<equiv> Trueprop (induct_conj A B)"
  1382   by (unfold atomize_conj induct_conj_def)
  1383 
  1384 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1385 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1386 lemmas induct_rulify' [symmetric] = induct_atomize'
  1387 lemmas induct_rulify [symmetric] = induct_atomize
  1388 lemmas induct_rulify_fallback =
  1389   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1390   induct_true_def induct_false_def
  1391 
  1392 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1393     induct_conj (induct_forall A) (induct_forall B)"
  1394   by (unfold induct_forall_def induct_conj_def) iprover
  1395 
  1396 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1397     induct_conj (induct_implies C A) (induct_implies C B)"
  1398   by (unfold induct_implies_def induct_conj_def) iprover
  1399 
  1400 lemma induct_conj_curry: "(induct_conj A B \<Longrightarrow> PROP C) \<equiv> (A \<Longrightarrow> B \<Longrightarrow> PROP C)"
  1401 proof
  1402   assume r: "induct_conj A B \<Longrightarrow> PROP C"
  1403   assume ab: A B
  1404   show "PROP C" by (rule r) (simp add: induct_conj_def ab)
  1405 next
  1406   assume r: "A \<Longrightarrow> B \<Longrightarrow> PROP C"
  1407   assume ab: "induct_conj A B"
  1408   show "PROP C" by (rule r) (simp_all add: ab [unfolded induct_conj_def])
  1409 qed
  1410 
  1411 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1412 
  1413 lemma induct_trueI: "induct_true"
  1414   by (simp add: induct_true_def)
  1415 
  1416 text \<open>Method setup.\<close>
  1417 
  1418 ML_file "~~/src/Tools/induct.ML"
  1419 ML \<open>
  1420 structure Induct = Induct
  1421 (
  1422   val cases_default = @{thm case_split}
  1423   val atomize = @{thms induct_atomize}
  1424   val rulify = @{thms induct_rulify'}
  1425   val rulify_fallback = @{thms induct_rulify_fallback}
  1426   val equal_def = @{thm induct_equal_def}
  1427   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1428     | dest_def _ = NONE
  1429   fun trivial_tac ctxt = match_tac ctxt @{thms induct_trueI}
  1430 )
  1431 \<close>
  1432 
  1433 ML_file "~~/src/Tools/induction.ML"
  1434 
  1435 declaration \<open>
  1436   fn _ => Induct.map_simpset (fn ss => ss
  1437     addsimprocs
  1438       [Simplifier.make_simproc @{context} "swap_induct_false"
  1439         {lhss = [@{term "induct_false \<Longrightarrow> PROP P \<Longrightarrow> PROP Q"}],
  1440          proc = fn _ => fn _ => fn ct =>
  1441           (case Thm.term_of ct of
  1442             _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1443               if P <> Q then SOME Drule.swap_prems_eq else NONE
  1444           | _ => NONE),
  1445          identifier = []},
  1446        Simplifier.make_simproc @{context} "induct_equal_conj_curry"
  1447         {lhss = [@{term "induct_conj P Q \<Longrightarrow> PROP R"}],
  1448          proc = fn _ => fn _ => fn ct =>
  1449           (case Thm.term_of ct of
  1450             _ $ (_ $ P) $ _ =>
  1451               let
  1452                 fun is_conj (@{const induct_conj} $ P $ Q) =
  1453                       is_conj P andalso is_conj Q
  1454                   | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1455                   | is_conj @{const induct_true} = true
  1456                   | is_conj @{const induct_false} = true
  1457                   | is_conj _ = false
  1458               in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1459             | _ => NONE),
  1460           identifier = []}]
  1461     |> Simplifier.set_mksimps (fn ctxt =>
  1462         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
  1463         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback}))))
  1464 \<close>
  1465 
  1466 text \<open>Pre-simplification of induction and cases rules\<close>
  1467 
  1468 lemma [induct_simp]: "(\<And>x. induct_equal x t \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1469   unfolding induct_equal_def
  1470 proof
  1471   assume r: "\<And>x. x = t \<Longrightarrow> PROP P x"
  1472   show "PROP P t" by (rule r [OF refl])
  1473 next
  1474   fix x
  1475   assume "PROP P t" "x = t"
  1476   then show "PROP P x" by simp
  1477 qed
  1478 
  1479 lemma [induct_simp]: "(\<And>x. induct_equal t x \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1480   unfolding induct_equal_def
  1481 proof
  1482   assume r: "\<And>x. t = x \<Longrightarrow> PROP P x"
  1483   show "PROP P t" by (rule r [OF refl])
  1484 next
  1485   fix x
  1486   assume "PROP P t" "t = x"
  1487   then show "PROP P x" by simp
  1488 qed
  1489 
  1490 lemma [induct_simp]: "(induct_false \<Longrightarrow> P) \<equiv> Trueprop induct_true"
  1491   unfolding induct_false_def induct_true_def
  1492   by (iprover intro: equal_intr_rule)
  1493 
  1494 lemma [induct_simp]: "(induct_true \<Longrightarrow> PROP P) \<equiv> PROP P"
  1495   unfolding induct_true_def
  1496 proof
  1497   assume "True \<Longrightarrow> PROP P"
  1498   then show "PROP P" using TrueI .
  1499 next
  1500   assume "PROP P"
  1501   then show "PROP P" .
  1502 qed
  1503 
  1504 lemma [induct_simp]: "(PROP P \<Longrightarrow> induct_true) \<equiv> Trueprop induct_true"
  1505   unfolding induct_true_def
  1506   by (iprover intro: equal_intr_rule)
  1507 
  1508 lemma [induct_simp]: "(\<And>x. induct_true) \<equiv> Trueprop induct_true"
  1509   unfolding induct_true_def
  1510   by (iprover intro: equal_intr_rule)
  1511 
  1512 lemma [induct_simp]: "induct_implies induct_true P \<equiv> P"
  1513   by (simp add: induct_implies_def induct_true_def)
  1514 
  1515 lemma [induct_simp]: "x = x \<longleftrightarrow> True"
  1516   by (rule simp_thms)
  1517 
  1518 end
  1519 
  1520 ML_file "~~/src/Tools/induct_tacs.ML"
  1521 
  1522 
  1523 subsubsection \<open>Coherent logic\<close>
  1524 
  1525 ML_file "~~/src/Tools/coherent.ML"
  1526 ML \<open>
  1527 structure Coherent = Coherent
  1528 (
  1529   val atomize_elimL = @{thm atomize_elimL};
  1530   val atomize_exL = @{thm atomize_exL};
  1531   val atomize_conjL = @{thm atomize_conjL};
  1532   val atomize_disjL = @{thm atomize_disjL};
  1533   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
  1534 );
  1535 \<close>
  1536 
  1537 
  1538 subsubsection \<open>Reorienting equalities\<close>
  1539 
  1540 ML \<open>
  1541 signature REORIENT_PROC =
  1542 sig
  1543   val add : (term -> bool) -> theory -> theory
  1544   val proc : morphism -> Proof.context -> cterm -> thm option
  1545 end;
  1546 
  1547 structure Reorient_Proc : REORIENT_PROC =
  1548 struct
  1549   structure Data = Theory_Data
  1550   (
  1551     type T = ((term -> bool) * stamp) list;
  1552     val empty = [];
  1553     val extend = I;
  1554     fun merge data : T = Library.merge (eq_snd op =) data;
  1555   );
  1556   fun add m = Data.map (cons (m, stamp ()));
  1557   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1558 
  1559   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1560   fun proc phi ctxt ct =
  1561     let
  1562       val thy = Proof_Context.theory_of ctxt;
  1563     in
  1564       case Thm.term_of ct of
  1565         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1566       | _ => NONE
  1567     end;
  1568 end;
  1569 \<close>
  1570 
  1571 
  1572 subsection \<open>Other simple lemmas and lemma duplicates\<close>
  1573 
  1574 lemma ex1_eq [iff]: "\<exists>!x. x = t" "\<exists>!x. t = x"
  1575   by blast+
  1576 
  1577 lemma choice_eq: "(\<forall>x. \<exists>!y. P x y) = (\<exists>!f. \<forall>x. P x (f x))"
  1578   apply (rule iffI)
  1579   apply (rule_tac a = "\<lambda>x. THE y. P x y" in ex1I)
  1580   apply (fast dest!: theI')
  1581   apply (fast intro: the1_equality [symmetric])
  1582   apply (erule ex1E)
  1583   apply (rule allI)
  1584   apply (rule ex1I)
  1585   apply (erule spec)
  1586   apply (erule_tac x = "\<lambda>z. if z = x then y else f z" in allE)
  1587   apply (erule impE)
  1588   apply (rule allI)
  1589   apply (case_tac "xa = x")
  1590   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1591   done
  1592 
  1593 lemmas eq_sym_conv = eq_commute
  1594 
  1595 lemma nnf_simps:
  1596   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
  1597   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))"
  1598   "(\<not> \<not>(P)) = P"
  1599 by blast+
  1600 
  1601 subsection \<open>Basic ML bindings\<close>
  1602 
  1603 ML \<open>
  1604 val FalseE = @{thm FalseE}
  1605 val Let_def = @{thm Let_def}
  1606 val TrueI = @{thm TrueI}
  1607 val allE = @{thm allE}
  1608 val allI = @{thm allI}
  1609 val all_dupE = @{thm all_dupE}
  1610 val arg_cong = @{thm arg_cong}
  1611 val box_equals = @{thm box_equals}
  1612 val ccontr = @{thm ccontr}
  1613 val classical = @{thm classical}
  1614 val conjE = @{thm conjE}
  1615 val conjI = @{thm conjI}
  1616 val conjunct1 = @{thm conjunct1}
  1617 val conjunct2 = @{thm conjunct2}
  1618 val disjCI = @{thm disjCI}
  1619 val disjE = @{thm disjE}
  1620 val disjI1 = @{thm disjI1}
  1621 val disjI2 = @{thm disjI2}
  1622 val eq_reflection = @{thm eq_reflection}
  1623 val ex1E = @{thm ex1E}
  1624 val ex1I = @{thm ex1I}
  1625 val ex1_implies_ex = @{thm ex1_implies_ex}
  1626 val exE = @{thm exE}
  1627 val exI = @{thm exI}
  1628 val excluded_middle = @{thm excluded_middle}
  1629 val ext = @{thm ext}
  1630 val fun_cong = @{thm fun_cong}
  1631 val iffD1 = @{thm iffD1}
  1632 val iffD2 = @{thm iffD2}
  1633 val iffI = @{thm iffI}
  1634 val impE = @{thm impE}
  1635 val impI = @{thm impI}
  1636 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1637 val mp = @{thm mp}
  1638 val notE = @{thm notE}
  1639 val notI = @{thm notI}
  1640 val not_all = @{thm not_all}
  1641 val not_ex = @{thm not_ex}
  1642 val not_iff = @{thm not_iff}
  1643 val not_not = @{thm not_not}
  1644 val not_sym = @{thm not_sym}
  1645 val refl = @{thm refl}
  1646 val rev_mp = @{thm rev_mp}
  1647 val spec = @{thm spec}
  1648 val ssubst = @{thm ssubst}
  1649 val subst = @{thm subst}
  1650 val sym = @{thm sym}
  1651 val trans = @{thm trans}
  1652 \<close>
  1653 
  1654 ML_file "Tools/cnf.ML"
  1655 
  1656 
  1657 section \<open>\<open>NO_MATCH\<close> simproc\<close>
  1658 
  1659 text \<open>
  1660  The simplification procedure can be used to avoid simplification of terms of a certain form
  1661 \<close>
  1662 
  1663 definition NO_MATCH :: "'a \<Rightarrow> 'b \<Rightarrow> bool" where "NO_MATCH pat val \<equiv> True"
  1664 
  1665 lemma NO_MATCH_cong[cong]: "NO_MATCH pat val = NO_MATCH pat val" by (rule refl)
  1666 
  1667 declare [[coercion_args NO_MATCH - -]]
  1668 
  1669 simproc_setup NO_MATCH ("NO_MATCH pat val") = \<open>fn _ => fn ctxt => fn ct =>
  1670   let
  1671     val thy = Proof_Context.theory_of ctxt
  1672     val dest_binop = Term.dest_comb #> apfst (Term.dest_comb #> snd)
  1673     val m = Pattern.matches thy (dest_binop (Thm.term_of ct))
  1674   in if m then NONE else SOME @{thm NO_MATCH_def} end
  1675 \<close>
  1676 
  1677 text \<open>
  1678   This setup ensures that a rewrite rule of the form @{term "NO_MATCH pat val \<Longrightarrow> t"}
  1679   is only applied, if the pattern @{term pat} does not match the value @{term val}.
  1680 \<close>
  1681 
  1682 
  1683 text\<open>Tagging a premise of a simp rule with ASSUMPTION forces the simplifier
  1684 not to simplify the argument and to solve it by an assumption.\<close>
  1685 
  1686 definition ASSUMPTION :: "bool \<Rightarrow> bool" where
  1687 "ASSUMPTION A \<equiv> A"
  1688 
  1689 lemma ASSUMPTION_cong[cong]: "ASSUMPTION A = ASSUMPTION A"
  1690 by (rule refl)
  1691 
  1692 lemma ASSUMPTION_I: "A \<Longrightarrow> ASSUMPTION A"
  1693 by(simp add: ASSUMPTION_def)
  1694 
  1695 lemma ASSUMPTION_D: "ASSUMPTION A \<Longrightarrow> A"
  1696 by(simp add: ASSUMPTION_def)
  1697 
  1698 setup \<open>
  1699 let
  1700   val asm_sol = mk_solver "ASSUMPTION" (fn ctxt =>
  1701     resolve_tac ctxt [@{thm ASSUMPTION_I}] THEN'
  1702     resolve_tac ctxt (Simplifier.prems_of ctxt))
  1703 in
  1704   map_theory_simpset (fn ctxt => Simplifier.addSolver (ctxt,asm_sol))
  1705 end
  1706 \<close>
  1707 
  1708 
  1709 subsection \<open>Code generator setup\<close>
  1710 
  1711 subsubsection \<open>Generic code generator preprocessor setup\<close>
  1712 
  1713 lemma conj_left_cong:
  1714   "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
  1715   by (fact arg_cong)
  1716 
  1717 lemma disj_left_cong:
  1718   "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
  1719   by (fact arg_cong)
  1720 
  1721 setup \<open>
  1722   Code_Preproc.map_pre (put_simpset HOL_basic_ss) #>
  1723   Code_Preproc.map_post (put_simpset HOL_basic_ss) #>
  1724   Code_Simp.map_ss (put_simpset HOL_basic_ss #>
  1725   Simplifier.add_cong @{thm conj_left_cong} #>
  1726   Simplifier.add_cong @{thm disj_left_cong})
  1727 \<close>
  1728 
  1729 
  1730 subsubsection \<open>Equality\<close>
  1731 
  1732 class equal =
  1733   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1734   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1735 begin
  1736 
  1737 lemma equal: "equal = (op =)"
  1738   by (rule ext equal_eq)+
  1739 
  1740 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1741   unfolding equal by rule+
  1742 
  1743 lemma eq_equal: "(op =) \<equiv> equal"
  1744   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1745 
  1746 end
  1747 
  1748 declare eq_equal [symmetric, code_post]
  1749 declare eq_equal [code]
  1750 
  1751 setup \<open>
  1752   Code_Preproc.map_pre (fn ctxt =>
  1753     ctxt addsimprocs
  1754       [Simplifier.make_simproc @{context} "equal"
  1755         {lhss = [@{term HOL.eq}],
  1756          proc = fn _ => fn _ => fn ct =>
  1757           (case Thm.term_of ct of
  1758             Const (_, Type (@{type_name fun}, [Type _, _])) => SOME @{thm eq_equal}
  1759           | _ => NONE),
  1760          identifier = []}])
  1761 \<close>
  1762 
  1763 
  1764 subsubsection \<open>Generic code generator foundation\<close>
  1765 
  1766 text \<open>Datatype @{typ bool}\<close>
  1767 
  1768 code_datatype True False
  1769 
  1770 lemma [code]:
  1771   shows "False \<and> P \<longleftrightarrow> False"
  1772     and "True \<and> P \<longleftrightarrow> P"
  1773     and "P \<and> False \<longleftrightarrow> False"
  1774     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1775 
  1776 lemma [code]:
  1777   shows "False \<or> P \<longleftrightarrow> P"
  1778     and "True \<or> P \<longleftrightarrow> True"
  1779     and "P \<or> False \<longleftrightarrow> P"
  1780     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1781 
  1782 lemma [code]:
  1783   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1784     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1785     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1786     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1787 
  1788 text \<open>More about @{typ prop}\<close>
  1789 
  1790 lemma [code nbe]:
  1791   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q"
  1792     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1793     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1794 
  1795 lemma Trueprop_code [code]:
  1796   "Trueprop True \<equiv> Code_Generator.holds"
  1797   by (auto intro!: equal_intr_rule holds)
  1798 
  1799 declare Trueprop_code [symmetric, code_post]
  1800 
  1801 text \<open>Equality\<close>
  1802 
  1803 declare simp_thms(6) [code nbe]
  1804 
  1805 instantiation itself :: (type) equal
  1806 begin
  1807 
  1808 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1809   "equal_itself x y \<longleftrightarrow> x = y"
  1810 
  1811 instance proof
  1812 qed (fact equal_itself_def)
  1813 
  1814 end
  1815 
  1816 lemma equal_itself_code [code]:
  1817   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1818   by (simp add: equal)
  1819 
  1820 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::type \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1821 
  1822 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1823 proof
  1824   assume "PROP ?ofclass"
  1825   show "PROP ?equal"
  1826     by (tactic \<open>ALLGOALS (resolve_tac @{context} [Thm.unconstrainT @{thm eq_equal}])\<close>)
  1827       (fact \<open>PROP ?ofclass\<close>)
  1828 next
  1829   assume "PROP ?equal"
  1830   show "PROP ?ofclass" proof
  1831   qed (simp add: \<open>PROP ?equal\<close>)
  1832 qed
  1833 
  1834 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::equal \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1835 
  1836 setup \<open>Nbe.add_const_alias @{thm equal_alias_cert}\<close>
  1837 
  1838 text \<open>Cases\<close>
  1839 
  1840 lemma Let_case_cert:
  1841   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1842   shows "CASE x \<equiv> f x"
  1843   using assms by simp_all
  1844 
  1845 setup \<open>
  1846   Code.add_case @{thm Let_case_cert} #>
  1847   Code.add_undefined @{const_name undefined}
  1848 \<close>
  1849 
  1850 declare [[code abort: undefined]]
  1851 
  1852 
  1853 subsubsection \<open>Generic code generator target languages\<close>
  1854 
  1855 text \<open>type @{typ bool}\<close>
  1856 
  1857 code_printing
  1858   type_constructor bool \<rightharpoonup>
  1859     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
  1860 | constant True \<rightharpoonup>
  1861     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
  1862 | constant False \<rightharpoonup>
  1863     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false"
  1864 
  1865 code_reserved SML
  1866   bool true false
  1867 
  1868 code_reserved OCaml
  1869   bool
  1870 
  1871 code_reserved Scala
  1872   Boolean
  1873 
  1874 code_printing
  1875   constant Not \<rightharpoonup>
  1876     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
  1877 | constant HOL.conj \<rightharpoonup>
  1878     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
  1879 | constant HOL.disj \<rightharpoonup>
  1880     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
  1881 | constant HOL.implies \<rightharpoonup>
  1882     (SML) "!(if (_)/ then (_)/ else true)"
  1883     and (OCaml) "!(if (_)/ then (_)/ else true)"
  1884     and (Haskell) "!(if (_)/ then (_)/ else True)"
  1885     and (Scala) "!(if ((_))/ (_)/ else true)"
  1886 | constant If \<rightharpoonup>
  1887     (SML) "!(if (_)/ then (_)/ else (_))"
  1888     and (OCaml) "!(if (_)/ then (_)/ else (_))"
  1889     and (Haskell) "!(if (_)/ then (_)/ else (_))"
  1890     and (Scala) "!(if ((_))/ (_)/ else (_))"
  1891 
  1892 code_reserved SML
  1893   not
  1894 
  1895 code_reserved OCaml
  1896   not
  1897 
  1898 code_identifier
  1899   code_module Pure \<rightharpoonup>
  1900     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
  1901 
  1902 text \<open>using built-in Haskell equality\<close>
  1903 
  1904 code_printing
  1905   type_class equal \<rightharpoonup> (Haskell) "Eq"
  1906 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
  1907 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
  1908 
  1909 text \<open>undefined\<close>
  1910 
  1911 code_printing
  1912   constant undefined \<rightharpoonup>
  1913     (SML) "!(raise/ Fail/ \"undefined\")"
  1914     and (OCaml) "failwith/ \"undefined\""
  1915     and (Haskell) "error/ \"undefined\""
  1916     and (Scala) "!sys.error(\"undefined\")"
  1917 
  1918 
  1919 subsubsection \<open>Evaluation and normalization by evaluation\<close>
  1920 
  1921 method_setup eval = \<open>
  1922   let
  1923     fun eval_tac ctxt =
  1924       let val conv = Code_Runtime.dynamic_holds_conv ctxt
  1925       in
  1926         CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN'
  1927         resolve_tac ctxt [TrueI]
  1928       end
  1929   in
  1930     Scan.succeed (SIMPLE_METHOD' o eval_tac)
  1931   end
  1932 \<close> "solve goal by evaluation"
  1933 
  1934 method_setup normalization = \<open>
  1935   Scan.succeed (fn ctxt =>
  1936     SIMPLE_METHOD'
  1937       (CHANGED_PROP o
  1938         (CONVERSION (Nbe.dynamic_conv ctxt)
  1939           THEN_ALL_NEW (TRY o resolve_tac ctxt [TrueI]))))
  1940 \<close> "solve goal by normalization"
  1941 
  1942 
  1943 subsection \<open>Counterexample Search Units\<close>
  1944 
  1945 subsubsection \<open>Quickcheck\<close>
  1946 
  1947 quickcheck_params [size = 5, iterations = 50]
  1948 
  1949 
  1950 subsubsection \<open>Nitpick setup\<close>
  1951 
  1952 named_theorems nitpick_unfold "alternative definitions of constants as needed by Nitpick"
  1953   and nitpick_simp "equational specification of constants as needed by Nitpick"
  1954   and nitpick_psimp "partial equational specification of constants as needed by Nitpick"
  1955   and nitpick_choice_spec "choice specification of constants as needed by Nitpick"
  1956 
  1957 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1958         if_bool_eq_disj [no_atp]
  1959 
  1960 
  1961 subsection \<open>Preprocessing for the predicate compiler\<close>
  1962 
  1963 named_theorems code_pred_def "alternative definitions of constants for the Predicate Compiler"
  1964   and code_pred_inline "inlining definitions for the Predicate Compiler"
  1965   and code_pred_simp "simplification rules for the optimisations in the Predicate Compiler"
  1966 
  1967 
  1968 subsection \<open>Legacy tactics and ML bindings\<close>
  1969 
  1970 ML \<open>
  1971   (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1972   local
  1973     fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  1974       | wrong_prem (Bound _) = true
  1975       | wrong_prem _ = false;
  1976     val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1977     fun smp i = funpow i (fn m => filter_right ([spec] RL m)) [mp];
  1978   in
  1979     fun smp_tac ctxt j = EVERY' [dresolve_tac ctxt (smp j), assume_tac ctxt];
  1980   end;
  1981 
  1982   local
  1983     val nnf_ss =
  1984       simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
  1985   in
  1986     fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
  1987   end
  1988 \<close>
  1989 
  1990 hide_const (open) eq equal
  1991 
  1992 end