src/Pure/Isar/attrib.ML
author wenzelm
Fri Mar 13 21:25:15 2009 +0100 (2009-03-13)
changeset 30513 1796b8ea88aa
parent 30466 5f31e24937c5
child 30525 8a5a0aa30e1c
permissions -rw-r--r--
eliminated type Args.T;
pervasive types 'a parser and 'a context_parser;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    20   val map_specs: ('a -> 'att) ->
    21     (('c * 'a list) * 'd) list -> (('c * 'att list) * 'd) list
    22   val map_facts: ('a -> 'att) ->
    23     (('c * 'a list) * ('d * 'a list) list) list ->
    24     (('c * 'att list) * ('d * 'att list) list) list
    25   val crude_closure: Proof.context -> src -> src
    26   val add_attributes: (bstring * (src -> attribute) * string) list -> theory -> theory
    27   val syntax: attribute context_parser -> src -> attribute
    28   val no_args: attribute -> src -> attribute
    29   val add_del_args: attribute -> attribute -> src -> attribute
    30   val thm_sel: Facts.interval list parser
    31   val thm: thm context_parser
    32   val thms: thm list context_parser
    33   val multi_thm: thm list context_parser
    34   val print_configs: Proof.context -> unit
    35   val internal: (morphism -> attribute) -> src
    36   val register_config: Config.value Config.T -> theory -> theory
    37   val config_bool: bstring -> bool -> bool Config.T * (theory -> theory)
    38   val config_int: bstring -> int -> int Config.T * (theory -> theory)
    39   val config_string: bstring -> string -> string Config.T * (theory -> theory)
    40   val config_bool_global: bstring -> bool -> bool Config.T * (theory -> theory)
    41   val config_int_global: bstring -> int -> int Config.T * (theory -> theory)
    42   val config_string_global: bstring -> string -> string Config.T * (theory -> theory)
    43 end;
    44 
    45 structure Attrib: ATTRIB =
    46 struct
    47 
    48 structure T = OuterLex;
    49 structure P = OuterParse;
    50 
    51 
    52 (* source and bindings *)
    53 
    54 type src = Args.src;
    55 
    56 type binding = binding * src list;
    57 val empty_binding: binding = (Binding.empty, []);
    58 
    59 
    60 
    61 (** named attributes **)
    62 
    63 (* theory data *)
    64 
    65 structure Attributes = TheoryDataFun
    66 (
    67   type T = (((src -> attribute) * string) * stamp) NameSpace.table;
    68   val empty = NameSpace.empty_table;
    69   val copy = I;
    70   val extend = I;
    71   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
    72     error ("Attempt to merge different versions of attribute " ^ quote dup);
    73 );
    74 
    75 fun print_attributes thy =
    76   let
    77     val attribs = Attributes.get thy;
    78     fun prt_attr (name, ((_, comment), _)) = Pretty.block
    79       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    80   in
    81     [Pretty.big_list "attributes:" (map prt_attr (NameSpace.extern_table attribs))]
    82     |> Pretty.chunks |> Pretty.writeln
    83   end;
    84 
    85 
    86 (* name space *)
    87 
    88 val intern = NameSpace.intern o #1 o Attributes.get;
    89 val intern_src = Args.map_name o intern;
    90 
    91 val extern = NameSpace.extern o #1 o Attributes.get o ProofContext.theory_of;
    92 
    93 
    94 (* pretty printing *)
    95 
    96 fun pretty_attribs _ [] = []
    97   | pretty_attribs ctxt srcs =
    98       [Pretty.enclose "[" "]"
    99         (Pretty.commas (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs))];
   100 
   101 
   102 (* get attributes *)
   103 
   104 val defined = Symtab.defined o #2 o Attributes.get;
   105 
   106 fun attribute_i thy =
   107   let
   108     val attrs = #2 (Attributes.get thy);
   109     fun attr src =
   110       let val ((name, _), pos) = Args.dest_src src in
   111         (case Symtab.lookup attrs name of
   112           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   113         | SOME ((att, _), _) => (Position.report (Markup.attribute name) pos; att src))
   114       end;
   115   in attr end;
   116 
   117 fun attribute thy = attribute_i thy o intern_src thy;
   118 
   119 fun eval_thms ctxt args = ProofContext.note_thmss Thm.theoremK
   120     [(Thm.empty_binding, map (apsnd (map (attribute (ProofContext.theory_of ctxt)))) args)] ctxt
   121   |> fst |> maps snd;
   122 
   123 
   124 (* attributed declarations *)
   125 
   126 fun map_specs f = map (apfst (apsnd (map f)));
   127 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   128 
   129 
   130 (* crude_closure *)
   131 
   132 (*Produce closure without knowing facts in advance! The following
   133   works reasonably well for attribute parsers that do not peek at the
   134   thm structure.*)
   135 
   136 fun crude_closure ctxt src =
   137  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   138     (Context.Proof ctxt, Drule.asm_rl)) ();
   139   Args.closure src);
   140 
   141 
   142 (* add_attributes *)
   143 
   144 fun add_attributes raw_attrs thy =
   145   let
   146     val new_attrs =
   147       raw_attrs |> map (fn (name, att, comment) => (Binding.name name, ((att, comment), stamp ())));
   148     fun add attrs = fold (snd oo NameSpace.define (Sign.naming_of thy)) new_attrs attrs
   149       handle Symtab.DUP dup => error ("Duplicate declaration of attributes " ^ quote dup);
   150   in Attributes.map add thy end;
   151 
   152 
   153 (* attribute syntax *)
   154 
   155 fun syntax scan src (st, th) =
   156   let val (f: attribute, st') = Args.syntax "attribute" scan src st
   157   in f (st', th) end;
   158 
   159 fun no_args x = syntax (Scan.succeed x);
   160 
   161 fun add_del_args add del = syntax
   162   (Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add));
   163 
   164 
   165 
   166 (** parsing attributed theorems **)
   167 
   168 val thm_sel = P.$$$ "(" |-- P.list1
   169  (P.nat --| P.minus -- P.nat >> Facts.FromTo ||
   170   P.nat --| P.minus >> Facts.From ||
   171   P.nat >> Facts.Single) --| P.$$$ ")";
   172 
   173 local
   174 
   175 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   176 
   177 fun gen_thm pick = Scan.depend (fn context =>
   178   let
   179     val thy = Context.theory_of context;
   180     val get = Context.cases (PureThy.get_fact context) ProofContext.get_fact context;
   181     val get_fact = get o Facts.Fact;
   182     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   183   in
   184     P.$$$ "[" |-- Args.attribs (intern thy) --| P.$$$ "]" >> (fn srcs =>
   185       let
   186         val atts = map (attribute_i thy) srcs;
   187         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   188       in (context', pick "" [th']) end)
   189     ||
   190     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   191       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   192      Scan.ahead (P.position fact_name) :|-- (fn (name, pos) =>
   193       Args.named_fact (get_named pos) -- Scan.option thm_sel
   194         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   195     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   196       let
   197         val ths = Facts.select thmref fact;
   198         val atts = map (attribute_i thy) srcs;
   199         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   200       in (context', pick name ths') end)
   201   end);
   202 
   203 in
   204 
   205 val thm = gen_thm Facts.the_single;
   206 val multi_thm = gen_thm (K I);
   207 val thms = Scan.repeat multi_thm >> flat;
   208 
   209 end;
   210 
   211 
   212 
   213 (** basic attributes **)
   214 
   215 (* internal *)
   216 
   217 fun internal att = Args.src (("Pure.attribute", [T.mk_attribute att]), Position.none);
   218 
   219 val internal_att =
   220   syntax (Scan.lift Args.internal_attribute >> Morphism.form);
   221 
   222 
   223 (* tags *)
   224 
   225 val tagged = syntax (Scan.lift (Args.name -- Args.name) >> Thm.tag);
   226 val untagged = syntax (Scan.lift Args.name >> Thm.untag);
   227 
   228 val kind = syntax (Scan.lift Args.name >> Thm.kind);
   229 
   230 
   231 (* rule composition *)
   232 
   233 val COMP_att =
   234   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   235     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B))));
   236 
   237 val THEN_att =
   238   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   239     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B))));
   240 
   241 val OF_att =
   242   syntax (thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A)));
   243 
   244 
   245 (* rename_abs *)
   246 
   247 val rename_abs = syntax
   248   (Scan.lift (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')));
   249 
   250 
   251 (* unfold / fold definitions *)
   252 
   253 fun unfolded_syntax rule =
   254   syntax (thms >>
   255     (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths)));
   256 
   257 val unfolded = unfolded_syntax LocalDefs.unfold;
   258 val folded = unfolded_syntax LocalDefs.fold;
   259 
   260 
   261 (* rule cases *)
   262 
   263 val consumes = syntax (Scan.lift (Scan.optional P.nat 1) >> RuleCases.consumes);
   264 val case_names = syntax (Scan.lift (Scan.repeat1 Args.name) >> RuleCases.case_names);
   265 val case_conclusion =
   266   syntax (Scan.lift (Args.name -- Scan.repeat Args.name) >> RuleCases.case_conclusion);
   267 val params = syntax (Scan.lift (P.and_list1 (Scan.repeat Args.name)) >> RuleCases.params);
   268 
   269 
   270 (* rule format *)
   271 
   272 val rule_format = syntax (Args.mode "no_asm"
   273   >> (fn true => ObjectLogic.rule_format_no_asm | false => ObjectLogic.rule_format));
   274 
   275 val elim_format = no_args (Thm.rule_attribute (K Tactic.make_elim));
   276 
   277 
   278 (* misc rules *)
   279 
   280 val standard = no_args (Thm.rule_attribute (K Drule.standard));
   281 
   282 val no_vars = no_args (Thm.rule_attribute (fn context => fn th =>
   283   let
   284     val ctxt = Variable.set_body false (Context.proof_of context);
   285     val ((_, [th']), _) = Variable.import_thms true [th] ctxt;
   286   in th' end));
   287 
   288 val eta_long =
   289   no_args (Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion)));
   290 
   291 val rotated = syntax
   292   (Scan.lift (Scan.optional P.int 1) >> (fn n => Thm.rule_attribute (K (rotate_prems n))));
   293 
   294 val abs_def = no_args (Thm.rule_attribute (K Drule.abs_def));
   295 
   296 
   297 (* theory setup *)
   298 
   299 val _ = Context.>> (Context.map_theory
   300  (add_attributes
   301    [("attribute", internal_att, "internal attribute"),
   302     ("tagged", tagged, "tagged theorem"),
   303     ("untagged", untagged, "untagged theorem"),
   304     ("kind", kind, "theorem kind"),
   305     ("COMP", COMP_att, "direct composition with rules (no lifting)"),
   306     ("THEN", THEN_att, "resolution with rule"),
   307     ("OF", OF_att, "rule applied to facts"),
   308     ("rename_abs", rename_abs, "rename bound variables in abstractions"),
   309     ("unfolded", unfolded, "unfolded definitions"),
   310     ("folded", folded, "folded definitions"),
   311     ("standard", standard, "result put into standard form"),
   312     ("elim_format", elim_format, "destruct rule turned into elimination rule format"),
   313     ("no_vars", no_vars, "frozen schematic vars"),
   314     ("eta_long", eta_long, "put theorem into eta long beta normal form"),
   315     ("consumes", consumes, "number of consumed facts"),
   316     ("case_names", case_names, "named rule cases"),
   317     ("case_conclusion", case_conclusion, "named conclusion of rule cases"),
   318     ("params", params, "named rule parameters"),
   319     ("atomize", no_args ObjectLogic.declare_atomize, "declaration of atomize rule"),
   320     ("rulify", no_args ObjectLogic.declare_rulify, "declaration of rulify rule"),
   321     ("rule_format", rule_format, "result put into standard rule format"),
   322     ("rotated", rotated, "rotated theorem premises"),
   323     ("defn", add_del_args LocalDefs.defn_add LocalDefs.defn_del,
   324       "declaration of definitional transformations"),
   325     ("abs_def", abs_def, "abstract over free variables of a definition")]));
   326 
   327 
   328 
   329 (** configuration options **)
   330 
   331 (* naming *)
   332 
   333 structure Configs = TheoryDataFun
   334 (
   335   type T = Config.value Config.T Symtab.table;
   336   val empty = Symtab.empty;
   337   val copy = I;
   338   val extend = I;
   339   fun merge _ = Symtab.merge (K true);
   340 );
   341 
   342 fun print_configs ctxt =
   343   let
   344     val thy = ProofContext.theory_of ctxt;
   345     fun prt (name, config) =
   346       let val value = Config.get ctxt config in
   347         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   348           Pretty.str (Config.print_value value)]
   349       end;
   350     val configs = NameSpace.extern_table (#1 (Attributes.get thy), Configs.get thy);
   351   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   352 
   353 
   354 (* concrete syntax *)
   355 
   356 local
   357 
   358 val equals = P.$$$ "=";
   359 
   360 fun scan_value (Config.Bool _) =
   361       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   362       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   363       Scan.succeed (Config.Bool true)
   364   | scan_value (Config.Int _) = equals |-- P.int >> Config.Int
   365   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   366 
   367 fun scan_config thy config =
   368   let val config_type = Config.get_thy thy config
   369   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   370 
   371 in
   372 
   373 fun register_config config thy =
   374   let
   375     val bname = Config.name_of config;
   376     val name = Sign.full_bname thy bname;
   377   in
   378     thy
   379     |> add_attributes [(bname, syntax (Scan.lift (scan_config thy config) >> Morphism.form),
   380       "configuration option")]
   381     |> Configs.map (Symtab.update (name, config))
   382   end;
   383 
   384 fun declare_config make coerce global name default =
   385   let
   386     val config_value = Config.declare global name (make default);
   387     val config = coerce config_value;
   388   in (config, register_config config_value) end;
   389 
   390 val config_bool   = declare_config Config.Bool Config.bool false;
   391 val config_int    = declare_config Config.Int Config.int false;
   392 val config_string = declare_config Config.String Config.string false;
   393 
   394 val config_bool_global   = declare_config Config.Bool Config.bool true;
   395 val config_int_global    = declare_config Config.Int Config.int true;
   396 val config_string_global = declare_config Config.String Config.string true;
   397 
   398 end;
   399 
   400 
   401 (* theory setup *)
   402 
   403 val _ = Context.>> (Context.map_theory
   404  (register_config Unify.trace_bound_value #>
   405   register_config Unify.search_bound_value #>
   406   register_config Unify.trace_simp_value #>
   407   register_config Unify.trace_types_value #>
   408   register_config MetaSimplifier.simp_depth_limit_value));
   409 
   410 end;