src/Pure/Syntax/syn_trans.ML
author wenzelm
Mon Jul 09 11:44:20 2007 +0200 (2007-07-09)
changeset 23660 18765718cf62
parent 21773 0038f5fc2065
child 23824 8ad7131dbfcf
permissions -rw-r--r--
type output = string indicates raw system output;
     1 (*  Title:      Pure/Syntax/syn_trans.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     4 
     5 Syntax translation functions.
     6 *)
     7 
     8 signature SYN_TRANS0 =
     9 sig
    10   val eta_contract: bool ref
    11   val atomic_abs_tr': string * typ * term -> term * term
    12   val mk_binder_tr: string * string -> string * (term list -> term)
    13   val mk_binder_tr': string * string -> string * (term list -> term)
    14   val dependent_tr': string * string -> term list -> term
    15   val antiquote_tr: string -> term -> term
    16   val quote_tr: string -> term -> term
    17   val quote_antiquote_tr: string -> string -> string -> string * (term list -> term)
    18   val antiquote_tr': string -> term -> term
    19   val quote_tr': string -> term -> term
    20   val quote_antiquote_tr': string -> string -> string -> string * (term list -> term)
    21   val mark_bound: string -> term
    22   val mark_boundT: string * typ -> term
    23   val bound_vars: (string * typ) list -> term -> term
    24   val variant_abs: string * typ * term -> string * term
    25   val variant_abs': string * typ * term -> string * term
    26 end;
    27 
    28 signature SYN_TRANS1 =
    29 sig
    30   include SYN_TRANS0
    31   val non_typed_tr': (term list -> term) -> bool -> typ -> term list -> term
    32   val non_typed_tr'': ('a -> term list -> term) -> 'a -> bool -> typ -> term list -> term
    33   val constrainAbsC: string
    34   val pure_trfuns:
    35       (string * (Ast.ast list -> Ast.ast)) list *
    36       (string * (term list -> term)) list *
    37       (string * (term list -> term)) list *
    38       (string * (Ast.ast list -> Ast.ast)) list
    39   val pure_trfunsT: (string * (bool -> typ -> term list -> term)) list
    40   val struct_trfuns: string list ->
    41       (string * (Ast.ast list -> Ast.ast)) list *
    42       (string * (term list -> term)) list *
    43       (string * (bool -> typ -> term list -> term)) list *
    44       (string * (Ast.ast list -> Ast.ast)) list
    45 end;
    46 
    47 signature SYN_TRANS =
    48 sig
    49   include SYN_TRANS1
    50   val abs_tr': term -> term
    51   val prop_tr': term -> term
    52   val appl_ast_tr': Ast.ast * Ast.ast list -> Ast.ast
    53   val applC_ast_tr': Ast.ast * Ast.ast list -> Ast.ast
    54   val pts_to_asts: Proof.context ->
    55     (string -> (Proof.context -> Ast.ast list -> Ast.ast) option) ->
    56     Parser.parsetree list -> Ast.ast list
    57   val asts_to_terms: Proof.context ->
    58     (string -> (Proof.context -> term list -> term) option) -> Ast.ast list -> term list
    59 end;
    60 
    61 structure SynTrans: SYN_TRANS =
    62 struct
    63 
    64 
    65 (** parse (ast) translations **)
    66 
    67 (* constify *)
    68 
    69 fun constify_ast_tr [Ast.Variable c] = Ast.Constant c
    70   | constify_ast_tr asts = raise Ast.AST ("constify_ast_tr", asts);
    71 
    72 
    73 (* application *)
    74 
    75 fun appl_ast_tr [f, args] = Ast.Appl (f :: Ast.unfold_ast "_args" args)
    76   | appl_ast_tr asts = raise Ast.AST ("appl_ast_tr", asts);
    77 
    78 fun applC_ast_tr [f, args] = Ast.Appl (f :: Ast.unfold_ast "_cargs" args)
    79   | applC_ast_tr asts = raise Ast.AST ("applC_ast_tr", asts);
    80 
    81 
    82 (* abstraction *)
    83 
    84 fun idtyp_ast_tr (*"_idtyp"*) [x, ty] = Ast.Appl [Ast.Constant "_constrain", x, ty]
    85   | idtyp_ast_tr (*"_idtyp"*) asts = raise Ast.AST ("idtyp_ast_tr", asts);
    86 
    87 fun idtypdummy_ast_tr (*"_idtypdummy"*) [ty] =
    88       Ast.Appl [Ast.Constant "_constrain", Ast.Constant "_idtdummy", ty]
    89   | idtypdummy_ast_tr (*"_idtypdummy"*) asts = raise Ast.AST ("idtyp_ast_tr", asts);
    90 
    91 fun lambda_ast_tr (*"_lambda"*) [pats, body] =
    92       Ast.fold_ast_p "_abs" (Ast.unfold_ast "_pttrns" pats, body)
    93   | lambda_ast_tr (*"_lambda"*) asts = raise Ast.AST ("lambda_ast_tr", asts);
    94 
    95 val constrainAbsC = "_constrainAbs";
    96 
    97 fun absfree_proper (x, T, t) =
    98   if can Name.dest_internal x then error ("Illegal internal variable in abstraction: " ^ quote x)
    99   else Term.absfree (x, T, t);
   100 
   101 fun abs_tr (*"_abs"*) [Free (x, T), t] = absfree_proper (x, T, t)
   102   | abs_tr (*"_abs"*) [Const ("_idtdummy", T), t] = Term.absdummy (T, t)
   103   | abs_tr (*"_abs"*) [Const ("_constrain", _) $ Free (x, T) $ tT, t] =
   104       Lexicon.const constrainAbsC $ absfree_proper (x, T, t) $ tT
   105   | abs_tr (*"_abs"*) [Const ("_constrain", _) $ Const ("_idtdummy", T) $ tT, t] =
   106       Lexicon.const constrainAbsC $ Term.absdummy (T, t) $ tT
   107   | abs_tr (*"_abs"*) ts = raise TERM ("abs_tr", ts);
   108 
   109 
   110 (* binder *)
   111 
   112 fun mk_binder_tr (syn, name) =
   113   let
   114     fun tr (Free (x, T), t) = Lexicon.const name $ absfree_proper (x, T, t)
   115       | tr (Const ("_idtdummy", T), t) = Lexicon.const name $ Term.absdummy (T, t)
   116       | tr (Const ("_constrain", _) $ Free (x, T) $ tT, t) =
   117           Lexicon.const name $ (Lexicon.const constrainAbsC $ absfree_proper (x, T, t) $ tT)
   118       | tr (Const ("_constrain", _) $ Const ("_idtdummy", T) $ tT, t) =
   119           Lexicon.const name $ (Lexicon.const constrainAbsC $ Term.absdummy (T, t) $ tT)
   120       | tr (Const ("_idts", _) $ idt $ idts, t) = tr (idt, tr (idts, t))
   121       | tr (t1, t2) = raise TERM ("binder_tr", [t1, t2]);
   122 
   123     fun binder_tr [idts, body] = tr (idts, body)
   124       | binder_tr ts = raise TERM ("binder_tr", ts);
   125   in (syn, binder_tr) end;
   126 
   127 
   128 (* meta propositions *)
   129 
   130 fun aprop_tr (*"_aprop"*) [t] = Lexicon.const "_constrain" $ t $ Lexicon.const "prop"
   131   | aprop_tr (*"_aprop"*) ts = raise TERM ("aprop_tr", ts);
   132 
   133 fun ofclass_tr (*"_ofclass"*) [ty, cls] =
   134       cls $ (Lexicon.const "_constrain" $ Lexicon.const "TYPE" $
   135         (Lexicon.const "itself" $ ty))
   136   | ofclass_tr (*"_ofclass"*) ts = raise TERM ("ofclass_tr", ts);
   137 
   138 
   139 (* meta implication *)
   140 
   141 fun bigimpl_ast_tr (*"_bigimpl"*) (asts as [asms, concl]) =
   142       let val prems =
   143         (case Ast.unfold_ast_p "_asms" asms of
   144           (asms', Ast.Appl [Ast.Constant "_asm", asm']) => asms' @ [asm']
   145         | _ => raise Ast.AST ("bigimpl_ast_tr", asts))
   146       in Ast.fold_ast_p "==>" (prems, concl) end
   147   | bigimpl_ast_tr (*"_bigimpl"*) asts = raise Ast.AST ("bigimpl_ast_tr", asts);
   148 
   149 
   150 (* type reflection *)
   151 
   152 fun type_tr (*"_TYPE"*) [ty] =
   153       Lexicon.const "_constrain" $ Lexicon.const "TYPE" $ (Lexicon.const "itself" $ ty)
   154   | type_tr (*"_TYPE"*) ts = raise TERM ("type_tr", ts);
   155 
   156 
   157 (* dddot *)
   158 
   159 fun dddot_tr (*"_DDDOT"*) ts = Term.list_comb (Lexicon.var SynExt.dddot_indexname, ts);
   160 
   161 
   162 (* quote / antiquote *)
   163 
   164 fun antiquote_tr name =
   165   let
   166     fun tr i ((t as Const (c, _)) $ u) =
   167           if c = name then tr i u $ Bound i
   168           else tr i t $ tr i u
   169       | tr i (t $ u) = tr i t $ tr i u
   170       | tr i (Abs (x, T, t)) = Abs (x, T, tr (i + 1) t)
   171       | tr _ a = a;
   172   in tr 0 end;
   173 
   174 fun quote_tr name t = Abs ("s", dummyT, antiquote_tr name (Term.incr_boundvars 1 t));
   175 
   176 fun quote_antiquote_tr quoteN antiquoteN name =
   177   let
   178     fun tr [t] = Lexicon.const name $ quote_tr antiquoteN t
   179       | tr ts = raise TERM ("quote_tr", ts);
   180   in (quoteN, tr) end;
   181 
   182 
   183 (* indexed syntax *)
   184 
   185 fun struct_ast_tr (*"_struct"*) [Ast.Appl [Ast.Constant "_index", ast]] = ast
   186   | struct_ast_tr (*"_struct"*) asts = Ast.mk_appl (Ast.Constant "_struct") asts;
   187 
   188 fun index_ast_tr ast =
   189   Ast.mk_appl (Ast.Constant "_index") [Ast.mk_appl (Ast.Constant "_struct") [ast]];
   190 
   191 fun indexdefault_ast_tr (*"_indexdefault"*) [] =
   192       index_ast_tr (Ast.Constant "_indexdefault")
   193   | indexdefault_ast_tr (*"_indexdefault"*) asts =
   194       raise Ast.AST ("indexdefault_ast_tr", asts);
   195 
   196 fun indexnum_ast_tr (*"_indexnum"*) [ast] =
   197       index_ast_tr (Ast.mk_appl (Ast.Constant "_indexnum") [ast])
   198   | indexnum_ast_tr (*"_indexnum"*) asts = raise Ast.AST ("indexnum_ast_tr", asts);
   199 
   200 fun indexvar_ast_tr (*"_indexvar"*) [] =
   201       Ast.mk_appl (Ast.Constant "_index") [Ast.Variable "some_index"]
   202   | indexvar_ast_tr (*"_indexvar"*) asts = raise Ast.AST ("indexvar_ast_tr", asts);
   203 
   204 fun index_tr (*"_index"*) [t] = t
   205   | index_tr (*"_index"*) ts = raise TERM ("index_tr", ts);
   206 
   207 
   208 (* implicit structures *)
   209 
   210 fun the_struct structs i =
   211   if 1 <= i andalso i <= length structs then List.nth (structs, i - 1)
   212   else raise error ("Illegal reference to implicit structure #" ^ string_of_int i);
   213 
   214 fun struct_tr structs (*"_struct"*) [Const ("_indexdefault", _)] =
   215       Lexicon.free (the_struct structs 1)
   216   | struct_tr structs (*"_struct"*) [t as (Const ("_indexnum", _) $ Const (s, _))] =
   217       Lexicon.free (the_struct structs
   218         (case Lexicon.read_nat s of SOME n => n | NONE => raise TERM ("struct_tr", [t])))
   219   | struct_tr _ (*"_struct"*) ts = raise TERM ("struct_tr", ts);
   220 
   221 
   222 
   223 (** print (ast) translations **)
   224 
   225 (* types *)
   226 
   227 fun non_typed_tr' f _ _ ts = f ts;
   228 fun non_typed_tr'' f x _ _ ts = f x ts;
   229 
   230 
   231 (* application *)
   232 
   233 fun appl_ast_tr' (f, []) = raise Ast.AST ("appl_ast_tr'", [f])
   234   | appl_ast_tr' (f, args) = Ast.Appl [Ast.Constant "_appl", f, Ast.fold_ast "_args" args];
   235 
   236 fun applC_ast_tr' (f, []) = raise Ast.AST ("applC_ast_tr'", [f])
   237   | applC_ast_tr' (f, args) = Ast.Appl [Ast.Constant "_applC", f, Ast.fold_ast "_cargs" args];
   238 
   239 
   240 (* abstraction *)
   241 
   242 fun mark_boundT (x, T) = Const ("_bound", T --> T) $ Free (x, T);
   243 fun mark_bound x = mark_boundT (x, dummyT);
   244 
   245 fun bound_vars vars body =
   246   subst_bounds (map mark_boundT (Term.rename_wrt_term body vars), body);
   247 
   248 fun strip_abss vars_of body_of tm =
   249   let
   250     val vars = vars_of tm;
   251     val body = body_of tm;
   252     val rev_new_vars = rename_wrt_term body vars;
   253     fun subst (x, T) b =
   254       if can Name.dest_internal x andalso not (Term.loose_bvar1 (b, 0))
   255       then (Const ("_idtdummy", T), incr_boundvars ~1 b)
   256       else (mark_boundT (x, T), Term.subst_bound (mark_bound x, b));
   257     val (rev_vars', body') = fold_map subst rev_new_vars body;
   258   in (rev rev_vars', body') end;
   259 
   260 
   261 (*do (partial) eta-contraction before printing*)
   262 
   263 val eta_contract = ref true;
   264 
   265 fun eta_contr tm =
   266   let
   267     fun is_aprop (Const ("_aprop", _)) = true
   268       | is_aprop _ = false;
   269 
   270     fun eta_abs (Abs (a, T, t)) =
   271           (case eta_abs t of
   272             t' as f $ u =>
   273               (case eta_abs u of
   274                 Bound 0 =>
   275                   if Term.loose_bvar1 (f, 0) orelse is_aprop f then Abs (a, T, t')
   276                   else  incr_boundvars ~1 f
   277               | _ => Abs (a, T, t'))
   278           | t' => Abs (a, T, t'))
   279       | eta_abs t = t;
   280   in
   281     if ! eta_contract then eta_abs tm else tm
   282   end;
   283 
   284 
   285 fun abs_tr' tm =
   286   uncurry (fold_rev (fn x => fn t => Lexicon.const "_abs" $ x $ t))
   287     (strip_abss strip_abs_vars strip_abs_body (eta_contr tm));
   288 
   289 fun atomic_abs_tr' (x, T, t) =
   290   let val [xT] = rename_wrt_term t [(x, T)]
   291   in (mark_boundT xT, subst_bound (mark_bound (fst xT), t)) end;
   292 
   293 fun abs_ast_tr' (*"_abs"*) asts =
   294   (case Ast.unfold_ast_p "_abs" (Ast.Appl (Ast.Constant "_abs" :: asts)) of
   295     ([], _) => raise Ast.AST ("abs_ast_tr'", asts)
   296   | (xs, body) => Ast.Appl [Ast.Constant "_lambda", Ast.fold_ast "_pttrns" xs, body]);
   297 
   298 
   299 (* binder *)
   300 
   301 fun mk_binder_tr' (name, syn) =
   302   let
   303     fun mk_idts [] = raise Match    (*abort translation*)
   304       | mk_idts [idt] = idt
   305       | mk_idts (idt :: idts) = Lexicon.const "_idts" $ idt $ mk_idts idts;
   306 
   307     fun tr' t =
   308       let
   309         val (xs, bd) = strip_abss (strip_qnt_vars name) (strip_qnt_body name) t;
   310       in Lexicon.const syn $ mk_idts xs $ bd end;
   311 
   312     fun binder_tr' (t :: ts) = Term.list_comb (tr' (Lexicon.const name $ t), ts)
   313       | binder_tr' [] = raise Match;
   314   in (name, binder_tr') end;
   315 
   316 
   317 (* idtyp constraints *)
   318 
   319 fun idtyp_ast_tr' a [Ast.Appl [Ast.Constant c, x, ty], xs] =
   320       if c = "_constrain" then
   321         Ast.Appl [ Ast.Constant a,  Ast.Appl [Ast.Constant "_idtyp", x, ty], xs]
   322       else raise Match
   323   | idtyp_ast_tr' _ _ = raise Match;
   324 
   325 
   326 (* meta propositions *)
   327 
   328 fun prop_tr' tm =
   329   let
   330     fun aprop t = Lexicon.const "_aprop" $ t;
   331 
   332     fun is_prop Ts t =
   333       fastype_of1 (Ts, t) = propT handle TERM _ => false;
   334 
   335     fun is_term (Const ("ProtoPure.term", _) $ _) = true
   336       | is_term _ = false;
   337 
   338     fun tr' _ (t as Const _) = t
   339       | tr' Ts (t as Const ("_bound", _) $ u) =
   340           if is_prop Ts u then aprop t else t
   341       | tr' _ (t as Free (x, T)) =
   342           if T = propT then aprop (Lexicon.free x) else t
   343       | tr' _ (t as Var (xi, T)) =
   344           if T = propT then aprop (Lexicon.var xi) else t
   345       | tr' Ts (t as Bound _) =
   346           if is_prop Ts t then aprop t else t
   347       | tr' Ts (Abs (x, T, t)) = Abs (x, T, tr' (T :: Ts) t)
   348       | tr' Ts (t as t1 $ (t2 as Const ("TYPE", Type ("itself", [T])))) =
   349           if is_prop Ts t andalso not (is_term t) then Const ("_mk_ofclass", T) $ tr' Ts t1
   350           else tr' Ts t1 $ tr' Ts t2
   351       | tr' Ts (t as t1 $ t2) =
   352           (if is_Const (Term.head_of t) orelse not (is_prop Ts t)
   353             then I else aprop) (tr' Ts t1 $ tr' Ts t2);
   354   in tr' [] tm end;
   355 
   356 fun mk_ofclass_tr' show_sorts (*"_mk_ofclass"*) T [t] =
   357       Lexicon.const "_ofclass" $ TypeExt.term_of_typ show_sorts T $ t
   358   | mk_ofclass_tr' _ (*"_mk_ofclass"*) T ts = raise TYPE ("mk_ofclass_tr'", [T], ts);
   359 
   360 
   361 (* meta implication *)
   362 
   363 fun impl_ast_tr' (*"==>"*) asts =
   364   if TypeExt.no_brackets () then raise Match
   365   else
   366     (case Ast.unfold_ast_p "==>" (Ast.Appl (Ast.Constant "==>" :: asts)) of
   367       (prems as _ :: _ :: _, concl) =>
   368         let
   369           val (asms, asm) = split_last prems;
   370           val asms' = Ast.fold_ast_p "_asms" (asms, Ast.Appl [Ast.Constant "_asm", asm]);
   371         in Ast.Appl [Ast.Constant "_bigimpl", asms', concl] end
   372     | _ => raise Match);
   373 
   374 
   375 (* type reflection *)
   376 
   377 fun type_tr' show_sorts (*"TYPE"*) (Type ("itself", [T])) ts =
   378       Term.list_comb (Lexicon.const "_TYPE" $ TypeExt.term_of_typ show_sorts T, ts)
   379   | type_tr' _ _ _ = raise Match;
   380 
   381 
   382 (* type constraints *)
   383 
   384 fun type_constraint_tr' show_sorts (*"_type_constraint_"*) (Type ("fun", [T, _])) (t :: ts) =
   385       Term.list_comb (Lexicon.const SynExt.constrainC $ t $ TypeExt.term_of_typ show_sorts T, ts)
   386   | type_constraint_tr' _ _ _ = raise Match;
   387 
   388 
   389 (* dependent / nondependent quantifiers *)
   390 
   391 fun var_abs mark (x, T, b) =
   392   let val ([x'], _) = Name.variants [x] (Term.declare_term_names b Name.context)
   393   in (x', subst_bound (mark (x', T), b)) end;
   394 
   395 val variant_abs = var_abs Free;
   396 val variant_abs' = var_abs mark_boundT;
   397 
   398 fun dependent_tr' (q, r) (A :: Abs (x, T, B) :: ts) =
   399       if Term.loose_bvar1 (B, 0) then
   400         let val (x', B') = variant_abs' (x, dummyT, B);
   401         in Term.list_comb (Lexicon.const q $ mark_boundT (x', T) $ A $ B', ts) end
   402       else Term.list_comb (Lexicon.const r $ A $ B, ts)
   403   | dependent_tr' _ _ = raise Match;
   404 
   405 
   406 (* quote / antiquote *)
   407 
   408 fun antiquote_tr' name =
   409   let
   410     fun tr' i (t $ u) =
   411       if u aconv Bound i then Lexicon.const name $ tr' i t
   412       else tr' i t $ tr' i u
   413       | tr' i (Abs (x, T, t)) = Abs (x, T, tr' (i + 1) t)
   414       | tr' i a = if a aconv Bound i then raise Match else a;
   415   in tr' 0 end;
   416 
   417 fun quote_tr' name (Abs (_, _, t)) = Term.incr_boundvars ~1 (antiquote_tr' name t)
   418   | quote_tr' _ _ = raise Match;
   419 
   420 fun quote_antiquote_tr' quoteN antiquoteN name =
   421   let
   422     fun tr' (t :: ts) = Term.list_comb (Lexicon.const quoteN $ quote_tr' antiquoteN t, ts)
   423       | tr' _ = raise Match;
   424   in (name, tr') end;
   425 
   426 
   427 (* indexed syntax *)
   428 
   429 fun index_ast_tr' (*"_index"*) [Ast.Appl [Ast.Constant "_struct", ast]] = ast
   430   | index_ast_tr' _ = raise Match;
   431 
   432 
   433 (* implicit structures *)
   434 
   435 fun the_struct' structs s =
   436   [(case Lexicon.read_nat s of
   437     SOME i => Ast.Variable (the_struct structs i handle ERROR _ => raise Match)
   438   | NONE => raise Match)] |> Ast.mk_appl (Ast.Constant "_free");
   439 
   440 fun struct_ast_tr' structs (*"_struct"*) [Ast.Constant "_indexdefault"] =
   441       the_struct' structs "1"
   442   | struct_ast_tr' structs (*"_struct"*) [Ast.Appl [Ast.Constant "_indexnum", Ast.Constant s]] =
   443       the_struct' structs s
   444   | struct_ast_tr' _ _ = raise Match;
   445 
   446 
   447 
   448 (** Pure translations **)
   449 
   450 val pure_trfuns =
   451  ([("_constify", constify_ast_tr), ("_appl", appl_ast_tr), ("_applC", applC_ast_tr),
   452    ("_lambda", lambda_ast_tr), ("_idtyp", idtyp_ast_tr), ("_idtypdummy", idtypdummy_ast_tr),
   453    ("_bigimpl", bigimpl_ast_tr), ("_indexdefault", indexdefault_ast_tr),
   454    ("_indexnum", indexnum_ast_tr), ("_indexvar", indexvar_ast_tr), ("_struct", struct_ast_tr)],
   455   [("_abs", abs_tr), ("_aprop", aprop_tr), ("_ofclass", ofclass_tr),
   456    ("_TYPE", type_tr), ("_DDDOT", dddot_tr),
   457    ("_index", index_tr)],
   458   ([]: (string * (term list -> term)) list),
   459   [("_abs", abs_ast_tr'), ("_idts", idtyp_ast_tr' "_idts"),
   460    ("_pttrns", idtyp_ast_tr' "_pttrns"), ("==>", impl_ast_tr'),
   461    ("_index", index_ast_tr')]);
   462 
   463 val pure_trfunsT =
   464   [("_mk_ofclass", mk_ofclass_tr'), ("TYPE", type_tr'),
   465    ("_type_constraint_", type_constraint_tr')];
   466 
   467 fun struct_trfuns structs =
   468   ([], [("_struct", struct_tr structs)], [], [("_struct", struct_ast_tr' structs)]);
   469 
   470 
   471 
   472 (** pts_to_asts **)
   473 
   474 fun pts_to_asts ctxt trf pts =
   475   let
   476     fun trans a args =
   477       (case trf a of
   478         NONE => Ast.mk_appl (Ast.Constant a) args
   479       | SOME f => transform_failure (fn exn =>
   480             EXCEPTION (exn, "Error in parse ast translation for " ^ quote a))
   481           (fn () => f ctxt args) ());
   482 
   483     (*translate pt bottom-up*)
   484     fun ast_of (Parser.Node (a, pts)) = trans a (map ast_of pts)
   485       | ast_of (Parser.Tip tok) = Ast.Variable (Lexicon.str_of_token tok);
   486 
   487     val exn_results = map (capture ast_of) pts;
   488     val exns = map_filter get_exn exn_results;
   489     val results = map_filter get_result exn_results
   490   in (case (results, exns) of ([], exn :: _) => raise exn | _ => results) end;
   491 
   492 
   493 
   494 (** asts_to_terms **)
   495 
   496 fun asts_to_terms ctxt trf asts =
   497   let
   498     fun trans a args =
   499       (case trf a of
   500         NONE => Term.list_comb (Lexicon.const a, args)
   501       | SOME f => transform_failure (fn exn =>
   502             EXCEPTION (exn, "Error in parse translation for " ^ quote a))
   503           (fn () => f ctxt args) ());
   504 
   505     fun term_of (Ast.Constant a) = trans a []
   506       | term_of (Ast.Variable x) = Lexicon.read_var x
   507       | term_of (Ast.Appl (Ast.Constant a :: (asts as _ :: _))) =
   508           trans a (map term_of asts)
   509       | term_of (Ast.Appl (ast :: (asts as _ :: _))) =
   510           Term.list_comb (term_of ast, map term_of asts)
   511       | term_of (ast as Ast.Appl _) = raise Ast.AST ("ast_to_term: malformed ast", [ast]);
   512 
   513     val free_fixed = Term.map_aterms
   514       (fn t as Const (c, T) =>
   515           (case try (unprefix Lexicon.fixedN) c of
   516             NONE => t
   517           | SOME x => Free (x, T))
   518         | t => t);
   519 
   520     val exn_results = map (capture (term_of #> free_fixed)) asts;
   521     val exns = map_filter get_exn exn_results;
   522     val results = map_filter get_result exn_results
   523   in (case (results, exns) of ([], exn :: _) => raise exn | _ => results) end;
   524 
   525 end;