src/HOL/Algebra/FiniteProduct.thy
 author wenzelm Sun Mar 21 15:57:40 2010 +0100 (2010-03-21) changeset 35847 19f1f7066917 parent 35416 d8d7d1b785af child 35848 5443079512ea permissions -rw-r--r--
eliminated old constdefs;
1 (*  Title:      HOL/Algebra/FiniteProduct.thy
2     Author:     Clemens Ballarin, started 19 November 2002
4 This file is largely based on HOL/Finite_Set.thy.
5 *)
7 theory FiniteProduct imports Group begin
10 subsection {* Product Operator for Commutative Monoids *}
12 subsubsection {* Inductive Definition of a Relation for Products over Sets *}
14 text {* Instantiation of locale @{text LC} of theory @{text Finite_Set} is not
15   possible, because here we have explicit typing rules like
16   @{text "x \<in> carrier G"}.  We introduce an explicit argument for the domain
17   @{text D}. *}
19 inductive_set
20   foldSetD :: "['a set, 'b => 'a => 'a, 'a] => ('b set * 'a) set"
21   for D :: "'a set" and f :: "'b => 'a => 'a" and e :: 'a
22   where
23     emptyI [intro]: "e \<in> D ==> ({}, e) \<in> foldSetD D f e"
24   | insertI [intro]: "[| x ~: A; f x y \<in> D; (A, y) \<in> foldSetD D f e |] ==>
25                       (insert x A, f x y) \<in> foldSetD D f e"
27 inductive_cases empty_foldSetDE [elim!]: "({}, x) \<in> foldSetD D f e"
29 definition foldD :: "['a set, 'b => 'a => 'a, 'a, 'b set] => 'a" where
30   "foldD D f e A == THE x. (A, x) \<in> foldSetD D f e"
32 lemma foldSetD_closed:
33   "[| (A, z) \<in> foldSetD D f e ; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D
34       |] ==> z \<in> D";
35   by (erule foldSetD.cases) auto
37 lemma Diff1_foldSetD:
38   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; f x y \<in> D |] ==>
39    (A, f x y) \<in> foldSetD D f e"
40   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
41     apply auto
42   done
44 lemma foldSetD_imp_finite [simp]: "(A, x) \<in> foldSetD D f e ==> finite A"
45   by (induct set: foldSetD) auto
47 lemma finite_imp_foldSetD:
48   "[| finite A; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D |] ==>
49    EX x. (A, x) \<in> foldSetD D f e"
50 proof (induct set: finite)
51   case empty then show ?case by auto
52 next
53   case (insert x F)
54   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
55   with insert have "y \<in> D" by (auto dest: foldSetD_closed)
56   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
57     by (intro foldSetD.intros) auto
58   then show ?case ..
59 qed
62 text {* Left-Commutative Operations *}
64 locale LCD =
65   fixes B :: "'b set"
66   and D :: "'a set"
67   and f :: "'b => 'a => 'a"    (infixl "\<cdot>" 70)
68   assumes left_commute:
69     "[| x \<in> B; y \<in> B; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
70   and f_closed [simp, intro!]: "!!x y. [| x \<in> B; y \<in> D |] ==> f x y \<in> D"
72 lemma (in LCD) foldSetD_closed [dest]:
73   "(A, z) \<in> foldSetD D f e ==> z \<in> D";
74   by (erule foldSetD.cases) auto
76 lemma (in LCD) Diff1_foldSetD:
77   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; A \<subseteq> B |] ==>
78   (A, f x y) \<in> foldSetD D f e"
79   apply (subgoal_tac "x \<in> B")
80    prefer 2 apply fast
81   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
82     apply auto
83   done
85 lemma (in LCD) foldSetD_imp_finite [simp]:
86   "(A, x) \<in> foldSetD D f e ==> finite A"
87   by (induct set: foldSetD) auto
89 lemma (in LCD) finite_imp_foldSetD:
90   "[| finite A; A \<subseteq> B; e \<in> D |] ==> EX x. (A, x) \<in> foldSetD D f e"
91 proof (induct set: finite)
92   case empty then show ?case by auto
93 next
94   case (insert x F)
95   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
96   with insert have "y \<in> D" by auto
97   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
98     by (intro foldSetD.intros) auto
99   then show ?case ..
100 qed
102 lemma (in LCD) foldSetD_determ_aux:
103   "e \<in> D ==> \<forall>A x. A \<subseteq> B & card A < n --> (A, x) \<in> foldSetD D f e -->
104     (\<forall>y. (A, y) \<in> foldSetD D f e --> y = x)"
105   apply (induct n)
106    apply (auto simp add: less_Suc_eq) (* slow *)
107   apply (erule foldSetD.cases)
108    apply blast
109   apply (erule foldSetD.cases)
110    apply blast
111   apply clarify
112   txt {* force simplification of @{text "card A < card (insert ...)"}. *}
113   apply (erule rev_mp)
114   apply (simp add: less_Suc_eq_le)
115   apply (rule impI)
116   apply (rename_tac xa Aa ya xb Ab yb, case_tac "xa = xb")
117    apply (subgoal_tac "Aa = Ab")
118     prefer 2 apply (blast elim!: equalityE)
119    apply blast
120   txt {* case @{prop "xa \<notin> xb"}. *}
121   apply (subgoal_tac "Aa - {xb} = Ab - {xa} & xb \<in> Aa & xa \<in> Ab")
122    prefer 2 apply (blast elim!: equalityE)
123   apply clarify
124   apply (subgoal_tac "Aa = insert xb Ab - {xa}")
125    prefer 2 apply blast
126   apply (subgoal_tac "card Aa \<le> card Ab")
127    prefer 2
128    apply (rule Suc_le_mono [THEN subst])
129    apply (simp add: card_Suc_Diff1)
130   apply (rule_tac A1 = "Aa - {xb}" in finite_imp_foldSetD [THEN exE])
131      apply (blast intro: foldSetD_imp_finite finite_Diff)
132     apply best
133    apply assumption
134   apply (frule (1) Diff1_foldSetD)
135    apply best
136   apply (subgoal_tac "ya = f xb x")
137    prefer 2
138    apply (subgoal_tac "Aa \<subseteq> B")
139     prefer 2 apply best (* slow *)
140    apply (blast del: equalityCE)
141   apply (subgoal_tac "(Ab - {xa}, x) \<in> foldSetD D f e")
142    prefer 2 apply simp
143   apply (subgoal_tac "yb = f xa x")
144    prefer 2
145    apply (blast del: equalityCE dest: Diff1_foldSetD)
146   apply (simp (no_asm_simp))
147   apply (rule left_commute)
148     apply assumption
149    apply best (* slow *)
150   apply best
151   done
153 lemma (in LCD) foldSetD_determ:
154   "[| (A, x) \<in> foldSetD D f e; (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |]
155   ==> y = x"
156   by (blast intro: foldSetD_determ_aux [rule_format])
158 lemma (in LCD) foldD_equality:
159   "[| (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |] ==> foldD D f e A = y"
160   by (unfold foldD_def) (blast intro: foldSetD_determ)
162 lemma foldD_empty [simp]:
163   "e \<in> D ==> foldD D f e {} = e"
164   by (unfold foldD_def) blast
166 lemma (in LCD) foldD_insert_aux:
167   "[| x ~: A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
168     ((insert x A, v) \<in> foldSetD D f e) =
169     (EX y. (A, y) \<in> foldSetD D f e & v = f x y)"
170   apply auto
171   apply (rule_tac A1 = A in finite_imp_foldSetD [THEN exE])
172      apply (fastsimp dest: foldSetD_imp_finite)
173     apply assumption
174    apply assumption
175   apply (blast intro: foldSetD_determ)
176   done
178 lemma (in LCD) foldD_insert:
179     "[| finite A; x ~: A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
180      foldD D f e (insert x A) = f x (foldD D f e A)"
181   apply (unfold foldD_def)
182   apply (simp add: foldD_insert_aux)
183   apply (rule the_equality)
184    apply (auto intro: finite_imp_foldSetD
185      cong add: conj_cong simp add: foldD_def [symmetric] foldD_equality)
186   done
188 lemma (in LCD) foldD_closed [simp]:
189   "[| finite A; e \<in> D; A \<subseteq> B |] ==> foldD D f e A \<in> D"
190 proof (induct set: finite)
191   case empty then show ?case by (simp add: foldD_empty)
192 next
193   case insert then show ?case by (simp add: foldD_insert)
194 qed
196 lemma (in LCD) foldD_commute:
197   "[| finite A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
198    f x (foldD D f e A) = foldD D f (f x e) A"
199   apply (induct set: finite)
200    apply simp
201   apply (auto simp add: left_commute foldD_insert)
202   done
204 lemma Int_mono2:
205   "[| A \<subseteq> C; B \<subseteq> C |] ==> A Int B \<subseteq> C"
206   by blast
208 lemma (in LCD) foldD_nest_Un_Int:
209   "[| finite A; finite C; e \<in> D; A \<subseteq> B; C \<subseteq> B |] ==>
210    foldD D f (foldD D f e C) A = foldD D f (foldD D f e (A Int C)) (A Un C)"
211   apply (induct set: finite)
212    apply simp
213   apply (simp add: foldD_insert foldD_commute Int_insert_left insert_absorb
214     Int_mono2)
215   done
217 lemma (in LCD) foldD_nest_Un_disjoint:
218   "[| finite A; finite B; A Int B = {}; e \<in> D; A \<subseteq> B; C \<subseteq> B |]
219     ==> foldD D f e (A Un B) = foldD D f (foldD D f e B) A"
220   by (simp add: foldD_nest_Un_Int)
222 -- {* Delete rules to do with @{text foldSetD} relation. *}
224 declare foldSetD_imp_finite [simp del]
225   empty_foldSetDE [rule del]
226   foldSetD.intros [rule del]
227 declare (in LCD)
228   foldSetD_closed [rule del]
231 text {* Commutative Monoids *}
233 text {*
234   We enter a more restrictive context, with @{text "f :: 'a => 'a => 'a"}
235   instead of @{text "'b => 'a => 'a"}.
236 *}
238 locale ACeD =
239   fixes D :: "'a set"
240     and f :: "'a => 'a => 'a"    (infixl "\<cdot>" 70)
241     and e :: 'a
242   assumes ident [simp]: "x \<in> D ==> x \<cdot> e = x"
243     and commute: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y = y \<cdot> x"
244     and assoc: "[| x \<in> D; y \<in> D; z \<in> D |] ==> (x \<cdot> y) \<cdot> z = x \<cdot> (y \<cdot> z)"
245     and e_closed [simp]: "e \<in> D"
246     and f_closed [simp]: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y \<in> D"
248 lemma (in ACeD) left_commute:
249   "[| x \<in> D; y \<in> D; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
250 proof -
251   assume D: "x \<in> D" "y \<in> D" "z \<in> D"
252   then have "x \<cdot> (y \<cdot> z) = (y \<cdot> z) \<cdot> x" by (simp add: commute)
253   also from D have "... = y \<cdot> (z \<cdot> x)" by (simp add: assoc)
254   also from D have "z \<cdot> x = x \<cdot> z" by (simp add: commute)
255   finally show ?thesis .
256 qed
258 lemmas (in ACeD) AC = assoc commute left_commute
260 lemma (in ACeD) left_ident [simp]: "x \<in> D ==> e \<cdot> x = x"
261 proof -
262   assume "x \<in> D"
263   then have "x \<cdot> e = x" by (rule ident)
264   with `x \<in> D` show ?thesis by (simp add: commute)
265 qed
267 lemma (in ACeD) foldD_Un_Int:
268   "[| finite A; finite B; A \<subseteq> D; B \<subseteq> D |] ==>
269     foldD D f e A \<cdot> foldD D f e B =
270     foldD D f e (A Un B) \<cdot> foldD D f e (A Int B)"
271   apply (induct set: finite)
272    apply (simp add: left_commute LCD.foldD_closed [OF LCD.intro [of D]])
273   apply (simp add: AC insert_absorb Int_insert_left
274     LCD.foldD_insert [OF LCD.intro [of D]]
275     LCD.foldD_closed [OF LCD.intro [of D]]
276     Int_mono2)
277   done
279 lemma (in ACeD) foldD_Un_disjoint:
280   "[| finite A; finite B; A Int B = {}; A \<subseteq> D; B \<subseteq> D |] ==>
281     foldD D f e (A Un B) = foldD D f e A \<cdot> foldD D f e B"
282   by (simp add: foldD_Un_Int
283     left_commute LCD.foldD_closed [OF LCD.intro [of D]])
286 subsubsection {* Products over Finite Sets *}
288 definition
289   finprod :: "[('b, 'm) monoid_scheme, 'a => 'b, 'a set] => 'b" where
290   "finprod G f A ==
291     if finite A
292     then foldD (carrier G) (mult G o f) \<one>\<^bsub>G\<^esub> A
293     else undefined"
295 syntax
296   "_finprod" :: "index => idt => 'a set => 'b => 'b"
297       ("(3\<Otimes>__:_. _)" [1000, 0, 51, 10] 10)
298 syntax (xsymbols)
299   "_finprod" :: "index => idt => 'a set => 'b => 'b"
300       ("(3\<Otimes>__\<in>_. _)" [1000, 0, 51, 10] 10)
301 syntax (HTML output)
302   "_finprod" :: "index => idt => 'a set => 'b => 'b"
303       ("(3\<Otimes>__\<in>_. _)" [1000, 0, 51, 10] 10)
304 translations
305   "\<Otimes>\<index>i:A. b" == "CONST finprod \<struct>\<index> (%i. b) A"
306   -- {* Beware of argument permutation! *}
308 lemma (in comm_monoid) finprod_empty [simp]:
309   "finprod G f {} = \<one>"
310   by (simp add: finprod_def)
312 declare funcsetI [intro]
313   funcset_mem [dest]
315 context comm_monoid begin
317 lemma finprod_insert [simp]:
318   "[| finite F; a \<notin> F; f \<in> F -> carrier G; f a \<in> carrier G |] ==>
319    finprod G f (insert a F) = f a \<otimes> finprod G f F"
320   apply (rule trans)
321    apply (simp add: finprod_def)
322   apply (rule trans)
323    apply (rule LCD.foldD_insert [OF LCD.intro [of "insert a F"]])
324          apply simp
325          apply (rule m_lcomm)
326            apply fast
327           apply fast
328          apply assumption
329         apply (fastsimp intro: m_closed)
330        apply simp+
331    apply fast
332   apply (auto simp add: finprod_def)
333   done
335 lemma finprod_one [simp]:
336   "finite A ==> (\<Otimes>i:A. \<one>) = \<one>"
337 proof (induct set: finite)
338   case empty show ?case by simp
339 next
340   case (insert a A)
341   have "(%i. \<one>) \<in> A -> carrier G" by auto
342   with insert show ?case by simp
343 qed
345 lemma finprod_closed [simp]:
346   fixes A
347   assumes fin: "finite A" and f: "f \<in> A -> carrier G"
348   shows "finprod G f A \<in> carrier G"
349 using fin f
350 proof induct
351   case empty show ?case by simp
352 next
353   case (insert a A)
354   then have a: "f a \<in> carrier G" by fast
355   from insert have A: "f \<in> A -> carrier G" by fast
356   from insert A a show ?case by simp
357 qed
359 lemma funcset_Int_left [simp, intro]:
360   "[| f \<in> A -> C; f \<in> B -> C |] ==> f \<in> A Int B -> C"
361   by fast
363 lemma funcset_Un_left [iff]:
364   "(f \<in> A Un B -> C) = (f \<in> A -> C & f \<in> B -> C)"
365   by fast
367 lemma finprod_Un_Int:
368   "[| finite A; finite B; g \<in> A -> carrier G; g \<in> B -> carrier G |] ==>
369      finprod G g (A Un B) \<otimes> finprod G g (A Int B) =
370      finprod G g A \<otimes> finprod G g B"
371 -- {* The reversed orientation looks more natural, but LOOPS as a simprule! *}
372 proof (induct set: finite)
373   case empty then show ?case by (simp add: finprod_closed)
374 next
375   case (insert a A)
376   then have a: "g a \<in> carrier G" by fast
377   from insert have A: "g \<in> A -> carrier G" by fast
378   from insert A a show ?case
379     by (simp add: m_ac Int_insert_left insert_absorb finprod_closed
380           Int_mono2)
381 qed
383 lemma finprod_Un_disjoint:
384   "[| finite A; finite B; A Int B = {};
385       g \<in> A -> carrier G; g \<in> B -> carrier G |]
386    ==> finprod G g (A Un B) = finprod G g A \<otimes> finprod G g B"
387   apply (subst finprod_Un_Int [symmetric])
388       apply (auto simp add: finprod_closed)
389   done
391 lemma finprod_multf:
392   "[| finite A; f \<in> A -> carrier G; g \<in> A -> carrier G |] ==>
393    finprod G (%x. f x \<otimes> g x) A = (finprod G f A \<otimes> finprod G g A)"
394 proof (induct set: finite)
395   case empty show ?case by simp
396 next
397   case (insert a A) then
398   have fA: "f \<in> A -> carrier G" by fast
399   from insert have fa: "f a \<in> carrier G" by fast
400   from insert have gA: "g \<in> A -> carrier G" by fast
401   from insert have ga: "g a \<in> carrier G" by fast
402   from insert have fgA: "(%x. f x \<otimes> g x) \<in> A -> carrier G"
403     by (simp add: Pi_def)
404   show ?case
405     by (simp add: insert fA fa gA ga fgA m_ac)
406 qed
408 lemma finprod_cong':
409   "[| A = B; g \<in> B -> carrier G;
410       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
411 proof -
412   assume prems: "A = B" "g \<in> B -> carrier G"
413     "!!i. i \<in> B ==> f i = g i"
414   show ?thesis
415   proof (cases "finite B")
416     case True
417     then have "!!A. [| A = B; g \<in> B -> carrier G;
418       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
419     proof induct
420       case empty thus ?case by simp
421     next
422       case (insert x B)
423       then have "finprod G f A = finprod G f (insert x B)" by simp
424       also from insert have "... = f x \<otimes> finprod G f B"
425       proof (intro finprod_insert)
426         show "finite B" by fact
427       next
428         show "x ~: B" by fact
429       next
430         assume "x ~: B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
431           "g \<in> insert x B \<rightarrow> carrier G"
432         thus "f \<in> B -> carrier G" by fastsimp
433       next
434         assume "x ~: B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
435           "g \<in> insert x B \<rightarrow> carrier G"
436         thus "f x \<in> carrier G" by fastsimp
437       qed
438       also from insert have "... = g x \<otimes> finprod G g B" by fastsimp
439       also from insert have "... = finprod G g (insert x B)"
440       by (intro finprod_insert [THEN sym]) auto
441       finally show ?case .
442     qed
443     with prems show ?thesis by simp
444   next
445     case False with prems show ?thesis by (simp add: finprod_def)
446   qed
447 qed
449 lemma finprod_cong:
450   "[| A = B; f \<in> B -> carrier G = True;
451       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
452   (* This order of prems is slightly faster (3%) than the last two swapped. *)
453   by (rule finprod_cong') force+
455 text {*Usually, if this rule causes a failed congruence proof error,
456   the reason is that the premise @{text "g \<in> B -> carrier G"} cannot be shown.
457   Adding @{thm [source] Pi_def} to the simpset is often useful.
458   For this reason, @{thm [source] comm_monoid.finprod_cong}
459   is not added to the simpset by default.
460 *}
462 end
464 declare funcsetI [rule del]
465   funcset_mem [rule del]
467 context comm_monoid begin
469 lemma finprod_0 [simp]:
470   "f \<in> {0::nat} -> carrier G ==> finprod G f {..0} = f 0"
471 by (simp add: Pi_def)
473 lemma finprod_Suc [simp]:
474   "f \<in> {..Suc n} -> carrier G ==>
475    finprod G f {..Suc n} = (f (Suc n) \<otimes> finprod G f {..n})"
476 by (simp add: Pi_def atMost_Suc)
478 lemma finprod_Suc2:
479   "f \<in> {..Suc n} -> carrier G ==>
480    finprod G f {..Suc n} = (finprod G (%i. f (Suc i)) {..n} \<otimes> f 0)"
481 proof (induct n)
482   case 0 thus ?case by (simp add: Pi_def)
483 next
484   case Suc thus ?case by (simp add: m_assoc Pi_def)
485 qed
487 lemma finprod_mult [simp]:
488   "[| f \<in> {..n} -> carrier G; g \<in> {..n} -> carrier G |] ==>
489      finprod G (%i. f i \<otimes> g i) {..n::nat} =
490      finprod G f {..n} \<otimes> finprod G g {..n}"
491   by (induct n) (simp_all add: m_ac Pi_def)
493 (* The following two were contributed by Jeremy Avigad. *)
495 lemma finprod_reindex:
496   assumes fin: "finite A"
497     shows "f : (h ` A) \<rightarrow> carrier G \<Longrightarrow>
498         inj_on h A ==> finprod G f (h ` A) = finprod G (%x. f (h x)) A"
499   using fin apply induct
500   apply (auto simp add: finprod_insert Pi_def)
501 done
503 lemma finprod_const:
504   assumes fin [simp]: "finite A"
505       and a [simp]: "a : carrier G"
506     shows "finprod G (%x. a) A = a (^) card A"
507   using fin apply induct
508   apply force
509   apply (subst finprod_insert)
510   apply auto
511   apply (subst m_comm)
512   apply auto
513 done
515 (* The following lemma was contributed by Jesus Aransay. *)
517 lemma finprod_singleton:
518   assumes i_in_A: "i \<in> A" and fin_A: "finite A" and f_Pi: "f \<in> A \<rightarrow> carrier G"
519   shows "(\<Otimes>j\<in>A. if i = j then f j else \<one>) = f i"
520   using i_in_A finprod_insert [of "A - {i}" i "(\<lambda>j. if i = j then f j else \<one>)"]
521     fin_A f_Pi finprod_one [of "A - {i}"]
522     finprod_cong [of "A - {i}" "A - {i}" "(\<lambda>j. if i = j then f j else \<one>)" "(\<lambda>i. \<one>)"]
523   unfolding Pi_def simp_implies_def by (force simp add: insert_absorb)
525 end
527 end