src/HOL/Algebra/UnivPoly.thy
author wenzelm
Sun Mar 21 15:57:40 2010 +0100 (2010-03-21)
changeset 35847 19f1f7066917
parent 34915 7894c7dab132
child 35848 5443079512ea
child 36092 8f1e60d9f7cc
permissions -rw-r--r--
eliminated old constdefs;
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Author:    Clemens Ballarin, started 9 December 1996
     4   Copyright: Clemens Ballarin
     5 
     6 Contributions, in particular on long division, by Jesus Aransay.
     7 *)
     8 
     9 theory UnivPoly
    10 imports Module RingHom
    11 begin
    12 
    13 
    14 section {* Univariate Polynomials *}
    15 
    16 text {*
    17   Polynomials are formalised as modules with additional operations for
    18   extracting coefficients from polynomials and for obtaining monomials
    19   from coefficients and exponents (record @{text "up_ring"}).  The
    20   carrier set is a set of bounded functions from Nat to the
    21   coefficient domain.  Bounded means that these functions return zero
    22   above a certain bound (the degree).  There is a chapter on the
    23   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    24   which was implemented with axiomatic type classes.  This was later
    25   ported to Locales.
    26 *}
    27 
    28 
    29 subsection {* The Constructor for Univariate Polynomials *}
    30 
    31 text {*
    32   Functions with finite support.
    33 *}
    34 
    35 locale bound =
    36   fixes z :: 'a
    37     and n :: nat
    38     and f :: "nat => 'a"
    39   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    40 
    41 declare bound.intro [intro!]
    42   and bound.bound [dest]
    43 
    44 lemma bound_below:
    45   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    46 proof (rule classical)
    47   assume "~ ?thesis"
    48   then have "m < n" by arith
    49   with bound have "f n = z" ..
    50   with nonzero show ?thesis by contradiction
    51 qed
    52 
    53 record ('a, 'p) up_ring = "('a, 'p) module" +
    54   monom :: "['a, nat] => 'p"
    55   coeff :: "['p, nat] => 'a"
    56 
    57 definition up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    58   where up_def: "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero>\<^bsub>R\<^esub> n f)}"
    59 
    60 definition UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    61   where UP_def: "UP R == (|
    62    carrier = up R,
    63    mult = (%p:up R. %q:up R. %n. \<Oplus>\<^bsub>R\<^esub>i \<in> {..n}. p i \<otimes>\<^bsub>R\<^esub> q (n-i)),
    64    one = (%i. if i=0 then \<one>\<^bsub>R\<^esub> else \<zero>\<^bsub>R\<^esub>),
    65    zero = (%i. \<zero>\<^bsub>R\<^esub>),
    66    add = (%p:up R. %q:up R. %i. p i \<oplus>\<^bsub>R\<^esub> q i),
    67    smult = (%a:carrier R. %p:up R. %i. a \<otimes>\<^bsub>R\<^esub> p i),
    68    monom = (%a:carrier R. %n i. if i=n then a else \<zero>\<^bsub>R\<^esub>),
    69    coeff = (%p:up R. %n. p n) |)"
    70 
    71 text {*
    72   Properties of the set of polynomials @{term up}.
    73 *}
    74 
    75 lemma mem_upI [intro]:
    76   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    77   by (simp add: up_def Pi_def)
    78 
    79 lemma mem_upD [dest]:
    80   "f \<in> up R ==> f n \<in> carrier R"
    81   by (simp add: up_def Pi_def)
    82 
    83 context ring
    84 begin
    85 
    86 lemma bound_upD [dest]: "f \<in> up R ==> EX n. bound \<zero> n f" by (simp add: up_def)
    87 
    88 lemma up_one_closed: "(%n. if n = 0 then \<one> else \<zero>) \<in> up R" using up_def by force
    89 
    90 lemma up_smult_closed: "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R" by force
    91 
    92 lemma up_add_closed:
    93   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    94 proof
    95   fix n
    96   assume "p \<in> up R" and "q \<in> up R"
    97   then show "p n \<oplus> q n \<in> carrier R"
    98     by auto
    99 next
   100   assume UP: "p \<in> up R" "q \<in> up R"
   101   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   102   proof -
   103     from UP obtain n where boundn: "bound \<zero> n p" by fast
   104     from UP obtain m where boundm: "bound \<zero> m q" by fast
   105     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   106     proof
   107       fix i
   108       assume "max n m < i"
   109       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   110     qed
   111     then show ?thesis ..
   112   qed
   113 qed
   114 
   115 lemma up_a_inv_closed:
   116   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   117 proof
   118   assume R: "p \<in> up R"
   119   then obtain n where "bound \<zero> n p" by auto
   120   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   121   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   122 qed auto
   123 
   124 lemma up_minus_closed:
   125   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<ominus> q i) \<in> up R"
   126   using mem_upD [of p R] mem_upD [of q R] up_add_closed up_a_inv_closed a_minus_def [of _ R]
   127   by auto
   128 
   129 lemma up_mult_closed:
   130   "[| p \<in> up R; q \<in> up R |] ==>
   131   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   132 proof
   133   fix n
   134   assume "p \<in> up R" "q \<in> up R"
   135   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   136     by (simp add: mem_upD  funcsetI)
   137 next
   138   assume UP: "p \<in> up R" "q \<in> up R"
   139   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   140   proof -
   141     from UP obtain n where boundn: "bound \<zero> n p" by fast
   142     from UP obtain m where boundm: "bound \<zero> m q" by fast
   143     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   144     proof
   145       fix k assume bound: "n + m < k"
   146       {
   147         fix i
   148         have "p i \<otimes> q (k-i) = \<zero>"
   149         proof (cases "n < i")
   150           case True
   151           with boundn have "p i = \<zero>" by auto
   152           moreover from UP have "q (k-i) \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         next
   155           case False
   156           with bound have "m < k-i" by arith
   157           with boundm have "q (k-i) = \<zero>" by auto
   158           moreover from UP have "p i \<in> carrier R" by auto
   159           ultimately show ?thesis by simp
   160         qed
   161       }
   162       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   163         by (simp add: Pi_def)
   164     qed
   165     then show ?thesis by fast
   166   qed
   167 qed
   168 
   169 end
   170 
   171 
   172 subsection {* Effect of Operations on Coefficients *}
   173 
   174 locale UP =
   175   fixes R (structure) and P (structure)
   176   defines P_def: "P == UP R"
   177 
   178 locale UP_ring = UP + R: ring R
   179 
   180 locale UP_cring = UP + R: cring R
   181 
   182 sublocale UP_cring < UP_ring
   183   by intro_locales [1] (rule P_def)
   184 
   185 locale UP_domain = UP + R: "domain" R
   186 
   187 sublocale UP_domain < UP_cring
   188   by intro_locales [1] (rule P_def)
   189 
   190 context UP
   191 begin
   192 
   193 text {*Temporarily declare @{thm P_def} as simp rule.*}
   194 
   195 declare P_def [simp]
   196 
   197 lemma up_eqI:
   198   assumes prem: "!!n. coeff P p n = coeff P q n" and R: "p \<in> carrier P" "q \<in> carrier P"
   199   shows "p = q"
   200 proof
   201   fix x
   202   from prem and R show "p x = q x" by (simp add: UP_def)
   203 qed
   204 
   205 lemma coeff_closed [simp]:
   206   "p \<in> carrier P ==> coeff P p n \<in> carrier R" by (auto simp add: UP_def)
   207 
   208 end
   209 
   210 context UP_ring 
   211 begin
   212 
   213 (* Theorems generalised from commutative rings to rings by Jesus Aransay. *)
   214 
   215 lemma coeff_monom [simp]:
   216   "a \<in> carrier R ==> coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   217 proof -
   218   assume R: "a \<in> carrier R"
   219   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   220     using up_def by force
   221   with R show ?thesis by (simp add: UP_def)
   222 qed
   223 
   224 lemma coeff_zero [simp]: "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>" by (auto simp add: UP_def)
   225 
   226 lemma coeff_one [simp]: "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   227   using up_one_closed by (simp add: UP_def)
   228 
   229 lemma coeff_smult [simp]:
   230   "[| a \<in> carrier R; p \<in> carrier P |] ==> coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   231   by (simp add: UP_def up_smult_closed)
   232 
   233 lemma coeff_add [simp]:
   234   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   235   by (simp add: UP_def up_add_closed)
   236 
   237 lemma coeff_mult [simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   239   by (simp add: UP_def up_mult_closed)
   240 
   241 end
   242 
   243 
   244 subsection {* Polynomials Form a Ring. *}
   245 
   246 context UP_ring
   247 begin
   248 
   249 text {* Operations are closed over @{term P}. *}
   250 
   251 lemma UP_mult_closed [simp]:
   252   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_mult_closed)
   253 
   254 lemma UP_one_closed [simp]:
   255   "\<one>\<^bsub>P\<^esub> \<in> carrier P" by (simp add: UP_def up_one_closed)
   256 
   257 lemma UP_zero_closed [intro, simp]:
   258   "\<zero>\<^bsub>P\<^esub> \<in> carrier P" by (auto simp add: UP_def)
   259 
   260 lemma UP_a_closed [intro, simp]:
   261   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_add_closed)
   262 
   263 lemma monom_closed [simp]:
   264   "a \<in> carrier R ==> monom P a n \<in> carrier P" by (auto simp add: UP_def up_def Pi_def)
   265 
   266 lemma UP_smult_closed [simp]:
   267   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P" by (simp add: UP_def up_smult_closed)
   268 
   269 end
   270 
   271 declare (in UP) P_def [simp del]
   272 
   273 text {* Algebraic ring properties *}
   274 
   275 context UP_ring
   276 begin
   277 
   278 lemma UP_a_assoc:
   279   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   280   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)" by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   281 
   282 lemma UP_l_zero [simp]:
   283   assumes R: "p \<in> carrier P"
   284   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p" by (rule up_eqI, simp_all add: R)
   285 
   286 lemma UP_l_neg_ex:
   287   assumes R: "p \<in> carrier P"
   288   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   289 proof -
   290   let ?q = "%i. \<ominus> (p i)"
   291   from R have closed: "?q \<in> carrier P"
   292     by (simp add: UP_def P_def up_a_inv_closed)
   293   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   294     by (simp add: UP_def P_def up_a_inv_closed)
   295   show ?thesis
   296   proof
   297     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   298       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   299   qed (rule closed)
   300 qed
   301 
   302 lemma UP_a_comm:
   303   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   304   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p" by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   305 
   306 lemma UP_m_assoc:
   307   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   308   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   309 proof (rule up_eqI)
   310   fix n
   311   {
   312     fix k and a b c :: "nat=>'a"
   313     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   314       "c \<in> UNIV -> carrier R"
   315     then have "k <= n ==>
   316       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   317       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   318       (is "_ \<Longrightarrow> ?eq k")
   319     proof (induct k)
   320       case 0 then show ?case by (simp add: Pi_def m_assoc)
   321     next
   322       case (Suc k)
   323       then have "k <= n" by arith
   324       from this R have "?eq k" by (rule Suc)
   325       with R show ?case
   326         by (simp cong: finsum_cong
   327              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   328            (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   329     qed
   330   }
   331   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   332     by (simp add: Pi_def)
   333 qed (simp_all add: R)
   334 
   335 lemma UP_r_one [simp]:
   336   assumes R: "p \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub> = p"
   337 proof (rule up_eqI)
   338   fix n
   339   show "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) n = coeff P p n"
   340   proof (cases n)
   341     case 0 
   342     {
   343       with R show ?thesis by simp
   344     }
   345   next
   346     case Suc
   347     {
   348       (*JE: in the locale UP_cring the proof was solved only with "by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)", but I did not get it to work here*)
   349       fix nn assume Succ: "n = Suc nn"
   350       have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = coeff P p (Suc nn)"
   351       proof -
   352         have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = (\<Oplus>i\<in>{..Suc nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" using R by simp
   353         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>) \<oplus> (\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))"
   354           using finsum_Suc [of "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "nn"] unfolding Pi_def using R by simp
   355         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>)"
   356         proof -
   357           have "(\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>)) = (\<Oplus>i\<in>{..nn}. \<zero>)"
   358             using finsum_cong [of "{..nn}" "{..nn}" "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "(\<lambda>i::nat. \<zero>)"] using R 
   359             unfolding Pi_def by simp
   360           also have "\<dots> = \<zero>" by simp
   361           finally show ?thesis using r_zero R by simp
   362         qed
   363         also have "\<dots> = coeff P p (Suc nn)" using R by simp
   364         finally show ?thesis by simp
   365       qed
   366       then show ?thesis using Succ by simp
   367     }
   368   qed
   369 qed (simp_all add: R)
   370   
   371 lemma UP_l_one [simp]:
   372   assumes R: "p \<in> carrier P"
   373   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   374 proof (rule up_eqI)
   375   fix n
   376   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   377   proof (cases n)
   378     case 0 with R show ?thesis by simp
   379   next
   380     case Suc with R show ?thesis
   381       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   382   qed
   383 qed (simp_all add: R)
   384 
   385 lemma UP_l_distr:
   386   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   387   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   388   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   389 
   390 lemma UP_r_distr:
   391   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   392   shows "r \<otimes>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = (r \<otimes>\<^bsub>P\<^esub> p) \<oplus>\<^bsub>P\<^esub> (r \<otimes>\<^bsub>P\<^esub> q)"
   393   by (rule up_eqI) (simp add: r_distr R Pi_def, simp_all add: R)
   394 
   395 theorem UP_ring: "ring P"
   396   by (auto intro!: ringI abelian_groupI monoidI UP_a_assoc)
   397     (auto intro: UP_a_comm UP_l_neg_ex UP_m_assoc UP_l_distr UP_r_distr)
   398 
   399 end
   400 
   401 
   402 subsection {* Polynomials Form a Commutative Ring. *}
   403 
   404 context UP_cring
   405 begin
   406 
   407 lemma UP_m_comm:
   408   assumes R1: "p \<in> carrier P" and R2: "q \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   409 proof (rule up_eqI)
   410   fix n
   411   {
   412     fix k and a b :: "nat=>'a"
   413     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   414     then have "k <= n ==>
   415       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) = (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   416       (is "_ \<Longrightarrow> ?eq k")
   417     proof (induct k)
   418       case 0 then show ?case by (simp add: Pi_def)
   419     next
   420       case (Suc k) then show ?case
   421         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   422     qed
   423   }
   424   note l = this
   425   from R1 R2 show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   426     unfolding coeff_mult [OF R1 R2, of n] 
   427     unfolding coeff_mult [OF R2 R1, of n] 
   428     using l [of "(\<lambda>i. coeff P p i)" "(\<lambda>i. coeff P q i)" "n"] by (simp add: Pi_def m_comm)
   429 qed (simp_all add: R1 R2)
   430 
   431 subsection{*Polynomials over a commutative ring for a commutative ring*}
   432 
   433 theorem UP_cring:
   434   "cring P" using UP_ring unfolding cring_def by (auto intro!: comm_monoidI UP_m_assoc UP_m_comm)
   435 
   436 end
   437 
   438 context UP_ring
   439 begin
   440 
   441 lemma UP_a_inv_closed [intro, simp]:
   442   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   443   by (rule abelian_group.a_inv_closed [OF ring.is_abelian_group [OF UP_ring]])
   444 
   445 lemma coeff_a_inv [simp]:
   446   assumes R: "p \<in> carrier P"
   447   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   448 proof -
   449   from R coeff_closed UP_a_inv_closed have
   450     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   451     by algebra
   452   also from R have "... =  \<ominus> (coeff P p n)"
   453     by (simp del: coeff_add add: coeff_add [THEN sym]
   454       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   455   finally show ?thesis .
   456 qed
   457 
   458 end
   459 
   460 sublocale UP_ring < P: ring P using UP_ring .
   461 sublocale UP_cring < P: cring P using UP_cring .
   462 
   463 
   464 subsection {* Polynomials Form an Algebra *}
   465 
   466 context UP_ring
   467 begin
   468 
   469 lemma UP_smult_l_distr:
   470   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   471   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   472   by (rule up_eqI) (simp_all add: R.l_distr)
   473 
   474 lemma UP_smult_r_distr:
   475   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   476   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   477   by (rule up_eqI) (simp_all add: R.r_distr)
   478 
   479 lemma UP_smult_assoc1:
   480       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   481       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   482   by (rule up_eqI) (simp_all add: R.m_assoc)
   483 
   484 lemma UP_smult_zero [simp]:
   485       "p \<in> carrier P ==> \<zero> \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   486   by (rule up_eqI) simp_all
   487 
   488 lemma UP_smult_one [simp]:
   489       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   490   by (rule up_eqI) simp_all
   491 
   492 lemma UP_smult_assoc2:
   493   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   494   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   495   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   496 
   497 end
   498 
   499 text {*
   500   Interpretation of lemmas from @{term algebra}.
   501 *}
   502 
   503 lemma (in cring) cring:
   504   "cring R" ..
   505 
   506 lemma (in UP_cring) UP_algebra:
   507   "algebra R P" by (auto intro!: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr
   508     UP_smult_assoc1 UP_smult_assoc2)
   509 
   510 sublocale UP_cring < algebra R P using UP_algebra .
   511 
   512 
   513 subsection {* Further Lemmas Involving Monomials *}
   514 
   515 context UP_ring
   516 begin
   517 
   518 lemma monom_zero [simp]:
   519   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>" by (simp add: UP_def P_def)
   520 
   521 lemma monom_mult_is_smult:
   522   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   523   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   524 proof (rule up_eqI)
   525   fix n
   526   show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   527   proof (cases n)
   528     case 0 with R show ?thesis by simp
   529   next
   530     case Suc with R show ?thesis
   531       using R.finsum_Suc2 by (simp del: R.finsum_Suc add: R.r_null Pi_def)
   532   qed
   533 qed (simp_all add: R)
   534 
   535 lemma monom_one [simp]:
   536   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   537   by (rule up_eqI) simp_all
   538 
   539 lemma monom_add [simp]:
   540   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   541   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   542   by (rule up_eqI) simp_all
   543 
   544 lemma monom_one_Suc:
   545   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   546 proof (rule up_eqI)
   547   fix k
   548   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   549   proof (cases "k = Suc n")
   550     case True show ?thesis
   551     proof -
   552       fix m
   553       from True have less_add_diff:
   554         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   555       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   556       also from True
   557       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   558         coeff P (monom P \<one> 1) (k - i))"
   559         by (simp cong: R.finsum_cong add: Pi_def)
   560       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   561         coeff P (monom P \<one> 1) (k - i))"
   562         by (simp only: ivl_disj_un_singleton)
   563       also from True
   564       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   565         coeff P (monom P \<one> 1) (k - i))"
   566         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   567           order_less_imp_not_eq Pi_def)
   568       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   569         by (simp add: ivl_disj_un_one)
   570       finally show ?thesis .
   571     qed
   572   next
   573     case False
   574     note neq = False
   575     let ?s =
   576       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   577     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   578     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   579     proof -
   580       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   581         by (simp cong: R.finsum_cong add: Pi_def)
   582       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   583         by (simp cong: R.finsum_cong add: Pi_def) arith
   584       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   585         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)
   586       show ?thesis
   587       proof (cases "k < n")
   588         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)
   589       next
   590         case False then have n_le_k: "n <= k" by arith
   591         show ?thesis
   592         proof (cases "n = k")
   593           case True
   594           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   595             by (simp cong: R.finsum_cong add: Pi_def)
   596           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   597             by (simp only: ivl_disj_un_singleton)
   598           finally show ?thesis .
   599         next
   600           case False with n_le_k have n_less_k: "n < k" by arith
   601           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   602             by (simp add: R.finsum_Un_disjoint f1 f2 Pi_def del: Un_insert_right)
   603           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   604             by (simp only: ivl_disj_un_singleton)
   605           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   606             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   607           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   608             by (simp only: ivl_disj_un_one)
   609           finally show ?thesis .
   610         qed
   611       qed
   612     qed
   613     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   614     finally show ?thesis .
   615   qed
   616 qed (simp_all)
   617 
   618 lemma monom_one_Suc2:
   619   "monom P \<one> (Suc n) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   620 proof (induct n)
   621   case 0 show ?case by simp
   622 next
   623   case Suc
   624   {
   625     fix k:: nat
   626     assume hypo: "monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   627     then show "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k)"
   628     proof -
   629       have lhs: "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   630         unfolding monom_one_Suc [of "Suc k"] unfolding hypo ..
   631       note cl = monom_closed [OF R.one_closed, of 1]
   632       note clk = monom_closed [OF R.one_closed, of k]
   633       have rhs: "monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   634         unfolding monom_one_Suc [of k] unfolding sym [OF m_assoc  [OF cl clk cl]] ..
   635       from lhs rhs show ?thesis by simp
   636     qed
   637   }
   638 qed
   639 
   640 text{*The following corollary follows from lemmas @{thm "monom_one_Suc"} 
   641   and @{thm "monom_one_Suc2"}, and is trivial in @{term UP_cring}*}
   642 
   643 corollary monom_one_comm: shows "monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   644   unfolding monom_one_Suc [symmetric] monom_one_Suc2 [symmetric] ..
   645 
   646 lemma monom_mult_smult:
   647   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   648   by (rule up_eqI) simp_all
   649 
   650 lemma monom_one_mult:
   651   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   652 proof (induct n)
   653   case 0 show ?case by simp
   654 next
   655   case Suc then show ?case
   656     unfolding add_Suc unfolding monom_one_Suc unfolding Suc.hyps
   657     using m_assoc monom_one_comm [of m] by simp
   658 qed
   659 
   660 lemma monom_one_mult_comm: "monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m = monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   661   unfolding monom_one_mult [symmetric] by (rule up_eqI) simp_all
   662 
   663 lemma monom_mult [simp]:
   664   assumes a_in_R: "a \<in> carrier R" and b_in_R: "b \<in> carrier R"
   665   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   666 proof (rule up_eqI)
   667   fix k 
   668   show "coeff P (monom P (a \<otimes> b) (n + m)) k = coeff P (monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m) k"
   669   proof (cases "n + m = k")
   670     case True 
   671     {
   672       show ?thesis
   673         unfolding True [symmetric]
   674           coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of "n + m"] 
   675           coeff_monom [OF a_in_R, of n] coeff_monom [OF b_in_R, of m]
   676         using R.finsum_cong [of "{.. n + m}" "{.. n + m}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = n + m - i then b else \<zero>))" 
   677           "(\<lambda>i. if n = i then a \<otimes> b else \<zero>)"]
   678           a_in_R b_in_R
   679         unfolding simp_implies_def
   680         using R.finsum_singleton [of n "{.. n + m}" "(\<lambda>i. a \<otimes> b)"]
   681         unfolding Pi_def by auto
   682     }
   683   next
   684     case False
   685     {
   686       show ?thesis
   687         unfolding coeff_monom [OF R.m_closed [OF a_in_R b_in_R], of "n + m" k] apply (simp add: False)
   688         unfolding coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of k]
   689         unfolding coeff_monom [OF a_in_R, of n] unfolding coeff_monom [OF b_in_R, of m] using False
   690         using R.finsum_cong [of "{..k}" "{..k}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = k - i then b else \<zero>))" "(\<lambda>i. \<zero>)"]
   691         unfolding Pi_def simp_implies_def using a_in_R b_in_R by force
   692     }
   693   qed
   694 qed (simp_all add: a_in_R b_in_R)
   695 
   696 lemma monom_a_inv [simp]:
   697   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   698   by (rule up_eqI) simp_all
   699 
   700 lemma monom_inj:
   701   "inj_on (%a. monom P a n) (carrier R)"
   702 proof (rule inj_onI)
   703   fix x y
   704   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   705   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   706   with R show "x = y" by simp
   707 qed
   708 
   709 end
   710 
   711 
   712 subsection {* The Degree Function *}
   713 
   714 definition deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   715   where "deg R p == LEAST n. bound \<zero>\<^bsub>R\<^esub> n (coeff (UP R) p)"
   716 
   717 context UP_ring
   718 begin
   719 
   720 lemma deg_aboveI:
   721   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   722   by (unfold deg_def P_def) (fast intro: Least_le)
   723 
   724 (*
   725 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   726 proof -
   727   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   728   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   729   then show ?thesis ..
   730 qed
   731 
   732 lemma bound_coeff_obtain:
   733   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   734 proof -
   735   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   736   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   737   with prem show P .
   738 qed
   739 *)
   740 
   741 lemma deg_aboveD:
   742   assumes "deg R p < m" and "p \<in> carrier P"
   743   shows "coeff P p m = \<zero>"
   744 proof -
   745   from `p \<in> carrier P` obtain n where "bound \<zero> n (coeff P p)"
   746     by (auto simp add: UP_def P_def)
   747   then have "bound \<zero> (deg R p) (coeff P p)"
   748     by (auto simp: deg_def P_def dest: LeastI)
   749   from this and `deg R p < m` show ?thesis ..
   750 qed
   751 
   752 lemma deg_belowI:
   753   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   754     and R: "p \<in> carrier P"
   755   shows "n <= deg R p"
   756 -- {* Logically, this is a slightly stronger version of
   757    @{thm [source] deg_aboveD} *}
   758 proof (cases "n=0")
   759   case True then show ?thesis by simp
   760 next
   761   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   762   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   763   then show ?thesis by arith
   764 qed
   765 
   766 lemma lcoeff_nonzero_deg:
   767   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   768   shows "coeff P p (deg R p) ~= \<zero>"
   769 proof -
   770   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   771   proof -
   772     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   773       by arith
   774     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   775       by (unfold deg_def P_def) simp
   776     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   777     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   778       by (unfold bound_def) fast
   779     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   780     then show ?thesis by (auto intro: that)
   781   qed
   782   with deg_belowI R have "deg R p = m" by fastsimp
   783   with m_coeff show ?thesis by simp
   784 qed
   785 
   786 lemma lcoeff_nonzero_nonzero:
   787   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   788   shows "coeff P p 0 ~= \<zero>"
   789 proof -
   790   have "EX m. coeff P p m ~= \<zero>"
   791   proof (rule classical)
   792     assume "~ ?thesis"
   793     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   794     with nonzero show ?thesis by contradiction
   795   qed
   796   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   797   from this and R have "m <= deg R p" by (rule deg_belowI)
   798   then have "m = 0" by (simp add: deg)
   799   with coeff show ?thesis by simp
   800 qed
   801 
   802 lemma lcoeff_nonzero:
   803   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   804   shows "coeff P p (deg R p) ~= \<zero>"
   805 proof (cases "deg R p = 0")
   806   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   807 next
   808   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   809 qed
   810 
   811 lemma deg_eqI:
   812   "[| !!m. n < m ==> coeff P p m = \<zero>;
   813       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   814 by (fast intro: le_antisym deg_aboveI deg_belowI)
   815 
   816 text {* Degree and polynomial operations *}
   817 
   818 lemma deg_add [simp]:
   819   "p \<in> carrier P \<Longrightarrow> q \<in> carrier P \<Longrightarrow>
   820   deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   821 by(rule deg_aboveI)(simp_all add: deg_aboveD)
   822 
   823 lemma deg_monom_le:
   824   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   825   by (intro deg_aboveI) simp_all
   826 
   827 lemma deg_monom [simp]:
   828   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   829   by (fastsimp intro: le_antisym deg_aboveI deg_belowI)
   830 
   831 lemma deg_const [simp]:
   832   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   833 proof (rule le_antisym)
   834   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   835 next
   836   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   837 qed
   838 
   839 lemma deg_zero [simp]:
   840   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   841 proof (rule le_antisym)
   842   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   843 next
   844   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   845 qed
   846 
   847 lemma deg_one [simp]:
   848   "deg R \<one>\<^bsub>P\<^esub> = 0"
   849 proof (rule le_antisym)
   850   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   851 next
   852   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   853 qed
   854 
   855 lemma deg_uminus [simp]:
   856   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   857 proof (rule le_antisym)
   858   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   859 next
   860   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   861     by (simp add: deg_belowI lcoeff_nonzero_deg
   862       inj_on_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)
   863 qed
   864 
   865 text{*The following lemma is later \emph{overwritten} by the most
   866   specific one for domains, @{text deg_smult}.*}
   867 
   868 lemma deg_smult_ring [simp]:
   869   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   870   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   871   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   872 
   873 end
   874 
   875 context UP_domain
   876 begin
   877 
   878 lemma deg_smult [simp]:
   879   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   880   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   881 proof (rule le_antisym)
   882   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   883     using R by (rule deg_smult_ring)
   884 next
   885   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   886   proof (cases "a = \<zero>")
   887   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   888 qed
   889 
   890 end
   891 
   892 context UP_ring
   893 begin
   894 
   895 lemma deg_mult_ring:
   896   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   897   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   898 proof (rule deg_aboveI)
   899   fix m
   900   assume boundm: "deg R p + deg R q < m"
   901   {
   902     fix k i
   903     assume boundk: "deg R p + deg R q < k"
   904     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   905     proof (cases "deg R p < i")
   906       case True then show ?thesis by (simp add: deg_aboveD R)
   907     next
   908       case False with boundk have "deg R q < k - i" by arith
   909       then show ?thesis by (simp add: deg_aboveD R)
   910     qed
   911   }
   912   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   913 qed (simp add: R)
   914 
   915 end
   916 
   917 context UP_domain
   918 begin
   919 
   920 lemma deg_mult [simp]:
   921   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   922   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   923 proof (rule le_antisym)
   924   assume "p \<in> carrier P" " q \<in> carrier P"
   925   then show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_ring)
   926 next
   927   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   928   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   929   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   930   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   931   proof (rule deg_belowI, simp add: R)
   932     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   933       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   934       by (simp only: ivl_disj_un_one)
   935     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   936       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   937         deg_aboveD less_add_diff R Pi_def)
   938     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   939       by (simp only: ivl_disj_un_singleton)
   940     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   941       by (simp cong: R.finsum_cong add: deg_aboveD R Pi_def)
   942     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   943       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   944     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
   945       by (simp add: integral_iff lcoeff_nonzero R)
   946   qed (simp add: R)
   947 qed
   948 
   949 end
   950 
   951 text{*The following lemmas also can be lifted to @{term UP_ring}.*}
   952 
   953 context UP_ring
   954 begin
   955 
   956 lemma coeff_finsum:
   957   assumes fin: "finite A"
   958   shows "p \<in> A -> carrier P ==>
   959     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
   960   using fin by induct (auto simp: Pi_def)
   961 
   962 lemma up_repr:
   963   assumes R: "p \<in> carrier P"
   964   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
   965 proof (rule up_eqI)
   966   let ?s = "(%i. monom P (coeff P p i) i)"
   967   fix k
   968   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
   969     by simp
   970   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
   971   proof (cases "k <= deg R p")
   972     case True
   973     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   974           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
   975       by (simp only: ivl_disj_un_one)
   976     also from True
   977     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
   978       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint
   979         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
   980     also
   981     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
   982       by (simp only: ivl_disj_un_singleton)
   983     also have "... = coeff P p k"
   984       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R RR Pi_def)
   985     finally show ?thesis .
   986   next
   987     case False
   988     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   989           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
   990       by (simp only: ivl_disj_un_singleton)
   991     also from False have "... = coeff P p k"
   992       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R Pi_def)
   993     finally show ?thesis .
   994   qed
   995 qed (simp_all add: R Pi_def)
   996 
   997 lemma up_repr_le:
   998   "[| deg R p <= n; p \<in> carrier P |] ==>
   999   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1000 proof -
  1001   let ?s = "(%i. monom P (coeff P p i) i)"
  1002   assume R: "p \<in> carrier P" and "deg R p <= n"
  1003   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1004     by (simp only: ivl_disj_un_one)
  1005   also have "... = finsum P ?s {..deg R p}"
  1006     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one
  1007       deg_aboveD R Pi_def)
  1008   also have "... = p" using R by (rule up_repr)
  1009   finally show ?thesis .
  1010 qed
  1011 
  1012 end
  1013 
  1014 
  1015 subsection {* Polynomials over Integral Domains *}
  1016 
  1017 lemma domainI:
  1018   assumes cring: "cring R"
  1019     and one_not_zero: "one R ~= zero R"
  1020     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1021       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1022   shows "domain R"
  1023   by (auto intro!: domain.intro domain_axioms.intro cring.axioms assms
  1024     del: disjCI)
  1025 
  1026 context UP_domain
  1027 begin
  1028 
  1029 lemma UP_one_not_zero:
  1030   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
  1031 proof
  1032   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1033   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1034   hence "\<one> = \<zero>" by simp
  1035   with R.one_not_zero show "False" by contradiction
  1036 qed
  1037 
  1038 lemma UP_integral:
  1039   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1040 proof -
  1041   fix p q
  1042   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1043   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1044   proof (rule classical)
  1045     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
  1046     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1047     also from pq have "... = 0" by simp
  1048     finally have "deg R p + deg R q = 0" .
  1049     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1050     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1051       by (simp only: up_repr_le)
  1052     also from R have "... = monom P (coeff P p 0) 0" by simp
  1053     finally have p: "p = monom P (coeff P p 0) 0" .
  1054     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1055       by (simp only: up_repr_le)
  1056     also from R have "... = monom P (coeff P q 0) 0" by simp
  1057     finally have q: "q = monom P (coeff P q 0) 0" .
  1058     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1059     also from pq have "... = \<zero>" by simp
  1060     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1061     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1062       by (simp add: R.integral_iff)
  1063     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
  1064   qed
  1065 qed
  1066 
  1067 theorem UP_domain:
  1068   "domain P"
  1069   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1070 
  1071 end
  1072 
  1073 text {*
  1074   Interpretation of theorems from @{term domain}.
  1075 *}
  1076 
  1077 sublocale UP_domain < "domain" P
  1078   by intro_locales (rule domain.axioms UP_domain)+
  1079 
  1080 
  1081 subsection {* The Evaluation Homomorphism and Universal Property*}
  1082 
  1083 (* alternative congruence rule (possibly more efficient)
  1084 lemma (in abelian_monoid) finsum_cong2:
  1085   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1086   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1087   sorry*)
  1088 
  1089 lemma (in abelian_monoid) boundD_carrier:
  1090   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1091   by auto
  1092 
  1093 context ring
  1094 begin
  1095 
  1096 theorem diagonal_sum:
  1097   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1098   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1099   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1100 proof -
  1101   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1102   {
  1103     fix j
  1104     have "j <= n + m ==>
  1105       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1106       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1107     proof (induct j)
  1108       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1109     next
  1110       case (Suc j)
  1111       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1112         using Suc by (auto intro!: funcset_mem [OF Rg])
  1113       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1114         using Suc by (auto intro!: funcset_mem [OF Rg])
  1115       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1116         using Suc by (auto intro!: funcset_mem [OF Rf])
  1117       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1118         using Suc by (auto intro!: funcset_mem [OF Rg])
  1119       have R11: "g 0 \<in> carrier R"
  1120         using Suc by (auto intro!: funcset_mem [OF Rg])
  1121       from Suc show ?case
  1122         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1123           Pi_def R6 R8 R9 R10 R11)
  1124     qed
  1125   }
  1126   then show ?thesis by fast
  1127 qed
  1128 
  1129 theorem cauchy_product:
  1130   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1131     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1132   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1133     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)
  1134 proof -
  1135   have f: "!!x. f x \<in> carrier R"
  1136   proof -
  1137     fix x
  1138     show "f x \<in> carrier R"
  1139       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1140   qed
  1141   have g: "!!x. g x \<in> carrier R"
  1142   proof -
  1143     fix x
  1144     show "g x \<in> carrier R"
  1145       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1146   qed
  1147   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1148       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1149     by (simp add: diagonal_sum Pi_def)
  1150   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1151     by (simp only: ivl_disj_un_one)
  1152   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1153     by (simp cong: finsum_cong
  1154       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1155   also from f g
  1156   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1157     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1158   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1159     by (simp cong: finsum_cong
  1160       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1161   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1162     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1163       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1164   finally show ?thesis .
  1165 qed
  1166 
  1167 end
  1168 
  1169 lemma (in UP_ring) const_ring_hom:
  1170   "(%a. monom P a 0) \<in> ring_hom R P"
  1171   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1172 
  1173 definition
  1174   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1175            'a => 'b, 'b, nat => 'a] => 'b"
  1176   where "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1177     \<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i"
  1178 
  1179 context UP
  1180 begin
  1181 
  1182 lemma eval_on_carrier:
  1183   fixes S (structure)
  1184   shows "p \<in> carrier P ==>
  1185   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1186   by (unfold eval_def, fold P_def) simp
  1187 
  1188 lemma eval_extensional:
  1189   "eval R S phi p \<in> extensional (carrier P)"
  1190   by (unfold eval_def, fold P_def) simp
  1191 
  1192 end
  1193 
  1194 text {* The universal property of the polynomial ring *}
  1195 
  1196 locale UP_pre_univ_prop = ring_hom_cring + UP_cring
  1197 
  1198 (* FIXME print_locale ring_hom_cring fails *)
  1199 
  1200 locale UP_univ_prop = UP_pre_univ_prop +
  1201   fixes s and Eval
  1202   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"
  1203   defines Eval_def: "Eval == eval R S h s"
  1204 
  1205 text{*JE: I have moved the following lemma from Ring.thy and lifted then to the locale @{term ring_hom_ring} from @{term ring_hom_cring}.*}
  1206 text{*JE: I was considering using it in @{text eval_ring_hom}, but that property does not hold for non commutative rings, so 
  1207   maybe it is not that necessary.*}
  1208 
  1209 lemma (in ring_hom_ring) hom_finsum [simp]:
  1210   "[| finite A; f \<in> A -> carrier R |] ==>
  1211   h (finsum R f A) = finsum S (h o f) A"
  1212 proof (induct set: finite)
  1213   case empty then show ?case by simp
  1214 next
  1215   case insert then show ?case by (simp add: Pi_def)
  1216 qed
  1217 
  1218 context UP_pre_univ_prop
  1219 begin
  1220 
  1221 theorem eval_ring_hom:
  1222   assumes S: "s \<in> carrier S"
  1223   shows "eval R S h s \<in> ring_hom P S"
  1224 proof (rule ring_hom_memI)
  1225   fix p
  1226   assume R: "p \<in> carrier P"
  1227   then show "eval R S h s p \<in> carrier S"
  1228     by (simp only: eval_on_carrier) (simp add: S Pi_def)
  1229 next
  1230   fix p q
  1231   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1232   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1233   proof (simp only: eval_on_carrier P.a_closed)
  1234     from S R have
  1235       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1236       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1237         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1238       by (simp cong: S.finsum_cong
  1239         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def del: coeff_add)
  1240     also from R have "... =
  1241         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1242           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1243       by (simp add: ivl_disj_un_one)
  1244     also from R S have "... =
  1245       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1246       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1247       by (simp cong: S.finsum_cong
  1248         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)
  1249     also have "... =
  1250         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1251           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1252         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1253           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1254       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1255     also from R S have "... =
  1256       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1257       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1258       by (simp cong: S.finsum_cong
  1259         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1260     finally show
  1261       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1262       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1263       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1264   qed
  1265 next
  1266   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1267     by (simp only: eval_on_carrier UP_one_closed) simp
  1268 next
  1269   fix p q
  1270   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1271   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1272   proof (simp only: eval_on_carrier UP_mult_closed)
  1273     from R S have
  1274       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1275       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1276         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1277       by (simp cong: S.finsum_cong
  1278         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1279         del: coeff_mult)
  1280     also from R have "... =
  1281       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1282       by (simp only: ivl_disj_un_one deg_mult_ring)
  1283     also from R S have "... =
  1284       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1285          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1286            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1287            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1288       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def
  1289         S.m_ac S.finsum_rdistr)
  1290     also from R S have "... =
  1291       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1292       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1293       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1294         Pi_def)
  1295     finally show
  1296       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1297       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1298       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1299   qed
  1300 qed
  1301 
  1302 text {*
  1303   The following lemma could be proved in @{text UP_cring} with the additional
  1304   assumption that @{text h} is closed. *}
  1305 
  1306 lemma (in UP_pre_univ_prop) eval_const:
  1307   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1308   by (simp only: eval_on_carrier monom_closed) simp
  1309 
  1310 text {* Further properties of the evaluation homomorphism. *}
  1311 
  1312 text {* The following proof is complicated by the fact that in arbitrary
  1313   rings one might have @{term "one R = zero R"}. *}
  1314 
  1315 (* TODO: simplify by cases "one R = zero R" *)
  1316 
  1317 lemma (in UP_pre_univ_prop) eval_monom1:
  1318   assumes S: "s \<in> carrier S"
  1319   shows "eval R S h s (monom P \<one> 1) = s"
  1320 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1321    from S have
  1322     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1323     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1324       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1325     by (simp cong: S.finsum_cong del: coeff_monom
  1326       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1327   also have "... =
  1328     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1329     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1330   also have "... = s"
  1331   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1332     case True then show ?thesis by (simp add: Pi_def)
  1333   next
  1334     case False then show ?thesis by (simp add: S Pi_def)
  1335   qed
  1336   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1337     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1338 qed
  1339 
  1340 end
  1341 
  1342 text {* Interpretation of ring homomorphism lemmas. *}
  1343 
  1344 sublocale UP_univ_prop < ring_hom_cring P S Eval
  1345   apply (unfold Eval_def)
  1346   apply intro_locales
  1347   apply (rule ring_hom_cring.axioms)
  1348   apply (rule ring_hom_cring.intro)
  1349   apply unfold_locales
  1350   apply (rule eval_ring_hom)
  1351   apply rule
  1352   done
  1353 
  1354 lemma (in UP_cring) monom_pow:
  1355   assumes R: "a \<in> carrier R"
  1356   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1357 proof (induct m)
  1358   case 0 from R show ?case by simp
  1359 next
  1360   case Suc with R show ?case
  1361     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1362 qed
  1363 
  1364 lemma (in ring_hom_cring) hom_pow [simp]:
  1365   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1366   by (induct n) simp_all
  1367 
  1368 lemma (in UP_univ_prop) Eval_monom:
  1369   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1370 proof -
  1371   assume R: "r \<in> carrier R"
  1372   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1373     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)
  1374   also
  1375   from R eval_monom1 [where s = s, folded Eval_def]
  1376   have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1377     by (simp add: eval_const [where s = s, folded Eval_def])
  1378   finally show ?thesis .
  1379 qed
  1380 
  1381 lemma (in UP_pre_univ_prop) eval_monom:
  1382   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"
  1383   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1384 proof -
  1385   interpret UP_univ_prop R S h P s "eval R S h s"
  1386     using UP_pre_univ_prop_axioms P_def R S
  1387     by (auto intro: UP_univ_prop.intro UP_univ_prop_axioms.intro)
  1388   from R
  1389   show ?thesis by (rule Eval_monom)
  1390 qed
  1391 
  1392 lemma (in UP_univ_prop) Eval_smult:
  1393   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"
  1394 proof -
  1395   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1396   then show ?thesis
  1397     by (simp add: monom_mult_is_smult [THEN sym]
  1398       eval_const [where s = s, folded Eval_def])
  1399 qed
  1400 
  1401 lemma ring_hom_cringI:
  1402   assumes "cring R"
  1403     and "cring S"
  1404     and "h \<in> ring_hom R S"
  1405   shows "ring_hom_cring R S h"
  1406   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1407     cring.axioms assms)
  1408 
  1409 context UP_pre_univ_prop
  1410 begin
  1411 
  1412 lemma UP_hom_unique:
  1413   assumes "ring_hom_cring P S Phi"
  1414   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"
  1415       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1416   assumes "ring_hom_cring P S Psi"
  1417   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"
  1418       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1419     and P: "p \<in> carrier P" and S: "s \<in> carrier S"
  1420   shows "Phi p = Psi p"
  1421 proof -
  1422   interpret ring_hom_cring P S Phi by fact
  1423   interpret ring_hom_cring P S Psi by fact
  1424   have "Phi p =
  1425       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1426     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1427   also
  1428   have "... =
  1429       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1430     by (simp add: Phi Psi P Pi_def comp_def)
  1431   also have "... = Psi p"
  1432     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1433   finally show ?thesis .
  1434 qed
  1435 
  1436 lemma ring_homD:
  1437   assumes Phi: "Phi \<in> ring_hom P S"
  1438   shows "ring_hom_cring P S Phi"
  1439 proof (rule ring_hom_cring.intro)
  1440   show "ring_hom_cring_axioms P S Phi"
  1441   by (rule ring_hom_cring_axioms.intro) (rule Phi)
  1442 qed unfold_locales
  1443 
  1444 theorem UP_universal_property:
  1445   assumes S: "s \<in> carrier S"
  1446   shows "EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1447     Phi (monom P \<one> 1) = s &
  1448     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1449   using S eval_monom1
  1450   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1451   apply (rule extensionalityI)
  1452   apply (auto intro: UP_hom_unique ring_homD)
  1453   done
  1454 
  1455 end
  1456 
  1457 text{*JE: The following lemma was added by me; it might be even lifted to a simpler locale*}
  1458 
  1459 context monoid
  1460 begin
  1461 
  1462 lemma nat_pow_eone[simp]: assumes x_in_G: "x \<in> carrier G" shows "x (^) (1::nat) = x"
  1463   using nat_pow_Suc [of x 0] unfolding nat_pow_0 [of x] unfolding l_one [OF x_in_G] by simp
  1464 
  1465 end
  1466 
  1467 context UP_ring
  1468 begin
  1469 
  1470 abbreviation lcoeff :: "(nat =>'a) => 'a" where "lcoeff p == coeff P p (deg R p)"
  1471 
  1472 lemma lcoeff_nonzero2: assumes p_in_R: "p \<in> carrier P" and p_not_zero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" shows "lcoeff p \<noteq> \<zero>" 
  1473   using lcoeff_nonzero [OF p_not_zero p_in_R] .
  1474 
  1475 subsection{*The long division algorithm: some previous facts.*}
  1476 
  1477 lemma coeff_minus [simp]:
  1478   assumes p: "p \<in> carrier P" and q: "q \<in> carrier P" shows "coeff P (p \<ominus>\<^bsub>P\<^esub> q) n = coeff P p n \<ominus> coeff P q n" 
  1479   unfolding a_minus_def [OF p q] unfolding coeff_add [OF p a_inv_closed [OF q]] unfolding coeff_a_inv [OF q]
  1480   using coeff_closed [OF p, of n] using coeff_closed [OF q, of n] by algebra
  1481 
  1482 lemma lcoeff_closed [simp]: assumes p: "p \<in> carrier P" shows "lcoeff p \<in> carrier R"
  1483   using coeff_closed [OF p, of "deg R p"] by simp
  1484 
  1485 lemma deg_smult_decr: assumes a_in_R: "a \<in> carrier R" and f_in_P: "f \<in> carrier P" shows "deg R (a \<odot>\<^bsub>P\<^esub> f) \<le> deg R f"
  1486   using deg_smult_ring [OF a_in_R f_in_P] by (cases "a = \<zero>", auto)
  1487 
  1488 lemma coeff_monom_mult: assumes R: "c \<in> carrier R" and P: "p \<in> carrier P" 
  1489   shows "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = c \<otimes> (coeff P p m)"
  1490 proof -
  1491   have "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = (\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"
  1492     unfolding coeff_mult [OF monom_closed [OF R, of n] P, of "m + n"] unfolding coeff_monom [OF R, of n] by simp
  1493   also have "(\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i)) = 
  1494     (\<Oplus>i\<in>{..m + n}. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"
  1495     using  R.finsum_cong [of "{..m + n}" "{..m + n}" "(\<lambda>i::nat. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))" 
  1496       "(\<lambda>i::nat. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"]
  1497     using coeff_closed [OF P] unfolding Pi_def simp_implies_def using R by auto
  1498   also have "\<dots> = c \<otimes> coeff P p m" using R.finsum_singleton [of n "{..m + n}" "(\<lambda>i. c \<otimes> coeff P p (m + n - i))"]
  1499     unfolding Pi_def using coeff_closed [OF P] using P R by auto
  1500   finally show ?thesis by simp
  1501 qed
  1502 
  1503 lemma deg_lcoeff_cancel: 
  1504   assumes p_in_P: "p \<in> carrier P" and q_in_P: "q \<in> carrier P" and r_in_P: "r \<in> carrier P" 
  1505   and deg_r_nonzero: "deg R r \<noteq> 0"
  1506   and deg_R_p: "deg R p \<le> deg R r" and deg_R_q: "deg R q \<le> deg R r" 
  1507   and coeff_R_p_eq_q: "coeff P p (deg R r) = \<ominus>\<^bsub>R\<^esub> (coeff P q (deg R r))"
  1508   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) < deg R r"
  1509 proof -
  1510   have deg_le: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> deg R r"
  1511   proof (rule deg_aboveI)
  1512     fix m
  1513     assume deg_r_le: "deg R r < m"
  1514     show "coeff P (p \<oplus>\<^bsub>P\<^esub> q) m = \<zero>"
  1515     proof -
  1516       have slp: "deg R p < m" and "deg R q < m" using deg_R_p deg_R_q using deg_r_le by auto
  1517       then have max_sl: "max (deg R p) (deg R q) < m" by simp
  1518       then have "deg R (p \<oplus>\<^bsub>P\<^esub> q) < m" using deg_add [OF p_in_P q_in_P] by arith
  1519       with deg_R_p deg_R_q show ?thesis using coeff_add [OF p_in_P q_in_P, of m]
  1520         using deg_aboveD [of "p \<oplus>\<^bsub>P\<^esub> q" m] using p_in_P q_in_P by simp 
  1521     qed
  1522   qed (simp add: p_in_P q_in_P)
  1523   moreover have deg_ne: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r"
  1524   proof (rule ccontr)
  1525     assume nz: "\<not> deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r" then have deg_eq: "deg R (p \<oplus>\<^bsub>P\<^esub> q) = deg R r" by simp
  1526     from deg_r_nonzero have r_nonzero: "r \<noteq> \<zero>\<^bsub>P\<^esub>" by (cases "r = \<zero>\<^bsub>P\<^esub>", simp_all)
  1527     have "coeff P (p \<oplus>\<^bsub>P\<^esub> q) (deg R r) = \<zero>\<^bsub>R\<^esub>" using coeff_add [OF p_in_P q_in_P, of "deg R r"] using coeff_R_p_eq_q
  1528       using coeff_closed [OF p_in_P, of "deg R r"] coeff_closed [OF q_in_P, of "deg R r"] by algebra
  1529     with lcoeff_nonzero [OF r_nonzero r_in_P]  and deg_eq show False using lcoeff_nonzero [of "p \<oplus>\<^bsub>P\<^esub> q"] using p_in_P q_in_P
  1530       using deg_r_nonzero by (cases "p \<oplus>\<^bsub>P\<^esub> q \<noteq> \<zero>\<^bsub>P\<^esub>", auto)
  1531   qed
  1532   ultimately show ?thesis by simp
  1533 qed
  1534 
  1535 lemma monom_deg_mult: 
  1536   assumes f_in_P: "f \<in> carrier P" and g_in_P: "g \<in> carrier P" and deg_le: "deg R g \<le> deg R f"
  1537   and a_in_R: "a \<in> carrier R"
  1538   shows "deg R (g \<otimes>\<^bsub>P\<^esub> monom P a (deg R f - deg R g)) \<le> deg R f"
  1539   using deg_mult_ring [OF g_in_P monom_closed [OF a_in_R, of "deg R f - deg R g"]]
  1540   apply (cases "a = \<zero>") using g_in_P apply simp 
  1541   using deg_monom [OF _ a_in_R, of "deg R f - deg R g"] using deg_le by simp
  1542 
  1543 lemma deg_zero_impl_monom:
  1544   assumes f_in_P: "f \<in> carrier P" and deg_f: "deg R f = 0" 
  1545   shows "f = monom P (coeff P f 0) 0"
  1546   apply (rule up_eqI) using coeff_monom [OF coeff_closed [OF f_in_P], of 0 0]
  1547   using f_in_P deg_f using deg_aboveD [of f _] by auto
  1548 
  1549 end
  1550 
  1551 
  1552 subsection {* The long division proof for commutative rings *}
  1553 
  1554 context UP_cring
  1555 begin
  1556 
  1557 lemma exI3: assumes exist: "Pred x y z" 
  1558   shows "\<exists> x y z. Pred x y z"
  1559   using exist by blast
  1560 
  1561 text {* Jacobson's Theorem 2.14 *}
  1562 
  1563 lemma long_div_theorem: 
  1564   assumes g_in_P [simp]: "g \<in> carrier P" and f_in_P [simp]: "f \<in> carrier P"
  1565   and g_not_zero: "g \<noteq> \<zero>\<^bsub>P\<^esub>"
  1566   shows "\<exists> q r (k::nat). (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1567 proof -
  1568   let ?pred = "(\<lambda> q r (k::nat).
  1569     (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"
  1570     and ?lg = "lcoeff g"
  1571   show ?thesis
  1572     (*JE: we distinguish some particular cases where the solution is almost direct.*)
  1573   proof (cases "deg R f < deg R g")
  1574     case True     
  1575       (*JE: if the degree of f is smaller than the one of g the solution is straightforward.*)
  1576       (* CB: avoid exI3 *)
  1577       have "?pred \<zero>\<^bsub>P\<^esub> f 0" using True by force
  1578       then show ?thesis by fast
  1579   next
  1580     case False then have deg_g_le_deg_f: "deg R g \<le> deg R f" by simp
  1581     {
  1582       (*JE: we now apply the induction hypothesis with some additional facts required*)
  1583       from f_in_P deg_g_le_deg_f show ?thesis
  1584       proof (induct "deg R f" arbitrary: "f" rule: less_induct)
  1585         case less
  1586         note f_in_P [simp] = `f \<in> carrier P`
  1587           and deg_g_le_deg_f = `deg R g \<le> deg R f`
  1588         let ?k = "1::nat" and ?r = "(g \<otimes>\<^bsub>P\<^esub> (monom P (lcoeff f) (deg R f - deg R g))) \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)"
  1589           and ?q = "monom P (lcoeff f) (deg R f - deg R g)"
  1590         show "\<exists> q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1591         proof -
  1592           (*JE: we first extablish the existence of a triple satisfying the previous equation. 
  1593             Then we will have to prove the second part of the predicate.*)
  1594           have exist: "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r"
  1595             using minus_add
  1596             using sym [OF a_assoc [of "g \<otimes>\<^bsub>P\<^esub> ?q" "\<ominus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "lcoeff g \<odot>\<^bsub>P\<^esub> f"]]
  1597             using r_neg by auto
  1598           show ?thesis
  1599           proof (cases "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g")
  1600             (*JE: if the degree of the remainder satisfies the statement property we are done*)
  1601             case True
  1602             {
  1603               show ?thesis
  1604               proof (rule exI3 [of _ ?q "\<ominus>\<^bsub>P\<^esub> ?r" ?k], intro conjI)
  1605                 show "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r" using exist by simp
  1606                 show "\<ominus>\<^bsub>P\<^esub> ?r = \<zero>\<^bsub>P\<^esub> \<or> deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g" using True by simp
  1607               qed (simp_all)
  1608             }
  1609           next
  1610             case False note n_deg_r_l_deg_g = False
  1611             {
  1612               (*JE: otherwise, we verify the conditions of the induction hypothesis.*)
  1613               show ?thesis
  1614               proof (cases "deg R f = 0")
  1615                 (*JE: the solutions are different if the degree of f is zero or not*)
  1616                 case True
  1617                 {
  1618                   have deg_g: "deg R g = 0" using True using deg_g_le_deg_f by simp
  1619                   have "lcoeff g (^) (1::nat) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> f \<oplus>\<^bsub>P\<^esub> \<zero>\<^bsub>P\<^esub>"
  1620                     unfolding deg_g apply simp
  1621                     unfolding sym [OF monom_mult_is_smult [OF coeff_closed [OF g_in_P, of 0] f_in_P]]
  1622                     using deg_zero_impl_monom [OF g_in_P deg_g] by simp
  1623                   then show ?thesis using f_in_P by blast
  1624                 }
  1625               next
  1626                 case False note deg_f_nzero = False
  1627                 {
  1628                   (*JE: now it only remains the case where the induction hypothesis can be used.*)
  1629                   (*JE: we first prove that the degree of the remainder is smaller than the one of f*)
  1630                   have deg_remainder_l_f: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R f"
  1631                   proof -
  1632                     have "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = deg R ?r" using deg_uminus [of ?r] by simp
  1633                     also have "\<dots> < deg R f"
  1634                     proof (rule deg_lcoeff_cancel)
  1635                       show "deg R (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) \<le> deg R f"
  1636                         using deg_smult_ring [of "lcoeff g" f]
  1637                         using lcoeff_nonzero2 [OF g_in_P g_not_zero] by simp
  1638                       show "deg R (g \<otimes>\<^bsub>P\<^esub> ?q) \<le> deg R f"
  1639                         using monom_deg_mult [OF _ g_in_P, of f "lcoeff f"] and deg_g_le_deg_f
  1640                         by simp
  1641                       show "coeff P (g \<otimes>\<^bsub>P\<^esub> ?q) (deg R f) = \<ominus> coeff P (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) (deg R f)"
  1642                         unfolding coeff_mult [OF g_in_P monom_closed [OF lcoeff_closed [OF f_in_P], of "deg R f - deg R g"], of "deg R f"]
  1643                         unfolding coeff_monom [OF lcoeff_closed [OF f_in_P], of "(deg R f - deg R g)"]
  1644                         using R.finsum_cong' [of "{..deg R f}" "{..deg R f}" 
  1645                           "(\<lambda>i. coeff P g i \<otimes> (if deg R f - deg R g = deg R f - i then lcoeff f else \<zero>))" 
  1646                           "(\<lambda>i. if deg R g = i then coeff P g i \<otimes> lcoeff f else \<zero>)"]
  1647                         using R.finsum_singleton [of "deg R g" "{.. deg R f}" "(\<lambda>i. coeff P g i \<otimes> lcoeff f)"]
  1648                         unfolding Pi_def using deg_g_le_deg_f by force
  1649                     qed (simp_all add: deg_f_nzero)
  1650                     finally show "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R f" .
  1651                   qed
  1652                   moreover have "\<ominus>\<^bsub>P\<^esub> ?r \<in> carrier P" by simp
  1653                   moreover obtain m where deg_rem_eq_m: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = m" by auto
  1654                   moreover have "deg R g \<le> deg R (\<ominus>\<^bsub>P\<^esub> ?r)" using n_deg_r_l_deg_g by simp
  1655                     (*JE: now, by applying the induction hypothesis, we obtain new quotient, remainder and exponent.*)
  1656                   ultimately obtain q' r' k'
  1657                     where rem_desc: "lcoeff g (^) (k'::nat) \<odot>\<^bsub>P\<^esub> (\<ominus>\<^bsub>P\<^esub> ?r) = g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"and rem_deg: "(r' = \<zero>\<^bsub>P\<^esub> \<or> deg R r' < deg R g)"
  1658                     and q'_in_carrier: "q' \<in> carrier P" and r'_in_carrier: "r' \<in> carrier P"
  1659                     using less by blast
  1660                       (*JE: we now prove that the new quotient, remainder and exponent can be used to get 
  1661                       the quotient, remainder and exponent of the long division theorem*)
  1662                   show ?thesis
  1663                   proof (rule exI3 [of _ "((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q')" r' "Suc k'"], intro conjI)
  1664                     show "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<oplus>\<^bsub>P\<^esub> r'"
  1665                     proof -
  1666                       have "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r)" 
  1667                         using smult_assoc1 exist by simp
  1668                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ( \<ominus>\<^bsub>P\<^esub> ?r))"
  1669                         using UP_smult_r_distr by simp
  1670                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r')"
  1671                         using rem_desc by simp
  1672                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"
  1673                         using sym [OF a_assoc [of "lcoeff g (^) k' \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "g \<otimes>\<^bsub>P\<^esub> q'" "r'"]]
  1674                         using q'_in_carrier r'_in_carrier by simp
  1675                       also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (?q \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1676                         using q'_in_carrier by (auto simp add: m_comm)
  1677                       also have "\<dots> = (((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q) \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'" 
  1678                         using smult_assoc2 q'_in_carrier by auto
  1679                       also have "\<dots> = ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1680                         using sym [OF l_distr] and q'_in_carrier by auto
  1681                       finally show ?thesis using m_comm q'_in_carrier by auto
  1682                     qed
  1683                   qed (simp_all add: rem_deg q'_in_carrier r'_in_carrier)
  1684                 }
  1685               qed
  1686             }
  1687           qed
  1688         qed
  1689       qed
  1690     }
  1691   qed
  1692 qed
  1693 
  1694 end
  1695 
  1696 
  1697 text {*The remainder theorem as corollary of the long division theorem.*}
  1698 
  1699 context UP_cring
  1700 begin
  1701 
  1702 lemma deg_minus_monom:
  1703   assumes a: "a \<in> carrier R"
  1704   and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1705   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1706   (is "deg R ?g = 1")
  1707 proof -
  1708   have "deg R ?g \<le> 1"
  1709   proof (rule deg_aboveI)
  1710     fix m
  1711     assume "(1::nat) < m" 
  1712     then show "coeff P ?g m = \<zero>" 
  1713       using coeff_minus using a by auto algebra
  1714   qed (simp add: a)
  1715   moreover have "deg R ?g \<ge> 1"
  1716   proof (rule deg_belowI)
  1717     show "coeff P ?g 1 \<noteq> \<zero>"
  1718       using a using R.carrier_one_not_zero R_not_trivial by simp algebra
  1719   qed (simp add: a)
  1720   ultimately show ?thesis by simp
  1721 qed
  1722 
  1723 lemma lcoeff_monom:
  1724   assumes a: "a \<in> carrier R" and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1725   shows "lcoeff (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<one>"
  1726   using deg_minus_monom [OF a R_not_trivial]
  1727   using coeff_minus a by auto algebra
  1728 
  1729 lemma deg_nzero_nzero:
  1730   assumes deg_p_nzero: "deg R p \<noteq> 0"
  1731   shows "p \<noteq> \<zero>\<^bsub>P\<^esub>"
  1732   using deg_zero deg_p_nzero by auto
  1733 
  1734 lemma deg_monom_minus:
  1735   assumes a: "a \<in> carrier R"
  1736   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1737   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1738   (is "deg R ?g = 1")
  1739 proof -
  1740   have "deg R ?g \<le> 1"
  1741   proof (rule deg_aboveI)
  1742     fix m::nat assume "1 < m" then show "coeff P ?g m = \<zero>" 
  1743       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of m] 
  1744       using coeff_monom [OF R.one_closed, of 1 m] using coeff_monom [OF a, of 0 m] by auto algebra
  1745   qed (simp add: a)
  1746   moreover have "1 \<le> deg R ?g"
  1747   proof (rule deg_belowI)
  1748     show "coeff P ?g 1 \<noteq> \<zero>" 
  1749       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of 1]
  1750       using coeff_monom [OF R.one_closed, of 1 1] using coeff_monom [OF a, of 0 1] 
  1751       using R_not_trivial using R.carrier_one_not_zero
  1752       by auto algebra
  1753   qed (simp add: a)
  1754   ultimately show ?thesis by simp
  1755 qed
  1756 
  1757 lemma eval_monom_expr:
  1758   assumes a: "a \<in> carrier R"
  1759   shows "eval R R id a (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<zero>"
  1760   (is "eval R R id a ?g = _")
  1761 proof -
  1762   interpret UP_pre_univ_prop R R id proof qed simp
  1763   have eval_ring_hom: "eval R R id a \<in> ring_hom P R" using eval_ring_hom [OF a] by simp
  1764   interpret ring_hom_cring P R "eval R R id a" proof qed (simp add: eval_ring_hom)
  1765   have mon1_closed: "monom P \<one>\<^bsub>R\<^esub> 1 \<in> carrier P" 
  1766     and mon0_closed: "monom P a 0 \<in> carrier P" 
  1767     and min_mon0_closed: "\<ominus>\<^bsub>P\<^esub> monom P a 0 \<in> carrier P"
  1768     using a R.a_inv_closed by auto
  1769   have "eval R R id a ?g = eval R R id a (monom P \<one> 1) \<ominus> eval R R id a (monom P a 0)"
  1770     unfolding P.minus_eq [OF mon1_closed mon0_closed]
  1771     unfolding hom_add [OF mon1_closed min_mon0_closed]
  1772     unfolding hom_a_inv [OF mon0_closed] 
  1773     using R.minus_eq [symmetric] mon1_closed mon0_closed by auto
  1774   also have "\<dots> = a \<ominus> a"
  1775     using eval_monom [OF R.one_closed a, of 1] using eval_monom [OF a a, of 0] using a by simp
  1776   also have "\<dots> = \<zero>"
  1777     using a by algebra
  1778   finally show ?thesis by simp
  1779 qed
  1780 
  1781 lemma remainder_theorem_exist:
  1782   assumes f: "f \<in> carrier P" and a: "a \<in> carrier R"
  1783   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1784   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)"
  1785   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)")
  1786 proof -
  1787   let ?g = "monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0"
  1788   from deg_minus_monom [OF a R_not_trivial]
  1789   have deg_g_nzero: "deg R ?g \<noteq> 0" by simp
  1790   have "\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and>
  1791     lcoeff ?g (^) k \<odot>\<^bsub>P\<^esub> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R ?g)"
  1792     using long_div_theorem [OF _ f deg_nzero_nzero [OF deg_g_nzero]] a
  1793     by auto
  1794   then show ?thesis
  1795     unfolding lcoeff_monom [OF a R_not_trivial]
  1796     unfolding deg_monom_minus [OF a R_not_trivial]
  1797     using smult_one [OF f] using deg_zero by force
  1798 qed
  1799 
  1800 lemma remainder_theorem_expression:
  1801   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1802   and q [simp]: "q \<in> carrier P" and r [simp]: "r \<in> carrier P"
  1803   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1804   and f_expr: "f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1805   (is "f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r" is "f = ?gq \<oplus>\<^bsub>P\<^esub> r")
  1806     and deg_r_0: "deg R r = 0"
  1807     shows "r = monom P (eval R R id a f) 0"
  1808 proof -
  1809   interpret UP_pre_univ_prop R R id P proof qed simp
  1810   have eval_ring_hom: "eval R R id a \<in> ring_hom P R"
  1811     using eval_ring_hom [OF a] by simp
  1812   have "eval R R id a f = eval R R id a ?gq \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1813     unfolding f_expr using ring_hom_add [OF eval_ring_hom] by auto
  1814   also have "\<dots> = ((eval R R id a ?g) \<otimes> (eval R R id a q)) \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1815     using ring_hom_mult [OF eval_ring_hom] by auto
  1816   also have "\<dots> = \<zero> \<oplus> eval R R id a r"
  1817     unfolding eval_monom_expr [OF a] using eval_ring_hom 
  1818     unfolding ring_hom_def using q unfolding Pi_def by simp
  1819   also have "\<dots> = eval R R id a r"
  1820     using eval_ring_hom unfolding ring_hom_def using r unfolding Pi_def by simp
  1821   finally have eval_eq: "eval R R id a f = eval R R id a r" by simp
  1822   from deg_zero_impl_monom [OF r deg_r_0]
  1823   have "r = monom P (coeff P r 0) 0" by simp
  1824   with eval_const [OF a, of "coeff P r 0"] eval_eq 
  1825   show ?thesis by auto
  1826 qed
  1827 
  1828 corollary remainder_theorem:
  1829   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1830   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1831   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> 
  1832      f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0"
  1833   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0")
  1834 proof -
  1835   from remainder_theorem_exist [OF f a R_not_trivial]
  1836   obtain q r
  1837     where q_r: "q \<in> carrier P \<and> r \<in> carrier P \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1838     and deg_r: "deg R r = 0" by force
  1839   with remainder_theorem_expression [OF f a _ _ R_not_trivial, of q r]
  1840   show ?thesis by auto
  1841 qed
  1842 
  1843 end
  1844 
  1845 
  1846 subsection {* Sample Application of Evaluation Homomorphism *}
  1847 
  1848 lemma UP_pre_univ_propI:
  1849   assumes "cring R"
  1850     and "cring S"
  1851     and "h \<in> ring_hom R S"
  1852   shows "UP_pre_univ_prop R S h"
  1853   using assms
  1854   by (auto intro!: UP_pre_univ_prop.intro ring_hom_cring.intro
  1855     ring_hom_cring_axioms.intro UP_cring.intro)
  1856 
  1857 definition  INTEG :: "int ring"
  1858   where INTEG_def: "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1859 
  1860 lemma INTEG_cring:
  1861   "cring INTEG"
  1862   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1863     zadd_zminus_inverse2 zadd_zmult_distrib)
  1864 
  1865 lemma INTEG_id_eval:
  1866   "UP_pre_univ_prop INTEG INTEG id"
  1867   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)
  1868 
  1869 text {*
  1870   Interpretation now enables to import all theorems and lemmas
  1871   valid in the context of homomorphisms between @{term INTEG} and @{term
  1872   "UP INTEG"} globally.
  1873 *}
  1874 
  1875 interpretation INTEG: UP_pre_univ_prop INTEG INTEG id "UP INTEG"
  1876   using INTEG_id_eval by simp_all
  1877 
  1878 lemma INTEG_closed [intro, simp]:
  1879   "z \<in> carrier INTEG"
  1880   by (unfold INTEG_def) simp
  1881 
  1882 lemma INTEG_mult [simp]:
  1883   "mult INTEG z w = z * w"
  1884   by (unfold INTEG_def) simp
  1885 
  1886 lemma INTEG_pow [simp]:
  1887   "pow INTEG z n = z ^ n"
  1888   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1889 
  1890 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1891   by (simp add: INTEG.eval_monom)
  1892 
  1893 end