src/HOL/Library/Formal_Power_Series.thy
author nipkow
Tue Sep 22 14:31:22 2015 +0200 (2015-09-22)
changeset 61225 1a690dce8cfc
parent 60867 86e7560e07d0
child 61552 980dd46a03fb
permissions -rw-r--r--
tuned references
     1 (*  Title:      HOL/Library/Formal_Power_Series.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>A formalization of formal power series\<close>
     6 
     7 theory Formal_Power_Series
     8 imports Complex_Main
     9 begin
    10 
    11 
    12 subsection \<open>The type of formal power series\<close>
    13 
    14 typedef 'a fps = "{f :: nat \<Rightarrow> 'a. True}"
    15   morphisms fps_nth Abs_fps
    16   by simp
    17 
    18 notation fps_nth (infixl "$" 75)
    19 
    20 lemma expand_fps_eq: "p = q \<longleftrightarrow> (\<forall>n. p $ n = q $ n)"
    21   by (simp add: fps_nth_inject [symmetric] fun_eq_iff)
    22 
    23 lemma fps_ext: "(\<And>n. p $ n = q $ n) \<Longrightarrow> p = q"
    24   by (simp add: expand_fps_eq)
    25 
    26 lemma fps_nth_Abs_fps [simp]: "Abs_fps f $ n = f n"
    27   by (simp add: Abs_fps_inverse)
    28 
    29 text \<open>Definition of the basic elements 0 and 1 and the basic operations of addition,
    30   negation and multiplication.\<close>
    31 
    32 instantiation fps :: (zero) zero
    33 begin
    34   definition fps_zero_def: "0 = Abs_fps (\<lambda>n. 0)"
    35   instance ..
    36 end
    37 
    38 lemma fps_zero_nth [simp]: "0 $ n = 0"
    39   unfolding fps_zero_def by simp
    40 
    41 instantiation fps :: ("{one, zero}") one
    42 begin
    43   definition fps_one_def: "1 = Abs_fps (\<lambda>n. if n = 0 then 1 else 0)"
    44   instance ..
    45 end
    46 
    47 lemma fps_one_nth [simp]: "1 $ n = (if n = 0 then 1 else 0)"
    48   unfolding fps_one_def by simp
    49 
    50 instantiation fps :: (plus) plus
    51 begin
    52   definition fps_plus_def: "op + = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n + g $ n))"
    53   instance ..
    54 end
    55 
    56 lemma fps_add_nth [simp]: "(f + g) $ n = f $ n + g $ n"
    57   unfolding fps_plus_def by simp
    58 
    59 instantiation fps :: (minus) minus
    60 begin
    61   definition fps_minus_def: "op - = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n - g $ n))"
    62   instance ..
    63 end
    64 
    65 lemma fps_sub_nth [simp]: "(f - g) $ n = f $ n - g $ n"
    66   unfolding fps_minus_def by simp
    67 
    68 instantiation fps :: (uminus) uminus
    69 begin
    70   definition fps_uminus_def: "uminus = (\<lambda>f. Abs_fps (\<lambda>n. - (f $ n)))"
    71   instance ..
    72 end
    73 
    74 lemma fps_neg_nth [simp]: "(- f) $ n = - (f $ n)"
    75   unfolding fps_uminus_def by simp
    76 
    77 instantiation fps :: ("{comm_monoid_add, times}") times
    78 begin
    79   definition fps_times_def: "op * = (\<lambda>f g. Abs_fps (\<lambda>n. \<Sum>i=0..n. f $ i * g $ (n - i)))"
    80   instance ..
    81 end
    82 
    83 lemma fps_mult_nth: "(f * g) $ n = (\<Sum>i=0..n. f$i * g$(n - i))"
    84   unfolding fps_times_def by simp
    85 
    86 declare atLeastAtMost_iff [presburger]
    87 declare Bex_def [presburger]
    88 declare Ball_def [presburger]
    89 
    90 lemma mult_delta_left:
    91   fixes x y :: "'a::mult_zero"
    92   shows "(if b then x else 0) * y = (if b then x * y else 0)"
    93   by simp
    94 
    95 lemma mult_delta_right:
    96   fixes x y :: "'a::mult_zero"
    97   shows "x * (if b then y else 0) = (if b then x * y else 0)"
    98   by simp
    99 
   100 lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
   101   by auto
   102 
   103 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
   104   by auto
   105 
   106 
   107 subsection \<open>Formal power series form a commutative ring with unity, if the range of sequences
   108   they represent is a commutative ring with unity\<close>
   109 
   110 instance fps :: (semigroup_add) semigroup_add
   111 proof
   112   fix a b c :: "'a fps"
   113   show "a + b + c = a + (b + c)"
   114     by (simp add: fps_ext add.assoc)
   115 qed
   116 
   117 instance fps :: (ab_semigroup_add) ab_semigroup_add
   118 proof
   119   fix a b :: "'a fps"
   120   show "a + b = b + a"
   121     by (simp add: fps_ext add.commute)
   122 qed
   123 
   124 lemma fps_mult_assoc_lemma:
   125   fixes k :: nat
   126     and f :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   127   shows "(\<Sum>j=0..k. \<Sum>i=0..j. f i (j - i) (n - j)) =
   128          (\<Sum>j=0..k. \<Sum>i=0..k - j. f j i (n - j - i))"
   129   by (induct k) (simp_all add: Suc_diff_le setsum.distrib add.assoc)
   130 
   131 instance fps :: (semiring_0) semigroup_mult
   132 proof
   133   fix a b c :: "'a fps"
   134   show "(a * b) * c = a * (b * c)"
   135   proof (rule fps_ext)
   136     fix n :: nat
   137     have "(\<Sum>j=0..n. \<Sum>i=0..j. a$i * b$(j - i) * c$(n - j)) =
   138           (\<Sum>j=0..n. \<Sum>i=0..n - j. a$j * b$i * c$(n - j - i))"
   139       by (rule fps_mult_assoc_lemma)
   140     then show "((a * b) * c) $ n = (a * (b * c)) $ n"
   141       by (simp add: fps_mult_nth setsum_right_distrib setsum_left_distrib mult.assoc)
   142   qed
   143 qed
   144 
   145 lemma fps_mult_commute_lemma:
   146   fixes n :: nat
   147     and f :: "nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   148   shows "(\<Sum>i=0..n. f i (n - i)) = (\<Sum>i=0..n. f (n - i) i)"
   149   by (rule setsum.reindex_bij_witness[where i="op - n" and j="op - n"]) auto
   150 
   151 instance fps :: (comm_semiring_0) ab_semigroup_mult
   152 proof
   153   fix a b :: "'a fps"
   154   show "a * b = b * a"
   155   proof (rule fps_ext)
   156     fix n :: nat
   157     have "(\<Sum>i=0..n. a$i * b$(n - i)) = (\<Sum>i=0..n. a$(n - i) * b$i)"
   158       by (rule fps_mult_commute_lemma)
   159     then show "(a * b) $ n = (b * a) $ n"
   160       by (simp add: fps_mult_nth mult.commute)
   161   qed
   162 qed
   163 
   164 instance fps :: (monoid_add) monoid_add
   165 proof
   166   fix a :: "'a fps"
   167   show "0 + a = a" by (simp add: fps_ext)
   168   show "a + 0 = a" by (simp add: fps_ext)
   169 qed
   170 
   171 instance fps :: (comm_monoid_add) comm_monoid_add
   172 proof
   173   fix a :: "'a fps"
   174   show "0 + a = a" by (simp add: fps_ext)
   175 qed
   176 
   177 instance fps :: (semiring_1) monoid_mult
   178 proof
   179   fix a :: "'a fps"
   180   show "1 * a = a"
   181     by (simp add: fps_ext fps_mult_nth mult_delta_left setsum.delta)
   182   show "a * 1 = a"
   183     by (simp add: fps_ext fps_mult_nth mult_delta_right setsum.delta')
   184 qed
   185 
   186 instance fps :: (cancel_semigroup_add) cancel_semigroup_add
   187 proof
   188   fix a b c :: "'a fps"
   189   show "b = c" if "a + b = a + c"
   190     using that by (simp add: expand_fps_eq)
   191   show "b = c" if "b + a = c + a"
   192     using that by (simp add: expand_fps_eq)
   193 qed
   194 
   195 instance fps :: (cancel_ab_semigroup_add) cancel_ab_semigroup_add
   196 proof
   197   fix a b c :: "'a fps"
   198   show "a + b - a = b"
   199     by (simp add: expand_fps_eq)
   200   show "a - b - c = a - (b + c)"
   201     by (simp add: expand_fps_eq diff_diff_eq)
   202 qed
   203 
   204 instance fps :: (cancel_comm_monoid_add) cancel_comm_monoid_add ..
   205 
   206 instance fps :: (group_add) group_add
   207 proof
   208   fix a b :: "'a fps"
   209   show "- a + a = 0" by (simp add: fps_ext)
   210   show "a + - b = a - b" by (simp add: fps_ext)
   211 qed
   212 
   213 instance fps :: (ab_group_add) ab_group_add
   214 proof
   215   fix a b :: "'a fps"
   216   show "- a + a = 0" by (simp add: fps_ext)
   217   show "a - b = a + - b" by (simp add: fps_ext)
   218 qed
   219 
   220 instance fps :: (zero_neq_one) zero_neq_one
   221   by standard (simp add: expand_fps_eq)
   222 
   223 instance fps :: (semiring_0) semiring
   224 proof
   225   fix a b c :: "'a fps"
   226   show "(a + b) * c = a * c + b * c"
   227     by (simp add: expand_fps_eq fps_mult_nth distrib_right setsum.distrib)
   228   show "a * (b + c) = a * b + a * c"
   229     by (simp add: expand_fps_eq fps_mult_nth distrib_left setsum.distrib)
   230 qed
   231 
   232 instance fps :: (semiring_0) semiring_0
   233 proof
   234   fix a :: "'a fps"
   235   show "0 * a = 0"
   236     by (simp add: fps_ext fps_mult_nth)
   237   show "a * 0 = 0"
   238     by (simp add: fps_ext fps_mult_nth)
   239 qed
   240 
   241 instance fps :: (semiring_0_cancel) semiring_0_cancel ..
   242 
   243 instance fps :: (semiring_1) semiring_1 ..
   244 
   245 
   246 subsection \<open>Selection of the nth power of the implicit variable in the infinite sum\<close>
   247 
   248 lemma fps_nonzero_nth: "f \<noteq> 0 \<longleftrightarrow> (\<exists> n. f $n \<noteq> 0)"
   249   by (simp add: expand_fps_eq)
   250 
   251 lemma fps_nonzero_nth_minimal: "f \<noteq> 0 \<longleftrightarrow> (\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m < n. f $ m = 0))"
   252   (is "?lhs \<longleftrightarrow> ?rhs")
   253 proof
   254   let ?n = "LEAST n. f $ n \<noteq> 0"
   255   show ?rhs if ?lhs
   256   proof -
   257     from that have "\<exists>n. f $ n \<noteq> 0"
   258       by (simp add: fps_nonzero_nth)
   259     then have "f $ ?n \<noteq> 0"
   260       by (rule LeastI_ex)
   261     moreover have "\<forall>m<?n. f $ m = 0"
   262       by (auto dest: not_less_Least)
   263     ultimately have "f $ ?n \<noteq> 0 \<and> (\<forall>m<?n. f $ m = 0)" ..
   264     then show ?thesis ..
   265   qed
   266   show ?lhs if ?rhs
   267     using that by (auto simp add: expand_fps_eq)
   268 qed
   269 
   270 lemma fps_eq_iff: "f = g \<longleftrightarrow> (\<forall>n. f $ n = g $n)"
   271   by (rule expand_fps_eq)
   272 
   273 lemma fps_setsum_nth: "setsum f S $ n = setsum (\<lambda>k. (f k) $ n) S"
   274 proof (cases "finite S")
   275   case True
   276   then show ?thesis by (induct set: finite) auto
   277 next
   278   case False
   279   then show ?thesis by simp
   280 qed
   281 
   282 
   283 subsection \<open>Injection of the basic ring elements and multiplication by scalars\<close>
   284 
   285 definition "fps_const c = Abs_fps (\<lambda>n. if n = 0 then c else 0)"
   286 
   287 lemma fps_nth_fps_const [simp]: "fps_const c $ n = (if n = 0 then c else 0)"
   288   unfolding fps_const_def by simp
   289 
   290 lemma fps_const_0_eq_0 [simp]: "fps_const 0 = 0"
   291   by (simp add: fps_ext)
   292 
   293 lemma fps_const_1_eq_1 [simp]: "fps_const 1 = 1"
   294   by (simp add: fps_ext)
   295 
   296 lemma fps_const_neg [simp]: "- (fps_const (c::'a::ring)) = fps_const (- c)"
   297   by (simp add: fps_ext)
   298 
   299 lemma fps_const_add [simp]: "fps_const (c::'a::monoid_add) + fps_const d = fps_const (c + d)"
   300   by (simp add: fps_ext)
   301 
   302 lemma fps_const_sub [simp]: "fps_const (c::'a::group_add) - fps_const d = fps_const (c - d)"
   303   by (simp add: fps_ext)
   304 
   305 lemma fps_const_mult[simp]: "fps_const (c::'a::ring) * fps_const d = fps_const (c * d)"
   306   by (simp add: fps_eq_iff fps_mult_nth setsum.neutral)
   307 
   308 lemma fps_const_add_left: "fps_const (c::'a::monoid_add) + f =
   309     Abs_fps (\<lambda>n. if n = 0 then c + f$0 else f$n)"
   310   by (simp add: fps_ext)
   311 
   312 lemma fps_const_add_right: "f + fps_const (c::'a::monoid_add) =
   313     Abs_fps (\<lambda>n. if n = 0 then f$0 + c else f$n)"
   314   by (simp add: fps_ext)
   315 
   316 lemma fps_const_mult_left: "fps_const (c::'a::semiring_0) * f = Abs_fps (\<lambda>n. c * f$n)"
   317   unfolding fps_eq_iff fps_mult_nth
   318   by (simp add: fps_const_def mult_delta_left setsum.delta)
   319 
   320 lemma fps_const_mult_right: "f * fps_const (c::'a::semiring_0) = Abs_fps (\<lambda>n. f$n * c)"
   321   unfolding fps_eq_iff fps_mult_nth
   322   by (simp add: fps_const_def mult_delta_right setsum.delta')
   323 
   324 lemma fps_mult_left_const_nth [simp]: "(fps_const (c::'a::semiring_1) * f)$n = c* f$n"
   325   by (simp add: fps_mult_nth mult_delta_left setsum.delta)
   326 
   327 lemma fps_mult_right_const_nth [simp]: "(f * fps_const (c::'a::semiring_1))$n = f$n * c"
   328   by (simp add: fps_mult_nth mult_delta_right setsum.delta')
   329 
   330 
   331 subsection \<open>Formal power series form an integral domain\<close>
   332 
   333 instance fps :: (ring) ring ..
   334 
   335 instance fps :: (ring_1) ring_1
   336   by (intro_classes, auto simp add: distrib_right)
   337 
   338 instance fps :: (comm_ring_1) comm_ring_1
   339   by (intro_classes, auto simp add: distrib_right)
   340 
   341 instance fps :: (ring_no_zero_divisors) ring_no_zero_divisors
   342 proof
   343   fix a b :: "'a fps"
   344   assume "a \<noteq> 0" and "b \<noteq> 0"
   345   then obtain i j where i: "a $ i \<noteq> 0" "\<forall>k<i. a $ k = 0" and j: "b $ j \<noteq> 0" "\<forall>k<j. b $ k =0"
   346     unfolding fps_nonzero_nth_minimal
   347     by blast+
   348   have "(a * b) $ (i + j) = (\<Sum>k=0..i+j. a $ k * b $ (i + j - k))"
   349     by (rule fps_mult_nth)
   350   also have "\<dots> = (a $ i * b $ (i + j - i)) + (\<Sum>k\<in>{0..i+j} - {i}. a $ k * b $ (i + j - k))"
   351     by (rule setsum.remove) simp_all
   352   also have "(\<Sum>k\<in>{0..i+j}-{i}. a $ k * b $ (i + j - k)) = 0"
   353   proof (rule setsum.neutral [rule_format])
   354     fix k assume "k \<in> {0..i+j} - {i}"
   355     then have "k < i \<or> i+j-k < j"
   356       by auto
   357     then show "a $ k * b $ (i + j - k) = 0"
   358       using i j by auto
   359   qed
   360   also have "a $ i * b $ (i + j - i) + 0 = a $ i * b $ j"
   361     by simp
   362   also have "a $ i * b $ j \<noteq> 0"
   363     using i j by simp
   364   finally have "(a*b) $ (i+j) \<noteq> 0" .
   365   then show "a * b \<noteq> 0"
   366     unfolding fps_nonzero_nth by blast
   367 qed
   368 
   369 instance fps :: (ring_1_no_zero_divisors) ring_1_no_zero_divisors ..
   370 
   371 instance fps :: (idom) idom ..
   372 
   373 lemma numeral_fps_const: "numeral k = fps_const (numeral k)"
   374   by (induct k) (simp_all only: numeral.simps fps_const_1_eq_1
   375     fps_const_add [symmetric])
   376 
   377 lemma neg_numeral_fps_const:
   378   "(- numeral k :: 'a :: ring_1 fps) = fps_const (- numeral k)"
   379   by (simp add: numeral_fps_const)
   380 
   381 
   382 subsection \<open>The eXtractor series X\<close>
   383 
   384 lemma minus_one_power_iff: "(- (1::'a::comm_ring_1)) ^ n = (if even n then 1 else - 1)"
   385   by (induct n) auto
   386 
   387 definition "X = Abs_fps (\<lambda>n. if n = 1 then 1 else 0)"
   388 
   389 lemma X_mult_nth [simp]:
   390   "(X * (f :: 'a::semiring_1 fps)) $n = (if n = 0 then 0 else f $ (n - 1))"
   391 proof (cases "n = 0")
   392   case False
   393   have "(X * f) $n = (\<Sum>i = 0..n. X $ i * f $ (n - i))"
   394     by (simp add: fps_mult_nth)
   395   also have "\<dots> = f $ (n - 1)"
   396     using False by (simp add: X_def mult_delta_left setsum.delta)
   397   finally show ?thesis
   398     using False by simp
   399 next
   400   case True
   401   then show ?thesis
   402     by (simp add: fps_mult_nth X_def)
   403 qed
   404 
   405 lemma X_mult_right_nth[simp]:
   406     "((f :: 'a::comm_semiring_1 fps) * X) $n = (if n = 0 then 0 else f $ (n - 1))"
   407   by (metis X_mult_nth mult.commute)
   408 
   409 lemma X_power_iff: "X^k = Abs_fps (\<lambda>n. if n = k then 1::'a::comm_ring_1 else 0)"
   410 proof (induct k)
   411   case 0
   412   then show ?case by (simp add: X_def fps_eq_iff)
   413 next
   414   case (Suc k)
   415   have "(X^Suc k) $ m = (if m = Suc k then 1::'a else 0)" for m
   416   proof -
   417     have "(X^Suc k) $ m = (if m = 0 then 0 else (X^k) $ (m - 1))"
   418       by (simp del: One_nat_def)
   419     then show ?thesis
   420       using Suc.hyps by (auto cong del: if_weak_cong)
   421   qed
   422   then show ?case
   423     by (simp add: fps_eq_iff)
   424 qed
   425 
   426 lemma X_power_mult_nth: "(X^k * (f :: 'a::comm_ring_1 fps)) $n = (if n < k then 0 else f $ (n - k))"
   427   apply (induct k arbitrary: n)
   428   apply simp
   429   unfolding power_Suc mult.assoc
   430   apply (case_tac n)
   431   apply auto
   432   done
   433 
   434 lemma X_power_mult_right_nth:
   435     "((f :: 'a::comm_ring_1 fps) * X^k) $n = (if n < k then 0 else f $ (n - k))"
   436   by (metis X_power_mult_nth mult.commute)
   437 
   438 
   439 subsection \<open>Formal Power series form a metric space\<close>
   440 
   441 definition (in dist) "ball x r = {y. dist y x < r}"
   442 
   443 instantiation fps :: (comm_ring_1) dist
   444 begin
   445 
   446 definition
   447   dist_fps_def: "dist (a :: 'a fps) b =
   448     (if (\<exists>n. a$n \<noteq> b$n) then inverse (2 ^ (LEAST n. a$n \<noteq> b$n)) else 0)"
   449 
   450 lemma dist_fps_ge0: "dist (a :: 'a fps) b \<ge> 0"
   451   by (simp add: dist_fps_def)
   452 
   453 lemma dist_fps_sym: "dist (a :: 'a fps) b = dist b a"
   454   apply (auto simp add: dist_fps_def)
   455   apply (rule cong[OF refl, where x="(\<lambda>n. a $ n \<noteq> b $ n)"])
   456   apply (rule ext)
   457   apply auto
   458   done
   459 
   460 instance ..
   461 
   462 end
   463 
   464 instantiation fps :: (comm_ring_1) metric_space
   465 begin
   466 
   467 definition open_fps_def: "open (S :: 'a fps set) = (\<forall>a \<in> S. \<exists>r. r >0 \<and> ball a r \<subseteq> S)"
   468 
   469 instance
   470 proof
   471   show "open S = (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)" for S :: "'a fps set"
   472     by (auto simp add: open_fps_def ball_def subset_eq)
   473   show th: "dist a b = 0 \<longleftrightarrow> a = b" for a b :: "'a fps"
   474   proof
   475     assume "a = b"
   476     then have "\<not> (\<exists>n. a $ n \<noteq> b $ n)" by simp
   477     then show "dist a b = 0" by (simp add: dist_fps_def)
   478   next
   479     assume d: "dist a b = 0"
   480     then have "\<forall>n. a$n = b$n"
   481       by - (rule ccontr, simp add: dist_fps_def)
   482     then show "a = b" by (simp add: fps_eq_iff)
   483   qed
   484   then have th'[simp]: "dist a a = 0" for a :: "'a fps"
   485     by simp
   486 
   487   fix a b c :: "'a fps"
   488   consider "a = b" | "c = a \<or> c = b" | "a \<noteq> b" "a \<noteq> c" "b \<noteq> c" by blast
   489   then show "dist a b \<le> dist a c + dist b c"
   490   proof cases
   491     case 1
   492     then have "dist a b = 0" unfolding th .
   493     then show ?thesis
   494       using dist_fps_ge0 [of a c] dist_fps_ge0 [of b c] by simp
   495   next
   496     case 2
   497     then show ?thesis
   498       by (cases "c = a") (simp_all add: th dist_fps_sym)
   499   next
   500     case neq: 3
   501     def n \<equiv> "\<lambda>a b::'a fps. LEAST n. a$n \<noteq> b$n"
   502     then have n': "\<And>m a b. m < n a b \<Longrightarrow> a$m = b$m"
   503       by (auto dest: not_less_Least)
   504     from neq have dab: "dist a b = inverse (2 ^ n a b)"
   505       and dac: "dist a c = inverse (2 ^ n a c)"
   506       and dbc: "dist b c = inverse (2 ^ n b c)"
   507       by (simp_all add: dist_fps_def n_def fps_eq_iff)
   508     from neq have nz: "dist a b \<noteq> 0" "dist a c \<noteq> 0" "dist b c \<noteq> 0"
   509       unfolding th by simp_all
   510     from nz have pos: "dist a b > 0" "dist a c > 0" "dist b c > 0"
   511       using dist_fps_ge0[of a b] dist_fps_ge0[of a c] dist_fps_ge0[of b c]
   512       by auto
   513     have th1: "\<And>n. (2::real)^n > 0" by auto
   514     have False if "dist a b > dist a c + dist b c"
   515     proof -
   516       from that have gt: "dist a b > dist a c" "dist a b > dist b c"
   517         using pos by auto
   518       from gt have gtn: "n a b < n b c" "n a b < n a c"
   519         unfolding dab dbc dac by (auto simp add: th1)
   520       from n'[OF gtn(2)] n'(1)[OF gtn(1)]
   521       have "a $ n a b = b $ n a b" by simp
   522       moreover have "a $ n a b \<noteq> b $ n a b"
   523          unfolding n_def by (rule LeastI_ex) (insert \<open>a \<noteq> b\<close>, simp add: fps_eq_iff)
   524       ultimately show ?thesis by contradiction
   525     qed
   526     then show ?thesis
   527       by (auto simp add: not_le[symmetric])
   528   qed
   529 qed
   530 
   531 end
   532 
   533 text \<open>The infinite sums and justification of the notation in textbooks.\<close>
   534 
   535 lemma reals_power_lt_ex:
   536   fixes x y :: real
   537   assumes xp: "x > 0"
   538     and y1: "y > 1"
   539   shows "\<exists>k>0. (1/y)^k < x"
   540 proof -
   541   have yp: "y > 0"
   542     using y1 by simp
   543   from reals_Archimedean2[of "max 0 (- log y x) + 1"]
   544   obtain k :: nat where k: "real k > max 0 (- log y x) + 1"
   545     by blast
   546   from k have kp: "k > 0"
   547     by simp
   548   from k have "real k > - log y x"
   549     by simp
   550   then have "ln y * real k > - ln x"
   551     unfolding log_def
   552     using ln_gt_zero_iff[OF yp] y1
   553     by (simp add: minus_divide_left field_simps del: minus_divide_left[symmetric])
   554   then have "ln y * real k + ln x > 0"
   555     by simp
   556   then have "exp (real k * ln y + ln x) > exp 0"
   557     by (simp add: ac_simps)
   558   then have "y ^ k * x > 1"
   559     unfolding exp_zero exp_add exp_real_of_nat_mult exp_ln [OF xp] exp_ln [OF yp]
   560     by simp
   561   then have "x > (1 / y)^k" using yp
   562     by (simp add: field_simps)
   563   then show ?thesis
   564     using kp by blast
   565 qed
   566 
   567 lemma X_nth[simp]: "X$n = (if n = 1 then 1 else 0)"
   568   by (simp add: X_def)
   569 
   570 lemma X_power_nth[simp]: "(X^k) $n = (if n = k then 1 else 0::'a::comm_ring_1)"
   571   by (simp add: X_power_iff)
   572 
   573 lemma fps_sum_rep_nth: "(setsum (\<lambda>i. fps_const(a$i)*X^i) {0..m})$n =
   574     (if n \<le> m then a$n else 0::'a::comm_ring_1)"
   575   apply (auto simp add: fps_setsum_nth cond_value_iff cong del: if_weak_cong)
   576   apply (simp add: setsum.delta')
   577   done
   578 
   579 lemma fps_notation: "(\<lambda>n. setsum (\<lambda>i. fps_const(a$i) * X^i) {0..n}) ----> a"
   580   (is "?s ----> a")
   581 proof -
   582   have "\<exists>n0. \<forall>n \<ge> n0. dist (?s n) a < r" if "r > 0" for r
   583   proof -
   584     obtain n0 where n0: "(1/2)^n0 < r" "n0 > 0"
   585       using reals_power_lt_ex[OF \<open>r > 0\<close>, of 2] by auto
   586     show ?thesis
   587     proof -
   588       have "dist (?s n) a < r" if nn0: "n \<ge> n0" for n
   589       proof -
   590         from that have thnn0: "(1/2)^n \<le> (1/2 :: real)^n0"
   591           by (simp add: divide_simps)
   592         show ?thesis
   593         proof (cases "?s n = a")
   594           case True
   595           then show ?thesis
   596             unfolding dist_eq_0_iff[of "?s n" a, symmetric]
   597             using \<open>r > 0\<close> by (simp del: dist_eq_0_iff)
   598         next
   599           case False
   600           def k \<equiv> "LEAST i. ?s n $ i \<noteq> a $ i"
   601           from False have dth: "dist (?s n) a = (1/2)^k"
   602             by (auto simp add: dist_fps_def inverse_eq_divide power_divide k_def fps_eq_iff)
   603           from False have kn: "k > n"
   604             by (auto simp: fps_sum_rep_nth not_le k_def fps_eq_iff
   605               split: split_if_asm intro: LeastI2_ex)
   606           then have "dist (?s n) a < (1/2)^n"
   607             unfolding dth by (simp add: divide_simps)
   608           also have "\<dots> \<le> (1/2)^n0"
   609             using nn0 by (simp add: divide_simps)
   610           also have "\<dots> < r"
   611             using n0 by simp
   612           finally show ?thesis .
   613         qed
   614       qed
   615       then show ?thesis by blast
   616     qed
   617   qed
   618   then show ?thesis
   619     unfolding lim_sequentially by blast
   620 qed
   621 
   622 
   623 subsection \<open>Inverses of formal power series\<close>
   624 
   625 declare setsum.cong[fundef_cong]
   626 
   627 instantiation fps :: ("{comm_monoid_add,inverse,times,uminus}") inverse
   628 begin
   629 
   630 fun natfun_inverse:: "'a fps \<Rightarrow> nat \<Rightarrow> 'a"
   631 where
   632   "natfun_inverse f 0 = inverse (f$0)"
   633 | "natfun_inverse f n = - inverse (f$0) * setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}"
   634 
   635 definition fps_inverse_def: "inverse f = (if f $ 0 = 0 then 0 else Abs_fps (natfun_inverse f))"
   636 
   637 definition fps_divide_def: "divide = (\<lambda>(f::'a fps) g. f * inverse g)"
   638 
   639 instance ..
   640 
   641 end
   642 
   643 lemma fps_inverse_zero [simp]:
   644   "inverse (0 :: 'a::{comm_monoid_add,inverse,times,uminus} fps) = 0"
   645   by (simp add: fps_ext fps_inverse_def)
   646 
   647 lemma fps_inverse_one [simp]: "inverse (1 :: 'a::{division_ring,zero_neq_one} fps) = 1"
   648   apply (auto simp add: expand_fps_eq fps_inverse_def)
   649   apply (case_tac n)
   650   apply auto
   651   done
   652 
   653 lemma inverse_mult_eq_1 [intro]:
   654   assumes f0: "f$0 \<noteq> (0::'a::field)"
   655   shows "inverse f * f = 1"
   656 proof -
   657   have c: "inverse f * f = f * inverse f"
   658     by (simp add: mult.commute)
   659   from f0 have ifn: "\<And>n. inverse f $ n = natfun_inverse f n"
   660     by (simp add: fps_inverse_def)
   661   from f0 have th0: "(inverse f * f) $ 0 = 1"
   662     by (simp add: fps_mult_nth fps_inverse_def)
   663   have "(inverse f * f)$n = 0" if np: "n > 0" for n
   664   proof -
   665     from np have eq: "{0..n} = {0} \<union> {1 .. n}"
   666       by auto
   667     have d: "{0} \<inter> {1 .. n} = {}"
   668       by auto
   669     from f0 np have th0: "- (inverse f $ n) =
   670       (setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}) / (f$0)"
   671       by (cases n) (simp_all add: divide_inverse fps_inverse_def)
   672     from th0[symmetric, unfolded nonzero_divide_eq_eq[OF f0]]
   673     have th1: "setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n} = - (f$0) * (inverse f)$n"
   674       by (simp add: field_simps)
   675     have "(f * inverse f) $ n = (\<Sum>i = 0..n. f $i * natfun_inverse f (n - i))"
   676       unfolding fps_mult_nth ifn ..
   677     also have "\<dots> = f$0 * natfun_inverse f n + (\<Sum>i = 1..n. f$i * natfun_inverse f (n-i))"
   678       by (simp add: eq)
   679     also have "\<dots> = 0"
   680       unfolding th1 ifn by simp
   681     finally show ?thesis unfolding c .
   682   qed
   683   with th0 show ?thesis
   684     by (simp add: fps_eq_iff)
   685 qed
   686 
   687 lemma fps_inverse_0_iff[simp]: "(inverse f) $ 0 = (0::'a::division_ring) \<longleftrightarrow> f $ 0 = 0"
   688   by (simp add: fps_inverse_def nonzero_imp_inverse_nonzero)
   689 
   690 lemma fps_inverse_eq_0_iff[simp]: "inverse f = (0:: ('a::field) fps) \<longleftrightarrow> f $ 0 = 0"
   691   (is "?lhs \<longleftrightarrow> ?rhs")
   692 proof
   693   show ?lhs if ?rhs
   694     using that by (simp add: fps_inverse_def)
   695   show ?rhs if h: ?lhs
   696   proof (rule ccontr)
   697     assume c: "f $0 \<noteq> 0"
   698     from inverse_mult_eq_1[OF c] h show False
   699       by simp
   700   qed
   701 qed
   702 
   703 lemma fps_inverse_idempotent[intro]:
   704   assumes f0: "f$0 \<noteq> (0::'a::field)"
   705   shows "inverse (inverse f) = f"
   706 proof -
   707   from f0 have if0: "inverse f $ 0 \<noteq> 0" by simp
   708   from inverse_mult_eq_1[OF f0] inverse_mult_eq_1[OF if0]
   709   have "inverse f * f = inverse f * inverse (inverse f)"
   710     by (simp add: ac_simps)
   711   then show ?thesis
   712     using f0 unfolding mult_cancel_left by simp
   713 qed
   714 
   715 lemma fps_inverse_unique:
   716   assumes f0: "f$0 \<noteq> (0::'a::field)"
   717     and fg: "f*g = 1"
   718   shows "inverse f = g"
   719 proof -
   720   from inverse_mult_eq_1[OF f0] fg
   721   have th0: "inverse f * f = g * f"
   722     by (simp add: ac_simps)
   723   then show ?thesis
   724     using f0
   725     unfolding mult_cancel_right
   726     by (auto simp add: expand_fps_eq)
   727 qed
   728 
   729 lemma setsum_zero_lemma:
   730   fixes n::nat
   731   assumes "0 < n"
   732   shows "(\<Sum>i = 0..n. if n = i then 1 else if n - i = 1 then - 1 else 0) = (0::'a::field)"
   733 proof -
   734   let ?f = "\<lambda>i. if n = i then 1 else if n - i = 1 then - 1 else 0"
   735   let ?g = "\<lambda>i. if i = n then 1 else if i = n - 1 then - 1 else 0"
   736   let ?h = "\<lambda>i. if i=n - 1 then - 1 else 0"
   737   have th1: "setsum ?f {0..n} = setsum ?g {0..n}"
   738     by (rule setsum.cong) auto
   739   have th2: "setsum ?g {0..n - 1} = setsum ?h {0..n - 1}"
   740     apply (rule setsum.cong)
   741     using assms
   742     apply auto
   743     done
   744   have eq: "{0 .. n} = {0.. n - 1} \<union> {n}"
   745     by auto
   746   from assms have d: "{0.. n - 1} \<inter> {n} = {}"
   747     by auto
   748   have f: "finite {0.. n - 1}" "finite {n}"
   749     by auto
   750   show ?thesis
   751     unfolding th1
   752     apply (simp add: setsum.union_disjoint[OF f d, unfolded eq[symmetric]] del: One_nat_def)
   753     unfolding th2
   754     apply (simp add: setsum.delta)
   755     done
   756 qed
   757 
   758 lemma fps_inverse_gp: "inverse (Abs_fps(\<lambda>n. (1::'a::field))) =
   759     Abs_fps (\<lambda>n. if n= 0 then 1 else if n=1 then - 1 else 0)"
   760   apply (rule fps_inverse_unique)
   761   apply (simp_all add: fps_eq_iff fps_mult_nth setsum_zero_lemma)
   762   done
   763 
   764 
   765 subsection \<open>Formal Derivatives, and the MacLaurin theorem around 0\<close>
   766 
   767 definition "fps_deriv f = Abs_fps (\<lambda>n. of_nat (n + 1) * f $ (n + 1))"
   768 
   769 lemma fps_deriv_nth[simp]: "fps_deriv f $ n = of_nat (n +1) * f $ (n + 1)"
   770   by (simp add: fps_deriv_def)
   771 
   772 lemma fps_deriv_linear[simp]:
   773   "fps_deriv (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
   774     fps_const a * fps_deriv f + fps_const b * fps_deriv g"
   775   unfolding fps_eq_iff fps_add_nth  fps_const_mult_left fps_deriv_nth by (simp add: field_simps)
   776 
   777 lemma fps_deriv_mult[simp]:
   778   fixes f :: "'a::comm_ring_1 fps"
   779   shows "fps_deriv (f * g) = f * fps_deriv g + fps_deriv f * g"
   780 proof -
   781   let ?D = "fps_deriv"
   782   have "(f * ?D g + ?D f * g) $ n = ?D (f*g) $ n" for n
   783   proof -
   784     let ?Zn = "{0 ..n}"
   785     let ?Zn1 = "{0 .. n + 1}"
   786     let ?g = "\<lambda>i. of_nat (i+1) * g $ (i+1) * f $ (n - i) +
   787         of_nat (i+1)* f $ (i+1) * g $ (n - i)"
   788     let ?h = "\<lambda>i. of_nat i * g $ i * f $ ((n+1) - i) +
   789         of_nat i* f $ i * g $ ((n + 1) - i)"
   790     have s0: "setsum (\<lambda>i. of_nat i * f $ i * g $ (n + 1 - i)) ?Zn1 =
   791       setsum (\<lambda>i. of_nat (n + 1 - i) * f $ (n + 1 - i) * g $ i) ?Zn1"
   792        by (rule setsum.reindex_bij_witness[where i="op - (n + 1)" and j="op - (n + 1)"]) auto
   793     have s1: "setsum (\<lambda>i. f $ i * g $ (n + 1 - i)) ?Zn1 =
   794       setsum (\<lambda>i. f $ (n + 1 - i) * g $ i) ?Zn1"
   795        by (rule setsum.reindex_bij_witness[where i="op - (n + 1)" and j="op - (n + 1)"]) auto
   796     have "(f * ?D g + ?D f * g)$n = (?D g * f + ?D f * g)$n"
   797       by (simp only: mult.commute)
   798     also have "\<dots> = (\<Sum>i = 0..n. ?g i)"
   799       by (simp add: fps_mult_nth setsum.distrib[symmetric])
   800     also have "\<dots> = setsum ?h {0..n+1}"
   801       by (rule setsum.reindex_bij_witness_not_neutral
   802             [where S'="{}" and T'="{0}" and j="Suc" and i="\<lambda>i. i - 1"]) auto
   803     also have "\<dots> = (fps_deriv (f * g)) $ n"
   804       apply (simp only: fps_deriv_nth fps_mult_nth setsum.distrib)
   805       unfolding s0 s1
   806       unfolding setsum.distrib[symmetric] setsum_right_distrib
   807       apply (rule setsum.cong)
   808       apply (auto simp add: of_nat_diff field_simps)
   809       done
   810     finally show ?thesis .
   811   qed
   812   then show ?thesis
   813     unfolding fps_eq_iff by auto
   814 qed
   815 
   816 lemma fps_deriv_X[simp]: "fps_deriv X = 1"
   817   by (simp add: fps_deriv_def X_def fps_eq_iff)
   818 
   819 lemma fps_deriv_neg[simp]:
   820   "fps_deriv (- (f:: 'a::comm_ring_1 fps)) = - (fps_deriv f)"
   821   by (simp add: fps_eq_iff fps_deriv_def)
   822 
   823 lemma fps_deriv_add[simp]:
   824   "fps_deriv ((f:: 'a::comm_ring_1 fps) + g) = fps_deriv f + fps_deriv g"
   825   using fps_deriv_linear[of 1 f 1 g] by simp
   826 
   827 lemma fps_deriv_sub[simp]:
   828   "fps_deriv ((f:: 'a::comm_ring_1 fps) - g) = fps_deriv f - fps_deriv g"
   829   using fps_deriv_add [of f "- g"] by simp
   830 
   831 lemma fps_deriv_const[simp]: "fps_deriv (fps_const c) = 0"
   832   by (simp add: fps_ext fps_deriv_def fps_const_def)
   833 
   834 lemma fps_deriv_mult_const_left[simp]:
   835   "fps_deriv (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_deriv f"
   836   by simp
   837 
   838 lemma fps_deriv_0[simp]: "fps_deriv 0 = 0"
   839   by (simp add: fps_deriv_def fps_eq_iff)
   840 
   841 lemma fps_deriv_1[simp]: "fps_deriv 1 = 0"
   842   by (simp add: fps_deriv_def fps_eq_iff )
   843 
   844 lemma fps_deriv_mult_const_right[simp]:
   845   "fps_deriv (f * fps_const (c::'a::comm_ring_1)) = fps_deriv f * fps_const c"
   846   by simp
   847 
   848 lemma fps_deriv_setsum:
   849   "fps_deriv (setsum f S) = setsum (\<lambda>i. fps_deriv (f i :: 'a::comm_ring_1 fps)) S"
   850 proof (cases "finite S")
   851   case False
   852   then show ?thesis by simp
   853 next
   854   case True
   855   show ?thesis by (induct rule: finite_induct [OF True]) simp_all
   856 qed
   857 
   858 lemma fps_deriv_eq_0_iff [simp]:
   859   "fps_deriv f = 0 \<longleftrightarrow> f = fps_const (f$0 :: 'a::{idom,semiring_char_0})"
   860   (is "?lhs \<longleftrightarrow> ?rhs")
   861 proof
   862   show ?lhs if ?rhs
   863   proof -
   864     from that have "fps_deriv f = fps_deriv (fps_const (f$0))"
   865       by simp
   866     then show ?thesis
   867       by simp
   868   qed
   869   show ?rhs if ?lhs
   870   proof -
   871     from that have "\<forall>n. (fps_deriv f)$n = 0"
   872       by simp
   873     then have "\<forall>n. f$(n+1) = 0"
   874       by (simp del: of_nat_Suc of_nat_add One_nat_def)
   875     then show ?thesis
   876       apply (clarsimp simp add: fps_eq_iff fps_const_def)
   877       apply (erule_tac x="n - 1" in allE)
   878       apply simp
   879       done
   880   qed
   881 qed
   882 
   883 lemma fps_deriv_eq_iff:
   884   fixes f :: "'a::{idom,semiring_char_0} fps"
   885   shows "fps_deriv f = fps_deriv g \<longleftrightarrow> (f = fps_const(f$0 - g$0) + g)"
   886 proof -
   887   have "fps_deriv f = fps_deriv g \<longleftrightarrow> fps_deriv (f - g) = 0"
   888     by simp
   889   also have "\<dots> \<longleftrightarrow> f - g = fps_const ((f - g) $ 0)"
   890     unfolding fps_deriv_eq_0_iff ..
   891   finally show ?thesis
   892     by (simp add: field_simps)
   893 qed
   894 
   895 lemma fps_deriv_eq_iff_ex:
   896   "(fps_deriv f = fps_deriv g) \<longleftrightarrow> (\<exists>c::'a::{idom,semiring_char_0}. f = fps_const c + g)"
   897   by (auto simp: fps_deriv_eq_iff)
   898 
   899 
   900 fun fps_nth_deriv :: "nat \<Rightarrow> 'a::semiring_1 fps \<Rightarrow> 'a fps"
   901 where
   902   "fps_nth_deriv 0 f = f"
   903 | "fps_nth_deriv (Suc n) f = fps_nth_deriv n (fps_deriv f)"
   904 
   905 lemma fps_nth_deriv_commute: "fps_nth_deriv (Suc n) f = fps_deriv (fps_nth_deriv n f)"
   906   by (induct n arbitrary: f) auto
   907 
   908 lemma fps_nth_deriv_linear[simp]:
   909   "fps_nth_deriv n (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
   910     fps_const a * fps_nth_deriv n f + fps_const b * fps_nth_deriv n g"
   911   by (induct n arbitrary: f g) (auto simp add: fps_nth_deriv_commute)
   912 
   913 lemma fps_nth_deriv_neg[simp]:
   914   "fps_nth_deriv n (- (f :: 'a::comm_ring_1 fps)) = - (fps_nth_deriv n f)"
   915   by (induct n arbitrary: f) simp_all
   916 
   917 lemma fps_nth_deriv_add[simp]:
   918   "fps_nth_deriv n ((f :: 'a::comm_ring_1 fps) + g) = fps_nth_deriv n f + fps_nth_deriv n g"
   919   using fps_nth_deriv_linear[of n 1 f 1 g] by simp
   920 
   921 lemma fps_nth_deriv_sub[simp]:
   922   "fps_nth_deriv n ((f :: 'a::comm_ring_1 fps) - g) = fps_nth_deriv n f - fps_nth_deriv n g"
   923   using fps_nth_deriv_add [of n f "- g"] by simp
   924 
   925 lemma fps_nth_deriv_0[simp]: "fps_nth_deriv n 0 = 0"
   926   by (induct n) simp_all
   927 
   928 lemma fps_nth_deriv_1[simp]: "fps_nth_deriv n 1 = (if n = 0 then 1 else 0)"
   929   by (induct n) simp_all
   930 
   931 lemma fps_nth_deriv_const[simp]:
   932   "fps_nth_deriv n (fps_const c) = (if n = 0 then fps_const c else 0)"
   933   by (cases n) simp_all
   934 
   935 lemma fps_nth_deriv_mult_const_left[simp]:
   936   "fps_nth_deriv n (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_nth_deriv n f"
   937   using fps_nth_deriv_linear[of n "c" f 0 0 ] by simp
   938 
   939 lemma fps_nth_deriv_mult_const_right[simp]:
   940   "fps_nth_deriv n (f * fps_const (c::'a::comm_ring_1)) = fps_nth_deriv n f * fps_const c"
   941   using fps_nth_deriv_linear[of n "c" f 0 0] by (simp add: mult.commute)
   942 
   943 lemma fps_nth_deriv_setsum:
   944   "fps_nth_deriv n (setsum f S) = setsum (\<lambda>i. fps_nth_deriv n (f i :: 'a::comm_ring_1 fps)) S"
   945 proof (cases "finite S")
   946   case True
   947   show ?thesis by (induct rule: finite_induct [OF True]) simp_all
   948 next
   949   case False
   950   then show ?thesis by simp
   951 qed
   952 
   953 lemma fps_deriv_maclauren_0:
   954   "(fps_nth_deriv k (f :: 'a::comm_semiring_1 fps)) $ 0 = of_nat (fact k) * f $ k"
   955   by (induct k arbitrary: f) (auto simp add: field_simps of_nat_mult)
   956 
   957 
   958 subsection \<open>Powers\<close>
   959 
   960 lemma fps_power_zeroth_eq_one: "a$0 =1 \<Longrightarrow> a^n $ 0 = (1::'a::semiring_1)"
   961   by (induct n) (auto simp add: expand_fps_eq fps_mult_nth)
   962 
   963 lemma fps_power_first_eq: "(a :: 'a::comm_ring_1 fps) $ 0 =1 \<Longrightarrow> a^n $ 1 = of_nat n * a$1"
   964 proof (induct n)
   965   case 0
   966   then show ?case by simp
   967 next
   968   case (Suc n)
   969   show ?case unfolding power_Suc fps_mult_nth
   970     using Suc.hyps[OF \<open>a$0 = 1\<close>] \<open>a$0 = 1\<close> fps_power_zeroth_eq_one[OF \<open>a$0=1\<close>]
   971     by (simp add: field_simps)
   972 qed
   973 
   974 lemma startsby_one_power:"a $ 0 = (1::'a::comm_ring_1) \<Longrightarrow> a^n $ 0 = 1"
   975   by (induct n) (auto simp add: fps_mult_nth)
   976 
   977 lemma startsby_zero_power:"a $0 = (0::'a::comm_ring_1) \<Longrightarrow> n > 0 \<Longrightarrow> a^n $0 = 0"
   978   by (induct n) (auto simp add: fps_mult_nth)
   979 
   980 lemma startsby_power:"a $0 = (v::'a::comm_ring_1) \<Longrightarrow> a^n $0 = v^n"
   981   by (induct n) (auto simp add: fps_mult_nth)
   982 
   983 lemma startsby_zero_power_iff[simp]: "a^n $0 = (0::'a::idom) \<longleftrightarrow> n \<noteq> 0 \<and> a$0 = 0"
   984   apply (rule iffI)
   985   apply (induct n)
   986   apply (auto simp add: fps_mult_nth)
   987   apply (rule startsby_zero_power, simp_all)
   988   done
   989 
   990 lemma startsby_zero_power_prefix:
   991   assumes a0: "a $ 0 = (0::'a::idom)"
   992   shows "\<forall>n < k. a ^ k $ n = 0"
   993   using a0
   994 proof (induct k rule: nat_less_induct)
   995   fix k
   996   assume H: "\<forall>m<k. a $0 =  0 \<longrightarrow> (\<forall>n<m. a ^ m $ n = 0)" and a0: "a $ 0 = 0"
   997   show "\<forall>m<k. a ^ k $ m = 0"
   998   proof (cases k)
   999     case 0
  1000     then show ?thesis by simp
  1001   next
  1002     case (Suc l)
  1003     have "a^k $ m = 0" if mk: "m < k" for m
  1004     proof (cases "m = 0")
  1005       case True
  1006       then show ?thesis
  1007         using startsby_zero_power[of a k] Suc a0 by simp
  1008     next
  1009       case False
  1010       have "a ^k $ m = (a^l * a) $m"
  1011         by (simp add: Suc mult.commute)
  1012       also have "\<dots> = (\<Sum>i = 0..m. a ^ l $ i * a $ (m - i))"
  1013         by (simp add: fps_mult_nth)
  1014       also have "\<dots> = 0"
  1015         apply (rule setsum.neutral)
  1016         apply auto
  1017         apply (case_tac "x = m")
  1018         using a0 apply simp
  1019         apply (rule H[rule_format])
  1020         using a0 Suc mk apply auto
  1021         done
  1022       finally show ?thesis .
  1023     qed
  1024     then show ?thesis by blast
  1025   qed
  1026 qed
  1027 
  1028 lemma startsby_zero_setsum_depends:
  1029   assumes a0: "a $0 = (0::'a::idom)"
  1030     and kn: "n \<ge> k"
  1031   shows "setsum (\<lambda>i. (a ^ i)$k) {0 .. n} = setsum (\<lambda>i. (a ^ i)$k) {0 .. k}"
  1032   apply (rule setsum.mono_neutral_right)
  1033   using kn
  1034   apply auto
  1035   apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1036   apply arith
  1037   done
  1038 
  1039 lemma startsby_zero_power_nth_same:
  1040   assumes a0: "a$0 = (0::'a::idom)"
  1041   shows "a^n $ n = (a$1) ^ n"
  1042 proof (induct n)
  1043   case 0
  1044   then show ?case by simp
  1045 next
  1046   case (Suc n)
  1047   have "a ^ Suc n $ (Suc n) = (a^n * a)$(Suc n)"
  1048     by (simp add: field_simps)
  1049   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {0.. Suc n}"
  1050     by (simp add: fps_mult_nth)
  1051   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {n .. Suc n}"
  1052     apply (rule setsum.mono_neutral_right)
  1053     apply simp
  1054     apply clarsimp
  1055     apply clarsimp
  1056     apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1057     apply arith
  1058     done
  1059   also have "\<dots> = a^n $ n * a$1"
  1060     using a0 by simp
  1061   finally show ?case
  1062     using Suc.hyps by simp
  1063 qed
  1064 
  1065 lemma fps_inverse_power:
  1066   fixes a :: "'a::field fps"
  1067   shows "inverse (a^n) = inverse a ^ n"
  1068 proof (cases "a$0 = 0")
  1069   case True
  1070   then have eq: "inverse a = 0"
  1071     by (simp add: fps_inverse_def)
  1072   consider "n = 0" | "n > 0" by blast
  1073   then show ?thesis
  1074   proof cases
  1075     case 1
  1076     then show ?thesis by simp
  1077   next
  1078     case 2
  1079     from startsby_zero_power[OF True this] eq show ?thesis
  1080       by (simp add: fps_inverse_def)
  1081   qed
  1082 next
  1083   case False
  1084   show ?thesis
  1085     apply (rule fps_inverse_unique)
  1086     apply (simp add: False)
  1087     unfolding power_mult_distrib[symmetric]
  1088     apply (rule ssubst[where t = "a * inverse a" and s= 1])
  1089     apply simp_all
  1090     apply (subst mult.commute)
  1091     apply (rule inverse_mult_eq_1[OF False])
  1092     done
  1093 qed
  1094 
  1095 lemma fps_deriv_power:
  1096   "fps_deriv (a ^ n) = fps_const (of_nat n :: 'a::comm_ring_1) * fps_deriv a * a ^ (n - 1)"
  1097   apply (induct n)
  1098   apply (auto simp add: field_simps fps_const_add[symmetric] simp del: fps_const_add)
  1099   apply (case_tac n)
  1100   apply (auto simp add: field_simps)
  1101   done
  1102 
  1103 lemma fps_inverse_deriv:
  1104   fixes a :: "'a::field fps"
  1105   assumes a0: "a$0 \<noteq> 0"
  1106   shows "fps_deriv (inverse a) = - fps_deriv a * (inverse a)\<^sup>2"
  1107 proof -
  1108   from inverse_mult_eq_1[OF a0]
  1109   have "fps_deriv (inverse a * a) = 0" by simp
  1110   then have "inverse a * fps_deriv a + fps_deriv (inverse a) * a = 0"
  1111     by simp
  1112   then have "inverse a * (inverse a * fps_deriv a + fps_deriv (inverse a) * a) = 0"
  1113     by simp
  1114   with inverse_mult_eq_1[OF a0]
  1115   have "(inverse a)\<^sup>2 * fps_deriv a + fps_deriv (inverse a) = 0"
  1116     unfolding power2_eq_square
  1117     apply (simp add: field_simps)
  1118     apply (simp add: mult.assoc[symmetric])
  1119     done
  1120   then have "(inverse a)\<^sup>2 * fps_deriv a + fps_deriv (inverse a) - fps_deriv a * (inverse a)\<^sup>2 =
  1121       0 - fps_deriv a * (inverse a)\<^sup>2"
  1122     by simp
  1123   then show "fps_deriv (inverse a) = - fps_deriv a * (inverse a)\<^sup>2"
  1124     by (simp add: field_simps)
  1125 qed
  1126 
  1127 lemma fps_inverse_mult:
  1128   fixes a :: "'a::field fps"
  1129   shows "inverse (a * b) = inverse a * inverse b"
  1130 proof -
  1131   consider "a $ 0 = 0" | "b $ 0 = 0" | "a $ 0 \<noteq> 0" "b $ 0 \<noteq> 0"
  1132     by blast
  1133   then show ?thesis
  1134   proof cases
  1135     case a: 1
  1136     then have "(a * b) $ 0 = 0"
  1137       by (simp add: fps_mult_nth)
  1138     with a have th: "inverse a = 0" "inverse (a * b) = 0"
  1139       by simp_all
  1140     show ?thesis
  1141       unfolding th by simp
  1142   next
  1143     case b: 2
  1144     then have "(a * b) $ 0 = 0"
  1145       by (simp add: fps_mult_nth)
  1146     with b have th: "inverse b = 0" "inverse (a * b) = 0"
  1147       by simp_all
  1148     show ?thesis
  1149       unfolding th by simp
  1150   next
  1151     case ab: 3
  1152     then have ab0:"(a * b) $ 0 \<noteq> 0"
  1153       by (simp add: fps_mult_nth)
  1154     from inverse_mult_eq_1[OF ab0]
  1155     have "inverse (a*b) * (a*b) * inverse a * inverse b = 1 * inverse a * inverse b"
  1156       by simp
  1157     then have "inverse (a*b) * (inverse a * a) * (inverse b * b) = inverse a * inverse b"
  1158       by (simp add: field_simps)
  1159     then show ?thesis
  1160       using inverse_mult_eq_1[OF ab(1)] inverse_mult_eq_1[OF ab(2)] by simp
  1161   qed
  1162 qed
  1163 
  1164 lemma fps_inverse_deriv':
  1165   fixes a :: "'a::field fps"
  1166   assumes a0: "a $ 0 \<noteq> 0"
  1167   shows "fps_deriv (inverse a) = - fps_deriv a / a\<^sup>2"
  1168   using fps_inverse_deriv[OF a0]
  1169   unfolding power2_eq_square fps_divide_def fps_inverse_mult
  1170   by simp
  1171 
  1172 lemma inverse_mult_eq_1':
  1173   assumes f0: "f$0 \<noteq> (0::'a::field)"
  1174   shows "f * inverse f = 1"
  1175   by (metis mult.commute inverse_mult_eq_1 f0)
  1176 
  1177 lemma fps_divide_deriv:
  1178   fixes a :: "'a::field fps"
  1179   assumes a0: "b$0 \<noteq> 0"
  1180   shows "fps_deriv (a / b) = (fps_deriv a * b - a * fps_deriv b) / b\<^sup>2"
  1181   using fps_inverse_deriv[OF a0]
  1182   by (simp add: fps_divide_def field_simps
  1183     power2_eq_square fps_inverse_mult inverse_mult_eq_1'[OF a0])
  1184 
  1185 
  1186 lemma fps_inverse_gp': "inverse (Abs_fps (\<lambda>n. 1::'a::field)) = 1 - X"
  1187   by (simp add: fps_inverse_gp fps_eq_iff X_def)
  1188 
  1189 lemma fps_nth_deriv_X[simp]: "fps_nth_deriv n X = (if n = 0 then X else if n=1 then 1 else 0)"
  1190   by (cases n) simp_all
  1191 
  1192 lemma fps_inverse_X_plus1: "inverse (1 + X) = Abs_fps (\<lambda>n. (- (1::'a::field)) ^ n)"
  1193   (is "_ = ?r")
  1194 proof -
  1195   have eq: "(1 + X) * ?r = 1"
  1196     unfolding minus_one_power_iff
  1197     by (auto simp add: field_simps fps_eq_iff)
  1198   show ?thesis
  1199     by (auto simp add: eq intro: fps_inverse_unique)
  1200 qed
  1201 
  1202 
  1203 subsection \<open>Integration\<close>
  1204 
  1205 definition fps_integral :: "'a::field_char_0 fps \<Rightarrow> 'a \<Rightarrow> 'a fps"
  1206   where "fps_integral a a0 = Abs_fps (\<lambda>n. if n = 0 then a0 else (a$(n - 1) / of_nat n))"
  1207 
  1208 lemma fps_deriv_fps_integral: "fps_deriv (fps_integral a a0) = a"
  1209   unfolding fps_integral_def fps_deriv_def
  1210   by (simp add: fps_eq_iff del: of_nat_Suc)
  1211 
  1212 lemma fps_integral_linear:
  1213   "fps_integral (fps_const a * f + fps_const b * g) (a*a0 + b*b0) =
  1214     fps_const a * fps_integral f a0 + fps_const b * fps_integral g b0"
  1215   (is "?l = ?r")
  1216 proof -
  1217   have "fps_deriv ?l = fps_deriv ?r"
  1218     by (simp add: fps_deriv_fps_integral)
  1219   moreover have "?l$0 = ?r$0"
  1220     by (simp add: fps_integral_def)
  1221   ultimately show ?thesis
  1222     unfolding fps_deriv_eq_iff by auto
  1223 qed
  1224 
  1225 
  1226 subsection \<open>Composition of FPSs\<close>
  1227 
  1228 definition fps_compose :: "'a::semiring_1 fps \<Rightarrow> 'a fps \<Rightarrow> 'a fps"  (infixl "oo" 55)
  1229   where "a oo b = Abs_fps (\<lambda>n. setsum (\<lambda>i. a$i * (b^i$n)) {0..n})"
  1230 
  1231 lemma fps_compose_nth: "(a oo b)$n = setsum (\<lambda>i. a$i * (b^i$n)) {0..n}"
  1232   by (simp add: fps_compose_def)
  1233 
  1234 lemma fps_compose_X[simp]: "a oo X = (a :: 'a::comm_ring_1 fps)"
  1235   by (simp add: fps_ext fps_compose_def mult_delta_right setsum.delta')
  1236 
  1237 lemma fps_const_compose[simp]: "fps_const (a::'a::comm_ring_1) oo b = fps_const a"
  1238   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum.delta)
  1239 
  1240 lemma numeral_compose[simp]: "(numeral k :: 'a::comm_ring_1 fps) oo b = numeral k"
  1241   unfolding numeral_fps_const by simp
  1242 
  1243 lemma neg_numeral_compose[simp]: "(- numeral k :: 'a::comm_ring_1 fps) oo b = - numeral k"
  1244   unfolding neg_numeral_fps_const by simp
  1245 
  1246 lemma X_fps_compose_startby0[simp]: "a$0 = 0 \<Longrightarrow> X oo a = (a :: 'a::comm_ring_1 fps)"
  1247   by (simp add: fps_eq_iff fps_compose_def mult_delta_left setsum.delta not_le)
  1248 
  1249 
  1250 subsection \<open>Rules from Herbert Wilf's Generatingfunctionology\<close>
  1251 
  1252 subsubsection \<open>Rule 1\<close>
  1253   (* {a_{n+k}}_0^infty Corresponds to (f - setsum (\<lambda>i. a_i * x^i))/x^h, for h>0*)
  1254 
  1255 lemma fps_power_mult_eq_shift:
  1256   "X^Suc k * Abs_fps (\<lambda>n. a (n + Suc k)) =
  1257     Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a::comm_ring_1) * X^i) {0 .. k}"
  1258   (is "?lhs = ?rhs")
  1259 proof -
  1260   have "?lhs $ n = ?rhs $ n" for n :: nat
  1261   proof -
  1262     have "?lhs $ n = (if n < Suc k then 0 else a n)"
  1263       unfolding X_power_mult_nth by auto
  1264     also have "\<dots> = ?rhs $ n"
  1265     proof (induct k)
  1266       case 0
  1267       then show ?case
  1268         by (simp add: fps_setsum_nth)
  1269     next
  1270       case (Suc k)
  1271       have "(Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. Suc k})$n =
  1272         (Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. k} -
  1273           fps_const (a (Suc k)) * X^ Suc k) $ n"
  1274         by (simp add: field_simps)
  1275       also have "\<dots> = (if n < Suc k then 0 else a n) - (fps_const (a (Suc k)) * X^ Suc k)$n"
  1276         using Suc.hyps[symmetric] unfolding fps_sub_nth by simp
  1277       also have "\<dots> = (if n < Suc (Suc k) then 0 else a n)"
  1278         unfolding X_power_mult_right_nth
  1279         apply (auto simp add: not_less fps_const_def)
  1280         apply (rule cong[of a a, OF refl])
  1281         apply arith
  1282         done
  1283       finally show ?case
  1284         by simp
  1285     qed
  1286     finally show ?thesis .
  1287   qed
  1288   then show ?thesis
  1289     by (simp add: fps_eq_iff)
  1290 qed
  1291 
  1292 
  1293 subsubsection \<open>Rule 2\<close>
  1294 
  1295   (* We can not reach the form of Wilf, but still near to it using rewrite rules*)
  1296   (* If f reprents {a_n} and P is a polynomial, then
  1297         P(xD) f represents {P(n) a_n}*)
  1298 
  1299 definition "XD = op * X \<circ> fps_deriv"
  1300 
  1301 lemma XD_add[simp]:"XD (a + b) = XD a + XD (b :: 'a::comm_ring_1 fps)"
  1302   by (simp add: XD_def field_simps)
  1303 
  1304 lemma XD_mult_const[simp]:"XD (fps_const (c::'a::comm_ring_1) * a) = fps_const c * XD a"
  1305   by (simp add: XD_def field_simps)
  1306 
  1307 lemma XD_linear[simp]: "XD (fps_const c * a + fps_const d * b) =
  1308     fps_const c * XD a + fps_const d * XD (b :: 'a::comm_ring_1 fps)"
  1309   by simp
  1310 
  1311 lemma XDN_linear:
  1312   "(XD ^^ n) (fps_const c * a + fps_const d * b) =
  1313     fps_const c * (XD ^^ n) a + fps_const d * (XD ^^ n) (b :: 'a::comm_ring_1 fps)"
  1314   by (induct n) simp_all
  1315 
  1316 lemma fps_mult_X_deriv_shift: "X* fps_deriv a = Abs_fps (\<lambda>n. of_nat n* a$n)"
  1317   by (simp add: fps_eq_iff)
  1318 
  1319 lemma fps_mult_XD_shift:
  1320   "(XD ^^ k) (a :: 'a::comm_ring_1 fps) = Abs_fps (\<lambda>n. (of_nat n ^ k) * a$n)"
  1321   by (induct k arbitrary: a) (simp_all add: XD_def fps_eq_iff field_simps del: One_nat_def)
  1322 
  1323 
  1324 subsubsection \<open>Rule 3\<close>
  1325 
  1326 text \<open>Rule 3 is trivial and is given by @{text fps_times_def}.\<close>
  1327 
  1328 
  1329 subsubsection \<open>Rule 5 --- summation and "division" by (1 - X)\<close>
  1330 
  1331 lemma fps_divide_X_minus1_setsum_lemma:
  1332   "a = ((1::'a::comm_ring_1 fps) - X) * Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1333 proof -
  1334   let ?sa = "Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1335   have th0: "\<And>i. (1 - (X::'a fps)) $ i = (if i = 0 then 1 else if i = 1 then - 1 else 0)"
  1336     by simp
  1337   have "a$n = ((1 - X) * ?sa) $ n" for n
  1338   proof (cases "n = 0")
  1339     case True
  1340     then show ?thesis
  1341       by (simp add: fps_mult_nth)
  1342   next
  1343     case False
  1344     then have u: "{0} \<union> ({1} \<union> {2..n}) = {0..n}" "{1} \<union> {2..n} = {1..n}"
  1345       "{0..n - 1} \<union> {n} = {0..n}"
  1346       by (auto simp: set_eq_iff)
  1347     have d: "{0} \<inter> ({1} \<union> {2..n}) = {}" "{1} \<inter> {2..n} = {}" "{0..n - 1} \<inter> {n} = {}"
  1348       using False by simp_all
  1349     have f: "finite {0}" "finite {1}" "finite {2 .. n}"
  1350       "finite {0 .. n - 1}" "finite {n}" by simp_all
  1351     have "((1 - X) * ?sa) $ n = setsum (\<lambda>i. (1 - X)$ i * ?sa $ (n - i)) {0 .. n}"
  1352       by (simp add: fps_mult_nth)
  1353     also have "\<dots> = a$n"
  1354       unfolding th0
  1355       unfolding setsum.union_disjoint[OF f(1) finite_UnI[OF f(2,3)] d(1), unfolded u(1)]
  1356       unfolding setsum.union_disjoint[OF f(2) f(3) d(2)]
  1357       apply (simp)
  1358       unfolding setsum.union_disjoint[OF f(4,5) d(3), unfolded u(3)]
  1359       apply simp
  1360       done
  1361     finally show ?thesis
  1362       by simp
  1363   qed
  1364   then show ?thesis
  1365     unfolding fps_eq_iff by blast
  1366 qed
  1367 
  1368 lemma fps_divide_X_minus1_setsum:
  1369   "a /((1::'a::field fps) - X) = Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1370 proof -
  1371   let ?X = "1 - (X::'a fps)"
  1372   have th0: "?X $ 0 \<noteq> 0"
  1373     by simp
  1374   have "a /?X = ?X *  Abs_fps (\<lambda>n::nat. setsum (op $ a) {0..n}) * inverse ?X"
  1375     using fps_divide_X_minus1_setsum_lemma[of a, symmetric] th0
  1376     by (simp add: fps_divide_def mult.assoc)
  1377   also have "\<dots> = (inverse ?X * ?X) * Abs_fps (\<lambda>n::nat. setsum (op $ a) {0..n}) "
  1378     by (simp add: ac_simps)
  1379   finally show ?thesis
  1380     by (simp add: inverse_mult_eq_1[OF th0])
  1381 qed
  1382 
  1383 
  1384 subsubsection \<open>Rule 4 in its more general form: generalizes Rule 3 for an arbitrary
  1385   finite product of FPS, also the relvant instance of powers of a FPS\<close>
  1386 
  1387 definition "natpermute n k = {l :: nat list. length l = k \<and> listsum l = n}"
  1388 
  1389 lemma natlist_trivial_1: "natpermute n 1 = {[n]}"
  1390   apply (auto simp add: natpermute_def)
  1391   apply (case_tac x)
  1392   apply auto
  1393   done
  1394 
  1395 lemma append_natpermute_less_eq:
  1396   assumes "xs @ ys \<in> natpermute n k"
  1397   shows "listsum xs \<le> n"
  1398     and "listsum ys \<le> n"
  1399 proof -
  1400   from assms have "listsum (xs @ ys) = n"
  1401     by (simp add: natpermute_def)
  1402   then have "listsum xs + listsum ys = n"
  1403     by simp
  1404   then show "listsum xs \<le> n" and "listsum ys \<le> n"
  1405     by simp_all
  1406 qed
  1407 
  1408 lemma natpermute_split:
  1409   assumes "h \<le> k"
  1410   shows "natpermute n k =
  1411     (\<Union>m \<in>{0..n}. {l1 @ l2 |l1 l2. l1 \<in> natpermute m h \<and> l2 \<in> natpermute (n - m) (k - h)})"
  1412   (is "?L = ?R" is "_ = (\<Union>m \<in>{0..n}. ?S m)")
  1413 proof
  1414   show "?R \<subseteq> ?L"
  1415   proof
  1416     fix l
  1417     assume l: "l \<in> ?R"
  1418     from l obtain m xs ys where h: "m \<in> {0..n}"
  1419       and xs: "xs \<in> natpermute m h"
  1420       and ys: "ys \<in> natpermute (n - m) (k - h)"
  1421       and leq: "l = xs@ys" by blast
  1422     from xs have xs': "listsum xs = m"
  1423       by (simp add: natpermute_def)
  1424     from ys have ys': "listsum ys = n - m"
  1425       by (simp add: natpermute_def)
  1426     show "l \<in> ?L" using leq xs ys h
  1427       apply (clarsimp simp add: natpermute_def)
  1428       unfolding xs' ys'
  1429       using assms xs ys
  1430       unfolding natpermute_def
  1431       apply simp
  1432       done
  1433   qed
  1434   show "?L \<subseteq> ?R"
  1435   proof
  1436     fix l
  1437     assume l: "l \<in> natpermute n k"
  1438     let ?xs = "take h l"
  1439     let ?ys = "drop h l"
  1440     let ?m = "listsum ?xs"
  1441     from l have ls: "listsum (?xs @ ?ys) = n"
  1442       by (simp add: natpermute_def)
  1443     have xs: "?xs \<in> natpermute ?m h" using l assms
  1444       by (simp add: natpermute_def)
  1445     have l_take_drop: "listsum l = listsum (take h l @ drop h l)"
  1446       by simp
  1447     then have ys: "?ys \<in> natpermute (n - ?m) (k - h)"
  1448       using l assms ls by (auto simp add: natpermute_def simp del: append_take_drop_id)
  1449     from ls have m: "?m \<in> {0..n}"
  1450       by (simp add: l_take_drop del: append_take_drop_id)
  1451     from xs ys ls show "l \<in> ?R"
  1452       apply auto
  1453       apply (rule bexI [where x = "?m"])
  1454       apply (rule exI [where x = "?xs"])
  1455       apply (rule exI [where x = "?ys"])
  1456       using ls l
  1457       apply (auto simp add: natpermute_def l_take_drop simp del: append_take_drop_id)
  1458       apply simp
  1459       done
  1460   qed
  1461 qed
  1462 
  1463 lemma natpermute_0: "natpermute n 0 = (if n = 0 then {[]} else {})"
  1464   by (auto simp add: natpermute_def)
  1465 
  1466 lemma natpermute_0'[simp]: "natpermute 0 k = (if k = 0 then {[]} else {replicate k 0})"
  1467   apply (auto simp add: set_replicate_conv_if natpermute_def)
  1468   apply (rule nth_equalityI)
  1469   apply simp_all
  1470   done
  1471 
  1472 lemma natpermute_finite: "finite (natpermute n k)"
  1473 proof (induct k arbitrary: n)
  1474   case 0
  1475   then show ?case
  1476     apply (subst natpermute_split[of 0 0, simplified])
  1477     apply (simp add: natpermute_0)
  1478     done
  1479 next
  1480   case (Suc k)
  1481   then show ?case unfolding natpermute_split [of k "Suc k", simplified]
  1482     apply -
  1483     apply (rule finite_UN_I)
  1484     apply simp
  1485     unfolding One_nat_def[symmetric] natlist_trivial_1
  1486     apply simp
  1487     done
  1488 qed
  1489 
  1490 lemma natpermute_contain_maximal:
  1491   "{xs \<in> natpermute n (k + 1). n \<in> set xs} = (\<Union>i\<in>{0 .. k}. {(replicate (k + 1) 0) [i:=n]})"
  1492   (is "?A = ?B")
  1493 proof
  1494   show "?A \<subseteq> ?B"
  1495   proof
  1496     fix xs
  1497     assume "xs \<in> ?A"
  1498     then have H: "xs \<in> natpermute n (k + 1)" and n: "n \<in> set xs"
  1499       by blast+
  1500     then obtain i where i: "i \<in> {0.. k}" "xs!i = n"
  1501       unfolding in_set_conv_nth by (auto simp add: less_Suc_eq_le natpermute_def)
  1502     have eqs: "({0..k} - {i}) \<union> {i} = {0..k}"
  1503       using i by auto
  1504     have f: "finite({0..k} - {i})" "finite {i}"
  1505       by auto
  1506     have d: "({0..k} - {i}) \<inter> {i} = {}"
  1507       using i by auto
  1508     from H have "n = setsum (nth xs) {0..k}"
  1509       apply (simp add: natpermute_def)
  1510       apply (auto simp add: atLeastLessThanSuc_atLeastAtMost listsum_setsum_nth)
  1511       done
  1512     also have "\<dots> = n + setsum (nth xs) ({0..k} - {i})"
  1513       unfolding setsum.union_disjoint[OF f d, unfolded eqs] using i by simp
  1514     finally have zxs: "\<forall> j\<in> {0..k} - {i}. xs!j = 0"
  1515       by auto
  1516     from H have xsl: "length xs = k+1"
  1517       by (simp add: natpermute_def)
  1518     from i have i': "i < length (replicate (k+1) 0)"   "i < k+1"
  1519       unfolding length_replicate by presburger+
  1520     have "xs = replicate (k+1) 0 [i := n]"
  1521       apply (rule nth_equalityI)
  1522       unfolding xsl length_list_update length_replicate
  1523       apply simp
  1524       apply clarify
  1525       unfolding nth_list_update[OF i'(1)]
  1526       using i zxs
  1527       apply (case_tac "ia = i")
  1528       apply (auto simp del: replicate.simps)
  1529       done
  1530     then show "xs \<in> ?B" using i by blast
  1531   qed
  1532   show "?B \<subseteq> ?A"
  1533   proof
  1534     fix xs
  1535     assume "xs \<in> ?B"
  1536     then obtain i where i: "i \<in> {0..k}" and xs: "xs = replicate (k + 1) 0 [i:=n]"
  1537       by auto
  1538     have nxs: "n \<in> set xs"
  1539       unfolding xs
  1540       apply (rule set_update_memI)
  1541       using i apply simp
  1542       done
  1543     have xsl: "length xs = k + 1"
  1544       by (simp only: xs length_replicate length_list_update)
  1545     have "listsum xs = setsum (nth xs) {0..<k+1}"
  1546       unfolding listsum_setsum_nth xsl ..
  1547     also have "\<dots> = setsum (\<lambda>j. if j = i then n else 0) {0..< k+1}"
  1548       by (rule setsum.cong) (simp_all add: xs del: replicate.simps)
  1549     also have "\<dots> = n" using i by (simp add: setsum.delta)
  1550     finally have "xs \<in> natpermute n (k + 1)"
  1551       using xsl unfolding natpermute_def mem_Collect_eq by blast
  1552     then show "xs \<in> ?A"
  1553       using nxs by blast
  1554   qed
  1555 qed
  1556 
  1557 text \<open>The general form.\<close>
  1558 lemma fps_setprod_nth:
  1559   fixes m :: nat
  1560     and a :: "nat \<Rightarrow> 'a::comm_ring_1 fps"
  1561   shows "(setprod a {0 .. m}) $ n =
  1562     setsum (\<lambda>v. setprod (\<lambda>j. (a j) $ (v!j)) {0..m}) (natpermute n (m+1))"
  1563   (is "?P m n")
  1564 proof (induct m arbitrary: n rule: nat_less_induct)
  1565   fix m n assume H: "\<forall>m' < m. \<forall>n. ?P m' n"
  1566   show "?P m n"
  1567   proof (cases m)
  1568     case 0
  1569     then show ?thesis
  1570       apply simp
  1571       unfolding natlist_trivial_1[where n = n, unfolded One_nat_def]
  1572       apply simp
  1573       done
  1574   next
  1575     case (Suc k)
  1576     then have km: "k < m" by arith
  1577     have u0: "{0 .. k} \<union> {m} = {0..m}"
  1578       using Suc by (simp add: set_eq_iff) presburger
  1579     have f0: "finite {0 .. k}" "finite {m}" by auto
  1580     have d0: "{0 .. k} \<inter> {m} = {}" using Suc by auto
  1581     have "(setprod a {0 .. m}) $ n = (setprod a {0 .. k} * a m) $ n"
  1582       unfolding setprod.union_disjoint[OF f0 d0, unfolded u0] by simp
  1583     also have "\<dots> = (\<Sum>i = 0..n. (\<Sum>v\<in>natpermute i (k + 1). \<Prod>j\<in>{0..k}. a j $ v ! j) * a m $ (n - i))"
  1584       unfolding fps_mult_nth H[rule_format, OF km] ..
  1585     also have "\<dots> = (\<Sum>v\<in>natpermute n (m + 1). \<Prod>j\<in>{0..m}. a j $ v ! j)"
  1586       apply (simp add: Suc)
  1587       unfolding natpermute_split[of m "m + 1", simplified, of n,
  1588         unfolded natlist_trivial_1[unfolded One_nat_def] Suc]
  1589       apply (subst setsum.UNION_disjoint)
  1590       apply simp
  1591       apply simp
  1592       unfolding image_Collect[symmetric]
  1593       apply clarsimp
  1594       apply (rule finite_imageI)
  1595       apply (rule natpermute_finite)
  1596       apply (clarsimp simp add: set_eq_iff)
  1597       apply auto
  1598       apply (rule setsum.cong)
  1599       apply (rule refl)
  1600       unfolding setsum_left_distrib
  1601       apply (rule sym)
  1602       apply (rule_tac l = "\<lambda>xs. xs @ [n - x]" in setsum.reindex_cong)
  1603       apply (simp add: inj_on_def)
  1604       apply auto
  1605       unfolding setprod.union_disjoint[OF f0 d0, unfolded u0, unfolded Suc]
  1606       apply (clarsimp simp add: natpermute_def nth_append)
  1607       done
  1608     finally show ?thesis .
  1609   qed
  1610 qed
  1611 
  1612 text \<open>The special form for powers.\<close>
  1613 lemma fps_power_nth_Suc:
  1614   fixes m :: nat
  1615     and a :: "'a::comm_ring_1 fps"
  1616   shows "(a ^ Suc m)$n = setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m}) (natpermute n (m+1))"
  1617 proof -
  1618   have th0: "a^Suc m = setprod (\<lambda>i. a) {0..m}"
  1619     by (simp add: setprod_constant)
  1620   show ?thesis unfolding th0 fps_setprod_nth ..
  1621 qed
  1622 
  1623 lemma fps_power_nth:
  1624   fixes m :: nat
  1625     and a :: "'a::comm_ring_1 fps"
  1626   shows "(a ^m)$n =
  1627     (if m=0 then 1$n else setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m - 1}) (natpermute n m))"
  1628   by (cases m) (simp_all add: fps_power_nth_Suc del: power_Suc)
  1629 
  1630 lemma fps_nth_power_0:
  1631   fixes m :: nat
  1632     and a :: "'a::comm_ring_1 fps"
  1633   shows "(a ^m)$0 = (a$0) ^ m"
  1634 proof (cases m)
  1635   case 0
  1636   then show ?thesis by simp
  1637 next
  1638   case (Suc n)
  1639   then have c: "m = card {0..n}" by simp
  1640   have "(a ^m)$0 = setprod (\<lambda>i. a$0) {0..n}"
  1641     by (simp add: Suc fps_power_nth del: replicate.simps power_Suc)
  1642   also have "\<dots> = (a$0) ^ m"
  1643    unfolding c by (rule setprod_constant) simp
  1644  finally show ?thesis .
  1645 qed
  1646 
  1647 lemma fps_compose_inj_right:
  1648   assumes a0: "a$0 = (0::'a::idom)"
  1649     and a1: "a$1 \<noteq> 0"
  1650   shows "(b oo a = c oo a) \<longleftrightarrow> b = c"
  1651   (is "?lhs \<longleftrightarrow>?rhs")
  1652 proof
  1653   show ?lhs if ?rhs using that by simp
  1654   show ?rhs if ?lhs
  1655   proof -
  1656     have "b$n = c$n" for n
  1657     proof (induct n rule: nat_less_induct)
  1658       fix n
  1659       assume H: "\<forall>m<n. b$m = c$m"
  1660       show "b$n = c$n"
  1661       proof (cases n)
  1662         case 0
  1663         from \<open>?lhs\<close> have "(b oo a)$n = (c oo a)$n"
  1664           by simp
  1665         then show ?thesis
  1666           using 0 by (simp add: fps_compose_nth)
  1667       next
  1668         case (Suc n1)
  1669         have f: "finite {0 .. n1}" "finite {n}" by simp_all
  1670         have eq: "{0 .. n1} \<union> {n} = {0 .. n}" using Suc by auto
  1671         have d: "{0 .. n1} \<inter> {n} = {}" using Suc by auto
  1672         have seq: "(\<Sum>i = 0..n1. b $ i * a ^ i $ n) = (\<Sum>i = 0..n1. c $ i * a ^ i $ n)"
  1673           apply (rule setsum.cong)
  1674           using H Suc
  1675           apply auto
  1676           done
  1677         have th0: "(b oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + b$n * (a$1)^n"
  1678           unfolding fps_compose_nth setsum.union_disjoint[OF f d, unfolded eq] seq
  1679           using startsby_zero_power_nth_same[OF a0]
  1680           by simp
  1681         have th1: "(c oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + c$n * (a$1)^n"
  1682           unfolding fps_compose_nth setsum.union_disjoint[OF f d, unfolded eq]
  1683           using startsby_zero_power_nth_same[OF a0]
  1684           by simp
  1685         from \<open>?lhs\<close>[unfolded fps_eq_iff, rule_format, of n] th0 th1 a1
  1686         show ?thesis by auto
  1687       qed
  1688     qed
  1689     then show ?rhs by (simp add: fps_eq_iff)
  1690   qed
  1691 qed
  1692 
  1693 
  1694 subsection \<open>Radicals\<close>
  1695 
  1696 declare setprod.cong [fundef_cong]
  1697 
  1698 function radical :: "(nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a::field fps \<Rightarrow> nat \<Rightarrow> 'a"
  1699 where
  1700   "radical r 0 a 0 = 1"
  1701 | "radical r 0 a (Suc n) = 0"
  1702 | "radical r (Suc k) a 0 = r (Suc k) (a$0)"
  1703 | "radical r (Suc k) a (Suc n) =
  1704     (a$ Suc n - setsum (\<lambda>xs. setprod (\<lambda>j. radical r (Suc k) a (xs ! j)) {0..k})
  1705       {xs. xs \<in> natpermute (Suc n) (Suc k) \<and> Suc n \<notin> set xs}) /
  1706     (of_nat (Suc k) * (radical r (Suc k) a 0)^k)"
  1707   by pat_completeness auto
  1708 
  1709 termination radical
  1710 proof
  1711   let ?R = "measure (\<lambda>(r, k, a, n). n)"
  1712   {
  1713     show "wf ?R" by auto
  1714   next
  1715     fix r k a n xs i
  1716     assume xs: "xs \<in> {xs \<in> natpermute (Suc n) (Suc k). Suc n \<notin> set xs}" and i: "i \<in> {0..k}"
  1717     have False if c: "Suc n \<le> xs ! i"
  1718     proof -
  1719       from xs i have "xs !i \<noteq> Suc n"
  1720         by (auto simp add: in_set_conv_nth natpermute_def)
  1721       with c have c': "Suc n < xs!i" by arith
  1722       have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}"
  1723         by simp_all
  1724       have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}"
  1725         by auto
  1726       have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})"
  1727         using i by auto
  1728       from xs have "Suc n = listsum xs"
  1729         by (simp add: natpermute_def)
  1730       also have "\<dots> = setsum (nth xs) {0..<Suc k}" using xs
  1731         by (simp add: natpermute_def listsum_setsum_nth)
  1732       also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  1733         unfolding eqs  setsum.union_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  1734         unfolding setsum.union_disjoint[OF fths(2) fths(3) d(2)]
  1735         by simp
  1736       finally show ?thesis using c' by simp
  1737     qed
  1738     then show "((r, Suc k, a, xs!i), r, Suc k, a, Suc n) \<in> ?R"
  1739       apply auto
  1740       apply (metis not_less)
  1741       done
  1742   next
  1743     fix r k a n
  1744     show "((r, Suc k, a, 0), r, Suc k, a, Suc n) \<in> ?R" by simp
  1745   }
  1746 qed
  1747 
  1748 definition "fps_radical r n a = Abs_fps (radical r n a)"
  1749 
  1750 lemma fps_radical0[simp]: "fps_radical r 0 a = 1"
  1751   apply (auto simp add: fps_eq_iff fps_radical_def)
  1752   apply (case_tac n)
  1753   apply auto
  1754   done
  1755 
  1756 lemma fps_radical_nth_0[simp]: "fps_radical r n a $ 0 = (if n = 0 then 1 else r n (a$0))"
  1757   by (cases n) (simp_all add: fps_radical_def)
  1758 
  1759 lemma fps_radical_power_nth[simp]:
  1760   assumes r: "(r k (a$0)) ^ k = a$0"
  1761   shows "fps_radical r k a ^ k $ 0 = (if k = 0 then 1 else a$0)"
  1762 proof (cases k)
  1763   case 0
  1764   then show ?thesis by simp
  1765 next
  1766   case (Suc h)
  1767   have eq1: "fps_radical r k a ^ k $ 0 = (\<Prod>j\<in>{0..h}. fps_radical r k a $ (replicate k 0) ! j)"
  1768     unfolding fps_power_nth Suc by simp
  1769   also have "\<dots> = (\<Prod>j\<in>{0..h}. r k (a$0))"
  1770     apply (rule setprod.cong)
  1771     apply simp
  1772     using Suc
  1773     apply (subgoal_tac "replicate k 0 ! x = 0")
  1774     apply (auto intro: nth_replicate simp del: replicate.simps)
  1775     done
  1776   also have "\<dots> = a$0"
  1777     using r Suc by (simp add: setprod_constant)
  1778   finally show ?thesis
  1779     using Suc by simp
  1780 qed
  1781 
  1782 lemma natpermute_max_card:
  1783   assumes n0: "n \<noteq> 0"
  1784   shows "card {xs \<in> natpermute n (k + 1). n \<in> set xs} = k + 1"
  1785   unfolding natpermute_contain_maximal
  1786 proof -
  1787   let ?A = "\<lambda>i. {replicate (k + 1) 0[i := n]}"
  1788   let ?K = "{0 ..k}"
  1789   have fK: "finite ?K"
  1790     by simp
  1791   have fAK: "\<forall>i\<in>?K. finite (?A i)"
  1792     by auto
  1793   have d: "\<forall>i\<in> ?K. \<forall>j\<in> ?K. i \<noteq> j \<longrightarrow>
  1794     {replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1795   proof clarify
  1796     fix i j
  1797     assume i: "i \<in> ?K" and j: "j \<in> ?K" and ij: "i \<noteq> j"
  1798     have False if eq: "replicate (k+1) 0 [i:=n] = replicate (k+1) 0 [j:= n]"
  1799     proof -
  1800       have "(replicate (k+1) 0 [i:=n] ! i) = n"
  1801         using i by (simp del: replicate.simps)
  1802       moreover
  1803       have "(replicate (k+1) 0 [j:=n] ! i) = 0"
  1804         using i ij by (simp del: replicate.simps)
  1805       ultimately show ?thesis
  1806         using eq n0 by (simp del: replicate.simps)
  1807     qed
  1808     then show "{replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1809       by auto
  1810   qed
  1811   from card_UN_disjoint[OF fK fAK d]
  1812   show "card (\<Union>i\<in>{0..k}. {replicate (k + 1) 0[i := n]}) = k + 1"
  1813     by simp
  1814 qed
  1815 
  1816 lemma power_radical:
  1817   fixes a:: "'a::field_char_0 fps"
  1818   assumes a0: "a$0 \<noteq> 0"
  1819   shows "(r (Suc k) (a$0)) ^ Suc k = a$0 \<longleftrightarrow> (fps_radical r (Suc k) a) ^ (Suc k) = a"
  1820     (is "?lhs \<longleftrightarrow> ?rhs")
  1821 proof
  1822   let ?r = "fps_radical r (Suc k) a"
  1823   show ?rhs if r0: ?lhs
  1824   proof -
  1825     from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1826     have "?r ^ Suc k $ z = a$z" for z
  1827     proof (induct z rule: nat_less_induct)
  1828       fix n
  1829       assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1830       show "?r ^ Suc k $ n = a $n"
  1831       proof (cases n)
  1832         case 0
  1833         then show ?thesis
  1834           using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp
  1835       next
  1836         case (Suc n1)
  1837         then have "n \<noteq> 0" by simp
  1838         let ?Pnk = "natpermute n (k + 1)"
  1839         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1840         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1841         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1842         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1843         have f: "finite ?Pnkn" "finite ?Pnknn"
  1844           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1845           by (metis natpermute_finite)+
  1846         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1847         have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1848         proof (rule setsum.cong)
  1849           fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1850           let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) =
  1851             fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1852           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1853             unfolding natpermute_contain_maximal by auto
  1854           have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) =
  1855               (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1856             apply (rule setprod.cong, simp)
  1857             using i r0
  1858             apply (simp del: replicate.simps)
  1859             done
  1860           also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1861             using i r0 by (simp add: setprod_gen_delta)
  1862           finally show ?ths .
  1863         qed rule
  1864         then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1865           by (simp add: natpermute_max_card[OF \<open>n \<noteq> 0\<close>, simplified])
  1866         also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1867           unfolding Suc using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc)
  1868         finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1869         have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1870           unfolding fps_power_nth_Suc setsum.union_disjoint[OF f d, unfolded eq] ..
  1871         also have "\<dots> = a$n" unfolding fn by simp
  1872         finally show ?thesis .
  1873       qed
  1874     qed
  1875     then show ?thesis using r0 by (simp add: fps_eq_iff)
  1876   qed
  1877   show ?lhs if ?rhs
  1878   proof -
  1879     from that have "((fps_radical r (Suc k) a) ^ (Suc k))$0 = a$0"
  1880       by simp
  1881     then show ?thesis
  1882       unfolding fps_power_nth_Suc
  1883       by (simp add: setprod_constant del: replicate.simps)
  1884   qed
  1885 qed
  1886 
  1887 (*
  1888 lemma power_radical:
  1889   fixes a:: "'a::field_char_0 fps"
  1890   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  1891   shows "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  1892 proof-
  1893   let ?r = "fps_radical r (Suc k) a"
  1894   from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1895   {fix z have "?r ^ Suc k $ z = a$z"
  1896     proof(induct z rule: nat_less_induct)
  1897       fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1898       {assume "n = 0" then have "?r ^ Suc k $ n = a $n"
  1899           using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  1900       moreover
  1901       {fix n1 assume n1: "n = Suc n1"
  1902         have fK: "finite {0..k}" by simp
  1903         have nz: "n \<noteq> 0" using n1 by arith
  1904         let ?Pnk = "natpermute n (k + 1)"
  1905         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1906         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1907         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1908         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1909         have f: "finite ?Pnkn" "finite ?Pnknn"
  1910           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1911           by (metis natpermute_finite)+
  1912         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1913         have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1914         proof(rule setsum.cong2)
  1915           fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1916           let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1917           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1918             unfolding natpermute_contain_maximal by auto
  1919           have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1920             apply (rule setprod.cong, simp)
  1921             using i r0 by (simp del: replicate.simps)
  1922           also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1923             unfolding setprod_gen_delta[OF fK] using i r0 by simp
  1924           finally show ?ths .
  1925         qed
  1926         then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1927           by (simp add: natpermute_max_card[OF nz, simplified])
  1928         also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1929           unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  1930         finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1931         have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1932           unfolding fps_power_nth_Suc setsum.union_disjoint[OF f d, unfolded eq] ..
  1933         also have "\<dots> = a$n" unfolding fn by simp
  1934         finally have "?r ^ Suc k $ n = a $n" .}
  1935       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  1936   qed }
  1937   then show ?thesis by (simp add: fps_eq_iff)
  1938 qed
  1939 
  1940 *)
  1941 lemma eq_divide_imp':
  1942   fixes c :: "'a::field"
  1943   shows "c \<noteq> 0 \<Longrightarrow> a * c = b \<Longrightarrow> a = b / c"
  1944   by (simp add: field_simps)
  1945 
  1946 lemma radical_unique:
  1947   assumes r0: "(r (Suc k) (b$0)) ^ Suc k = b$0"
  1948     and a0: "r (Suc k) (b$0 ::'a::field_char_0) = a$0"
  1949     and b0: "b$0 \<noteq> 0"
  1950   shows "a^(Suc k) = b \<longleftrightarrow> a = fps_radical r (Suc k) b"
  1951     (is "?lhs \<longleftrightarrow> ?rhs" is "_ \<longleftrightarrow> a = ?r")
  1952 proof
  1953   show ?lhs if ?rhs
  1954     using that using power_radical[OF b0, of r k, unfolded r0] by simp
  1955   show ?rhs if ?lhs
  1956   proof -
  1957     have r00: "r (Suc k) (b$0) \<noteq> 0" using b0 r0 by auto
  1958     have ceq: "card {0..k} = Suc k" by simp
  1959     from a0 have a0r0: "a$0 = ?r$0" by simp
  1960     have "a $ n = ?r $ n" for n
  1961     proof (induct n rule: nat_less_induct)
  1962       fix n
  1963       assume h: "\<forall>m<n. a$m = ?r $m"
  1964       show "a$n = ?r $ n"
  1965       proof (cases n)
  1966         case 0
  1967         then show ?thesis using a0 by simp
  1968       next
  1969         case (Suc n1)
  1970         have fK: "finite {0..k}" by simp
  1971         have nz: "n \<noteq> 0" using Suc by simp
  1972         let ?Pnk = "natpermute n (Suc k)"
  1973         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1974         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1975         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1976         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1977         have f: "finite ?Pnkn" "finite ?Pnknn"
  1978           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1979           by (metis natpermute_finite)+
  1980         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1981         let ?g = "\<lambda>v. \<Prod>j\<in>{0..k}. a $ v ! j"
  1982         have "setsum ?g ?Pnkn = setsum (\<lambda>v. a $ n * (?r$0)^k) ?Pnkn"
  1983         proof (rule setsum.cong)
  1984           fix v
  1985           assume v: "v \<in> {xs \<in> natpermute n (Suc k). n \<in> set xs}"
  1986           let ?ths = "(\<Prod>j\<in>{0..k}. a $ v ! j) = a $ n * (?r$0)^k"
  1987           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1988             unfolding Suc_eq_plus1 natpermute_contain_maximal
  1989             by (auto simp del: replicate.simps)
  1990           have "(\<Prod>j\<in>{0..k}. a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then a $ n else r (Suc k) (b$0))"
  1991             apply (rule setprod.cong, simp)
  1992             using i a0
  1993             apply (simp del: replicate.simps)
  1994             done
  1995           also have "\<dots> = a $ n * (?r $ 0)^k"
  1996             using i by (simp add: setprod_gen_delta)
  1997           finally show ?ths .
  1998         qed rule
  1999         then have th0: "setsum ?g ?Pnkn = of_nat (k+1) * a $ n * (?r $ 0)^k"
  2000           by (simp add: natpermute_max_card[OF nz, simplified])
  2001         have th1: "setsum ?g ?Pnknn = setsum ?f ?Pnknn"
  2002         proof (rule setsum.cong, rule refl, rule setprod.cong, simp)
  2003           fix xs i
  2004           assume xs: "xs \<in> ?Pnknn" and i: "i \<in> {0..k}"
  2005           have False if c: "n \<le> xs ! i"
  2006           proof -
  2007             from xs i have "xs ! i \<noteq> n"
  2008               by (auto simp add: in_set_conv_nth natpermute_def)
  2009             with c have c': "n < xs!i" by arith
  2010             have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}"
  2011               by simp_all
  2012             have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}"
  2013               by auto
  2014             have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})"
  2015               using i by auto
  2016             from xs have "n = listsum xs"
  2017               by (simp add: natpermute_def)
  2018             also have "\<dots> = setsum (nth xs) {0..<Suc k}"
  2019               using xs by (simp add: natpermute_def listsum_setsum_nth)
  2020             also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  2021               unfolding eqs  setsum.union_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  2022               unfolding setsum.union_disjoint[OF fths(2) fths(3) d(2)]
  2023               by simp
  2024             finally show ?thesis using c' by simp
  2025           qed
  2026           then have thn: "xs!i < n" by presburger
  2027           from h[rule_format, OF thn] show "a$(xs !i) = ?r$(xs!i)" .
  2028         qed
  2029         have th00: "\<And>x::'a. of_nat (Suc k) * (x * inverse (of_nat (Suc k))) = x"
  2030           by (simp add: field_simps del: of_nat_Suc)
  2031         from \<open>?lhs\<close> have "b$n = a^Suc k $ n"
  2032           by (simp add: fps_eq_iff)
  2033         also have "a ^ Suc k$n = setsum ?g ?Pnkn + setsum ?g ?Pnknn"
  2034           unfolding fps_power_nth_Suc
  2035           using setsum.union_disjoint[OF f d, unfolded Suc_eq_plus1[symmetric],
  2036             unfolded eq, of ?g] by simp
  2037         also have "\<dots> = of_nat (k+1) * a $ n * (?r $ 0)^k + setsum ?f ?Pnknn"
  2038           unfolding th0 th1 ..
  2039         finally have "of_nat (k+1) * a $ n * (?r $ 0)^k = b$n - setsum ?f ?Pnknn"
  2040           by simp
  2041         then have "a$n = (b$n - setsum ?f ?Pnknn) / (of_nat (k+1) * (?r $ 0)^k)"
  2042           apply -
  2043           apply (rule eq_divide_imp')
  2044           using r00
  2045           apply (simp del: of_nat_Suc)
  2046           apply (simp add: ac_simps)
  2047           done
  2048         then show ?thesis
  2049           apply (simp del: of_nat_Suc)
  2050           unfolding fps_radical_def Suc
  2051           apply (simp add: field_simps Suc th00 del: of_nat_Suc)
  2052           done
  2053       qed
  2054     qed
  2055     then show ?rhs by (simp add: fps_eq_iff)
  2056   qed
  2057 qed
  2058 
  2059 
  2060 lemma radical_power:
  2061   assumes r0: "r (Suc k) ((a$0) ^ Suc k) = a$0"
  2062     and a0: "(a$0 :: 'a::field_char_0) \<noteq> 0"
  2063   shows "(fps_radical r (Suc k) (a ^ Suc k)) = a"
  2064 proof -
  2065   let ?ak = "a^ Suc k"
  2066   have ak0: "?ak $ 0 = (a$0) ^ Suc k"
  2067     by (simp add: fps_nth_power_0 del: power_Suc)
  2068   from r0 have th0: "r (Suc k) (a ^ Suc k $ 0) ^ Suc k = a ^ Suc k $ 0"
  2069     using ak0 by auto
  2070   from r0 ak0 have th1: "r (Suc k) (a ^ Suc k $ 0) = a $ 0"
  2071     by auto
  2072   from ak0 a0 have ak00: "?ak $ 0 \<noteq>0 "
  2073     by auto
  2074   from radical_unique[of r k ?ak a, OF th0 th1 ak00] show ?thesis
  2075     by metis
  2076 qed
  2077 
  2078 lemma fps_deriv_radical:
  2079   fixes a :: "'a::field_char_0 fps"
  2080   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0"
  2081     and a0: "a$0 \<noteq> 0"
  2082   shows "fps_deriv (fps_radical r (Suc k) a) =
  2083     fps_deriv a / (fps_const (of_nat (Suc k)) * (fps_radical r (Suc k) a) ^ k)"
  2084 proof -
  2085   let ?r = "fps_radical r (Suc k) a"
  2086   let ?w = "(fps_const (of_nat (Suc k)) * ?r ^ k)"
  2087   from a0 r0 have r0': "r (Suc k) (a$0) \<noteq> 0"
  2088     by auto
  2089   from r0' have w0: "?w $ 0 \<noteq> 0"
  2090     by (simp del: of_nat_Suc)
  2091   note th0 = inverse_mult_eq_1[OF w0]
  2092   let ?iw = "inverse ?w"
  2093   from iffD1[OF power_radical[of a r], OF a0 r0]
  2094   have "fps_deriv (?r ^ Suc k) = fps_deriv a"
  2095     by simp
  2096   then have "fps_deriv ?r * ?w = fps_deriv a"
  2097     by (simp add: fps_deriv_power ac_simps del: power_Suc)
  2098   then have "?iw * fps_deriv ?r * ?w = ?iw * fps_deriv a"
  2099     by simp
  2100   then have "fps_deriv ?r * (?iw * ?w) = fps_deriv a / ?w"
  2101     by (simp add: fps_divide_def)
  2102   then show ?thesis unfolding th0 by simp
  2103 qed
  2104 
  2105 lemma radical_mult_distrib:
  2106   fixes a :: "'a::field_char_0 fps"
  2107   assumes k: "k > 0"
  2108     and ra0: "r k (a $ 0) ^ k = a $ 0"
  2109     and rb0: "r k (b $ 0) ^ k = b $ 0"
  2110     and a0: "a $ 0 \<noteq> 0"
  2111     and b0: "b $ 0 \<noteq> 0"
  2112   shows "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0) \<longleftrightarrow>
  2113     fps_radical r k (a * b) = fps_radical r k a * fps_radical r k b"
  2114     (is "?lhs \<longleftrightarrow> ?rhs")
  2115 proof
  2116   show ?rhs if r0': ?lhs
  2117   proof -
  2118     from r0' have r0: "(r k ((a * b) $ 0)) ^ k = (a * b) $ 0"
  2119       by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  2120     show ?thesis
  2121     proof (cases k)
  2122       case 0
  2123       then show ?thesis using r0' by simp
  2124     next
  2125       case (Suc h)
  2126       let ?ra = "fps_radical r (Suc h) a"
  2127       let ?rb = "fps_radical r (Suc h) b"
  2128       have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  2129         using r0' Suc by (simp add: fps_mult_nth)
  2130       have ab0: "(a*b) $ 0 \<noteq> 0"
  2131         using a0 b0 by (simp add: fps_mult_nth)
  2132       from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded Suc] th0 ab0, symmetric]
  2133         iffD1[OF power_radical[of _ r], OF a0 ra0[unfolded Suc]] iffD1[OF power_radical[of _ r], OF b0 rb0[unfolded Suc]] Suc r0'
  2134       show ?thesis
  2135         by (auto simp add: power_mult_distrib simp del: power_Suc)
  2136     qed
  2137   qed
  2138   show ?lhs if ?rhs
  2139   proof -
  2140     from that have "(fps_radical r k (a * b)) $ 0 = (fps_radical r k a * fps_radical r k b) $ 0"
  2141       by simp
  2142     then show ?thesis
  2143       using k by (simp add: fps_mult_nth)
  2144   qed
  2145 qed
  2146 
  2147 (*
  2148 lemma radical_mult_distrib:
  2149   fixes a:: "'a::field_char_0 fps"
  2150   assumes
  2151   ra0: "r k (a $ 0) ^ k = a $ 0"
  2152   and rb0: "r k (b $ 0) ^ k = b $ 0"
  2153   and r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  2154   and a0: "a$0 \<noteq> 0"
  2155   and b0: "b$0 \<noteq> 0"
  2156   shows "fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  2157 proof-
  2158   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  2159     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  2160   {assume "k=0" then have ?thesis by simp}
  2161   moreover
  2162   {fix h assume k: "k = Suc h"
  2163   let ?ra = "fps_radical r (Suc h) a"
  2164   let ?rb = "fps_radical r (Suc h) b"
  2165   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  2166     using r0' k by (simp add: fps_mult_nth)
  2167   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  2168   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  2169     power_radical[of r, OF ra0[unfolded k] a0] power_radical[of r, OF rb0[unfolded k] b0] k
  2170   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  2171 ultimately show ?thesis by (cases k, auto)
  2172 qed
  2173 *)
  2174 
  2175 lemma fps_divide_1[simp]: "(a :: 'a::field fps) / 1 = a"
  2176   by (simp add: fps_divide_def)
  2177 
  2178 lemma radical_divide:
  2179   fixes a :: "'a::field_char_0 fps"
  2180   assumes kp: "k > 0"
  2181     and ra0: "(r k (a $ 0)) ^ k = a $ 0"
  2182     and rb0: "(r k (b $ 0)) ^ k = b $ 0"
  2183     and a0: "a$0 \<noteq> 0"
  2184     and b0: "b$0 \<noteq> 0"
  2185   shows "r k ((a $ 0) / (b$0)) = r k (a$0) / r k (b $ 0) \<longleftrightarrow>
  2186     fps_radical r k (a/b) = fps_radical r k a / fps_radical r k b"
  2187   (is "?lhs = ?rhs")
  2188 proof
  2189   let ?r = "fps_radical r k"
  2190   from kp obtain h where k: "k = Suc h"
  2191     by (cases k) auto
  2192   have ra0': "r k (a$0) \<noteq> 0" using a0 ra0 k by auto
  2193   have rb0': "r k (b$0) \<noteq> 0" using b0 rb0 k by auto
  2194 
  2195   show ?lhs if ?rhs
  2196   proof -
  2197     from that have "?r (a/b) $ 0 = (?r a / ?r b)$0"
  2198       by simp
  2199     then show ?thesis
  2200       using k a0 b0 rb0' by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse)
  2201   qed
  2202   show ?rhs if ?lhs
  2203   proof -
  2204     from a0 b0 have ab0[simp]: "(a/b)$0 = a$0 / b$0"
  2205       by (simp add: fps_divide_def fps_mult_nth divide_inverse fps_inverse_def)
  2206     have th0: "r k ((a/b)$0) ^ k = (a/b)$0"
  2207       by (simp add: \<open>?lhs\<close> power_divide ra0 rb0)
  2208     from a0 b0 ra0' rb0' kp \<open>?lhs\<close>
  2209     have th1: "r k ((a / b) $ 0) = (fps_radical r k a / fps_radical r k b) $ 0"
  2210       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse)
  2211     from a0 b0 ra0' rb0' kp have ab0': "(a / b) $ 0 \<noteq> 0"
  2212       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def nonzero_imp_inverse_nonzero)
  2213     note tha[simp] = iffD1[OF power_radical[where r=r and k=h], OF a0 ra0[unfolded k], unfolded k[symmetric]]
  2214     note thb[simp] = iffD1[OF power_radical[where r=r and k=h], OF b0 rb0[unfolded k], unfolded k[symmetric]]
  2215     have th2: "(?r a / ?r b)^k = a/b"
  2216       by (simp add: fps_divide_def power_mult_distrib fps_inverse_power[symmetric])
  2217     from iffD1[OF radical_unique[where r=r and a="?r a / ?r b" and b="a/b" and k=h], symmetric, unfolded k[symmetric], OF th0 th1 ab0' th2]
  2218     show ?thesis .
  2219   qed
  2220 qed
  2221 
  2222 lemma radical_inverse:
  2223   fixes a :: "'a::field_char_0 fps"
  2224   assumes k: "k > 0"
  2225     and ra0: "r k (a $ 0) ^ k = a $ 0"
  2226     and r1: "(r k 1)^k = 1"
  2227     and a0: "a$0 \<noteq> 0"
  2228   shows "r k (inverse (a $ 0)) = r k 1 / (r k (a $ 0)) \<longleftrightarrow>
  2229     fps_radical r k (inverse a) = fps_radical r k 1 / fps_radical r k a"
  2230   using radical_divide[where k=k and r=r and a=1 and b=a, OF k ] ra0 r1 a0
  2231   by (simp add: divide_inverse fps_divide_def)
  2232 
  2233 
  2234 subsection \<open>Derivative of composition\<close>
  2235 
  2236 lemma fps_compose_deriv:
  2237   fixes a :: "'a::idom fps"
  2238   assumes b0: "b$0 = 0"
  2239   shows "fps_deriv (a oo b) = ((fps_deriv a) oo b) * fps_deriv b"
  2240 proof -
  2241   have "(fps_deriv (a oo b))$n = (((fps_deriv a) oo b) * (fps_deriv b)) $n" for n
  2242   proof -
  2243     have "(fps_deriv (a oo b))$n = setsum (\<lambda>i. a $ i * (fps_deriv (b^i))$n) {0.. Suc n}"
  2244       by (simp add: fps_compose_def field_simps setsum_right_distrib del: of_nat_Suc)
  2245     also have "\<dots> = setsum (\<lambda>i. a$i * ((fps_const (of_nat i)) * (fps_deriv b * (b^(i - 1))))$n) {0.. Suc n}"
  2246       by (simp add: field_simps fps_deriv_power del: fps_mult_left_const_nth of_nat_Suc)
  2247     also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (((b^(i - 1)) * fps_deriv b))$n) {0.. Suc n}"
  2248       unfolding fps_mult_left_const_nth  by (simp add: field_simps)
  2249     also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {0.. Suc n}"
  2250       unfolding fps_mult_nth ..
  2251     also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {1.. Suc n}"
  2252       apply (rule setsum.mono_neutral_right)
  2253       apply (auto simp add: mult_delta_left setsum.delta not_le)
  2254       done
  2255     also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  2256       unfolding fps_deriv_nth
  2257       by (rule setsum.reindex_cong [of Suc]) (auto simp add: mult.assoc)
  2258     finally have th0: "(fps_deriv (a oo b))$n =
  2259       setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}" .
  2260 
  2261     have "(((fps_deriv a) oo b) * (fps_deriv b))$n = setsum (\<lambda>i. (fps_deriv b)$ (n - i) * ((fps_deriv a) oo b)$i) {0..n}"
  2262       unfolding fps_mult_nth by (simp add: ac_simps)
  2263     also have "\<dots> = setsum (\<lambda>i. setsum (\<lambda>j. of_nat (n - i +1) * b$(n - i + 1) * of_nat (j + 1) * a$(j+1) * (b^j)$i) {0..n}) {0..n}"
  2264       unfolding fps_deriv_nth fps_compose_nth setsum_right_distrib mult.assoc
  2265       apply (rule setsum.cong)
  2266       apply (rule refl)
  2267       apply (rule setsum.mono_neutral_left)
  2268       apply (simp_all add: subset_eq)
  2269       apply clarify
  2270       apply (subgoal_tac "b^i$x = 0")
  2271       apply simp
  2272       apply (rule startsby_zero_power_prefix[OF b0, rule_format])
  2273       apply simp
  2274       done
  2275     also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  2276       unfolding setsum_right_distrib
  2277       apply (subst setsum.commute)
  2278       apply (rule setsum.cong, rule refl)+
  2279       apply simp
  2280       done
  2281     finally show ?thesis
  2282       unfolding th0 by simp
  2283   qed
  2284   then show ?thesis by (simp add: fps_eq_iff)
  2285 qed
  2286 
  2287 lemma fps_mult_X_plus_1_nth:
  2288   "((1+X)*a) $n = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  2289 proof (cases n)
  2290   case 0
  2291   then show ?thesis
  2292     by (simp add: fps_mult_nth)
  2293 next
  2294   case (Suc m)
  2295   have "((1 + X)*a) $ n = setsum (\<lambda>i. (1 + X) $ i * a $ (n - i)) {0..n}"
  2296     by (simp add: fps_mult_nth)
  2297   also have "\<dots> = setsum (\<lambda>i. (1+X)$i * a$(n-i)) {0.. 1}"
  2298     unfolding Suc by (rule setsum.mono_neutral_right) auto
  2299   also have "\<dots> = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  2300     by (simp add: Suc)
  2301   finally show ?thesis .
  2302 qed
  2303 
  2304 
  2305 subsection \<open>Finite FPS (i.e. polynomials) and X\<close>
  2306 
  2307 lemma fps_poly_sum_X:
  2308   assumes "\<forall>i > n. a$i = (0::'a::comm_ring_1)"
  2309   shows "a = setsum (\<lambda>i. fps_const (a$i) * X^i) {0..n}" (is "a = ?r")
  2310 proof -
  2311   have "a$i = ?r$i" for i
  2312     unfolding fps_setsum_nth fps_mult_left_const_nth X_power_nth
  2313     by (simp add: mult_delta_right setsum.delta' assms)
  2314   then show ?thesis
  2315     unfolding fps_eq_iff by blast
  2316 qed
  2317 
  2318 
  2319 subsection \<open>Compositional inverses\<close>
  2320 
  2321 fun compinv :: "'a fps \<Rightarrow> nat \<Rightarrow> 'a::field"
  2322 where
  2323   "compinv a 0 = X$0"
  2324 | "compinv a (Suc n) =
  2325     (X$ Suc n - setsum (\<lambda>i. (compinv a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  2326 
  2327 definition "fps_inv a = Abs_fps (compinv a)"
  2328 
  2329 lemma fps_inv:
  2330   assumes a0: "a$0 = 0"
  2331     and a1: "a$1 \<noteq> 0"
  2332   shows "fps_inv a oo a = X"
  2333 proof -
  2334   let ?i = "fps_inv a oo a"
  2335   have "?i $n = X$n" for n
  2336   proof (induct n rule: nat_less_induct)
  2337     fix n
  2338     assume h: "\<forall>m<n. ?i$m = X$m"
  2339     show "?i $ n = X$n"
  2340     proof (cases n)
  2341       case 0
  2342       then show ?thesis using a0
  2343         by (simp add: fps_compose_nth fps_inv_def)
  2344     next
  2345       case (Suc n1)
  2346       have "?i $ n = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + fps_inv a $ Suc n1 * (a $ 1)^ Suc n1"
  2347         by (simp only: fps_compose_nth) (simp add: Suc startsby_zero_power_nth_same [OF a0] del: power_Suc)
  2348       also have "\<dots> = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} +
  2349         (X$ Suc n1 - setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1})"
  2350         using a0 a1 Suc by (simp add: fps_inv_def)
  2351       also have "\<dots> = X$n" using Suc by simp
  2352       finally show ?thesis .
  2353     qed
  2354   qed
  2355   then show ?thesis
  2356     by (simp add: fps_eq_iff)
  2357 qed
  2358 
  2359 
  2360 fun gcompinv :: "'a fps \<Rightarrow> 'a fps \<Rightarrow> nat \<Rightarrow> 'a::field"
  2361 where
  2362   "gcompinv b a 0 = b$0"
  2363 | "gcompinv b a (Suc n) =
  2364     (b$ Suc n - setsum (\<lambda>i. (gcompinv b a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  2365 
  2366 definition "fps_ginv b a = Abs_fps (gcompinv b a)"
  2367 
  2368 lemma fps_ginv:
  2369   assumes a0: "a$0 = 0"
  2370     and a1: "a$1 \<noteq> 0"
  2371   shows "fps_ginv b a oo a = b"
  2372 proof -
  2373   let ?i = "fps_ginv b a oo a"
  2374   have "?i $n = b$n" for n
  2375   proof (induct n rule: nat_less_induct)
  2376     fix n
  2377     assume h: "\<forall>m<n. ?i$m = b$m"
  2378     show "?i $ n = b$n"
  2379     proof (cases n)
  2380       case 0
  2381       then show ?thesis using a0
  2382         by (simp add: fps_compose_nth fps_ginv_def)
  2383     next
  2384       case (Suc n1)
  2385       have "?i $ n = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + fps_ginv b a $ Suc n1 * (a $ 1)^ Suc n1"
  2386         by (simp only: fps_compose_nth) (simp add: Suc startsby_zero_power_nth_same [OF a0] del: power_Suc)
  2387       also have "\<dots> = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} +
  2388         (b$ Suc n1 - setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1})"
  2389         using a0 a1 Suc by (simp add: fps_ginv_def)
  2390       also have "\<dots> = b$n" using Suc by simp
  2391       finally show ?thesis .
  2392     qed
  2393   qed
  2394   then show ?thesis
  2395     by (simp add: fps_eq_iff)
  2396 qed
  2397 
  2398 lemma fps_inv_ginv: "fps_inv = fps_ginv X"
  2399   apply (auto simp add: fun_eq_iff fps_eq_iff fps_inv_def fps_ginv_def)
  2400   apply (induct_tac n rule: nat_less_induct)
  2401   apply auto
  2402   apply (case_tac na)
  2403   apply simp
  2404   apply simp
  2405   done
  2406 
  2407 lemma fps_compose_1[simp]: "1 oo a = 1"
  2408   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum.delta)
  2409 
  2410 lemma fps_compose_0[simp]: "0 oo a = 0"
  2411   by (simp add: fps_eq_iff fps_compose_nth)
  2412 
  2413 lemma fps_compose_0_right[simp]: "a oo 0 = fps_const (a $ 0)"
  2414   by (auto simp add: fps_eq_iff fps_compose_nth power_0_left setsum.neutral)
  2415 
  2416 lemma fps_compose_add_distrib: "(a + b) oo c = (a oo c) + (b oo c)"
  2417   by (simp add: fps_eq_iff fps_compose_nth field_simps setsum.distrib)
  2418 
  2419 lemma fps_compose_setsum_distrib: "(setsum f S) oo a = setsum (\<lambda>i. f i oo a) S"
  2420 proof (cases "finite S")
  2421   case True
  2422   show ?thesis
  2423   proof (rule finite_induct[OF True])
  2424     show "setsum f {} oo a = (\<Sum>i\<in>{}. f i oo a)"
  2425       by simp
  2426   next
  2427     fix x F
  2428     assume fF: "finite F"
  2429       and xF: "x \<notin> F"
  2430       and h: "setsum f F oo a = setsum (\<lambda>i. f i oo a) F"
  2431     show "setsum f (insert x F) oo a  = setsum (\<lambda>i. f i oo a) (insert x F)"
  2432       using fF xF h by (simp add: fps_compose_add_distrib)
  2433   qed
  2434 next
  2435   case False
  2436   then show ?thesis by simp
  2437 qed
  2438 
  2439 lemma convolution_eq:
  2440   "setsum (\<lambda>i. a (i :: nat) * b (n - i)) {0 .. n} =
  2441     setsum (\<lambda>(i,j). a i * b j) {(i,j). i \<le> n \<and> j \<le> n \<and> i + j = n}"
  2442   by (rule setsum.reindex_bij_witness[where i=fst and j="\<lambda>i. (i, n - i)"]) auto
  2443 
  2444 lemma product_composition_lemma:
  2445   assumes c0: "c$0 = (0::'a::idom)"
  2446     and d0: "d$0 = 0"
  2447   shows "((a oo c) * (b oo d))$n =
  2448     setsum (\<lambda>(k,m). a$k * b$m * (c^k * d^m) $ n) {(k,m). k + m \<le> n}"  (is "?l = ?r")
  2449 proof -
  2450   let ?S = "{(k::nat, m::nat). k + m \<le> n}"
  2451   have s: "?S \<subseteq> {0..n} <*> {0..n}" by (auto simp add: subset_eq)
  2452   have f: "finite {(k::nat, m::nat). k + m \<le> n}"
  2453     apply (rule finite_subset[OF s])
  2454     apply auto
  2455     done
  2456   have "?r =  setsum (\<lambda>i. setsum (\<lambda>(k,m). a$k * (c^k)$i * b$m * (d^m) $ (n - i)) {(k,m). k + m \<le> n}) {0..n}"
  2457     apply (simp add: fps_mult_nth setsum_right_distrib)
  2458     apply (subst setsum.commute)
  2459     apply (rule setsum.cong)
  2460     apply (auto simp add: field_simps)
  2461     done
  2462   also have "\<dots> = ?l"
  2463     apply (simp add: fps_mult_nth fps_compose_nth setsum_product)
  2464     apply (rule setsum.cong)
  2465     apply (rule refl)
  2466     apply (simp add: setsum.cartesian_product mult.assoc)
  2467     apply (rule setsum.mono_neutral_right[OF f])
  2468     apply (simp add: subset_eq)
  2469     apply presburger
  2470     apply clarsimp
  2471     apply (rule ccontr)
  2472     apply (clarsimp simp add: not_le)
  2473     apply (case_tac "x < aa")
  2474     apply simp
  2475     apply (frule_tac startsby_zero_power_prefix[rule_format, OF c0])
  2476     apply blast
  2477     apply simp
  2478     apply (frule_tac startsby_zero_power_prefix[rule_format, OF d0])
  2479     apply blast
  2480     done
  2481   finally show ?thesis by simp
  2482 qed
  2483 
  2484 lemma product_composition_lemma':
  2485   assumes c0: "c$0 = (0::'a::idom)"
  2486     and d0: "d$0 = 0"
  2487   shows "((a oo c) * (b oo d))$n =
  2488     setsum (\<lambda>k. setsum (\<lambda>m. a$k * b$m * (c^k * d^m) $ n) {0..n}) {0..n}"  (is "?l = ?r")
  2489   unfolding product_composition_lemma[OF c0 d0]
  2490   unfolding setsum.cartesian_product
  2491   apply (rule setsum.mono_neutral_left)
  2492   apply simp
  2493   apply (clarsimp simp add: subset_eq)
  2494   apply clarsimp
  2495   apply (rule ccontr)
  2496   apply (subgoal_tac "(c^aa * d^ba) $ n = 0")
  2497   apply simp
  2498   unfolding fps_mult_nth
  2499   apply (rule setsum.neutral)
  2500   apply (clarsimp simp add: not_le)
  2501   apply (case_tac "x < aa")
  2502   apply (rule startsby_zero_power_prefix[OF c0, rule_format])
  2503   apply simp
  2504   apply (subgoal_tac "n - x < ba")
  2505   apply (frule_tac k = "ba" in startsby_zero_power_prefix[OF d0, rule_format])
  2506   apply simp
  2507   apply arith
  2508   done
  2509 
  2510 
  2511 lemma setsum_pair_less_iff:
  2512   "setsum (\<lambda>((k::nat),m). a k * b m * c (k + m)) {(k,m). k + m \<le> n} =
  2513     setsum (\<lambda>s. setsum (\<lambda>i. a i * b (s - i) * c s) {0..s}) {0..n}"
  2514   (is "?l = ?r")
  2515 proof -
  2516   let ?KM = "{(k,m). k + m \<le> n}"
  2517   let ?f = "\<lambda>s. UNION {(0::nat)..s} (\<lambda>i. {(i,s - i)})"
  2518   have th0: "?KM = UNION {0..n} ?f"
  2519     by (auto simp add: set_eq_iff Bex_def)
  2520   show "?l = ?r "
  2521     unfolding th0
  2522     apply (subst setsum.UNION_disjoint)
  2523     apply auto
  2524     apply (subst setsum.UNION_disjoint)
  2525     apply auto
  2526     done
  2527 qed
  2528 
  2529 lemma fps_compose_mult_distrib_lemma:
  2530   assumes c0: "c$0 = (0::'a::idom)"
  2531   shows "((a oo c) * (b oo c))$n = setsum (\<lambda>s. setsum (\<lambda>i. a$i * b$(s - i) * (c^s) $ n) {0..s}) {0..n}"
  2532   unfolding product_composition_lemma[OF c0 c0] power_add[symmetric]
  2533   unfolding setsum_pair_less_iff[where a = "\<lambda>k. a$k" and b="\<lambda>m. b$m" and c="\<lambda>s. (c ^ s)$n" and n = n] ..
  2534 
  2535 lemma fps_compose_mult_distrib:
  2536   assumes c0: "c $ 0 = (0::'a::idom)"
  2537   shows "(a * b) oo c = (a oo c) * (b oo c)"
  2538   apply (simp add: fps_eq_iff fps_compose_mult_distrib_lemma [OF c0])
  2539   apply (simp add: fps_compose_nth fps_mult_nth setsum_left_distrib)
  2540   done
  2541 
  2542 lemma fps_compose_setprod_distrib:
  2543   assumes c0: "c$0 = (0::'a::idom)"
  2544   shows "setprod a S oo c = setprod (\<lambda>k. a k oo c) S"
  2545   apply (cases "finite S")
  2546   apply simp_all
  2547   apply (induct S rule: finite_induct)
  2548   apply simp
  2549   apply (simp add: fps_compose_mult_distrib[OF c0])
  2550   done
  2551 
  2552 lemma fps_compose_power:
  2553   assumes c0: "c$0 = (0::'a::idom)"
  2554   shows "(a oo c)^n = a^n oo c"
  2555 proof (cases n)
  2556   case 0
  2557   then show ?thesis by simp
  2558 next
  2559   case (Suc m)
  2560   have th0: "a^n = setprod (\<lambda>k. a) {0..m}" "(a oo c) ^ n = setprod (\<lambda>k. a oo c) {0..m}"
  2561     by (simp_all add: setprod_constant Suc)
  2562   then show ?thesis
  2563     by (simp add: fps_compose_setprod_distrib[OF c0])
  2564 qed
  2565 
  2566 lemma fps_compose_uminus: "- (a::'a::ring_1 fps) oo c = - (a oo c)"
  2567   by (simp add: fps_eq_iff fps_compose_nth field_simps setsum_negf[symmetric])
  2568 
  2569 lemma fps_compose_sub_distrib: "(a - b) oo (c::'a::ring_1 fps) = (a oo c) - (b oo c)"
  2570   using fps_compose_add_distrib [of a "- b" c] by (simp add: fps_compose_uminus)
  2571 
  2572 lemma X_fps_compose: "X oo a = Abs_fps (\<lambda>n. if n = 0 then (0::'a::comm_ring_1) else a$n)"
  2573   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum.delta)
  2574 
  2575 lemma fps_inverse_compose:
  2576   assumes b0: "(b$0 :: 'a::field) = 0"
  2577     and a0: "a$0 \<noteq> 0"
  2578   shows "inverse a oo b = inverse (a oo b)"
  2579 proof -
  2580   let ?ia = "inverse a"
  2581   let ?ab = "a oo b"
  2582   let ?iab = "inverse ?ab"
  2583 
  2584   from a0 have ia0: "?ia $ 0 \<noteq> 0" by simp
  2585   from a0 have ab0: "?ab $ 0 \<noteq> 0" by (simp add: fps_compose_def)
  2586   have "(?ia oo b) *  (a oo b) = 1"
  2587     unfolding fps_compose_mult_distrib[OF b0, symmetric]
  2588     unfolding inverse_mult_eq_1[OF a0]
  2589     fps_compose_1 ..
  2590 
  2591   then have "(?ia oo b) *  (a oo b) * ?iab  = 1 * ?iab" by simp
  2592   then have "(?ia oo b) *  (?iab * (a oo b))  = ?iab" by simp
  2593   then show ?thesis unfolding inverse_mult_eq_1[OF ab0] by simp
  2594 qed
  2595 
  2596 lemma fps_divide_compose:
  2597   assumes c0: "(c$0 :: 'a::field) = 0"
  2598     and b0: "b$0 \<noteq> 0"
  2599   shows "(a/b) oo c = (a oo c) / (b oo c)"
  2600     unfolding fps_divide_def fps_compose_mult_distrib[OF c0]
  2601     fps_inverse_compose[OF c0 b0] ..
  2602 
  2603 lemma gp:
  2604   assumes a0: "a$0 = (0::'a::field)"
  2605   shows "(Abs_fps (\<lambda>n. 1)) oo a = 1/(1 - a)"
  2606     (is "?one oo a = _")
  2607 proof -
  2608   have o0: "?one $ 0 \<noteq> 0" by simp
  2609   have th0: "(1 - X) $ 0 \<noteq> (0::'a)" by simp
  2610   from fps_inverse_gp[where ?'a = 'a]
  2611   have "inverse ?one = 1 - X" by (simp add: fps_eq_iff)
  2612   then have "inverse (inverse ?one) = inverse (1 - X)" by simp
  2613   then have th: "?one = 1/(1 - X)" unfolding fps_inverse_idempotent[OF o0]
  2614     by (simp add: fps_divide_def)
  2615   show ?thesis
  2616     unfolding th
  2617     unfolding fps_divide_compose[OF a0 th0]
  2618     fps_compose_1 fps_compose_sub_distrib X_fps_compose_startby0[OF a0] ..
  2619 qed
  2620 
  2621 lemma fps_const_power [simp]: "fps_const (c::'a::ring_1) ^ n = fps_const (c^n)"
  2622   by (induct n) auto
  2623 
  2624 lemma fps_compose_radical:
  2625   assumes b0: "b$0 = (0::'a::field_char_0)"
  2626     and ra0: "r (Suc k) (a$0) ^ Suc k = a$0"
  2627     and a0: "a$0 \<noteq> 0"
  2628   shows "fps_radical r (Suc k)  a oo b = fps_radical r (Suc k) (a oo b)"
  2629 proof -
  2630   let ?r = "fps_radical r (Suc k)"
  2631   let ?ab = "a oo b"
  2632   have ab0: "?ab $ 0 = a$0"
  2633     by (simp add: fps_compose_def)
  2634   from ab0 a0 ra0 have rab0: "?ab $ 0 \<noteq> 0" "r (Suc k) (?ab $ 0) ^ Suc k = ?ab $ 0"
  2635     by simp_all
  2636   have th00: "r (Suc k) ((a oo b) $ 0) = (fps_radical r (Suc k) a oo b) $ 0"
  2637     by (simp add: ab0 fps_compose_def)
  2638   have th0: "(?r a oo b) ^ (Suc k) = a  oo b"
  2639     unfolding fps_compose_power[OF b0]
  2640     unfolding iffD1[OF power_radical[of a r k], OF a0 ra0]  ..
  2641   from iffD1[OF radical_unique[where r=r and k=k and b= ?ab and a = "?r a oo b", OF rab0(2) th00 rab0(1)], OF th0]
  2642   show ?thesis  .
  2643 qed
  2644 
  2645 lemma fps_const_mult_apply_left: "fps_const c * (a oo b) = (fps_const c * a) oo b"
  2646   by (simp add: fps_eq_iff fps_compose_nth setsum_right_distrib mult.assoc)
  2647 
  2648 lemma fps_const_mult_apply_right:
  2649   "(a oo b) * fps_const (c::'a::comm_semiring_1) = (fps_const c * a) oo b"
  2650   by (auto simp add: fps_const_mult_apply_left mult.commute)
  2651 
  2652 lemma fps_compose_assoc:
  2653   assumes c0: "c$0 = (0::'a::idom)"
  2654     and b0: "b$0 = 0"
  2655   shows "a oo (b oo c) = a oo b oo c" (is "?l = ?r")
  2656 proof -
  2657   have "?l$n = ?r$n" for n
  2658   proof -
  2659     have "?l$n = (setsum (\<lambda>i. (fps_const (a$i) * b^i) oo c) {0..n})$n"
  2660       by (simp add: fps_compose_nth fps_compose_power[OF c0] fps_const_mult_apply_left
  2661         setsum_right_distrib mult.assoc fps_setsum_nth)
  2662     also have "\<dots> = ((setsum (\<lambda>i. fps_const (a$i) * b^i) {0..n}) oo c)$n"
  2663       by (simp add: fps_compose_setsum_distrib)
  2664     also have "\<dots> = ?r$n"
  2665       apply (simp add: fps_compose_nth fps_setsum_nth setsum_left_distrib mult.assoc)
  2666       apply (rule setsum.cong)
  2667       apply (rule refl)
  2668       apply (rule setsum.mono_neutral_right)
  2669       apply (auto simp add: not_le)
  2670       apply (erule startsby_zero_power_prefix[OF b0, rule_format])
  2671       done
  2672     finally show ?thesis .
  2673   qed
  2674   then show ?thesis
  2675     by (simp add: fps_eq_iff)
  2676 qed
  2677 
  2678 
  2679 lemma fps_X_power_compose:
  2680   assumes a0: "a$0=0"
  2681   shows "X^k oo a = (a::'a::idom fps)^k"
  2682   (is "?l = ?r")
  2683 proof (cases k)
  2684   case 0
  2685   then show ?thesis by simp
  2686 next
  2687   case (Suc h)
  2688   have "?l $ n = ?r $n" for n
  2689   proof -
  2690     consider "k > n" | "k \<le> n" by arith
  2691     then show ?thesis
  2692     proof cases
  2693       case 1
  2694       then show ?thesis
  2695         using a0 startsby_zero_power_prefix[OF a0] Suc
  2696         by (simp add: fps_compose_nth del: power_Suc)
  2697     next
  2698       case 2
  2699       then show ?thesis
  2700         by (simp add: fps_compose_nth mult_delta_left setsum.delta)
  2701     qed
  2702   qed
  2703   then show ?thesis
  2704     unfolding fps_eq_iff by blast
  2705 qed
  2706 
  2707 lemma fps_inv_right:
  2708   assumes a0: "a$0 = 0"
  2709     and a1: "a$1 \<noteq> 0"
  2710   shows "a oo fps_inv a = X"
  2711 proof -
  2712   let ?ia = "fps_inv a"
  2713   let ?iaa = "a oo fps_inv a"
  2714   have th0: "?ia $ 0 = 0"
  2715     by (simp add: fps_inv_def)
  2716   have th1: "?iaa $ 0 = 0"
  2717     using a0 a1 by (simp add: fps_inv_def fps_compose_nth)
  2718   have th2: "X$0 = 0"
  2719     by simp
  2720   from fps_inv[OF a0 a1] have "a oo (fps_inv a oo a) = a oo X"
  2721     by simp
  2722   then have "(a oo fps_inv a) oo a = X oo a"
  2723     by (simp add: fps_compose_assoc[OF a0 th0] X_fps_compose_startby0[OF a0])
  2724   with fps_compose_inj_right[OF a0 a1] show ?thesis
  2725     by simp
  2726 qed
  2727 
  2728 lemma fps_inv_deriv:
  2729   assumes a0: "a$0 = (0::'a::field)"
  2730     and a1: "a$1 \<noteq> 0"
  2731   shows "fps_deriv (fps_inv a) = inverse (fps_deriv a oo fps_inv a)"
  2732 proof -
  2733   let ?ia = "fps_inv a"
  2734   let ?d = "fps_deriv a oo ?ia"
  2735   let ?dia = "fps_deriv ?ia"
  2736   have ia0: "?ia$0 = 0"
  2737     by (simp add: fps_inv_def)
  2738   have th0: "?d$0 \<noteq> 0"
  2739     using a1 by (simp add: fps_compose_nth)
  2740   from fps_inv_right[OF a0 a1] have "?d * ?dia = 1"
  2741     by (simp add: fps_compose_deriv[OF ia0, of a, symmetric] )
  2742   then have "inverse ?d * ?d * ?dia = inverse ?d * 1"
  2743     by simp
  2744   with inverse_mult_eq_1 [OF th0] show "?dia = inverse ?d"
  2745     by simp
  2746 qed
  2747 
  2748 lemma fps_inv_idempotent:
  2749   assumes a0: "a$0 = 0"
  2750     and a1: "a$1 \<noteq> 0"
  2751   shows "fps_inv (fps_inv a) = a"
  2752 proof -
  2753   let ?r = "fps_inv"
  2754   have ra0: "?r a $ 0 = 0"
  2755     by (simp add: fps_inv_def)
  2756   from a1 have ra1: "?r a $ 1 \<noteq> 0"
  2757     by (simp add: fps_inv_def field_simps)
  2758   have X0: "X$0 = 0"
  2759     by simp
  2760   from fps_inv[OF ra0 ra1] have "?r (?r a) oo ?r a = X" .
  2761   then have "?r (?r a) oo ?r a oo a = X oo a"
  2762     by simp
  2763   then have "?r (?r a) oo (?r a oo a) = a"
  2764     unfolding X_fps_compose_startby0[OF a0]
  2765     unfolding fps_compose_assoc[OF a0 ra0, symmetric] .
  2766   then show ?thesis
  2767     unfolding fps_inv[OF a0 a1] by simp
  2768 qed
  2769 
  2770 lemma fps_ginv_ginv:
  2771   assumes a0: "a$0 = 0"
  2772     and a1: "a$1 \<noteq> 0"
  2773     and c0: "c$0 = 0"
  2774     and  c1: "c$1 \<noteq> 0"
  2775   shows "fps_ginv b (fps_ginv c a) = b oo a oo fps_inv c"
  2776 proof -
  2777   let ?r = "fps_ginv"
  2778   from c0 have rca0: "?r c a $0 = 0"
  2779     by (simp add: fps_ginv_def)
  2780   from a1 c1 have rca1: "?r c a $ 1 \<noteq> 0"
  2781     by (simp add: fps_ginv_def field_simps)
  2782   from fps_ginv[OF rca0 rca1]
  2783   have "?r b (?r c a) oo ?r c a = b" .
  2784   then have "?r b (?r c a) oo ?r c a oo a = b oo a"
  2785     by simp
  2786   then have "?r b (?r c a) oo (?r c a oo a) = b oo a"
  2787     apply (subst fps_compose_assoc)
  2788     using a0 c0
  2789     apply (auto simp add: fps_ginv_def)
  2790     done
  2791   then have "?r b (?r c a) oo c = b oo a"
  2792     unfolding fps_ginv[OF a0 a1] .
  2793   then have "?r b (?r c a) oo c oo fps_inv c= b oo a oo fps_inv c"
  2794     by simp
  2795   then have "?r b (?r c a) oo (c oo fps_inv c) = b oo a oo fps_inv c"
  2796     apply (subst fps_compose_assoc)
  2797     using a0 c0
  2798     apply (auto simp add: fps_inv_def)
  2799     done
  2800   then show ?thesis
  2801     unfolding fps_inv_right[OF c0 c1] by simp
  2802 qed
  2803 
  2804 lemma fps_ginv_deriv:
  2805   assumes a0:"a$0 = (0::'a::field)"
  2806     and a1: "a$1 \<noteq> 0"
  2807   shows "fps_deriv (fps_ginv b a) = (fps_deriv b / fps_deriv a) oo fps_ginv X a"
  2808 proof -
  2809   let ?ia = "fps_ginv b a"
  2810   let ?iXa = "fps_ginv X a"
  2811   let ?d = "fps_deriv"
  2812   let ?dia = "?d ?ia"
  2813   have iXa0: "?iXa $ 0 = 0"
  2814     by (simp add: fps_ginv_def)
  2815   have da0: "?d a $ 0 \<noteq> 0"
  2816     using a1 by simp
  2817   from fps_ginv[OF a0 a1, of b] have "?d (?ia oo a) = fps_deriv b"
  2818     by simp
  2819   then have "(?d ?ia oo a) * ?d a = ?d b"
  2820     unfolding fps_compose_deriv[OF a0] .
  2821   then have "(?d ?ia oo a) * ?d a * inverse (?d a) = ?d b * inverse (?d a)"
  2822     by simp
  2823   then have "(?d ?ia oo a) * (inverse (?d a) * ?d a) = ?d b / ?d a"
  2824     by (simp add: fps_divide_def)
  2825   then have "(?d ?ia oo a) oo ?iXa =  (?d b / ?d a) oo ?iXa"
  2826     unfolding inverse_mult_eq_1[OF da0] by simp
  2827   then have "?d ?ia oo (a oo ?iXa) =  (?d b / ?d a) oo ?iXa"
  2828     unfolding fps_compose_assoc[OF iXa0 a0] .
  2829   then show ?thesis unfolding fps_inv_ginv[symmetric]
  2830     unfolding fps_inv_right[OF a0 a1] by simp
  2831 qed
  2832 
  2833 
  2834 subsection \<open>Elementary series\<close>
  2835 
  2836 subsubsection \<open>Exponential series\<close>
  2837 
  2838 definition "E x = Abs_fps (\<lambda>n. x^n / of_nat (fact n))"
  2839 
  2840 lemma E_deriv[simp]: "fps_deriv (E a) = fps_const (a::'a::field_char_0) * E a" (is "?l = ?r")
  2841 proof -
  2842   have "?l$n = ?r $ n" for n
  2843     apply (auto simp add: E_def field_simps power_Suc[symmetric]
  2844       simp del: fact.simps of_nat_Suc power_Suc)
  2845     apply (simp add: of_nat_mult field_simps)
  2846     done
  2847   then show ?thesis
  2848     by (simp add: fps_eq_iff)
  2849 qed
  2850 
  2851 lemma E_unique_ODE:
  2852   "fps_deriv a = fps_const c * a \<longleftrightarrow> a = fps_const (a$0) * E (c::'a::field_char_0)"
  2853   (is "?lhs \<longleftrightarrow> ?rhs")
  2854 proof
  2855   show ?rhs if ?lhs
  2856   proof -
  2857     from that have th: "\<And>n. a $ Suc n = c * a$n / of_nat (Suc n)"
  2858       by (simp add: fps_deriv_def fps_eq_iff field_simps del: of_nat_Suc)
  2859     have th': "a$n = a$0 * c ^ n/ (fact n)" for n
  2860     proof (induct n)
  2861       case 0
  2862       then show ?case by simp
  2863     next
  2864       case Suc
  2865       then show ?case
  2866         unfolding th
  2867         using fact_gt_zero
  2868         apply (simp add: field_simps del: of_nat_Suc fact_Suc)
  2869         apply simp
  2870         done
  2871     qed
  2872     show ?thesis
  2873       by (auto simp add: fps_eq_iff fps_const_mult_left E_def intro: th')
  2874   qed
  2875   show ?lhs if ?rhs
  2876     using that by (metis E_deriv fps_deriv_mult_const_left mult.left_commute)
  2877 qed
  2878 
  2879 lemma E_add_mult: "E (a + b) = E (a::'a::field_char_0) * E b" (is "?l = ?r")
  2880 proof -
  2881   have "fps_deriv ?r = fps_const (a + b) * ?r"
  2882     by (simp add: fps_const_add[symmetric] field_simps del: fps_const_add)
  2883   then have "?r = ?l"
  2884     by (simp only: E_unique_ODE) (simp add: fps_mult_nth E_def)
  2885   then show ?thesis ..
  2886 qed
  2887 
  2888 lemma E_nth[simp]: "E a $ n = a^n / of_nat (fact n)"
  2889   by (simp add: E_def)
  2890 
  2891 lemma E0[simp]: "E (0::'a::field) = 1"
  2892   by (simp add: fps_eq_iff power_0_left)
  2893 
  2894 lemma E_neg: "E (- a) = inverse (E (a::'a::field_char_0))"
  2895 proof -
  2896   from E_add_mult[of a "- a"] have th0: "E a * E (- a) = 1"
  2897     by (simp )
  2898   have th1: "E a $ 0 \<noteq> 0" by simp
  2899   from fps_inverse_unique[OF th1 th0] show ?thesis by simp
  2900 qed
  2901 
  2902 lemma E_nth_deriv[simp]: "fps_nth_deriv n (E (a::'a::field_char_0)) = (fps_const a)^n * (E a)"
  2903   by (induct n) auto
  2904 
  2905 lemma X_compose_E[simp]: "X oo E (a::'a::field) = E a - 1"
  2906   by (simp add: fps_eq_iff X_fps_compose)
  2907 
  2908 lemma LE_compose:
  2909   assumes a: "a \<noteq> 0"
  2910   shows "fps_inv (E a - 1) oo (E a - 1) = X"
  2911     and "(E a - 1) oo fps_inv (E a - 1) = X"
  2912 proof -
  2913   let ?b = "E a - 1"
  2914   have b0: "?b $ 0 = 0"
  2915     by simp
  2916   have b1: "?b $ 1 \<noteq> 0"
  2917     by (simp add: a)
  2918   from fps_inv[OF b0 b1] show "fps_inv (E a - 1) oo (E a - 1) = X" .
  2919   from fps_inv_right[OF b0 b1] show "(E a - 1) oo fps_inv (E a - 1) = X" .
  2920 qed
  2921 
  2922 lemma fps_const_inverse: "a \<noteq> 0 \<Longrightarrow> inverse (fps_const (a::'a::field)) = fps_const (inverse a)"
  2923   apply (auto simp add: fps_eq_iff fps_inverse_def)
  2924   apply (case_tac n)
  2925   apply auto
  2926   done
  2927 
  2928 lemma E_power_mult: "(E (c::'a::field_char_0))^n = E (of_nat n * c)"
  2929   by (induct n) (auto simp add: field_simps E_add_mult)
  2930 
  2931 lemma radical_E:
  2932   assumes r: "r (Suc k) 1 = 1"
  2933   shows "fps_radical r (Suc k) (E (c::'a::field_char_0)) = E (c / of_nat (Suc k))"
  2934 proof -
  2935   let ?ck = "(c / of_nat (Suc k))"
  2936   let ?r = "fps_radical r (Suc k)"
  2937   have eq0[simp]: "?ck * of_nat (Suc k) = c" "of_nat (Suc k) * ?ck = c"
  2938     by (simp_all del: of_nat_Suc)
  2939   have th0: "E ?ck ^ (Suc k) = E c" unfolding E_power_mult eq0 ..
  2940   have th: "r (Suc k) (E c $0) ^ Suc k = E c $ 0"
  2941     "r (Suc k) (E c $ 0) = E ?ck $ 0" "E c $ 0 \<noteq> 0" using r by simp_all
  2942   from th0 radical_unique[where r=r and k=k, OF th] show ?thesis
  2943     by auto
  2944 qed
  2945 
  2946 lemma Ec_E1_eq: "E (1::'a::field_char_0) oo (fps_const c * X) = E c"
  2947   apply (auto simp add: fps_eq_iff E_def fps_compose_def power_mult_distrib)
  2948   apply (simp add: cond_value_iff cond_application_beta setsum.delta' cong del: if_weak_cong)
  2949   done
  2950 
  2951 
  2952 subsubsection \<open>Logarithmic series\<close>
  2953 
  2954 lemma Abs_fps_if_0:
  2955   "Abs_fps (\<lambda>n. if n = 0 then (v::'a::ring_1) else f n) =
  2956     fps_const v + X * Abs_fps (\<lambda>n. f (Suc n))"
  2957   by (auto simp add: fps_eq_iff)
  2958 
  2959 definition L :: "'a::field_char_0 \<Rightarrow> 'a fps"
  2960   where "L c = fps_const (1/c) * Abs_fps (\<lambda>n. if n = 0 then 0 else (- 1) ^ (n - 1) / of_nat n)"
  2961 
  2962 lemma fps_deriv_L: "fps_deriv (L c) = fps_const (1/c) * inverse (1 + X)"
  2963   unfolding fps_inverse_X_plus1
  2964   by (simp add: L_def fps_eq_iff del: of_nat_Suc)
  2965 
  2966 lemma L_nth: "L c $ n = (if n = 0 then 0 else 1/c * ((- 1) ^ (n - 1) / of_nat n))"
  2967   by (simp add: L_def field_simps)
  2968 
  2969 lemma L_0[simp]: "L c $ 0 = 0" by (simp add: L_def)
  2970 
  2971 lemma L_E_inv:
  2972   fixes a :: "'a::field_char_0"
  2973   assumes a: "a \<noteq> 0"
  2974   shows "L a = fps_inv (E a - 1)"  (is "?l = ?r")
  2975 proof -
  2976   let ?b = "E a - 1"
  2977   have b0: "?b $ 0 = 0" by simp
  2978   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  2979   have "fps_deriv (E a - 1) oo fps_inv (E a - 1) =
  2980     (fps_const a * (E a - 1) + fps_const a) oo fps_inv (E a - 1)"
  2981     by (simp add: field_simps)
  2982   also have "\<dots> = fps_const a * (X + 1)"
  2983     apply (simp add: fps_compose_add_distrib fps_const_mult_apply_left[symmetric] fps_inv_right[OF b0 b1])
  2984     apply (simp add: field_simps)
  2985     done
  2986   finally have eq: "fps_deriv (E a - 1) oo fps_inv (E a - 1) = fps_const a * (X + 1)" .
  2987   from fps_inv_deriv[OF b0 b1, unfolded eq]
  2988   have "fps_deriv (fps_inv ?b) = fps_const (inverse a) / (X + 1)"
  2989     using a
  2990     by (simp add: fps_const_inverse eq fps_divide_def fps_inverse_mult)
  2991   then have "fps_deriv ?l = fps_deriv ?r"
  2992     by (simp add: fps_deriv_L add.commute fps_divide_def divide_inverse)
  2993   then show ?thesis unfolding fps_deriv_eq_iff
  2994     by (simp add: L_nth fps_inv_def)
  2995 qed
  2996 
  2997 lemma L_mult_add:
  2998   assumes c0: "c\<noteq>0"
  2999     and d0: "d\<noteq>0"
  3000   shows "L c + L d = fps_const (c+d) * L (c*d)"
  3001   (is "?r = ?l")
  3002 proof-
  3003   from c0 d0 have eq: "1/c + 1/d = (c+d)/(c*d)" by (simp add: field_simps)
  3004   have "fps_deriv ?r = fps_const (1/c + 1/d) * inverse (1 + X)"
  3005     by (simp add: fps_deriv_L fps_const_add[symmetric] algebra_simps del: fps_const_add)
  3006   also have "\<dots> = fps_deriv ?l"
  3007     apply (simp add: fps_deriv_L)
  3008     apply (simp add: fps_eq_iff eq)
  3009     done
  3010   finally show ?thesis
  3011     unfolding fps_deriv_eq_iff by simp
  3012 qed
  3013 
  3014 
  3015 subsubsection \<open>Binomial series\<close>
  3016 
  3017 definition "fps_binomial a = Abs_fps (\<lambda>n. a gchoose n)"
  3018 
  3019 lemma fps_binomial_nth[simp]: "fps_binomial a $ n = a gchoose n"
  3020   by (simp add: fps_binomial_def)
  3021 
  3022 lemma fps_binomial_ODE_unique:
  3023   fixes c :: "'a::field_char_0"
  3024   shows "fps_deriv a = (fps_const c * a) / (1 + X) \<longleftrightarrow> a = fps_const (a$0) * fps_binomial c"
  3025   (is "?lhs \<longleftrightarrow> ?rhs")
  3026 proof
  3027   let ?da = "fps_deriv a"
  3028   let ?x1 = "(1 + X):: 'a fps"
  3029   let ?l = "?x1 * ?da"
  3030   let ?r = "fps_const c * a"
  3031 
  3032   have eq: "?l = ?r \<longleftrightarrow> ?lhs"
  3033   proof -
  3034     have x10: "?x1 $ 0 \<noteq> 0" by simp
  3035     have "?l = ?r \<longleftrightarrow> inverse ?x1 * ?l = inverse ?x1 * ?r" by simp
  3036     also have "\<dots> \<longleftrightarrow> ?da = (fps_const c * a) / ?x1"
  3037       apply (simp only: fps_divide_def  mult.assoc[symmetric] inverse_mult_eq_1[OF x10])
  3038       apply (simp add: field_simps)
  3039       done
  3040     finally show ?thesis .
  3041   qed
  3042 
  3043   show ?rhs if ?lhs
  3044   proof -
  3045     from eq that have h: "?l = ?r" ..
  3046     have th0: "a$ Suc n = ((c - of_nat n) / of_nat (Suc n)) * a $n" for n
  3047     proof -
  3048       from h have "?l $ n = ?r $ n" by simp
  3049       then show ?thesis
  3050         apply (simp add: field_simps del: of_nat_Suc)
  3051         apply (cases n)
  3052         apply (simp_all add: field_simps del: of_nat_Suc)
  3053         done
  3054     qed
  3055     have th1: "a $ n = (c gchoose n) * a $ 0" for n
  3056     proof (induct n)
  3057       case 0
  3058       then show ?case by simp
  3059     next
  3060       case (Suc m)
  3061       then show ?case
  3062         unfolding th0
  3063         apply (simp add: field_simps del: of_nat_Suc)
  3064         unfolding mult.assoc[symmetric] gbinomial_mult_1
  3065         apply (simp add: field_simps)
  3066         done
  3067     qed
  3068     show ?thesis
  3069       apply (simp add: fps_eq_iff)
  3070       apply (subst th1)
  3071       apply (simp add: field_simps)
  3072       done
  3073   qed
  3074 
  3075   show ?lhs if ?rhs
  3076   proof -
  3077     have th00: "x * (a $ 0 * y) = a $ 0 * (x * y)" for x y
  3078       by (simp add: mult.commute)
  3079     have "?l = ?r"
  3080       apply (subst \<open>?rhs\<close>)
  3081       apply (subst (2) \<open>?rhs\<close>)
  3082       apply (clarsimp simp add: fps_eq_iff field_simps)
  3083       unfolding mult.assoc[symmetric] th00 gbinomial_mult_1
  3084       apply (simp add: field_simps gbinomial_mult_1)
  3085       done
  3086     with eq show ?thesis ..
  3087   qed
  3088 qed
  3089 
  3090 lemma fps_binomial_deriv: "fps_deriv (fps_binomial c) = fps_const c * fps_binomial c / (1 + X)"
  3091 proof -
  3092   let ?a = "fps_binomial c"
  3093   have th0: "?a = fps_const (?a$0) * ?a" by (simp)
  3094   from iffD2[OF fps_binomial_ODE_unique, OF th0] show ?thesis .
  3095 qed
  3096 
  3097 lemma fps_binomial_add_mult: "fps_binomial (c+d) = fps_binomial c * fps_binomial d" (is "?l = ?r")
  3098 proof -
  3099   let ?P = "?r - ?l"
  3100   let ?b = "fps_binomial"
  3101   let ?db = "\<lambda>x. fps_deriv (?b x)"
  3102   have "fps_deriv ?P = ?db c * ?b d + ?b c * ?db d - ?db (c + d)"  by simp
  3103   also have "\<dots> = inverse (1 + X) *
  3104       (fps_const c * ?b c * ?b d + fps_const d * ?b c * ?b d - fps_const (c+d) * ?b (c + d))"
  3105     unfolding fps_binomial_deriv
  3106     by (simp add: fps_divide_def field_simps)
  3107   also have "\<dots> = (fps_const (c + d)/ (1 + X)) * ?P"
  3108     by (simp add: field_simps fps_divide_def fps_const_add[symmetric] del: fps_const_add)
  3109   finally have th0: "fps_deriv ?P = fps_const (c+d) * ?P / (1 + X)"
  3110     by (simp add: fps_divide_def)
  3111   have "?P = fps_const (?P$0) * ?b (c + d)"
  3112     unfolding fps_binomial_ODE_unique[symmetric]
  3113     using th0 by simp
  3114   then have "?P = 0" by (simp add: fps_mult_nth)
  3115   then show ?thesis by simp
  3116 qed
  3117 
  3118 lemma fps_minomial_minus_one: "fps_binomial (- 1) = inverse (1 + X)"
  3119   (is "?l = inverse ?r")
  3120 proof-
  3121   have th: "?r$0 \<noteq> 0" by simp
  3122   have th': "fps_deriv (inverse ?r) = fps_const (- 1) * inverse ?r / (1 + X)"
  3123     by (simp add: fps_inverse_deriv[OF th] fps_divide_def
  3124       power2_eq_square mult.commute fps_const_neg[symmetric] del: fps_const_neg)
  3125   have eq: "inverse ?r $ 0 = 1"
  3126     by (simp add: fps_inverse_def)
  3127   from iffD1[OF fps_binomial_ODE_unique[of "inverse (1 + X)" "- 1"] th'] eq
  3128   show ?thesis by (simp add: fps_inverse_def)
  3129 qed
  3130 
  3131 text \<open>Vandermonde's Identity as a consequence.\<close>
  3132 lemma gbinomial_Vandermonde:
  3133   "setsum (\<lambda>k. (a gchoose k) * (b gchoose (n - k))) {0..n} = (a + b) gchoose n"
  3134 proof -
  3135   let ?ba = "fps_binomial a"
  3136   let ?bb = "fps_binomial b"
  3137   let ?bab = "fps_binomial (a + b)"
  3138   from fps_binomial_add_mult[of a b] have "?bab $ n = (?ba * ?bb)$n" by simp
  3139   then show ?thesis by (simp add: fps_mult_nth)
  3140 qed
  3141 
  3142 lemma binomial_Vandermonde:
  3143   "setsum (\<lambda>k. (a choose k) * (b choose (n - k))) {0..n} = (a + b) choose n"
  3144   using gbinomial_Vandermonde[of "(of_nat a)" "of_nat b" n]
  3145   apply (simp only: binomial_gbinomial[symmetric] of_nat_mult[symmetric]
  3146     of_nat_setsum[symmetric] of_nat_add[symmetric])
  3147   apply simp
  3148   done
  3149 
  3150 lemma binomial_Vandermonde_same: "setsum (\<lambda>k. (n choose k)\<^sup>2) {0..n} = (2 * n) choose n"
  3151   using binomial_Vandermonde[of n n n, symmetric]
  3152   unfolding mult_2
  3153   apply (simp add: power2_eq_square)
  3154   apply (rule setsum.cong)
  3155   apply (auto intro:  binomial_symmetric)
  3156   done
  3157 
  3158 lemma Vandermonde_pochhammer_lemma:
  3159   fixes a :: "'a::field_char_0"
  3160   assumes b: "\<forall>j\<in>{0 ..<n}. b \<noteq> of_nat j"
  3161   shows "setsum (\<lambda>k. (pochhammer (- a) k * pochhammer (- (of_nat n)) k) /
  3162       (of_nat (fact k) * pochhammer (b - of_nat n + 1) k)) {0..n} =
  3163     pochhammer (- (a + b)) n / pochhammer (- b) n"
  3164   (is "?l = ?r")
  3165 proof -
  3166   let ?m1 = "\<lambda>m. (- 1 :: 'a) ^ m"
  3167   let ?f = "\<lambda>m. of_nat (fact m)"
  3168   let ?p = "\<lambda>(x::'a). pochhammer (- x)"
  3169   from b have bn0: "?p b n \<noteq> 0"
  3170     unfolding pochhammer_eq_0_iff by simp
  3171   have th00:
  3172     "b gchoose (n - k) =
  3173         (?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k)"
  3174       (is ?gchoose)
  3175     "pochhammer (1 + b - of_nat n) k \<noteq> 0"
  3176       (is ?pochhammer)
  3177     if kn: "k \<in> {0..n}" for k
  3178   proof -
  3179     have nz: "pochhammer (1 + b - of_nat n) n \<noteq> 0"
  3180     proof
  3181       assume "pochhammer (1 + b - of_nat n) n = 0"
  3182       then have c: "pochhammer (b - of_nat n + 1) n = 0"
  3183         by (simp add: algebra_simps)
  3184       then obtain j where j: "j < n" "b - of_nat n + 1 = - of_nat j"
  3185         unfolding pochhammer_eq_0_iff by blast
  3186       from j have "b = of_nat n - of_nat j - of_nat 1"
  3187         by (simp add: algebra_simps)
  3188       then have "b = of_nat (n - j - 1)"
  3189         using j kn by (simp add: of_nat_diff)
  3190       with b show False using j by auto
  3191     qed
  3192 
  3193     from nz kn [simplified] have nz': "pochhammer (1 + b - of_nat n) k \<noteq> 0"
  3194       by (rule pochhammer_neq_0_mono)
  3195 
  3196     consider "k = 0 \<or> n = 0" | "k \<noteq> 0" "n \<noteq> 0"
  3197       by blast
  3198     then have "b gchoose (n - k) =
  3199       (?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k)"
  3200     proof cases
  3201       case 1
  3202       then show ?thesis
  3203         using kn by (cases "k = 0") (simp_all add: gbinomial_pochhammer)
  3204     next
  3205       case neq: 2
  3206       then obtain m where m: "n = Suc m"
  3207         by (cases n) auto
  3208       from neq(1) obtain h where h: "k = Suc h"
  3209         by (cases k) auto
  3210       show ?thesis
  3211       proof (cases "k = n")
  3212         case True
  3213         then show ?thesis
  3214           using pochhammer_minus'[where k=k and b=b]
  3215           apply (simp add: pochhammer_same)
  3216           using bn0
  3217           apply (simp add: field_simps power_add[symmetric])
  3218           done
  3219       next
  3220         case False
  3221         with kn have kn': "k < n"
  3222           by simp
  3223         have m1nk: "?m1 n = setprod (\<lambda>i. - 1) {0..m}" "?m1 k = setprod (\<lambda>i. - 1) {0..h}"
  3224           by (simp_all add: setprod_constant m h)
  3225         have bnz0: "pochhammer (b - of_nat n + 1) k \<noteq> 0"
  3226           using bn0 kn
  3227           unfolding pochhammer_eq_0_iff
  3228           apply auto
  3229           apply (erule_tac x= "n - ka - 1" in allE)
  3230           apply (auto simp add: algebra_simps of_nat_diff)
  3231           done
  3232         have eq1: "setprod (\<lambda>k. (1::'a) + of_nat m - of_nat k) {0 .. h} =
  3233           setprod of_nat {Suc (m - h) .. Suc m}"
  3234           using kn' h m
  3235           by (intro setprod.reindex_bij_witness[where i="\<lambda>k. Suc m - k" and j="\<lambda>k. Suc m - k"])
  3236              (auto simp: of_nat_diff)
  3237 
  3238         have th1: "(?m1 k * ?p (of_nat n) k) / ?f n = 1 / of_nat(fact (n - k))"
  3239           unfolding m1nk
  3240           unfolding m h pochhammer_Suc_setprod
  3241           apply (simp add: field_simps del: fact_Suc)
  3242           unfolding fact_altdef id_def
  3243           unfolding of_nat_setprod
  3244           unfolding setprod.distrib[symmetric]
  3245           apply auto
  3246           unfolding eq1
  3247           apply (subst setprod.union_disjoint[symmetric])
  3248           apply (auto)
  3249           apply (rule setprod.cong)
  3250           apply auto
  3251           done
  3252         have th20: "?m1 n * ?p b n = setprod (\<lambda>i. b - of_nat i) {0..m}"
  3253           unfolding m1nk
  3254           unfolding m h pochhammer_Suc_setprod
  3255           unfolding setprod.distrib[symmetric]
  3256           apply (rule setprod.cong)
  3257           apply auto
  3258           done
  3259         have th21:"pochhammer (b - of_nat n + 1) k = setprod (\<lambda>i. b - of_nat i) {n - k .. n - 1}"
  3260           unfolding h m
  3261           unfolding pochhammer_Suc_setprod
  3262           using kn m h
  3263           by (intro setprod.reindex_bij_witness[where i="\<lambda>k. n - 1 - k" and j="\<lambda>i. m-i"])
  3264              (auto simp: of_nat_diff)
  3265 
  3266         have "?m1 n * ?p b n =
  3267           pochhammer (b - of_nat n + 1) k * setprod (\<lambda>i. b - of_nat i) {0.. n - k - 1}"
  3268           unfolding th20 th21
  3269           unfolding h m
  3270           apply (subst setprod.union_disjoint[symmetric])
  3271           using kn' h m
  3272           apply auto
  3273           apply (rule setprod.cong)
  3274           apply auto
  3275           done
  3276         then have th2: "(?m1 n * ?p b n)/pochhammer (b - of_nat n + 1) k =
  3277           setprod (\<lambda>i. b - of_nat i) {0.. n - k - 1}"
  3278           using nz' by (simp add: field_simps)
  3279         have "(?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k) =
  3280           ((?m1 k * ?p (of_nat n) k) / ?f n) * ((?m1 n * ?p b n)/pochhammer (b - of_nat n + 1) k)"
  3281           using bnz0
  3282           by (simp add: field_simps)
  3283         also have "\<dots> = b gchoose (n - k)"
  3284           unfolding th1 th2
  3285           using kn' by (simp add: gbinomial_def)
  3286         finally show ?thesis by simp
  3287       qed
  3288     qed
  3289     then show ?gchoose and ?pochhammer
  3290       apply (cases "n = 0")
  3291       using nz'
  3292       apply auto
  3293       done
  3294   qed
  3295   have "?r = ((a + b) gchoose n) * (of_nat (fact n) / (?m1 n * pochhammer (- b) n))"
  3296     unfolding gbinomial_pochhammer
  3297     using bn0 by (auto simp add: field_simps)
  3298   also have "\<dots> = ?l"
  3299     unfolding gbinomial_Vandermonde[symmetric]
  3300     apply (simp add: th00)
  3301     unfolding gbinomial_pochhammer
  3302     using bn0
  3303     apply (simp add: setsum_left_distrib setsum_right_distrib field_simps)
  3304     apply (rule setsum.cong)
  3305     apply (rule refl)
  3306     apply (drule th00(2))
  3307     apply (simp add: field_simps power_add[symmetric])
  3308     done
  3309   finally show ?thesis by simp
  3310 qed
  3311 
  3312 lemma Vandermonde_pochhammer:
  3313   fixes a :: "'a::field_char_0"
  3314   assumes c: "\<forall>i \<in> {0..< n}. c \<noteq> - of_nat i"
  3315   shows "setsum (\<lambda>k. (pochhammer a k * pochhammer (- (of_nat n)) k) /
  3316     (of_nat (fact k) * pochhammer c k)) {0..n} = pochhammer (c - a) n / pochhammer c n"
  3317 proof -
  3318   let ?a = "- a"
  3319   let ?b = "c + of_nat n - 1"
  3320   have h: "\<forall> j \<in>{0..< n}. ?b \<noteq> of_nat j"
  3321     using c
  3322     apply (auto simp add: algebra_simps of_nat_diff)
  3323     apply (erule_tac x = "n - j - 1" in ballE)
  3324     apply (auto simp add: of_nat_diff algebra_simps)
  3325     done
  3326   have th0: "pochhammer (- (?a + ?b)) n = (- 1)^n * pochhammer (c - a) n"
  3327     unfolding pochhammer_minus
  3328     by (simp add: algebra_simps)
  3329   have th1: "pochhammer (- ?b) n = (- 1)^n * pochhammer c n"
  3330     unfolding pochhammer_minus
  3331     by simp
  3332   have nz: "pochhammer c n \<noteq> 0" using c
  3333     by (simp add: pochhammer_eq_0_iff)
  3334   from Vandermonde_pochhammer_lemma[where a = "?a" and b="?b" and n=n, OF h, unfolded th0 th1]
  3335   show ?thesis
  3336     using nz by (simp add: field_simps setsum_right_distrib)
  3337 qed
  3338 
  3339 
  3340 subsubsection \<open>Formal trigonometric functions\<close>
  3341 
  3342 definition "fps_sin (c::'a::field_char_0) =
  3343   Abs_fps (\<lambda>n. if even n then 0 else (- 1) ^((n - 1) div 2) * c^n /(of_nat (fact n)))"
  3344 
  3345 definition "fps_cos (c::'a::field_char_0) =
  3346   Abs_fps (\<lambda>n. if even n then (- 1) ^ (n div 2) * c^n / (of_nat (fact n)) else 0)"
  3347 
  3348 lemma fps_sin_deriv:
  3349   "fps_deriv (fps_sin c) = fps_const c * fps_cos c"
  3350   (is "?lhs = ?rhs")
  3351 proof (rule fps_ext)
  3352   fix n :: nat
  3353   show "?lhs $ n = ?rhs $ n"
  3354   proof (cases "even n")
  3355     case True
  3356     have "?lhs$n = of_nat (n+1) * (fps_sin c $ (n+1))" by simp
  3357     also have "\<dots> = of_nat (n+1) * ((- 1)^(n div 2) * c^Suc n / of_nat (fact (Suc n)))"
  3358       using True by (simp add: fps_sin_def)
  3359     also have "\<dots> = (- 1)^(n div 2) * c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  3360       unfolding fact_Suc of_nat_mult
  3361       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  3362     also have "\<dots> = (- 1)^(n div 2) *c^Suc n / of_nat (fact n)"
  3363       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  3364     finally show ?thesis
  3365       using True by (simp add: fps_cos_def field_simps)
  3366   next
  3367     case False
  3368     then show ?thesis
  3369       by (simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  3370   qed
  3371 qed
  3372 
  3373 lemma fps_cos_deriv: "fps_deriv (fps_cos c) = fps_const (- c)* (fps_sin c)"
  3374   (is "?lhs = ?rhs")
  3375 proof (rule fps_ext)
  3376   have th0: "- ((- 1::'a) ^ n) = (- 1)^Suc n" for n
  3377     by simp
  3378   show "?lhs $ n = ?rhs $ n" for n
  3379   proof (cases "even n")
  3380     case False
  3381     then have n0: "n \<noteq> 0" by presburger
  3382     from False have th1: "Suc ((n - 1) div 2) = Suc n div 2"
  3383       by (cases n) simp_all
  3384     have "?lhs$n = of_nat (n+1) * (fps_cos c $ (n+1))" by simp
  3385     also have "\<dots> = of_nat (n+1) * ((- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact (Suc n)))"
  3386       using False by (simp add: fps_cos_def)
  3387     also have "\<dots> = (- 1)^((n + 1) div 2)*c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  3388       unfolding fact_Suc of_nat_mult
  3389       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  3390     also have "\<dots> = (- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact n)"
  3391       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  3392     also have "\<dots> = (- ((- 1)^((n - 1) div 2))) * c^Suc n / of_nat (fact n)"
  3393       unfolding th0 unfolding th1 by simp
  3394     finally show ?thesis
  3395       using False by (simp add: fps_sin_def field_simps)
  3396   next
  3397     case True
  3398     then show ?thesis
  3399       by (simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  3400   qed
  3401 qed
  3402 
  3403 lemma fps_sin_cos_sum_of_squares: "(fps_cos c)\<^sup>2 + (fps_sin c)\<^sup>2 = 1"
  3404   (is "?lhs = _")
  3405 proof -
  3406   have "fps_deriv ?lhs = 0"
  3407     apply (simp add:  fps_deriv_power fps_sin_deriv fps_cos_deriv)
  3408     apply (simp add: field_simps fps_const_neg[symmetric] del: fps_const_neg)
  3409     done
  3410   then have "?lhs = fps_const (?lhs $ 0)"
  3411     unfolding fps_deriv_eq_0_iff .
  3412   also have "\<dots> = 1"
  3413     by (auto simp add: fps_eq_iff numeral_2_eq_2 fps_mult_nth fps_cos_def fps_sin_def)
  3414   finally show ?thesis .
  3415 qed
  3416 
  3417 lemma fps_sin_nth_0 [simp]: "fps_sin c $ 0 = 0"
  3418   unfolding fps_sin_def by simp
  3419 
  3420 lemma fps_sin_nth_1 [simp]: "fps_sin c $ 1 = c"
  3421   unfolding fps_sin_def by simp
  3422 
  3423 lemma fps_sin_nth_add_2:
  3424     "fps_sin c $ (n + 2) = - (c * c * fps_sin c $ n / (of_nat (n + 1) * of_nat (n + 2)))"
  3425   unfolding fps_sin_def
  3426   apply (cases n)
  3427   apply simp
  3428   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq del: of_nat_Suc fact_Suc)
  3429   apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  3430   done
  3431 
  3432 lemma fps_cos_nth_0 [simp]: "fps_cos c $ 0 = 1"
  3433   unfolding fps_cos_def by simp
  3434 
  3435 lemma fps_cos_nth_1 [simp]: "fps_cos c $ 1 = 0"
  3436   unfolding fps_cos_def by simp
  3437 
  3438 lemma fps_cos_nth_add_2:
  3439   "fps_cos c $ (n + 2) = - (c * c * fps_cos c $ n / (of_nat (n + 1) * of_nat (n + 2)))"
  3440   unfolding fps_cos_def
  3441   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq del: of_nat_Suc fact_Suc)
  3442   apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  3443   done
  3444 
  3445 lemma nat_induct2: "P 0 \<Longrightarrow> P 1 \<Longrightarrow> (\<And>n. P n \<Longrightarrow> P (n + 2)) \<Longrightarrow> P (n::nat)"
  3446   unfolding One_nat_def numeral_2_eq_2
  3447   apply (induct n rule: nat_less_induct)
  3448   apply (case_tac n)
  3449   apply simp
  3450   apply (rename_tac m)
  3451   apply (case_tac m)
  3452   apply simp
  3453   apply (rename_tac k)
  3454   apply (case_tac k)
  3455   apply simp_all
  3456   done
  3457 
  3458 lemma nat_add_1_add_1: "(n::nat) + 1 + 1 = n + 2"
  3459   by simp
  3460 
  3461 lemma eq_fps_sin:
  3462   assumes 0: "a $ 0 = 0"
  3463     and 1: "a $ 1 = c"
  3464     and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  3465   shows "a = fps_sin c"
  3466   apply (rule fps_ext)
  3467   apply (induct_tac n rule: nat_induct2)
  3468   apply (simp add: 0)
  3469   apply (simp add: 1 del: One_nat_def)
  3470   apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  3471   apply (simp add: nat_add_1_add_1 fps_sin_nth_add_2
  3472               del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  3473   apply (subst minus_divide_left)
  3474   apply (subst nonzero_eq_divide_eq)
  3475   apply (simp del: of_nat_add of_nat_Suc)
  3476   apply (simp only: ac_simps)
  3477   done
  3478 
  3479 lemma eq_fps_cos:
  3480   assumes 0: "a $ 0 = 1"
  3481     and 1: "a $ 1 = 0"
  3482     and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  3483   shows "a = fps_cos c"
  3484   apply (rule fps_ext)
  3485   apply (induct_tac n rule: nat_induct2)
  3486   apply (simp add: 0)
  3487   apply (simp add: 1 del: One_nat_def)
  3488   apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  3489   apply (simp add: nat_add_1_add_1 fps_cos_nth_add_2
  3490               del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  3491   apply (subst minus_divide_left)
  3492   apply (subst nonzero_eq_divide_eq)
  3493   apply (simp del: of_nat_add of_nat_Suc)
  3494   apply (simp only: ac_simps)
  3495   done
  3496 
  3497 lemma mult_nth_0 [simp]: "(a * b) $ 0 = a $ 0 * b $ 0"
  3498   by (simp add: fps_mult_nth)
  3499 
  3500 lemma mult_nth_1 [simp]: "(a * b) $ 1 = a $ 0 * b $ 1 + a $ 1 * b $ 0"
  3501   by (simp add: fps_mult_nth)
  3502 
  3503 lemma fps_sin_add: "fps_sin (a + b) = fps_sin a * fps_cos b + fps_cos a * fps_sin b"
  3504   apply (rule eq_fps_sin [symmetric], simp, simp del: One_nat_def)
  3505   apply (simp del: fps_const_neg fps_const_add fps_const_mult
  3506               add: fps_const_add [symmetric] fps_const_neg [symmetric]
  3507                    fps_sin_deriv fps_cos_deriv algebra_simps)
  3508   done
  3509 
  3510 lemma fps_cos_add: "fps_cos (a + b) = fps_cos a * fps_cos b - fps_sin a * fps_sin b"
  3511   apply (rule eq_fps_cos [symmetric], simp, simp del: One_nat_def)
  3512   apply (simp del: fps_const_neg fps_const_add fps_const_mult
  3513               add: fps_const_add [symmetric] fps_const_neg [symmetric]
  3514                    fps_sin_deriv fps_cos_deriv algebra_simps)
  3515   done
  3516 
  3517 lemma fps_sin_even: "fps_sin (- c) = - fps_sin c"
  3518   by (auto simp add: fps_eq_iff fps_sin_def)
  3519 
  3520 lemma fps_cos_odd: "fps_cos (- c) = fps_cos c"
  3521   by (auto simp add: fps_eq_iff fps_cos_def)
  3522 
  3523 definition "fps_tan c = fps_sin c / fps_cos c"
  3524 
  3525 lemma fps_tan_deriv: "fps_deriv (fps_tan c) = fps_const c / (fps_cos c)\<^sup>2"
  3526 proof -
  3527   have th0: "fps_cos c $ 0 \<noteq> 0" by (simp add: fps_cos_def)
  3528   show ?thesis
  3529     using fps_sin_cos_sum_of_squares[of c]
  3530     apply (simp add: fps_tan_def fps_divide_deriv[OF th0] fps_sin_deriv fps_cos_deriv
  3531       fps_const_neg[symmetric] field_simps power2_eq_square del: fps_const_neg)
  3532     unfolding distrib_left[symmetric]
  3533     apply simp
  3534     done
  3535 qed
  3536 
  3537 text \<open>Connection to E c over the complex numbers --- Euler and de Moivre.\<close>
  3538 
  3539 lemma Eii_sin_cos: "E (ii * c) = fps_cos c + fps_const ii * fps_sin c"
  3540   (is "?l = ?r")
  3541 proof -
  3542   have "?l $ n = ?r $ n" for n
  3543   proof (cases "even n")
  3544     case True
  3545     then obtain m where m: "n = 2 * m" ..
  3546     show ?thesis
  3547       by (simp add: m fps_sin_def fps_cos_def power_mult_distrib power_mult power_minus [of "c ^ 2"])
  3548   next
  3549     case False
  3550     then obtain m where m: "n = 2 * m + 1" ..
  3551     show ?thesis
  3552       by (simp add: m fps_sin_def fps_cos_def power_mult_distrib
  3553         power_mult power_minus [of "c ^ 2"])
  3554   qed
  3555   then show ?thesis
  3556     by (simp add: fps_eq_iff)
  3557 qed
  3558 
  3559 lemma E_minus_ii_sin_cos: "E (- (ii * c)) = fps_cos c - fps_const ii * fps_sin c"
  3560   unfolding minus_mult_right Eii_sin_cos by (simp add: fps_sin_even fps_cos_odd)
  3561 
  3562 lemma fps_const_minus: "fps_const (c::'a::group_add) - fps_const d = fps_const (c - d)"
  3563   by (simp add: fps_eq_iff fps_const_def)
  3564 
  3565 lemma fps_numeral_fps_const: "numeral i = fps_const (numeral i :: 'a::comm_ring_1)"
  3566   by (fact numeral_fps_const) (* FIXME: duplicate *)
  3567 
  3568 lemma fps_cos_Eii: "fps_cos c = (E (ii * c) + E (- ii * c)) / fps_const 2"
  3569 proof -
  3570   have th: "fps_cos c + fps_cos c = fps_cos c * fps_const 2"
  3571     by (simp add: numeral_fps_const)
  3572   show ?thesis
  3573     unfolding Eii_sin_cos minus_mult_commute
  3574     by (simp add: fps_sin_even fps_cos_odd numeral_fps_const fps_divide_def fps_const_inverse th)
  3575 qed
  3576 
  3577 lemma fps_sin_Eii: "fps_sin c = (E (ii * c) - E (- ii * c)) / fps_const (2*ii)"
  3578 proof -
  3579   have th: "fps_const \<i> * fps_sin c + fps_const \<i> * fps_sin c = fps_sin c * fps_const (2 * ii)"
  3580     by (simp add: fps_eq_iff numeral_fps_const)
  3581   show ?thesis
  3582     unfolding Eii_sin_cos minus_mult_commute
  3583     by (simp add: fps_sin_even fps_cos_odd fps_divide_def fps_const_inverse th)
  3584 qed
  3585 
  3586 lemma fps_tan_Eii:
  3587   "fps_tan c = (E (ii * c) - E (- ii * c)) / (fps_const ii * (E (ii * c) + E (- ii * c)))"
  3588   unfolding fps_tan_def fps_sin_Eii fps_cos_Eii mult_minus_left E_neg
  3589   apply (simp add: fps_divide_def fps_inverse_mult fps_const_mult[symmetric] fps_const_inverse del: fps_const_mult)
  3590   apply simp
  3591   done
  3592 
  3593 lemma fps_demoivre:
  3594   "(fps_cos a + fps_const ii * fps_sin a)^n =
  3595     fps_cos (of_nat n * a) + fps_const ii * fps_sin (of_nat n * a)"
  3596   unfolding Eii_sin_cos[symmetric] E_power_mult
  3597   by (simp add: ac_simps)
  3598 
  3599 
  3600 subsection \<open>Hypergeometric series\<close>
  3601 
  3602 definition "F as bs (c::'a::{field_char_0,field}) =
  3603   Abs_fps (\<lambda>n. (foldl (\<lambda>r a. r* pochhammer a n) 1 as * c^n) /
  3604     (foldl (\<lambda>r b. r * pochhammer b n) 1 bs * of_nat (fact n)))"
  3605 
  3606 lemma F_nth[simp]: "F as bs c $ n =
  3607   (foldl (\<lambda>r a. r* pochhammer a n) 1 as * c^n) /
  3608     (foldl (\<lambda>r b. r * pochhammer b n) 1 bs * of_nat (fact n))"
  3609   by (simp add: F_def)
  3610 
  3611 lemma foldl_mult_start:
  3612   fixes v :: "'a::comm_ring_1"
  3613   shows "foldl (\<lambda>r x. r * f x) v as * x = foldl (\<lambda>r x. r * f x) (v * x) as "
  3614   by (induct as arbitrary: x v) (auto simp add: algebra_simps)
  3615 
  3616 lemma foldr_mult_foldl:
  3617   fixes v :: "'a::comm_ring_1"
  3618   shows "foldr (\<lambda>x r. r * f x) as v = foldl (\<lambda>r x. r * f x) v as"
  3619   by (induct as arbitrary: v) (auto simp add: foldl_mult_start)
  3620 
  3621 lemma F_nth_alt:
  3622   "F as bs c $ n = foldr (\<lambda>a r. r * pochhammer a n) as (c ^ n) /
  3623     foldr (\<lambda>b r. r * pochhammer b n) bs (of_nat (fact n))"
  3624   by (simp add: foldl_mult_start foldr_mult_foldl)
  3625 
  3626 lemma F_E[simp]: "F [] [] c = E c"
  3627   by (simp add: fps_eq_iff)
  3628 
  3629 lemma F_1_0[simp]: "F [1] [] c = 1/(1 - fps_const c * X)"
  3630 proof -
  3631   let ?a = "(Abs_fps (\<lambda>n. 1)) oo (fps_const c * X)"
  3632   have th0: "(fps_const c * X) $ 0 = 0" by simp
  3633   show ?thesis unfolding gp[OF th0, symmetric]
  3634     by (auto simp add: fps_eq_iff pochhammer_fact[symmetric]
  3635       fps_compose_nth power_mult_distrib cond_value_iff setsum.delta' cong del: if_weak_cong)
  3636 qed
  3637 
  3638 lemma F_B[simp]: "F [-a] [] (- 1) = fps_binomial a"
  3639   by (simp add: fps_eq_iff gbinomial_pochhammer algebra_simps)
  3640 
  3641 lemma F_0[simp]: "F as bs c $ 0 = 1"
  3642   apply simp
  3643   apply (subgoal_tac "\<forall>as. foldl (\<lambda>(r::'a) (a::'a). r) 1 as = 1")
  3644   apply auto
  3645   apply (induct_tac as)
  3646   apply auto
  3647   done
  3648 
  3649 lemma foldl_prod_prod:
  3650   "foldl (\<lambda>(r::'b::comm_ring_1) (x::'a::comm_ring_1). r * f x) v as * foldl (\<lambda>r x. r * g x) w as =
  3651     foldl (\<lambda>r x. r * f x * g x) (v * w) as"
  3652   by (induct as arbitrary: v w) (auto simp add: algebra_simps)
  3653 
  3654 
  3655 lemma F_rec:
  3656   "F as bs c $ Suc n = ((foldl (\<lambda>r a. r* (a + of_nat n)) c as) /
  3657     (foldl (\<lambda>r b. r * (b + of_nat n)) (of_nat (Suc n)) bs )) * F as bs c $ n"
  3658   apply (simp del: of_nat_Suc of_nat_add fact_Suc)
  3659   apply (simp add: foldl_mult_start del: fact_Suc of_nat_Suc)
  3660   unfolding foldl_prod_prod[unfolded foldl_mult_start] pochhammer_Suc
  3661   apply (simp add: algebra_simps of_nat_mult)
  3662   done
  3663 
  3664 lemma XD_nth[simp]: "XD a $ n = (if n = 0 then 0 else of_nat n * a$n)"
  3665   by (simp add: XD_def)
  3666 
  3667 lemma XD_0th[simp]: "XD a $ 0 = 0"
  3668   by simp
  3669 lemma XD_Suc[simp]:" XD a $ Suc n = of_nat (Suc n) * a $ Suc n"
  3670   by simp
  3671 
  3672 definition "XDp c a = XD a + fps_const c * a"
  3673 
  3674 lemma XDp_nth[simp]: "XDp c a $ n = (c + of_nat n) * a$n"
  3675   by (simp add: XDp_def algebra_simps)
  3676 
  3677 lemma XDp_commute: "XDp b \<circ> XDp (c::'a::comm_ring_1) = XDp c \<circ> XDp b"
  3678   by (auto simp add: XDp_def fun_eq_iff fps_eq_iff algebra_simps)
  3679 
  3680 lemma XDp0 [simp]: "XDp 0 = XD"
  3681   by (simp add: fun_eq_iff fps_eq_iff)
  3682 
  3683 lemma XDp_fps_integral [simp]: "XDp 0 (fps_integral a c) = X * a"
  3684   by (simp add: fps_eq_iff fps_integral_def)
  3685 
  3686 lemma F_minus_nat:
  3687   "F [- of_nat n] [- of_nat (n + m)] (c::'a::{field_char_0,field}) $ k =
  3688     (if k \<le> n then
  3689       pochhammer (- of_nat n) k * c ^ k / (pochhammer (- of_nat (n + m)) k * of_nat (fact k))
  3690      else 0)"
  3691   "F [- of_nat m] [- of_nat (m + n)] (c::'a::{field_char_0,field}) $ k =
  3692     (if k \<le> m then
  3693       pochhammer (- of_nat m) k * c ^ k / (pochhammer (- of_nat (m + n)) k * of_nat (fact k))
  3694      else 0)"
  3695   by (auto simp add: pochhammer_eq_0_iff)
  3696 
  3697 lemma setsum_eq_if: "setsum f {(n::nat) .. m} = (if m < n then 0 else f n + setsum f {n+1 .. m})"
  3698   apply simp
  3699   apply (subst setsum.insert[symmetric])
  3700   apply (auto simp add: not_less setsum_head_Suc)
  3701   done
  3702 
  3703 lemma pochhammer_rec_if: "pochhammer a n = (if n = 0 then 1 else a * pochhammer (a + 1) (n - 1))"
  3704   by (cases n) (simp_all add: pochhammer_rec)
  3705 
  3706 lemma XDp_foldr_nth [simp]: "foldr (\<lambda>c r. XDp c \<circ> r) cs (\<lambda>c. XDp c a) c0 $ n =
  3707     foldr (\<lambda>c r. (c + of_nat n) * r) cs (c0 + of_nat n) * a$n"
  3708   by (induct cs arbitrary: c0) (auto simp add: algebra_simps)
  3709 
  3710 lemma genric_XDp_foldr_nth:
  3711   assumes f: "\<forall>n c a. f c a $ n = (of_nat n + k c) * a$n"
  3712   shows "foldr (\<lambda>c r. f c \<circ> r) cs (\<lambda>c. g c a) c0 $ n =
  3713     foldr (\<lambda>c r. (k c + of_nat n) * r) cs (g c0 a $ n)"
  3714   by (induct cs arbitrary: c0) (auto simp add: algebra_simps f)
  3715 
  3716 lemma dist_less_imp_nth_equal:
  3717   assumes "dist f g < inverse (2 ^ i)"
  3718     and"j \<le> i"
  3719   shows "f $ j = g $ j"
  3720 proof (rule ccontr)
  3721   assume "f $ j \<noteq> g $ j"
  3722   then have "\<exists>n. f $ n \<noteq> g $ n" by auto
  3723   with assms have "i < (LEAST n. f $ n \<noteq> g $ n)"
  3724     by (simp add: split_if_asm dist_fps_def)
  3725   also have "\<dots> \<le> j"
  3726     using \<open>f $ j \<noteq> g $ j\<close> by (auto intro: Least_le)
  3727   finally show False using \<open>j \<le> i\<close> by simp
  3728 qed
  3729 
  3730 lemma nth_equal_imp_dist_less:
  3731   assumes "\<And>j. j \<le> i \<Longrightarrow> f $ j = g $ j"
  3732   shows "dist f g < inverse (2 ^ i)"
  3733 proof (cases "f = g")
  3734   case True
  3735   then show ?thesis by simp
  3736 next
  3737   case False
  3738   then have "\<exists>n. f $ n \<noteq> g $ n" by (simp add: fps_eq_iff)
  3739   with assms have "dist f g = inverse (2 ^ (LEAST n. f $ n \<noteq> g $ n))"
  3740     by (simp add: split_if_asm dist_fps_def)
  3741   moreover
  3742   from assms \<open>\<exists>n. f $ n \<noteq> g $ n\<close> have "i < (LEAST n. f $ n \<noteq> g $ n)"
  3743     by (metis (mono_tags) LeastI not_less)
  3744   ultimately show ?thesis by simp
  3745 qed
  3746 
  3747 lemma dist_less_eq_nth_equal: "dist f g < inverse (2 ^ i) \<longleftrightarrow> (\<forall>j \<le> i. f $ j = g $ j)"
  3748   using dist_less_imp_nth_equal nth_equal_imp_dist_less by blast
  3749 
  3750 instance fps :: (comm_ring_1) complete_space
  3751 proof
  3752   fix X :: "nat \<Rightarrow> 'a fps"
  3753   assume "Cauchy X"
  3754   obtain M where M: "\<forall>i. \<forall>m \<ge> M i. \<forall>j \<le> i. X (M i) $ j = X m $ j"
  3755   proof -
  3756     have "\<exists>M. \<forall>m \<ge> M. \<forall>j\<le>i. X M $ j = X m $ j" for i
  3757     proof -
  3758       have "0 < inverse ((2::real)^i)" by simp
  3759       from metric_CauchyD[OF \<open>Cauchy X\<close> this] dist_less_imp_nth_equal
  3760       show ?thesis by blast
  3761     qed
  3762     then show ?thesis using that by metis
  3763   qed
  3764 
  3765   show "convergent X"
  3766   proof (rule convergentI)
  3767     show "X ----> Abs_fps (\<lambda>i. X (M i) $ i)"
  3768       unfolding tendsto_iff
  3769     proof safe
  3770       fix e::real assume "0 < e"
  3771       with LIMSEQ_inverse_realpow_zero[of 2, simplified, simplified filterlim_iff,
  3772         THEN spec, of "\<lambda>x. x < e"]
  3773       have "eventually (\<lambda>i. inverse (2 ^ i) < e) sequentially"
  3774         unfolding eventually_nhds
  3775         apply clarsimp
  3776         apply (rule FalseE)
  3777         apply auto -- \<open>slow\<close>
  3778         done
  3779       then obtain i where "inverse (2 ^ i) < e"
  3780         by (auto simp: eventually_sequentially)
  3781       have "eventually (\<lambda>x. M i \<le> x) sequentially"
  3782         by (auto simp: eventually_sequentially)
  3783       then show "eventually (\<lambda>x. dist (X x) (Abs_fps (\<lambda>i. X (M i) $ i)) < e) sequentially"
  3784       proof eventually_elim
  3785         fix x
  3786         assume x: "M i \<le> x"
  3787         have "X (M i) $ j = X (M j) $ j" if "j \<le> i" for j
  3788           using M that by (metis nat_le_linear)
  3789         with x have "dist (X x) (Abs_fps (\<lambda>j. X (M j) $ j)) < inverse (2 ^ i)"
  3790           using M by (force simp: dist_less_eq_nth_equal)
  3791         also note \<open>inverse (2 ^ i) < e\<close>
  3792         finally show "dist (X x) (Abs_fps (\<lambda>j. X (M j) $ j)) < e" .
  3793       qed
  3794     qed
  3795   qed
  3796 qed
  3797 
  3798 end