src/HOL/Library/FuncSet.thy
author nipkow
Tue Sep 22 14:31:22 2015 +0200 (2015-09-22)
changeset 61225 1a690dce8cfc
parent 59425 c5e79df8cc21
child 61359 e985b52c3eb3
permissions -rw-r--r--
tuned references
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 section \<open>Pi and Function Sets\<close>
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    12   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    13 
    14 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    15   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    16 
    17 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    18   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    19 
    20 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "->" 60)
    21   where "A -> B \<equiv> Pi A (\<lambda>_. B)"
    22 
    23 notation (xsymbols)
    24   funcset  (infixr "\<rightarrow>" 60)
    25 
    26 syntax
    27   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    28   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    29 syntax (xsymbols)
    30   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    31   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 syntax (HTML output)
    33   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    34   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    35 translations
    36   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    37   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    38 
    39 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    40   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    41 
    42 
    43 subsection \<open>Basic Properties of @{term Pi}\<close>
    44 
    45 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    46   by (simp add: Pi_def)
    47 
    48 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    49   by (simp add:Pi_def)
    50 
    51 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    52   by (simp add: Pi_def)
    53 
    54 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    58   unfolding Pi_def by auto
    59 
    60 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    61   by (auto simp: Pi_def)
    62 
    63 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    64   by (auto simp: Pi_def)
    65 
    66 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    67   by auto
    68 
    69 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    70   by (simp add: Pi_def)
    71 
    72 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    73   by auto
    74 
    75 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    76   by auto
    77 
    78 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    79   apply (simp add: Pi_def)
    80   apply auto
    81   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    82   picking an element from each non-empty @{term "B x"}\<close>
    83   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    84   apply auto
    85   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    86   apply auto
    87   done
    88 
    89 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    90   by (simp add: Pi_def)
    91 
    92 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    93   by auto
    94 
    95 lemma Pi_UN:
    96   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    97   assumes "finite I"
    98     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    99   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   100 proof (intro set_eqI iffI)
   101   fix f
   102   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   103   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
   104     by auto
   105   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)"
   106     by auto
   107   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   108     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   109   have "f \<in> Pi I (A k)"
   110   proof (intro Pi_I)
   111     fix i
   112     assume "i \<in> I"
   113     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   114     show "f i \<in> A k i" by auto
   115   qed
   116   then show "f \<in> (\<Union>n. Pi I (A n))"
   117     by auto
   118 qed auto
   119 
   120 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   121   by (simp add: Pi_def)
   122 
   123 text \<open>Covariance of Pi-sets in their second argument\<close>
   124 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   125   by auto
   126 
   127 text \<open>Contravariance of Pi-sets in their first argument\<close>
   128 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   129   by auto
   130 
   131 lemma prod_final:
   132   assumes 1: "fst \<circ> f \<in> Pi A B"
   133     and 2: "snd \<circ> f \<in> Pi A C"
   134   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   135 proof (rule Pi_I)
   136   fix z
   137   assume z: "z \<in> A"
   138   have "f z = (fst (f z), snd (f z))"
   139     by simp
   140   also have "\<dots> \<in> B z \<times> C z"
   141     by (metis SigmaI PiE o_apply 1 2 z)
   142   finally show "f z \<in> B z \<times> C z" .
   143 qed
   144 
   145 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   146   by (auto simp: Pi_def)
   147 
   148 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   149   by (auto simp: Pi_def)
   150 
   151 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   152   by (auto simp: Pi_def)
   153 
   154 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   155   by (auto simp: Pi_def)
   156 
   157 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   158   apply auto
   159   apply (drule_tac x=x in Pi_mem)
   160   apply (simp_all split: split_if_asm)
   161   apply (drule_tac x=i in Pi_mem)
   162   apply (auto dest!: Pi_mem)
   163   done
   164 
   165 
   166 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   167 
   168 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   169   by (simp add: Pi_def compose_def restrict_def)
   170 
   171 lemma compose_assoc:
   172   assumes "f \<in> A \<rightarrow> B"
   173     and "g \<in> B \<rightarrow> C"
   174     and "h \<in> C \<rightarrow> D"
   175   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   176   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   177 
   178 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   179   by (simp add: compose_def restrict_def)
   180 
   181 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   182   by (auto simp add: image_def compose_eq)
   183 
   184 
   185 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   186 
   187 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   188   by (simp add: Pi_def restrict_def)
   189 
   190 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   191   by (simp add: Pi_def restrict_def)
   192 
   193 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   194   by (simp add: restrict_def)
   195 
   196 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   197   by simp
   198 
   199 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   200   by (simp add: fun_eq_iff Pi_def restrict_def)
   201 
   202 lemma restrict_UNIV: "restrict f UNIV = f"
   203   by (simp add: restrict_def)
   204 
   205 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   206   by (simp add: inj_on_def restrict_def)
   207 
   208 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   209   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   210 
   211 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   212   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   213 
   214 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   215   by (auto simp add: restrict_def)
   216 
   217 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   218   unfolding restrict_def by (simp add: fun_eq_iff)
   219 
   220 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   221   by (auto simp: restrict_def)
   222 
   223 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   224   by (auto simp: fun_eq_iff)
   225 
   226 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   227   by (auto simp: restrict_def Pi_def)
   228 
   229 
   230 subsection \<open>Bijections Between Sets\<close>
   231 
   232 text \<open>The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   233 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   234 
   235 lemma bij_betwI:
   236   assumes "f \<in> A \<rightarrow> B"
   237     and "g \<in> B \<rightarrow> A"
   238     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   239     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   240   shows "bij_betw f A B"
   241   unfolding bij_betw_def
   242 proof
   243   show "inj_on f A"
   244     by (metis g_f inj_on_def)
   245   have "f ` A \<subseteq> B"
   246     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   247   moreover
   248   have "B \<subseteq> f ` A"
   249     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   250   ultimately show "f ` A = B"
   251     by blast
   252 qed
   253 
   254 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   255   by (auto simp add: bij_betw_def)
   256 
   257 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   258   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   259 
   260 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   261   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   262   apply (auto simp add: compose_def image_def)
   263   done
   264 
   265 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   266   by (simp add: bij_betw_def)
   267 
   268 
   269 subsection \<open>Extensionality\<close>
   270 
   271 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   272   unfolding extensional_def by auto
   273 
   274 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   275   by (simp add: extensional_def)
   276 
   277 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   278   by (simp add: restrict_def extensional_def)
   279 
   280 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   281   by (simp add: compose_def)
   282 
   283 lemma extensionalityI:
   284   assumes "f \<in> extensional A"
   285     and "g \<in> extensional A"
   286     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   287   shows "f = g"
   288   using assms by (force simp add: fun_eq_iff extensional_def)
   289 
   290 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   291   by (rule extensionalityI[OF restrict_extensional]) auto
   292 
   293 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   294   unfolding extensional_def by auto
   295 
   296 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   297   by (unfold inv_into_def) (fast intro: someI2)
   298 
   299 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   300   apply (simp add: bij_betw_def compose_def)
   301   apply (rule restrict_ext, auto)
   302   done
   303 
   304 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   305   apply (simp add: compose_def)
   306   apply (rule restrict_ext)
   307   apply (simp add: f_inv_into_f)
   308   done
   309 
   310 lemma extensional_insert[intro, simp]:
   311   assumes "a \<in> extensional (insert i I)"
   312   shows "a(i := b) \<in> extensional (insert i I)"
   313   using assms unfolding extensional_def by auto
   314 
   315 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   316   unfolding extensional_def by auto
   317 
   318 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   319   by (auto simp: extensional_def)
   320 
   321 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   322   unfolding restrict_def extensional_def by auto
   323 
   324 lemma extensional_insert_undefined[intro, simp]:
   325   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   326   unfolding extensional_def by auto
   327 
   328 lemma extensional_insert_cancel[intro, simp]:
   329   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   330   unfolding extensional_def by auto
   331 
   332 
   333 subsection \<open>Cardinality\<close>
   334 
   335 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   336   by (rule card_inj_on_le) auto
   337 
   338 lemma card_bij:
   339   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   340     and "g \<in> B \<rightarrow> A" "inj_on g B"
   341     and "finite A" "finite B"
   342   shows "card A = card B"
   343   using assms by (blast intro: card_inj order_antisym)
   344 
   345 
   346 subsection \<open>Extensional Function Spaces\<close>
   347 
   348 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   349   where "PiE S T = Pi S T \<inter> extensional S"
   350 
   351 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   352 
   353 syntax
   354   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   355 syntax (xsymbols)
   356   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   357 syntax (HTML output)
   358   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   359 translations "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   360 
   361 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60)
   362   where "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   363 
   364 notation (xsymbols)
   365   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   366 
   367 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   368   by (simp add: PiE_def)
   369 
   370 lemma PiE_empty_domain[simp]: "PiE {} T = {\<lambda>x. undefined}"
   371   unfolding PiE_def by simp
   372 
   373 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   374   unfolding PiE_def by simp
   375 
   376 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   377   unfolding PiE_def by auto
   378 
   379 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   380 proof
   381   assume "Pi\<^sub>E I F = {}"
   382   show "\<exists>i\<in>I. F i = {}"
   383   proof (rule ccontr)
   384     assume "\<not> ?thesis"
   385     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   386       by auto
   387     from choice[OF this]
   388     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   389     then have "f \<in> Pi\<^sub>E I F"
   390       by (auto simp: extensional_def PiE_def)
   391     with \<open>Pi\<^sub>E I F = {}\<close> show False
   392       by auto
   393   qed
   394 qed (auto simp: PiE_def)
   395 
   396 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   397   unfolding PiE_def by auto (auto dest!: extensional_arb)
   398 
   399 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   400   unfolding PiE_def by auto
   401 
   402 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   403   unfolding PiE_def extensional_def by auto
   404 
   405 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   406   unfolding PiE_def extensional_def by auto
   407 
   408 lemma PiE_insert_eq: "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   409 proof -
   410   {
   411     fix f assume "f \<in> PiE (insert x S) T" "x \<notin> S"
   412     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   413       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   414   }
   415   moreover
   416   {
   417     fix f assume "f \<in> PiE (insert x S) T" "x \<in> S"
   418     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   419       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   420   }
   421   ultimately show ?thesis
   422     using assms by (auto intro: PiE_fun_upd)
   423 qed
   424 
   425 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   426   by (auto simp: PiE_def)
   427 
   428 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   429   unfolding PiE_def by (auto simp: Pi_cong)
   430 
   431 lemma PiE_E [elim]:
   432   assumes "f \<in> PiE A B"
   433   obtains "x \<in> A" and "f x \<in> B x"
   434     | "x \<notin> A" and "f x = undefined"
   435   using assms by (auto simp: Pi_def PiE_def extensional_def)
   436 
   437 lemma PiE_I[intro!]:
   438   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   439   by (simp add: PiE_def extensional_def)
   440 
   441 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   442   by auto
   443 
   444 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   445   by (simp add: PiE_def Pi_iff)
   446 
   447 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   448   by (simp add: extensional_restrict PiE_def)
   449 
   450 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   451   by (auto simp: PiE_iff)
   452 
   453 lemma PiE_eq_subset:
   454   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   455     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   456     and "i \<in> I"
   457   shows "F i \<subseteq> F' i"
   458 proof
   459   fix x
   460   assume "x \<in> F i"
   461   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   462     by auto
   463   from choice[OF this] obtain f
   464     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   465   then have "f \<in> Pi\<^sub>E I F"
   466     by (auto simp: extensional_def PiE_def)
   467   then have "f \<in> Pi\<^sub>E I F'"
   468     using assms by simp
   469   then show "x \<in> F' i"
   470     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   471 qed
   472 
   473 lemma PiE_eq_iff_not_empty:
   474   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   475   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   476 proof (intro iffI ballI)
   477   fix i
   478   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   479   assume i: "i \<in> I"
   480   show "F i = F' i"
   481     using PiE_eq_subset[of I F F', OF ne eq i]
   482     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   483     by auto
   484 qed (auto simp: PiE_def)
   485 
   486 lemma PiE_eq_iff:
   487   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   488 proof (intro iffI disjCI)
   489   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   490   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   491   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   492     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   493   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   494     by auto
   495 next
   496   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   497   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   498     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   499 qed
   500 
   501 lemma extensional_funcset_fun_upd_restricts_rangeI:
   502   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   503   unfolding extensional_funcset_def extensional_def
   504   apply auto
   505   apply (case_tac "x = xa")
   506   apply auto
   507   done
   508 
   509 lemma extensional_funcset_fun_upd_extends_rangeI:
   510   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   511   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   512   using assms unfolding extensional_funcset_def extensional_def by auto
   513 
   514 
   515 subsubsection \<open>Injective Extensional Function Spaces\<close>
   516 
   517 lemma extensional_funcset_fun_upd_inj_onI:
   518   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   519     and "inj_on f S"
   520   shows "inj_on (f(x := a)) S"
   521   using assms
   522   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   523 
   524 lemma extensional_funcset_extend_domain_inj_on_eq:
   525   assumes "x \<notin> S"
   526   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   527     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   528   using assms
   529   apply (auto del: PiE_I PiE_E)
   530   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   531     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   532   apply (auto simp add: image_iff inj_on_def)
   533   apply (rule_tac x="xa x" in exI)
   534   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   535   apply (rule_tac x="xa(x := undefined)" in exI)
   536   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   537   apply (auto dest!: PiE_mem split: split_if_asm)
   538   done
   539 
   540 lemma extensional_funcset_extend_domain_inj_onI:
   541   assumes "x \<notin> S"
   542   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   543   using assms
   544   apply (auto intro!: inj_onI)
   545   apply (metis fun_upd_same)
   546   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   547   done
   548 
   549 
   550 subsubsection \<open>Cardinality\<close>
   551 
   552 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   553   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   554 
   555 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   556 proof (safe intro!: inj_onI ext)
   557   fix f y g z
   558   assume "x \<notin> S"
   559   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   560   assume "f(x := y) = g(x := z)"
   561   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   562     unfolding fun_eq_iff by auto
   563   from this[of x] show "y = z" by simp
   564   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   565     by (auto split: split_if_asm simp: PiE_def extensional_def)
   566 qed
   567 
   568 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   569 proof (induct rule: finite_induct)
   570   case empty
   571   then show ?case by auto
   572 next
   573   case (insert x S)
   574   then show ?case
   575     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   576 qed
   577 
   578 end