src/Pure/conjunction.ML
author wenzelm
Mon Nov 02 20:34:59 2009 +0100 (2009-11-02)
changeset 33384 1b5ba4e6a953
parent 33277 1bdc3c732fdd
child 35845 e5980f0ad025
permissions -rw-r--r--
modernized structure Simple_Syntax;
     1 (*  Title:      Pure/conjunction.ML
     2     Author:     Makarius
     3 
     4 Meta-level conjunction.
     5 *)
     6 
     7 signature CONJUNCTION =
     8 sig
     9   val conjunction: cterm
    10   val mk_conjunction: cterm * cterm -> cterm
    11   val mk_conjunction_balanced: cterm list -> cterm
    12   val dest_conjunction: cterm -> cterm * cterm
    13   val dest_conjunctions: cterm -> cterm list
    14   val cong: thm -> thm -> thm
    15   val convs: (cterm -> thm) -> cterm -> thm
    16   val conjunctionD1: thm
    17   val conjunctionD2: thm
    18   val conjunctionI: thm
    19   val intr: thm -> thm -> thm
    20   val intr_balanced: thm list -> thm
    21   val elim: thm -> thm * thm
    22   val elim_balanced: int -> thm -> thm list
    23   val curry_balanced: int -> thm -> thm
    24   val uncurry_balanced: int -> thm -> thm
    25 end;
    26 
    27 structure Conjunction: CONJUNCTION =
    28 struct
    29 
    30 (** abstract syntax **)
    31 
    32 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
    33 val read_prop = certify o Simple_Syntax.read_prop;
    34 
    35 val true_prop = certify Logic.true_prop;
    36 val conjunction = certify Logic.conjunction;
    37 
    38 fun mk_conjunction (A, B) = Thm.capply (Thm.capply conjunction A) B;
    39 
    40 fun mk_conjunction_balanced [] = true_prop
    41   | mk_conjunction_balanced ts = Balanced_Tree.make mk_conjunction ts;
    42 
    43 fun dest_conjunction ct =
    44   (case Thm.term_of ct of
    45     (Const ("Pure.conjunction", _) $ _ $ _) => Thm.dest_binop ct
    46   | _ => raise TERM ("dest_conjunction", [Thm.term_of ct]));
    47 
    48 fun dest_conjunctions ct =
    49   (case try dest_conjunction ct of
    50     NONE => [ct]
    51   | SOME (A, B) => dest_conjunctions A @ dest_conjunctions B);
    52 
    53 
    54 
    55 (** derived rules **)
    56 
    57 (* conversion *)
    58 
    59 val cong = Thm.combination o Thm.combination (Thm.reflexive conjunction);
    60 
    61 fun convs cv ct =
    62   (case try dest_conjunction ct of
    63     NONE => cv ct
    64   | SOME (A, B) => cong (convs cv A) (convs cv B));
    65 
    66 
    67 (* intro/elim *)
    68 
    69 local
    70 
    71 val A = read_prop "A" and vA = read_prop "?A";
    72 val B = read_prop "B" and vB = read_prop "?B";
    73 val C = read_prop "C";
    74 val ABC = read_prop "A ==> B ==> C";
    75 val A_B = read_prop "A &&& B";
    76 
    77 val conjunction_def =
    78   Thm.unvarify (Thm.axiom (Context.the_theory (Context.the_thread_data ())) "Pure.conjunction_def");
    79 
    80 fun conjunctionD which =
    81   Drule.implies_intr_list [A, B] (Thm.assume (which (A, B))) COMP
    82   Thm.forall_elim_vars 0 (Thm.equal_elim conjunction_def (Thm.assume A_B));
    83 
    84 in
    85 
    86 val conjunctionD1 = Drule.store_standard_thm (Binding.name "conjunctionD1") (conjunctionD #1);
    87 val conjunctionD2 = Drule.store_standard_thm (Binding.name "conjunctionD2") (conjunctionD #2);
    88 
    89 val conjunctionI =
    90   Drule.store_standard_thm (Binding.name "conjunctionI")
    91     (Drule.implies_intr_list [A, B]
    92       (Thm.equal_elim
    93         (Thm.symmetric conjunction_def)
    94         (Thm.forall_intr C (Thm.implies_intr ABC
    95           (Drule.implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B])))));
    96 
    97 
    98 fun intr tha thb =
    99   Thm.implies_elim
   100     (Thm.implies_elim
   101       (Thm.instantiate ([], [(vA, Thm.cprop_of tha), (vB, Thm.cprop_of thb)]) conjunctionI)
   102     tha)
   103   thb;
   104 
   105 fun elim th =
   106   let
   107     val (A, B) = dest_conjunction (Thm.cprop_of th)
   108       handle TERM (msg, _) => raise THM (msg, 0, [th]);
   109     val inst = Thm.instantiate ([], [(vA, A), (vB, B)]);
   110   in
   111    (Thm.implies_elim (inst conjunctionD1) th,
   112     Thm.implies_elim (inst conjunctionD2) th)
   113   end;
   114 
   115 end;
   116 
   117 
   118 (* balanced conjuncts *)
   119 
   120 fun intr_balanced [] = asm_rl
   121   | intr_balanced ths = Balanced_Tree.make (uncurry intr) ths;
   122 
   123 fun elim_balanced 0 _ = []
   124   | elim_balanced n th = Balanced_Tree.dest elim n th;
   125 
   126 
   127 (* currying *)
   128 
   129 local
   130 
   131 fun conjs thy n =
   132   let val As = map (fn A => Thm.cterm_of thy (Free (A, propT))) (Name.invents Name.context "A" n)
   133   in (As, mk_conjunction_balanced As) end;
   134 
   135 val B = read_prop "B";
   136 
   137 fun comp_rule th rule =
   138   Thm.adjust_maxidx_thm ~1 (th COMP
   139     (rule |> Drule.forall_intr_frees |> Thm.forall_elim_vars (Thm.maxidx_of th + 1)));
   140 
   141 in
   142 
   143 (*
   144   A1 &&& ... &&& An ==> B
   145   -----------------------
   146   A1 ==> ... ==> An ==> B
   147 *)
   148 fun curry_balanced n th =
   149   if n < 2 then th
   150   else
   151     let
   152       val thy = Thm.theory_of_thm th;
   153       val (As, C) = conjs thy n;
   154       val D = Drule.mk_implies (C, B);
   155     in
   156       comp_rule th
   157         (Thm.implies_elim (Thm.assume D) (intr_balanced (map Thm.assume As))
   158           |> Drule.implies_intr_list (D :: As))
   159     end;
   160 
   161 (*
   162   A1 ==> ... ==> An ==> B
   163   -----------------------
   164   A1 &&& ... &&& An ==> B
   165 *)
   166 fun uncurry_balanced n th =
   167   if n < 2 then th
   168   else
   169     let
   170       val thy = Thm.theory_of_thm th;
   171       val (As, C) = conjs thy n;
   172       val D = Drule.list_implies (As, B);
   173     in
   174       comp_rule th
   175         (Drule.implies_elim_list (Thm.assume D) (elim_balanced n (Thm.assume C))
   176           |> Drule.implies_intr_list [D, C])
   177     end;
   178 
   179 end;
   180 
   181 end;